test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32
  33 use lib "$RealBin/lib";
  34 use Exim::Runtest;
  35 use Exim::Utils qw(uniq numerically);
  36
  37 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  39
  40 use constant TEST_TOP => 8999;
  41 use constant TEST_SPECIAL_TOP => 9999;
  42
  43
  44 # Start by initializing some global variables
  45
  46 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  47
  48 # This gets embedded in the D-H params filename, and the value comes
  49 # from asking GnuTLS for "normal", but there appears to be no way to
  50 # use certtool/... to ask what that value currently is.  *sigh*
  51 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  52 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  53 # normal = 2432   tls_dh_max_bits = 2236
  54 my $gnutls_dh_bits_normal = 2236;
  55
  56 my $cf = 'bin/cf -exact';
  57 my $cr = "\r";
  58 my $debug = 0;
  59 my $flavour = do {
  60   my $f = Exim::Runtest::flavour() // '';
  61   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  62 };
  63 my $force_continue = 0;
  64 my $force_update = 0;
  65 my $log_failed_filename = 'failed-summary.log';
  66 my $log_summary_filename = 'run-summary.log';
  67 my $more = 'less -XF';
  68 my $optargs = '';
  69 my $save_output = 0;
  70 my $server_opts = '';
  71 my $slow = 0;
  72 my $valgrind = 0;
  73
  74 my $have_ipv4 = 1;
  75 my $have_ipv6 = 1;
  76 my $have_largefiles = 0;
  77
  78 my @test_list = ();
  79
  80
  81 # Networks to use for DNS tests. We need to choose some networks that will
  82 # never be used so that there is no chance that the host on which we are
  83 # running is actually in one of the test networks. Private networks such as
  84 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  85 # Rather than use some unassigned numbers (that might become assigned later),
  86 # I have chosen some multicast networks, in the belief that such addresses
  87 # won't ever be assigned to hosts. This is the only place where these numbers
  88 # are defined, so it is trivially possible to change them should that ever
  89 # become necessary.
  90
  91 my $parm_ipv4_test_net = 224;
  92 my $parm_ipv6_test_net = 'ff00';
  93
  94 # Port numbers are currently hard-wired
  95
  96 my $parm_port_n = 1223;         # Nothing listening on this port
  97 my $parm_port_s = 1224;         # Used for the "server" command
  98 my $parm_port_d = 1225;         # Used for the Exim daemon
  99 my $parm_port_d2 = 1226;        # Additional for daemon
 100 my $parm_port_d3 = 1227;        # Additional for daemon
 101 my $parm_port_d4 = 1228;        # Additional for daemon
 102 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 103
 104 # Find a suiteable group name for test (currently only 0001
 105 # uses a group name. A numeric group id would do
 106 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 107
 108 # Manually set locale
 109 $ENV{LC_ALL} = 'C';
 110
 111 # In some environments USER does not exist, but we need it for some test(s)
 112 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 113
 114 my ($parm_configure_owner, $parm_configure_group);
 115 my ($parm_ipv4, $parm_ipv6);
 116 my $parm_hostname;
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121 # Define a number of subroutines
 122
 123 ###############################################################################
 124 ###############################################################################
 125
 126
 127 ##################################################
 128 #              Handle signals                    #
 129 ##################################################
 130
 131 sub pipehandler { $sigpipehappened = 1; }
 132
 133 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 134
 135
 136 ##################################################
 137 #       Do global macro substitutions            #
 138 ##################################################
 139
 140 # This function is applied to configurations, command lines and data lines in
 141 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 142 # directory. It takes one argument: the current test number, or zero when
 143 # setting up files before running any tests.
 144
 145 sub do_substitute{
 146 s?\bCALLER\b?$parm_caller?g;
 147 s?\bCALLERGROUP\b?$parm_caller_group?g;
 148 s?\bCALLER_UID\b?$parm_caller_uid?g;
 149 s?\bCALLER_GID\b?$parm_caller_gid?g;
 150 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 151 s?\bDIR/?$parm_cwd/?g;
 152 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 153 s?\bEXIMUSER\b?$parm_eximuser?g;
 154 s?\bHOSTIPV4\b?$parm_ipv4?g;
 155 s?\bHOSTIPV6\b?$parm_ipv6?g;
 156 s?\bHOSTNAME\b?$parm_hostname?g;
 157 s?\bPORT_D\b?$parm_port_d?g;
 158 s?\bPORT_D2\b?$parm_port_d2?g;
 159 s?\bPORT_D3\b?$parm_port_d3?g;
 160 s?\bPORT_D4\b?$parm_port_d4?g;
 161 s?\bPORT_N\b?$parm_port_n?g;
 162 s?\bPORT_S\b?$parm_port_s?g;
 163 s?\bTESTNUM\b?$_[0]?g;
 164 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 165 s?\bV6NET:?$parm_ipv6_test_net:?g;
 166 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 167 s?\bMAILGROUP\b?$parm_mailgroup?g;
 168 }
 169
 170
 171 ##################################################
 172 #     Any state to be preserved across tests     #
 173 ##################################################
 174
 175 my $TEST_STATE = {};
 176
 177
 178 ##################################################
 179 #        Subroutine to tidy up and exit          #
 180 ##################################################
 181
 182 # In all cases, we check for any Exim daemons that have been left running, and
 183 # kill them. Then remove all the spool data, test output, and the modified Exim
 184 # binary if we are ending normally.
 185
 186 # Arguments:
 187 #    $_[0] = 0 for a normal exit; full cleanup done
 188 #    $_[0] > 0 for an error exit; no files cleaned up
 189 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 190
 191 sub tests_exit{
 192 my($rc) = $_[0];
 193 my($spool);
 194
 195 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 196 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 197 # the background.
 198
 199 if (exists $TEST_STATE->{exim_pid})
 200   {
 201   $pid = $TEST_STATE->{exim_pid};
 202   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 203   system("sudo kill -INT $pid");
 204   }
 205
 206 if (opendir(DIR, "spool"))
 207   {
 208   my(@spools) = sort readdir(DIR);
 209   closedir(DIR);
 210   foreach $spool (@spools)
 211     {
 212     next if $spool !~ /^exim-daemon./;
 213     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 214     chomp($pid = <PID>);
 215     close(PID);
 216     print "Tidyup: killing daemon pid=$pid\n";
 217     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 218     }
 219   }
 220 else
 221   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 222
 223 # Close the terminal input and remove the test files if all went well, unless
 224 # the option to save them is set. Always remove the patched Exim binary. Then
 225 # exit normally, or die.
 226
 227 close(T);
 228 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 229   if ($rc == 0 && !$save_output);
 230
 231 system("sudo /bin/rm -rf ./eximdir/*")
 232   if (!$save_output);
 233
 234 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 235 exit $rc if ($rc >= 0);
 236 die "** runtest error: $_[1]\n";
 237 }
 238
 239
 240
 241 ##################################################
 242 #   Subroutines used by the munging subroutine   #
 243 ##################################################
 244
 245 # This function is used for things like message ids, where we want to generate
 246 # more than one value, but keep a consistent mapping throughout.
 247 #
 248 # Arguments:
 249 #   $oldid        the value from the file
 250 #   $base         a base string into which we insert a sequence
 251 #   $sequence     the address of the current sequence counter
 252
 253 sub new_value {
 254 my($oldid, $base, $sequence) = @_;
 255 my($newid) = $cache{$oldid};
 256 if (! defined $newid)
 257   {
 258   $newid = sprintf($base, $$sequence++);
 259   $cache{$oldid} = $newid;
 260   }
 261 return $newid;
 262 }
 263
 264
 265 # This is used while munging the output from exim_dumpdb.
 266 # May go wrong across DST changes.
 267
 268 sub date_seconds {
 269 my($day,$month,$year,$hour,$min,$sec) =
 270   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 271 my($mon);
 272 if   ($month =~ /Jan/) {$mon = 0;}
 273 elsif($month =~ /Feb/) {$mon = 1;}
 274 elsif($month =~ /Mar/) {$mon = 2;}
 275 elsif($month =~ /Apr/) {$mon = 3;}
 276 elsif($month =~ /May/) {$mon = 4;}
 277 elsif($month =~ /Jun/) {$mon = 5;}
 278 elsif($month =~ /Jul/) {$mon = 6;}
 279 elsif($month =~ /Aug/) {$mon = 7;}
 280 elsif($month =~ /Sep/) {$mon = 8;}
 281 elsif($month =~ /Oct/) {$mon = 9;}
 282 elsif($month =~ /Nov/) {$mon = 10;}
 283 elsif($month =~ /Dec/) {$mon = 11;}
 284 return timelocal($sec,$min,$hour,$day,$mon,$year);
 285 }
 286
 287
 288 # This is a subroutine to sort maildir files into time-order. The second field
 289 # is the microsecond field, and may vary in length, so must be compared
 290 # numerically.
 291
 292 sub maildirsort {
 293 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 294 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 295 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 296 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 297 }
 298
 299
 300
 301 ##################################################
 302 #   Subroutine list files below a directory      #
 303 ##################################################
 304
 305 # This is used to build up a list of expected mail files below a certain path
 306 # in the directory tree. It has to be recursive in order to deal with multiple
 307 # maildir mailboxes.
 308
 309 sub list_files_below {
 310 my($dir) = $_[0];
 311 my(@yield) = ();
 312 my(@sublist, $file);
 313
 314 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 315 @sublist = sort maildirsort readdir(DIR);
 316 closedir(DIR);
 317
 318 foreach $file (@sublist)
 319   {
 320   next if $file eq "." || $file eq ".." || $file eq "CVS";
 321   if (-d "$dir/$file")
 322     { @yield = (@yield, list_files_below("$dir/$file")); }
 323   else
 324     { push @yield, "$dir/$file"; }
 325   }
 326
 327 return @yield;
 328 }
 329
 330
 331
 332 ##################################################
 333 #         Munge a file before comparing          #
 334 ##################################################
 335
 336 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 337 # on into standard values, so that the compare works. Perl's substitution with
 338 # an expression provides a neat way to do some of these changes.
 339
 340 # We keep a global associative array for repeatedly turning the same values
 341 # into the same standard values throughout the data from a single test.
 342 # Message ids get this treatment (can't be made reliable for times), and
 343 # times in dumped retry databases are also handled in a special way, as are
 344 # incoming port numbers.
 345
 346 # On entry to the subroutine, the file to write to is already opened with the
 347 # name MUNGED. The input file name is the only argument to the subroutine.
 348 # Certain actions are taken only when the name contains "stderr", "stdout",
 349 # or "log". The yield of the function is 1 if a line matching "*** truncated
 350 # ***" is encountered; otherwise it is 0.
 351
 352 sub munge {
 353 my($file) = $_[0];
 354 my($extra) = $_[1];
 355 my($yield) = 0;
 356 my(@saved) = ();
 357
 358 local $_;
 359
 360 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 361
 362 my($is_log) = $file =~ /log/;
 363 my($is_stdout) = $file =~ /stdout/;
 364 my($is_stderr) = $file =~ /stderr/;
 365 my($is_mail) = $file =~ /mail/;
 366
 367 # Date pattern
 368
 369 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 370
 371 # Pattern for matching pids at start of stderr lines; initially something
 372 # that won't match.
 373
 374 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 375
 376 # Scan the file and make the changes. Near the bottom there are some changes
 377 # that are specific to certain file types, though there are also some of those
 378 # inline too.
 379
 380 LINE: while(<IN>)
 381   {
 382 RESET_AFTER_EXTRA_LINE_READ:
 383   # Custom munges
 384   if ($extra)
 385     {
 386     next if $extra =~ m%^/%  &&  eval $extra;
 387     eval $extra if $extra =~ m/^s/;
 388     }
 389
 390   # Check for "*** truncated ***"
 391   $yield = 1 if /\*\*\* truncated \*\*\*/;
 392
 393   # Replace the name of this host
 394   s/\Q$parm_hostname\E/the.local.host.name/g;
 395
 396   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 397   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 398
 399   # The name of the shell may vary
 400   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 401
 402   # Replace the path to the testsuite directory
 403   s?\Q$parm_cwd\E?TESTSUITE?g;
 404
 405   # Replace the Exim version number (may appear in various places)
 406   # patchexim should have fixed this for us
 407   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 408
 409   # Replace Exim message ids by a unique series
 410   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 411     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 412
 413   # The names of lock files appear in some error and debug messages
 414   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 415
 416   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 417   # port" message, because it is not always the same.
 418   s/port (\d+) \([^)]+\)/port $1/g
 419     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 420
 421   # Challenges in SPA authentication
 422   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 423
 424   # PRVS values
 425   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 426   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463     my($increment) = date_seconds($date3) - date_seconds($date2);
 464
 465     # We used to use globally unique replacement values, but timing
 466     # differences make this impossible. Just show the increment on the
 467     # last one.
 468
 469     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 470       $increment, $expired);
 471     next;
 472     }
 473
 474   # more_errno values in exim_dumpdb output which are times
 475   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 476
 477
 478   # ======== Dates and times ========
 479
 480   # Dates and times are all turned into the same value - trying to turn
 481   # them into different ones cannot be done repeatedly because they are
 482   # real time stamps generated while running the test. The actual date and
 483   # time used was fixed when I first started running automatic Exim tests.
 484
 485   # Date/time in header lines and SMTP responses
 486   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 487     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 488
 489   # Date/time in logs and in one instance of a filter test
 490   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 491   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 492   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 493
 494   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 495   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 496
 497   # Date/time in message separators
 498   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 499     /Tue Mar 02 09:44:33 1999/gx;
 500
 501   # Date of message arrival in spool file as shown by -Mvh
 502   s/^\d{9,10}\s0$/ddddddddd 0/;
 503
 504   # Date/time in mbx mailbox files
 505   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 506
 507   # Dates/times in debugging output for writing retry records
 508   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 509     {
 510     my($next) = $3 - $2;
 511     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 512     }
 513   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 514   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 515
 516   # Time to retry may vary
 517   s/time to retry = \S+/time to retry = tttt/;
 518   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 519   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 520
 521   # Date/time in exim -bV output
 522   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 523
 524   # Eximstats heading
 525   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 526     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 527
 528   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 529   # us the former on a new connection.
 530   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 531
 532   # ======== TLS certificate algorithms ========
 533   # Test machines might have various different TLS library versions supporting
 534   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 535   # treat the standard algorithms the same.
 536   # So far, have seen:
 537   #   TLSv1:AES128-GCM-SHA256:128
 538   #   TLSv1:AES256-SHA:256
 539   #   TLSv1.1:AES256-SHA:256
 540   #   TLSv1.2:AES256-GCM-SHA384:256
 541   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 542   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 543   # We also need to handle the ciphersuite without the TLS part present, for
 544   # client-ssl's output.  We also see some older forced ciphersuites, but
 545   # negotiating TLS 1.2 instead of 1.0.
 546   # Mail headers (...), log-lines X=..., client-ssl output ...
 547   # (and \b doesn't match between ' ' and '(' )
 548   #
 549   # Retain the authentication algorith field as we want to test that.
 550
 551   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 552   s/((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHA/g;
 553   s/((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHA:xxx/g;
 554
 555   # LibreSSL
 556   # TLSv1:AES256-GCM-SHA384:256
 557   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 558   #
 559   # ECDHE-RSA-CHACHA20-POLY1305
 560   # AES256-GCM-SHA384
 561
 562   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 563   s/((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHA/g;
 564   s/((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHA:xxx/g;
 565
 566   # GnuTLS have seen:
 567   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 568   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 569   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 570   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 571   #
 572   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 573   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 574   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 575   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 576   # and as stand-alone cipher:
 577   #   ECDHE-RSA-AES256-SHA
 578   #   DHE-RSA-AES256-SHA256
 579   #   DHE-RSA-AES256-SHA
 580   # picking latter as canonical simply because regex easier that way.
 581   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 582   s/TLS1.[012]:((EC)?DHE_)?(RSA|ECDSA)_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:ke_$3_AES_256_CBC_SHAnnn:256/g;
 583   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAxx/g;
 584
 585   # GnuTLS library error message changes
 586   s/No certificate was found/The peer did not send any certificate/g;
 587 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 588   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 589
 590   # (this new one is a generic channel-read error, but the testsuite
 591   # only hits it in one place)
 592   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 593
 594   # (replace old with new, hoping that old only happens in one situation)
 595   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 596   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 597
 598   # signature algorithm names
 599   s/RSA-SHA1/RSA-SHA/;
 600
 601
 602   # ======== Caller's login, uid, gid, home, gecos ========
 603
 604   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 605   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 606   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 607
 608   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 609   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 610
 611   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 612   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 613
 614   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 615
 616   # When looking at spool files with -Mvh, we will find not only the caller
 617   # login, but also the uid and gid. It seems that $) in some Perls gives all
 618   # the auxiliary gids as well, so don't bother checking for that.
 619
 620   s/^CALLER $> \d+$/CALLER UID GID/;
 621
 622   # There is one case where the caller's login is forced to something else,
 623   # in order to test the processing of logins that contain spaces. Weird what
 624   # some people do, isn't it?
 625
 626   s/^spaced user $> \d+$/CALLER UID GID/;
 627
 628
 629   # ======== Exim's login ========
 630   # For messages received by the daemon, this is in the -H file, which some
 631   # tests inspect. For bounce messages, this will appear on the U= lines in
 632   # logs and also after Received: and in addresses. In one pipe test it appears
 633   # after "Running as:". It also appears in addresses, and in the names of lock
 634   # files.
 635
 636   s/U=$parm_eximuser/U=EXIMUSER/;
 637   s/user=$parm_eximuser/user=EXIMUSER/;
 638   s/login=$parm_eximuser/login=EXIMUSER/;
 639   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 640   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 641   s/\b$parm_eximuser@/EXIMUSER@/;
 642   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 643
 644   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 645   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 646
 647   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 648   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 649
 650   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 651
 652
 653   # ======== General uids, gids, and pids ========
 654   # Note: this must come after munges for caller's and exim's uid/gid
 655
 656   # These are for systems where long int is 64
 657   s/\buid=4294967295/uid=-1/;
 658   s/\beuid=4294967295/euid=-1/;
 659   s/\bgid=4294967295/gid=-1/;
 660   s/\begid=4294967295/egid=-1/;
 661
 662   s/\bgid=\d+/gid=gggg/;
 663   s/\begid=\d+/egid=gggg/;
 664   s/\b(pid=|PID: )\d+/$1pppp/;
 665   s/\buid=\d+/uid=uuuu/;
 666   s/\beuid=\d+/euid=uuuu/;
 667   s/set_process_info:\s+\d+/set_process_info: pppp/;
 668   s/queue run pid \d+/queue run pid ppppp/;
 669   s/process \d+ running as transport filter/process pppp running as transport filter/;
 670   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 671   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 672   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 673
 674   # Pid in temp file in appendfile transport
 675   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 676
 677   # Optional pid in log lines
 678   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 679     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 680
 681   # Detect a daemon stderr line with a pid and save the pid for subsequent
 682   # removal from following lines.
 683   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 684   s/^$spid //;
 685
 686   # Queue runner waiting messages
 687   s/waiting for children of \d+/waiting for children of pppp/;
 688   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 689
 690   # The spool header file name varies with PID
 691   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 692
 693   # ======== Port numbers ========
 694   # Incoming port numbers may vary, but not in daemon startup line.
 695
 696   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 697   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 698
 699   # This handles "connection from" and the like, when the port is given
 700   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 701       && !/\*>/ && !/Connection refused/)
 702     {
 703     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 704     }
 705
 706   # Port in host address in spool file output from -Mvh
 707   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 708
 709   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 710     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 711   }
 712
 713
 714   # ======== Local IP addresses ========
 715   # The amount of space between "host" and the address in verification output
 716   # depends on the length of the host name. We therefore reduce it to one space
 717   # for all of them.
 718   # Also, the length of space at the end of the host line is dependent
 719   # on the length of the longest line, so strip it also on otherwise
 720   # un-rewritten lines like localhost
 721
 722   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 723   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 724   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 725   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 726   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 727   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 728   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 729   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 730   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 731   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 732
 733
 734   # ======== Test network IP addresses ========
 735   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 736   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 737
 738
 739   # ======== IP error numbers and messages ========
 740   # These vary between operating systems
 741   s/Can't assign requested address/Network Error/;
 742   s/Cannot assign requested address/Network Error/;
 743   s/Operation timed out/Connection timed out/;
 744   s/Address family not supported by protocol family/Network Error/;
 745   s/Network is unreachable/Network Error/;
 746   s/Invalid argument/Network Error/;
 747
 748   s/\(\d+\): Network/(dd): Network/;
 749   s/\(\d+\): Connection refused/(dd): Connection refused/;
 750   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 751   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 752   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 753
 754
 755   # ======== Other error numbers ========
 756   s/errno=\d+/errno=dd/g;
 757
 758   # ======== System Error Messages ======
 759   # depending on the underlaying file system the error message seems to differ
 760   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 761
 762   # ======== Output from ls ========
 763   # Different operating systems use different spacing on long output
 764   #s/ +/ /g if /^[-rwd]{10} /;
 765   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 766   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 767   # unfortunately matches a non-ls linefull of dashes.
 768   # Allow the case where we've already picked out the file protection bits.
 769   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 770     s/ +/ /g;
 771   }
 772
 773
 774   # ======== Message sizes =========
 775   # Message sizes vary, owing to different logins and host names that get
 776   # automatically inserted. I can't think of any way of even approximately
 777   # comparing these.
 778
 779   s/([\s,])S=\d+\b/$1S=sss/;
 780   s/:S\d+\b/:Ssss/;
 781   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 782   s/\sSIZE=\d+\b/ SIZE=ssss/;
 783   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 784   s/old size = \d+\b/old size = sssss/;
 785   s/message size = \d+\b/message size = sss/;
 786   s/this message = \d+\b/this message = sss/;
 787   s/Size of headers = \d+/Size of headers = sss/;
 788   s/sum=(?!0)\d+/sum=dddd/;
 789   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 790   s/(?<=sum=0 )count=\d+\b/count=dd/;
 791   s/,S is \d+\b/,S is ddddd/;
 792   s/\+0100,\d+;/+0100,ddd;/;
 793   s/\(\d+ bytes written\)/(ddd bytes written)/;
 794   s/added '\d+ 1'/added 'ddd 1'/;
 795   s/Received\s+\d+/Received               nnn/;
 796   s/Delivered\s+\d+/Delivered              nnn/;
 797
 798
 799   # ======== Values in spool space failure message ========
 800   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 801
 802
 803   # ======== Filter sizes ========
 804   # The sizes of filter files may vary because of the substitution of local
 805   # filenames, logins, etc.
 806
 807   s/^\d+(?= bytes read from )/ssss/;
 808
 809
 810   # ======== OpenSSL error messages ========
 811   # Different releases of the OpenSSL libraries seem to give different error
 812   # numbers, or handle specific bad conditions in different ways, leading to
 813   # different wording in the error messages, so we cannot compare them.
 814
 815 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 816 #    but I can't work out how to deal with that.
 817   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 818   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 819   next if /SSL verify error: depth=0 error=certificate not trusted/;
 820
 821   # ======== Maildir things ========
 822   # timestamp output in maildir processing
 823   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 824
 825   # maildir delivery files appearing in log lines (in cases of error)
 826   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 827
 828   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 829
 830   # Maildir file names in general
 831   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 832
 833   # Maildirsize data
 834   while (/^\d+S,\d+C\s*$/)
 835     {
 836     print MUNGED;
 837     while (<IN>)
 838       {
 839       last if !/^\d+ \d+\s*$/;
 840       print MUNGED "ddd d\n";
 841       }
 842     last if !defined $_;
 843     }
 844   last if !defined $_;
 845
 846
 847   # ======== Output from the "fd" program about open descriptors ========
 848   # The statuses seem to be different on different operating systems, but
 849   # at least we'll still be checking the number of open fd's.
 850
 851   s/max fd = \d+/max fd = dddd/;
 852   s/status=0 RDONLY/STATUS/g;
 853   s/status=1 WRONLY/STATUS/g;
 854   s/status=2 RDWR/STATUS/g;
 855
 856
 857   # ======== Contents of spool files ========
 858   # A couple of tests dump the contents of the -H file. The length fields
 859   # will be wrong because of different user names, etc.
 860   s/^\d\d\d(?=[PFS*])/ddd/;
 861
 862
 863   # ========= Exim lookups ==================
 864   # Lookups have a char which depends on the number of lookup types compiled in,
 865   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 866   # other output is fragile; perhaps the debug output should be revised instead.
 867   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 868
 869   # ==========================================================
 870   # MIME boundaries in RFC3461 DSN messages
 871   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 872
 873   # ==========================================================
 874   # Some munging is specific to the specific file types
 875
 876   # ======== stdout ========
 877
 878   if ($is_stdout)
 879     {
 880     # Skip translate_ip_address and use_classresources in -bP output because
 881     # they aren't always there.
 882
 883     next if /translate_ip_address =/;
 884     next if /use_classresources/;
 885
 886     # In certain filter tests, remove initial filter lines because they just
 887     # clog up by repetition.
 888
 889     if ($rmfiltertest)
 890       {
 891       next if /^(Sender\staken\sfrom|
 892                  Return-path\scopied\sfrom|
 893                  Sender\s+=|
 894                  Recipient\s+=)/x;
 895       if (/^Testing \S+ filter/)
 896         {
 897         $_ = <IN>;    # remove blank line
 898         next;
 899         }
 900       }
 901
 902     # remote IPv6 addrs vary
 903     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 904
 905     # openssl version variances
 906   # Error lines on stdout from SSL contain process id values and file names.
 907   # They also contain a source file name and line number, which may vary from
 908   # release to release.
 909
 910     next if /^SSL info:/;
 911     next if /SSL verify error: depth=0 error=certificate not trusted/;
 912     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 913     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
 914     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
 915
 916     # gnutls version variances
 917     next if /^Error in the pull function./;
 918
 919     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
 920     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
 921     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
 922
 923     # subsecond timstamp info in reported header-files
 924     s/^(-received_time_usec \.)\d{6}$/$1uuuuuu/;
 925
 926     # Postgres server takes varible time to shut down; lives in various places
 927     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
 928     s/^\/.*postgres /POSTGRES /;
 929
 930     # ARC is not always supported by the build
 931     next if /^arc_sign =/;
 932     }
 933
 934   # ======== stderr ========
 935
 936   elsif ($is_stderr)
 937     {
 938     # The very first line of debugging output will vary
 939
 940     s/^Exim version .*/Exim version x.yz ..../;
 941
 942     # Debugging lines for Exim terminations and process-generation
 943
 944     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 945     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
 946
 947     # IP address lookups use gethostbyname() when IPv6 is not supported,
 948     # and gethostbyname2() or getipnodebyname() when it is.
 949
 950     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 951
 952     # we don't care what TZ enviroment the testhost was running
 953     next if /^Reset TZ to/;
 954
 955     # drop gnutls version strings
 956     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 957     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 958
 959     # drop openssl version strings
 960     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 961     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 962
 963     # drop lookups
 964     next if /^Lookups \(built-in\):/;
 965     next if /^Loading lookup modules from/;
 966     next if /^Loaded \d+ lookup modules/;
 967     next if /^Total \d+ lookups/;
 968
 969     # drop compiler information
 970     next if /^Compiler:/;
 971
 972     # and the ugly bit
 973     # different libraries will have different numbers (possibly 0) of follow-up
 974     # lines, indenting with more data
 975     if (/^Library version:/) {
 976       while (1) {
 977         $_ = <IN>;
 978         next if /^\s/;
 979         goto RESET_AFTER_EXTRA_LINE_READ;
 980       }
 981     }
 982
 983     # drop other build-time controls emitted for debugging
 984     next if /^WHITELIST_D_MACROS:/;
 985     next if /^TRUSTED_CONFIG_LIST:/;
 986
 987     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 988     # with -be, privileges will have been dropped, so this will always
 989     # be the case
 990     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 991
 992     # We might not keep this check; rather than change all the tests, just
 993     # ignore it as long as it succeeds; then we only need to change the
 994     # TLS tests where tls_require_ciphers has been set.
 995     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 996       my $discard = <IN>;
 997       next;
 998     }
 999     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1000
1001     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1002     next if /^macros_trusted overridden to true by whitelisting/;
1003
1004     # We have to omit the localhost ::1 address so that all is well in
1005     # the IPv4-only case.
1006
1007     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1008       if (/looked up these IP addresses/);
1009     next if /name=localhost address=::1/;
1010
1011     # drop pdkim debugging header
1012     next if /^PDKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1013
1014     # Various other IPv6 lines must be omitted too
1015
1016     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1017     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1018     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1019     next if / in dns_ipv4_lookup?/;
1020
1021     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1022       {
1023       $_= <IN>;     # Gets "returning DNS_NODATA"
1024       next;
1025       }
1026
1027     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1028     # are unset, because tls ain't always there.
1029
1030     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1031                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1032
1033     # Skip auxiliary group lists because they will vary.
1034
1035     next if /auxiliary group list:/;
1036
1037     # Skip "extracted from gecos field" because the gecos field varies
1038
1039     next if /extracted from gecos field/;
1040
1041     # Skip "waiting for data on socket" and "read response data: size=" lines
1042     # because some systems pack more stuff into packets than others.
1043
1044     next if /waiting for data on socket/;
1045     next if /read response data: size=/;
1046
1047     # If Exim is compiled with readline support but it can't find the library
1048     # to load, there will be an extra debug line. Omit it.
1049
1050     next if /failed to load readline:/;
1051
1052     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1053     # O_CREAT; other's don't. In the latter case there is some debugging output
1054     # which is not present in the former. Skip the relevant lines (there are
1055     # two of them).
1056
1057     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1058       {
1059       $_ = <IN>;
1060       next;
1061       }
1062
1063     # Some tests turn on +expand debugging to check on expansions.
1064     # Unfortunately, the Received: expansion varies, depending on whether TLS
1065     # is compiled or not. So we must remove the relevant debugging if it is.
1066
1067     if (/^condition: def:tls_cipher/)
1068       {
1069       while (<IN>) { last if /^condition: def:sender_address/; }
1070       }
1071     elsif (/^expanding: Received: /)
1072       {
1073       while (<IN>) { last if !/^\s/; }
1074       }
1075
1076     # remote port numbers vary
1077     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1078
1079     # Skip hosts_require_dane checks when the options
1080     # are unset, because dane ain't always there.
1081
1082     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1083
1084     # SUPPORT_PROXY
1085     next if /host in hosts_proxy\?/;
1086
1087     # Experimental_International
1088     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1089
1090     # Environment cleaning
1091     next if /\w+ in keep_environment\? (yes|no)/;
1092
1093     # Sizes vary with test hostname
1094     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1095
1096     # Spool filesystem free space changes on different systems.
1097     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1098
1099     # Non-TLS builds have different expansions for received_header_text
1100     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1101       {
1102       $_ .= <IN>;
1103       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1104       }
1105     if (/^ ├──condition: def:tls_cipher$/)
1106       {
1107       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1108       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1109       }
1110
1111     # Not all platforms build with DKIM enabled
1112     next if /^PDKIM >> Body data for hash, canonicalized/;
1113
1114     # Not all platforms have sendfile support
1115     next if /^cannot use sendfile for body: no support$/;
1116
1117     #  Parts of DKIM-specific debug output depend on the time/date
1118     next if /^date:\w+,\{SP\}/;
1119     next if /^PDKIM \[[^[]+\] (Header hash|b) computed:/;
1120
1121     # Not all platforms support TCP Fast Open, and the compile omits the check
1122     if (s/\S+ in hosts_try_fastopen\? no \(option unset\)\n$//)
1123       {
1124       $_ .= <IN>;
1125       s/ \.\.\. >>> / ... /;
1126       s/Address family not supported by protocol family/Network Error/;
1127       s/Network is unreachable/Network Error/;
1128       }
1129
1130     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1131
1132     # Specific pointer values reported for DB operations change from run to run
1133     s/^(returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1134     s/^(EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1135
1136     # Platform-dependent output during MySQL startup
1137     next if /PerconaFT file system space/;
1138     next if /^Waiting for MySQL server to answer/;
1139     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1140
1141     # Not all builds include DMARC
1142     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1143
1144     # When Exim is checking the size of directories for maildir, it uses
1145     # the check_dir_size() function to scan directories. Of course, the order
1146     # of the files that are obtained using readdir() varies from system to
1147     # system. We therefore buffer up debugging lines from check_dir_size()
1148     # and sort them before outputting them.
1149
1150     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1151       {
1152       push @saved, $_;
1153       }
1154     else
1155       {
1156       if (@saved > 0)
1157         {
1158         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1159           "to ensure consistency\n";
1160         @saved = sort(@saved);
1161         print MUNGED @saved;
1162         @saved = ();
1163         }
1164
1165       # Skip some lines that Exim puts out at the start of debugging output
1166       # because they will be different in different binaries.
1167
1168       print MUNGED
1169         unless (/^Berkeley DB: / ||
1170                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1171                 /^Authenticators:/ ||
1172                 /^Lookups:/ ||
1173                 /^Support for:/ ||
1174                 /^Routers:/ ||
1175                 /^Transports:/ ||
1176                 /^Malware:/ ||
1177                 /^log selectors =/ ||
1178                 /^cwd=/ ||
1179                 /^Fixed never_users:/ ||
1180                 /^Configure owner:/ ||
1181                 /^Size of off_t:/
1182                 );
1183
1184
1185       }
1186
1187     next;
1188     }
1189
1190   # ======== log ========
1191
1192   elsif ($is_log)
1193     {
1194     # Berkeley DB version differences
1195     next if / Berkeley DB error: /;
1196
1197     # CHUNKING: exact sizes depend on hostnames in headers
1198     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1199
1200     # openssl version variances
1201     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1202     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1203     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1204     }
1205
1206   # ======== All files other than stderr ========
1207
1208   print MUNGED;
1209   }
1210
1211 close(IN);
1212 return $yield;
1213 }
1214
1215
1216
1217
1218 ##################################################
1219 #        Subroutine to interact with caller      #
1220 ##################################################
1221
1222 # Arguments: [0] the prompt string
1223 #            [1] if there is a U in the prompt and $force_update is true
1224 #            [2] if there is a C in the prompt and $force_continue is true
1225 # Returns:   returns the answer
1226
1227 sub interact {
1228   my ($prompt, $have_u, $have_c) = @_;
1229
1230   print $prompt;
1231
1232   if ($have_u) {
1233     print "... update forced\n";
1234     return 'u';
1235   }
1236
1237   if ($have_c) {
1238     print "... continue forced\n";
1239     return 'c';
1240   }
1241
1242   return lc <T>;
1243 }
1244
1245
1246
1247 ##################################################
1248 #    Subroutine to log in force_continue mode    #
1249 ##################################################
1250
1251 # In force_continue mode, we just want a terse output to a statically
1252 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1253 # all have mismatches, it will log multiple times.
1254 #
1255 # Arguments: [0] the logfile to append to
1256 #            [1] the testno that failed
1257 # Returns:   nothing
1258
1259
1260
1261 sub log_failure {
1262   my ($logfile, $testno, $detail) = @_;
1263
1264   open(my $fh, '>>', $logfile) or return;
1265
1266   print $fh "Test $testno "
1267         . (defined $detail ? "$detail " : '')
1268         . "failed\n";
1269 }
1270
1271 # Computer-readable summary results logfile
1272
1273 sub log_test {
1274   my ($logfile, $testno, $resultchar) = @_;
1275
1276   open(my $fh, '>>', $logfile) or return;
1277   print $fh "$testno $resultchar\n";
1278 }
1279
1280
1281
1282 ##################################################
1283 #    Subroutine to compare one output file       #
1284 ##################################################
1285
1286 # When an Exim server is part of the test, its output is in separate files from
1287 # an Exim client. The server data is concatenated with the client data as part
1288 # of the munging operation.
1289 #
1290 # Arguments:  [0] the name of the main raw output file
1291 #             [1] the name of the server raw output file or undef
1292 #             [2] where to put the munged copy
1293 #             [3] the name of the saved file
1294 #             [4] TRUE if this is a log file whose deliveries must be sorted
1295 #             [5] optionally, a custom munge command
1296 #
1297 # Returns:    0 comparison succeeded
1298 #             1 comparison failed; differences to be ignored
1299 #             2 comparison failed; files may have been updated (=> re-compare)
1300 #
1301 # Does not return if the user replies "Q" to a prompt.
1302
1303 sub check_file{
1304 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1305
1306 # If there is no saved file, the raw files must either not exist, or be
1307 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1308
1309 # we check if there is a flavour specific file, but we remember
1310 # the original file name as "generic"
1311 $sf_generic = $sf;
1312 $sf_flavour = "$sf_generic.$flavour";
1313 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1314
1315 if (! -e $sf_current)
1316   {
1317   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1318
1319   print "\n";
1320   print "** $rf is not empty\n" if (-s $rf);
1321   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1322
1323   for (;;)
1324     {
1325     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1326     tests_exit(1) if /^q?$/;
1327     if (/^c$/ && $force_continue) {
1328       log_failure($log_failed_filename, $testno, $rf);
1329       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1330     }
1331     return 1 if /^c$/i && $rf !~ /paniclog/ && $rsf !~ /paniclog/;
1332     last if (/^[sc]$/);
1333     }
1334
1335   foreach $f ($rf, $rsf)
1336     {
1337     if (defined $f && -s $f)
1338       {
1339       print "\n";
1340       print "------------ $f -----------\n"
1341         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1342       system("$more '$f'");
1343       }
1344     }
1345
1346   print "\n";
1347   for (;;)
1348     {
1349     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1350     tests_exit(1) if /^q?$/;
1351     if (/^c$/ && $force_continue) {
1352       log_failure($log_failed_filename, $testno, $rf);
1353       log_test($log_summary_filename, $testno, 'F')
1354     }
1355     return 1 if /^c$/i;
1356     last if (/^u$/i);
1357     }
1358   }
1359
1360 #### $_
1361
1362 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1363 # was a request to create a saved file. First, create the munged file from any
1364 # data that does exist.
1365
1366 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1367 my($truncated) = munge($rf, $extra) if -e $rf;
1368
1369 # Append the raw server log, if it is non-empty
1370 if (defined $rsf && -e $rsf)
1371   {
1372   print MUNGED "\n******** SERVER ********\n";
1373   $truncated |= munge($rsf, $extra);
1374   }
1375 close(MUNGED);
1376
1377 # If a saved file exists, do the comparison. There are two awkward cases:
1378 #
1379 # If "*** truncated ***" was found in the new file, it means that a log line
1380 # was overlong, and truncated. The problem is that it may be truncated at
1381 # different points on different systems, because of different user name
1382 # lengths. We reload the file and the saved file, and remove lines from the new
1383 # file that precede "*** truncated ***" until we reach one that matches the
1384 # line that precedes it in the saved file.
1385 #
1386 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1387 # for an individual message might vary in their order from system to system, as
1388 # a result of parallel deliveries. We load the munged file and sort sequences
1389 # of delivery lines.
1390
1391 if (-e $sf_current)
1392   {
1393   # Deal with truncated text items
1394
1395   if ($truncated)
1396     {
1397     my(@munged, @saved, $i, $j, $k);
1398
1399     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1400     @munged = <MUNGED>;
1401     close(MUNGED);
1402     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1403     @saved = <SAVED>;
1404     close(SAVED);
1405
1406     $j = 0;
1407     for ($i = 0; $i < @munged; $i++)
1408       {
1409       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1410         {
1411         for (; $j < @saved; $j++)
1412           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1413         last if $j >= @saved;     # not found in saved
1414
1415         for ($k = $i - 1; $k >= 0; $k--)
1416           { last if $munged[$k] eq $saved[$j - 1]; }
1417
1418         last if $k <= 0;          # failed to find previous match
1419         splice @munged, $k + 1, $i - $k - 1;
1420         $i = $k + 1;
1421         }
1422       }
1423
1424     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1425     for ($i = 0; $i < @munged; $i++)
1426       { print MUNGED $munged[$i]; }
1427     close(MUNGED);
1428     }
1429
1430   # Deal with log sorting
1431
1432   if ($sortfile)
1433     {
1434     my(@munged, $i, $j);
1435
1436     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1437     @munged = <MUNGED>;
1438     close(MUNGED);
1439
1440     for ($i = 0; $i < @munged; $i++)
1441       {
1442       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1443         {
1444         for ($j = $i + 1; $j < @munged; $j++)
1445           {
1446           last if $munged[$j] !~
1447             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1448           }
1449         @temp = splice(@munged, $i, $j - $i);
1450         @temp = sort(@temp);
1451         splice(@munged, $i, 0, @temp);
1452         }
1453       }
1454
1455     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1456     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1457     for ($i = 0; $i < @munged; $i++)
1458       { print MUNGED $munged[$i]; }
1459     close(MUNGED);
1460     }
1461
1462   # Do the comparison
1463
1464   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1465
1466   # Handle comparison failure
1467
1468   print "** Comparison of $mf with $sf_current failed";
1469   system("$more test-cf");
1470
1471   print "\n";
1472   for (;;)
1473     {
1474     $_ = interact('Continue, Retry, Update current'
1475         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1476         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1477     tests_exit(1) if /^q?$/;
1478     if (/^c$/ && $force_continue) {
1479       log_failure($log_failed_filename, $testno, $sf_current);
1480       log_test($log_summary_filename, $testno, 'F')
1481     }
1482     return 1 if /^c$/i;
1483     return 2 if /^r$/i;
1484     last if (/^[us]$/i);
1485     }
1486   }
1487
1488 # Update or delete the saved file, and give the appropriate return code.
1489
1490 if (-s $mf)
1491   {
1492     my $sf = /^u/i ? $sf_current : $sf_flavour;
1493     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1494   }
1495 else
1496   {
1497     # if we deal with a flavour file, we can't delete it, because next time the generic
1498     # file would be used again
1499     if ($sf_current eq $sf_flavour) {
1500       open(FOO, ">$sf_current");
1501       close(FOO);
1502     }
1503     else {
1504       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1505     }
1506   }
1507
1508 return 2;
1509 }
1510
1511
1512
1513 ##################################################
1514 # Custom munges
1515 # keyed by name of munge; value is a ref to a hash
1516 # which is keyed by file, value a string to look for.
1517 # Usable files are:
1518 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1519 # Search strings starting with 's' do substitutions;
1520 # with '/' do line-skips.
1521 # Triggered by a scriptfile line "munge <name>"
1522 ##################################################
1523 $munges =
1524   { 'dnssec' =>
1525     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1526
1527     'gnutls_unexpected' =>
1528     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1529
1530     'gnutls_handshake' =>
1531     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1532
1533     'optional_events' =>
1534     { 'stdout' => '/event_action =/' },
1535
1536     'optional_ocsp' =>
1537     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1538
1539     'optional_cert_hostnames' =>
1540     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1541
1542     'loopback' =>
1543     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1544
1545     'scanfile_size' =>
1546     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1547
1548     'delay_1500' =>
1549     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1550
1551     'tls_anycipher' =>
1552     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1553
1554     'debug_pid' =>
1555     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1556
1557     'optional_dsn_info' =>
1558     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1559     },
1560
1561     'optional_config' =>
1562     { 'stdout' => '/^(
1563                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity)
1564                   |gnutls_require_(kx|mac|protocols)
1565                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1566                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1567                   |socks_proxy
1568                   |tls_[^ ]*
1569                   )($|[ ]=)/x'
1570     },
1571
1572     'sys_bindir' =>
1573     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1574
1575     'sync_check_data' =>
1576     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1577       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1578
1579     'debuglog_stdout' =>
1580     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1581                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1582     },
1583
1584     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1585     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1586
1587     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1588     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1589
1590     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1591     { 'stdout' => 's%^> X/X$%> X%' },
1592   };
1593
1594
1595 sub max {
1596   my ($a, $b) = @_;
1597   return $a if ($a > $b);
1598   return $b;
1599 }
1600
1601 ##################################################
1602 #    Subroutine to check the output of a test    #
1603 ##################################################
1604
1605 # This function is called when the series of subtests is complete. It makes
1606 # use of check_file(), whose arguments are:
1607 #
1608 #  [0] the name of the main raw output file
1609 #  [1] the name of the server raw output file or undef
1610 #  [2] where to put the munged copy
1611 #  [3] the name of the saved file
1612 #  [4] TRUE if this is a log file whose deliveries must be sorted
1613 #  [5] an optional custom munge command
1614 #
1615 # Arguments: Optionally, name of a single custom munge to run.
1616 # Returns:   0 if the output compared equal
1617 #            1 if comparison failed; differences to be ignored
1618 #            2 if re-run needed (files may have been updated)
1619
1620 sub check_output{
1621 my($mungename) = $_[0];
1622 my($yield) = 0;
1623 my($munge) = $munges->{$mungename} if defined $mungename;
1624
1625 $yield = max($yield,  check_file("spool/log/paniclog",
1626                        "spool/log/serverpaniclog",
1627                        "test-paniclog-munged",
1628                        "paniclog/$testno", 0,
1629                        $munge->{paniclog}));
1630
1631 $yield = max($yield,  check_file("spool/log/rejectlog",
1632                        "spool/log/serverrejectlog",
1633                        "test-rejectlog-munged",
1634                        "rejectlog/$testno", 0,
1635                        $munge->{rejectlog}));
1636
1637 $yield = max($yield,  check_file("spool/log/mainlog",
1638                        "spool/log/servermainlog",
1639                        "test-mainlog-munged",
1640                        "log/$testno", $sortlog,
1641                        $munge->{mainlog}));
1642
1643 if (!$stdout_skip)
1644   {
1645   $yield = max($yield,  check_file("test-stdout",
1646                        "test-stdout-server",
1647                        "test-stdout-munged",
1648                        "stdout/$testno", 0,
1649                        $munge->{stdout}));
1650   }
1651
1652 if (!$stderr_skip)
1653   {
1654   $yield = max($yield,  check_file("test-stderr",
1655                        "test-stderr-server",
1656                        "test-stderr-munged",
1657                        "stderr/$testno", 0,
1658                        $munge->{stderr}));
1659   }
1660
1661 # Compare any delivered messages, unless this test is skipped.
1662
1663 if (! $message_skip)
1664   {
1665   my($msgno) = 0;
1666
1667   # Get a list of expected mailbox files for this script. We don't bother with
1668   # directories, just the files within them.
1669
1670   foreach $oldmail (@oldmails)
1671     {
1672     next unless $oldmail =~ /^mail\/$testno\./;
1673     print ">> EXPECT $oldmail\n" if $debug;
1674     $expected_mails{$oldmail} = 1;
1675     }
1676
1677   # If there are any files in test-mail, compare them. Note that "." and
1678   # ".." are automatically omitted by list_files_below().
1679
1680   @mails = list_files_below("test-mail");
1681
1682   foreach $mail (@mails)
1683     {
1684     next if $mail eq "test-mail/oncelog";
1685
1686     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1687     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1688
1689     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1690       {
1691       $msgno++;
1692       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1693       }
1694
1695     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1696     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1697       "mail/$testno.$saved_mail", 0,
1698       $munge->{mail}));
1699     delete $expected_mails{"mail/$testno.$saved_mail"};
1700     }
1701
1702   # Complain if not all expected mails have been found
1703
1704   if (scalar(keys %expected_mails) != 0)
1705     {
1706     foreach $key (keys %expected_mails)
1707       { print "** no test file found for $key\n"; }
1708
1709     for (;;)
1710       {
1711       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1712       tests_exit(1) if /^q?$/;
1713       if (/^c$/ && $force_continue) {
1714         log_failure($log_failed_filename, $testno, "missing email");
1715         log_test($log_summary_filename, $testno, 'F')
1716       }
1717       last if /^c$/;
1718
1719       # For update, we not only have to unlink the file, but we must also
1720       # remove it from the @oldmails vector, as otherwise it will still be
1721       # checked for when we re-run the test.
1722
1723       if (/^u$/)
1724         {
1725         foreach $key (keys %expected_mails)
1726           {
1727           my($i);
1728           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1729           for ($i = 0; $i < @oldmails; $i++)
1730             {
1731             if ($oldmails[$i] eq $key)
1732               {
1733               splice @oldmails, $i, 1;
1734               last;
1735               }
1736             }
1737           }
1738         last;
1739         }
1740       }
1741     }
1742   }
1743
1744 # Compare any remaining message logs, unless this test is skipped.
1745
1746 if (! $msglog_skip)
1747   {
1748   # Get a list of expected msglog files for this test
1749
1750   foreach $oldmsglog (@oldmsglogs)
1751     {
1752     next unless $oldmsglog =~ /^$testno\./;
1753     $expected_msglogs{$oldmsglog} = 1;
1754     }
1755
1756   # If there are any files in spool/msglog, compare them. However, we have
1757   # to munge the file names because they are message ids, which are
1758   # time dependent.
1759
1760   if (opendir(DIR, "spool/msglog"))
1761     {
1762     @msglogs = sort readdir(DIR);
1763     closedir(DIR);
1764
1765     foreach $msglog (@msglogs)
1766       {
1767       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1768       ($munged_msglog = $msglog) =~
1769         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1770           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1771       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
1772         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1773         $munge->{msglog}));
1774       delete $expected_msglogs{"$testno.$munged_msglog"};
1775       }
1776     }
1777
1778   # Complain if not all expected msglogs have been found
1779
1780   if (scalar(keys %expected_msglogs) != 0)
1781     {
1782     foreach $key (keys %expected_msglogs)
1783       {
1784       print "** no test msglog found for msglog/$key\n";
1785       ($msgid) = $key =~ /^\d+\.(.*)$/;
1786       foreach $cachekey (keys %cache)
1787         {
1788         if ($cache{$cachekey} eq $msgid)
1789           {
1790           print "** original msgid $cachekey\n";
1791           last;
1792           }
1793         }
1794       }
1795
1796     for (;;)
1797       {
1798       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1799       tests_exit(1) if /^q?$/;
1800       if (/^c$/ && $force_continue) {
1801         log_failure($log_failed_filename, $testno, "missing msglog");
1802         log_test($log_summary_filename, $testno, 'F')
1803       }
1804       last if /^c$/;
1805       if (/^u$/)
1806         {
1807         foreach $key (keys %expected_msglogs)
1808           {
1809           tests_exit(-1, "Failed to unlink msglog/$key")
1810             if !unlink("msglog/$key");
1811           }
1812         last;
1813         }
1814       }
1815     }
1816   }
1817
1818 return $yield;
1819 }
1820
1821
1822
1823 ##################################################
1824 #     Subroutine to run one "system" command     #
1825 ##################################################
1826
1827 # We put this in a subroutine so that the command can be reflected when
1828 # debugging.
1829 #
1830 # Argument: the command to be run
1831 # Returns:  nothing
1832
1833 sub run_system {
1834 my($cmd) = $_[0];
1835 if ($debug)
1836   {
1837   my($prcmd) = $cmd;
1838   $prcmd =~ s/; /;\n>> /;
1839   print ">> $prcmd\n";
1840   }
1841 system("$cmd");
1842 }
1843
1844
1845
1846 ##################################################
1847 #      Subroutine to run one script command      #
1848 ##################################################
1849
1850 # The <SCRIPT> file is open for us to read an optional return code line,
1851 # followed by the command line and any following data lines for stdin. The
1852 # command line can be continued by the use of \. Data lines are not continued
1853 # in this way. In all lines, the following substitutions are made:
1854 #
1855 # DIR    => the current directory
1856 # CALLER => the caller of this script
1857 #
1858 # Arguments: the current test number
1859 #            reference to the subtest number, holding previous value
1860 #            reference to the expected return code value
1861 #            reference to where to put the command name (for messages)
1862 #            auxiliary information returned from a previous run
1863 #
1864 # Returns:   0 the command was executed inline, no subprocess was run
1865 #            1 a non-exim command was run and waited for
1866 #            2 an exim command was run and waited for
1867 #            3 a command was run and not waited for (daemon, server, exim_lock)
1868 #            4 EOF was encountered after an initial return code line
1869 # Optionally also a second parameter, a hash-ref, with auxiliary information:
1870 #            exim_pid: pid of a run process
1871 #            munge: name of a post-script results munger
1872
1873 sub run_command{
1874 my($testno) = $_[0];
1875 my($subtestref) = $_[1];
1876 my($commandnameref) = $_[3];
1877 my($aux_info) = $_[4];
1878 my($yield) = 1;
1879
1880 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1881
1882 if (/^(\d+)\s*$/)                # Handle unusual return code
1883   {
1884   my($r) = $_[2];
1885   $$r = $1 << 8;
1886   $_ = <SCRIPT>;
1887   return 4 if !defined $_;       # Missing command
1888   $lineno++;
1889   }
1890
1891 chomp;
1892 $wait_time = 0;
1893
1894 # Handle concatenated command lines
1895
1896 s/\s+$//;
1897 while (substr($_, -1) eq"\\")
1898   {
1899   my($temp);
1900   $_ = substr($_, 0, -1);
1901   chomp($temp = <SCRIPT>);
1902   if (defined $temp)
1903     {
1904     $lineno++;
1905     $temp =~ s/\s+$//;
1906     $temp =~ s/^\s+//;
1907     $_ .= $temp;
1908     }
1909   }
1910
1911 # Do substitutions
1912
1913 do_substitute($testno);
1914 if ($debug) { printf ">> $_\n"; }
1915
1916 # Pass back the command name (for messages)
1917
1918 ($$commandnameref) = /^(\S+)/;
1919
1920 # Here follows code for handling the various different commands that are
1921 # supported by this script. The first group of commands are all freestanding
1922 # in that they share no common code and are not followed by any data lines.
1923
1924
1925 ###################
1926 ###################
1927
1928 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1929 # utility and to make DBM files for testing DBM lookups.
1930
1931 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1932   {
1933   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1934          "echo exim_dbmbuild exit code = \$?)" .
1935          ">>test-stdout");
1936   return 1;
1937   }
1938
1939
1940 # The "dump" command runs exim_dumpdb. On different systems, the output for
1941 # some types of dump may appear in a different order because it's just hauled
1942 # out of the DBM file. We can solve this by sorting. Ignore the leading
1943 # date/time, as it will be flattened later during munging.
1944
1945 if (/^dump\s+(\S+)/)
1946   {
1947   my($which) = $1;
1948   my(@temp);
1949   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1950   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1951   open(OUT, ">>test-stdout");
1952   print OUT "+++++++++++++++++++++++++++\n";
1953
1954   if ($which eq "retry")
1955     {
1956     $/ = "\n  ";
1957     @temp = <IN>;
1958     $/ = "\n";
1959
1960     @temp = sort {
1961                    my($aa) = split(' ', $a);
1962                    my($bb) = split(' ', $b);
1963                    return $aa cmp $bb;
1964                  } @temp;
1965
1966     foreach $item (@temp)
1967       {
1968       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1969       print OUT "  $item\n";
1970       }
1971     }
1972   else
1973     {
1974     @temp = <IN>;
1975     if ($which eq "callout")
1976       {
1977       @temp = sort {
1978                    my($aa) = substr $a, 21;
1979                    my($bb) = substr $b, 21;
1980                    return $aa cmp $bb;
1981                    } @temp;
1982       }
1983     print OUT @temp;
1984     }
1985
1986   close(IN);
1987   close(OUT);
1988   return 1;
1989   }
1990
1991
1992 # verbose comments start with ###
1993 if (/^###\s/) {
1994   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
1995     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
1996     say {$fh} $_;
1997   }
1998   return 0;
1999 }
2000
2001 # The "echo" command is a way of writing comments to the screen.
2002 if (/^echo\s+(.*)$/)
2003   {
2004   print "$1\n";
2005   return 0;
2006   }
2007
2008
2009 # The "exim_lock" command runs exim_lock in the same manner as "server",
2010 # but it doesn't use any input.
2011
2012 if (/^exim_lock\s+(.*)$/)
2013   {
2014   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2015   $server_pid = open SERVERCMD, "|$cmd" ||
2016     tests_exit(-1, "Failed to run $cmd\n");
2017
2018   # This gives the process time to get started; otherwise the next
2019   # process may not find it there when it expects it.
2020
2021   select(undef, undef, undef, 0.1);
2022   return 3;
2023   }
2024
2025
2026 # The "exinext" command runs exinext
2027
2028 if (/^exinext\s+(.*)/)
2029   {
2030   run_system("(./eximdir/exinext " .
2031     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2032     "-C $parm_cwd/test-config $1;" .
2033     "echo exinext exit code = \$?)" .
2034     ">>test-stdout");
2035   return 1;
2036   }
2037
2038
2039 # The "exigrep" command runs exigrep on the current mainlog
2040
2041 if (/^exigrep\s+(.*)/)
2042   {
2043   run_system("(./eximdir/exigrep " .
2044     "$1 $parm_cwd/spool/log/mainlog;" .
2045     "echo exigrep exit code = \$?)" .
2046     ">>test-stdout");
2047   return 1;
2048   }
2049
2050
2051 # The "eximstats" command runs eximstats on the current mainlog
2052
2053 if (/^eximstats\s+(.*)/)
2054   {
2055   run_system("(./eximdir/eximstats " .
2056     "$1 $parm_cwd/spool/log/mainlog;" .
2057     "echo eximstats exit code = \$?)" .
2058     ">>test-stdout");
2059   return 1;
2060   }
2061
2062
2063 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2064 # spool directory, to save Exim from re-creating it each time.
2065
2066 if (/^gnutls/)
2067   {
2068   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2069   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2070          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2071          "sudo chmod 0400 $gen_fn";
2072   return 1;
2073   }
2074
2075
2076 # The "killdaemon" command should ultimately follow the starting of any Exim
2077 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2078 # it outputting "Terminated" to the terminal when not in the background.
2079
2080 if (/^killdaemon/)
2081   {
2082   my $return_extra = {};
2083   if (exists $aux_info->{exim_pid})
2084     {
2085     $pid = $aux_info->{exim_pid};
2086     $return_extra->{exim_pid} = undef;
2087     print ">> killdaemon: recovered pid $pid\n" if $debug;
2088     if ($pid)
2089       {
2090       run_system("sudo /bin/kill -INT $pid");
2091       wait;
2092       }
2093     } else {
2094     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2095     if ($pid)
2096       {
2097       run_system("sudo /bin/kill -INT $pid");
2098       close DAEMONCMD;                                   # Waits for process
2099       }
2100     }
2101     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2102   return (1, $return_extra);
2103   }
2104
2105
2106 # The "millisleep" command is like "sleep" except that its argument is in
2107 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2108 # is used for.
2109
2110 elsif (/^millisleep\s+(.*)$/)
2111   {
2112   select(undef, undef, undef, $1/1000);
2113   return 0;
2114   }
2115
2116
2117 # The "munge" command selects one of a hardwired set of test-result modifications
2118 # to be made before result compares are run agains the golden set.  This lets
2119 # us account for test-system dependent things which only affect a few, but known,
2120 # test-cases.
2121 # Currently only the last munge takes effect.
2122
2123 if (/^munge\s+(.*)$/)
2124   {
2125   return (0, { munge => $1 });
2126   }
2127
2128
2129 # The "sleep" command does just that. For sleeps longer than 1 second we
2130 # tell the user what's going on.
2131
2132 if (/^sleep\s+(.*)$/)
2133   {
2134   if ($1 == 1)
2135     {
2136     sleep(1);
2137     }
2138   else
2139     {
2140     printf("  Test %d sleep $1 ", $$subtestref);
2141     for (1..$1)
2142       {
2143       print ".";
2144       sleep(1);
2145       }
2146     printf("\r  Test %d                            $cr", $$subtestref);
2147     }
2148   return 0;
2149   }
2150
2151
2152 # Various Unix management commands are recognized
2153
2154 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2155     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2156   {
2157   run_system("$_ >>test-stdout 2>>test-stderr");
2158   return 1;
2159   }
2160
2161
2162
2163 ###################
2164 ###################
2165
2166 # The next group of commands are also freestanding, but they are all followed
2167 # by data lines.
2168
2169
2170 # The "server" command starts up a script-driven server that runs in parallel
2171 # with the following exim command. Therefore, we want to run a subprocess and
2172 # not yet wait for it to complete. The waiting happens after the next exim
2173 # command, triggered by $server_pid being non-zero. The server sends its output
2174 # to a different file. The variable $server_opts, if not empty, contains
2175 # options to disable IPv4 or IPv6 if necessary.
2176 # This works because "server" swallows its stdin before waiting for a connection.
2177
2178 if (/^server\s+(.*)$/)
2179   {
2180   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2181   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2182   print ">> $cmd\n" if ($debug);
2183   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2184   SERVERCMD->autoflush(1);
2185   print ">> Server pid is $server_pid\n" if $debug;
2186   while (<SCRIPT>)
2187     {
2188     $lineno++;
2189     last if /^\*{4}\s*$/;
2190     print SERVERCMD;
2191     }
2192   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2193                             # because close() waits for the process.
2194
2195   # Interlock the server startup; otherwise the next
2196   # process may not find it there when it expects it.
2197   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2198   return 3;
2199   }
2200
2201
2202 # The "write" command is a way of creating files of specific sizes for
2203 # buffering tests, or containing specific data lines from within the script
2204 # (rather than hold lots of little files). The "catwrite" command does the
2205 # same, but it also copies the lines to test-stdout.
2206
2207 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2208   {
2209   my($cat) = defined $1;
2210   @sizes = ();
2211   @sizes = split /\s+/, $3 if defined $3;
2212   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2213
2214   if ($cat)
2215     {
2216     open CAT, ">>test-stdout" ||
2217       tests_exit(-1, "Failed to open test-stdout: $!");
2218     print CAT "==========\n";
2219     }
2220
2221   if (scalar @sizes > 0)
2222     {
2223     # Pre-data
2224
2225     while (<SCRIPT>)
2226       {
2227       $lineno++;
2228       last if /^\+{4}\s*$/;
2229       print FILE;
2230       print CAT if $cat;
2231       }
2232
2233     # Sized data
2234
2235     while (scalar @sizes > 0)
2236       {
2237       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2238       $leadin = '' if !defined $leadin;
2239       $leadin =~ s/_/ /g;
2240       $len -= length($leadin) + 1;
2241       while ($count-- > 0)
2242         {
2243         print FILE $leadin, "a" x $len, "\n";
2244         print CAT $leadin, "a" x $len, "\n" if $cat;
2245         }
2246       }
2247     }
2248
2249   # Post data, or only data if no sized data
2250
2251   while (<SCRIPT>)
2252     {
2253     $lineno++;
2254     last if /^\*{4}\s*$/;
2255     print FILE;
2256     print CAT if $cat;
2257     }
2258   close FILE;
2259
2260   if ($cat)
2261     {
2262     print CAT "==========\n";
2263     close CAT;
2264     }
2265
2266   return 0;
2267   }
2268
2269
2270 ###################
2271 ###################
2272
2273 # From this point on, script commands are implemented by setting up a shell
2274 # command in the variable $cmd. Shared code to run this command and handle its
2275 # input and output follows.
2276
2277 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2278 # program that plays the part of an email client. We also have the availability
2279 # of running Perl for doing one-off special things. Note that all these
2280 # commands expect stdin data to be supplied.
2281
2282 if (/^client/ || /^(sudo\s+)?perl\b/)
2283   {
2284   s"client"./bin/client";
2285   $cmd = "$_ >>test-stdout 2>>test-stderr";
2286   }
2287
2288 # For the "exim" command, replace the text "exim" with the path for the test
2289 # binary, plus -D options to pass over various parameters, and a -C option for
2290 # the testing configuration file. When running in the test harness, Exim does
2291 # not drop privilege when -C and -D options are present. To run the exim
2292 # command as root, we use sudo.
2293
2294 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2295   {
2296   $args = $6;
2297   my($envset) = (defined $1)? $1      : '';
2298   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2299   my($special)= (defined $5)? $5      : '';
2300   $wait_time  = (defined $2)? $2      : 0;
2301
2302   # Return 2 rather than 1 afterwards
2303
2304   $yield = 2;
2305
2306   # Update the test number
2307
2308   $$subtestref = $$subtestref + 1;
2309   printf("  Test %d       $cr", $$subtestref);
2310
2311   # Copy the configuration file, making the usual substitutions.
2312
2313   open (IN, "$parm_cwd/confs/$testno") ||
2314     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2315   open (OUT, ">test-config") ||
2316     tests_exit(-1, "Couldn't open test-config: $!\n");
2317   while (<IN>)
2318     {
2319     do_substitute($testno);
2320     print OUT;
2321     }
2322   close(IN);
2323   close(OUT);
2324
2325   # The string $msg1 in args substitutes the message id of the first
2326   # message on the queue, and so on. */
2327
2328   if ($args =~ /\$msg/)
2329     {
2330     my @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2331                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2332                    -C => "$parm_cwd/test-config");
2333     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2334     # We need the message ids sorted in ascending order.
2335     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2336     # PIDs are randomized, so sorting just the whole PID doesn't work.
2337     # We do the Schartz' transformation here (sort on
2338     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2339     my @msglist =
2340       map { $_->[1] }                                   # extract the values
2341       sort { $a->[0] cmp $b->[0] }                      # sort by key
2342       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2343       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2344
2345     # Done backwards just in case there are more than 9
2346
2347     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2348     if ( $args =~ /\$msg\d/ )
2349       {
2350       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2351         unless $force_continue;
2352       }
2353     }
2354
2355   # If -d is specified in $optargs, remove it from $args; i.e. let
2356   # the command line for runtest override. Then run Exim.
2357
2358   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2359
2360   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2361
2362   $cmd = "$envset$sudo$opt_valgrind" .
2363          "$parm_cwd/eximdir/exim$special$optargs " .
2364          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2365          "-C $parm_cwd/test-config $args " .
2366          ">>test-stdout 2>>test-stderr";
2367   # If the command is starting an Exim daemon, we run it in the same
2368   # way as the "server" command above, that is, we don't want to wait
2369   # for the process to finish. That happens when "killdaemon" is obeyed later
2370   # in the script. We also send the stderr output to test-stderr-server. The
2371   # daemon has its log files put in a different place too (by configuring with
2372   # log_file_path). This requires the  directory to be set up in advance.
2373   #
2374   # There are also times when we want to run a non-daemon version of Exim
2375   # (e.g. a queue runner) with the server configuration. In this case,
2376   # we also define -DNOTDAEMON.
2377
2378   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2379     {
2380     if ($debug) { printf ">> daemon: $cmd\n"; }
2381     run_system("sudo mkdir spool/log 2>/dev/null");
2382     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2383
2384     # Before running the command, convert the -bd option into -bdf so that an
2385     # Exim daemon doesn't double fork. This means that when we wait close
2386     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2387     # file is written to the spool directory, in case the Exim binary was
2388     # built with PID_FILE_PATH pointing somewhere else.
2389
2390     if ($cmd =~ /\s-oP\s/)
2391       {
2392       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2393       $cmd =~ s!\s-bd\s! -bdf !;
2394       }
2395     else
2396       {
2397       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2398       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2399       }
2400     print ">> |${cmd}-server\n" if ($debug);
2401     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2402     DAEMONCMD->autoflush(1);
2403     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2404
2405     # Interlock with daemon startup
2406     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2407       { select(undef, undef, undef, 0.3); }
2408     return 3;                                     # Don't wait
2409     }
2410   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2411     {
2412
2413     # The port and the $dynamic_socket was already allocated while parsing the
2414     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2415
2416     my $listen_port = $1;
2417     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2418     run_system("sudo mkdir spool/log 2>/dev/null");
2419     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2420
2421     my $pid = fork();
2422     if (not defined $pid) { die "** fork failed: $!\n" }
2423     if (not $pid) {
2424       close(STDIN);
2425       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2426       close($dynamic_socket);
2427       print "[$$]>> ${cmd}-server\n" if ($debug);
2428       exec "exec ${cmd}-server";
2429       die "Can't exec ${cmd}-server: $!\n";
2430     }
2431     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2432     select(undef, undef, undef, 0.3);             # Let the daemon get going
2433     return (3, { exim_pid => $pid });             # Don't wait
2434     }
2435   }
2436
2437 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2438 # One script line is read and fork-exec'd.  The PID is stored for a later
2439 # killdaemon.
2440
2441 elsif (/^background$/)
2442   {
2443   my $line;
2444 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2445
2446   $_ = <SCRIPT>; $lineno++;
2447   chomp;
2448   do_substitute($testno);
2449   $line = $_;
2450   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2451
2452   my $pid = fork();
2453   if (not defined $pid) { die "** fork failed: $!\n" }
2454   if (not $pid) {
2455     print "[$$]>> ${line}\n" if ($debug);
2456     close(STDIN);
2457     open(STDIN, "<", "test-stdout");
2458     close(STDOUT);
2459     open(STDOUT, ">>", "test-stdout");
2460     close(STDERR);
2461     open(STDERR, ">>", "test-stderr-server");
2462     exec "exec ${line}";
2463     exit(1);
2464   }
2465
2466 #  open(my $fh, ">", $pidfile) ||
2467 #      tests_exit(-1, "Failed to open $pidfile: $!");
2468 #  printf($fh, "%d\n", $pid);
2469 #  close($fh);
2470
2471   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2472   select(undef, undef, undef, 0.3);             # Let the daemon get going
2473   return (3, { exim_pid => $pid });             # Don't wait
2474   }
2475
2476
2477
2478 # Unknown command
2479
2480 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2481
2482
2483 # Run the command, with stdin connected to a pipe, and write the stdin data
2484 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2485 # the terminating newline (and the \NONL\). If the command contains
2486 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2487 # for the stderr file. See comment above about the use of -DSERVER.
2488
2489 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2490 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2491 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2492
2493 CMD->autoflush(1);
2494 while (<SCRIPT>)
2495   {
2496   $lineno++;
2497   last if /^\*{4}\s*$/;
2498   do_substitute($testno);
2499   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2500   }
2501
2502 # For timeout tests, wait before closing the pipe; we expect a
2503 # SIGPIPE error in this case.
2504
2505 if ($wait_time > 0)
2506   {
2507   printf("  Test %d sleep $wait_time ", $$subtestref);
2508   while ($wait_time-- > 0)
2509     {
2510     print ".";
2511     sleep(1);
2512     }
2513   printf("\r  Test %d                                       $cr", $$subtestref);
2514   }
2515
2516 $sigpipehappened = 0;
2517 close CMD;                # Waits for command to finish
2518 return $yield;            # Ran command and waited
2519 }
2520
2521
2522
2523
2524 ###############################################################################
2525 ###############################################################################
2526
2527 # Here begins the Main Program ...
2528
2529 ###############################################################################
2530 ###############################################################################
2531
2532
2533 autoflush STDOUT 1;
2534 print "Exim tester $testversion\n";
2535
2536 # extend the PATH with .../sbin
2537 # we map all (.../bin) to (.../sbin:.../bin)
2538 $ENV{PATH} = do {
2539   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2540   join ':' => map { m{(.*)/bin$}
2541                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2542                 : ($_) }
2543       split /:/, $ENV{PATH};
2544 };
2545
2546 ##################################################
2547 #      Some tests check created file modes       #
2548 ##################################################
2549
2550 umask 022;
2551
2552
2553 ##################################################
2554 #       Check for the "less" command             #
2555 ##################################################
2556
2557 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2558
2559
2560
2561 ##################################################
2562 #      See if an Exim binary has been given      #
2563 ##################################################
2564
2565 # If the first character of the first argument is '/', the argument is taken
2566 # as the path to the binary. If the first argument does not start with a
2567 # '/' but exists in the file system, it's assumed to be the Exim binary.
2568
2569
2570 ##################################################
2571 # Sort out options and which tests are to be run #
2572 ##################################################
2573
2574 # There are a few possible options for the test script itself; after these, any
2575 # options are passed on to Exim calls within the tests. Typically, this is used
2576 # to turn on Exim debugging while setting up a test.
2577
2578 Getopt::Long::Configure qw(no_getopt_compat);
2579 GetOptions(
2580     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2581     'diff'     => sub { $cf             = 'diff -u' },
2582     'continue' => sub { $force_continue = 1; $more = 'cat' },
2583     'update'   => \$force_update,
2584     'ipv4!'    => \$have_ipv4,
2585     'ipv6!'    => \$have_ipv6,
2586     'keep'     => \$save_output,
2587     'slow'     => \$slow,
2588     'valgrind' => \$valgrind,
2589     'range=s{2}'       => \my @range_wanted,
2590     'test=i@'          => \my @tests_wanted,
2591     'flavor|flavour=s' => $flavour,
2592     'help'             => sub { pod2usage(-exit => 0) },
2593     'man'              => sub {
2594         pod2usage(
2595             -exit      => 0,
2596             -verbose   => 2,
2597             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2598         );
2599     },
2600 ) or pod2usage;
2601
2602 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2603 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2604
2605
2606 my @wanted = sort numerically uniq
2607   @tests_wanted ? @tests_wanted : (),
2608   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
2609   @ARGV ? @ARGV == 1 ? $ARGV[0] :
2610           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
2611           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
2612         : ();
2613 @wanted = 1..TEST_TOP if not @wanted;
2614
2615 ##################################################
2616 #        Check for sudo access to root           #
2617 ##################################################
2618
2619 print "You need to have sudo access to root to run these tests. Checking ...\n";
2620 if (system('sudo true >/dev/null') != 0)
2621   {
2622   die "** Test for sudo failed: testing abandoned.\n";
2623   }
2624 else
2625   {
2626   print "Test for sudo OK\n";
2627   }
2628
2629
2630
2631
2632 ##################################################
2633 #      Make the command's directory current      #
2634 ##################################################
2635
2636 # After doing so, we find its absolute path name.
2637
2638 $cwd = $0;
2639 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2640 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2641 $parm_cwd = Cwd::getcwd();
2642
2643
2644 ##################################################
2645 #     Search for an Exim binary to test          #
2646 ##################################################
2647
2648 # If an Exim binary hasn't been provided, try to find one. We can handle the
2649 # case where exim-testsuite is installed alongside Exim source directories. For
2650 # PH's private convenience, if there's a directory just called "exim4", that
2651 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2652 # releases.
2653
2654 # If $parm_exim is still empty, ask the caller
2655
2656 if (not $parm_exim)
2657   {
2658   print "** Did not find an Exim binary to test\n";
2659   for ($i = 0; $i < 5; $i++)
2660     {
2661     my($trybin);
2662     print "** Enter pathname for Exim binary: ";
2663     chomp($trybin = <STDIN>);
2664     if (-e $trybin)
2665       {
2666       $parm_exim = $trybin;
2667       last;
2668       }
2669     else
2670       {
2671       print "** $trybin does not exist\n";
2672       }
2673     }
2674   die "** Too many tries\n" if $parm_exim eq '';
2675   }
2676
2677
2678
2679 ##################################################
2680 #          Find what is in the binary            #
2681 ##################################################
2682
2683 # deal with TRUSTED_CONFIG_LIST restrictions
2684 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2685 open (IN, "$parm_cwd/confs/0000") ||
2686   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2687 open (OUT, ">test-config") ||
2688   tests_exit(-1, "Couldn't open test-config: $!\n");
2689 while (<IN>) { print OUT; }
2690 close(IN);
2691 close(OUT);
2692
2693 print("Probing with config file: $parm_cwd/test-config\n");
2694
2695 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2696 chomp(my @eximinfo = `$eximinfo 2>&1`);
2697 die "$0: Can't run $eximinfo\n" if $? == -1;
2698
2699 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2700 foreach (@eximinfo)
2701   {
2702   if (my ($version) = /^Exim version (\S+)/) {
2703     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2704     if (defined $git and $? == 0) {
2705       chomp $git;
2706       $version =~ s/^\d+\K\./_/;
2707       $git =~ s/^exim-//i;
2708       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2709       print <<___
2710
2711 *** Version mismatch
2712 *** Exim binary: $version
2713 *** Git        : $git
2714
2715 ___
2716         if not $version eq $git;
2717     }
2718   }
2719   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2720   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2721   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2722   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2723         if /^Configure owner:\s*(\d+):(\d+)/;
2724   print if /wrong owner/;
2725   }
2726
2727 if (not defined $parm_eximuser) {
2728   die <<XXX, map { "|$_\n" } @eximinfo;
2729 Unable to extract exim_user from binary.
2730 Check if Exim refused to run; if so, consider:
2731   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2732 If debug permission denied, are you in the exim group?
2733 Failing to get information from binary.
2734 Output from $eximinfo:
2735 XXX
2736
2737 }
2738
2739 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2740 else { $parm_exim_uid = getpwnam($parm_eximuser); }
2741
2742 if (defined $parm_eximgroup)
2743   {
2744   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2745     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2746   }
2747
2748 # check the permissions on the TRUSTED_CONFIG_LIST
2749 if (defined $parm_trusted_config_list)
2750   {
2751   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2752     if not -f $parm_trusted_config_list;
2753
2754   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2755     if 02 & (stat _)[2];
2756
2757   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2758   (stat _)[1],
2759     scalar(getgrgid 0), scalar(getgrgid $>)
2760     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2761
2762   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2763   scalar(getpwuid 0), scalar(getpwuid $>)
2764      if (not (-o _ or (stat _)[4] == 0));
2765
2766   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2767   my $test_config = getcwd() . '/test-config';
2768   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2769   if not grep { /^\Q$test_config\E$/ } <TCL>;
2770   }
2771 else
2772   {
2773   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2774   }
2775
2776 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2777         if $parm_configure_owner != $>;
2778
2779 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2780         if 0020 & (stat "$parm_cwd/test-config")[2]
2781         and $parm_configure_group != $);
2782
2783 die "aux-fixed file is world-writeable; best to strip them all, recursively\n"
2784         if 0020 & (stat "aux-fixed/0037.f-1")[2];
2785
2786
2787 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2788   die "** Cannot run $parm_exim: $!\n";
2789
2790 print "-" x 78, "\n";
2791
2792 while (<EXIMINFO>)
2793   {
2794   my(@temp);
2795
2796   if (/^(Exim|Library) version/) { print; }
2797   if (/Runtime: /) {print; }
2798
2799   elsif (/^Size of off_t: (\d+)/)
2800     {
2801     print;
2802     $have_largefiles = 1 if $1 > 4;
2803     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2804         if ($1 > 32);
2805     }
2806
2807   elsif (/^Support for: (.*)/)
2808     {
2809     print;
2810     @temp = split /(\s+)/, $1;
2811     push(@temp, ' ');
2812     %parm_support = @temp;
2813     }
2814
2815   elsif (/^Lookups \(built-in\): (.*)/)
2816     {
2817     print;
2818     @temp = split /(\s+)/, $1;
2819     push(@temp, ' ');
2820     %parm_lookups = @temp;
2821     }
2822
2823   elsif (/^Authenticators: (.*)/)
2824     {
2825     print;
2826     @temp = split /(\s+)/, $1;
2827     push(@temp, ' ');
2828     %parm_authenticators = @temp;
2829     }
2830
2831   elsif (/^Routers: (.*)/)
2832     {
2833     print;
2834     @temp = split /(\s+)/, $1;
2835     push(@temp, ' ');
2836     %parm_routers = @temp;
2837     }
2838
2839   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2840   # that the basic transport name is set, and then the name with each of the
2841   # options.
2842
2843   elsif (/^Transports: (.*)/)
2844     {
2845     print;
2846     @temp = split /(\s+)/, $1;
2847     my($i,$k);
2848     push(@temp, ' ');
2849     %parm_transports = @temp;
2850     foreach $k (keys %parm_transports)
2851       {
2852       if ($k =~ "/")
2853         {
2854         @temp = split /\//, $k;
2855         $parm_transports{$temp[0]} = " ";
2856         for ($i = 1; $i < @temp; $i++)
2857           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2858         }
2859       }
2860     }
2861
2862   elsif (/^Malware: (.*)/)
2863     {
2864     print;
2865     @temp = split /(\s+)/, $1;
2866     push(@temp, ' ');
2867     %parm_malware = @temp;
2868     }
2869
2870   }
2871 close(EXIMINFO);
2872 print "-" x 78, "\n";
2873
2874 unlink("$parm_cwd/test-config");
2875
2876 ##################################################
2877 #    Check for SpamAssassin and ClamAV           #
2878 ##################################################
2879
2880 # These are crude tests. If they aren't good enough, we'll have to improve
2881 # them, for example by actually passing a message through spamc or clamscan.
2882
2883 if (defined $parm_support{Content_Scanning})
2884   {
2885   my $sock = new FileHandle;
2886
2887   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2888     {
2889     print "The spamc command works:\n";
2890
2891     # This test for an active SpamAssassin is courtesy of John Jetmore.
2892     # The tests are hard coded to localhost:783, so no point in making
2893     # this test flexible like the clamav test until the test scripts are
2894     # changed.  spamd doesn't have the nice PING/PONG protocol that
2895     # clamd does, but it does respond to errors in an informative manner,
2896     # so use that.
2897
2898     my($sint,$sport) = ('127.0.0.1',783);
2899     eval
2900       {
2901       my $sin = sockaddr_in($sport, inet_aton($sint))
2902           or die "** Failed packing $sint:$sport\n";
2903       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2904           or die "** Unable to open socket $sint:$sport\n";
2905
2906       local $SIG{ALRM} =
2907           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2908       alarm(5);
2909       connect($sock, $sin)
2910           or die "** Unable to connect to socket $sint:$sport\n";
2911       alarm(0);
2912
2913       select((select($sock), $| = 1)[0]);
2914       print $sock "bad command\r\n";
2915
2916       $SIG{ALRM} =
2917           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2918       alarm(10);
2919       my $res = <$sock>;
2920       alarm(0);
2921
2922       $res =~ m|^SPAMD/|
2923           or die "** Did not get SPAMD from socket $sint:$sport. "
2924                 ."It said: $res\n";
2925       };
2926     alarm(0);
2927     if($@)
2928       {
2929       print "  $@";
2930       print "  Assume SpamAssassin (spamd) is not running\n";
2931       }
2932     else
2933       {
2934       $parm_running{SpamAssassin} = ' ';
2935       print "  SpamAssassin (spamd) seems to be running\n";
2936       }
2937     }
2938   else
2939     {
2940     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2941     }
2942
2943   # For ClamAV, we need to find the clamd socket for use in the Exim
2944   # configuration. Search for the clamd configuration file.
2945
2946   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2947     {
2948     my($f, $clamconf, $test_prefix);
2949
2950     print "The clamscan command works";
2951
2952     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2953     $test_prefix = '' if !defined $test_prefix;
2954
2955     foreach $f ("$test_prefix/etc/clamd.conf",
2956                 "$test_prefix/usr/local/etc/clamd.conf",
2957                 "$test_prefix/etc/clamav/clamd.conf", '')
2958       {
2959       if (-e $f)
2960         {
2961         $clamconf = $f;
2962         last;
2963         }
2964       }
2965
2966     # Read the ClamAV configuration file and find the socket interface.
2967
2968     if ($clamconf ne '')
2969       {
2970       my $socket_domain;
2971       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2972       while (<IN>)
2973         {
2974         if (/^LocalSocket\s+(.*)/)
2975           {
2976           $parm_clamsocket = $1;
2977           $socket_domain = AF_UNIX;
2978           last;
2979           }
2980         if (/^TCPSocket\s+(\d+)/)
2981           {
2982           if (defined $parm_clamsocket)
2983             {
2984             $parm_clamsocket .= " $1";
2985             $socket_domain = AF_INET;
2986             last;
2987             }
2988           else
2989             {
2990             $parm_clamsocket = " $1";
2991             }
2992           }
2993         elsif (/^TCPAddr\s+(\S+)/)
2994           {
2995           if (defined $parm_clamsocket)
2996             {
2997             $parm_clamsocket = $1 . $parm_clamsocket;
2998             $socket_domain = AF_INET;
2999             last;
3000             }
3001           else
3002             {
3003             $parm_clamsocket = $1;
3004             }
3005           }
3006         }
3007       close(IN);
3008
3009       if (defined $socket_domain)
3010         {
3011         print ":\n  The clamd socket is $parm_clamsocket\n";
3012         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3013         eval
3014           {
3015           my $socket;
3016           if ($socket_domain == AF_UNIX)
3017             {
3018             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3019             }
3020           elsif ($socket_domain == AF_INET)
3021             {
3022             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3023             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3024             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3025             }
3026           else
3027             {
3028             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3029             }
3030           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3031           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3032           alarm(5);
3033           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3034           alarm(0);
3035
3036           my $ofh = select $sock; $| = 1; select $ofh;
3037           print $sock "PING\n";
3038
3039           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3040           alarm(10);
3041           my $res = <$sock>;
3042           alarm(0);
3043
3044           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3045           };
3046         alarm(0);
3047
3048         if($@)
3049           {
3050           print "  $@";
3051           print "  Assume ClamAV is not running\n";
3052           }
3053         else
3054           {
3055           $parm_running{ClamAV} = ' ';
3056           print "  ClamAV seems to be running\n";
3057           }
3058         }
3059       else
3060         {
3061         print ", but the socket for clamd could not be determined\n";
3062         print "Assume ClamAV is not running\n";
3063         }
3064       }
3065
3066     else
3067       {
3068       print ", but I can't find a configuration for clamd\n";
3069       print "Assume ClamAV is not running\n";
3070       }
3071     }
3072   }
3073
3074
3075 ##################################################
3076 #       Check for redis                          #
3077 ##################################################
3078 if (defined $parm_lookups{redis})
3079   {
3080   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3081     {
3082     print "The redis-server command works\n";
3083     $parm_running{redis} = ' ';
3084     }
3085   else
3086     {
3087     print "The redis-server command failed: assume Redis not installed\n";
3088     }
3089   }
3090
3091 ##################################################
3092 #         Test for the basic requirements        #
3093 ##################################################
3094
3095 # This test suite assumes that Exim has been built with at least the "usual"
3096 # set of routers, transports, and lookups. Ensure that this is so.
3097
3098 $missing = '';
3099
3100 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3101
3102 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3103 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3104 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3105 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3106
3107 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3108 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3109 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3110 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3111
3112 if ($missing ne '')
3113   {
3114   print "\n";
3115   print "** Many features can be included or excluded from Exim binaries.\n";
3116   print "** This test suite requires that Exim is built to contain a certain\n";
3117   print "** set of basic facilities. It seems that some of these are missing\n";
3118   print "** from the binary that is under test, so the test cannot proceed.\n";
3119   print "** The missing facilities are:\n";
3120   print "$missing";
3121   die "** Test script abandoned\n";
3122   }
3123
3124
3125 ##################################################
3126 #      Check for the auxiliary programs          #
3127 ##################################################
3128
3129 # These are always required:
3130
3131 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3132            "fakens", "iefbr14", "server")
3133   {
3134   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3135   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3136   if (!-e "bin/$prog")
3137     {
3138     print "\n";
3139     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3140     die "** Test script abandoned\n";
3141     }
3142   }
3143
3144 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3145 # compiled on systems where we don't know how to. However, if Exim does not
3146 # have that functionality compiled, we needn't bother.
3147
3148 $dlfunc_deleted = 0;
3149 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3150   {
3151   delete $parm_support{Expand_dlfunc};
3152   $dlfunc_deleted = 1;
3153   }
3154
3155
3156 ##################################################
3157 #          Find environmental details            #
3158 ##################################################
3159
3160 # Find the caller of this program.
3161
3162 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3163  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3164
3165 $pwpw = $pwpw;       # Kill Perl warnings
3166 $pwquota = $pwquota;
3167 $pwcomm = $pwcomm;
3168
3169 $parm_caller_group = getgrgid($parm_caller_gid);
3170
3171 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3172 print "Home directory is $parm_caller_home\n";
3173
3174 unless (defined $parm_eximgroup)
3175   {
3176   print "Unable to derive \$parm_eximgroup.\n";
3177   die "** ABANDONING.\n";
3178   }
3179
3180 if ($parm_caller_home eq $parm_cwd)
3181   {
3182   print "will confuse working dir with homedir; change homedir\n";
3183   die "** ABANDONING.\n";
3184   }
3185
3186 print "You need to be in the Exim group to run these tests. Checking ...";
3187
3188 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3189   {
3190   print " OK\n";
3191   }
3192 else
3193   {
3194   print "\nOh dear, you are not in the Exim group.\n";
3195   die "** Testing abandoned.\n";
3196   }
3197
3198 # Find this host's IP addresses - there may be many, of course, but we keep
3199 # one of each type (IPv4 and IPv6).
3200
3201 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3202   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3203 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3204   {
3205   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3206     {
3207     next if $1 =~ /^(?:127|10)\./;
3208     $parm_ipv4 = $1;
3209     }
3210
3211   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3212     {
3213     next if $1 eq '::1' or $1 =~ /^fe80/i;
3214     $parm_ipv6 = $1;
3215     }
3216   }
3217 close(IFCONFIG);
3218
3219 # Use private IP addresses if there are no public ones.
3220
3221 # If either type of IP address is missing, we need to set the value to
3222 # something other than empty, because that wrecks the substitutions. The value
3223 # is reflected, so use a meaningful string. Set appropriate options for the
3224 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3225 # available, so things will go wrong if there is no IPv4 address. The lack
3226 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3227 # and $have_ipv6 false.
3228
3229 if (not $parm_ipv4)
3230   {
3231   $have_ipv4 = 0;
3232   $parm_ipv4 = "<no IPv4 address found>";
3233   $server_opts .= " -noipv4";
3234   }
3235 elsif ($have_ipv4 == 0)
3236   {
3237   $parm_ipv4 = "<IPv4 testing disabled>";
3238   $server_opts .= " -noipv4";
3239   }
3240 else
3241   {
3242   $parm_running{IPv4} = " ";
3243   }
3244
3245 if (not $parm_ipv6)
3246   {
3247   $have_ipv6 = 0;
3248   $parm_ipv6 = "<no IPv6 address found>";
3249   $server_opts .= " -noipv6";
3250   delete($parm_support{IPv6});
3251   }
3252 elsif ($have_ipv6 == 0)
3253   {
3254   $parm_ipv6 = "<IPv6 testing disabled>";
3255   $server_opts .= " -noipv6";
3256   delete($parm_support{IPv6});
3257   }
3258 elsif (!defined $parm_support{IPv6})
3259   {
3260   $have_ipv6 = 0;
3261   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3262   $server_opts .= " -noipv6";
3263   }
3264 else
3265   {
3266   $parm_running{IPv6} = " ";
3267   }
3268
3269 print "IPv4 address is $parm_ipv4\n";
3270 print "IPv6 address is $parm_ipv6\n";
3271
3272 # For munging test output, we need the reversed IP addresses.
3273
3274 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3275   join(".", reverse(split /\./, $parm_ipv4));
3276
3277 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3278 if ($parm_ipv6 =~ /^[\da-f]/)
3279   {
3280   my(@comps) = split /:/, $parm_ipv6;
3281   my(@nibbles);
3282   foreach $comp (@comps)
3283     {
3284     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3285     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3286     }
3287   $parm_ipv6r = join(".", reverse(@nibbles));
3288   }
3289
3290 # Find the host name, fully qualified.
3291
3292 chomp($temp = `hostname`);
3293 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3294 if ($temp =~ /\./)
3295   {
3296   $parm_hostname = $temp;
3297   }
3298 else
3299   {
3300   $parm_hostname = (gethostbyname($temp))[0];
3301   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3302   }
3303 print "Hostname is $parm_hostname\n";
3304
3305 if ($parm_hostname !~ /\./)
3306   {
3307   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3308   }
3309
3310 if ($parm_hostname =~ /[[:upper:]]/)
3311   {
3312   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3313   }
3314
3315
3316
3317 ##################################################
3318 #     Create a testing version of Exim           #
3319 ##################################################
3320
3321 # We want to be able to run Exim with a variety of configurations. Normally,
3322 # the use of -C to change configuration causes Exim to give up its root
3323 # privilege (unless the caller is exim or root). For these tests, we do not
3324 # want this to happen. Also, we want Exim to know that it is running in its
3325 # test harness.
3326
3327 # We achieve this by copying the binary and patching it as we go. The new
3328 # binary knows it is a testing copy, and it allows -C and -D without loss of
3329 # privilege. Clearly, this file is dangerous to have lying around on systems
3330 # where there are general users with login accounts. To protect against this,
3331 # we put the new binary in a special directory that is accessible only to the
3332 # caller of this script, who is known to have sudo root privilege from the test
3333 # that was done above. Furthermore, we ensure that the binary is deleted at the
3334 # end of the test. First ensure the directory exists.
3335
3336 if (-d "eximdir")
3337   { unlink "eximdir/exim"; }     # Just in case
3338 else
3339   {
3340   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3341   system("sudo chgrp $parm_eximgroup eximdir");
3342   }
3343
3344 # The construction of the patched binary must be done as root, so we use
3345 # a separate script. As well as indicating that this is a test-harness binary,
3346 # the version number is patched to "x.yz" so that its length is always the
3347 # same. Otherwise, when it appears in Received: headers, it affects the length
3348 # of the message, which breaks certain comparisons.
3349
3350 die "** Unable to make patched exim: $!\n"
3351   if (system("sudo ./patchexim $parm_exim") != 0);
3352
3353 # From this point on, exits from the program must go via the subroutine
3354 # tests_exit(), so that suitable cleaning up can be done when required.
3355 # Arrange to catch interrupting signals, to assist with this.
3356
3357 $SIG{INT} = \&inthandler;
3358 $SIG{PIPE} = \&pipehandler;
3359
3360 # For some tests, we need another copy of the binary that is setuid exim rather
3361 # than root.
3362
3363 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3364        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3365        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3366        "sudo chmod 06755 eximdir/exim_exim");
3367
3368 ##################################################
3369 #     Make copies of utilities we might need     #
3370 ##################################################
3371
3372 # Certain of the tests make use of some of Exim's utilities. We do not need
3373 # to be root to copy these.
3374
3375 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3376
3377 $dbm_build_deleted = 0;
3378 if (defined $parm_lookups{dbm} &&
3379     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3380   {
3381   delete $parm_lookups{dbm};
3382   $dbm_build_deleted = 1;
3383   }
3384
3385 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3386   {
3387   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3388   }
3389
3390 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3391   {
3392   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3393   }
3394
3395 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3396   {
3397   tests_exit(-1, "Failed to make a copy of exinext: $!");
3398   }
3399
3400 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3401   {
3402   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3403   }
3404
3405 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3406   {
3407   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3408   }
3409
3410 # Collect some version information
3411 print '-' x 78, "\n";
3412 print "Perl version for runtest: $]\n";
3413 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3414   # fold (or unfold?) multiline output into a one-liner
3415   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3416 }
3417 print '-' x 78, "\n";
3418
3419
3420 ##################################################
3421 #    Check that the Exim user can access stuff   #
3422 ##################################################
3423
3424 # We delay this test till here so that we can check access to the actual test
3425 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3426
3427 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3428 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3429
3430 if ($parm_caller_uid eq $parm_exim_uid) {
3431   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3432                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3433 }
3434 if ($parm_caller_gid eq $parm_exim_gid) {
3435   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3436                 ."the same as caller's ($parm_caller) group as it confuses "
3437                 ."results analysis");
3438 }
3439
3440 print "The Exim user needs access to the test suite directory. Checking ...";
3441
3442 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3443   {
3444   my($why) = "unknown failure $rc";
3445   $rc >>= 8;
3446   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3447   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3448   $why = "Couldn't read auxiliary group list" if $rc == 3;
3449   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3450   $why = "Couldn't set gid" if $rc == 5;
3451   $why = "Couldn't set uid" if $rc == 6;
3452   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3453   print "\n** $why\n";
3454   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3455   }
3456 else
3457   {
3458   print " OK\n";
3459   }
3460
3461 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3462   if not unlink($log_summary_filename) and -e $log_summary_filename;
3463
3464 ##################################################
3465 #        Create a list of available tests        #
3466 ##################################################
3467
3468 # The scripts directory contains a number of subdirectories whose names are
3469 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3470 # from the first requires certain optional features to be included in the Exim
3471 # binary. These requirements are contained in a file called "REQUIRES" within
3472 # the directory. We scan all these tests, discarding those that cannot be run
3473 # because the current binary does not support the right facilities, and also
3474 # those that are outside the numerical range selected.
3475
3476 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3477   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3478
3479 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3480   if $dlfunc_deleted;
3481 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3482   if $dbm_build_deleted;
3483
3484
3485 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3486   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3487
3488 # Scan for relevant tests
3489 # HS12: Needs to be reworked.
3490 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3491   {
3492   my($testdir) = $test_dirs[$i];
3493   my($wantthis) = 1;
3494
3495   print ">>Checking $testdir\n" if $debug;
3496
3497   # Skip this directory if the first test is equal or greater than the first
3498   # test in the next directory.
3499
3500   next DIR if ($i < @test_dirs - 1) &&
3501           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3502
3503   # No need to carry on if the end test is less than the first test in this
3504   # subdirectory.
3505
3506   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3507
3508   # Check requirements, if any.
3509
3510   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3511     {
3512     while (<$requires>)
3513       {
3514       next if /^\s*$/;
3515       s/\s+$//;
3516       if (/^support (.*)$/)
3517         {
3518         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3519         }
3520       elsif (/^running (.*)$/)
3521         {
3522         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3523         }
3524       elsif (/^lookup (.*)$/)
3525         {
3526         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3527         }
3528       elsif (/^authenticators? (.*)$/)
3529         {
3530         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3531         }
3532       elsif (/^router (.*)$/)
3533         {
3534         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3535         }
3536       elsif (/^transport (.*)$/)
3537         {
3538         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3539         }
3540       elsif (/^malware (.*)$/)
3541         {
3542         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3543         }
3544       elsif (/^feature (.*)$/)
3545         {
3546         # move to a subroutine?
3547         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3548
3549         open (IN, "$parm_cwd/confs/0000") ||
3550           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3551         open (OUT, ">test-config") ||
3552           tests_exit(-1, "Couldn't open test-config: $!\n");
3553         while (<IN>)
3554           {
3555           do_substitute($testno);
3556           print OUT;
3557           }
3558         close(IN);
3559         close(OUT);
3560
3561         system($eximinfo . " >/dev/null 2>&1");
3562         if ($? != 0) {
3563           unlink("$parm_cwd/test-config");
3564           $wantthis = 0;
3565           $_ = "feature $1";
3566           last;
3567         }
3568         unlink("$parm_cwd/test-config");
3569         }
3570       else
3571         {
3572         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3573         }
3574       }
3575     }
3576   else
3577     {
3578     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3579       unless $!{ENOENT};
3580     }
3581
3582   # Loop if we do not want the tests in this subdirectory.
3583
3584   if (!$wantthis)
3585     {
3586     chomp;
3587     print "Omitting tests in $testdir (missing $_)\n";
3588     }
3589
3590   # We want the tests from this subdirectory, provided they are in the
3591   # range that was selected.
3592
3593   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3594   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3595     if not @testlist;
3596
3597   foreach $test (@testlist)
3598     {
3599     if (!$wantthis)
3600       {
3601       log_test($log_summary_filename, $test, '.');
3602       }
3603     else
3604       {
3605       push @test_list, "$testdir/$test";
3606       }
3607     }
3608   }
3609
3610 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
3611
3612
3613 ##################################################
3614 #         Munge variable auxiliary data          #
3615 ##################################################
3616
3617 # Some of the auxiliary data files have to refer to the current testing
3618 # directory and other parameter data. The generic versions of these files are
3619 # stored in the aux-var-src directory. At this point, we copy each of them
3620 # to the aux-var directory, making appropriate substitutions. There aren't very
3621 # many of them, so it's easiest just to do this every time. Ensure the mode
3622 # is standardized, as this path is used as a test for the ${stat: expansion.
3623
3624 # A similar job has to be done for the files in the dnszones-src directory, to
3625 # make the fake DNS zones for testing. Most of the zone files are copied to
3626 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3627 # networks that are defined by parameter.
3628
3629 foreach $basedir ("aux-var", "dnszones")
3630   {
3631   system("sudo rm -rf $parm_cwd/$basedir");
3632   mkdir("$parm_cwd/$basedir", 0777);
3633   chmod(0755, "$parm_cwd/$basedir");
3634
3635   opendir(AUX, "$parm_cwd/$basedir-src") ||
3636     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3637   my(@filelist) = readdir(AUX);
3638   close(AUX);
3639
3640   foreach $file (@filelist)
3641     {
3642     my($outfile) = $file;
3643     next if $file =~ /^\./;
3644
3645     if ($file eq "db.ip4.V4NET")
3646       {
3647       $outfile = "db.ip4.$parm_ipv4_test_net";
3648       }
3649     elsif ($file eq "db.ip6.V6NET")
3650       {
3651       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3652       $" = '.';
3653       $outfile = "db.ip6.@nibbles";
3654       $" = ' ';
3655       }
3656
3657     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3658     open(IN, "$parm_cwd/$basedir-src/$file") ||
3659       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3660     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3661       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3662     while (<IN>)
3663       {
3664       do_substitute(0);
3665       print OUT;
3666       }
3667     close(IN);
3668     close(OUT);
3669     }
3670   }
3671
3672 # Set a user's shell, distinguishable from /bin/sh
3673
3674 symlink('/bin/sh' => 'aux-var/sh');
3675 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3676
3677 ##################################################
3678 #     Create fake DNS zones for this host        #
3679 ##################################################
3680
3681 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3682 # sure that there are forward and reverse registrations for this host, using
3683 # its real IP addresses. Dynamically created zone files achieve this.
3684
3685 if ($have_ipv4 || $have_ipv6)
3686   {
3687   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3688   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3689     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3690   print OUT "; This is a dynamically constructed fake zone file.\n" .
3691     "; The following line causes fakens to return PASS_ON\n" .
3692     "; for queries that it cannot answer\n\n" .
3693     "PASS ON NOT FOUND\n\n";
3694   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3695   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3696   print OUT "\n; End\n";
3697   close(OUT);
3698   }
3699
3700 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3701   {
3702   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3703   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3704     tests_exit(-1,
3705       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3706   print OUT "; This is a dynamically constructed fake zone file.\n" .
3707     "; The zone is $components[0].in-addr.arpa.\n\n" .
3708     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3709     "; End\n";
3710   close(OUT);
3711   }
3712
3713 if ($have_ipv6 && $parm_ipv6 ne "::1")
3714   {
3715   my($exp_v6) = $parm_ipv6;
3716   $exp_v6 =~ s/[^:]//g;
3717   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3718     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3719   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3720     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3721   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3722     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3723   } else {
3724     $exp_v6 = $parm_ipv6;
3725   }
3726   my(@components) = split /:/, $exp_v6;
3727   my(@nibbles) = reverse (split /\s*/, shift @components);
3728   my($sep) =  '';
3729
3730   $" = ".";
3731   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3732     tests_exit(-1,
3733       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3734   print OUT "; This is a dynamically constructed fake zone file.\n" .
3735     "; The zone is @nibbles.ip6.arpa.\n\n";
3736
3737   @components = reverse @components;
3738   foreach $c (@components)
3739     {
3740     $c = "0$c" until $c =~ /^..../;
3741     @nibbles = reverse(split /\s*/, $c);
3742     print OUT "$sep@nibbles";
3743     $sep = ".";
3744     }
3745
3746   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3747   close(OUT);
3748   $" = " ";
3749   }
3750
3751
3752
3753 ##################################################
3754 #    Create lists of mailboxes and message logs  #
3755 ##################################################
3756
3757 # We use these lists to check that a test has created the expected files. It
3758 # should be faster than looking for the file each time. For mailboxes, we have
3759 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3760 # is just a flat list of files.
3761
3762 @oldmails = list_files_below("mail");
3763 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3764 @oldmsglogs = readdir(DIR);
3765 closedir(DIR);
3766
3767
3768
3769 ##################################################
3770 #         Run the required tests                 #
3771 ##################################################
3772
3773 # Each test script contains a number of tests, separated by a line that
3774 # contains ****. We open input from the terminal so that we can read responses
3775 # to prompts.
3776
3777 if (not $force_continue) {
3778   # runtest needs to interact if we're not in continue
3779   # mode. It does so by communicate to /dev/tty
3780   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
3781   print "\nPress RETURN to run the tests: ";
3782   <T>;
3783 }
3784
3785
3786 foreach $test (@test_list)
3787   {
3788   state $lasttestdir = '';
3789
3790   local $lineno     = 0;
3791   local $commandno  = 0;
3792   local $subtestno  = 0;
3793   local $sortlog    = 0;
3794
3795   (local $testno = $test) =~ s|.*/||;
3796
3797   # Leaving traces in the process table and in the environment
3798   # gives us a chance to identify hanging processes (exim daemons)
3799   local $0 = "[runtest $testno]";
3800   local $ENV{EXIM_TEST_NUMBER} = $testno;
3801
3802   my $gnutls   = 0;
3803   my $docheck  = 1;
3804   my $thistestdir  = substr($test, 0, -5);
3805
3806   $dynamic_socket->close() if $dynamic_socket;
3807
3808   if ($lasttestdir ne $thistestdir)
3809     {
3810     $gnutls = 0;
3811     if (-s "scripts/$thistestdir/REQUIRES")
3812       {
3813       my $indent = '';
3814       print "\n>>> The following tests require: ";
3815       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
3816         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
3817       while (<$requires>)
3818         {
3819         $gnutls = 1 if /^support GnuTLS/;
3820         print $indent, $_;
3821         $indent = ">>>                              ";
3822         }
3823       }
3824       $lasttestdir = $thistestdir;
3825     }
3826
3827   # Remove any debris in the spool directory and the test-mail directory
3828   # and also the files for collecting stdout and stderr. Then put back
3829   # the test-mail directory for appendfile deliveries.
3830
3831   system "sudo /bin/rm -rf spool test-*";
3832   system "mkdir test-mail 2>/dev/null";
3833
3834   # A privileged Exim will normally make its own spool directory, but some of
3835   # the tests run in unprivileged modes that don't always work if the spool
3836   # directory isn't already there. What is more, we want anybody to be able
3837   # to read it in order to find the daemon's pid.
3838
3839   system "mkdir spool; " .
3840          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3841          "sudo chmod 0755 spool";
3842
3843   # Empty the cache that keeps track of things like message id mappings, and
3844   # set up the initial sequence strings.
3845
3846   undef %cache;
3847   $next_msgid = "aX";
3848   $next_pid = 1234;
3849   $next_port = 1111;
3850   $message_skip = 0;
3851   $msglog_skip = 0;
3852   $stderr_skip = 0;
3853   $stdout_skip = 0;
3854   $rmfiltertest = 0;
3855   $is_ipv6test = 0;
3856   $TEST_STATE->{munge} = '';
3857
3858   # Remove the associative arrays used to hold checked mail files and msglogs
3859
3860   undef %expected_mails;
3861   undef %expected_msglogs;
3862
3863   # Open the test's script
3864   open(SCRIPT, "scripts/$test") ||
3865     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3866   # Run through the script once to set variables which should be global
3867   while (<SCRIPT>)
3868     {
3869     if (/^no_message_check/) { $message_skip = 1; next; }
3870     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3871     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3872     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3873     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3874     if (/^sortlog/)          { $sortlog = 1; next; }
3875     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
3876     }
3877   # Reset to beginning of file for per test interpreting/processing
3878   seek(SCRIPT, 0, 0);
3879
3880   # The first line in the script must be a comment that is used to identify
3881   # the set of tests as a whole.
3882
3883   $_ = <SCRIPT>;
3884   $lineno++;
3885   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3886   printf("%s %s", (substr $test, 5), (substr $_, 2));
3887
3888   # Loop for each of the subtests within the script. The variable $server_pid
3889   # is used to remember the pid of a "server" process, for which we do not
3890   # wait until we have waited for a subsequent command.
3891
3892   local($server_pid) = 0;
3893   for ($commandno = 1; !eof SCRIPT; $commandno++)
3894     {
3895     # Skip further leading comments and blank lines, handle the flag setting
3896     # commands, and deal with tests for IP support.
3897
3898     while (<SCRIPT>)
3899       {
3900       $lineno++;
3901       # Could remove these variable settings because they are already
3902       # set above, but doesn't hurt to leave them here.
3903       if (/^no_message_check/) { $message_skip = 1; next; }
3904       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3905       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3906       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3907       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3908       if (/^sortlog/)          { $sortlog = 1; next; }
3909
3910       if (/^need_largefiles/)
3911         {
3912         next if $have_largefiles;
3913         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3914         $docheck = 0;      # don't check output
3915         undef $_;          # pretend EOF
3916         last;
3917         }
3918
3919       if (/^need_ipv4/)
3920         {
3921         next if $have_ipv4;
3922         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3923         $docheck = 0;      # don't check output
3924         undef $_;          # pretend EOF
3925         last;
3926         }
3927
3928       if (/^need_ipv6/)
3929         {
3930         if ($have_ipv6)
3931           {
3932           $is_ipv6test = 1;
3933           next;
3934           }
3935         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3936         $docheck = 0;      # don't check output
3937         undef $_;          # pretend EOF
3938         last;
3939         }
3940
3941       if (/^need_move_frozen_messages/)
3942         {
3943         next if defined $parm_support{move_frozen_messages};
3944         print ">>> move frozen message support is needed for test $testno, " .
3945           "but is not\n>>> available: skipping\n";
3946         $docheck = 0;      # don't check output
3947         undef $_;          # pretend EOF
3948         last;
3949         }
3950
3951       last unless /^(?:#(?!##\s)|\s*$)/;
3952       }
3953     last if !defined $_;  # Hit EOF
3954
3955     my($subtest_startline) = $lineno;
3956
3957     # Now run the command. The function returns 0 for an inline command,
3958     # 1 if a non-exim command was run and waited for, 2 if an exim
3959     # command was run and waited for, and 3 if a command
3960     # was run and not waited for (usually a daemon or server startup).
3961
3962     my($commandname) = '';
3963     my($expectrc) = 0;
3964     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3965     my($cmdrc) = $?;
3966
3967     if ($debug) {
3968       print ">> rc=$rc cmdrc=$cmdrc\n";
3969       if (defined $run_extra) {
3970         foreach my $k (keys %$run_extra) {
3971           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3972           print ">>   $k -> $v\n";
3973         }
3974       }
3975     }
3976     $run_extra = {} unless defined $run_extra;
3977     foreach my $k (keys %$run_extra) {
3978       if (exists $TEST_STATE->{$k}) {
3979         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3980         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3981       }
3982       if (defined $run_extra->{$k}) {
3983         $TEST_STATE->{$k} = $run_extra->{$k};
3984       } elsif (exists $TEST_STATE->{$k}) {
3985         delete $TEST_STATE->{$k};
3986       }
3987     }
3988
3989     # Hit EOF after an initial return code number
3990
3991     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3992
3993     # Carry on with the next command if we did not wait for this one. $rc == 0
3994     # if no subprocess was run; $rc == 3 if we started a process but did not
3995     # wait for it.
3996
3997     next if ($rc == 0 || $rc == 3);
3998
3999     # We ran and waited for a command. Check for the expected result unless
4000     # it died.
4001
4002     if ($cmdrc != $expectrc && !$sigpipehappened)
4003       {
4004       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4005       if (($cmdrc & 0xff) == 0)
4006         {
4007         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4008         }
4009       elsif (($cmdrc & 0xff00) == 0)
4010         { printf("** Killed by signal %d", $cmdrc & 255); }
4011       else
4012         { printf("** Status %x", $cmdrc); }
4013
4014       for (;;)
4015         {
4016         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4017         $_ = $force_continue ? "c" : <T>;
4018         tests_exit(1) if /^q?$/i;
4019         if (/^c$/ && $force_continue) {
4020           log_failure($log_failed_filename, $testno, "exit code unexpected");
4021           log_test($log_summary_filename, $testno, 'F')
4022         }
4023         if ($force_continue)
4024           {
4025           print "\nstdout tail:\n";
4026           print "==================>\n";
4027           system("tail -20 test-stdout");
4028           print "===================\n";
4029           print "stderr tail:\n";
4030           print "==================>\n";
4031           system("tail -20 test-stderr");
4032           print "===================\n";
4033           print "... continue forced\n";
4034           }
4035
4036         last if /^[rc]$/i;
4037         if (/^e$/i)
4038           {
4039           system("$more test-stderr");
4040           }
4041         elsif (/^o$/i)
4042           {
4043           system("$more test-stdout");
4044           }
4045         }
4046
4047       $retry = 1 if /^r$/i;
4048       $docheck = 0;
4049       }
4050
4051     # If the command was exim, and a listening server is running, we can now
4052     # close its input, which causes us to wait for it to finish, which is why
4053     # we didn't close it earlier.
4054
4055     if ($rc == 2 && $server_pid != 0)
4056       {
4057       close SERVERCMD;
4058       $server_pid = 0;
4059       if ($? != 0)
4060         {
4061         if (($? & 0xff) == 0)
4062           { printf("Server return code %d for test %d starting line %d", $?/256,
4063                 $testno, $subtest_startline); }
4064         elsif (($? & 0xff00) == 0)
4065           { printf("Server killed by signal %d", $? & 255); }
4066         else
4067           { printf("Server status %x", $?); }
4068
4069         for (;;)
4070           {
4071           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4072           $_ = $force_continue ? "c" : <T>;
4073           tests_exit(1) if /^q?$/i;
4074           if (/^c$/ && $force_continue) {
4075             log_failure($log_failed_filename, $testno, "exit code unexpected");
4076             log_test($log_summary_filename, $testno, 'F')
4077           }
4078           print "... continue forced\n" if $force_continue;
4079           last if /^[rc]$/i;
4080
4081           if (/^s$/i)
4082             {
4083             open(S, "test-stdout-server") ||
4084               tests_exit(-1, "Failed to open test-stdout-server: $!");
4085             print while <S>;
4086             close(S);
4087             }
4088           }
4089         $retry = 1 if /^r$/i;
4090         }
4091       }
4092     }
4093
4094   close SCRIPT;
4095
4096   # The script has finished. Check the all the output that was generated. The
4097   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4098   # rerun the test (the files # have been updated).
4099   # It does not return if the user responds Q to a prompt.
4100
4101   if ($retry)
4102     {
4103     $retry = '0';
4104     print (("#" x 79) . "\n");
4105     redo;
4106     }
4107
4108   if ($docheck)
4109     {
4110     sleep 1 if $slow;
4111     my $rc = check_output($TEST_STATE->{munge});
4112     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4113     if ($rc < 2)
4114       {
4115       print ("  Script completed\n");
4116       }
4117     else
4118       {
4119       print (("#" x 79) . "\n");
4120       redo;
4121       }
4122     }
4123   }
4124
4125
4126 ##################################################
4127 #         Exit from the test script              #
4128 ##################################################
4129
4130 tests_exit(-1, "No runnable tests selected") if not @test_list;
4131 tests_exit(0);
4132
4133 __END__
4134
4135 =head1 NAME
4136
4137  runtest - run the exim testsuite
4138
4139 =head1 SYNOPSIS
4140
4141  runtest [exim-path] [options] [test0 [test1]]
4142
4143 =head1 DESCRIPTION
4144
4145 B<runtest> runs the Exim testsuite.
4146
4147 =head1 OPTIONS
4148
4149 For legacy reasons the options are not case sensitive.
4150
4151 =over
4152
4153 =item B<--continue>
4154
4155 Do not stop for user interaction or on errors. (default: off)
4156
4157 =item B<--debug>
4158
4159 This option enables the output of debug information when running the
4160 various test commands. (default: off)
4161
4162 =item B<--diff>
4163
4164 Use C<diff -u> for comparing the expected output with the produced
4165 output. (default: use a built-in routine)
4166
4167 =item B<--flavor>|B<--flavour> I<flavour>
4168
4169 Override the expected results for results for a specific (OS) flavour.
4170 (default: unused)
4171
4172 =item B<--[no]ipv4>
4173
4174 Skip IPv4 related setup and tests (default: use ipv4)
4175
4176 =item B<--[no]ipv6>
4177
4178 Skip IPv6 related setup and tests (default: use ipv6)
4179
4180 =item B<--keep>
4181
4182 Keep the various output files produced during a test run. (default: don't keep)
4183
4184 =item B<--range> I<n0> I<n1>
4185
4186 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4187 test available".
4188
4189 =item B<--slow>
4190
4191 Insert some delays to compensate for a slow host system. (default: off)
4192
4193 =item B<--test> I<n>
4194
4195 Run the specified test. This option may used multiple times.
4196
4197 =item B<--update>
4198
4199 Automatically update the recorded (expected) data on mismatch. (default: off)
4200
4201 =item B<--valgrind>
4202
4203 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4204
4205 =back
4206
4207 =cut
4208
4209
4210 # End of runtest script