test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32
  33 use lib "$RealBin/lib";
  34 use Exim::Runtest;
  35 use Exim::Utils qw(uniq numerically);
  36
  37 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  39
  40 use constant TEST_TOP => 8999;
  41 use constant TEST_SPECIAL_TOP => 9999;
  42
  43
  44 # Start by initializing some global variables
  45
  46 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  47
  48 # This gets embedded in the D-H params filename, and the value comes
  49 # from asking GnuTLS for "normal", but there appears to be no way to
  50 # use certtool/... to ask what that value currently is.  *sigh*
  51 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  52 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  53 # normal = 2432   tls_dh_max_bits = 2236
  54 my $gnutls_dh_bits_normal = 2236;
  55
  56 my $cf = 'bin/cf -exact';
  57 my $cr = "\r";
  58 my $debug = 0;
  59 my $flavour = do {
  60   my $f = Exim::Runtest::flavour() // '';
  61   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  62 };
  63 my $force_continue = 0;
  64 my $force_update = 0;
  65 my $log_failed_filename = 'failed-summary.log';
  66 my $log_summary_filename = 'run-summary.log';
  67 my $more = 'less -XF';
  68 my $optargs = '';
  69 my $save_output = 0;
  70 my $server_opts = '';
  71 my $slow = 0;
  72 my $valgrind = 0;
  73
  74 my $have_ipv4 = 1;
  75 my $have_ipv6 = 1;
  76 my $have_largefiles = 0;
  77
  78 my @test_list = ();
  79
  80
  81 # Networks to use for DNS tests. We need to choose some networks that will
  82 # never be used so that there is no chance that the host on which we are
  83 # running is actually in one of the test networks. Private networks such as
  84 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  85 # Rather than use some unassigned numbers (that might become assigned later),
  86 # I have chosen some multicast networks, in the belief that such addresses
  87 # won't ever be assigned to hosts. This is the only place where these numbers
  88 # are defined, so it is trivially possible to change them should that ever
  89 # become necessary.
  90
  91 my $parm_ipv4_test_net = 224;
  92 my $parm_ipv6_test_net = 'ff00';
  93
  94 # Port numbers are currently hard-wired
  95
  96 my $parm_port_n = 1223;         # Nothing listening on this port
  97 my $parm_port_s = 1224;         # Used for the "server" command
  98 my $parm_port_d = 1225;         # Used for the Exim daemon
  99 my $parm_port_d2 = 1226;        # Additional for daemon
 100 my $parm_port_d3 = 1227;        # Additional for daemon
 101 my $parm_port_d4 = 1228;        # Additional for daemon
 102 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 103
 104 # Find a suiteable group name for test (currently only 0001
 105 # uses a group name. A numeric group id would do
 106 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 107
 108 # Manually set locale
 109 $ENV{LC_ALL} = 'C';
 110
 111 # In some environments USER does not exist, but we need it for some test(s)
 112 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 113
 114 my ($parm_configure_owner, $parm_configure_group);
 115 my ($parm_ipv4, $parm_ipv6);
 116 my $parm_hostname;
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121 # Define a number of subroutines
 122
 123 ###############################################################################
 124 ###############################################################################
 125
 126
 127 ##################################################
 128 #              Handle signals                    #
 129 ##################################################
 130
 131 sub pipehandler { $sigpipehappened = 1; }
 132
 133 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 134
 135
 136 ##################################################
 137 #       Do global macro substitutions            #
 138 ##################################################
 139
 140 # This function is applied to configurations, command lines and data lines in
 141 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 142 # directory. It takes one argument: the current test number, or zero when
 143 # setting up files before running any tests.
 144
 145 sub do_substitute{
 146 s?\bCALLER\b?$parm_caller?g;
 147 s?\bCALLERGROUP\b?$parm_caller_group?g;
 148 s?\bCALLER_UID\b?$parm_caller_uid?g;
 149 s?\bCALLER_GID\b?$parm_caller_gid?g;
 150 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 151 s?\bDIR/?$parm_cwd/?g;
 152 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 153 s?\bEXIMUSER\b?$parm_eximuser?g;
 154 s?\bHOSTIPV4\b?$parm_ipv4?g;
 155 s?\bHOSTIPV6\b?$parm_ipv6?g;
 156 s?\bHOSTNAME\b?$parm_hostname?g;
 157 s?\bPORT_D\b?$parm_port_d?g;
 158 s?\bPORT_D2\b?$parm_port_d2?g;
 159 s?\bPORT_D3\b?$parm_port_d3?g;
 160 s?\bPORT_D4\b?$parm_port_d4?g;
 161 s?\bPORT_N\b?$parm_port_n?g;
 162 s?\bPORT_S\b?$parm_port_s?g;
 163 s?\bTESTNUM\b?$_[0]?g;
 164 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 165 s?\bV6NET:?$parm_ipv6_test_net:?g;
 166 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 167 s?\bMAILGROUP\b?$parm_mailgroup?g;
 168 }
 169
 170
 171 ##################################################
 172 #     Any state to be preserved across tests     #
 173 ##################################################
 174
 175 my $TEST_STATE = {};
 176
 177
 178 ##################################################
 179 #        Subroutine to tidy up and exit          #
 180 ##################################################
 181
 182 # In all cases, we check for any Exim daemons that have been left running, and
 183 # kill them. Then remove all the spool data, test output, and the modified Exim
 184 # binary if we are ending normally.
 185
 186 # Arguments:
 187 #    $_[0] = 0 for a normal exit; full cleanup done
 188 #    $_[0] > 0 for an error exit; no files cleaned up
 189 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 190
 191 sub tests_exit{
 192 my($rc) = $_[0];
 193 my($spool);
 194
 195 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 196 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 197 # the background.
 198
 199 if (exists $TEST_STATE->{exim_pid})
 200   {
 201   $pid = $TEST_STATE->{exim_pid};
 202   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 203   system("sudo kill -INT $pid");
 204   }
 205
 206 if (opendir(DIR, "spool"))
 207   {
 208   my(@spools) = sort readdir(DIR);
 209   closedir(DIR);
 210   foreach $spool (@spools)
 211     {
 212     next if $spool !~ /^exim-daemon./;
 213     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 214     chomp($pid = <PID>);
 215     close(PID);
 216     print "Tidyup: killing daemon pid=$pid\n";
 217     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 218     }
 219   }
 220 else
 221   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 222
 223 # Close the terminal input and remove the test files if all went well, unless
 224 # the option to save them is set. Always remove the patched Exim binary. Then
 225 # exit normally, or die.
 226
 227 close(T);
 228 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 229   if ($rc == 0 && !$save_output);
 230
 231 system("sudo /bin/rm -rf ./eximdir/*")
 232   if (!$save_output);
 233
 234 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 235 exit $rc if ($rc >= 0);
 236 die "** runtest error: $_[1]\n";
 237 }
 238
 239
 240
 241 ##################################################
 242 #   Subroutines used by the munging subroutine   #
 243 ##################################################
 244
 245 # This function is used for things like message ids, where we want to generate
 246 # more than one value, but keep a consistent mapping throughout.
 247 #
 248 # Arguments:
 249 #   $oldid        the value from the file
 250 #   $base         a base string into which we insert a sequence
 251 #   $sequence     the address of the current sequence counter
 252
 253 sub new_value {
 254 my($oldid, $base, $sequence) = @_;
 255 my($newid) = $cache{$oldid};
 256 if (! defined $newid)
 257   {
 258   $newid = sprintf($base, $$sequence++);
 259   $cache{$oldid} = $newid;
 260   }
 261 return $newid;
 262 }
 263
 264
 265 # This is used while munging the output from exim_dumpdb.
 266 # May go wrong across DST changes.
 267
 268 sub date_seconds {
 269 my($day,$month,$year,$hour,$min,$sec) =
 270   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 271 my($mon);
 272 if   ($month =~ /Jan/) {$mon = 0;}
 273 elsif($month =~ /Feb/) {$mon = 1;}
 274 elsif($month =~ /Mar/) {$mon = 2;}
 275 elsif($month =~ /Apr/) {$mon = 3;}
 276 elsif($month =~ /May/) {$mon = 4;}
 277 elsif($month =~ /Jun/) {$mon = 5;}
 278 elsif($month =~ /Jul/) {$mon = 6;}
 279 elsif($month =~ /Aug/) {$mon = 7;}
 280 elsif($month =~ /Sep/) {$mon = 8;}
 281 elsif($month =~ /Oct/) {$mon = 9;}
 282 elsif($month =~ /Nov/) {$mon = 10;}
 283 elsif($month =~ /Dec/) {$mon = 11;}
 284 return timelocal($sec,$min,$hour,$day,$mon,$year);
 285 }
 286
 287
 288 # This is a subroutine to sort maildir files into time-order. The second field
 289 # is the microsecond field, and may vary in length, so must be compared
 290 # numerically.
 291
 292 sub maildirsort {
 293 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 294 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 295 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 296 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 297 }
 298
 299
 300
 301 ##################################################
 302 #   Subroutine list files below a directory      #
 303 ##################################################
 304
 305 # This is used to build up a list of expected mail files below a certain path
 306 # in the directory tree. It has to be recursive in order to deal with multiple
 307 # maildir mailboxes.
 308
 309 sub list_files_below {
 310 my($dir) = $_[0];
 311 my(@yield) = ();
 312 my(@sublist, $file);
 313
 314 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 315 @sublist = sort maildirsort readdir(DIR);
 316 closedir(DIR);
 317
 318 foreach $file (@sublist)
 319   {
 320   next if $file eq "." || $file eq ".." || $file eq "CVS";
 321   if (-d "$dir/$file")
 322     { @yield = (@yield, list_files_below("$dir/$file")); }
 323   else
 324     { push @yield, "$dir/$file"; }
 325   }
 326
 327 return @yield;
 328 }
 329
 330
 331
 332 ##################################################
 333 #         Munge a file before comparing          #
 334 ##################################################
 335
 336 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 337 # on into standard values, so that the compare works. Perl's substitution with
 338 # an expression provides a neat way to do some of these changes.
 339
 340 # We keep a global associative array for repeatedly turning the same values
 341 # into the same standard values throughout the data from a single test.
 342 # Message ids get this treatment (can't be made reliable for times), and
 343 # times in dumped retry databases are also handled in a special way, as are
 344 # incoming port numbers.
 345
 346 # On entry to the subroutine, the file to write to is already opened with the
 347 # name MUNGED. The input file name is the only argument to the subroutine.
 348 # Certain actions are taken only when the name contains "stderr", "stdout",
 349 # or "log". The yield of the function is 1 if a line matching "*** truncated
 350 # ***" is encountered; otherwise it is 0.
 351
 352 sub munge {
 353 my($file) = $_[0];
 354 my($extra) = $_[1];
 355 my($yield) = 0;
 356 my(@saved) = ();
 357
 358 local $_;
 359
 360 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 361
 362 my($is_log) = $file =~ /log/;
 363 my($is_stdout) = $file =~ /stdout/;
 364 my($is_stderr) = $file =~ /stderr/;
 365 my($is_mail) = $file =~ /mail/;
 366
 367 # Date pattern
 368
 369 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 370
 371 # Pattern for matching pids at start of stderr lines; initially something
 372 # that won't match.
 373
 374 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 375
 376 # Scan the file and make the changes. Near the bottom there are some changes
 377 # that are specific to certain file types, though there are also some of those
 378 # inline too.
 379
 380 LINE: while(<IN>)
 381   {
 382 RESET_AFTER_EXTRA_LINE_READ:
 383   # Custom munges
 384   if ($extra)
 385     {
 386     next if $extra =~ m%^/%  &&  eval $extra;
 387     eval $extra if $extra =~ m/^s/;
 388     }
 389
 390   # Check for "*** truncated ***"
 391   $yield = 1 if /\*\*\* truncated \*\*\*/;
 392
 393   # Replace the name of this host
 394   s/\Q$parm_hostname\E/the.local.host.name/g;
 395
 396   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 397   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 398
 399   # The name of the shell may vary
 400   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 401
 402   # Replace the path to the testsuite directory
 403   s?\Q$parm_cwd\E?TESTSUITE?g;
 404
 405   # Replace the Exim version number (may appear in various places)
 406   # patchexim should have fixed this for us
 407   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 408
 409   # Replace Exim message ids by a unique series
 410   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 411     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 412
 413   # The names of lock files appear in some error and debug messages
 414   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 415
 416   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 417   # port" message, because it is not always the same.
 418   s/port (\d+) \([^)]+\)/port $1/g
 419     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 420
 421   # Challenges in SPA authentication
 422   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 423
 424   # PRVS values
 425   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 426   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463
 464     # Round the time-difference up to nearest even value
 465     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
 466
 467     # We used to use globally unique replacement values, but timing
 468     # differences make this impossible. Just show the increment on the
 469     # last one.
 470
 471     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 472       $increment, $expired);
 473     next;
 474     }
 475
 476   # more_errno values in exim_dumpdb output which are times
 477   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 478
 479   # port numbers in dumpdb output
 480   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
 481
 482   # port numbers in stderr
 483   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
 484   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
 485
 486
 487   # ======== Dates and times ========
 488
 489   # Dates and times are all turned into the same value - trying to turn
 490   # them into different ones cannot be done repeatedly because they are
 491   # real time stamps generated while running the test. The actual date and
 492   # time used was fixed when I first started running automatic Exim tests.
 493
 494   # Date/time in header lines and SMTP responses
 495   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 496     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 497
 498   # Date/time in logs and in one instance of a filter test
 499   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 500   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 501   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 502   # Date/time in syslog test
 503   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 504   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 505   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 506   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 507
 508   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 509   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 510
 511   # Date/time in message separators
 512   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 513     /Tue Mar 02 09:44:33 1999/gx;
 514
 515   # Date of message arrival in spool file as shown by -Mvh
 516   s/^\d{9,10}\s0$/ddddddddd 0/;
 517
 518   # Date/time in mbx mailbox files
 519   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 520
 521   # Dates/times in debugging output for writing retry records
 522   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 523     {
 524     my($next) = $3 - $2;
 525     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 526     }
 527   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 528   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 529
 530   # Time to retry may vary
 531   s/time to retry = \S+/time to retry = tttt/;
 532   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 533   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 534
 535   # Date/time in exim -bV output
 536   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 537
 538   # Eximstats heading
 539   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 540     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 541
 542   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 543   # us the former on a new connection.
 544   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 545
 546   # ======== TLS certificate algorithms ========
 547   #
 548   # In Received: headers, convert RFC 8314 style ciphersuite to
 549   # the older (comment) style, keeping only the Auth element
 550   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
 551   # element (and no _WITH); insert a spurious "RSA".
 552
 553   s/^\s+by .+ with .+ \K tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-\1-AES256-SHAnnn:xxx)/;
 554   s/^\s+by .+ with .+ \K tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
 555
 556   # Test machines might have various different TLS library versions supporting
 557   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 558   # treat the standard algorithms the same.
 559   #
 560   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : ???
 561   #
 562   # So far, have seen:
 563   #   TLSv1:AES128-GCM-SHA256:128
 564   #   TLSv1:AES256-SHA:256
 565   #   TLSv1.1:AES256-SHA:256
 566   #   TLSv1.2:AES256-GCM-SHA384:256
 567   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 568   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 569   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 570   # We also need to handle the ciphersuite without the TLS part present, for
 571   # client-ssl's output.  We also see some older forced ciphersuites, but
 572   # negotiating TLS 1.2 instead of 1.0.
 573   # Mail headers (...), log-lines X=..., client-ssl output ...
 574   # (and \b doesn't match between ' ' and '(' )
 575   #
 576   # Retain the authentication algorith field as we want to test that.
 577
 578   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1(\.[123])?:/$1TLS1.x:/xg;
 579   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
 580   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
 581
 582   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 583   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
 584   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
 585   #
 586   # TLSversion : "TLS" - C_iph_er - MAC : ???
 587   #
 588   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
 589   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
 590
 591   # LibreSSL
 592   # TLSv1:AES256-GCM-SHA384:256
 593   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 594   #
 595   # ECDHE-RSA-CHACHA20-POLY1305
 596   # AES256-GCM-SHA384
 597
 598   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 599   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
 600   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
 601
 602   # GnuTLS have seen:
 603   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
 604   #
 605   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 606   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 607   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 608   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 609   #
 610   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 611   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 612   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 613   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 614   # and as stand-alone cipher:
 615   #   ECDHE-RSA-AES256-SHA
 616   #   DHE-RSA-AES256-SHA256
 617   #   DHE-RSA-AES256-SHA
 618   # picking latter as canonical simply because regex easier that way.
 619   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
 620   s/TLS1.[0123]:((EC)?DHE_)?(RSA|ECDSA)_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:ke-$3-AES256-SHAnnn:xxx/g;
 621   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
 622
 623   # GnuTLS library error message changes
 624   s/No certificate was found/The peer did not send any certificate/g;
 625 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 626   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 627   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 628
 629   # (this new one is a generic channel-read error, but the testsuite
 630   # only hits it in one place)
 631   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 632
 633   # (replace old with new, hoping that old only happens in one situation)
 634   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 635   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 636
 637   # signature algorithm names
 638   s/RSA-SHA1/RSA-SHA/;
 639
 640
 641   # ======== Caller's login, uid, gid, home, gecos ========
 642
 643   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 644   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 645   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 646
 647   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 648   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 649
 650   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 651   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 652
 653   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 654
 655   # When looking at spool files with -Mvh, we will find not only the caller
 656   # login, but also the uid and gid. It seems that $) in some Perls gives all
 657   # the auxiliary gids as well, so don't bother checking for that.
 658
 659   s/^CALLER $> \d+$/CALLER UID GID/;
 660
 661   # There is one case where the caller's login is forced to something else,
 662   # in order to test the processing of logins that contain spaces. Weird what
 663   # some people do, isn't it?
 664
 665   s/^spaced user $> \d+$/CALLER UID GID/;
 666
 667
 668   # ======== Exim's login ========
 669   # For messages received by the daemon, this is in the -H file, which some
 670   # tests inspect. For bounce messages, this will appear on the U= lines in
 671   # logs and also after Received: and in addresses. In one pipe test it appears
 672   # after "Running as:". It also appears in addresses, and in the names of lock
 673   # files.
 674
 675   s/U=$parm_eximuser/U=EXIMUSER/;
 676   s/user=$parm_eximuser/user=EXIMUSER/;
 677   s/login=$parm_eximuser/login=EXIMUSER/;
 678   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 679   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 680   s/\b$parm_eximuser@/EXIMUSER@/;
 681   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 682
 683   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 684   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 685
 686   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 687   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 688
 689   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 690
 691
 692   # ======== General uids, gids, and pids ========
 693   # Note: this must come after munges for caller's and exim's uid/gid
 694
 695   # These are for systems where long int is 64
 696   s/\buid=4294967295/uid=-1/;
 697   s/\beuid=4294967295/euid=-1/;
 698   s/\bgid=4294967295/gid=-1/;
 699   s/\begid=4294967295/egid=-1/;
 700
 701   s/\bgid=\d+/gid=gggg/;
 702   s/\begid=\d+/egid=gggg/;
 703   s/\b(pid=|PID: )\d+/$1pppp/;
 704   s/\buid=\d+/uid=uuuu/;
 705   s/\beuid=\d+/euid=uuuu/;
 706   s/set_process_info:\s+\d+/set_process_info: pppp/;
 707   s/queue run pid \d+/queue run pid ppppp/;
 708   s/process \d+ running as transport filter/process pppp running as transport filter/;
 709   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 710   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 711   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 712
 713   # Pid in temp file in appendfile transport
 714   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 715
 716   # Optional pid in log lines
 717   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 718     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 719
 720   # Optional pid in syslog test lines
 721   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 722     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 723
 724   # Detect a daemon stderr line with a pid and save the pid for subsequent
 725   # removal from following lines.
 726   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 727   s/^$spid //;
 728
 729   # Queue runner waiting messages
 730   s/waiting for children of \d+/waiting for children of pppp/;
 731   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 732
 733   # The spool header file name varies with PID
 734   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 735
 736   # ======== Port numbers ========
 737   # Incoming port numbers may vary, but not in daemon startup line.
 738
 739   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 740   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 741
 742   # This handles "connection from" and the like, when the port is given
 743   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 744       && !/\*>/ && !/Connection refused/)
 745     {
 746     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 747     }
 748
 749   # Port in host address in spool file output from -Mvh
 750   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 751
 752   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 753     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 754   }
 755
 756
 757   # ======== Local IP addresses ========
 758   # The amount of space between "host" and the address in verification output
 759   # depends on the length of the host name. We therefore reduce it to one space
 760   # for all of them.
 761   # Also, the length of space at the end of the host line is dependent
 762   # on the length of the longest line, so strip it also on otherwise
 763   # un-rewritten lines like localhost
 764
 765   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 766   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 767   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 768   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 769   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 770   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 771   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 772   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 773   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 774   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 775
 776
 777   # ======== Test network IP addresses ========
 778   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 779   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 780
 781
 782   # ======== IP error numbers and messages ========
 783   # These vary between operating systems
 784   s/Can't assign requested address/Network Error/;
 785   s/Cannot assign requested address/Network Error/;
 786   s/Operation timed out/Connection timed out/;
 787   s/Address family not supported by protocol family/Network Error/;
 788   s/Network is unreachable/Network Error/;
 789   s/Invalid argument/Network Error/;
 790
 791   s/\(\d+\): Network/(dd): Network/;
 792   s/\(\d+\): Connection refused/(dd): Connection refused/;
 793   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 794   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 795   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 796
 797
 798   # ======== Other error numbers ========
 799   s/errno=\d+/errno=dd/g;
 800
 801   # ======== System Error Messages ======
 802   # depending on the underlaying file system the error message seems to differ
 803   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 804
 805   # ======== Output from ls ========
 806   # Different operating systems use different spacing on long output
 807   #s/ +/ /g if /^[-rwd]{10} /;
 808   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 809   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 810   # unfortunately matches a non-ls linefull of dashes.
 811   # Allow the case where we've already picked out the file protection bits.
 812   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 813     s/ +/ /g;
 814   }
 815
 816
 817   # ======== Message sizes =========
 818   # Message sizes vary, owing to different logins and host names that get
 819   # automatically inserted. I can't think of any way of even approximately
 820   # comparing these.
 821
 822   s/([\s,])S=\d+\b/$1S=sss/;
 823   s/:S\d+\b/:Ssss/;
 824   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 825   s/\sSIZE=\d+\b/ SIZE=ssss/;
 826   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 827   s/old size = \d+\b/old size = sssss/;
 828   s/message size = \d+\b/message size = sss/;
 829   s/this message = \d+\b/this message = sss/;
 830   s/Size of headers = \d+/Size of headers = sss/;
 831   s/sum=(?!0)\d+/sum=dddd/;
 832   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 833   s/(?<=sum=0 )count=\d+\b/count=dd/;
 834   s/,S is \d+\b/,S is ddddd/;
 835   s/\+0100,\d+;/+0100,ddd;/;
 836   s/\(\d+ bytes written\)/(ddd bytes written)/;
 837   s/added '\d+ 1'/added 'ddd 1'/;
 838   s/Received\s+\d+/Received               nnn/;
 839   s/Delivered\s+\d+/Delivered              nnn/;
 840
 841
 842   # ======== Values in spool space failure message ========
 843   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 844
 845
 846   # ======== Filter sizes ========
 847   # The sizes of filter files may vary because of the substitution of local
 848   # filenames, logins, etc.
 849
 850   s/^\d+(?= bytes read from )/ssss/;
 851
 852
 853   # ======== OpenSSL error messages ========
 854   # Different releases of the OpenSSL libraries seem to give different error
 855   # numbers, or handle specific bad conditions in different ways, leading to
 856   # different wording in the error messages, so we cannot compare them.
 857
 858 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 859 #    but I can't work out how to deal with that.
 860   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 861   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 862   next if /SSL verify error: depth=0 error=certificate not trusted/;
 863
 864   # ======== Maildir things ========
 865   # timestamp output in maildir processing
 866   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 867
 868   # maildir delivery files appearing in log lines (in cases of error)
 869   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 870
 871   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 872
 873   # Maildir file names in general
 874   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 875
 876   # Maildirsize data
 877   while (/^\d+S,\d+C\s*$/)
 878     {
 879     print MUNGED;
 880     while (<IN>)
 881       {
 882       last if !/^\d+ \d+\s*$/;
 883       print MUNGED "ddd d\n";
 884       }
 885     last if !defined $_;
 886     }
 887   last if !defined $_;
 888
 889
 890   # ======== Output from the "fd" program about open descriptors ========
 891   # The statuses seem to be different on different operating systems, but
 892   # at least we'll still be checking the number of open fd's.
 893
 894   s/max fd = \d+/max fd = dddd/;
 895   s/status=0 RDONLY/STATUS/g;
 896   s/status=1 WRONLY/STATUS/g;
 897   s/status=2 RDWR/STATUS/g;
 898
 899
 900   # ======== Contents of spool files ========
 901   # A couple of tests dump the contents of the -H file. The length fields
 902   # will be wrong because of different user names, etc.
 903   s/^\d\d\d(?=[PFS*])/ddd/;
 904
 905
 906   # ========= Exim lookups ==================
 907   # Lookups have a char which depends on the number of lookup types compiled in,
 908   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 909   # other output is fragile; perhaps the debug output should be revised instead.
 910   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 911
 912   # ==========================================================
 913   # MIME boundaries in RFC3461 DSN messages
 914   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 915
 916   # ==========================================================
 917   # Some munging is specific to the specific file types
 918
 919   # ======== stdout ========
 920
 921   if ($is_stdout)
 922     {
 923     # Skip translate_ip_address and use_classresources in -bP output because
 924     # they aren't always there.
 925
 926     next if /translate_ip_address =/;
 927     next if /use_classresources/;
 928
 929     # In certain filter tests, remove initial filter lines because they just
 930     # clog up by repetition.
 931
 932     if ($rmfiltertest)
 933       {
 934       next if /^(Sender\staken\sfrom|
 935                  Return-path\scopied\sfrom|
 936                  Sender\s+=|
 937                  Recipient\s+=)/x;
 938       if (/^Testing \S+ filter/)
 939         {
 940         $_ = <IN>;    # remove blank line
 941         next;
 942         }
 943       }
 944
 945     # remote IPv6 addrs vary
 946     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 947
 948     # openssl version variances
 949   # Error lines on stdout from SSL contain process id values and file names.
 950   # They also contain a source file name and line number, which may vary from
 951   # release to release.
 952
 953     next if /^SSL info:/;
 954     next if /SSL verify error: depth=0 error=certificate not trusted/;
 955     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 956     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
 957     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
 958     s/^error:[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/error:dddddddd:$1/;
 959
 960     # gnutls version variances
 961     next if /^Error in the pull function./;
 962
 963     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
 964     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
 965     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
 966
 967     # subsecond timstamp info in reported header-files
 968     s/^(-received_time_usec \.)\d{6}$/$1uuuuuu/;
 969
 970     # Postgres server takes varible time to shut down; lives in various places
 971     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
 972     s/^\/.*postgres /POSTGRES /;
 973
 974     # ARC is not always supported by the build
 975     next if /^arc_sign =/;
 976     }
 977
 978   # ======== stderr ========
 979
 980   elsif ($is_stderr)
 981     {
 982     # The very first line of debugging output will vary
 983
 984     s/^Exim version .*/Exim version x.yz ..../;
 985
 986     # Debugging lines for Exim terminations and process-generation
 987
 988     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 989     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
 990
 991     # IP address lookups use gethostbyname() when IPv6 is not supported,
 992     # and gethostbyname2() or getipnodebyname() when it is.
 993
 994     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 995
 996     # we don't care what TZ enviroment the testhost was running
 997     next if /^Reset TZ to/;
 998
 999     # drop gnutls version strings
1000     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1001     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1002
1003     # drop openssl version strings
1004     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1005     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1006
1007     # drop lookups
1008     next if /^Lookups \(built-in\):/;
1009     next if /^Loading lookup modules from/;
1010     next if /^Loaded \d+ lookup modules/;
1011     next if /^Total \d+ lookups/;
1012
1013     # drop compiler information
1014     next if /^Compiler:/;
1015
1016     # and the ugly bit
1017     # different libraries will have different numbers (possibly 0) of follow-up
1018     # lines, indenting with more data
1019     if (/^Library version:/) {
1020       while (1) {
1021         $_ = <IN>;
1022         next if /^\s/;
1023         goto RESET_AFTER_EXTRA_LINE_READ;
1024       }
1025     }
1026
1027     # drop other build-time controls emitted for debugging
1028     next if /^WHITELIST_D_MACROS:/;
1029     next if /^TRUSTED_CONFIG_LIST:/;
1030
1031     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1032     # with -be, privileges will have been dropped, so this will always
1033     # be the case
1034     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1035
1036     # We might not keep this check; rather than change all the tests, just
1037     # ignore it as long as it succeeds; then we only need to change the
1038     # TLS tests where tls_require_ciphers has been set.
1039     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1040       my $discard = <IN>;
1041       next;
1042     }
1043     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1044
1045     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1046     next if /^macros_trusted overridden to true by whitelisting/;
1047
1048     # We have to omit the localhost ::1 address so that all is well in
1049     # the IPv4-only case.
1050
1051     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1052       if (/looked up these IP addresses/);
1053     next if /name=localhost address=::1/;
1054
1055     # drop pdkim debugging header
1056     next if /^PDKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1057
1058     # Various other IPv6 lines must be omitted too
1059
1060     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1061     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1062     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1063     next if / in dns_ipv4_lookup?/;
1064
1065     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1066       {
1067       $_= <IN>;     # Gets "returning DNS_NODATA"
1068       next;
1069       }
1070
1071     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1072     # are unset, because tls ain't always there.
1073
1074     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1075                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1076
1077     # Skip auxiliary group lists because they will vary.
1078
1079     next if /auxiliary group list:/;
1080
1081     # Skip "extracted from gecos field" because the gecos field varies
1082
1083     next if /extracted from gecos field/;
1084
1085     # Skip "waiting for data on socket" and "read response data: size=" lines
1086     # because some systems pack more stuff into packets than others.
1087
1088     next if /waiting for data on socket/;
1089     next if /read response data: size=/;
1090
1091     # If Exim is compiled with readline support but it can't find the library
1092     # to load, there will be an extra debug line. Omit it.
1093
1094     next if /failed to load readline:/;
1095
1096     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1097     # O_CREAT; other's don't. In the latter case there is some debugging output
1098     # which is not present in the former. Skip the relevant lines (there are
1099     # three of them).
1100
1101     if (/returned from EXIM_DBOPEN: \(nil\)/)
1102       {
1103       $_ .= <IN>;
1104       s?\Q$parm_cwd\E?TESTSUITE?g;
1105       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1106         { $_ = <IN>; next; }
1107       }
1108
1109     # Some tests turn on +expand debugging to check on expansions.
1110     # Unfortunately, the Received: expansion varies, depending on whether TLS
1111     # is compiled or not. So we must remove the relevant debugging if it is.
1112
1113     if (/^condition: def:tls_cipher/)
1114       {
1115       while (<IN>) { last if /^condition: def:sender_address/; }
1116       }
1117     elsif (/^expanding: Received: /)
1118       {
1119       while (<IN>) { last if !/^\s/; }
1120       }
1121
1122     # remote port numbers vary
1123     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1124
1125     # Skip hosts_require_dane checks when the options
1126     # are unset, because dane ain't always there.
1127     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1128
1129     # DISABLE_OCSP
1130     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1131
1132     # SUPPORT_PROXY
1133     next if /host in hosts_proxy\?/;
1134
1135     # Experimental_International
1136     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1137
1138     # Experimental_REQUIRETLS
1139     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1140
1141     # TCP Fast Open
1142     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1143
1144     # Experimental_PIPE_CONNECT
1145     next if / in (pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1146
1147     # Environment cleaning
1148     next if /\w+ in keep_environment\? (yes|no)/;
1149
1150     # Sizes vary with test hostname
1151     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1152
1153     # Spool filesystem free space changes on different systems.
1154     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1155
1156     # Non-TLS builds have different expansions for received_header_text
1157     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1158       {
1159       $_ .= <IN>;
1160       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1161       }
1162     if (/^ ├──condition: def:tls_cipher$/)
1163       {
1164       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1165       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1166       }
1167
1168     # Not all platforms build with DKIM enabled
1169     next if /^PDKIM >> Body data for hash, canonicalized/;
1170
1171     # Not all platforms have sendfile support
1172     next if /^cannot use sendfile for body: no support$/;
1173
1174     #  Parts of DKIM-specific debug output depend on the time/date
1175     next if /^date:\w+,\{SP\}/;
1176     next if /^PDKIM \[[^[]+\] (Header hash|b) computed:/;
1177
1178     # Not all platforms support TCP Fast Open, and the compile omits the check
1179     if (s/\S+ in hosts_try_fastopen\? no \(option unset\)\n$//)
1180       {
1181       $_ .= <IN>;
1182       s/ \.\.\. >>> / ... /;
1183       s/Address family not supported by protocol family/Network Error/;
1184       s/Network is unreachable/Network Error/;
1185       }
1186     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1187     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1188
1189     # Specific pointer values reported for DB operations change from run to run
1190     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1191     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1192
1193     # Platform-dependent output during MySQL startup
1194     next if /PerconaFT file system space/;
1195     next if /^Waiting for MySQL server to answer/;
1196     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1197
1198     # Not all builds include DMARC
1199     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1200
1201     # When Exim is checking the size of directories for maildir, it uses
1202     # the check_dir_size() function to scan directories. Of course, the order
1203     # of the files that are obtained using readdir() varies from system to
1204     # system. We therefore buffer up debugging lines from check_dir_size()
1205     # and sort them before outputting them.
1206
1207     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1208       {
1209       push @saved, $_;
1210       }
1211     else
1212       {
1213       if (@saved > 0)
1214         {
1215         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1216           "to ensure consistency\n";
1217         @saved = sort(@saved);
1218         print MUNGED @saved;
1219         @saved = ();
1220         }
1221
1222       # Skip some lines that Exim puts out at the start of debugging output
1223       # because they will be different in different binaries.
1224
1225       print MUNGED
1226         unless (/^Berkeley DB: / ||
1227                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1228                 /^Authenticators:/ ||
1229                 /^Lookups:/ ||
1230                 /^Support for:/ ||
1231                 /^Routers:/ ||
1232                 /^Transports:/ ||
1233                 /^Malware:/ ||
1234                 /^log selectors =/ ||
1235                 /^cwd=/ ||
1236                 /^Fixed never_users:/ ||
1237                 /^Configure owner:/ ||
1238                 /^Size of off_t:/
1239                 );
1240
1241
1242       }
1243
1244     next;
1245     }
1246
1247   # ======== log ========
1248
1249   elsif ($is_log)
1250     {
1251     # Berkeley DB version differences
1252     next if / Berkeley DB error: /;
1253
1254     # CHUNKING: exact sizes depend on hostnames in headers
1255     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1256
1257     # openssl version variances
1258     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1259     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1260     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1261
1262     # DKIM timestamps
1263     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1264       {
1265       my ($prefix, $t_diff) = ($1, $3 - $2);
1266       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1267       }
1268     }
1269
1270   # ======== mail ========
1271
1272   elsif ($is_mail)
1273     {
1274     # DKIM timestamps, and signatures depending thereon
1275     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1276       {
1277       my ($indent, $t_diff) = ($1, $3 - $2);
1278       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1279       <IN>;
1280       <IN>;
1281       }
1282     }
1283
1284   # ======== All files other than stderr ========
1285
1286   print MUNGED;
1287   }
1288
1289 close(IN);
1290 return $yield;
1291 }
1292
1293
1294
1295
1296 ##################################################
1297 #        Subroutine to interact with caller      #
1298 ##################################################
1299
1300 # Arguments: [0] the prompt string
1301 #            [1] if there is a U in the prompt and $force_update is true
1302 #            [2] if there is a C in the prompt and $force_continue is true
1303 # Returns:   returns the answer
1304
1305 sub interact {
1306   my ($prompt, $have_u, $have_c) = @_;
1307
1308   print $prompt;
1309
1310   if ($have_u) {
1311     print "... update forced\n";
1312     return 'u';
1313   }
1314
1315   if ($have_c) {
1316     print "... continue forced\n";
1317     return 'c';
1318   }
1319
1320   return lc <T>;
1321 }
1322
1323
1324
1325 ##################################################
1326 #    Subroutine to log in force_continue mode    #
1327 ##################################################
1328
1329 # In force_continue mode, we just want a terse output to a statically
1330 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1331 # all have mismatches, it will log multiple times.
1332 #
1333 # Arguments: [0] the logfile to append to
1334 #            [1] the testno that failed
1335 # Returns:   nothing
1336
1337
1338
1339 sub log_failure {
1340   my ($logfile, $testno, $detail) = @_;
1341
1342   open(my $fh, '>>', $logfile) or return;
1343
1344   print $fh "Test $testno "
1345         . (defined $detail ? "$detail " : '')
1346         . "failed\n";
1347 }
1348
1349 # Computer-readable summary results logfile
1350
1351 sub log_test {
1352   my ($logfile, $testno, $resultchar) = @_;
1353
1354   open(my $fh, '>>', $logfile) or return;
1355   print $fh "$testno $resultchar\n";
1356 }
1357
1358
1359
1360 ##################################################
1361 #    Subroutine to compare one output file       #
1362 ##################################################
1363
1364 # When an Exim server is part of the test, its output is in separate files from
1365 # an Exim client. The server data is concatenated with the client data as part
1366 # of the munging operation.
1367 #
1368 # Arguments:  [0] the name of the main raw output file
1369 #             [1] the name of the server raw output file or undef
1370 #             [2] where to put the munged copy
1371 #             [3] the name of the saved file
1372 #             [4] TRUE if this is a log file whose deliveries must be sorted
1373 #             [5] optionally, a custom munge command
1374 #
1375 # Returns:    0 comparison succeeded
1376 #             1 comparison failed; differences to be ignored
1377 #             2 comparison failed; files may have been updated (=> re-compare)
1378 #
1379 # Does not return if the user replies "Q" to a prompt.
1380
1381 sub check_file{
1382 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1383
1384 # If there is no saved file, the raw files must either not exist, or be
1385 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1386
1387 # we check if there is a flavour specific file, but we remember
1388 # the original file name as "generic"
1389 $sf_generic = $sf;
1390 $sf_flavour = "$sf_generic.$flavour";
1391 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1392
1393 if (! -e $sf_current)
1394   {
1395   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1396
1397   print "\n";
1398   print "** $rf is not empty\n" if (-s $rf);
1399   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1400
1401   for (;;)
1402     {
1403     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1404     tests_exit(1) if /^q?$/;
1405     if (/^c$/ && $force_continue) {
1406       log_failure($log_failed_filename, $testno, $rf);
1407       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1408     }
1409     return 1 if /^c$/i && $rf !~ /paniclog/ && $rsf !~ /paniclog/;
1410     last if (/^[sc]$/);
1411     }
1412
1413   foreach $f ($rf, $rsf)
1414     {
1415     if (defined $f && -s $f)
1416       {
1417       print "\n";
1418       print "------------ $f -----------\n"
1419         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1420       system("$more '$f'");
1421       }
1422     }
1423
1424   print "\n";
1425   for (;;)
1426     {
1427     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1428     tests_exit(1) if /^q?$/;
1429     if (/^c$/ && $force_continue) {
1430       log_failure($log_failed_filename, $testno, $rf);
1431       log_test($log_summary_filename, $testno, 'F')
1432     }
1433     return 1 if /^c$/i;
1434     last if (/^u$/i);
1435     }
1436   }
1437
1438 #### $_
1439
1440 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1441 # was a request to create a saved file. First, create the munged file from any
1442 # data that does exist.
1443
1444 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1445 my($truncated) = munge($rf, $extra) if -e $rf;
1446
1447 # Append the raw server log, if it is non-empty
1448 if (defined $rsf && -e $rsf)
1449   {
1450   print MUNGED "\n******** SERVER ********\n";
1451   $truncated |= munge($rsf, $extra);
1452   }
1453 close(MUNGED);
1454
1455 # If a saved file exists, do the comparison. There are two awkward cases:
1456 #
1457 # If "*** truncated ***" was found in the new file, it means that a log line
1458 # was overlong, and truncated. The problem is that it may be truncated at
1459 # different points on different systems, because of different user name
1460 # lengths. We reload the file and the saved file, and remove lines from the new
1461 # file that precede "*** truncated ***" until we reach one that matches the
1462 # line that precedes it in the saved file.
1463 #
1464 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1465 # for an individual message might vary in their order from system to system, as
1466 # a result of parallel deliveries. We load the munged file and sort sequences
1467 # of delivery lines.
1468
1469 if (-e $sf_current)
1470   {
1471   # Deal with truncated text items
1472
1473   if ($truncated)
1474     {
1475     my(@munged, @saved, $i, $j, $k);
1476
1477     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1478     @munged = <MUNGED>;
1479     close(MUNGED);
1480     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1481     @saved = <SAVED>;
1482     close(SAVED);
1483
1484     $j = 0;
1485     for ($i = 0; $i < @munged; $i++)
1486       {
1487       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1488         {
1489         for (; $j < @saved; $j++)
1490           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1491         last if $j >= @saved;     # not found in saved
1492
1493         for ($k = $i - 1; $k >= 0; $k--)
1494           { last if $munged[$k] eq $saved[$j - 1]; }
1495
1496         last if $k <= 0;          # failed to find previous match
1497         splice @munged, $k + 1, $i - $k - 1;
1498         $i = $k + 1;
1499         }
1500       }
1501
1502     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1503     for ($i = 0; $i < @munged; $i++)
1504       { print MUNGED $munged[$i]; }
1505     close(MUNGED);
1506     }
1507
1508   # Deal with log sorting
1509
1510   if ($sortfile)
1511     {
1512     my(@munged, $i, $j);
1513
1514     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1515     @munged = <MUNGED>;
1516     close(MUNGED);
1517
1518     for ($i = 0; $i < @munged; $i++)
1519       {
1520       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1521         {
1522         for ($j = $i + 1; $j < @munged; $j++)
1523           {
1524           last if $munged[$j] !~
1525             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1526           }
1527         @temp = splice(@munged, $i, $j - $i);
1528         @temp = sort(@temp);
1529         splice(@munged, $i, 0, @temp);
1530         }
1531       }
1532
1533     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1534     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1535     for ($i = 0; $i < @munged; $i++)
1536       { print MUNGED $munged[$i]; }
1537     close(MUNGED);
1538     }
1539
1540   # Do the comparison
1541
1542   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1543
1544   # Handle comparison failure
1545
1546   print "** Comparison of $mf with $sf_current failed";
1547   system("$more test-cf");
1548
1549   print "\n";
1550   for (;;)
1551     {
1552     $_ = interact('Continue, Retry, Update current'
1553         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1554         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1555     tests_exit(1) if /^q?$/;
1556     if (/^c$/ && $force_continue) {
1557       log_failure($log_failed_filename, $testno, $sf_current);
1558       log_test($log_summary_filename, $testno, 'F')
1559     }
1560     return 1 if /^c$/i;
1561     return 2 if /^r$/i;
1562     last if (/^[us]$/i);
1563     }
1564   }
1565
1566 # Update or delete the saved file, and give the appropriate return code.
1567
1568 if (-s $mf)
1569   {
1570     my $sf = /^u/i ? $sf_current : $sf_flavour;
1571     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1572   }
1573 else
1574   {
1575     # if we deal with a flavour file, we can't delete it, because next time the generic
1576     # file would be used again
1577     if ($sf_current eq $sf_flavour) {
1578       open(FOO, ">$sf_current");
1579       close(FOO);
1580     }
1581     else {
1582       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1583     }
1584   }
1585
1586 return 2;
1587 }
1588
1589
1590
1591 ##################################################
1592 # Custom munges
1593 # keyed by name of munge; value is a ref to a hash
1594 # which is keyed by file, value a string to look for.
1595 # Usable files are:
1596 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1597 # Search strings starting with 's' do substitutions;
1598 # with '/' do line-skips.
1599 # Triggered by a scriptfile line "munge <name>"
1600 ##################################################
1601 $munges =
1602   { 'dnssec' =>
1603     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1604
1605     'gnutls_unexpected' =>
1606     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1607
1608     'gnutls_handshake' =>
1609     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1610
1611     'gnutls_bad_clientcert' =>
1612     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1613       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1614     },
1615
1616     'optional_events' =>
1617     { 'stdout' => '/event_action =/' },
1618
1619     'optional_ocsp' =>
1620     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1621
1622     'optional_cert_hostnames' =>
1623     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1624
1625     'loopback' =>
1626     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1627
1628     'scanfile_size' =>
1629     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1630
1631     'delay_1500' =>
1632     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1633
1634     'tls_anycipher' =>
1635     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1636                       s! DN="C=! DN="/C=!;
1637                       s! DN="[^,"]*\K,!/!;
1638                       s! DN="[^,"]*\K,!/!;
1639                       s! DN="[^,"]*\K,!/!;
1640                      ',
1641       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1642       'mail'      => 's/^\s+by .+ with .+ \K tls TLS_.+$/(TLS_proto_and_cipher)/;
1643                       s/ \(TLS[^)]*\)/ (TLS_proto_and_cipher)/;
1644                      ',
1645     },
1646
1647     'debug_pid' =>
1648     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1649
1650     'optional_dsn_info' =>
1651     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1652     },
1653
1654     'optional_config' =>
1655     { 'stdout' => '/^(
1656                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1657                   |gnutls_require_(kx|mac|protocols)
1658                   |hosts_pipe_connect
1659                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1660                   |dane_require_tls_ciphers
1661                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1662                   |pipelining_connect_advertise_hosts
1663                   |socks_proxy
1664                   |tls_[^ ]*
1665                   |utf8_downconvert
1666                   )($|[ ]=)/x'
1667     },
1668
1669     'sys_bindir' =>
1670     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1671
1672     'sync_check_data' =>
1673     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1674       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1675
1676     'debuglog_stdout' =>
1677     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1678                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1679     },
1680
1681     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1682     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1683
1684     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1685     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1686
1687     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1688     { 'stdout' => 's%^> X/X$%> X%' },
1689   };
1690
1691
1692 sub max {
1693   my ($a, $b) = @_;
1694   return $a if ($a > $b);
1695   return $b;
1696 }
1697
1698 ##################################################
1699 #    Subroutine to check the output of a test    #
1700 ##################################################
1701
1702 # This function is called when the series of subtests is complete. It makes
1703 # use of check_file(), whose arguments are:
1704 #
1705 #  [0] the name of the main raw output file
1706 #  [1] the name of the server raw output file or undef
1707 #  [2] where to put the munged copy
1708 #  [3] the name of the saved file
1709 #  [4] TRUE if this is a log file whose deliveries must be sorted
1710 #  [5] an optional custom munge command
1711 #
1712 # Arguments: Optionally, name of a single custom munge to run.
1713 # Returns:   0 if the output compared equal
1714 #            1 if comparison failed; differences to be ignored
1715 #            2 if re-run needed (files may have been updated)
1716
1717 sub check_output{
1718 my($mungename) = $_[0];
1719 my($yield) = 0;
1720 my($munge) = $munges->{$mungename} if defined $mungename;
1721
1722 $yield = max($yield,  check_file("spool/log/paniclog",
1723                        "spool/log/serverpaniclog",
1724                        "test-paniclog-munged",
1725                        "paniclog/$testno", 0,
1726                        $munge->{paniclog}));
1727
1728 $yield = max($yield,  check_file("spool/log/rejectlog",
1729                        "spool/log/serverrejectlog",
1730                        "test-rejectlog-munged",
1731                        "rejectlog/$testno", 0,
1732                        $munge->{rejectlog}));
1733
1734 $yield = max($yield,  check_file("spool/log/mainlog",
1735                        "spool/log/servermainlog",
1736                        "test-mainlog-munged",
1737                        "log/$testno", $sortlog,
1738                        $munge->{mainlog}));
1739
1740 if (!$stdout_skip)
1741   {
1742   $yield = max($yield,  check_file("test-stdout",
1743                        "test-stdout-server",
1744                        "test-stdout-munged",
1745                        "stdout/$testno", 0,
1746                        $munge->{stdout}));
1747   }
1748
1749 if (!$stderr_skip)
1750   {
1751   $yield = max($yield,  check_file("test-stderr",
1752                        "test-stderr-server",
1753                        "test-stderr-munged",
1754                        "stderr/$testno", 0,
1755                        $munge->{stderr}));
1756   }
1757
1758 # Compare any delivered messages, unless this test is skipped.
1759
1760 if (! $message_skip)
1761   {
1762   my($msgno) = 0;
1763
1764   # Get a list of expected mailbox files for this script. We don't bother with
1765   # directories, just the files within them.
1766
1767   foreach $oldmail (@oldmails)
1768     {
1769     next unless $oldmail =~ /^mail\/$testno\./;
1770     print ">> EXPECT $oldmail\n" if $debug;
1771     $expected_mails{$oldmail} = 1;
1772     }
1773
1774   # If there are any files in test-mail, compare them. Note that "." and
1775   # ".." are automatically omitted by list_files_below().
1776
1777   @mails = list_files_below("test-mail");
1778
1779   foreach $mail (@mails)
1780     {
1781     next if $mail eq "test-mail/oncelog";
1782
1783     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1784     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1785
1786     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1787       {
1788       $msgno++;
1789       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1790       }
1791
1792     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1793     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1794       "mail/$testno.$saved_mail", 0,
1795       $munge->{mail}));
1796     delete $expected_mails{"mail/$testno.$saved_mail"};
1797     }
1798
1799   # Complain if not all expected mails have been found
1800
1801   if (scalar(keys %expected_mails) != 0)
1802     {
1803     foreach $key (keys %expected_mails)
1804       { print "** no test file found for $key\n"; }
1805
1806     for (;;)
1807       {
1808       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1809       tests_exit(1) if /^q?$/;
1810       if (/^c$/ && $force_continue) {
1811         log_failure($log_failed_filename, $testno, "missing email");
1812         log_test($log_summary_filename, $testno, 'F')
1813       }
1814       last if /^c$/;
1815
1816       # For update, we not only have to unlink the file, but we must also
1817       # remove it from the @oldmails vector, as otherwise it will still be
1818       # checked for when we re-run the test.
1819
1820       if (/^u$/)
1821         {
1822         foreach $key (keys %expected_mails)
1823           {
1824           my($i);
1825           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1826           for ($i = 0; $i < @oldmails; $i++)
1827             {
1828             if ($oldmails[$i] eq $key)
1829               {
1830               splice @oldmails, $i, 1;
1831               last;
1832               }
1833             }
1834           }
1835         last;
1836         }
1837       }
1838     }
1839   }
1840
1841 # Compare any remaining message logs, unless this test is skipped.
1842
1843 if (! $msglog_skip)
1844   {
1845   # Get a list of expected msglog files for this test
1846
1847   foreach $oldmsglog (@oldmsglogs)
1848     {
1849     next unless $oldmsglog =~ /^$testno\./;
1850     $expected_msglogs{$oldmsglog} = 1;
1851     }
1852
1853   # If there are any files in spool/msglog, compare them. However, we have
1854   # to munge the file names because they are message ids, which are
1855   # time dependent.
1856
1857   if (opendir(DIR, "spool/msglog"))
1858     {
1859     @msglogs = sort readdir(DIR);
1860     closedir(DIR);
1861
1862     foreach $msglog (@msglogs)
1863       {
1864       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1865       ($munged_msglog = $msglog) =~
1866         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1867           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1868       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
1869         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1870         $munge->{msglog}));
1871       delete $expected_msglogs{"$testno.$munged_msglog"};
1872       }
1873     }
1874
1875   # Complain if not all expected msglogs have been found
1876
1877   if (scalar(keys %expected_msglogs) != 0)
1878     {
1879     foreach $key (keys %expected_msglogs)
1880       {
1881       print "** no test msglog found for msglog/$key\n";
1882       ($msgid) = $key =~ /^\d+\.(.*)$/;
1883       foreach $cachekey (keys %cache)
1884         {
1885         if ($cache{$cachekey} eq $msgid)
1886           {
1887           print "** original msgid $cachekey\n";
1888           last;
1889           }
1890         }
1891       }
1892
1893     for (;;)
1894       {
1895       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1896       tests_exit(1) if /^q?$/;
1897       if (/^c$/ && $force_continue) {
1898         log_failure($log_failed_filename, $testno, "missing msglog");
1899         log_test($log_summary_filename, $testno, 'F')
1900       }
1901       last if /^c$/;
1902       if (/^u$/)
1903         {
1904         foreach $key (keys %expected_msglogs)
1905           {
1906           tests_exit(-1, "Failed to unlink msglog/$key")
1907             if !unlink("msglog/$key");
1908           }
1909         last;
1910         }
1911       }
1912     }
1913   }
1914
1915 return $yield;
1916 }
1917
1918
1919
1920 ##################################################
1921 #     Subroutine to run one "system" command     #
1922 ##################################################
1923
1924 # We put this in a subroutine so that the command can be reflected when
1925 # debugging.
1926 #
1927 # Argument: the command to be run
1928 # Returns:  nothing
1929
1930 sub run_system {
1931 my($cmd) = $_[0];
1932 if ($debug)
1933   {
1934   my($prcmd) = $cmd;
1935   $prcmd =~ s/; /;\n>> /;
1936   print ">> $prcmd\n";
1937   }
1938 system("$cmd");
1939 }
1940
1941
1942
1943 ##################################################
1944 #      Subroutine to run one script command      #
1945 ##################################################
1946
1947 # The <SCRIPT> file is open for us to read an optional return code line,
1948 # followed by the command line and any following data lines for stdin. The
1949 # command line can be continued by the use of \. Data lines are not continued
1950 # in this way. In all lines, the following substitutions are made:
1951 #
1952 # DIR    => the current directory
1953 # CALLER => the caller of this script
1954 #
1955 # Arguments: the current test number
1956 #            reference to the subtest number, holding previous value
1957 #            reference to the expected return code value
1958 #            reference to where to put the command name (for messages)
1959 #            auxiliary information returned from a previous run
1960 #
1961 # Returns:   0 the command was executed inline, no subprocess was run
1962 #            1 a non-exim command was run and waited for
1963 #            2 an exim command was run and waited for
1964 #            3 a command was run and not waited for (daemon, server, exim_lock)
1965 #            4 EOF was encountered after an initial return code line
1966 # Optionally also a second parameter, a hash-ref, with auxiliary information:
1967 #            exim_pid: pid of a run process
1968 #            munge: name of a post-script results munger
1969
1970 sub run_command{
1971 my($testno) = $_[0];
1972 my($subtestref) = $_[1];
1973 my($commandnameref) = $_[3];
1974 my($aux_info) = $_[4];
1975 my($yield) = 1;
1976
1977 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1978
1979 if (/^(\d+)\s*$/)                # Handle unusual return code
1980   {
1981   my($r) = $_[2];
1982   $$r = $1 << 8;
1983   $_ = <SCRIPT>;
1984   return 4 if !defined $_;       # Missing command
1985   $lineno++;
1986   }
1987
1988 chomp;
1989 $wait_time = 0;
1990
1991 # Handle concatenated command lines
1992
1993 s/\s+$//;
1994 while (substr($_, -1) eq"\\")
1995   {
1996   my($temp);
1997   $_ = substr($_, 0, -1);
1998   chomp($temp = <SCRIPT>);
1999   if (defined $temp)
2000     {
2001     $lineno++;
2002     $temp =~ s/\s+$//;
2003     $temp =~ s/^\s+//;
2004     $_ .= $temp;
2005     }
2006   }
2007
2008 # Do substitutions
2009
2010 do_substitute($testno);
2011 if ($debug) { printf ">> $_\n"; }
2012
2013 # Pass back the command name (for messages)
2014
2015 ($$commandnameref) = /^(\S+)/;
2016
2017 # Here follows code for handling the various different commands that are
2018 # supported by this script. The first group of commands are all freestanding
2019 # in that they share no common code and are not followed by any data lines.
2020
2021
2022 ###################
2023 ###################
2024
2025 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2026 # utility and to make DBM files for testing DBM lookups.
2027
2028 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2029   {
2030   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2031          "echo exim_dbmbuild exit code = \$?)" .
2032          ">>test-stdout");
2033   return 1;
2034   }
2035
2036
2037 # The "dump" command runs exim_dumpdb. On different systems, the output for
2038 # some types of dump may appear in a different order because it's just hauled
2039 # out of the DBM file. We can solve this by sorting. Ignore the leading
2040 # date/time, as it will be flattened later during munging.
2041
2042 if (/^dump\s+(\S+)/)
2043   {
2044   my($which) = $1;
2045   my(@temp);
2046   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2047   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
2048   open(OUT, ">>test-stdout");
2049   print OUT "+++++++++++++++++++++++++++\n";
2050
2051   if ($which eq "retry")
2052     {
2053     $/ = "\n  ";
2054     @temp = <IN>;
2055     $/ = "\n";
2056
2057     @temp = sort {
2058                    my($aa) = split(' ', $a);
2059                    my($bb) = split(' ', $b);
2060                    return $aa cmp $bb;
2061                  } @temp;
2062
2063     foreach $item (@temp)
2064       {
2065       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2066       print OUT "  $item\n";
2067       }
2068     }
2069   else
2070     {
2071     @temp = <IN>;
2072     if ($which eq "callout")
2073       {
2074       @temp = sort {
2075                    my($aa) = substr $a, 21;
2076                    my($bb) = substr $b, 21;
2077                    return $aa cmp $bb;
2078                    } @temp;
2079       }
2080     print OUT @temp;
2081     }
2082
2083   close(IN);
2084   close(OUT);
2085   return 1;
2086   }
2087
2088
2089 # verbose comments start with ###
2090 if (/^###\s/) {
2091   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2092     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2093     say {$fh} $_;
2094   }
2095   return 0;
2096 }
2097
2098 # The "echo" command is a way of writing comments to the screen.
2099 if (/^echo\s+(.*)$/)
2100   {
2101   print "$1\n";
2102   return 0;
2103   }
2104
2105
2106 # The "exim_lock" command runs exim_lock in the same manner as "server",
2107 # but it doesn't use any input.
2108
2109 if (/^exim_lock\s+(.*)$/)
2110   {
2111   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2112   $server_pid = open SERVERCMD, "|$cmd" ||
2113     tests_exit(-1, "Failed to run $cmd\n");
2114
2115   # This gives the process time to get started; otherwise the next
2116   # process may not find it there when it expects it.
2117
2118   select(undef, undef, undef, 0.1);
2119   return 3;
2120   }
2121
2122
2123 # The "exinext" command runs exinext
2124
2125 if (/^exinext\s+(.*)/)
2126   {
2127   run_system("(./eximdir/exinext " .
2128     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2129     "-C $parm_cwd/test-config $1;" .
2130     "echo exinext exit code = \$?)" .
2131     ">>test-stdout");
2132   return 1;
2133   }
2134
2135
2136 # The "exigrep" command runs exigrep on the current mainlog
2137
2138 if (/^exigrep\s+(.*)/)
2139   {
2140   run_system("(./eximdir/exigrep " .
2141     "$1 $parm_cwd/spool/log/mainlog;" .
2142     "echo exigrep exit code = \$?)" .
2143     ">>test-stdout");
2144   return 1;
2145   }
2146
2147
2148 # The "eximstats" command runs eximstats on the current mainlog
2149
2150 if (/^eximstats\s+(.*)/)
2151   {
2152   run_system("(./eximdir/eximstats " .
2153     "$1 $parm_cwd/spool/log/mainlog;" .
2154     "echo eximstats exit code = \$?)" .
2155     ">>test-stdout");
2156   return 1;
2157   }
2158
2159
2160 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2161 # spool directory, to save Exim from re-creating it each time.
2162
2163 if (/^gnutls/)
2164   {
2165   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2166   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2167          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2168          "sudo chmod 0400 $gen_fn";
2169   return 1;
2170   }
2171
2172
2173 # The "killdaemon" command should ultimately follow the starting of any Exim
2174 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2175 # it outputting "Terminated" to the terminal when not in the background.
2176
2177 if (/^killdaemon/)
2178   {
2179   my $return_extra = {};
2180   if (exists $aux_info->{exim_pid})
2181     {
2182     $pid = $aux_info->{exim_pid};
2183     $return_extra->{exim_pid} = undef;
2184     print ">> killdaemon: recovered pid $pid\n" if $debug;
2185     if ($pid)
2186       {
2187       run_system("sudo /bin/kill -INT $pid");
2188       wait;
2189       }
2190     } else {
2191     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2192     if ($pid)
2193       {
2194       run_system("sudo /bin/kill -INT $pid");
2195       close DAEMONCMD;                                   # Waits for process
2196       }
2197     }
2198     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2199   return (1, $return_extra);
2200   }
2201
2202
2203 # The "millisleep" command is like "sleep" except that its argument is in
2204 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2205 # is used for.
2206
2207 elsif (/^millisleep\s+(.*)$/)
2208   {
2209   select(undef, undef, undef, $1/1000);
2210   return 0;
2211   }
2212
2213
2214 # The "munge" command selects one of a hardwired set of test-result modifications
2215 # to be made before result compares are run against the golden set.  This lets
2216 # us account for test-system dependent things which only affect a few, but known,
2217 # test-cases.
2218 # Currently only the last munge takes effect.
2219
2220 if (/^munge\s+(.*)$/)
2221   {
2222   return (0, { munge => $1 });
2223   }
2224
2225
2226 # The "sleep" command does just that. For sleeps longer than 1 second we
2227 # tell the user what's going on.
2228
2229 if (/^sleep\s+(.*)$/)
2230   {
2231   if ($1 == 1)
2232     {
2233     sleep(1);
2234     }
2235   else
2236     {
2237     printf("  Test %d sleep $1 ", $$subtestref);
2238     for (1..$1)
2239       {
2240       print ".";
2241       sleep(1);
2242       }
2243     printf("\r  Test %d                            $cr", $$subtestref);
2244     }
2245   return 0;
2246   }
2247
2248
2249 # Various Unix management commands are recognized
2250
2251 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2252     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2253   {
2254   run_system("$_ >>test-stdout 2>>test-stderr");
2255   return 1;
2256   }
2257
2258
2259
2260 ###################
2261 ###################
2262
2263 # The next group of commands are also freestanding, but they are all followed
2264 # by data lines.
2265
2266
2267 # The "server" command starts up a script-driven server that runs in parallel
2268 # with the following exim command. Therefore, we want to run a subprocess and
2269 # not yet wait for it to complete. The waiting happens after the next exim
2270 # command, triggered by $server_pid being non-zero. The server sends its output
2271 # to a different file. The variable $server_opts, if not empty, contains
2272 # options to disable IPv4 or IPv6 if necessary.
2273 # This works because "server" swallows its stdin before waiting for a connection.
2274
2275 if (/^server\s+(.*)$/)
2276   {
2277   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2278   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2279   print ">> $cmd\n" if ($debug);
2280   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2281   SERVERCMD->autoflush(1);
2282   print ">> Server pid is $server_pid\n" if $debug;
2283   while (<SCRIPT>)
2284     {
2285     $lineno++;
2286     last if /^\*{4}\s*$/;
2287     print SERVERCMD;
2288     }
2289   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2290                             # because close() waits for the process.
2291
2292   # Interlock the server startup; otherwise the next
2293   # process may not find it there when it expects it.
2294   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2295   return 3;
2296   }
2297
2298
2299 # The "write" command is a way of creating files of specific sizes for
2300 # buffering tests, or containing specific data lines from within the script
2301 # (rather than hold lots of little files). The "catwrite" command does the
2302 # same, but it also copies the lines to test-stdout.
2303
2304 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2305   {
2306   my($cat) = defined $1;
2307   @sizes = ();
2308   @sizes = split /\s+/, $3 if defined $3;
2309   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2310
2311   if ($cat)
2312     {
2313     open CAT, ">>test-stdout" ||
2314       tests_exit(-1, "Failed to open test-stdout: $!");
2315     print CAT "==========\n";
2316     }
2317
2318   if (scalar @sizes > 0)
2319     {
2320     # Pre-data
2321
2322     while (<SCRIPT>)
2323       {
2324       $lineno++;
2325       last if /^\+{4}\s*$/;
2326       print FILE;
2327       print CAT if $cat;
2328       }
2329
2330     # Sized data
2331
2332     while (scalar @sizes > 0)
2333       {
2334       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2335       $leadin = '' if !defined $leadin;
2336       $leadin =~ s/_/ /g;
2337       $len -= length($leadin) + 1;
2338       while ($count-- > 0)
2339         {
2340         print FILE $leadin, "a" x $len, "\n";
2341         print CAT $leadin, "a" x $len, "\n" if $cat;
2342         }
2343       }
2344     }
2345
2346   # Post data, or only data if no sized data
2347
2348   while (<SCRIPT>)
2349     {
2350     $lineno++;
2351     last if /^\*{4}\s*$/;
2352     print FILE;
2353     print CAT if $cat;
2354     }
2355   close FILE;
2356
2357   if ($cat)
2358     {
2359     print CAT "==========\n";
2360     close CAT;
2361     }
2362
2363   return 0;
2364   }
2365
2366
2367 ###################
2368 ###################
2369
2370 # From this point on, script commands are implemented by setting up a shell
2371 # command in the variable $cmd. Shared code to run this command and handle its
2372 # input and output follows.
2373
2374 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2375 # program that plays the part of an email client. We also have the availability
2376 # of running Perl for doing one-off special things. Note that all these
2377 # commands expect stdin data to be supplied.
2378
2379 if (/^client/ || /^(sudo\s+)?perl\b/)
2380   {
2381   s"client"./bin/client";
2382   $cmd = "$_ >>test-stdout 2>>test-stderr";
2383   }
2384
2385 # For the "exim" command, replace the text "exim" with the path for the test
2386 # binary, plus -D options to pass over various parameters, and a -C option for
2387 # the testing configuration file. When running in the test harness, Exim does
2388 # not drop privilege when -C and -D options are present. To run the exim
2389 # command as root, we use sudo.
2390
2391 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2392   {
2393   $args = $6;
2394   my($envset) = (defined $1)? $1      : '';
2395   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2396   my($special)= (defined $5)? $5      : '';
2397   $wait_time  = (defined $2)? $2      : 0;
2398
2399   # Return 2 rather than 1 afterwards
2400
2401   $yield = 2;
2402
2403   # Update the test number
2404
2405   $$subtestref = $$subtestref + 1;
2406   printf("  Test %d       $cr", $$subtestref);
2407
2408   # Copy the configuration file, making the usual substitutions.
2409
2410   open (IN, "$parm_cwd/confs/$testno") ||
2411     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2412   open (OUT, ">test-config") ||
2413     tests_exit(-1, "Couldn't open test-config: $!\n");
2414   while (<IN>)
2415     {
2416     do_substitute($testno);
2417     print OUT;
2418     }
2419   close(IN);
2420   close(OUT);
2421
2422   # The string $msg1 in args substitutes the message id of the first
2423   # message on the queue, and so on. */
2424
2425   if ($args =~ /\$msg/)
2426     {
2427     my @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2428                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2429                    -C => "$parm_cwd/test-config");
2430     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2431     # We need the message ids sorted in ascending order.
2432     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2433     # PIDs are randomized, so sorting just the whole PID doesn't work.
2434     # We do the Schartz' transformation here (sort on
2435     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2436     my @msglist =
2437       map { $_->[1] }                                   # extract the values
2438       sort { $a->[0] cmp $b->[0] }                      # sort by key
2439       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2440       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2441
2442     # Done backwards just in case there are more than 9
2443
2444     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2445     if ( $args =~ /\$msg\d/ )
2446       {
2447       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2448         unless $force_continue;
2449       }
2450     }
2451
2452   # If -d is specified in $optargs, remove it from $args; i.e. let
2453   # the command line for runtest override. Then run Exim.
2454
2455   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2456
2457   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2458
2459   $cmd = "$envset$sudo$opt_valgrind" .
2460          "$parm_cwd/eximdir/exim$special$optargs " .
2461          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2462          "-C $parm_cwd/test-config $args " .
2463          ">>test-stdout 2>>test-stderr";
2464   # If the command is starting an Exim daemon, we run it in the same
2465   # way as the "server" command above, that is, we don't want to wait
2466   # for the process to finish. That happens when "killdaemon" is obeyed later
2467   # in the script. We also send the stderr output to test-stderr-server. The
2468   # daemon has its log files put in a different place too (by configuring with
2469   # log_file_path). This requires the  directory to be set up in advance.
2470   #
2471   # There are also times when we want to run a non-daemon version of Exim
2472   # (e.g. a queue runner) with the server configuration. In this case,
2473   # we also define -DNOTDAEMON.
2474
2475   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2476     {
2477     if ($debug) { printf ">> daemon: $cmd\n"; }
2478     run_system("sudo mkdir spool/log 2>/dev/null");
2479     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2480
2481     # Before running the command, convert the -bd option into -bdf so that an
2482     # Exim daemon doesn't double fork. This means that when we wait close
2483     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2484     # file is written to the spool directory, in case the Exim binary was
2485     # built with PID_FILE_PATH pointing somewhere else.
2486
2487     if ($cmd =~ /\s-oP\s/)
2488       {
2489       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2490       $cmd =~ s!\s-bd\s! -bdf !;
2491       }
2492     else
2493       {
2494       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2495       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2496       }
2497     print ">> |${cmd}-server\n" if ($debug);
2498     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2499     DAEMONCMD->autoflush(1);
2500     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2501
2502     # Interlock with daemon startup
2503     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2504       { select(undef, undef, undef, 0.3); }
2505     return 3;                                     # Don't wait
2506     }
2507   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2508     {
2509
2510     # The port and the $dynamic_socket was already allocated while parsing the
2511     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2512
2513     my $listen_port = $1;
2514     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2515     run_system("sudo mkdir spool/log 2>/dev/null");
2516     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2517
2518     my $pid = fork();
2519     if (not defined $pid) { die "** fork failed: $!\n" }
2520     if (not $pid) {
2521       close(STDIN);
2522       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2523       close($dynamic_socket);
2524       print "[$$]>> ${cmd}-server\n" if ($debug);
2525       exec "exec ${cmd}-server";
2526       die "Can't exec ${cmd}-server: $!\n";
2527     }
2528     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2529     select(undef, undef, undef, 0.3);             # Let the daemon get going
2530     return (3, { exim_pid => $pid });             # Don't wait
2531     }
2532   }
2533
2534 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2535 # One script line is read and fork-exec'd.  The PID is stored for a later
2536 # killdaemon.
2537
2538 elsif (/^background$/)
2539   {
2540   my $line;
2541 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2542
2543   $_ = <SCRIPT>; $lineno++;
2544   chomp;
2545   do_substitute($testno);
2546   $line = $_;
2547   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2548
2549   my $pid = fork();
2550   if (not defined $pid) { die "** fork failed: $!\n" }
2551   if (not $pid) {
2552     print "[$$]>> ${line}\n" if ($debug);
2553     close(STDIN);
2554     open(STDIN, "<", "test-stdout");
2555     close(STDOUT);
2556     open(STDOUT, ">>", "test-stdout");
2557     close(STDERR);
2558     open(STDERR, ">>", "test-stderr-server");
2559     exec "exec ${line}";
2560     exit(1);
2561   }
2562
2563 #  open(my $fh, ">", $pidfile) ||
2564 #      tests_exit(-1, "Failed to open $pidfile: $!");
2565 #  printf($fh, "%d\n", $pid);
2566 #  close($fh);
2567
2568   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2569   select(undef, undef, undef, 0.3);             # Let the daemon get going
2570   return (3, { exim_pid => $pid });             # Don't wait
2571   }
2572
2573
2574
2575 # Unknown command
2576
2577 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2578
2579
2580 # Run the command, with stdin connected to a pipe, and write the stdin data
2581 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2582 # the terminating newline (and the \NONL\). If the command contains
2583 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2584 # for the stderr file. See comment above about the use of -DSERVER.
2585
2586 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2587 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2588 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2589
2590 CMD->autoflush(1);
2591 while (<SCRIPT>)
2592   {
2593   $lineno++;
2594   last if /^\*{4}\s*$/;
2595   do_substitute($testno);
2596   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2597   }
2598
2599 # For timeout tests, wait before closing the pipe; we expect a
2600 # SIGPIPE error in this case.
2601
2602 if ($wait_time > 0)
2603   {
2604   printf("  Test %d sleep $wait_time ", $$subtestref);
2605   while ($wait_time-- > 0)
2606     {
2607     print ".";
2608     sleep(1);
2609     }
2610   printf("\r  Test %d                                       $cr", $$subtestref);
2611   }
2612
2613 $sigpipehappened = 0;
2614 close CMD;                # Waits for command to finish
2615 return $yield;            # Ran command and waited
2616 }
2617
2618
2619
2620
2621 ###############################################################################
2622 ###############################################################################
2623
2624 # Here begins the Main Program ...
2625
2626 ###############################################################################
2627 ###############################################################################
2628
2629
2630 autoflush STDOUT 1;
2631 print "Exim tester $testversion\n";
2632
2633 # extend the PATH with .../sbin
2634 # we map all (.../bin) to (.../sbin:.../bin)
2635 $ENV{PATH} = do {
2636   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2637   join ':' => map { m{(.*)/bin$}
2638                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2639                 : ($_) }
2640       split /:/, $ENV{PATH};
2641 };
2642
2643 ##################################################
2644 #      Some tests check created file modes       #
2645 ##################################################
2646
2647 umask 022;
2648
2649
2650 ##################################################
2651 #       Check for the "less" command             #
2652 ##################################################
2653
2654 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2655
2656
2657
2658 ##################################################
2659 #      See if an Exim binary has been given      #
2660 ##################################################
2661
2662 # If the first character of the first argument is '/', the argument is taken
2663 # as the path to the binary. If the first argument does not start with a
2664 # '/' but exists in the file system, it's assumed to be the Exim binary.
2665
2666
2667 ##################################################
2668 # Sort out options and which tests are to be run #
2669 ##################################################
2670
2671 # There are a few possible options for the test script itself; after these, any
2672 # options are passed on to Exim calls within the tests. Typically, this is used
2673 # to turn on Exim debugging while setting up a test.
2674
2675 Getopt::Long::Configure qw(no_getopt_compat);
2676 GetOptions(
2677     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2678     'diff'     => sub { $cf             = 'diff -u' },
2679     'continue' => sub { $force_continue = 1; $more = 'cat' },
2680     'update'   => \$force_update,
2681     'ipv4!'    => \$have_ipv4,
2682     'ipv6!'    => \$have_ipv6,
2683     'keep'     => \$save_output,
2684     'slow'     => \$slow,
2685     'valgrind' => \$valgrind,
2686     'range=s{2}'       => \my @range_wanted,
2687     'test=i@'          => \my @tests_wanted,
2688     'flavor|flavour=s' => \$flavour,
2689     'help'             => sub { pod2usage(-exit => 0) },
2690     'man'              => sub {
2691         pod2usage(
2692             -exit      => 0,
2693             -verbose   => 2,
2694             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2695         );
2696     },
2697 ) or pod2usage;
2698
2699 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2700 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2701
2702
2703 my @wanted = sort numerically uniq
2704   @tests_wanted ? @tests_wanted : (),
2705   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
2706   @ARGV ? @ARGV == 1 ? $ARGV[0] :
2707           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
2708           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
2709         : ();
2710 @wanted = 1..TEST_TOP if not @wanted;
2711
2712 ##################################################
2713 #        Check for sudo access to root           #
2714 ##################################################
2715
2716 print "You need to have sudo access to root to run these tests. Checking ...\n";
2717 if (system('sudo true >/dev/null') != 0)
2718   {
2719   die "** Test for sudo failed: testing abandoned.\n";
2720   }
2721 else
2722   {
2723   print "Test for sudo OK\n";
2724   }
2725
2726
2727
2728
2729 ##################################################
2730 #      Make the command's directory current      #
2731 ##################################################
2732
2733 # After doing so, we find its absolute path name.
2734
2735 $cwd = $0;
2736 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2737 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2738 $parm_cwd = Cwd::getcwd();
2739
2740
2741 ##################################################
2742 #     Search for an Exim binary to test          #
2743 ##################################################
2744
2745 # If an Exim binary hasn't been provided, try to find one. We can handle the
2746 # case where exim-testsuite is installed alongside Exim source directories. For
2747 # PH's private convenience, if there's a directory just called "exim4", that
2748 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2749 # releases.
2750
2751 # If $parm_exim is still empty, ask the caller
2752
2753 if (not $parm_exim)
2754   {
2755   print "** Did not find an Exim binary to test\n";
2756   for ($i = 0; $i < 5; $i++)
2757     {
2758     my($trybin);
2759     print "** Enter pathname for Exim binary: ";
2760     chomp($trybin = <STDIN>);
2761     if (-e $trybin)
2762       {
2763       $parm_exim = $trybin;
2764       last;
2765       }
2766     else
2767       {
2768       print "** $trybin does not exist\n";
2769       }
2770     }
2771   die "** Too many tries\n" if $parm_exim eq '';
2772   }
2773
2774
2775
2776 ##################################################
2777 #          Find what is in the binary            #
2778 ##################################################
2779
2780 # deal with TRUSTED_CONFIG_LIST restrictions
2781 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2782 open (IN, "$parm_cwd/confs/0000") ||
2783   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2784 open (OUT, ">test-config") ||
2785   tests_exit(-1, "Couldn't open test-config: $!\n");
2786 while (<IN>) { print OUT; }
2787 close(IN);
2788 close(OUT);
2789
2790 print("Probing with config file: $parm_cwd/test-config\n");
2791
2792 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2793 chomp(my @eximinfo = `$eximinfo 2>&1`);
2794 die "$0: Can't run $eximinfo\n" if $? == -1;
2795
2796 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2797 foreach (@eximinfo)
2798   {
2799   if (my ($version) = /^Exim version (\S+)/) {
2800     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2801     if (defined $git and $? == 0) {
2802       chomp $git;
2803       $version =~ s/^\d+\K\./_/;
2804       $git =~ s/^exim-//i;
2805       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2806       print <<___
2807
2808 *** Version mismatch
2809 *** Exim binary: $version
2810 *** Git        : $git
2811
2812 ___
2813         if not $version eq $git;
2814     }
2815   }
2816   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2817   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2818   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2819   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2820         if /^Configure owner:\s*(\d+):(\d+)/;
2821   print if /wrong owner/;
2822   }
2823
2824 if (not defined $parm_eximuser) {
2825   die <<XXX, map { "|$_\n" } @eximinfo;
2826 Unable to extract exim_user from binary.
2827 Check if Exim refused to run; if so, consider:
2828   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2829 If debug permission denied, are you in the exim group?
2830 Failing to get information from binary.
2831 Output from $eximinfo:
2832 XXX
2833
2834 }
2835
2836 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2837 else { $parm_exim_uid = getpwnam($parm_eximuser); }
2838
2839 if (defined $parm_eximgroup)
2840   {
2841   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2842     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2843   }
2844
2845 # check the permissions on the TRUSTED_CONFIG_LIST
2846 if (defined $parm_trusted_config_list)
2847   {
2848   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2849     if not -f $parm_trusted_config_list;
2850
2851   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2852     if 02 & (stat _)[2];
2853
2854   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2855   (stat _)[1],
2856     scalar(getgrgid 0), scalar(getgrgid $>)
2857     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2858
2859   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2860   scalar(getpwuid 0), scalar(getpwuid $>)
2861      if (not (-o _ or (stat _)[4] == 0));
2862
2863   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2864   my $test_config = getcwd() . '/test-config';
2865   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2866   if not grep { /^\Q$test_config\E$/ } <TCL>;
2867   }
2868 else
2869   {
2870   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2871   }
2872
2873 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2874         if $parm_configure_owner != $>;
2875
2876 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2877         if 0020 & (stat "$parm_cwd/test-config")[2]
2878         and $parm_configure_group != $);
2879
2880 die "aux-fixed file is world-writeable; best to strip them all, recursively\n"
2881         if 0020 & (stat "aux-fixed/0037.f-1")[2];
2882
2883
2884 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2885   die "** Cannot run $parm_exim: $!\n";
2886
2887 print "-" x 78, "\n";
2888
2889 while (<EXIMINFO>)
2890   {
2891   my(@temp);
2892
2893   if (/^(Exim|Library) version/) { print; }
2894   if (/Runtime: /) {print; }
2895
2896   elsif (/^Size of off_t: (\d+)/)
2897     {
2898     print;
2899     $have_largefiles = 1 if $1 > 4;
2900     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2901         if ($1 > 32);
2902     }
2903
2904   elsif (/^Support for: (.*)/)
2905     {
2906     print;
2907     @temp = split /(\s+)/, $1;
2908     push(@temp, ' ');
2909     %parm_support = @temp;
2910     }
2911
2912   elsif (/^Lookups \(built-in\): (.*)/)
2913     {
2914     print;
2915     @temp = split /(\s+)/, $1;
2916     push(@temp, ' ');
2917     %parm_lookups = @temp;
2918     }
2919
2920   elsif (/^Authenticators: (.*)/)
2921     {
2922     print;
2923     @temp = split /(\s+)/, $1;
2924     push(@temp, ' ');
2925     %parm_authenticators = @temp;
2926     }
2927
2928   elsif (/^Routers: (.*)/)
2929     {
2930     print;
2931     @temp = split /(\s+)/, $1;
2932     push(@temp, ' ');
2933     %parm_routers = @temp;
2934     }
2935
2936   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2937   # that the basic transport name is set, and then the name with each of the
2938   # options.
2939
2940   elsif (/^Transports: (.*)/)
2941     {
2942     print;
2943     @temp = split /(\s+)/, $1;
2944     my($i,$k);
2945     push(@temp, ' ');
2946     %parm_transports = @temp;
2947     foreach $k (keys %parm_transports)
2948       {
2949       if ($k =~ "/")
2950         {
2951         @temp = split /\//, $k;
2952         $parm_transports{$temp[0]} = " ";
2953         for ($i = 1; $i < @temp; $i++)
2954           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2955         }
2956       }
2957     }
2958
2959   elsif (/^Malware: (.*)/)
2960     {
2961     print;
2962     @temp = split /(\s+)/, $1;
2963     push(@temp, ' ');
2964     %parm_malware = @temp;
2965     }
2966
2967   }
2968 close(EXIMINFO);
2969 print "-" x 78, "\n";
2970
2971 unlink("$parm_cwd/test-config");
2972
2973 ##################################################
2974 #    Check for SpamAssassin and ClamAV           #
2975 ##################################################
2976
2977 # These are crude tests. If they aren't good enough, we'll have to improve
2978 # them, for example by actually passing a message through spamc or clamscan.
2979
2980 if (defined $parm_support{Content_Scanning})
2981   {
2982   my $sock = new FileHandle;
2983
2984   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2985     {
2986     print "The spamc command works:\n";
2987
2988     # This test for an active SpamAssassin is courtesy of John Jetmore.
2989     # The tests are hard coded to localhost:783, so no point in making
2990     # this test flexible like the clamav test until the test scripts are
2991     # changed.  spamd doesn't have the nice PING/PONG protocol that
2992     # clamd does, but it does respond to errors in an informative manner,
2993     # so use that.
2994
2995     my($sint,$sport) = ('127.0.0.1',783);
2996     eval
2997       {
2998       my $sin = sockaddr_in($sport, inet_aton($sint))
2999           or die "** Failed packing $sint:$sport\n";
3000       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3001           or die "** Unable to open socket $sint:$sport\n";
3002
3003       local $SIG{ALRM} =
3004           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3005       alarm(5);
3006       connect($sock, $sin)
3007           or die "** Unable to connect to socket $sint:$sport\n";
3008       alarm(0);
3009
3010       select((select($sock), $| = 1)[0]);
3011       print $sock "bad command\r\n";
3012
3013       $SIG{ALRM} =
3014           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3015       alarm(10);
3016       my $res = <$sock>;
3017       alarm(0);
3018
3019       $res =~ m|^SPAMD/|
3020           or die "** Did not get SPAMD from socket $sint:$sport. "
3021                 ."It said: $res\n";
3022       };
3023     alarm(0);
3024     if($@)
3025       {
3026       print "  $@";
3027       print "  Assume SpamAssassin (spamd) is not running\n";
3028       }
3029     else
3030       {
3031       $parm_running{SpamAssassin} = ' ';
3032       print "  SpamAssassin (spamd) seems to be running\n";
3033       }
3034     }
3035   else
3036     {
3037     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3038     }
3039
3040   # For ClamAV, we need to find the clamd socket for use in the Exim
3041   # configuration. Search for the clamd configuration file.
3042
3043   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3044     {
3045     my($f, $clamconf, $test_prefix);
3046
3047     print "The clamscan command works";
3048
3049     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3050     $test_prefix = '' if !defined $test_prefix;
3051
3052     foreach $f ("$test_prefix/etc/clamd.conf",
3053                 "$test_prefix/usr/local/etc/clamd.conf",
3054                 "$test_prefix/etc/clamav/clamd.conf", '')
3055       {
3056       if (-e $f)
3057         {
3058         $clamconf = $f;
3059         last;
3060         }
3061       }
3062
3063     # Read the ClamAV configuration file and find the socket interface.
3064
3065     if ($clamconf ne '')
3066       {
3067       my $socket_domain;
3068       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3069       while (<IN>)
3070         {
3071         if (/^LocalSocket\s+(.*)/)
3072           {
3073           $parm_clamsocket = $1;
3074           $socket_domain = AF_UNIX;
3075           last;
3076           }
3077         if (/^TCPSocket\s+(\d+)/)
3078           {
3079           if (defined $parm_clamsocket)
3080             {
3081             $parm_clamsocket .= " $1";
3082             $socket_domain = AF_INET;
3083             last;
3084             }
3085           else
3086             {
3087             $parm_clamsocket = " $1";
3088             }
3089           }
3090         elsif (/^TCPAddr\s+(\S+)/)
3091           {
3092           if (defined $parm_clamsocket)
3093             {
3094             $parm_clamsocket = $1 . $parm_clamsocket;
3095             $socket_domain = AF_INET;
3096             last;
3097             }
3098           else
3099             {
3100             $parm_clamsocket = $1;
3101             }
3102           }
3103         }
3104       close(IN);
3105
3106       if (defined $socket_domain)
3107         {
3108         print ":\n  The clamd socket is $parm_clamsocket\n";
3109         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3110         eval
3111           {
3112           my $socket;
3113           if ($socket_domain == AF_UNIX)
3114             {
3115             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3116             }
3117           elsif ($socket_domain == AF_INET)
3118             {
3119             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3120             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3121             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3122             }
3123           else
3124             {
3125             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3126             }
3127           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3128           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3129           alarm(5);
3130           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3131           alarm(0);
3132
3133           my $ofh = select $sock; $| = 1; select $ofh;
3134           print $sock "PING\n";
3135
3136           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3137           alarm(10);
3138           my $res = <$sock>;
3139           alarm(0);
3140
3141           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3142           };
3143         alarm(0);
3144
3145         if($@)
3146           {
3147           print "  $@";
3148           print "  Assume ClamAV is not running\n";
3149           }
3150         else
3151           {
3152           $parm_running{ClamAV} = ' ';
3153           print "  ClamAV seems to be running\n";
3154           }
3155         }
3156       else
3157         {
3158         print ", but the socket for clamd could not be determined\n";
3159         print "Assume ClamAV is not running\n";
3160         }
3161       }
3162
3163     else
3164       {
3165       print ", but I can't find a configuration for clamd\n";
3166       print "Assume ClamAV is not running\n";
3167       }
3168     }
3169   }
3170
3171
3172 ##################################################
3173 #       Check for redis                          #
3174 ##################################################
3175 if (defined $parm_lookups{redis})
3176   {
3177   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3178     {
3179     print "The redis-server command works\n";
3180     $parm_running{redis} = ' ';
3181     }
3182   else
3183     {
3184     print "The redis-server command failed: assume Redis not installed\n";
3185     }
3186   }
3187
3188 ##################################################
3189 #         Test for the basic requirements        #
3190 ##################################################
3191
3192 # This test suite assumes that Exim has been built with at least the "usual"
3193 # set of routers, transports, and lookups. Ensure that this is so.
3194
3195 $missing = '';
3196
3197 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3198
3199 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3200 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3201 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3202 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3203
3204 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3205 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3206 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3207 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3208
3209 if ($missing ne '')
3210   {
3211   print "\n";
3212   print "** Many features can be included or excluded from Exim binaries.\n";
3213   print "** This test suite requires that Exim is built to contain a certain\n";
3214   print "** set of basic facilities. It seems that some of these are missing\n";
3215   print "** from the binary that is under test, so the test cannot proceed.\n";
3216   print "** The missing facilities are:\n";
3217   print "$missing";
3218   die "** Test script abandoned\n";
3219   }
3220
3221
3222 ##################################################
3223 #      Check for the auxiliary programs          #
3224 ##################################################
3225
3226 # These are always required:
3227
3228 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3229            "fakens", "iefbr14", "server")
3230   {
3231   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3232   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3233   if (!-e "bin/$prog")
3234     {
3235     print "\n";
3236     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3237     die "** Test script abandoned\n";
3238     }
3239   }
3240
3241 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3242 # compiled on systems where we don't know how to. However, if Exim does not
3243 # have that functionality compiled, we needn't bother.
3244
3245 $dlfunc_deleted = 0;
3246 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3247   {
3248   delete $parm_support{Expand_dlfunc};
3249   $dlfunc_deleted = 1;
3250   }
3251
3252
3253 ##################################################
3254 #          Find environmental details            #
3255 ##################################################
3256
3257 # Find the caller of this program.
3258
3259 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3260  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3261
3262 $pwpw = $pwpw;       # Kill Perl warnings
3263 $pwquota = $pwquota;
3264 $pwcomm = $pwcomm;
3265
3266 $parm_caller_group = getgrgid($parm_caller_gid);
3267
3268 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3269 print "Home directory is $parm_caller_home\n";
3270
3271 unless (defined $parm_eximgroup)
3272   {
3273   print "Unable to derive \$parm_eximgroup.\n";
3274   die "** ABANDONING.\n";
3275   }
3276
3277 if ($parm_caller_home eq $parm_cwd)
3278   {
3279   print "will confuse working dir with homedir; change homedir\n";
3280   die "** ABANDONING.\n";
3281   }
3282
3283 print "You need to be in the Exim group to run these tests. Checking ...";
3284
3285 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3286   {
3287   print " OK\n";
3288   }
3289 else
3290   {
3291   print "\nOh dear, you are not in the Exim group.\n";
3292   die "** Testing abandoned.\n";
3293   }
3294
3295 # Find this host's IP addresses - there may be many, of course, but we keep
3296 # one of each type (IPv4 and IPv6).
3297
3298 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3299   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3300 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3301   {
3302   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3303     {
3304     next if $1 =~ /^(?:127|10)\./;
3305     $parm_ipv4 = $1;
3306     }
3307
3308   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3309     {
3310     next if $1 eq '::1' or $1 =~ /^fe80/i;
3311     $parm_ipv6 = $1;
3312     }
3313   }
3314 close(IFCONFIG);
3315
3316 # Use private IP addresses if there are no public ones.
3317
3318 # If either type of IP address is missing, we need to set the value to
3319 # something other than empty, because that wrecks the substitutions. The value
3320 # is reflected, so use a meaningful string. Set appropriate options for the
3321 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3322 # available, so things will go wrong if there is no IPv4 address. The lack
3323 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3324 # and $have_ipv6 false.
3325
3326 if (not $parm_ipv4)
3327   {
3328   $have_ipv4 = 0;
3329   $parm_ipv4 = "<no IPv4 address found>";
3330   $server_opts .= " -noipv4";
3331   }
3332 elsif ($have_ipv4 == 0)
3333   {
3334   $parm_ipv4 = "<IPv4 testing disabled>";
3335   $server_opts .= " -noipv4";
3336   }
3337 else
3338   {
3339   $parm_running{IPv4} = " ";
3340   }
3341
3342 if (not $parm_ipv6)
3343   {
3344   $have_ipv6 = 0;
3345   $parm_ipv6 = "<no IPv6 address found>";
3346   $server_opts .= " -noipv6";
3347   delete($parm_support{IPv6});
3348   }
3349 elsif ($have_ipv6 == 0)
3350   {
3351   $parm_ipv6 = "<IPv6 testing disabled>";
3352   $server_opts .= " -noipv6";
3353   delete($parm_support{IPv6});
3354   }
3355 elsif (!defined $parm_support{IPv6})
3356   {
3357   $have_ipv6 = 0;
3358   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3359   $server_opts .= " -noipv6";
3360   }
3361 else
3362   {
3363   $parm_running{IPv6} = " ";
3364   }
3365
3366 print "IPv4 address is $parm_ipv4\n";
3367 print "IPv6 address is $parm_ipv6\n";
3368
3369 # For munging test output, we need the reversed IP addresses.
3370
3371 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3372   join(".", reverse(split /\./, $parm_ipv4));
3373
3374 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3375 if ($parm_ipv6 =~ /^[\da-f]/)
3376   {
3377   my(@comps) = split /:/, $parm_ipv6;
3378   my(@nibbles);
3379   foreach $comp (@comps)
3380     {
3381     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3382     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3383     }
3384   $parm_ipv6r = join(".", reverse(@nibbles));
3385   }
3386
3387 # Find the host name, fully qualified.
3388
3389 chomp($temp = `hostname`);
3390 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3391 if ($temp =~ /\./)
3392   {
3393   $parm_hostname = $temp;
3394   }
3395 else
3396   {
3397   $parm_hostname = (gethostbyname($temp))[0];
3398   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3399   }
3400 print "Hostname is $parm_hostname\n";
3401
3402 if ($parm_hostname !~ /\./)
3403   {
3404   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3405   }
3406
3407 if ($parm_hostname =~ /[[:upper:]]/)
3408   {
3409   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3410   }
3411
3412 if ($parm_hostname =~ /\.example\.com$/)
3413   {
3414   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3415         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3416   }
3417
3418
3419
3420 ##################################################
3421 #     Create a testing version of Exim           #
3422 ##################################################
3423
3424 # We want to be able to run Exim with a variety of configurations. Normally,
3425 # the use of -C to change configuration causes Exim to give up its root
3426 # privilege (unless the caller is exim or root). For these tests, we do not
3427 # want this to happen. Also, we want Exim to know that it is running in its
3428 # test harness.
3429
3430 # We achieve this by copying the binary and patching it as we go. The new
3431 # binary knows it is a testing copy, and it allows -C and -D without loss of
3432 # privilege. Clearly, this file is dangerous to have lying around on systems
3433 # where there are general users with login accounts. To protect against this,
3434 # we put the new binary in a special directory that is accessible only to the
3435 # caller of this script, who is known to have sudo root privilege from the test
3436 # that was done above. Furthermore, we ensure that the binary is deleted at the
3437 # end of the test. First ensure the directory exists.
3438
3439 if (-d "eximdir")
3440   { unlink "eximdir/exim"; }     # Just in case
3441 else
3442   {
3443   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3444   system("sudo chgrp $parm_eximgroup eximdir");
3445   }
3446
3447 # The construction of the patched binary must be done as root, so we use
3448 # a separate script. As well as indicating that this is a test-harness binary,
3449 # the version number is patched to "x.yz" so that its length is always the
3450 # same. Otherwise, when it appears in Received: headers, it affects the length
3451 # of the message, which breaks certain comparisons.
3452
3453 die "** Unable to make patched exim: $!\n"
3454   if (system("sudo ./patchexim $parm_exim") != 0);
3455
3456 # From this point on, exits from the program must go via the subroutine
3457 # tests_exit(), so that suitable cleaning up can be done when required.
3458 # Arrange to catch interrupting signals, to assist with this.
3459
3460 $SIG{INT} = \&inthandler;
3461 $SIG{PIPE} = \&pipehandler;
3462
3463 # For some tests, we need another copy of the binary that is setuid exim rather
3464 # than root.
3465
3466 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3467        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3468        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3469        "sudo chmod 06755 eximdir/exim_exim");
3470
3471 ##################################################
3472 #     Make copies of utilities we might need     #
3473 ##################################################
3474
3475 # Certain of the tests make use of some of Exim's utilities. We do not need
3476 # to be root to copy these.
3477
3478 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3479
3480 $dbm_build_deleted = 0;
3481 if (defined $parm_lookups{dbm} &&
3482     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3483   {
3484   delete $parm_lookups{dbm};
3485   $dbm_build_deleted = 1;
3486   }
3487
3488 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3489   {
3490   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3491   }
3492
3493 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3494   {
3495   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3496   }
3497
3498 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3499   {
3500   tests_exit(-1, "Failed to make a copy of exinext: $!");
3501   }
3502
3503 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3504   {
3505   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3506   }
3507
3508 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3509   {
3510   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3511   }
3512
3513 # Collect some version information
3514 print '-' x 78, "\n";
3515 print "Perl version for runtest: $]\n";
3516 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3517   # fold (or unfold?) multiline output into a one-liner
3518   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3519 }
3520 print '-' x 78, "\n";
3521
3522
3523 ##################################################
3524 #    Check that the Exim user can access stuff   #
3525 ##################################################
3526
3527 # We delay this test till here so that we can check access to the actual test
3528 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3529
3530 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3531 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3532
3533 if ($parm_caller_uid eq $parm_exim_uid) {
3534   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3535                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3536 }
3537 if ($parm_caller_gid eq $parm_exim_gid) {
3538   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3539                 ."the same as caller's ($parm_caller) group as it confuses "
3540                 ."results analysis");
3541 }
3542
3543 print "The Exim user needs access to the test suite directory. Checking ...";
3544
3545 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3546   {
3547   my($why) = "unknown failure $rc";
3548   $rc >>= 8;
3549   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3550   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3551   $why = "Couldn't read auxiliary group list" if $rc == 3;
3552   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3553   $why = "Couldn't set gid" if $rc == 5;
3554   $why = "Couldn't set uid" if $rc == 6;
3555   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3556   print "\n** $why\n";
3557   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3558   }
3559 else
3560   {
3561   print " OK\n";
3562   }
3563
3564 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3565   if not unlink($log_summary_filename) and -e $log_summary_filename;
3566
3567 ##################################################
3568 #        Create a list of available tests        #
3569 ##################################################
3570
3571 # The scripts directory contains a number of subdirectories whose names are
3572 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3573 # from the first requires certain optional features to be included in the Exim
3574 # binary. These requirements are contained in a file called "REQUIRES" within
3575 # the directory. We scan all these tests, discarding those that cannot be run
3576 # because the current binary does not support the right facilities, and also
3577 # those that are outside the numerical range selected.
3578
3579 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3580   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3581
3582 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3583   if $dlfunc_deleted;
3584 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3585   if $dbm_build_deleted;
3586
3587
3588 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3589   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3590
3591 # Scan for relevant tests
3592 # HS12: Needs to be reworked.
3593 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3594   {
3595   my($testdir) = $test_dirs[$i];
3596   my($wantthis) = 1;
3597
3598   print ">>Checking $testdir\n" if $debug;
3599
3600   # Skip this directory if the first test is equal or greater than the first
3601   # test in the next directory.
3602
3603   next DIR if ($i < @test_dirs - 1) &&
3604           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3605
3606   # No need to carry on if the end test is less than the first test in this
3607   # subdirectory.
3608
3609   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3610
3611   # Check requirements, if any.
3612
3613   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3614     {
3615     while (<$requires>)
3616       {
3617       next if /^\s*$/;
3618       s/\s+$//;
3619       if (/^support (.*)$/)
3620         {
3621         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3622         }
3623       elsif (/^running (.*)$/)
3624         {
3625         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3626         }
3627       elsif (/^lookup (.*)$/)
3628         {
3629         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3630         }
3631       elsif (/^authenticators? (.*)$/)
3632         {
3633         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3634         }
3635       elsif (/^router (.*)$/)
3636         {
3637         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3638         }
3639       elsif (/^transport (.*)$/)
3640         {
3641         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3642         }
3643       elsif (/^malware (.*)$/)
3644         {
3645         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3646         }
3647       elsif (/^feature (.*)$/)
3648         {
3649         # move to a subroutine?
3650         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3651
3652         open (IN, "$parm_cwd/confs/0000") ||
3653           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3654         open (OUT, ">test-config") ||
3655           tests_exit(-1, "Couldn't open test-config: $!\n");
3656         while (<IN>)
3657           {
3658           do_substitute($testno);
3659           print OUT;
3660           }
3661         close(IN);
3662         close(OUT);
3663
3664         system($eximinfo . " >/dev/null 2>&1");
3665         if ($? != 0) {
3666           unlink("$parm_cwd/test-config");
3667           $wantthis = 0;
3668           $_ = "feature $1";
3669           last;
3670         }
3671         unlink("$parm_cwd/test-config");
3672         }
3673       else
3674         {
3675         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3676         }
3677       }
3678     }
3679   else
3680     {
3681     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3682       unless $!{ENOENT};
3683     }
3684
3685   # Loop if we do not want the tests in this subdirectory.
3686
3687   if (!$wantthis)
3688     {
3689     chomp;
3690     print "Omitting tests in $testdir (missing $_)\n";
3691     }
3692
3693   # We want the tests from this subdirectory, provided they are in the
3694   # range that was selected.
3695
3696   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3697   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3698     if not @testlist;
3699
3700   foreach $test (@testlist)
3701     {
3702     if (!$wantthis)
3703       {
3704       log_test($log_summary_filename, $test, '.');
3705       }
3706     else
3707       {
3708       push @test_list, "$testdir/$test";
3709       }
3710     }
3711   }
3712
3713 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
3714
3715
3716 ##################################################
3717 #         Munge variable auxiliary data          #
3718 ##################################################
3719
3720 # Some of the auxiliary data files have to refer to the current testing
3721 # directory and other parameter data. The generic versions of these files are
3722 # stored in the aux-var-src directory. At this point, we copy each of them
3723 # to the aux-var directory, making appropriate substitutions. There aren't very
3724 # many of them, so it's easiest just to do this every time. Ensure the mode
3725 # is standardized, as this path is used as a test for the ${stat: expansion.
3726
3727 # A similar job has to be done for the files in the dnszones-src directory, to
3728 # make the fake DNS zones for testing. Most of the zone files are copied to
3729 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3730 # networks that are defined by parameter.
3731
3732 foreach $basedir ("aux-var", "dnszones")
3733   {
3734   system("sudo rm -rf $parm_cwd/$basedir");
3735   mkdir("$parm_cwd/$basedir", 0777);
3736   chmod(0755, "$parm_cwd/$basedir");
3737
3738   opendir(AUX, "$parm_cwd/$basedir-src") ||
3739     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3740   my(@filelist) = readdir(AUX);
3741   close(AUX);
3742
3743   foreach $file (@filelist)
3744     {
3745     my($outfile) = $file;
3746     next if $file =~ /^\./;
3747
3748     if ($file eq "db.ip4.V4NET")
3749       {
3750       $outfile = "db.ip4.$parm_ipv4_test_net";
3751       }
3752     elsif ($file eq "db.ip6.V6NET")
3753       {
3754       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3755       $" = '.';
3756       $outfile = "db.ip6.@nibbles";
3757       $" = ' ';
3758       }
3759
3760     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3761     open(IN, "$parm_cwd/$basedir-src/$file") ||
3762       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3763     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3764       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3765     while (<IN>)
3766       {
3767       do_substitute(0);
3768       print OUT;
3769       }
3770     close(IN);
3771     close(OUT);
3772     }
3773   }
3774
3775 # Set a user's shell, distinguishable from /bin/sh
3776
3777 symlink('/bin/sh' => 'aux-var/sh');
3778 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3779
3780 ##################################################
3781 #     Create fake DNS zones for this host        #
3782 ##################################################
3783
3784 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3785 # sure that there are forward and reverse registrations for this host, using
3786 # its real IP addresses. Dynamically created zone files achieve this.
3787
3788 if ($have_ipv4 || $have_ipv6)
3789   {
3790   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3791   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3792     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3793   print OUT "; This is a dynamically constructed fake zone file.\n" .
3794     "; The following line causes fakens to return PASS_ON\n" .
3795     "; for queries that it cannot answer\n\n" .
3796     "PASS ON NOT FOUND\n\n";
3797   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3798   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3799   print OUT "\n; End\n";
3800   close(OUT);
3801   }
3802
3803 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3804   {
3805   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3806   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3807     tests_exit(-1,
3808       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3809   print OUT "; This is a dynamically constructed fake zone file.\n" .
3810     "; The zone is $components[0].in-addr.arpa.\n\n" .
3811     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3812     "; End\n";
3813   close(OUT);
3814   }
3815
3816 if ($have_ipv6 && $parm_ipv6 ne "::1")
3817   {
3818   my($exp_v6) = $parm_ipv6;
3819   $exp_v6 =~ s/[^:]//g;
3820   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3821     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3822   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3823     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3824   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3825     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3826   } else {
3827     $exp_v6 = $parm_ipv6;
3828   }
3829   my(@components) = split /:/, $exp_v6;
3830   my(@nibbles) = reverse (split /\s*/, shift @components);
3831   my($sep) =  '';
3832
3833   $" = ".";
3834   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3835     tests_exit(-1,
3836       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3837   print OUT "; This is a dynamically constructed fake zone file.\n" .
3838     "; The zone is @nibbles.ip6.arpa.\n\n";
3839
3840   @components = reverse @components;
3841   foreach $c (@components)
3842     {
3843     $c = "0$c" until $c =~ /^..../;
3844     @nibbles = reverse(split /\s*/, $c);
3845     print OUT "$sep@nibbles";
3846     $sep = ".";
3847     }
3848
3849   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3850   close(OUT);
3851   $" = " ";
3852   }
3853
3854
3855
3856 ##################################################
3857 #    Create lists of mailboxes and message logs  #
3858 ##################################################
3859
3860 # We use these lists to check that a test has created the expected files. It
3861 # should be faster than looking for the file each time. For mailboxes, we have
3862 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3863 # is just a flat list of files.
3864
3865 @oldmails = list_files_below("mail");
3866 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3867 @oldmsglogs = readdir(DIR);
3868 closedir(DIR);
3869
3870
3871
3872 ##################################################
3873 #         Run the required tests                 #
3874 ##################################################
3875
3876 # Each test script contains a number of tests, separated by a line that
3877 # contains ****. We open input from the terminal so that we can read responses
3878 # to prompts.
3879
3880 if (not $force_continue) {
3881   # runtest needs to interact if we're not in continue
3882   # mode. It does so by communicate to /dev/tty
3883   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
3884   print "\nPress RETURN to run the tests: ";
3885   <T>;
3886 }
3887
3888
3889 foreach $test (@test_list)
3890   {
3891   state $lasttestdir = '';
3892
3893   local $lineno     = 0;
3894   local $commandno  = 0;
3895   local $subtestno  = 0;
3896   local $sortlog    = 0;
3897
3898   (local $testno = $test) =~ s|.*/||;
3899
3900   # Leaving traces in the process table and in the environment
3901   # gives us a chance to identify hanging processes (exim daemons)
3902   local $0 = "[runtest $testno]";
3903   local $ENV{EXIM_TEST_NUMBER} = $testno;
3904
3905   my $gnutls   = 0;
3906   my $docheck  = 1;
3907   my $thistestdir  = substr($test, 0, -5);
3908
3909   $dynamic_socket->close() if $dynamic_socket;
3910
3911   if ($lasttestdir ne $thistestdir)
3912     {
3913     $gnutls = 0;
3914     if (-s "scripts/$thistestdir/REQUIRES")
3915       {
3916       my $indent = '';
3917       print "\n>>> The following tests require: ";
3918       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
3919         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
3920       while (<$requires>)
3921         {
3922         $gnutls = 1 if /^support GnuTLS/;
3923         print $indent, $_;
3924         $indent = ">>>                              ";
3925         }
3926       }
3927       $lasttestdir = $thistestdir;
3928     }
3929
3930   # Remove any debris in the spool directory and the test-mail directory
3931   # and also the files for collecting stdout and stderr. Then put back
3932   # the test-mail directory for appendfile deliveries.
3933
3934   system "sudo /bin/rm -rf spool test-*";
3935   system "mkdir test-mail 2>/dev/null";
3936
3937   # A privileged Exim will normally make its own spool directory, but some of
3938   # the tests run in unprivileged modes that don't always work if the spool
3939   # directory isn't already there. What is more, we want anybody to be able
3940   # to read it in order to find the daemon's pid.
3941
3942   system "mkdir spool; " .
3943          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3944          "sudo chmod 0755 spool";
3945
3946   # Empty the cache that keeps track of things like message id mappings, and
3947   # set up the initial sequence strings.
3948
3949   undef %cache;
3950   $next_msgid = "aX";
3951   $next_pid = 1234;
3952   $next_port = 1111;
3953   $message_skip = 0;
3954   $msglog_skip = 0;
3955   $stderr_skip = 0;
3956   $stdout_skip = 0;
3957   $rmfiltertest = 0;
3958   $is_ipv6test = 0;
3959   $TEST_STATE->{munge} = '';
3960
3961   # Remove the associative arrays used to hold checked mail files and msglogs
3962
3963   undef %expected_mails;
3964   undef %expected_msglogs;
3965
3966   # Open the test's script
3967   open(SCRIPT, "scripts/$test") ||
3968     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3969   # Run through the script once to set variables which should be global
3970   while (<SCRIPT>)
3971     {
3972     if (/^no_message_check/) { $message_skip = 1; next; }
3973     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3974     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3975     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3976     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3977     if (/^sortlog/)          { $sortlog = 1; next; }
3978     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
3979     }
3980   # Reset to beginning of file for per test interpreting/processing
3981   seek(SCRIPT, 0, 0);
3982
3983   # The first line in the script must be a comment that is used to identify
3984   # the set of tests as a whole.
3985
3986   $_ = <SCRIPT>;
3987   $lineno++;
3988   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3989   printf("%s %s", (substr $test, 5), (substr $_, 2));
3990
3991   # Loop for each of the subtests within the script. The variable $server_pid
3992   # is used to remember the pid of a "server" process, for which we do not
3993   # wait until we have waited for a subsequent command.
3994
3995   local($server_pid) = 0;
3996   for ($commandno = 1; !eof SCRIPT; $commandno++)
3997     {
3998     # Skip further leading comments and blank lines, handle the flag setting
3999     # commands, and deal with tests for IP support.
4000
4001     while (<SCRIPT>)
4002       {
4003       $lineno++;
4004       # Could remove these variable settings because they are already
4005       # set above, but doesn't hurt to leave them here.
4006       if (/^no_message_check/) { $message_skip = 1; next; }
4007       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4008       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4009       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4010       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4011       if (/^sortlog/)          { $sortlog = 1; next; }
4012
4013       if (/^need_largefiles/)
4014         {
4015         next if $have_largefiles;
4016         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4017         $docheck = 0;      # don't check output
4018         undef $_;          # pretend EOF
4019         last;
4020         }
4021
4022       if (/^need_ipv4/)
4023         {
4024         next if $have_ipv4;
4025         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4026         $docheck = 0;      # don't check output
4027         undef $_;          # pretend EOF
4028         last;
4029         }
4030
4031       if (/^need_ipv6/)
4032         {
4033         if ($have_ipv6)
4034           {
4035           $is_ipv6test = 1;
4036           next;
4037           }
4038         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4039         $docheck = 0;      # don't check output
4040         undef $_;          # pretend EOF
4041         last;
4042         }
4043
4044       if (/^need_move_frozen_messages/)
4045         {
4046         next if defined $parm_support{move_frozen_messages};
4047         print ">>> move frozen message support is needed for test $testno, " .
4048           "but is not\n>>> available: skipping\n";
4049         $docheck = 0;      # don't check output
4050         undef $_;          # pretend EOF
4051         last;
4052         }
4053
4054       last unless /^(?:#(?!##\s)|\s*$)/;
4055       }
4056     last if !defined $_;  # Hit EOF
4057
4058     my($subtest_startline) = $lineno;
4059
4060     # Now run the command. The function returns 0 for an inline command,
4061     # 1 if a non-exim command was run and waited for, 2 if an exim
4062     # command was run and waited for, and 3 if a command
4063     # was run and not waited for (usually a daemon or server startup).
4064
4065     my($commandname) = '';
4066     my($expectrc) = 0;
4067     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4068     my($cmdrc) = $?;
4069
4070     if ($debug) {
4071       print ">> rc=$rc cmdrc=$cmdrc\n";
4072       if (defined $run_extra) {
4073         foreach my $k (keys %$run_extra) {
4074           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4075           print ">>   $k -> $v\n";
4076         }
4077       }
4078     }
4079     $run_extra = {} unless defined $run_extra;
4080     foreach my $k (keys %$run_extra) {
4081       if (exists $TEST_STATE->{$k}) {
4082         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4083         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4084       }
4085       if (defined $run_extra->{$k}) {
4086         $TEST_STATE->{$k} = $run_extra->{$k};
4087       } elsif (exists $TEST_STATE->{$k}) {
4088         delete $TEST_STATE->{$k};
4089       }
4090     }
4091
4092     # Hit EOF after an initial return code number
4093
4094     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4095
4096     # Carry on with the next command if we did not wait for this one. $rc == 0
4097     # if no subprocess was run; $rc == 3 if we started a process but did not
4098     # wait for it.
4099
4100     next if ($rc == 0 || $rc == 3);
4101
4102     # We ran and waited for a command. Check for the expected result unless
4103     # it died.
4104
4105     if ($cmdrc != $expectrc && !$sigpipehappened)
4106       {
4107       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4108       if (($cmdrc & 0xff) == 0)
4109         {
4110         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4111         }
4112       elsif (($cmdrc & 0xff00) == 0)
4113         { printf("** Killed by signal %d", $cmdrc & 255); }
4114       else
4115         { printf("** Status %x", $cmdrc); }
4116
4117       for (;;)
4118         {
4119         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4120         $_ = $force_continue ? "c" : <T>;
4121         tests_exit(1) if /^q?$/i;
4122         if (/^c$/ && $force_continue) {
4123           log_failure($log_failed_filename, $testno, "exit code unexpected");
4124           log_test($log_summary_filename, $testno, 'F')
4125         }
4126         if ($force_continue)
4127           {
4128           print "\nstdout tail:\n";
4129           print "==================>\n";
4130           system("tail -20 test-stdout");
4131           print "===================\n";
4132           print "stderr tail:\n";
4133           print "==================>\n";
4134           system("tail -20 test-stderr");
4135           print "===================\n";
4136           print "... continue forced\n";
4137           }
4138
4139         last if /^[rc]$/i;
4140         if (/^e$/i)
4141           {
4142           system("$more test-stderr");
4143           }
4144         elsif (/^o$/i)
4145           {
4146           system("$more test-stdout");
4147           }
4148         }
4149
4150       $retry = 1 if /^r$/i;
4151       $docheck = 0;
4152       }
4153
4154     # If the command was exim, and a listening server is running, we can now
4155     # close its input, which causes us to wait for it to finish, which is why
4156     # we didn't close it earlier.
4157
4158     if ($rc == 2 && $server_pid != 0)
4159       {
4160       close SERVERCMD;
4161       $server_pid = 0;
4162       if ($? != 0)
4163         {
4164         if (($? & 0xff) == 0)
4165           { printf("Server return code %d for test %d starting line %d", $?/256,
4166                 $testno, $subtest_startline); }
4167         elsif (($? & 0xff00) == 0)
4168           { printf("Server killed by signal %d", $? & 255); }
4169         else
4170           { printf("Server status %x", $?); }
4171
4172         for (;;)
4173           {
4174           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4175           $_ = $force_continue ? "c" : <T>;
4176           tests_exit(1) if /^q?$/i;
4177           if (/^c$/ && $force_continue) {
4178             log_failure($log_failed_filename, $testno, "exit code unexpected");
4179             log_test($log_summary_filename, $testno, 'F')
4180           }
4181           print "... continue forced\n" if $force_continue;
4182           last if /^[rc]$/i;
4183
4184           if (/^s$/i)
4185             {
4186             open(S, "test-stdout-server") ||
4187               tests_exit(-1, "Failed to open test-stdout-server: $!");
4188             print while <S>;
4189             close(S);
4190             }
4191           }
4192         $retry = 1 if /^r$/i;
4193         }
4194       }
4195     }
4196
4197   close SCRIPT;
4198
4199   # The script has finished. Check the all the output that was generated. The
4200   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4201   # rerun the test (the files # have been updated).
4202   # It does not return if the user responds Q to a prompt.
4203
4204   if ($retry)
4205     {
4206     $retry = '0';
4207     print (("#" x 79) . "\n");
4208     redo;
4209     }
4210
4211   if ($docheck)
4212     {
4213     sleep 1 if $slow;
4214     my $rc = check_output($TEST_STATE->{munge});
4215     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4216     if ($rc < 2)
4217       {
4218       print ("  Script completed\n");
4219       }
4220     else
4221       {
4222       print (("#" x 79) . "\n");
4223       redo;
4224       }
4225     }
4226   }
4227
4228
4229 ##################################################
4230 #         Exit from the test script              #
4231 ##################################################
4232
4233 tests_exit(-1, "No runnable tests selected") if not @test_list;
4234 tests_exit(0);
4235
4236 __END__
4237
4238 =head1 NAME
4239
4240  runtest - run the exim testsuite
4241
4242 =head1 SYNOPSIS
4243
4244  runtest [exim-path] [options] [test0 [test1]]
4245
4246 =head1 DESCRIPTION
4247
4248 B<runtest> runs the Exim testsuite.
4249
4250 =head1 OPTIONS
4251
4252 For legacy reasons the options are not case sensitive.
4253
4254 =over
4255
4256 =item B<--continue>
4257
4258 Do not stop for user interaction or on errors. (default: off)
4259
4260 =item B<--debug>
4261
4262 This option enables the output of debug information when running the
4263 various test commands. (default: off)
4264
4265 =item B<--diff>
4266
4267 Use C<diff -u> for comparing the expected output with the produced
4268 output. (default: use a built-in routine)
4269
4270 =item B<--flavor>|B<--flavour> I<flavour>
4271
4272 Override the expected results for results for a specific (OS) flavour.
4273 (default: unused)
4274
4275 =item B<--[no]ipv4>
4276
4277 Skip IPv4 related setup and tests (default: use ipv4)
4278
4279 =item B<--[no]ipv6>
4280
4281 Skip IPv6 related setup and tests (default: use ipv6)
4282
4283 =item B<--keep>
4284
4285 Keep the various output files produced during a test run. (default: don't keep)
4286
4287 =item B<--range> I<n0> I<n1>
4288
4289 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4290 test available".
4291
4292 =item B<--slow>
4293
4294 Insert some delays to compensate for a slow host system. (default: off)
4295
4296 =item B<--test> I<n>
4297
4298 Run the specified test. This option may used multiple times.
4299
4300 =item B<--update>
4301
4302 Automatically update the recorded (expected) data on mismatch. (default: off)
4303
4304 =item B<--valgrind>
4305
4306 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4307
4308 =back
4309
4310 =cut
4311
4312
4313 # End of runtest script