test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32
  33 use lib "$RealBin/lib";
  34 use Exim::Runtest;
  35 use Exim::Utils qw(uniq numerically);
  36
  37 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  39
  40 use constant TEST_TOP => 8999;
  41 use constant TEST_SPECIAL_TOP => 9999;
  42
  43
  44 # Start by initializing some global variables
  45
  46 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  47
  48 # This gets embedded in the D-H params filename, and the value comes
  49 # from asking GnuTLS for "normal", but there appears to be no way to
  50 # use certtool/... to ask what that value currently is.  *sigh*
  51 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  52 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  53 # normal = 2432   tls_dh_max_bits = 2236
  54 my $gnutls_dh_bits_normal = 2236;
  55
  56 my $cf = 'bin/cf -exact';
  57 my $cr = "\r";
  58 my $debug = 0;
  59 my $flavour = do {
  60   my $f = Exim::Runtest::flavour() // '';
  61   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  62 };
  63 my $force_continue = 0;
  64 my $force_update = 0;
  65 my $log_failed_filename = 'failed-summary.log';
  66 my $log_summary_filename = 'run-summary.log';
  67 my @more = qw'less -XF';
  68 my $optargs = '';
  69 my $save_output = 0;
  70 my $server_opts = '';
  71 my $slow = 0;
  72 my $valgrind = 0;
  73
  74 my $have_ipv4 = 1;
  75 my $have_ipv6 = 1;
  76 my $have_largefiles = 0;
  77
  78 my @test_list = ();
  79
  80
  81 # Networks to use for DNS tests. We need to choose some networks that will
  82 # never be used so that there is no chance that the host on which we are
  83 # running is actually in one of the test networks. Private networks such as
  84 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  85 # Rather than use some unassigned numbers (that might become assigned later),
  86 # I have chosen some multicast networks, in the belief that such addresses
  87 # won't ever be assigned to hosts. This is the only place where these numbers
  88 # are defined, so it is trivially possible to change them should that ever
  89 # become necessary.
  90
  91 my $parm_ipv4_test_net = 224;
  92 my $parm_ipv6_test_net = 'ff00';
  93
  94 # Port numbers are currently hard-wired
  95
  96 my $parm_port_n = 1223;         # Nothing listening on this port
  97 my $parm_port_s = 1224;         # Used for the "server" command
  98 my $parm_port_d = 1225;         # Used for the Exim daemon
  99 my $parm_port_d2 = 1226;        # Additional for daemon
 100 my $parm_port_d3 = 1227;        # Additional for daemon
 101 my $parm_port_d4 = 1228;        # Additional for daemon
 102 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 103
 104 # Find a suiteable group name for test (currently only 0001
 105 # uses a group name. A numeric group id would do
 106 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 107
 108 # Manually set locale
 109 $ENV{LC_ALL} = 'C';
 110
 111 # In some environments USER does not exist, but we need it for some test(s)
 112 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 113
 114 my ($parm_configure_owner, $parm_configure_group);
 115 my ($parm_ipv4, $parm_ipv6, $parm_ipv6_stripped);
 116 my $parm_hostname;
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121 # Define a number of subroutines
 122
 123 ###############################################################################
 124 ###############################################################################
 125
 126
 127 ##################################################
 128 #              Handle signals                    #
 129 ##################################################
 130
 131 sub pipehandler { $sigpipehappened = 1; }
 132
 133 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 134
 135
 136 ##################################################
 137 #       Do global macro substitutions            #
 138 ##################################################
 139
 140 # This function is applied to configurations, command lines and data lines in
 141 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 142 # directory. It takes one argument: the current test number, or zero when
 143 # setting up files before running any tests.
 144
 145 sub do_substitute{
 146 s?\bCALLER\b?$parm_caller?g;
 147 s?\bCALLERGROUP\b?$parm_caller_group?g;
 148 s?\bCALLER_UID\b?$parm_caller_uid?g;
 149 s?\bCALLER_GID\b?$parm_caller_gid?g;
 150 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 151 s?\bDIR/?$parm_cwd/?g;
 152 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 153 s?\bEXIMUSER\b?$parm_eximuser?g;
 154 s?\bHOSTIPV4\b?$parm_ipv4?g;
 155 s?\bHOSTIPV6\b?$parm_ipv6?g;
 156 s?\bHOSTNAME\b?$parm_hostname?g;
 157 s?\bPORT_D\b?$parm_port_d?g;
 158 s?\bPORT_D2\b?$parm_port_d2?g;
 159 s?\bPORT_D3\b?$parm_port_d3?g;
 160 s?\bPORT_D4\b?$parm_port_d4?g;
 161 s?\bPORT_N\b?$parm_port_n?g;
 162 s?\bPORT_S\b?$parm_port_s?g;
 163 s?\bTESTNUM\b?$_[0]?g;
 164 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 165 s?\bV6NET:?$parm_ipv6_test_net:?g;
 166 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 167 s?\bMAILGROUP\b?$parm_mailgroup?g;
 168 }
 169
 170
 171 ##################################################
 172 #     Any state to be preserved across tests     #
 173 ##################################################
 174
 175 my $TEST_STATE = {};
 176
 177
 178 ##################################################
 179 #        Subroutine to tidy up and exit          #
 180 ##################################################
 181
 182 # In all cases, we check for any Exim daemons that have been left running, and
 183 # kill them. Then remove all the spool data, test output, and the modified Exim
 184 # binary if we are ending normally.
 185
 186 # Arguments:
 187 #    $_[0] = 0 for a normal exit; full cleanup done
 188 #    $_[0] > 0 for an error exit; no files cleaned up
 189 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 190
 191 sub tests_exit{
 192 my($rc) = $_[0];
 193 my($spool);
 194
 195 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 196 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 197 # the background.
 198
 199 if (exists $TEST_STATE->{exim_pid})
 200   {
 201   $pid = $TEST_STATE->{exim_pid};
 202   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 203   system("sudo kill -INT $pid");
 204   }
 205
 206 if (opendir(DIR, "spool"))
 207   {
 208   my(@spools) = sort readdir(DIR);
 209   closedir(DIR);
 210   foreach $spool (@spools)
 211     {
 212     next if $spool !~ /^exim-daemon./;
 213     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 214     chomp($pid = <PID>);
 215     close(PID);
 216     print "Tidyup: killing daemon pid=$pid\n";
 217     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 218     }
 219   }
 220 else
 221   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 222
 223 # Close the terminal input and remove the test files if all went well, unless
 224 # the option to save them is set. Always remove the patched Exim binary. Then
 225 # exit normally, or die.
 226
 227 close(T);
 228 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 229   if ($rc == 0 && !$save_output);
 230
 231 system("sudo /bin/rm -rf ./eximdir/*")
 232   if (!$save_output);
 233
 234 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 235 exit $rc if ($rc >= 0);
 236 die "** runtest error: $_[1]\n";
 237 }
 238
 239
 240
 241 ##################################################
 242 #   Subroutines used by the munging subroutine   #
 243 ##################################################
 244
 245 # This function is used for things like message ids, where we want to generate
 246 # more than one value, but keep a consistent mapping throughout.
 247 #
 248 # Arguments:
 249 #   $oldid        the value from the file
 250 #   $base         a base string into which we insert a sequence
 251 #   $sequence     the address of the current sequence counter
 252
 253 sub new_value {
 254 my($oldid, $base, $sequence) = @_;
 255 my($newid) = $cache{$oldid};
 256 if (! defined $newid)
 257   {
 258   $newid = sprintf($base, $$sequence++);
 259   $cache{$oldid} = $newid;
 260   }
 261 return $newid;
 262 }
 263
 264
 265 # This is used while munging the output from exim_dumpdb.
 266 # May go wrong across DST changes.
 267
 268 sub date_seconds {
 269 my($day,$month,$year,$hour,$min,$sec) =
 270   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 271 my($mon);
 272 if   ($month =~ /Jan/) {$mon = 0;}
 273 elsif($month =~ /Feb/) {$mon = 1;}
 274 elsif($month =~ /Mar/) {$mon = 2;}
 275 elsif($month =~ /Apr/) {$mon = 3;}
 276 elsif($month =~ /May/) {$mon = 4;}
 277 elsif($month =~ /Jun/) {$mon = 5;}
 278 elsif($month =~ /Jul/) {$mon = 6;}
 279 elsif($month =~ /Aug/) {$mon = 7;}
 280 elsif($month =~ /Sep/) {$mon = 8;}
 281 elsif($month =~ /Oct/) {$mon = 9;}
 282 elsif($month =~ /Nov/) {$mon = 10;}
 283 elsif($month =~ /Dec/) {$mon = 11;}
 284 return timelocal($sec,$min,$hour,$day,$mon,$year);
 285 }
 286
 287
 288 # This is a subroutine to sort maildir files into time-order. The second field
 289 # is the microsecond field, and may vary in length, so must be compared
 290 # numerically.
 291
 292 sub maildirsort {
 293 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 294 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 295 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 296 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 297 }
 298
 299
 300
 301 ##################################################
 302 #   Subroutine list files below a directory      #
 303 ##################################################
 304
 305 # This is used to build up a list of expected mail files below a certain path
 306 # in the directory tree. It has to be recursive in order to deal with multiple
 307 # maildir mailboxes.
 308
 309 sub list_files_below {
 310 my($dir) = $_[0];
 311 my(@yield) = ();
 312 my(@sublist, $file);
 313
 314 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 315 @sublist = sort maildirsort readdir(DIR);
 316 closedir(DIR);
 317
 318 foreach $file (@sublist)
 319   {
 320   next if $file eq "." || $file eq ".." || $file eq "CVS";
 321   if (-d "$dir/$file")
 322     { @yield = (@yield, list_files_below("$dir/$file")); }
 323   else
 324     { push @yield, "$dir/$file"; }
 325   }
 326
 327 return @yield;
 328 }
 329
 330
 331
 332 ##################################################
 333 #         Munge a file before comparing          #
 334 ##################################################
 335
 336 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 337 # on into standard values, so that the compare works. Perl's substitution with
 338 # an expression provides a neat way to do some of these changes.
 339
 340 # We keep a global associative array for repeatedly turning the same values
 341 # into the same standard values throughout the data from a single test.
 342 # Message ids get this treatment (can't be made reliable for times), and
 343 # times in dumped retry databases are also handled in a special way, as are
 344 # incoming port numbers.
 345
 346 # On entry to the subroutine, the file to write to is already opened with the
 347 # name MUNGED. The input file name is the only argument to the subroutine.
 348 # Certain actions are taken only when the name contains "stderr", "stdout",
 349 # or "log". The yield of the function is 1 if a line matching "*** truncated
 350 # ***" is encountered; otherwise it is 0.
 351
 352 sub munge {
 353 my($file) = $_[0];
 354 my($extra) = $_[1];
 355 my($yield) = 0;
 356 my(@saved) = ();
 357
 358 local $_;
 359
 360 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 361
 362 my($is_log) = $file =~ /log/;
 363 my($is_stdout) = $file =~ /stdout/;
 364 my($is_stderr) = $file =~ /stderr/;
 365 my($is_mail) = $file =~ /mail/;
 366
 367 # Date pattern
 368
 369 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 370
 371 # Pattern for matching pids at start of stderr lines; initially something
 372 # that won't match.
 373
 374 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 375
 376 # Scan the file and make the changes. Near the bottom there are some changes
 377 # that are specific to certain file types, though there are also some of those
 378 # inline too.
 379
 380 LINE: while(<IN>)
 381   {
 382 RESET_AFTER_EXTRA_LINE_READ:
 383   # Custom munges
 384   if ($extra)
 385     {
 386     next if $extra =~ m%^/%  &&  eval $extra;
 387     eval $extra if $extra =~ m/^s/;
 388     }
 389
 390   # Check for "*** truncated ***"
 391   $yield = 1 if /\*\*\* truncated \*\*\*/;
 392
 393   # Replace the name of this host
 394   s/\Q$parm_hostname\E/the.local.host.name/g;
 395
 396   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 397   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 398
 399   # The name of the shell may vary
 400   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 401
 402   # Replace the path to the testsuite directory
 403   s?\Q$parm_cwd\E?TESTSUITE?g;
 404
 405   # Replace the Exim version number (may appear in various places)
 406   # patchexim should have fixed this for us
 407   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 408
 409   # Replace Exim message ids by a unique series
 410   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 411     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 412
 413   # The names of lock files appear in some error and debug messages
 414   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 415
 416   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 417   # port" message, because it is not always the same.
 418   s/port (\d+) \([^)]+\)/port $1/g
 419     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 420
 421   # Challenges in SPA authentication
 422   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 423
 424   # PRVS values
 425   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 426   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463
 464     # Round the time-difference up to nearest even value
 465     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
 466
 467     # We used to use globally unique replacement values, but timing
 468     # differences make this impossible. Just show the increment on the
 469     # last one.
 470
 471     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 472       $increment, $expired);
 473     next;
 474     }
 475
 476   # more_errno values in exim_dumpdb output which are times
 477   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 478
 479   # port numbers in dumpdb output
 480   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
 481
 482   # port numbers in stderr
 483   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
 484   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
 485
 486
 487   # ======== Dates and times ========
 488
 489   # Dates and times are all turned into the same value - trying to turn
 490   # them into different ones cannot be done repeatedly because they are
 491   # real time stamps generated while running the test. The actual date and
 492   # time used was fixed when I first started running automatic Exim tests.
 493
 494   # Date/time in header lines and SMTP responses
 495   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 496     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 497   # and in a French locale
 498   s/\S{4},\s\d\d?\s[^,]+\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 499     /dim., 10 f\xE9vr 2019 20:05:49 +0000/gx;
 500
 501   # Date/time in logs and in one instance of a filter test
 502   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 503   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 504   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 505   # Date/time in syslog test
 506   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 507   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 508   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 509   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 510
 511   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 512   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 513
 514   # Date/time in message separators
 515   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 516     /Tue Mar 02 09:44:33 1999/gx;
 517
 518   # Date of message arrival in spool file as shown by -Mvh
 519   s/^\d{9,10}\s0$/ddddddddd 0/;
 520
 521   # Date/time in mbx mailbox files
 522   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 523
 524   # Dates/times in debugging output for writing retry records
 525   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 526     {
 527     my($next) = $3 - $2;
 528     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 529     }
 530   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 531   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 532
 533   # Time to retry may vary
 534   s/time to retry = \S+/time to retry = tttt/;
 535   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 536   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 537
 538   # Date/time in exim -bV output
 539   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 540
 541   # Eximstats heading
 542   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 543     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 544
 545   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 546   # us the former on a new connection.
 547   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 548
 549   # ======== TLS certificate algorithms ========
 550   #
 551   # In Received: headers, convert RFC 8314 style ciphersuite to
 552   # the older (comment) style, keeping only the Auth element
 553   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
 554   # element (and no _WITH); insert a spurious "RSA".
 555   # Also in $tls_X_cipher_std reporting.
 556
 557   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-$1-AES256-SHAnnn:xxx)/;
 558   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
 559
 560   s/ cipher_ TLS_.*?([^_]+)_WITH.+$/ cipher_ TLS1.x:ke_$1_WITH_ci_mac/;
 561   s/ cipher_ TLS_.*$/ cipher_ TLS1.x:ke_RSA_WITH_ci_mac/;
 562
 563   # Test machines might have various different TLS library versions supporting
 564   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 565   # treat the standard algorithms the same.
 566   #
 567   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : bits
 568   #
 569   # So far, have seen:
 570   #   TLSv1:AES128-GCM-SHA256:128
 571   #   TLSv1:AES256-SHA:256
 572   #   TLSv1.1:AES256-SHA:256
 573   #   TLSv1.2:AES256-GCM-SHA384:256
 574   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 575   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 576   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 577   # We also need to handle the ciphersuite without the TLS part present, for
 578   # client-ssl's output.  We also see some older forced ciphersuites, but
 579   # negotiating TLS 1.2 instead of 1.0.
 580   # Mail headers (...), log-lines X=..., client-ssl output ...
 581   # (and \b doesn't match between ' ' and '(' )
 582   #
 583   # Retain the authentication algorith field as we want to test that.
 584
 585   s/( (?: (?:\b|\s) [\(=] ) | \s )TLS1(\.[123])?:/$1TLS1.x:/xg;
 586   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
 587   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
 588
 589   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 590   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
 591   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
 592   #
 593   # TLSversion : "TLS" - C_iph_er - MAC : ???
 594   #
 595   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
 596   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
 597
 598   # LibreSSL
 599   # TLSv1:AES256-GCM-SHA384:256
 600   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 601   #
 602   # ECDHE-RSA-CHACHA20-POLY1305
 603   # AES256-GCM-SHA384
 604
 605   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 606   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
 607   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
 608
 609   # GnuTLS have seen:
 610   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
 611   #   TLS1.3:ECDHE_SECP256R1__RSA_PSS_RSAE_SHA256__AES_256_GCM__AEAD:256
 612   #   TLS1.3:ECDHE_X25519__RSA_PSS_RSAE_SHA256__AES_256_GCM:256
 613   #   TLS1.3:ECDHE_PSK_SECP256R1__AES_256_GCM__AEAD:256
 614   #
 615   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 616   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 617   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 618   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 619   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_256_GCM:256
 620   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_128_CBC__SHA256:128
 621   #   TLS1.2:ECDHE_SECP256R1__ECDSA_SHA512__AES_256_GCM:256
 622   #   TLS1.2:ECDHE_SECP256R1__AES_256_GCM:256           (3.6.7 resumption)
 623   #   TLS1.2:ECDHE_RSA_SECP256R1__AES_256_GCM:256       (! 3.5.18 !)
 624   #   TLS1.2:RSA__CAMELLIA_256_GCM:256                  (leave the cipher name)
 625   #   TLS1.2-PKIX:RSA__AES_128_GCM__AEAD:128            (the -PKIX seems to be a 3.1.20 thing)
 626   #   TLS1.2-PKIX:ECDHE_RSA_SECP521R1__AES_256_GCM__AEAD:256
 627   #
 628   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 629   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 630   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 631   #   X=TLS1.0:RSA_AES_256_CBC_SHA1:256
 632   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 633   #   X=TLS1.0-PKIX:RSA__AES_256_CBC__SHA1:256
 634   # and as stand-alone cipher:
 635   #   ECDHE-RSA-AES256-SHA
 636   #   DHE-RSA-AES256-SHA256
 637   #   DHE-RSA-AES256-SHA
 638   # picking latter as canonical simply because regex easier that way.
 639   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
 640   s/TLS1.[x0123](-PKIX)?:                                               # TLS version
 641     ((EC)?DHE(_((?<psk>PSK)_)?((?<auth>RSA|ECDSA)_)?
 642                                 (SECP(256|521)R1|X25519))?__?)?         # key-exchange
 643     ((?<auth>RSA|ECDSA)((_PSS_RSAE)?_SHA(512|256))?__?)?                # authentication
 644     (?<with>WITH_)?                                                     # stdname-with
 645     AES_(256|128)_(CBC|GCM)                                             # cipher
 646     (__?AEAD)?                                                          # pseudo-MAC
 647     (__?SHA(1|256|384))?                                                # PRF
 648     :(256|128)                                                          # cipher strength
 649     /"TLS1.x:ke-"
 650         . (defined($+{psk}) ? $+{psk} : "")
 651         . (defined($+{auth}) ? $+{auth} : "")
 652         . (defined($+{with}) ? $+{with} : "")
 653         . "-AES256-SHAnnn:xxx"/gex;
 654   s/TLS1.2:RSA__CAMELLIA_256_GCM(_SHA384)?:256/TLS1.2:RSA_CAMELLIA_256_GCM-SHAnnn:256/g;
 655   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
 656
 657   # Separate reporting of TLS version
 658   s/ver:    TLS1(\.[0-3])?$/ver:    TLS1.x/;
 659   s/ \(TLS1(\.[0-3])?\) / (TLS1.x) /;
 660
 661   # GnuTLS library error message changes
 662   s/(No certificate was found|Certificate is required)/The peer did not send any certificate/g;
 663 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 664   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 665   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 666
 667   # (this new one is a generic channel-read error, but the testsuite
 668   # only hits it in one place)
 669   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 670
 671   # (replace old with new, hoping that old only happens in one situation)
 672   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 673   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 674
 675   # signature algorithm names
 676   s/RSA-SHA1/RSA-SHA/;
 677
 678
 679   # ======== Caller's login, uid, gid, home, gecos ========
 680
 681   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 682   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 683   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 684
 685   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 686   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 687
 688   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 689   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 690
 691   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 692
 693   # When looking at spool files with -Mvh, we will find not only the caller
 694   # login, but also the uid and gid. It seems that $) in some Perls gives all
 695   # the auxiliary gids as well, so don't bother checking for that.
 696
 697   s/^CALLER $> \d+$/CALLER UID GID/;
 698
 699   # There is one case where the caller's login is forced to something else,
 700   # in order to test the processing of logins that contain spaces. Weird what
 701   # some people do, isn't it?
 702
 703   s/^spaced user $> \d+$/CALLER UID GID/;
 704
 705
 706   # ======== Exim's login ========
 707   # For messages received by the daemon, this is in the -H file, which some
 708   # tests inspect. For bounce messages, this will appear on the U= lines in
 709   # logs and also after Received: and in addresses. In one pipe test it appears
 710   # after "Running as:". It also appears in addresses, and in the names of lock
 711   # files.
 712
 713   s/U=$parm_eximuser/U=EXIMUSER/;
 714   s/user=$parm_eximuser/user=EXIMUSER/;
 715   s/login=$parm_eximuser/login=EXIMUSER/;
 716   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 717   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 718   s/\b$parm_eximuser@/EXIMUSER@/;
 719   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 720
 721   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 722   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 723
 724   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 725   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 726
 727   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 728
 729
 730   # ======== General uids, gids, and pids ========
 731   # Note: this must come after munges for caller's and exim's uid/gid
 732
 733   # These are for systems where long int is 64
 734   s/\buid=4294967295/uid=-1/;
 735   s/\beuid=4294967295/euid=-1/;
 736   s/\bgid=4294967295/gid=-1/;
 737   s/\begid=4294967295/egid=-1/;
 738
 739   s/\bgid=\d+/gid=gggg/;
 740   s/\begid=\d+/egid=gggg/;
 741   s/\b(pid=|PID: )\d+/$1pppp/;
 742   s/\buid=\d+/uid=uuuu/;
 743   s/\beuid=\d+/euid=uuuu/;
 744   s/set_process_info:\s+\d+/set_process_info: pppp/;
 745   s/queue run pid \d+/queue run pid ppppp/;
 746   s/process \d+ running as transport filter/process pppp running as transport filter/;
 747   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 748   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 749   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 750
 751   # Pid in temp file in appendfile transport
 752   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 753
 754   # Optional pid in log lines
 755   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 756     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 757
 758   # Optional pid in syslog test lines
 759   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 760     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 761
 762   # Detect a daemon stderr line with a pid and save the pid for subsequent
 763   # removal from following lines.
 764   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 765   s/^$spid //;
 766
 767   # Queue runner waiting messages
 768   s/waiting for children of \d+/waiting for children of pppp/;
 769   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 770
 771   # Most builds are without HAVE_LOCAL_SCAN
 772   next if /^calling local_scan\(\); timeout=300$/;
 773   next if /^local_scan\(\) returned 0 NULL$/;
 774
 775   # ======== Port numbers ========
 776   # Incoming port numbers may vary, but not in daemon startup line.
 777
 778   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 779   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 780
 781   # This handles "connection from" and the like, when the port is given
 782   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 783       && !/\*>/ && !/Connection refused/)
 784     {
 785     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 786     }
 787
 788   # Port in host address in spool file output from -Mvh
 789   s/^(--?host_address) (.*)\.\d+/$1 $2.9999/;
 790
 791   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 792     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 793   }
 794
 795
 796   # ======== Local IP addresses ========
 797   # The amount of space between "host" and the address in verification output
 798   # depends on the length of the host name. We therefore reduce it to one space
 799   # for all of them.
 800   # Also, the length of space at the end of the host line is dependent
 801   # on the length of the longest line, so strip it also on otherwise
 802   # un-rewritten lines like localhost
 803   #
 804   # host 127.0.0.1     [127.0.0.1]
 805   # host 10.0.0.1      [10.0.0.1]-
 806   #
 807   # host 127.0.0.1     [127.0.0.1]--
 808   # host 169.16.16.16  [169.16.16.10]
 809
 810   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 811   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 812   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 813   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 814   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 815   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 816   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 817   s/(^|\W)\K\Q$parm_ipv6_stripped\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 818   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 819   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 820   s/^\s+host\s\S+\s+\[\S+\]\K +$//;     # strip, not collapse the trailing whitespace
 821
 822
 823   # ======== Test network IP addresses ========
 824   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 825   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 826
 827
 828   # ======== IP error numbers and messages ========
 829   # These vary between operating systems
 830   s/Can't assign requested address/Network Error/;
 831   s/Cannot assign requested address/Network Error/;
 832   s/Operation timed out/Connection timed out/;
 833   s/Address family not supported by protocol family/Network Error/;
 834   s/Network is unreachable/Network Error/;
 835   s/Invalid argument/Network Error/;
 836
 837   s/\(\d+\): Network/(dd): Network/;
 838   s/\(\d+\): Connection refused/(dd): Connection refused/;
 839   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 840   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 841   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 842
 843
 844   # ======== Other error numbers ========
 845   s/errno=\d+/errno=dd/g;
 846
 847   # ======== System Error Messages ======
 848   # depending on the underlaying file system the error message seems to differ
 849   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 850
 851   # ======== Output from ls ========
 852   # Different operating systems use different spacing on long output
 853   #s/ +/ /g if /^[-rwd]{10} /;
 854   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 855   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 856   # unfortunately matches a non-ls linefull of dashes.
 857   # Allow the case where we've already picked out the file protection bits.
 858   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 859     s/ +/ /g;
 860   }
 861
 862
 863   # ======== Message sizes =========
 864   # Message sizes vary, owing to different logins and host names that get
 865   # automatically inserted. I can't think of any way of even approximately
 866   # comparing these.
 867
 868   s/([\s,])S=\d+\b/$1S=sss/;
 869   s/:S\d+\b/:Ssss/;
 870   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 871   s/\sSIZE=\d+\b/ SIZE=ssss/;
 872   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 873   s/old size = \d+\b/old size = sssss/;
 874   s/message size = \d+\b/message size = sss/;
 875   s/this message = \d+\b/this message = sss/;
 876   s/Size of headers = \d+/Size of headers = sss/;
 877   s/sum=(?!0)\d+/sum=dddd/;
 878   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 879   s/(?<=sum=0 )count=\d+\b/count=dd/;
 880   s/,S is \d+\b/,S is ddddd/;
 881   s/\+0100,\d+;/+0100,ddd;/;
 882   s/\(\d+ bytes written\)/(ddd bytes written)/;
 883   s/added '\d+ 1'/added 'ddd 1'/;
 884   s/Received\s+\d+/Received               nnn/;
 885   s/Delivered\s+\d+/Delivered              nnn/;
 886
 887
 888   # ======== Values in spool space failure message ========
 889   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 890
 891
 892   # ======== Filter sizes ========
 893   # The sizes of filter files may vary because of the substitution of local
 894   # filenames, logins, etc.
 895
 896   s/^\d+(?= (\(tainted\) )?bytes read from )/ssss/;
 897
 898
 899   # ======== OpenSSL error messages ========
 900   # Different releases of the OpenSSL libraries seem to give different error
 901   # numbers, or handle specific bad conditions in different ways, leading to
 902   # different wording in the error messages, so we cannot compare them.
 903
 904 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 905 #    but I can't work out how to deal with that.
 906   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 907   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 908   next if /SSL verify error: depth=0 error=certificate not trusted/;
 909
 910   # ======== Maildir things ========
 911   # timestamp output in maildir processing
 912   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 913
 914   # maildir delivery files appearing in log lines (in cases of error)
 915   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 916
 917   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 918
 919   # Maildir file names in general
 920   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 921
 922   # Maildirsize data
 923   while (/^\d+S,\d+C\s*$/)
 924     {
 925     print MUNGED;
 926     while (<IN>)
 927       {
 928       last if !/^\d+ \d+\s*$/;
 929       print MUNGED "ddd d\n";
 930       }
 931     last if !defined $_;
 932     }
 933   last if !defined $_;
 934
 935
 936   # SRS timestamps and signatures vary by hostname and from run to run
 937
 938   s/SRS0=....=..=[^=]+=[^@]+\@test.ex/SRS0=ZZZZ=YY=the.local.host.name=CALLER\@test.ex/;
 939
 940
 941   # ======== Output from the "fd" program about open descriptors ========
 942   # The statuses seem to be different on different operating systems, but
 943   # at least we'll still be checking the number of open fd's.
 944
 945   s/max fd = \d+/max fd = dddd/;
 946   s/status=[0-9a-f]+ (?:RDONLY|WRONLY|RDWR)/STATUS/g;
 947
 948
 949   # ======== Contents of spool files ========
 950   # A couple of tests dump the contents of the -H file. The length fields
 951   # will be wrong because of different user names, etc.
 952   s/^\d\d\d(?=[PFS*])/ddd/;
 953
 954
 955   # ========= Exim lookups ==================
 956   # Lookups have a char which depends on the number of lookup types compiled in,
 957   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 958   # other output is fragile; perhaps the debug output should be revised instead.
 959   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 960
 961   # ==========================================================
 962   # MIME boundaries in RFC3461 DSN messages
 963   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 964
 965   # ==========================================================
 966   # Some munging is specific to the specific file types
 967
 968   # ======== stdout ========
 969
 970   if ($is_stdout)
 971     {
 972     # Skip translate_ip_address and use_classresources in -bP output because
 973     # they aren't always there.
 974
 975     next if /translate_ip_address =/;
 976     next if /use_classresources/;
 977
 978     # In certain filter tests, remove initial filter lines because they just
 979     # clog up by repetition.
 980
 981     if ($rmfiltertest)
 982       {
 983       next if /^(Sender\staken\sfrom|
 984                  Return-path\scopied\sfrom|
 985                  Sender\s+=|
 986                  Recipient\s+=)/x;
 987       if (/^Testing \S+ filter/)
 988         {
 989         $_ = <IN>;    # remove blank line
 990         next;
 991         }
 992       }
 993
 994     # remote IPv6 addrs vary
 995     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 996
 997     # openssl version variances
 998   # Error lines on stdout from SSL contain process id values and file names.
 999   # They also contain a source file name and line number, which may vary from
1000   # release to release.
1001
1002     next if /^SSL info:/;
1003     next if /SSL verify error: depth=0 error=certificate not trusted/;
1004     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
1005     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
1006     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
1007     s/^error:[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/error:dddddddd:$1/;
1008
1009     # gnutls version variances
1010     next if /^Error in the pull function./;
1011
1012     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
1013     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
1014     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
1015
1016     # subsecond timstamp info in reported header-files
1017     s/^(-received_time_usec \.)\d{6}$/$1uuuuuu/;
1018
1019     # Postgres server takes varible time to shut down; lives in various places
1020     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
1021     s/^\/.*postgres /POSTGRES /;
1022
1023     # DMARC is not always supported by the build
1024     next if /^dmarc_tld_file =/;
1025
1026     # ARC is not always supported by the build
1027     next if /^arc_sign =/;
1028
1029     # TLS resumption is not always supported by the build
1030     next if /^tls_resumption_hosts =/;
1031     next if /^-tls_resumption/;
1032     }
1033
1034   # ======== stderr ========
1035
1036   elsif ($is_stderr)
1037     {
1038     # The very first line of debugging output will vary
1039
1040     s/^Exim version .*/Exim version x.yz ..../;
1041
1042     # Debugging lines for Exim terminations and process-generation
1043
1044     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
1045     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
1046     s/^(?:\s*\d+ )(exec .* -oPX)$/pppp $1/;
1047
1048     # IP address lookups use gethostbyname() when IPv6 is not supported,
1049     # and gethostbyname2() or getipnodebyname() when it is.
1050
1051     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
1052
1053     # we don't care what TZ enviroment the testhost was running
1054     next if /^Reset TZ to/;
1055
1056     # drop gnutls version strings
1057     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1058     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1059
1060     # drop openssl version strings
1061     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1062     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1063
1064     # this is timing-dependent
1065     next if /^OpenSSL: creating STEK$/;
1066
1067     # drop lookups
1068     next if /^Lookups \(built-in\):/;
1069     next if /^Loading lookup modules from/;
1070     next if /^Loaded \d+ lookup modules/;
1071     next if /^Total \d+ lookups/;
1072
1073     # drop compiler information
1074     next if /^Compiler:/;
1075
1076     # and the ugly bit
1077     # different libraries will have different numbers (possibly 0) of follow-up
1078     # lines, indenting with more data
1079     if (/^Library version:/) {
1080       while (1) {
1081         $_ = <IN>;
1082         next if /^\s/;
1083         goto RESET_AFTER_EXTRA_LINE_READ;
1084       }
1085     }
1086
1087     # drop other build-time controls emitted for debugging
1088     next if /^WHITELIST_D_MACROS:/;
1089     next if /^TRUSTED_CONFIG_LIST:/;
1090
1091     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1092     # with -be, privileges will have been dropped, so this will always
1093     # be the case
1094     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1095
1096     # We might not keep this check; rather than change all the tests, just
1097     # ignore it as long as it succeeds; then we only need to change the
1098     # TLS tests where tls_require_ciphers has been set.
1099     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1100       my $discard = <IN>;
1101       next;
1102     }
1103     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1104
1105     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1106     next if /^macros_trusted overridden to true by whitelisting/;
1107
1108     # We have to omit the localhost ::1 address so that all is well in
1109     # the IPv4-only case.
1110
1111     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1112       if (/looked up these IP addresses/);
1113     next if /name=localhost address=::1/;
1114
1115     # drop pdkim debugging header
1116     next if /^DKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1117
1118     # Various other IPv6 lines must be omitted too
1119
1120     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1121     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1122     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1123     next if / in dns_ipv4_lookup?/;
1124     next if / writing neg-cache entry for .*AAAA/;
1125     next if /^faking res_search\(AAAA\) response length as 65535/;
1126
1127     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1128       {
1129       $_= <IN>;     # Gets "returning DNS_NODATA"
1130       next;
1131       }
1132
1133     # Non-TLS bulds have a different Recieved: header expansion
1134     s/^((.*)\t}}}}by \$primary_hostname \$\{if def:received_protocol \{with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1135     s/^((\s*).*considering: with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1136     if (/condition: def:tls_in_cipher_std$/)
1137       {
1138       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1139       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1140       $_= <IN>; $_= <IN>; $_= <IN>; next;
1141       }
1142
1143
1144     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1145     # are unset, because tls ain't always there.
1146
1147     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1148                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1149
1150     # Skip auxiliary group lists because they will vary.
1151
1152     next if /auxiliary group list:/;
1153
1154     # Skip "extracted from gecos field" because the gecos field varies
1155
1156     next if /extracted from gecos field/;
1157
1158     # Skip "waiting for data on socket" and "read response data: size=" lines
1159     # because some systems pack more stuff into packets than others.
1160
1161     next if /waiting for data on socket/;
1162     next if /read response data: size=/;
1163
1164     # If Exim is compiled with readline support but it can't find the library
1165     # to load, there will be an extra debug line. Omit it.
1166
1167     next if /failed to load readline:/;
1168
1169     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1170     # O_CREAT; other's don't. In the latter case there is some debugging output
1171     # which is not present in the former. Skip the relevant lines (there are
1172     # three of them).
1173
1174     if (/returned from EXIM_DBOPEN: \(nil\)/)
1175       {
1176       $_ .= <IN>;
1177       s?\Q$parm_cwd\E?TESTSUITE?g;
1178       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1179         { $_ = <IN>; next; }
1180       }
1181
1182     # Some tests turn on +expand debugging to check on expansions.
1183     # Unfortunately, the Received: expansion varies, depending on whether TLS
1184     # is compiled or not. So we must remove the relevant debugging if it is.
1185
1186     if (/^condition: def:tls_cipher/)
1187       {
1188       while (<IN>) { last if /^condition: def:sender_address/; }
1189       }
1190     elsif (/^expanding: Received: /)
1191       {
1192       while (<IN>) { last if !/^\s/; }
1193       }
1194
1195     # remote port numbers vary
1196     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1197
1198     # Platform-dependent error strings
1199     s/Operation timed out/Connection timed out/;
1200
1201     # Platform differences on disconnect
1202     s/unexpected disconnection while reading SMTP command from \[127.0.0.1\] \K\(error: Connection reset by peer\) //;
1203
1204     # Platform-dependent resolver option bits
1205     s/^ (?:writing|update) neg-cache entry for [^,]+-\K[0-9a-f]+, ttl/xxxx, ttl/;
1206
1207     # timing variance, run-to-run
1208     s/^time on queue = \K1s/0s/;
1209
1210     # Skip hosts_require_dane checks when the options
1211     # are unset, because dane ain't always there.
1212     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1213
1214     # DISABLE_OCSP
1215     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1216
1217     # SUPPORT_PROXY
1218     next if /host in hosts_proxy\?/;
1219
1220     # PIPE_CONNECT
1221     next if / in (pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1222
1223     # Experimental_International
1224     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1225
1226     # Experimental_REQUIRETLS
1227     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1228
1229     # TCP Fast Open
1230     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1231
1232     # Environment cleaning
1233     next if /\w+ in keep_environment\? (yes|no)/;
1234
1235     # Sizes vary with test hostname
1236     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1237
1238     # Spool filesystem free space changes on different systems.
1239     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1240
1241     # Non-TLS builds have different expansions for received_header_text
1242     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1243       {
1244       $_ .= <IN>;
1245       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1246       }
1247     if (/^ ├──condition: def:tls_cipher$/)
1248       {
1249       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1250       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1251       }
1252
1253     # Not all platforms build with DKIM enabled
1254     next if /^DKIM >> Body data for hash, canonicalized/;
1255
1256     # Not all platforms build with SPF enabled
1257     next if /^(spf_conn_init|SPF_dns_exim_new|spf_compile\.c)/;
1258
1259     # Not all platforms have sendfile support
1260     next if /^cannot use sendfile for body: no support$/;
1261
1262     #  Parts of DKIM-specific debug output depend on the time/date
1263     next if /^date:\w+,\{SP\}/;
1264     next if /^DKIM \[[^[]+\] (Header hash|b) computed:/;
1265
1266     # Not all platforms support TCP Fast Open, and the compile omits the check
1267     if (s/\S+ in hosts_try_fastopen\? (no \(option unset\)|no \(end of list\)|yes \(matched "\*"\))\n$//)
1268       {
1269       chomp;
1270       $_ .= <IN>;
1271       s/ \.\.\. >>> / ... /;
1272       if (s/ non-TFO mode connection attempt to 224.0.0.0, 0 data\b$//) { chomp; $_ .= <IN>; }
1273       s/Address family not supported by protocol family/Network Error/;
1274       s/Network is unreachable/Network Error/;
1275       }
1276     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1277     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1278
1279     if (/^([0-9: ]*                                             # possible timestamp
1280         Connecting\ to\ [^ ]+\ [^ ]+(\ from\ [^ ]+)?)\ \.\.\.
1281         \ .*TFO\ mode\x20
1282         (sendto,\ no\ data:\ EINPROGRESS                        # Linux
1283         |connection\ attempt\ to\ [^,]+,\ 0\ data)              # MacOS & no-support
1284         $/x)
1285       {
1286       $_ = $1 . " ... " . <IN>;
1287       s/^(.* \.\.\.) [0-9: ]*connected$/$1  connected/;
1288
1289       if (/^Connecting to .* \.\.\.  connected$/)
1290         {
1291         $_ .= <IN>;
1292         if (/^(Connecting to .* \.\.\.  )connected\n\s+SMTP(\(close\)>>|\(Connection refused\)<<)$/)
1293           {
1294           $_ = $1 . "failed: Connection refused\n" . <IN>;
1295           s/^(Connecting .*)\n\s+SMTP\(close\)>>$/$1/;
1296           }
1297         elsif (/^(Connecting to .* \.\.\.  connected\n)read response data: size=/)
1298           { $_ = $1; }
1299
1300         # Date/time in SMTP banner
1301         s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
1302           /Tue, 2 Mar 1999 09:44:33 +0000/gx;
1303         }
1304       }
1305
1306     # Specific pointer values reported for DB operations change from run to run
1307     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1308     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1309
1310     # Platform-dependent output during MySQL startup
1311     next if /PerconaFT file system space/;
1312     next if /^Waiting for MySQL server to answer/;
1313     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1314
1315     # Not all builds include DMARC
1316     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1317
1318     # TLS resumption is not always supported by the build
1319     next if /in tls_resumption_hosts\?/;
1320
1321     # Platform differences in errno strings
1322     s/  SMTP\(Operation timed out\)<</  SMTP(Connection timed out)<</;
1323
1324     # Platform differences for errno values (eg. Hurd)
1325     s/^errno = \d+$/errno = EEE/;
1326     s/^writing error \d+: /writing error EEE: /;
1327
1328     # When Exim is checking the size of directories for maildir, it uses
1329     # the check_dir_size() function to scan directories. Of course, the order
1330     # of the files that are obtained using readdir() varies from system to
1331     # system. We therefore buffer up debugging lines from check_dir_size()
1332     # and sort them before outputting them.
1333
1334     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1335       {
1336       push @saved, $_;
1337       }
1338     else
1339       {
1340       if (@saved > 0)
1341         {
1342         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1343           "to ensure consistency\n";
1344         @saved = sort(@saved);
1345         print MUNGED @saved;
1346         @saved = ();
1347         }
1348
1349       # Skip some lines that Exim puts out at the start of debugging output
1350       # because they will be different in different binaries.
1351
1352       print MUNGED
1353         unless (/^Berkeley DB: / ||
1354                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1355                 /^Authenticators:/ ||
1356                 /^Lookups:/ ||
1357                 /^Support for:/ ||
1358                 /^Routers:/ ||
1359                 /^Transports:/ ||
1360                 /^Malware:/ ||
1361                 /^log selectors =/ ||
1362                 /^cwd=/ ||
1363                 /^Fixed never_users:/ ||
1364                 /^Configure owner:/ ||
1365                 /^Size of off_t:/
1366                 );
1367
1368
1369       }
1370
1371     next;
1372     }
1373
1374   # ======== log ========
1375
1376   elsif ($is_log)
1377     {
1378     # Berkeley DB version differences
1379     next if / Berkeley DB error: /;
1380
1381     # CHUNKING: exact sizes depend on hostnames in headers
1382     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1383
1384     # openssl version variances
1385     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1386     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(?:(?i)ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1387     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1388     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:(PEM routines):get_name:(no start line)/0906D06C:$1:PEM_read_bio:$2/;
1389
1390     # gnutls version variances
1391     if (/TLS error on connection \(recv\): .* (Decode error|peer did not send any certificate)/)
1392       {
1393       my $prev = $_;
1394       $_ = <IN>;
1395       if (/error on first read/)
1396         {
1397         s/TLS session: \Kerror on first read:/(gnutls_handshake): A TLS fatal alert has been received.:/;
1398         goto RESET_AFTER_EXTRA_LINE_READ;
1399         }
1400       else
1401         { $_ = $prev; }
1402       }
1403     # translate gnutls error into the openssl one
1404     s/ARC: AMS signing: privkey PEM-block import: \KThe requested data were not available.$/error:0906D06C:PEM routines:PEM_read_bio:no start line/;
1405
1406     # DKIM timestamps
1407     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1408       {
1409       my ($prefix, $t_diff) = ($1, $3 - $2);
1410       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1411       }
1412
1413     # port numbers
1414     s/(?:\[[^\]]*\]:|port )\K$parm_port_d/PORT_D/;
1415     s/(?:\[[^\]]*\]:|port )\K$parm_port_d2/PORT_D2/;
1416     s/(?:\[[^\]]*\]:|port )\K$parm_port_d3/PORT_D3/;
1417     s/(?:\[[^\]]*\]:|port )\K$parm_port_d4/PORT_D4/;
1418     s/(?:\[[^\]]*\]:|port )\K$parm_port_s/PORT_S/;
1419     s/(?:\[[^\]]*\]:|port )\K$parm_port_n/PORT_N/;
1420     s/I=\[[^\]]*\]:\K\d+/ppppp/;
1421
1422     # Platform differences for errno values (eg. Hurd).  Leave 0 and negative numbers alone.
1423     s/R=\w+ T=\w+ defer\K \([1-9]\d*\): / (EEE): /;
1424
1425     # Platform differences in errno strings
1426     s/Arg list too long/Argument list too long/;
1427     }
1428
1429   # ======== mail ========
1430
1431   elsif ($is_mail)
1432     {
1433     # DKIM timestamps, and signatures depending thereon
1434     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1435       {
1436       my ($indent, $t_diff) = ($1, $3 - $2);
1437       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1438       <IN>;
1439       <IN>;
1440       }
1441     }
1442
1443   # ======== All files other than stderr ========
1444
1445   print MUNGED;
1446   }
1447
1448 close(IN);
1449 return $yield;
1450 }
1451
1452
1453
1454
1455 ##################################################
1456 #        Subroutine to interact with caller      #
1457 ##################################################
1458
1459 # Arguments: [0] the prompt string
1460 #            [1] if there is a U in the prompt and $force_update is true
1461 #            [2] if there is a C in the prompt and $force_continue is true
1462 # Returns:   returns the answer
1463
1464 sub interact {
1465   my ($prompt, $have_u, $have_c) = @_;
1466
1467   print $prompt;
1468
1469   if ($have_u) {
1470     print "... update forced\n";
1471     return 'u';
1472   }
1473
1474   if ($have_c) {
1475     print "... continue forced\n";
1476     return 'c';
1477   }
1478
1479   return lc <T>;
1480 }
1481
1482
1483
1484 ##################################################
1485 #    Subroutine to log in force_continue mode    #
1486 ##################################################
1487
1488 # In force_continue mode, we just want a terse output to a statically
1489 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1490 # all have mismatches, it will log multiple times.
1491 #
1492 # Arguments: [0] the logfile to append to
1493 #            [1] the testno that failed
1494 # Returns:   nothing
1495
1496
1497
1498 sub log_failure {
1499   my ($logfile, $testno, $detail) = @_;
1500
1501   open(my $fh, '>>', $logfile) or return;
1502
1503   print $fh "Test $testno "
1504         . (defined $detail ? "$detail " : '')
1505         . "failed\n";
1506 }
1507
1508 # Computer-readable summary results logfile
1509
1510 sub log_test {
1511   my ($logfile, $testno, $resultchar) = @_;
1512
1513   open(my $fh, '>>', $logfile) or return;
1514   print $fh "$testno $resultchar\n";
1515 }
1516
1517
1518
1519 ##################################################
1520 #    Subroutine to compare one output file       #
1521 ##################################################
1522
1523 # When an Exim server is part of the test, its output is in separate files from
1524 # an Exim client. The server data is concatenated with the client data as part
1525 # of the munging operation.
1526 #
1527 # Arguments:  [0] the name of the main raw output file
1528 #             [1] the name of the server raw output file or undef
1529 #             [2] where to put the munged copy
1530 #             [3] the name of the saved file
1531 #             [4] TRUE if this is a log file whose deliveries must be sorted
1532 #             [5] optionally, a custom munge command
1533 #
1534 # Returns:    0 comparison succeeded
1535 #             1 comparison failed; differences to be ignored
1536 #             2 comparison failed; files may have been updated (=> re-compare)
1537 #
1538 # Does not return if the user replies "Q" to a prompt.
1539
1540 sub check_file{
1541 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1542
1543 # If there is no saved file, the raw files must either not exist, or be
1544 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1545
1546 # we check if there is a flavour specific file, but we remember
1547 # the original file name as "generic"
1548 $sf_generic = $sf;
1549 $sf_flavour = "$sf_generic.$flavour";
1550 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1551
1552 if (! -e $sf_current)
1553   {
1554   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1555
1556   print "\n";
1557   print "** $rf is not empty\n" if (-s $rf);
1558   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1559
1560   for (;;)
1561     {
1562     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1563     tests_exit(1) if /^q?$/;
1564     if (/^c$/ && $force_continue) {
1565       log_failure($log_failed_filename, $testno, $rf);
1566       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1567     }
1568     return 1 if /^c$/i && $rf !~ /paniclog/ && (!defined $rsf || $rsf !~ /paniclog/);
1569     last if (/^[sc]$/);
1570     }
1571
1572   foreach $f ($rf, $rsf)
1573     {
1574     if (defined $f && -s $f)
1575       {
1576       print "\n";
1577       print "------------ $f -----------\n"
1578         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1579       system @more => $f;
1580       }
1581     }
1582
1583   print "\n";
1584   for (;;)
1585     {
1586     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1587     tests_exit(1) if /^q?$/;
1588     if (/^c$/ && $force_continue) {
1589       log_failure($log_failed_filename, $testno, $rf);
1590       log_test($log_summary_filename, $testno, 'F')
1591     }
1592     return 1 if /^c$/i;
1593     last if (/^u$/i);
1594     }
1595   }
1596
1597 #### $_
1598
1599 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1600 # was a request to create a saved file. First, create the munged file from any
1601 # data that does exist.
1602
1603 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1604 my($truncated) = munge($rf, $extra) if -e $rf;
1605
1606 # Append the raw server log, if it is non-empty
1607 if (defined $rsf && -e $rsf)
1608   {
1609   print MUNGED "\n******** SERVER ********\n";
1610   $truncated |= munge($rsf, $extra);
1611   }
1612 close(MUNGED);
1613
1614 # If a saved file exists, do the comparison. There are two awkward cases:
1615 #
1616 # If "*** truncated ***" was found in the new file, it means that a log line
1617 # was overlong, and truncated. The problem is that it may be truncated at
1618 # different points on different systems, because of different user name
1619 # lengths. We reload the file and the saved file, and remove lines from the new
1620 # file that precede "*** truncated ***" until we reach one that matches the
1621 # line that precedes it in the saved file.
1622 #
1623 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1624 # for an individual message might vary in their order from system to system, as
1625 # a result of parallel deliveries. We load the munged file and sort sequences
1626 # of delivery lines.
1627
1628 if (-e $sf_current)
1629   {
1630   # Deal with truncated text items
1631
1632   if ($truncated)
1633     {
1634     my(@munged, @saved, $i, $j, $k);
1635
1636     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1637     @munged = <MUNGED>;
1638     close(MUNGED);
1639     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1640     @saved = <SAVED>;
1641     close(SAVED);
1642
1643     $j = 0;
1644     for ($i = 0; $i < @munged; $i++)
1645       {
1646       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1647         {
1648         for (; $j < @saved; $j++)
1649           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1650         last if $j >= @saved;     # not found in saved
1651
1652         for ($k = $i - 1; $k >= 0; $k--)
1653           { last if $munged[$k] eq $saved[$j - 1]; }
1654
1655         last if $k <= 0;          # failed to find previous match
1656         splice @munged, $k + 1, $i - $k - 1;
1657         $i = $k + 1;
1658         }
1659       }
1660
1661     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1662     print $fh @munged;
1663     }
1664
1665   # Deal with log sorting
1666
1667   if ($sortfile)
1668     {
1669
1670     my @munged = do {
1671       open(my $fh, '<', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1672       <$fh>;
1673     };
1674
1675     for (my $i = 0; $i < @munged; $i++)
1676       {
1677       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1678         {
1679         my $j;
1680         for ($j = $i + 1; $j < @munged; $j++)
1681           {
1682           last if $munged[$j] !~
1683             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1684           }
1685         @temp = splice(@munged, $i, $j - $i);
1686         @temp = sort(@temp);
1687         splice(@munged, $i, 0, @temp);
1688         }
1689       }
1690
1691     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1692     print $fh "**NOTE: The delivery lines in this file have been sorted.\n";
1693     print $fh @munged;
1694     }
1695
1696   # Do the comparison
1697
1698   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1699
1700   # Handle comparison failure
1701
1702   print "** Comparison of $mf with $sf_current failed";
1703   system @more => 'test-cf';
1704
1705   print "\n";
1706   for (;;)
1707     {
1708     $_ = interact('Continue, Retry, Update current'
1709         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1710         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1711     tests_exit(1) if /^q?$/;
1712     if (/^c$/ && $force_continue) {
1713       log_failure($log_failed_filename, $testno, $sf_current);
1714       log_test($log_summary_filename, $testno, 'F')
1715     }
1716     return 1 if /^c$/i;
1717     return 2 if /^r$/i;
1718     last if (/^[us]$/i);
1719     }
1720   }
1721
1722 # Update or delete the saved file, and give the appropriate return code.
1723
1724 if (-s $mf)
1725   {
1726     my $sf = /^u/i ? $sf_current : $sf_flavour;
1727     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1728   }
1729 else
1730   {
1731     # if we deal with a flavour file, we can't delete it, because next time the generic
1732     # file would be used again
1733     if ($sf_current eq $sf_flavour) {
1734       open(my $fh, '>', $sf_current);
1735     }
1736     else {
1737       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1738     }
1739   }
1740
1741 return 2;
1742 }
1743
1744
1745
1746 ##################################################
1747 # Custom munges
1748 # keyed by name of munge; value is a ref to a hash
1749 # which is keyed by file, value a string to look for.
1750 # Usable files are:
1751 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1752 # Search strings starting with 's' do substitutions;
1753 # with '/' do line-skips.
1754 # Triggered by a scriptfile line "munge <name>"
1755 ##################################################
1756 $munges =
1757   { 'dnssec' =>
1758     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1759
1760     'gnutls_unexpected' =>
1761     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1762
1763     'gnutls_handshake' =>
1764     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1765
1766     'gnutls_bad_clientcert' =>
1767     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1768       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1769     },
1770
1771     'optional_events' =>
1772     { 'stdout' => '/event_action =/' },
1773
1774     'optional_ocsp' =>
1775     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1776
1777     'optional_cert_hostnames' =>
1778     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1779
1780     'loopback' =>
1781     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1782
1783     'scanfile_size' =>
1784     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1785
1786     'delay_1500' =>
1787     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1788
1789     'tls_anycipher' =>
1790     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1791                       s! DN="C=! DN="/C=!;
1792                       s! DN="[^,"]*\K,!/!;
1793                       s! DN="[^,"]*\K,!/!;
1794                       s! DN="[^,"]*\K,!/!;
1795                      ',
1796       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1797     },
1798
1799     'debug_pid' =>
1800     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d+/ppppp/g' },
1801
1802     'optional_dsn_info' =>
1803     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1804     },
1805
1806     'optional_config' =>
1807     { 'stdout' => '/^(
1808                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1809                   |gnutls_require_(kx|mac|protocols)
1810                   |hosts_pipe_connect
1811                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1812                   |dane_require_tls_ciphers
1813                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1814                   |pipelining_connect_advertise_hosts
1815                   |socks_proxy
1816                   |tls_[^ ]*
1817                   |utf8_downconvert
1818                   )($|[ ]=)/x'
1819     },
1820
1821     'sys_bindir' =>
1822     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1823
1824     'sync_check_data' =>
1825     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1826       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1827
1828     'debuglog_stdout' =>
1829     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1830                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1831     },
1832
1833     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1834     { 'mainlog' => 's/((?:host|message) deferral .* errno) <\d+> /$1 <EEE> /' },
1835
1836     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1837     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1838
1839     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1840     { 'stdout' => 's%^> X/X$%> X%' },
1841   };
1842
1843
1844 sub max {
1845   my ($a, $b) = @_;
1846   return $a if ($a > $b);
1847   return $b;
1848 }
1849
1850 ##################################################
1851 #    Subroutine to check the output of a test    #
1852 ##################################################
1853
1854 # This function is called when the series of subtests is complete. It makes
1855 # use of check_file(), whose arguments are:
1856 #
1857 #  [0] the name of the main raw output file
1858 #  [1] the name of the server raw output file or undef
1859 #  [2] where to put the munged copy
1860 #  [3] the name of the saved file
1861 #  [4] TRUE if this is a log file whose deliveries must be sorted
1862 #  [5] an optional custom munge command
1863 #
1864 # Arguments: Optionally, name of a single custom munge to run.
1865 # Returns:   0 if the output compared equal
1866 #            1 if comparison failed; differences to be ignored
1867 #            2 if re-run needed (files may have been updated)
1868
1869 sub check_output{
1870 my($mungename) = $_[0];
1871 my($yield) = 0;
1872 my($munge) = $munges->{$mungename} if defined $mungename;
1873
1874 $yield = max($yield,  check_file("spool/log/paniclog",
1875                        "spool/log/serverpaniclog",
1876                        "test-paniclog-munged",
1877                        "paniclog/$testno", 0,
1878                        $munge->{paniclog}));
1879
1880 $yield = max($yield,  check_file("spool/log/rejectlog",
1881                        "spool/log/serverrejectlog",
1882                        "test-rejectlog-munged",
1883                        "rejectlog/$testno", 0,
1884                        $munge->{rejectlog}));
1885
1886 $yield = max($yield,  check_file("spool/log/mainlog",
1887                        "spool/log/servermainlog",
1888                        "test-mainlog-munged",
1889                        "log/$testno", $sortlog,
1890                        $munge->{mainlog}));
1891
1892 if (!$stdout_skip)
1893   {
1894   $yield = max($yield,  check_file("test-stdout",
1895                        "test-stdout-server",
1896                        "test-stdout-munged",
1897                        "stdout/$testno", 0,
1898                        $munge->{stdout}));
1899   }
1900
1901 if (!$stderr_skip)
1902   {
1903   $yield = max($yield,  check_file("test-stderr",
1904                        "test-stderr-server",
1905                        "test-stderr-munged",
1906                        "stderr/$testno", 0,
1907                        $munge->{stderr}));
1908   }
1909
1910 # Compare any delivered messages, unless this test is skipped.
1911
1912 if (! $message_skip)
1913   {
1914   my($msgno) = 0;
1915
1916   # Get a list of expected mailbox files for this script. We don't bother with
1917   # directories, just the files within them.
1918
1919   foreach $oldmail (@oldmails)
1920     {
1921     next unless $oldmail =~ /^mail\/$testno\./;
1922     print ">> EXPECT $oldmail\n" if $debug;
1923     $expected_mails{$oldmail} = 1;
1924     }
1925
1926   # If there are any files in test-mail, compare them. Note that "." and
1927   # ".." are automatically omitted by list_files_below().
1928
1929   @mails = list_files_below("test-mail");
1930
1931   foreach $mail (@mails)
1932     {
1933     next if $mail eq "test-mail/oncelog";
1934
1935     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1936     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1937
1938     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1939       {
1940       $msgno++;
1941       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1942       }
1943
1944     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1945     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1946       "mail/$testno.$saved_mail", 0,
1947       $munge->{mail}));
1948     delete $expected_mails{"mail/$testno.$saved_mail"};
1949     }
1950
1951   # Complain if not all expected mails have been found
1952
1953   if (scalar(keys %expected_mails) != 0)
1954     {
1955     foreach $key (keys %expected_mails)
1956       { print "** no test file found for $key\n"; }
1957
1958     for (;;)
1959       {
1960       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1961       tests_exit(1) if /^q?$/;
1962       if (/^c$/ && $force_continue) {
1963         log_failure($log_failed_filename, $testno, "missing email");
1964         log_test($log_summary_filename, $testno, 'F')
1965       }
1966       last if /^c$/;
1967
1968       # For update, we not only have to unlink the file, but we must also
1969       # remove it from the @oldmails vector, as otherwise it will still be
1970       # checked for when we re-run the test.
1971
1972       if (/^u$/)
1973         {
1974         foreach $key (keys %expected_mails)
1975           {
1976           my($i);
1977           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1978           for ($i = 0; $i < @oldmails; $i++)
1979             {
1980             if ($oldmails[$i] eq $key)
1981               {
1982               splice @oldmails, $i, 1;
1983               last;
1984               }
1985             }
1986           }
1987         last;
1988         }
1989       }
1990     }
1991   }
1992
1993 # Compare any remaining message logs, unless this test is skipped.
1994
1995 if (! $msglog_skip)
1996   {
1997   # Get a list of expected msglog files for this test
1998
1999   foreach $oldmsglog (@oldmsglogs)
2000     {
2001     next unless $oldmsglog =~ /^$testno\./;
2002     $expected_msglogs{$oldmsglog} = 1;
2003     }
2004
2005   # If there are any files in spool/msglog, compare them. However, we have
2006   # to munge the file names because they are message ids, which are
2007   # time dependent.
2008
2009   if (opendir(DIR, "spool/msglog"))
2010     {
2011     @msglogs = sort readdir(DIR);
2012     closedir(DIR);
2013
2014     foreach $msglog (@msglogs)
2015       {
2016       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
2017       ($munged_msglog = $msglog) =~
2018         s/((?:[^\W_]{6}-){2}[^\W_]{2})
2019           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
2020       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
2021         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
2022         $munge->{msglog}));
2023       delete $expected_msglogs{"$testno.$munged_msglog"};
2024       }
2025     }
2026
2027   # Complain if not all expected msglogs have been found
2028
2029   if (scalar(keys %expected_msglogs) != 0)
2030     {
2031     foreach $key (keys %expected_msglogs)
2032       {
2033       print "** no test msglog found for msglog/$key\n";
2034       ($msgid) = $key =~ /^\d+\.(.*)$/;
2035       foreach $cachekey (keys %cache)
2036         {
2037         if ($cache{$cachekey} eq $msgid)
2038           {
2039           print "** original msgid $cachekey\n";
2040           last;
2041           }
2042         }
2043       }
2044
2045     for (;;)
2046       {
2047       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
2048       tests_exit(1) if /^q?$/;
2049       if (/^c$/ && $force_continue) {
2050         log_failure($log_failed_filename, $testno, "missing msglog");
2051         log_test($log_summary_filename, $testno, 'F')
2052       }
2053       last if /^c$/;
2054       if (/^u$/)
2055         {
2056         foreach $key (keys %expected_msglogs)
2057           {
2058           tests_exit(-1, "Failed to unlink msglog/$key")
2059             if !unlink("msglog/$key");
2060           }
2061         last;
2062         }
2063       }
2064     }
2065   }
2066
2067 return $yield;
2068 }
2069
2070
2071
2072 ##################################################
2073 #     Subroutine to run one "system" command     #
2074 ##################################################
2075
2076 # We put this in a subroutine so that the command can be reflected when
2077 # debugging.
2078 #
2079 # Argument: the command to be run
2080 # Returns:  nothing
2081
2082 sub run_system {
2083 my($cmd) = $_[0];
2084 if ($debug)
2085   {
2086   my($prcmd) = $cmd;
2087   $prcmd =~ s/; /;\n>> /;
2088   print ">> $prcmd\n";
2089   }
2090 system("$cmd");
2091 }
2092
2093
2094
2095 ##################################################
2096 #      Subroutine to run one script command      #
2097 ##################################################
2098
2099 # The <SCRIPT> file is open for us to read an optional return code line,
2100 # followed by the command line and any following data lines for stdin. The
2101 # command line can be continued by the use of \. Data lines are not continued
2102 # in this way. In all lines, the following substitutions are made:
2103 #
2104 # DIR    => the current directory
2105 # CALLER => the caller of this script
2106 #
2107 # Arguments: the current test number
2108 #            reference to the subtest number, holding previous value
2109 #            reference to the expected return code value
2110 #            reference to where to put the command name (for messages)
2111 #            auxiliary information returned from a previous run
2112 #
2113 # Returns:   0 the command was executed inline, no subprocess was run
2114 #            1 a non-exim command was run and waited for
2115 #            2 an exim command was run and waited for
2116 #            3 a command was run and not waited for (daemon, server, exim_lock)
2117 #            4 EOF was encountered after an initial return code line
2118 # Optionally also a second parameter, a hash-ref, with auxiliary information:
2119 #            exim_pid: pid of a run process
2120 #            munge: name of a post-script results munger
2121
2122 sub run_command{
2123 my($testno) = $_[0];
2124 my($subtestref) = $_[1];
2125 my($commandnameref) = $_[3];
2126 my($aux_info) = $_[4];
2127 my($yield) = 1;
2128
2129 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
2130
2131 if (/^(\d+)\s*$/)                # Handle unusual return code
2132   {
2133   my($r) = $_[2];
2134   $$r = $1 << 8;
2135   $_ = <SCRIPT>;
2136   return 4 if !defined $_;       # Missing command
2137   $lineno++;
2138   }
2139
2140 chomp;
2141 $wait_time = 0;
2142
2143 # Handle concatenated command lines
2144
2145 s/\s+$//;
2146 while (substr($_, -1) eq"\\")
2147   {
2148   my($temp);
2149   $_ = substr($_, 0, -1);
2150   chomp($temp = <SCRIPT>);
2151   if (defined $temp)
2152     {
2153     $lineno++;
2154     $temp =~ s/\s+$//;
2155     $temp =~ s/^\s+//;
2156     $_ .= $temp;
2157     }
2158   }
2159
2160 # Do substitutions
2161
2162 do_substitute($testno);
2163 if ($debug) { printf ">> $_\n"; }
2164
2165 # Pass back the command name (for messages)
2166
2167 ($$commandnameref) = /^(\S+)/;
2168
2169 # Here follows code for handling the various different commands that are
2170 # supported by this script. The first group of commands are all freestanding
2171 # in that they share no common code and are not followed by any data lines.
2172
2173
2174 ###################
2175 ###################
2176
2177 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2178 # utility and to make DBM files for testing DBM lookups.
2179
2180 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2181   {
2182   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2183          "echo exim_dbmbuild exit code = \$?)" .
2184          ">>test-stdout");
2185   return 1;
2186   }
2187
2188
2189 # The "dump" command runs exim_dumpdb. On different systems, the output for
2190 # some types of dump may appear in a different order because it's just hauled
2191 # out of the DBM file. We can solve this by sorting. Ignore the leading
2192 # date/time, as it will be flattened later during munging.
2193
2194 if (/^dump\s+(\S+)/)
2195   {
2196   my $which  = $1;
2197   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2198   open(my $in, "-|", './eximdir/exim_dumpdb', "$parm_cwd/spool", $which) or die "Can't run exim_dumpdb: $!";
2199   open(my $out, ">>test-stdout");
2200   print $out "+++++++++++++++++++++++++++\n";
2201
2202   if ($which eq "retry")
2203     {
2204     # the sort key is the first part of the retry db dump line, but for
2205     # sorting we (temporarly) replace the own hosts ipv4 with a munged
2206     # version, which matches the munging that is done later
2207     # Why? We must ensure sure, that 127.0.0.1 always sorts first
2208     # map-sort-map: Schwartz's transformation
2209     # test 0099
2210     my @temp = map  { $_->[1] }
2211                sort { $a->[0] cmp $b->[0] }
2212                #map  { [ (split)[0] =~ s/\Q$parm_ipv4/ip4.ip4.ip4.ip4/gr, $_ ] }  # this is too modern for 5.10.1
2213                map  {
2214                 (my $k = (split)[0]) =~ s/\Q$parm_ipv4/ip4.ip4.ip4.ip4/g;
2215                 [ $k, $_ ]
2216                }
2217                do { local $/ = "\n  "; <$in> };
2218     foreach $item (@temp)
2219       {
2220       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2221       print $out "  $item\n";
2222       }
2223     }
2224   else
2225     {
2226     my @temp = <$in>;
2227     if ($which eq "callout")
2228       {
2229       @temp = sort {
2230                    my($aa) = substr $a, 21;
2231                    my($bb) = substr $b, 21;
2232                    return $aa cmp $bb;
2233                    } @temp;
2234       }
2235     print $out @temp;
2236     }
2237   close($in); # close it explicitly, otherwise $? does not get set
2238   return 1;
2239   }
2240
2241
2242 # verbose comments start with ###
2243 if (/^###\s/) {
2244   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2245     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2246     say {$fh} $_;
2247   }
2248   return 0;
2249 }
2250
2251 # The "echo" command is a way of writing comments to the screen.
2252 if (/^echo\s+(.*)$/)
2253   {
2254   print "$1\n";
2255   return 0;
2256   }
2257
2258
2259 # The "exim_lock" command runs exim_lock in the same manner as "server",
2260 # but it doesn't use any input.
2261
2262 if (/^exim_lock\s+(.*)$/)
2263   {
2264   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2265   $server_pid = open SERVERCMD, "|$cmd" ||
2266     tests_exit(-1, "Failed to run $cmd\n");
2267
2268   # This gives the process time to get started; otherwise the next
2269   # process may not find it there when it expects it.
2270
2271   select(undef, undef, undef, 0.1);
2272   return 3;
2273   }
2274
2275
2276 # The "exinext" command runs exinext
2277
2278 if (/^exinext\s+(.*)/)
2279   {
2280   run_system("(./eximdir/exinext " .
2281     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2282     "-C $parm_cwd/test-config $1;" .
2283     "echo exinext exit code = \$?)" .
2284     ">>test-stdout");
2285   return 1;
2286   }
2287
2288
2289 # The "exigrep" command runs exigrep on the current mainlog
2290
2291 if (/^exigrep\s+(.*)/)
2292   {
2293   run_system("(./eximdir/exigrep " .
2294     "$1 $parm_cwd/spool/log/mainlog;" .
2295     "echo exigrep exit code = \$?)" .
2296     ">>test-stdout");
2297   return 1;
2298   }
2299
2300
2301 # The "eximstats" command runs eximstats on the current mainlog
2302
2303 if (/^eximstats\s+(.*)/)
2304   {
2305   run_system("(./eximdir/eximstats " .
2306     "$1 $parm_cwd/spool/log/mainlog;" .
2307     "echo eximstats exit code = \$?)" .
2308     ">>test-stdout");
2309   return 1;
2310   }
2311
2312
2313 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2314 # spool directory, to save Exim from re-creating it each time.
2315
2316 if (/^gnutls/)
2317   {
2318   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2319   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2320          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2321          "sudo chmod 0400 $gen_fn";
2322   return 1;
2323   }
2324
2325
2326 # The "killdaemon" command should ultimately follow the starting of any Exim
2327 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2328 # it outputting "Terminated" to the terminal when not in the background.
2329
2330 if (/^killdaemon/)
2331   {
2332   my $return_extra = {};
2333   if (exists $aux_info->{exim_pid})
2334     {
2335     $pid = $aux_info->{exim_pid};
2336     $return_extra->{exim_pid} = undef;
2337     print ">> killdaemon: recovered pid $pid\n" if $debug;
2338     if ($pid)
2339       {
2340       run_system("sudo /bin/kill -INT $pid");
2341       wait;
2342       }
2343     } else {
2344     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2345     if ($pid)
2346       {
2347       run_system("sudo /bin/kill -INT $pid");
2348       close DAEMONCMD;                                   # Waits for process
2349       }
2350     }
2351     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2352   return (1, $return_extra);
2353   }
2354
2355
2356 # The "millisleep" command is like "sleep" except that its argument is in
2357 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2358 # is used for.
2359
2360 elsif (/^millisleep\s+(.*)$/)
2361   {
2362   select(undef, undef, undef, $1/1000);
2363   return 0;
2364   }
2365
2366
2367 # The "munge" command selects one of a hardwired set of test-result modifications
2368 # to be made before result compares are run against the golden set.  This lets
2369 # us account for test-system dependent things which only affect a few, but known,
2370 # test-cases.
2371 # Currently only the last munge takes effect.
2372
2373 if (/^munge\s+(.*)$/)
2374   {
2375   return (0, { munge => $1 });
2376   }
2377
2378
2379 # The "sleep" command does just that. For sleeps longer than 1 second we
2380 # tell the user what's going on.
2381
2382 if (/^sleep\s+(.*)$/)
2383   {
2384   if ($1 == 1)
2385     {
2386     sleep(1);
2387     }
2388   else
2389     {
2390     printf("  Test %d sleep $1 ", $$subtestref);
2391     for (1..$1)
2392       {
2393       print ".";
2394       sleep(1);
2395       }
2396     printf("\r  Test %d                            $cr", $$subtestref);
2397     }
2398   return 0;
2399   }
2400
2401
2402 # Various Unix management commands are recognized
2403
2404 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2405     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2406   {
2407   run_system("$_ >>test-stdout 2>>test-stderr");
2408   return 1;
2409   }
2410
2411
2412
2413 ###################
2414 ###################
2415
2416 # The next group of commands are also freestanding, but they are all followed
2417 # by data lines.
2418
2419
2420 # The "server" command starts up a script-driven server that runs in parallel
2421 # with the following exim command. Therefore, we want to run a subprocess and
2422 # not yet wait for it to complete. The waiting happens after the next exim
2423 # command, triggered by $server_pid being non-zero. The server sends its output
2424 # to a different file. The variable $server_opts, if not empty, contains
2425 # options to disable IPv4 or IPv6 if necessary.
2426 # This works because "server" swallows its stdin before waiting for a connection.
2427
2428 if (/^server\s+(.*)$/)
2429   {
2430   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2431   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2432   print ">> $cmd\n" if ($debug);
2433   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2434   SERVERCMD->autoflush(1);
2435   print ">> Server pid is $server_pid\n" if $debug;
2436   while (<SCRIPT>)
2437     {
2438     $lineno++;
2439     last if /^\*{4}\s*$/;
2440     print SERVERCMD;
2441     }
2442   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2443                             # because close() waits for the process.
2444
2445   # Interlock the server startup; otherwise the next
2446   # process may not find it there when it expects it.
2447   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2448   return 3;
2449   }
2450
2451
2452 # The "write" command is a way of creating files of specific sizes for
2453 # buffering tests, or containing specific data lines from within the script
2454 # (rather than hold lots of little files). The "catwrite" command does the
2455 # same, but it also copies the lines to test-stdout.
2456
2457 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2458   {
2459   my($cat) = defined $1;
2460   @sizes = ();
2461   @sizes = split /\s+/, $3 if defined $3;
2462   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2463
2464   if ($cat)
2465     {
2466     open CAT, ">>test-stdout" ||
2467       tests_exit(-1, "Failed to open test-stdout: $!");
2468     print CAT "==========\n";
2469     }
2470
2471   if (scalar @sizes > 0)
2472     {
2473     # Pre-data
2474
2475     while (<SCRIPT>)
2476       {
2477       $lineno++;
2478       last if /^\+{4}\s*$/;
2479       print FILE;
2480       print CAT if $cat;
2481       }
2482
2483     # Sized data
2484
2485     while (scalar @sizes > 0)
2486       {
2487       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2488       $leadin = '' if !defined $leadin;
2489       $leadin =~ s/_/ /g;
2490       $len -= length($leadin) + 1;
2491       while ($count-- > 0)
2492         {
2493         print FILE $leadin, "a" x $len, "\n";
2494         print CAT $leadin, "a" x $len, "\n" if $cat;
2495         }
2496       }
2497     }
2498
2499   # Post data, or only data if no sized data
2500
2501   while (<SCRIPT>)
2502     {
2503     $lineno++;
2504     last if /^\*{4}\s*$/;
2505     print FILE;
2506     print CAT if $cat;
2507     }
2508   close FILE;
2509
2510   if ($cat)
2511     {
2512     print CAT "==========\n";
2513     close CAT;
2514     }
2515
2516   return 0;
2517   }
2518
2519
2520 ###################
2521 ###################
2522
2523 # From this point on, script commands are implemented by setting up a shell
2524 # command in the variable $cmd. Shared code to run this command and handle its
2525 # input and output follows.
2526
2527 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2528 # program that plays the part of an email client. We also have the availability
2529 # of running Perl for doing one-off special things. Note that all these
2530 # commands expect stdin data to be supplied.
2531
2532 if (/^client/ || /^(sudo\s+)?perl\b/)
2533   {
2534   s"client"./bin/client";
2535   $cmd = "$_ >>test-stdout 2>>test-stderr";
2536   }
2537
2538 # For the "exim" command, replace the text "exim" with the path for the test
2539 # binary, plus -D options to pass over various parameters, and a -C option for
2540 # the testing configuration file. When running in the test harness, Exim does
2541 # not drop privilege when -C and -D options are present. To run the exim
2542 # command as root, we use sudo.
2543
2544 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2545   {
2546   $args = $6;
2547   my($envset) = (defined $1)? $1      : '';
2548   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2549   my($special)= (defined $5)? $5      : '';
2550   $wait_time  = (defined $2)? $2      : 0;
2551
2552   # Return 2 rather than 1 afterwards
2553
2554   $yield = 2;
2555
2556   # Update the test number
2557
2558   $$subtestref = $$subtestref + 1;
2559   printf("  Test %d       $cr", $$subtestref);
2560
2561   # Copy the configuration file, making the usual substitutions.
2562
2563   open (IN, "$parm_cwd/confs/$testno") ||
2564     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2565   open (OUT, ">test-config") ||
2566     tests_exit(-1, "Couldn't open test-config: $!\n");
2567   while (<IN>)
2568     {
2569     do_substitute($testno);
2570     print OUT;
2571     }
2572   close(IN);
2573   close(OUT);
2574
2575   # The string $msg1 in args substitutes the message id of the first
2576   # message on the queue, and so on. */
2577
2578   if ($args =~ /\$msg/)
2579     {
2580     my($queuespec);
2581     if ($args =~ /-qG\w+/) { $queuespec = $&; }
2582
2583     my @listcmd;
2584
2585     if (defined $queuespec)
2586       {
2587       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2588                    $queuespec,
2589                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2590                    -C => "$parm_cwd/test-config");
2591       }
2592     else
2593       {
2594       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2595                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2596                    -C => "$parm_cwd/test-config");
2597       }
2598     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2599     # We need the message ids sorted in ascending order.
2600     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2601     # PIDs are randomized, so sorting just the whole PID doesn't work.
2602     # We do the Schartz' transformation here (sort on
2603     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2604     my @msglist =
2605       map { $_->[1] }                                   # extract the values
2606       sort { $a->[0] cmp $b->[0] }                      # sort by key
2607       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2608       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2609
2610     # Done backwards just in case there are more than 9
2611
2612     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2613     if ( $args =~ /\$msg\d/ )
2614       {
2615       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2616         unless $force_continue;
2617       }
2618     }
2619
2620   # If -d is specified in $optargs, remove it from $args; i.e. let
2621   # the command line for runtest override. Then run Exim.
2622
2623   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2624
2625   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2626
2627   $cmd = "$envset$sudo$opt_valgrind" .
2628          "$parm_cwd/eximdir/exim$special$optargs " .
2629          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2630          "-C $parm_cwd/test-config $args " .
2631          ">>test-stdout 2>>test-stderr";
2632   # If the command is starting an Exim daemon, we run it in the same
2633   # way as the "server" command above, that is, we don't want to wait
2634   # for the process to finish. That happens when "killdaemon" is obeyed later
2635   # in the script. We also send the stderr output to test-stderr-server. The
2636   # daemon has its log files put in a different place too (by configuring with
2637   # log_file_path). This requires the  directory to be set up in advance.
2638   #
2639   # There are also times when we want to run a non-daemon version of Exim
2640   # (e.g. a queue runner) with the server configuration. In this case,
2641   # we also define -DNOTDAEMON.
2642
2643   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2644     {
2645     if ($debug) { printf ">> daemon: $cmd\n"; }
2646     run_system("sudo mkdir spool/log 2>/dev/null");
2647     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2648
2649     # Before running the command, convert the -bd option into -bdf so that an
2650     # Exim daemon doesn't double fork. This means that when we wait close
2651     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2652     # file is written to the spool directory, in case the Exim binary was
2653     # built with PID_FILE_PATH pointing somewhere else.
2654
2655     if ($cmd =~ /\s-oP\s/)
2656       {
2657       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2658       $cmd =~ s!\s-bd\s! -bdf !;
2659       }
2660     else
2661       {
2662       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2663       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2664       }
2665     print ">> |${cmd}-server\n" if ($debug);
2666     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2667     DAEMONCMD->autoflush(1);
2668     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2669
2670     # Interlock with daemon startup
2671     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2672       { select(undef, undef, undef, 0.3); }
2673     return 3;                                     # Don't wait
2674     }
2675   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2676     {
2677
2678     # The port and the $dynamic_socket was already allocated while parsing the
2679     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2680
2681     my $listen_port = $1;
2682     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2683     run_system("sudo mkdir spool/log 2>/dev/null");
2684     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2685
2686     my $pid = fork();
2687     if (not defined $pid) { die "** fork failed: $!\n" }
2688     if (not $pid) {
2689       close(STDIN);
2690       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2691       close($dynamic_socket);
2692       print "[$$]>> ${cmd}-server\n" if ($debug);
2693       exec "exec ${cmd}-server";
2694       die "Can't exec ${cmd}-server: $!\n";
2695     }
2696     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2697     select(undef, undef, undef, 0.3);             # Let the daemon get going
2698     return (3, { exim_pid => $pid });             # Don't wait
2699     }
2700   }
2701
2702 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2703 # One script line is read and fork-exec'd.  The PID is stored for a later
2704 # killdaemon.
2705
2706 elsif (/^background$/)
2707   {
2708   my $line;
2709 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2710
2711   $_ = <SCRIPT>; $lineno++;
2712   chomp;
2713   do_substitute($testno);
2714   $line = $_;
2715   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2716
2717   my $pid = fork();
2718   if (not defined $pid) { die "** fork failed: $!\n" }
2719   if (not $pid) {
2720     print "[$$]>> ${line}\n" if ($debug);
2721     close(STDIN);
2722     open(STDIN, "<", "test-stdout");
2723     close(STDOUT);
2724     open(STDOUT, ">>", "test-stdout");
2725     close(STDERR);
2726     open(STDERR, ">>", "test-stderr-server");
2727     exec "exec ${line}";
2728     exit(1);
2729   }
2730
2731 #  open(my $fh, ">", $pidfile) ||
2732 #      tests_exit(-1, "Failed to open $pidfile: $!");
2733 #  printf($fh, "%d\n", $pid);
2734 #  close($fh);
2735
2736   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2737   select(undef, undef, undef, 0.3);             # Let the daemon get going
2738   return (3, { exim_pid => $pid });             # Don't wait
2739   }
2740
2741
2742
2743 # Unknown command
2744
2745 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2746
2747
2748 # Run the command, with stdin connected to a pipe, and write the stdin data
2749 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2750 # the terminating newline (and the \NONL\). If the command contains
2751 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2752 # for the stderr file. See comment above about the use of -DSERVER.
2753
2754 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2755 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2756 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2757
2758 CMD->autoflush(1);
2759 while (<SCRIPT>)
2760   {
2761   $lineno++;
2762   last if /^\*{4}\s*$/;
2763   do_substitute($testno);
2764   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2765   }
2766
2767 # For timeout tests, wait before closing the pipe; we expect a
2768 # SIGPIPE error in this case.
2769
2770 if ($wait_time > 0)
2771   {
2772   printf("  Test %d sleep $wait_time ", $$subtestref);
2773   while ($wait_time-- > 0)
2774     {
2775     print ".";
2776     sleep(1);
2777     }
2778   printf("\r  Test %d                                       $cr", $$subtestref);
2779   }
2780
2781 $sigpipehappened = 0;
2782 close CMD;                # Waits for command to finish
2783 return $yield;            # Ran command and waited
2784 }
2785
2786
2787
2788
2789 ###############################################################################
2790 ###############################################################################
2791
2792 # Here begins the Main Program ...
2793
2794 ###############################################################################
2795 ###############################################################################
2796
2797
2798 autoflush STDOUT 1;
2799 print "Exim tester $testversion\n";
2800
2801 # extend the PATH with .../sbin
2802 # we map all (.../bin) to (.../sbin:.../bin)
2803 $ENV{PATH} = do {
2804   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2805   join ':' => map { m{(.*)/bin$}
2806                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2807                 : ($_) }
2808       split /:/, $ENV{PATH};
2809 };
2810
2811 ##################################################
2812 #      Some tests check created file modes       #
2813 ##################################################
2814
2815 umask 022;
2816
2817
2818 ##################################################
2819 #       Check for the "less" command             #
2820 ##################################################
2821
2822 @more = 'more' if system('which less >/dev/null 2>&1') != 0;
2823
2824
2825
2826 ##################################################
2827 #      See if an Exim binary has been given      #
2828 ##################################################
2829
2830 # If the first character of the first argument is '/', the argument is taken
2831 # as the path to the binary. If the first argument does not start with a
2832 # '/' but exists in the file system, it's assumed to be the Exim binary.
2833
2834
2835 ##################################################
2836 # Sort out options and which tests are to be run #
2837 ##################################################
2838
2839 # There are a few possible options for the test script itself; after these, any
2840 # options are passed on to Exim calls within the tests. Typically, this is used
2841 # to turn on Exim debugging while setting up a test.
2842
2843 Getopt::Long::Configure qw(no_getopt_compat);
2844 GetOptions(
2845     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2846     'diff'     => sub { $cf             = 'diff -u' },
2847     'continue' => sub { $force_continue = 1; @more = 'cat' },
2848     'update'   => \$force_update,
2849     'ipv4!'    => \$have_ipv4,
2850     'ipv6!'    => \$have_ipv6,
2851     'keep'     => \$save_output,
2852     'slow'     => \$slow,
2853     'valgrind' => \$valgrind,
2854     'range=s{2}'       => \my @range_wanted,
2855     'test=i@'          => \my @tests_wanted,
2856     'flavor|flavour=s' => \$flavour,
2857     'help'             => sub { pod2usage(-exit => 0) },
2858     'man'              => sub {
2859         pod2usage(
2860             -exit      => 0,
2861             -verbose   => 2,
2862             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2863         );
2864     },
2865 ) or pod2usage;
2866
2867 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2868 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2869
2870
2871 my @wanted = sort numerically uniq
2872   @tests_wanted ? @tests_wanted : (),
2873   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
2874   @ARGV ? @ARGV == 1 ? $ARGV[0] :
2875           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
2876           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
2877         : ();
2878 @wanted = 1..TEST_TOP if not @wanted;
2879
2880 ##################################################
2881 #        Check for sudo access to root           #
2882 ##################################################
2883
2884 print "You need to have sudo access to root to run these tests. Checking ...\n";
2885 if (system('sudo true >/dev/null') != 0)
2886   {
2887   die "** Test for sudo failed: testing abandoned.\n";
2888   }
2889 else
2890   {
2891   print "Test for sudo OK\n";
2892   }
2893
2894
2895
2896
2897 ##################################################
2898 #      Make the command's directory current      #
2899 ##################################################
2900
2901 # After doing so, we find its absolute path name.
2902
2903 $cwd = $0;
2904 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2905 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2906 $parm_cwd = Cwd::getcwd();
2907
2908
2909 ##################################################
2910 #     Search for an Exim binary to test          #
2911 ##################################################
2912
2913 # If an Exim binary hasn't been provided, try to find one. We can handle the
2914 # case where exim-testsuite is installed alongside Exim source directories. For
2915 # PH's private convenience, if there's a directory just called "exim4", that
2916 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2917 # releases.
2918
2919 # If $parm_exim is still empty, ask the caller
2920
2921 if (not $parm_exim)
2922   {
2923   print "** Did not find an Exim binary to test\n";
2924   for ($i = 0; $i < 5; $i++)
2925     {
2926     my($trybin);
2927     print "** Enter pathname for Exim binary: ";
2928     chomp($trybin = <STDIN>);
2929     if (-e $trybin)
2930       {
2931       $parm_exim = $trybin;
2932       last;
2933       }
2934     else
2935       {
2936       print "** $trybin does not exist\n";
2937       }
2938     }
2939   die "** Too many tries\n" if $parm_exim eq '';
2940   }
2941
2942
2943
2944 ##################################################
2945 #          Find what is in the binary            #
2946 ##################################################
2947
2948 # deal with TRUSTED_CONFIG_LIST restrictions
2949 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2950 open (IN, "$parm_cwd/confs/0000") ||
2951   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2952 open (OUT, ">test-config") ||
2953   tests_exit(-1, "Couldn't open test-config: $!\n");
2954 while (<IN>) { print OUT; }
2955 close(IN);
2956 close(OUT);
2957
2958 print("Probing with config file: $parm_cwd/test-config\n");
2959
2960 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2961 chomp(my @eximinfo = `$eximinfo 2>&1`);
2962 die "$0: Can't run $eximinfo\n" if $? == -1;
2963
2964 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2965 foreach (@eximinfo)
2966   {
2967   if (my ($version) = /^Exim version (\S+)/) {
2968     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2969     if (defined $git and $? == 0) {
2970       chomp $git;
2971       $git =~ s/^exim-//i;
2972       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2973       print <<___
2974
2975 *** Version mismatch
2976 *** Exim binary: $version
2977 *** Git        : $git
2978
2979 ___
2980         if not $version eq $git;
2981     }
2982   }
2983   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2984   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2985   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2986   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2987         if /^Configure owner:\s*(\d+):(\d+)/;
2988   print if /wrong owner/;
2989   }
2990
2991 if (not defined $parm_eximuser) {
2992   die <<XXX, map { "|$_\n" } @eximinfo;
2993 Unable to extract exim_user from binary.
2994 Check if Exim refused to run; if so, consider:
2995   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2996 If debug permission denied, are you in the exim group?
2997 Failing to get information from binary.
2998 Output from $eximinfo:
2999 XXX
3000
3001 }
3002
3003 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
3004 else { $parm_exim_uid = getpwnam($parm_eximuser); }
3005
3006 if (defined $parm_eximgroup)
3007   {
3008   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
3009     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
3010   }
3011
3012 # check the permissions on the TRUSTED_CONFIG_LIST
3013 if (defined $parm_trusted_config_list)
3014   {
3015   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
3016     if not -f $parm_trusted_config_list;
3017
3018   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
3019     if 02 & (stat _)[2];
3020
3021   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
3022   (stat _)[1],
3023     scalar(getgrgid 0), scalar(getgrgid $>)
3024     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
3025
3026   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
3027   scalar(getpwuid 0), scalar(getpwuid $>)
3028      if (not (-o _ or (stat _)[4] == 0));
3029
3030   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
3031   my $test_config = getcwd() . '/test-config';
3032   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
3033   if not grep { /^\Q$test_config\E$/ } <TCL>;
3034   }
3035 else
3036   {
3037   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
3038   }
3039
3040 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
3041         if $parm_configure_owner != $>;
3042
3043 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
3044         if 0020 & (stat "$parm_cwd/test-config")[2]
3045         and $parm_configure_group != $);
3046
3047 die "aux-fixed file is group-writeable; best to strip them all, recursively\n"
3048         if 0020 & (stat "aux-fixed/0037.f-1")[2];
3049
3050
3051 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
3052   die "** Cannot run $parm_exim: $!\n";
3053
3054 print "-" x 78, "\n";
3055
3056 while (<EXIMINFO>)
3057   {
3058   my(@temp);
3059
3060   if (/^(Exim|Library) version/) { print; }
3061   if (/Runtime: /) {print; }
3062
3063   elsif (/^Size of off_t: (\d+)/)
3064     {
3065     print;
3066     $have_largefiles = 1 if $1 > 4;
3067     die "** Size of off_t > 32 which seems improbable, not running tests\n"
3068         if ($1 > 32);
3069     }
3070
3071   elsif (/^Support for: (.*)/)
3072     {
3073     print;
3074     @temp = split /(\s+)/, $1;
3075     push(@temp, ' ');
3076     %parm_support = @temp;
3077     }
3078
3079   elsif (/^Lookups \(built-in\): (.*)/)
3080     {
3081     print;
3082     @temp = split /(\s+)/, $1;
3083     push(@temp, ' ');
3084     %parm_lookups = @temp;
3085     }
3086
3087   elsif (/^Authenticators: (.*)/)
3088     {
3089     print;
3090     @temp = split /(\s+)/, $1;
3091     push(@temp, ' ');
3092     %parm_authenticators = @temp;
3093     }
3094
3095   elsif (/^Routers: (.*)/)
3096     {
3097     print;
3098     @temp = split /(\s+)/, $1;
3099     push(@temp, ' ');
3100     %parm_routers = @temp;
3101     }
3102
3103   # Some transports have options, e.g. appendfile/maildir. For those, ensure
3104   # that the basic transport name is set, and then the name with each of the
3105   # options.
3106
3107   elsif (/^Transports: (.*)/)
3108     {
3109     print;
3110     @temp = split /(\s+)/, $1;
3111     my($i,$k);
3112     push(@temp, ' ');
3113     %parm_transports = @temp;
3114     foreach $k (keys %parm_transports)
3115       {
3116       if ($k =~ "/")
3117         {
3118         @temp = split /\//, $k;
3119         $parm_transports{$temp[0]} = " ";
3120         for ($i = 1; $i < @temp; $i++)
3121           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
3122         }
3123       }
3124     }
3125
3126   elsif (/^Malware: (.*)/)
3127     {
3128     print;
3129     @temp = split /(\s+)/, $1;
3130     push(@temp, ' ');
3131     %parm_malware = @temp;
3132     }
3133
3134   }
3135 close(EXIMINFO);
3136 print "-" x 78, "\n";
3137
3138 unlink("$parm_cwd/test-config");
3139
3140 ##################################################
3141 #    Check for SpamAssassin and ClamAV           #
3142 ##################################################
3143
3144 # These are crude tests. If they aren't good enough, we'll have to improve
3145 # them, for example by actually passing a message through spamc or clamscan.
3146
3147 if (defined $parm_support{Content_Scanning})
3148   {
3149   my $sock = new FileHandle;
3150
3151   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
3152     {
3153     print "The spamc command works:\n";
3154
3155     # This test for an active SpamAssassin is courtesy of John Jetmore.
3156     # The tests are hard coded to localhost:783, so no point in making
3157     # this test flexible like the clamav test until the test scripts are
3158     # changed.  spamd doesn't have the nice PING/PONG protocol that
3159     # clamd does, but it does respond to errors in an informative manner,
3160     # so use that.
3161
3162     my($sint,$sport) = ('127.0.0.1',783);
3163     eval
3164       {
3165       my $sin = sockaddr_in($sport, inet_aton($sint))
3166           or die "** Failed packing $sint:$sport\n";
3167       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3168           or die "** Unable to open socket $sint:$sport\n";
3169
3170       local $SIG{ALRM} =
3171           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3172       alarm(5);
3173       connect($sock, $sin)
3174           or die "** Unable to connect to socket $sint:$sport\n";
3175       alarm(0);
3176
3177       select((select($sock), $| = 1)[0]);
3178       print $sock "bad command\r\n";
3179
3180       $SIG{ALRM} =
3181           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3182       alarm(10);
3183       my $res = <$sock>;
3184       alarm(0);
3185
3186       $res =~ m|^SPAMD/|
3187           or die "** Did not get SPAMD from socket $sint:$sport. "
3188                 ."It said: $res\n";
3189       };
3190     alarm(0);
3191     if($@)
3192       {
3193       print "  $@";
3194       print "  Assume SpamAssassin (spamd) is not running\n";
3195       }
3196     else
3197       {
3198       $parm_running{SpamAssassin} = ' ';
3199       print "  SpamAssassin (spamd) seems to be running\n";
3200       }
3201     }
3202   else
3203     {
3204     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3205     }
3206
3207   # For ClamAV, we need to find the clamd socket for use in the Exim
3208   # configuration. Search for the clamd configuration file.
3209
3210   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3211     {
3212     my($f, $clamconf, $test_prefix);
3213
3214     print "The clamscan command works";
3215
3216     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3217     $test_prefix = '' if !defined $test_prefix;
3218
3219     foreach $f ("$test_prefix/etc/clamd.conf",
3220                 "$test_prefix/usr/local/etc/clamd.conf",
3221                 "$test_prefix/etc/clamav/clamd.conf", '')
3222       {
3223       if (-e $f)
3224         {
3225         $clamconf = $f;
3226         last;
3227         }
3228       }
3229
3230     # Read the ClamAV configuration file and find the socket interface.
3231
3232     if ($clamconf ne '')
3233       {
3234       my $socket_domain;
3235       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3236       while (<IN>)
3237         {
3238         if (/^LocalSocket\s+(.*)/)
3239           {
3240           $parm_clamsocket = $1;
3241           $socket_domain = AF_UNIX;
3242           last;
3243           }
3244         if (/^TCPSocket\s+(\d+)/)
3245           {
3246           if (defined $parm_clamsocket)
3247             {
3248             $parm_clamsocket .= " $1";
3249             $socket_domain = AF_INET;
3250             last;
3251             }
3252           else
3253             {
3254             $parm_clamsocket = " $1";
3255             }
3256           }
3257         elsif (/^TCPAddr\s+(\S+)/)
3258           {
3259           if (defined $parm_clamsocket)
3260             {
3261             $parm_clamsocket = $1 . $parm_clamsocket;
3262             $socket_domain = AF_INET;
3263             last;
3264             }
3265           else
3266             {
3267             $parm_clamsocket = $1;
3268             }
3269           }
3270         }
3271       close(IN);
3272
3273       if (defined $socket_domain)
3274         {
3275         print ":\n  The clamd socket is $parm_clamsocket\n";
3276         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3277         eval
3278           {
3279           my $socket;
3280           if ($socket_domain == AF_UNIX)
3281             {
3282             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3283             }
3284           elsif ($socket_domain == AF_INET)
3285             {
3286             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3287             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3288             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3289             }
3290           else
3291             {
3292             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3293             }
3294           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3295           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3296           alarm(5);
3297           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3298           alarm(0);
3299
3300           my $ofh = select $sock; $| = 1; select $ofh;
3301           print $sock "PING\n";
3302
3303           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3304           alarm(10);
3305           my $res = <$sock>;
3306           alarm(0);
3307
3308           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3309           };
3310         alarm(0);
3311
3312         if($@)
3313           {
3314           print "  $@";
3315           print "  Assume ClamAV is not running\n";
3316           }
3317         else
3318           {
3319           $parm_running{ClamAV} = ' ';
3320           print "  ClamAV seems to be running\n";
3321           }
3322         }
3323       else
3324         {
3325         print ", but the socket for clamd could not be determined\n";
3326         print "Assume ClamAV is not running\n";
3327         }
3328       }
3329
3330     else
3331       {
3332       print ", but I can't find a configuration for clamd\n";
3333       print "Assume ClamAV is not running\n";
3334       }
3335     }
3336   }
3337
3338
3339 ##################################################
3340 #       Check for redis                          #
3341 ##################################################
3342 if (defined $parm_lookups{redis})
3343   {
3344   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3345     {
3346     print "The redis-server command works\n";
3347     $parm_running{redis} = ' ';
3348     }
3349   else
3350     {
3351     print "The redis-server command failed: assume Redis not installed\n";
3352     }
3353   }
3354
3355 ##################################################
3356 #         Test for the basic requirements        #
3357 ##################################################
3358
3359 # This test suite assumes that Exim has been built with at least the "usual"
3360 # set of routers, transports, and lookups. Ensure that this is so.
3361
3362 $missing = '';
3363
3364 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3365
3366 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3367 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3368 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3369 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3370
3371 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3372 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3373 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3374 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3375
3376 if ($missing ne '')
3377   {
3378   print "\n";
3379   print "** Many features can be included or excluded from Exim binaries.\n";
3380   print "** This test suite requires that Exim is built to contain a certain\n";
3381   print "** set of basic facilities. It seems that some of these are missing\n";
3382   print "** from the binary that is under test, so the test cannot proceed.\n";
3383   print "** The missing facilities are:\n";
3384   print "$missing";
3385   die "** Test script abandoned\n";
3386   }
3387
3388
3389 ##################################################
3390 #      Check for the auxiliary programs          #
3391 ##################################################
3392
3393 # These are always required:
3394
3395 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3396            "fakens", "iefbr14", "server")
3397   {
3398   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3399   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3400   if (!-e "bin/$prog")
3401     {
3402     print "\n";
3403     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3404     die "** Test script abandoned\n";
3405     }
3406   }
3407
3408 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3409 # compiled on systems where we don't know how to. However, if Exim does not
3410 # have that functionality compiled, we needn't bother.
3411
3412 $dlfunc_deleted = 0;
3413 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3414   {
3415   delete $parm_support{Expand_dlfunc};
3416   $dlfunc_deleted = 1;
3417   }
3418
3419
3420 ##################################################
3421 #          Find environmental details            #
3422 ##################################################
3423
3424 # Find the caller of this program.
3425
3426 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3427  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3428
3429 $pwpw = $pwpw;       # Kill Perl warnings
3430 $pwquota = $pwquota;
3431 $pwcomm = $pwcomm;
3432
3433 $parm_caller_group = getgrgid($parm_caller_gid);
3434
3435 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3436 print "Home directory is $parm_caller_home\n";
3437
3438 unless (defined $parm_eximgroup)
3439   {
3440   print "Unable to derive \$parm_eximgroup.\n";
3441   die "** ABANDONING.\n";
3442   }
3443
3444 if ($parm_caller_home eq $parm_cwd)
3445   {
3446   print "will confuse working dir with homedir; change homedir\n";
3447   die "** ABANDONING.\n";
3448   }
3449
3450 print "You need to be in the Exim group to run these tests. Checking ...";
3451
3452 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3453   {
3454   print " OK\n";
3455   }
3456 else
3457   {
3458   print "\nOh dear, you are not in the Exim group.\n";
3459   die "** Testing abandoned.\n";
3460   }
3461
3462 # Find this host's IP addresses - there may be many, of course, but we keep
3463 # one of each type (IPv4 and IPv6).
3464 #XXX it would be good to avoid non-UP interfaces
3465
3466 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3467   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3468 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3469   {
3470   if (/^(?:[0-9]+: )?([a-z0-9]+): /) { $ifname = $1; }
3471
3472   if (not $parm_ipv4 and /^\s*inet(?:\saddr(?:ess))?:?\s*(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3473     {
3474     # It would be nice to be able to vary the /16 used for manyhome; we could take
3475     # an option to runtest used here - but we'd also have to pass it on to fakens.
3476     # Possibly an environment variable?
3477     next if $1 eq '0.0.0.0' or $1 =~ /^(?:127|10\.250)\./;
3478     $parm_ipv4 = $1;
3479     }
3480
3481   if (   (not $parm_ipv6 or $parm_ipv6 =~ /%/)
3482      and /^\s*inet6(?:\saddr(?:ess))?:?\s*([abcdef\d:]+)(?:%[^ \/]+)?(?:\/\d+)?/i)
3483     {
3484     next if $1 eq '::' or $1 eq '::1' or $1 =~ /^ff00/i or $1 =~ /^fe80::1/i;
3485     $parm_ipv6 = $1;
3486     if ($1 =~ /^fe80/i) { $parm_ipv6 .= '%' . $ifname; }
3487     }
3488   }
3489 close(IFCONFIG);
3490
3491 # Use private IP addresses if there are no public ones.
3492
3493 # If either type of IP address is missing, we need to set the value to
3494 # something other than empty, because that wrecks the substitutions. The value
3495 # is reflected, so use a meaningful string. Set appropriate options for the
3496 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3497 # available, so things will go wrong if there is no IPv4 address. The lack
3498 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3499 # and $have_ipv6 false.
3500
3501 if (not $parm_ipv4)
3502   {
3503   $have_ipv4 = 0;
3504   $parm_ipv4 = "<no IPv4 address found>";
3505   $server_opts .= " -noipv4";
3506   }
3507 elsif ($have_ipv4 == 0)
3508   {
3509   $parm_ipv4 = "<IPv4 testing disabled>";
3510   $server_opts .= " -noipv4";
3511   }
3512 else
3513   {
3514   $parm_running{IPv4} = " ";
3515   }
3516
3517 if (not $parm_ipv6)
3518   {
3519   $have_ipv6 = 0;
3520   $parm_ipv6 = "<no IPv6 address found>";
3521   $server_opts .= " -noipv6";
3522   delete($parm_support{IPv6});
3523   }
3524 elsif ($have_ipv6 == 0)
3525   {
3526   $parm_ipv6 = "<IPv6 testing disabled>";
3527   $server_opts .= " -noipv6";
3528   delete($parm_support{IPv6});
3529   }
3530 elsif (!defined $parm_support{IPv6})
3531   {
3532   $have_ipv6 = 0;
3533   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3534   $server_opts .= " -noipv6";
3535   }
3536 else
3537   {
3538   $parm_running{IPv6} = " ";
3539   }
3540
3541 print "IPv4 address is $parm_ipv4\n";
3542 print "IPv6 address is $parm_ipv6\n";
3543 $parm_ipv6 =~ /^[^%\/]*/;
3544 # drop any %scope from the ipv6, for some uses
3545 ($parm_ipv6_stripped = $parm_ipv6) =~ s/%.*//g;
3546
3547 # For munging test output, we need the reversed IP addresses.
3548
3549 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3550   join(".", reverse(split /\./, $parm_ipv4));
3551
3552 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3553 if ($parm_ipv6 =~ /^[\da-f]/)
3554   {
3555   my(@comps) = split /:/, $parm_ipv6_stripped;
3556   my(@nibbles);
3557   foreach $comp (@comps)
3558     {
3559     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3560     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3561     }
3562   $parm_ipv6r = join(".", reverse(@nibbles));
3563   }
3564
3565 # Find the host name, fully qualified.
3566
3567 chomp($temp = `hostname`);
3568 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3569 if ($temp =~ /\./)
3570   {
3571   $parm_hostname = $temp;
3572   }
3573 else
3574   {
3575   $parm_hostname = (gethostbyname($temp))[0];
3576   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3577   }
3578 print "Hostname is $parm_hostname\n";
3579
3580 if ($parm_hostname !~ /\./)
3581   {
3582   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3583   }
3584
3585 if ($parm_hostname =~ /[[:upper:]]/)
3586   {
3587   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3588   }
3589
3590 if ($parm_hostname =~ /\.example\.com$/)
3591   {
3592   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3593         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3594   }
3595
3596
3597
3598 ##################################################
3599 #     Create a testing version of Exim           #
3600 ##################################################
3601
3602 # We want to be able to run Exim with a variety of configurations. Normally,
3603 # the use of -C to change configuration causes Exim to give up its root
3604 # privilege (unless the caller is exim or root). For these tests, we do not
3605 # want this to happen. Also, we want Exim to know that it is running in its
3606 # test harness.
3607
3608 # We achieve this by copying the binary and patching it as we go. The new
3609 # binary knows it is a testing copy, and it allows -C and -D without loss of
3610 # privilege. Clearly, this file is dangerous to have lying around on systems
3611 # where there are general users with login accounts. To protect against this,
3612 # we put the new binary in a special directory that is accessible only to the
3613 # caller of this script, who is known to have sudo root privilege from the test
3614 # that was done above. Furthermore, we ensure that the binary is deleted at the
3615 # end of the test. First ensure the directory exists.
3616
3617 if (-d "eximdir")
3618   { unlink "eximdir/exim"; }     # Just in case
3619 else
3620   {
3621   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3622   system("sudo chgrp $parm_eximgroup eximdir");
3623   }
3624
3625 # The construction of the patched binary must be done as root, so we use
3626 # a separate script. As well as indicating that this is a test-harness binary,
3627 # the version number is patched to "x.yz" so that its length is always the
3628 # same. Otherwise, when it appears in Received: headers, it affects the length
3629 # of the message, which breaks certain comparisons.
3630
3631 die "** Unable to make patched exim: $!\n"
3632   if (system("sudo ./patchexim $parm_exim") != 0);
3633
3634 # From this point on, exits from the program must go via the subroutine
3635 # tests_exit(), so that suitable cleaning up can be done when required.
3636 # Arrange to catch interrupting signals, to assist with this.
3637
3638 $SIG{INT} = \&inthandler;
3639 $SIG{PIPE} = \&pipehandler;
3640
3641 # For some tests, we need another copy of the binary that is setuid exim rather
3642 # than root.
3643
3644 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3645        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3646        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3647        "sudo chmod 06755 eximdir/exim_exim");
3648
3649 ##################################################
3650 #     Make copies of utilities we might need     #
3651 ##################################################
3652
3653 # Certain of the tests make use of some of Exim's utilities. We do not need
3654 # to be root to copy these.
3655
3656 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3657
3658 $dbm_build_deleted = 0;
3659 if (defined $parm_lookups{dbm} &&
3660     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3661   {
3662   delete $parm_lookups{dbm};
3663   $dbm_build_deleted = 1;
3664   }
3665
3666 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3667   {
3668   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3669   }
3670
3671 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3672   {
3673   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3674   }
3675
3676 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3677   {
3678   tests_exit(-1, "Failed to make a copy of exinext: $!");
3679   }
3680
3681 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3682   {
3683   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3684   }
3685
3686 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3687   {
3688   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3689   }
3690
3691 # Collect some version information
3692 print '-' x 78, "\n";
3693 print "Perl version for runtest: $]\n";
3694 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3695   # fold (or unfold?) multiline output into a one-liner
3696   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3697 }
3698 print '-' x 78, "\n";
3699
3700
3701 ##################################################
3702 #    Check that the Exim user can access stuff   #
3703 ##################################################
3704
3705 # We delay this test till here so that we can check access to the actual test
3706 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3707
3708 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3709 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3710
3711 if ($parm_caller_uid eq $parm_exim_uid) {
3712   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3713                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3714 }
3715 if ($parm_caller_gid eq $parm_exim_gid) {
3716   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3717                 ."the same as caller's ($parm_caller) group as it confuses "
3718                 ."results analysis");
3719 }
3720
3721 print "The Exim user needs access to the test suite directory. Checking ...";
3722
3723 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3724   {
3725   my($why) = "unknown failure $rc";
3726   $rc >>= 8;
3727   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3728   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3729   $why = "Couldn't read auxiliary group list" if $rc == 3;
3730   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3731   $why = "Couldn't set gid" if $rc == 5;
3732   $why = "Couldn't set uid" if $rc == 6;
3733   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3734   print "\n** $why\n";
3735   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3736   }
3737 else
3738   {
3739   print " OK\n";
3740   }
3741
3742 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3743   if not unlink($log_summary_filename) and -e $log_summary_filename;
3744
3745 ##################################################
3746 #        Create a list of available tests        #
3747 ##################################################
3748
3749 # The scripts directory contains a number of subdirectories whose names are
3750 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3751 # from the first requires certain optional features to be included in the Exim
3752 # binary. These requirements are contained in a file called "REQUIRES" within
3753 # the directory. We scan all these tests, discarding those that cannot be run
3754 # because the current binary does not support the right facilities, and also
3755 # those that are outside the numerical range selected.
3756
3757 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3758   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3759
3760 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3761   if $dlfunc_deleted;
3762 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3763   if $dbm_build_deleted;
3764
3765
3766 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3767   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3768
3769 # Scan for relevant tests
3770 # HS12: Needs to be reworked.
3771 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3772   {
3773   my($testdir) = $test_dirs[$i];
3774   my($wantthis) = 1;
3775
3776   print ">>Checking $testdir\n" if $debug;
3777
3778   # Skip this directory if the first test is equal or greater than the first
3779   # test in the next directory.
3780
3781   next DIR if ($i < @test_dirs - 1) &&
3782           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3783
3784   # No need to carry on if the end test is less than the first test in this
3785   # subdirectory.
3786
3787   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3788
3789   # Check requirements, if any.
3790
3791   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3792     {
3793     while (<$requires>)
3794       {
3795       next if /^\s*$/;
3796       s/\s+$//;
3797       if (/^support (.*)$/)
3798         {
3799         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3800         }
3801       elsif (/^running (.*)$/)
3802         {
3803         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3804         }
3805       elsif (/^lookup (.*)$/)
3806         {
3807         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3808         }
3809       elsif (/^authenticators? (.*)$/)
3810         {
3811         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3812         }
3813       elsif (/^router (.*)$/)
3814         {
3815         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3816         }
3817       elsif (/^transport (.*)$/)
3818         {
3819         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3820         }
3821       elsif (/^malware (.*)$/)
3822         {
3823         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3824         }
3825       elsif (/^feature (.*)$/)
3826         {
3827         # move to a subroutine?
3828         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3829
3830         open (IN, "$parm_cwd/confs/0000") ||
3831           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3832         open (OUT, ">test-config") ||
3833           tests_exit(-1, "Couldn't open test-config: $!\n");
3834         while (<IN>)
3835           {
3836           do_substitute($testno);
3837           print OUT;
3838           }
3839         close(IN);
3840         close(OUT);
3841
3842         system($eximinfo . " >/dev/null 2>&1");
3843         if ($? != 0) {
3844           unlink("$parm_cwd/test-config");
3845           $wantthis = 0;
3846           $_ = "feature $1";
3847           last;
3848         }
3849         unlink("$parm_cwd/test-config");
3850         }
3851       elsif (/^ipv6-non-linklocal/)
3852         {
3853         if ($parm_ipv6 =~ /%/) { $wantthis = 0; last; }
3854         }
3855       else
3856         {
3857         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3858         }
3859       }
3860     }
3861   else
3862     {
3863     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3864       unless $!{ENOENT};
3865     }
3866
3867   # Loop if we do not want the tests in this subdirectory.
3868
3869   if (!$wantthis)
3870     {
3871     chomp;
3872     print "Omitting tests in $testdir (missing $_)\n";
3873     }
3874
3875   # We want the tests from this subdirectory, provided they are in the
3876   # range that was selected.
3877
3878   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3879   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3880     if not @testlist;
3881
3882   foreach $test (@testlist)
3883     {
3884     if (!$wantthis)
3885       {
3886       log_test($log_summary_filename, $test, '.');
3887       }
3888     else
3889       {
3890       push @test_list, "$testdir/$test";
3891       }
3892     }
3893   }
3894
3895 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
3896
3897
3898 ##################################################
3899 #         Munge variable auxiliary data          #
3900 ##################################################
3901
3902 # Some of the auxiliary data files have to refer to the current testing
3903 # directory and other parameter data. The generic versions of these files are
3904 # stored in the aux-var-src directory. At this point, we copy each of them
3905 # to the aux-var directory, making appropriate substitutions. There aren't very
3906 # many of them, so it's easiest just to do this every time. Ensure the mode
3907 # is standardized, as this path is used as a test for the ${stat: expansion.
3908
3909 # A similar job has to be done for the files in the dnszones-src directory, to
3910 # make the fake DNS zones for testing. Most of the zone files are copied to
3911 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3912 # networks that are defined by parameter.
3913
3914 foreach $basedir ("aux-var", "dnszones")
3915   {
3916   system("sudo rm -rf $parm_cwd/$basedir");
3917   mkdir("$parm_cwd/$basedir", 0777);
3918   chmod(0755, "$parm_cwd/$basedir");
3919
3920   opendir(AUX, "$parm_cwd/$basedir-src") ||
3921     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3922   my(@filelist) = readdir(AUX);
3923   close(AUX);
3924
3925   foreach $file (@filelist)
3926     {
3927     my($outfile) = $file;
3928     next if $file =~ /^\./;
3929
3930     if ($file eq "db.ip4.V4NET")
3931       {
3932       $outfile = "db.ip4.$parm_ipv4_test_net";
3933       }
3934     elsif ($file eq "db.ip6.V6NET")
3935       {
3936       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3937       $" = '.';
3938       $outfile = "db.ip6.@nibbles";
3939       $" = ' ';
3940       }
3941
3942     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3943     open(IN, "$parm_cwd/$basedir-src/$file") ||
3944       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3945     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3946       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3947     while (<IN>)
3948       {
3949       do_substitute(0);
3950       print OUT;
3951       }
3952     close(IN);
3953     close(OUT);
3954     }
3955   }
3956
3957 # Set a user's shell, distinguishable from /bin/sh
3958
3959 symlink('/bin/sh' => 'aux-var/sh');
3960 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3961
3962 ##################################################
3963 #     Create fake DNS zones for this host        #
3964 ##################################################
3965
3966 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3967 # sure that there are forward and reverse registrations for this host, using
3968 # its real IP addresses. Dynamically created zone files achieve this.
3969
3970 if ($have_ipv4 || $have_ipv6)
3971   {
3972   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3973   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3974     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3975   print OUT "; This is a dynamically constructed fake zone file.\n" .
3976     "; The following line causes fakens to return PASS_ON\n" .
3977     "; for queries that it cannot answer\n\n" .
3978     "PASS ON NOT FOUND\n\n";
3979   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3980   print OUT "$shortname  AAAA  $parm_ipv6_stripped\n" if $have_ipv6;
3981   print OUT "\n; End\n";
3982   close(OUT);
3983   }
3984
3985 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3986   {
3987   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3988
3989   if ($components[0]=='10')
3990     {
3991     open(OUT, ">>$parm_cwd/dnszones/db.ip4.$components[0]") ||
3992       tests_exit(-1, "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3993     print OUT "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n";
3994     close(OUT);
3995     }
3996   else
3997     {
3998     open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3999       tests_exit(-1,
4000         "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4001     print OUT "; This is a dynamically constructed fake zone file.\n" .
4002       "; The zone is $components[0].in-addr.arpa.\n\n" .
4003       "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
4004       "; End\n";
4005     close(OUT);
4006     }
4007   }
4008
4009 if ($have_ipv6 && $parm_ipv6_stripped ne "::1")
4010   {
4011   my($exp_v6) = $parm_ipv6_stripped;
4012   $exp_v6 =~ s/[^:]//g;
4013   if ( $parm_ipv6_stripped =~ /^([^:].+)::$/ ) {
4014     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
4015   } elsif ( $parm_ipv6_stripped =~ /^(.+)::(.+)$/ ) {
4016     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
4017   } elsif ( $parm_ipv6_stripped =~ /^::(.+[^:])$/ ) {
4018     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
4019   } else {
4020     $exp_v6 = $parm_ipv6_stripped;
4021   }
4022   my(@components) = split /:/, $exp_v6;
4023   my(@nibbles) = reverse (split /\s*/, shift @components);
4024   my($sep) =  '';
4025
4026   $" = ".";
4027   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
4028     tests_exit(-1,
4029       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
4030   print OUT "; This is a dynamically constructed fake zone file.\n" .
4031     "; The zone is @nibbles.ip6.arpa.\n\n";
4032
4033   @components = reverse @components;
4034   foreach $c (@components)
4035     {
4036     $c = "0$c" until $c =~ /^..../;
4037     @nibbles = reverse(split /\s*/, $c);
4038     print OUT "$sep@nibbles";
4039     $sep = ".";
4040     }
4041
4042   print OUT "  PTR  $parm_hostname.\n\n; End\n";
4043   close(OUT);
4044   $" = " ";
4045   }
4046
4047
4048
4049 ##################################################
4050 #    Create lists of mailboxes and message logs  #
4051 ##################################################
4052
4053 # We use these lists to check that a test has created the expected files. It
4054 # should be faster than looking for the file each time. For mailboxes, we have
4055 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
4056 # is just a flat list of files.
4057
4058 @oldmails = list_files_below("mail");
4059 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
4060 @oldmsglogs = readdir(DIR);
4061 closedir(DIR);
4062
4063
4064
4065 ##################################################
4066 #         Run the required tests                 #
4067 ##################################################
4068
4069 # Each test script contains a number of tests, separated by a line that
4070 # contains ****. We open input from the terminal so that we can read responses
4071 # to prompts.
4072
4073 if (not $force_continue) {
4074   # runtest needs to interact if we're not in continue
4075   # mode. It does so by communicate to /dev/tty
4076   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
4077   print "\nPress RETURN to run the tests: ";
4078   <T>;
4079 }
4080
4081
4082 foreach $test (@test_list)
4083   {
4084   state $lasttestdir = '';
4085
4086   local $lineno     = 0;
4087   local $commandno  = 0;
4088   local $subtestno  = 0;
4089   local $sortlog    = 0;
4090
4091   (local $testno = $test) =~ s|.*/||;
4092
4093   # Leaving traces in the process table and in the environment
4094   # gives us a chance to identify hanging processes (exim daemons)
4095   local $0 = "[runtest $testno]";
4096   local $ENV{EXIM_TEST_NUMBER} = $testno;
4097
4098   my $gnutls   = 0;
4099   my $docheck  = 1;
4100   my $thistestdir  = substr($test, 0, -5);
4101
4102   $dynamic_socket->close() if $dynamic_socket;
4103
4104   if ($lasttestdir ne $thistestdir)
4105     {
4106     $gnutls = 0;
4107     if (-s "scripts/$thistestdir/REQUIRES")
4108       {
4109       my $indent = '';
4110       print "\n>>> The following tests require: ";
4111       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
4112         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
4113       while (<$requires>)
4114         {
4115         $gnutls = 1 if /^support GnuTLS/;
4116         print $indent, $_;
4117         $indent = ">>>                              ";
4118         }
4119       }
4120       $lasttestdir = $thistestdir;
4121     }
4122
4123   # Remove any debris in the spool directory and the test-mail directory
4124   # and also the files for collecting stdout and stderr. Then put back
4125   # the test-mail directory for appendfile deliveries.
4126
4127   system "sudo /bin/rm -rf spool test-*";
4128   system "mkdir test-mail 2>/dev/null";
4129
4130   # A privileged Exim will normally make its own spool directory, but some of
4131   # the tests run in unprivileged modes that don't always work if the spool
4132   # directory isn't already there. What is more, we want anybody to be able
4133   # to read it in order to find the daemon's pid.
4134
4135   system "mkdir spool; " .
4136          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
4137          "sudo chmod 0755 spool";
4138
4139   # Empty the cache that keeps track of things like message id mappings, and
4140   # set up the initial sequence strings.
4141
4142   undef %cache;
4143   $next_msgid = "aX";
4144   $next_pid = 1234;
4145   $next_port = 1111;
4146   $message_skip = 0;
4147   $msglog_skip = 0;
4148   $stderr_skip = 0;
4149   $stdout_skip = 0;
4150   $rmfiltertest = 0;
4151   $is_ipv6test = 0;
4152   $TEST_STATE->{munge} = '';
4153
4154   # Remove the associative arrays used to hold checked mail files and msglogs
4155
4156   undef %expected_mails;
4157   undef %expected_msglogs;
4158
4159   # Open the test's script
4160   open(SCRIPT, "scripts/$test") ||
4161     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
4162   # Run through the script once to set variables which should be global
4163   while (<SCRIPT>)
4164     {
4165     if (/^no_message_check/) { $message_skip = 1; next; }
4166     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4167     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4168     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4169     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4170     if (/^sortlog/)          { $sortlog = 1; next; }
4171     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
4172     }
4173   # Reset to beginning of file for per test interpreting/processing
4174   seek(SCRIPT, 0, 0);
4175
4176   # The first line in the script must be a comment that is used to identify
4177   # the set of tests as a whole.
4178
4179   $_ = <SCRIPT>;
4180   $lineno++;
4181   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
4182   printf("%s %s", (substr $test, 5), (substr $_, 2));
4183
4184   # Loop for each of the subtests within the script. The variable $server_pid
4185   # is used to remember the pid of a "server" process, for which we do not
4186   # wait until we have waited for a subsequent command.
4187
4188   local($server_pid) = 0;
4189   for ($commandno = 1; !eof SCRIPT; $commandno++)
4190     {
4191     # Skip further leading comments and blank lines, handle the flag setting
4192     # commands, and deal with tests for IP support.
4193
4194     while (<SCRIPT>)
4195       {
4196       $lineno++;
4197       # Could remove these variable settings because they are already
4198       # set above, but doesn't hurt to leave them here.
4199       if (/^no_message_check/) { $message_skip = 1; next; }
4200       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4201       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4202       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4203       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4204       if (/^sortlog/)          { $sortlog = 1; next; }
4205
4206       if (/^need_largefiles/)
4207         {
4208         next if $have_largefiles;
4209         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4210         $docheck = 0;      # don't check output
4211         undef $_;          # pretend EOF
4212         last;
4213         }
4214
4215       if (/^need_ipv4/)
4216         {
4217         next if $have_ipv4;
4218         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4219         $docheck = 0;      # don't check output
4220         undef $_;          # pretend EOF
4221         last;
4222         }
4223
4224       if (/^need_ipv6/)
4225         {
4226         if ($have_ipv6)
4227           {
4228           $is_ipv6test = 1;
4229           next;
4230           }
4231         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4232         $docheck = 0;      # don't check output
4233         undef $_;          # pretend EOF
4234         last;
4235         }
4236
4237       if (/^need_move_frozen_messages/)
4238         {
4239         next if defined $parm_support{move_frozen_messages};
4240         print ">>> move frozen message support is needed for test $testno, " .
4241           "but is not\n>>> available: skipping\n";
4242         $docheck = 0;      # don't check output
4243         undef $_;          # pretend EOF
4244         last;
4245         }
4246
4247       last unless /^(?:#(?!##\s)|\s*$)/;
4248       }
4249     last if !defined $_;  # Hit EOF
4250
4251     my($subtest_startline) = $lineno;
4252
4253     # Now run the command. The function returns 0 for an inline command,
4254     # 1 if a non-exim command was run and waited for, 2 if an exim
4255     # command was run and waited for, and 3 if a command
4256     # was run and not waited for (usually a daemon or server startup).
4257
4258     my($commandname) = '';
4259     my($expectrc) = 0;
4260     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4261     my($cmdrc) = $?;
4262
4263     if ($debug) {
4264       print ">> rc=$rc cmdrc=$cmdrc\n";
4265       if (defined $run_extra) {
4266         foreach my $k (keys %$run_extra) {
4267           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4268           print ">>   $k -> $v\n";
4269         }
4270       }
4271     }
4272     $run_extra = {} unless defined $run_extra;
4273     foreach my $k (keys %$run_extra) {
4274       if (exists $TEST_STATE->{$k}) {
4275         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4276         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4277       }
4278       if (defined $run_extra->{$k}) {
4279         $TEST_STATE->{$k} = $run_extra->{$k};
4280       } elsif (exists $TEST_STATE->{$k}) {
4281         delete $TEST_STATE->{$k};
4282       }
4283     }
4284
4285     # Hit EOF after an initial return code number
4286
4287     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4288
4289     # Carry on with the next command if we did not wait for this one. $rc == 0
4290     # if no subprocess was run; $rc == 3 if we started a process but did not
4291     # wait for it.
4292
4293     next if ($rc == 0 || $rc == 3);
4294
4295     # We ran and waited for a command. Check for the expected result unless
4296     # it died.
4297
4298     if ($cmdrc != $expectrc && !$sigpipehappened)
4299       {
4300       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4301       if (($cmdrc & 0xff) == 0)
4302         {
4303         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4304         }
4305       elsif (($cmdrc & 0xff00) == 0)
4306         { printf("** Killed by signal %d", $cmdrc & 255); }
4307       else
4308         { printf("** Status %x", $cmdrc); }
4309
4310       for (;;)
4311         {
4312         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4313         $_ = $force_continue ? "c" : <T>;
4314         tests_exit(1) if /^q?$/i;
4315         if (/^c$/ && $force_continue) {
4316           log_failure($log_failed_filename, $testno, "exit code unexpected");
4317           log_test($log_summary_filename, $testno, 'F')
4318         }
4319         if ($force_continue)
4320           {
4321           print "\nstdout tail:\n";
4322           print "==================>\n";
4323           system("tail -20 test-stdout");
4324           print "===================\n";
4325
4326           print "stderr tail:\n";
4327           print "==================>\n";
4328           system("tail -30 test-stderr");
4329           print "===================\n";
4330
4331           print "stdout-server tail:\n";
4332           print "==================>\n";
4333           system("tail -20 test-stdout-server");
4334           print "===================\n";
4335
4336           print "stderr-server tail:\n";
4337           print "==================>\n";
4338           system("tail -30 test-stderr-server");
4339           print "===================\n";
4340
4341           print "... continue forced\n";
4342           }
4343
4344         last if /^[rc]$/i;
4345         if (/^e$/i)
4346           {
4347           system @more => 'test-stderr';
4348           }
4349         elsif (/^o$/i)
4350           {
4351           system @more => 'test-stdout';
4352           }
4353         }
4354
4355       $retry = 1 if /^r$/i;
4356       $docheck = 0;
4357       }
4358
4359     # If the command was exim, and a listening server is running, we can now
4360     # close its input, which causes us to wait for it to finish, which is why
4361     # we didn't close it earlier.
4362
4363     if ($rc == 2 && $server_pid != 0)
4364       {
4365       close SERVERCMD;
4366       $server_pid = 0;
4367       if ($? != 0)
4368         {
4369         if (($? & 0xff) == 0)
4370           { printf("Server return code %d for test %d starting line %d", $?/256,
4371                 $testno, $subtest_startline); }
4372         elsif (($? & 0xff00) == 0)
4373           { printf("Server killed by signal %d", $? & 255); }
4374         else
4375           { printf("Server status %x", $?); }
4376
4377         for (;;)
4378           {
4379           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4380           $_ = $force_continue ? "c" : <T>;
4381           tests_exit(1) if /^q?$/i;
4382           if (/^c$/ && $force_continue) {
4383             log_failure($log_failed_filename, $testno, "exit code unexpected");
4384             log_test($log_summary_filename, $testno, 'F')
4385           }
4386           print "... continue forced\n" if $force_continue;
4387           last if /^[rc]$/i;
4388
4389           if (/^s$/i)
4390             {
4391             open(S, "test-stdout-server") ||
4392               tests_exit(-1, "Failed to open test-stdout-server: $!");
4393             print while <S>;
4394             close(S);
4395             }
4396           }
4397         $retry = 1 if /^r$/i;
4398         }
4399       }
4400     }
4401
4402   close SCRIPT;
4403
4404   # The script has finished. Check the all the output that was generated. The
4405   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4406   # rerun the test (the files # have been updated).
4407   # It does not return if the user responds Q to a prompt.
4408
4409   if ($retry)
4410     {
4411     $retry = '0';
4412     print (("#" x 79) . "\n");
4413     redo;
4414     }
4415
4416   if ($docheck)
4417     {
4418     sleep 1 if $slow;
4419     my $rc = check_output($TEST_STATE->{munge});
4420     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4421     if ($rc < 2)
4422       {
4423       print ("  Script completed\n");
4424       }
4425     else
4426       {
4427       print (("#" x 79) . "\n");
4428       redo;
4429       }
4430     }
4431   }
4432
4433
4434 ##################################################
4435 #         Exit from the test script              #
4436 ##################################################
4437
4438 tests_exit(-1, "No runnable tests selected") if not @test_list;
4439 tests_exit(0);
4440
4441 __END__
4442
4443 =head1 NAME
4444
4445  runtest - run the exim testsuite
4446
4447 =head1 SYNOPSIS
4448
4449  runtest [exim-path] [options] [test0 [test1]]
4450
4451 =head1 DESCRIPTION
4452
4453 B<runtest> runs the Exim testsuite.
4454
4455 =head1 OPTIONS
4456
4457 For legacy reasons the options are not case sensitive.
4458
4459 =over
4460
4461 =item B<--continue>
4462
4463 Do not stop for user interaction or on errors. (default: off)
4464
4465 =item B<--debug>
4466
4467 This option enables the output of debug information when running the
4468 various test commands. (default: off)
4469
4470 =item B<--diff>
4471
4472 Use C<diff -u> for comparing the expected output with the produced
4473 output. (default: use a built-in routine)
4474
4475 =item B<--flavor>|B<--flavour> I<flavour>
4476
4477 Override the expected results for results for a specific (OS) flavour.
4478 (default: unused)
4479
4480 =item B<--[no]ipv4>
4481
4482 Skip IPv4 related setup and tests (default: use ipv4)
4483
4484 =item B<--[no]ipv6>
4485
4486 Skip IPv6 related setup and tests (default: use ipv6)
4487
4488 =item B<--keep>
4489
4490 Keep the various output files produced during a test run. (default: don't keep)
4491
4492 =item B<--range> I<n0> I<n1>
4493
4494 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4495 test available".
4496
4497 =item B<--slow>
4498
4499 Insert some delays to compensate for a slow host system. (default: off)
4500
4501 =item B<--test> I<n>
4502
4503 Run the specified test. This option may used multiple times.
4504
4505 =item B<--update>
4506
4507 Automatically update the recorded (expected) data on mismatch. (default: off)
4508
4509 =item B<--valgrind>
4510
4511 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4512
4513 =back
4514
4515 =cut
4516
4517
4518 # End of runtest script