src/src/exigrep.src

   1 #! PERL_COMMAND -w
   2 # $Cambridge: exim/src/src/exigrep.src,v 1.5 2007/02/07 12:23:35 ph10 Exp $
   3
   4 use strict;
   5
   6 # Copyright (c) 2007 University of Cambridge.
   7 # See the file NOTICE for conditions of use and distribution.
   8
   9 # Except when they appear in comments, the following placeholders in this
  10 # source are replaced when it is turned into a runnable script:
  11 #
  12 # PERL_COMMAND
  13 # ZCAT_COMMAND
  14 # COMPRESS_SUFFIX
  15
  16 # PROCESSED_FLAG
  17
  18 # This is a perl script which extracts from an Exim log all entries
  19 # for all messages that have an entry that matches a given pattern.
  20 # If *any* entry for a particular message matches the pattern, *all*
  21 # entries for that message are displayed.
  22
  23 # We buffer up information on a per-message basis. It is done this way rather
  24 # than reading the input twice so that the input can be a pipe.
  25
  26 # There must be one argument, which is the pattern. Subsequent arguments
  27 # are the files to scan; if none, the standard input is read. If any file
  28 # appears to be compressed, it is passed through zcat. We can't just do this
  29 # for all files, because zcat chokes on non-compressed files.
  30
  31 # Performance optimized in 02/02/2007 by Jori Hamalainen
  32 # Typical run time acceleration: 4 times
  33
  34
  35 use Getopt::Std qw(getopts);
  36 use POSIX qw(mktime);
  37
  38
  39 # This subroutine converts a time/date string from an Exim log line into
  40 # the number of seconds since the epoch. It handles optional timezone
  41 # information.
  42
  43 sub seconds {
  44 my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
  45   $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?>\s([+-])(\d\d)(\d\d))?/o;
  46
  47 my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;
  48
  49 if (defined $tzs)
  50   {
  51   $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
  52   $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
  53   }
  54
  55 return $seconds;
  56 }
  57
  58
  59 # This subroutine processes a single line (in $_) from a log file. Program
  60 # defensively against short lines finding their way into the log.
  61
  62 my (%saved, %id_list, $pattern, $queue_time, $insensitive);
  63
  64 sub do_line {
  65
  66 # Convert syslog lines to mainlog format, as in eximstats.
  67
  68 if (!/^\d{4}-/o) { $_ =~ s/^.*? exim\b.*?: //o; }
  69
  70 return unless
  71   my($date,$id) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(\w{6}\-\w{6}\-\w{2})?/o;
  72
  73 # Handle the case when the log line belongs to a specific message. We save
  74 # lines for specific messages until the message is complete. Then either print
  75 # or discard.
  76
  77 if (defined $id)
  78   {
  79   $saved{$id} = '' unless defined($saved{$id});
  80
  81   # Save up the data for this message in case it becomes interesting later.
  82
  83   $saved{$id} .= $_;
  84
  85   # Are we interested in this id ? Short circuit if we already were interested.
  86
  87   $id_list{$id} = 1 if defined $id_list{$id} ||
  88     ($insensitive && /$pattern/io) || /$pattern/o;
  89
  90   # See if this is a completion for some message. If it is interesting,
  91   # print it, but in any event, throw away what was saved.
  92
  93   if (index($_, 'Completed') != -1 ||
  94       (index($_, 'rejected') != -1 &&
  95        /rejected (?:by local_scan|by non-SMTP ACL|after DATA)/o))
  96     {
  97     if ($queue_time != -1 &&
  98         $saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)/o)
  99       {
 100       my $old_sec = &seconds($1);
 101       my $sec = &seconds($date);
 102       delete $id_list{$id} if $id_list{$id} && $sec - $old_sec <= $queue_time;
 103       }
 104
 105     if ($id_list{$id})
 106       {
 107       delete $id_list{$id};
 108       print "$saved{$id}\n";
 109       }
 110
 111     delete $saved{$id};
 112     }
 113   }
 114
 115 # Handle the case where the log line does not belong to a specific message.
 116 # Print it if it is interesting.
 117
 118 elsif (($insensitive && $_ =~ /$pattern/io) || $_ =~ /$pattern/o)
 119   { print "$_\n"; }
 120 }
 121
 122
 123 # The main program. Extract the pattern and make sure any relevant characters
 124 # are quoted if the -l flag is given. The -t flag gives a time-on-queue value
 125 # which is an additional condition.
 126
 127 getopts('Ilt:',\my %args);
 128 $queue_time = $args{'t'}? $args{'t'} : -1;
 129 $insensitive = $args{'I'}? 0 : 1;
 130
 131 die "usage: exigrep [-I] [-l] [-t <seconds>] <pattern> [<log file>]...\n"
 132   if ($#ARGV < 0);
 133
 134 $pattern = shift @ARGV;
 135 $pattern = quotemeta $pattern if $args{l};
 136
 137
 138 # If file arguments are given, open each one and process according as it is
 139 # is compressed or not.
 140
 141 if (@ARGV)
 142   {
 143   foreach (@ARGV)
 144     {
 145     my $filename = $_;
 146     if ($filename =~ /\.(?:COMPRESS_SUFFIX)$/o)
 147       {
 148       open(LOG, "ZCAT_COMMAND $filename |") ||
 149         die "Unable to zcat $filename: $!\n";
 150       }
 151     else
 152       {
 153       open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
 154       }
 155     do_line() while (<LOG>);
 156     close(LOG);
 157     }
 158   }
 159
 160 # If no files are named, process STDIN only
 161
 162 else { do_line() while (<STDIN>); }
 163
 164 # At the end of processing all the input, print any uncompleted data
 165
 166 for (keys %id_list) { print "+++ $_ not completed +++\n$saved{$_}\n"; }
 167
 168 # End of exigrep