test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32
  33 use lib "$RealBin/lib";
  34 use Exim::Runtest;
  35 use Exim::Utils qw(uniq numerically);
  36
  37 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  39
  40 use constant TEST_TOP => 8999;
  41 use constant TEST_SPECIAL_TOP => 9999;
  42
  43
  44 # Start by initializing some global variables
  45
  46 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  47
  48 # This gets embedded in the D-H params filename, and the value comes
  49 # from asking GnuTLS for "normal", but there appears to be no way to
  50 # use certtool/... to ask what that value currently is.  *sigh*
  51 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  52 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  53 # normal = 2432   tls_dh_max_bits = 2236
  54 my $gnutls_dh_bits_normal = 2236;
  55
  56 my $cf = 'bin/cf -exact';
  57 my $cr = "\r";
  58 my $debug = 0;
  59 my $flavour = do {
  60   my $f = Exim::Runtest::flavour() // '';
  61   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  62 };
  63 my $force_continue = 0;
  64 my $force_update = 0;
  65 my $log_failed_filename = 'failed-summary.log';
  66 my $log_summary_filename = 'run-summary.log';
  67 my $more = 'less -XF';
  68 my $optargs = '';
  69 my $save_output = 0;
  70 my $server_opts = '';
  71 my $slow = 0;
  72 my $valgrind = 0;
  73
  74 my $have_ipv4 = 1;
  75 my $have_ipv6 = 1;
  76 my $have_largefiles = 0;
  77
  78 my @test_list = ();
  79
  80
  81 # Networks to use for DNS tests. We need to choose some networks that will
  82 # never be used so that there is no chance that the host on which we are
  83 # running is actually in one of the test networks. Private networks such as
  84 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  85 # Rather than use some unassigned numbers (that might become assigned later),
  86 # I have chosen some multicast networks, in the belief that such addresses
  87 # won't ever be assigned to hosts. This is the only place where these numbers
  88 # are defined, so it is trivially possible to change them should that ever
  89 # become necessary.
  90
  91 my $parm_ipv4_test_net = 224;
  92 my $parm_ipv6_test_net = 'ff00';
  93
  94 # Port numbers are currently hard-wired
  95
  96 my $parm_port_n = 1223;         # Nothing listening on this port
  97 my $parm_port_s = 1224;         # Used for the "server" command
  98 my $parm_port_d = 1225;         # Used for the Exim daemon
  99 my $parm_port_d2 = 1226;        # Additional for daemon
 100 my $parm_port_d3 = 1227;        # Additional for daemon
 101 my $parm_port_d4 = 1228;        # Additional for daemon
 102 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 103
 104 # Find a suiteable group name for test (currently only 0001
 105 # uses a group name. A numeric group id would do
 106 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 107
 108 # Manually set locale
 109 $ENV{LC_ALL} = 'C';
 110
 111 # In some environments USER does not exist, but we need it for some test(s)
 112 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 113
 114 my ($parm_configure_owner, $parm_configure_group);
 115 my ($parm_ipv4, $parm_ipv6);
 116 my $parm_hostname;
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121 # Define a number of subroutines
 122
 123 ###############################################################################
 124 ###############################################################################
 125
 126
 127 ##################################################
 128 #              Handle signals                    #
 129 ##################################################
 130
 131 sub pipehandler { $sigpipehappened = 1; }
 132
 133 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 134
 135
 136 ##################################################
 137 #       Do global macro substitutions            #
 138 ##################################################
 139
 140 # This function is applied to configurations, command lines and data lines in
 141 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 142 # directory. It takes one argument: the current test number, or zero when
 143 # setting up files before running any tests.
 144
 145 sub do_substitute{
 146 s?\bCALLER\b?$parm_caller?g;
 147 s?\bCALLERGROUP\b?$parm_caller_group?g;
 148 s?\bCALLER_UID\b?$parm_caller_uid?g;
 149 s?\bCALLER_GID\b?$parm_caller_gid?g;
 150 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 151 s?\bDIR/?$parm_cwd/?g;
 152 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 153 s?\bEXIMUSER\b?$parm_eximuser?g;
 154 s?\bHOSTIPV4\b?$parm_ipv4?g;
 155 s?\bHOSTIPV6\b?$parm_ipv6?g;
 156 s?\bHOSTNAME\b?$parm_hostname?g;
 157 s?\bPORT_D\b?$parm_port_d?g;
 158 s?\bPORT_D2\b?$parm_port_d2?g;
 159 s?\bPORT_D3\b?$parm_port_d3?g;
 160 s?\bPORT_D4\b?$parm_port_d4?g;
 161 s?\bPORT_N\b?$parm_port_n?g;
 162 s?\bPORT_S\b?$parm_port_s?g;
 163 s?\bTESTNUM\b?$_[0]?g;
 164 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 165 s?\bV6NET:?$parm_ipv6_test_net:?g;
 166 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 167 s?\bMAILGROUP\b?$parm_mailgroup?g;
 168 }
 169
 170
 171 ##################################################
 172 #     Any state to be preserved across tests     #
 173 ##################################################
 174
 175 my $TEST_STATE = {};
 176
 177
 178 ##################################################
 179 #        Subroutine to tidy up and exit          #
 180 ##################################################
 181
 182 # In all cases, we check for any Exim daemons that have been left running, and
 183 # kill them. Then remove all the spool data, test output, and the modified Exim
 184 # binary if we are ending normally.
 185
 186 # Arguments:
 187 #    $_[0] = 0 for a normal exit; full cleanup done
 188 #    $_[0] > 0 for an error exit; no files cleaned up
 189 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 190
 191 sub tests_exit{
 192 my($rc) = $_[0];
 193 my($spool);
 194
 195 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 196 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 197 # the background.
 198
 199 if (exists $TEST_STATE->{exim_pid})
 200   {
 201   $pid = $TEST_STATE->{exim_pid};
 202   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 203   system("sudo kill -INT $pid");
 204   }
 205
 206 if (opendir(DIR, "spool"))
 207   {
 208   my(@spools) = sort readdir(DIR);
 209   closedir(DIR);
 210   foreach $spool (@spools)
 211     {
 212     next if $spool !~ /^exim-daemon./;
 213     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 214     chomp($pid = <PID>);
 215     close(PID);
 216     print "Tidyup: killing daemon pid=$pid\n";
 217     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 218     }
 219   }
 220 else
 221   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 222
 223 # Close the terminal input and remove the test files if all went well, unless
 224 # the option to save them is set. Always remove the patched Exim binary. Then
 225 # exit normally, or die.
 226
 227 close(T);
 228 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 229   if ($rc == 0 && !$save_output);
 230
 231 system("sudo /bin/rm -rf ./eximdir/*")
 232   if (!$save_output);
 233
 234 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 235 exit $rc if ($rc >= 0);
 236 die "** runtest error: $_[1]\n";
 237 }
 238
 239
 240
 241 ##################################################
 242 #   Subroutines used by the munging subroutine   #
 243 ##################################################
 244
 245 # This function is used for things like message ids, where we want to generate
 246 # more than one value, but keep a consistent mapping throughout.
 247 #
 248 # Arguments:
 249 #   $oldid        the value from the file
 250 #   $base         a base string into which we insert a sequence
 251 #   $sequence     the address of the current sequence counter
 252
 253 sub new_value {
 254 my($oldid, $base, $sequence) = @_;
 255 my($newid) = $cache{$oldid};
 256 if (! defined $newid)
 257   {
 258   $newid = sprintf($base, $$sequence++);
 259   $cache{$oldid} = $newid;
 260   }
 261 return $newid;
 262 }
 263
 264
 265 # This is used while munging the output from exim_dumpdb.
 266 # May go wrong across DST changes.
 267
 268 sub date_seconds {
 269 my($day,$month,$year,$hour,$min,$sec) =
 270   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 271 my($mon);
 272 if   ($month =~ /Jan/) {$mon = 0;}
 273 elsif($month =~ /Feb/) {$mon = 1;}
 274 elsif($month =~ /Mar/) {$mon = 2;}
 275 elsif($month =~ /Apr/) {$mon = 3;}
 276 elsif($month =~ /May/) {$mon = 4;}
 277 elsif($month =~ /Jun/) {$mon = 5;}
 278 elsif($month =~ /Jul/) {$mon = 6;}
 279 elsif($month =~ /Aug/) {$mon = 7;}
 280 elsif($month =~ /Sep/) {$mon = 8;}
 281 elsif($month =~ /Oct/) {$mon = 9;}
 282 elsif($month =~ /Nov/) {$mon = 10;}
 283 elsif($month =~ /Dec/) {$mon = 11;}
 284 return timelocal($sec,$min,$hour,$day,$mon,$year);
 285 }
 286
 287
 288 # This is a subroutine to sort maildir files into time-order. The second field
 289 # is the microsecond field, and may vary in length, so must be compared
 290 # numerically.
 291
 292 sub maildirsort {
 293 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 294 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 295 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 296 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 297 }
 298
 299
 300
 301 ##################################################
 302 #   Subroutine list files below a directory      #
 303 ##################################################
 304
 305 # This is used to build up a list of expected mail files below a certain path
 306 # in the directory tree. It has to be recursive in order to deal with multiple
 307 # maildir mailboxes.
 308
 309 sub list_files_below {
 310 my($dir) = $_[0];
 311 my(@yield) = ();
 312 my(@sublist, $file);
 313
 314 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 315 @sublist = sort maildirsort readdir(DIR);
 316 closedir(DIR);
 317
 318 foreach $file (@sublist)
 319   {
 320   next if $file eq "." || $file eq ".." || $file eq "CVS";
 321   if (-d "$dir/$file")
 322     { @yield = (@yield, list_files_below("$dir/$file")); }
 323   else
 324     { push @yield, "$dir/$file"; }
 325   }
 326
 327 return @yield;
 328 }
 329
 330
 331
 332 ##################################################
 333 #         Munge a file before comparing          #
 334 ##################################################
 335
 336 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 337 # on into standard values, so that the compare works. Perl's substitution with
 338 # an expression provides a neat way to do some of these changes.
 339
 340 # We keep a global associative array for repeatedly turning the same values
 341 # into the same standard values throughout the data from a single test.
 342 # Message ids get this treatment (can't be made reliable for times), and
 343 # times in dumped retry databases are also handled in a special way, as are
 344 # incoming port numbers.
 345
 346 # On entry to the subroutine, the file to write to is already opened with the
 347 # name MUNGED. The input file name is the only argument to the subroutine.
 348 # Certain actions are taken only when the name contains "stderr", "stdout",
 349 # or "log". The yield of the function is 1 if a line matching "*** truncated
 350 # ***" is encountered; otherwise it is 0.
 351
 352 sub munge {
 353 my($file) = $_[0];
 354 my($extra) = $_[1];
 355 my($yield) = 0;
 356 my(@saved) = ();
 357
 358 local $_;
 359
 360 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 361
 362 my($is_log) = $file =~ /log/;
 363 my($is_stdout) = $file =~ /stdout/;
 364 my($is_stderr) = $file =~ /stderr/;
 365 my($is_mail) = $file =~ /mail/;
 366
 367 # Date pattern
 368
 369 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 370
 371 # Pattern for matching pids at start of stderr lines; initially something
 372 # that won't match.
 373
 374 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 375
 376 # Scan the file and make the changes. Near the bottom there are some changes
 377 # that are specific to certain file types, though there are also some of those
 378 # inline too.
 379
 380 LINE: while(<IN>)
 381   {
 382 RESET_AFTER_EXTRA_LINE_READ:
 383   # Custom munges
 384   if ($extra)
 385     {
 386     next if $extra =~ m%^/%  &&  eval $extra;
 387     eval $extra if $extra =~ m/^s/;
 388     }
 389
 390   # Check for "*** truncated ***"
 391   $yield = 1 if /\*\*\* truncated \*\*\*/;
 392
 393   # Replace the name of this host
 394   s/\Q$parm_hostname\E/the.local.host.name/g;
 395
 396   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 397   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 398
 399   # The name of the shell may vary
 400   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 401
 402   # Replace the path to the testsuite directory
 403   s?\Q$parm_cwd\E?TESTSUITE?g;
 404
 405   # Replace the Exim version number (may appear in various places)
 406   # patchexim should have fixed this for us
 407   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 408
 409   # Replace Exim message ids by a unique series
 410   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 411     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 412
 413   # The names of lock files appear in some error and debug messages
 414   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 415
 416   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 417   # port" message, because it is not always the same.
 418   s/port (\d+) \([^)]+\)/port $1/g
 419     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 420
 421   # Challenges in SPA authentication
 422   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 423
 424   # PRVS values
 425   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 426   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463
 464     # Round the time-difference up to nearest even value
 465     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
 466
 467     # We used to use globally unique replacement values, but timing
 468     # differences make this impossible. Just show the increment on the
 469     # last one.
 470
 471     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 472       $increment, $expired);
 473     next;
 474     }
 475
 476   # more_errno values in exim_dumpdb output which are times
 477   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 478
 479   # port numbers in dumpdb output
 480   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
 481
 482   # port numbers in stderr
 483   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
 484   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
 485
 486
 487   # ======== Dates and times ========
 488
 489   # Dates and times are all turned into the same value - trying to turn
 490   # them into different ones cannot be done repeatedly because they are
 491   # real time stamps generated while running the test. The actual date and
 492   # time used was fixed when I first started running automatic Exim tests.
 493
 494   # Date/time in header lines and SMTP responses
 495   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 496     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 497   # and in a French locale
 498   s/\S{4},\s\d\d?\s[^,]+\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 499     /dim., 10 f\xE9vr 2019 20:05:49 +0000/gx;
 500
 501   # Date/time in logs and in one instance of a filter test
 502   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 503   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 504   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 505   # Date/time in syslog test
 506   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 507   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 508   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 509   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 510
 511   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 512   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 513
 514   # Date/time in message separators
 515   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 516     /Tue Mar 02 09:44:33 1999/gx;
 517
 518   # Date of message arrival in spool file as shown by -Mvh
 519   s/^\d{9,10}\s0$/ddddddddd 0/;
 520
 521   # Date/time in mbx mailbox files
 522   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 523
 524   # Dates/times in debugging output for writing retry records
 525   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 526     {
 527     my($next) = $3 - $2;
 528     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 529     }
 530   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 531   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 532
 533   # Time to retry may vary
 534   s/time to retry = \S+/time to retry = tttt/;
 535   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 536   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 537
 538   # Date/time in exim -bV output
 539   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 540
 541   # Eximstats heading
 542   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 543     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 544
 545   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 546   # us the former on a new connection.
 547   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 548
 549   # ======== TLS certificate algorithms ========
 550   #
 551   # In Received: headers, convert RFC 8314 style ciphersuite to
 552   # the older (comment) style, keeping only the Auth element
 553   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
 554   # element (and no _WITH); insert a spurious "RSA".
 555
 556   s/^\s+by .+ with .+ \K tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-$1-AES256-SHAnnn:xxx)/;
 557   s/^\s+by .+ with .+ \K tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
 558
 559   # Test machines might have various different TLS library versions supporting
 560   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 561   # treat the standard algorithms the same.
 562   #
 563   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : ???
 564   #
 565   # So far, have seen:
 566   #   TLSv1:AES128-GCM-SHA256:128
 567   #   TLSv1:AES256-SHA:256
 568   #   TLSv1.1:AES256-SHA:256
 569   #   TLSv1.2:AES256-GCM-SHA384:256
 570   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 571   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 572   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 573   # We also need to handle the ciphersuite without the TLS part present, for
 574   # client-ssl's output.  We also see some older forced ciphersuites, but
 575   # negotiating TLS 1.2 instead of 1.0.
 576   # Mail headers (...), log-lines X=..., client-ssl output ...
 577   # (and \b doesn't match between ' ' and '(' )
 578   #
 579   # Retain the authentication algorith field as we want to test that.
 580
 581   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1(\.[123])?:/$1TLS1.x:/xg;
 582   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
 583   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
 584
 585   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 586   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
 587   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
 588   #
 589   # TLSversion : "TLS" - C_iph_er - MAC : ???
 590   #
 591   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
 592   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
 593
 594   # LibreSSL
 595   # TLSv1:AES256-GCM-SHA384:256
 596   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 597   #
 598   # ECDHE-RSA-CHACHA20-POLY1305
 599   # AES256-GCM-SHA384
 600
 601   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 602   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
 603   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
 604
 605   # GnuTLS have seen:
 606   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
 607   #   TLS1.3:ECDHE_SECP256R1__RSA_PSS_RSAE_SHA256__AES_256_GCM__AEAD:256
 608   #   TLS1.3:ECDHE_X25519__RSA_PSS_RSAE_SHA256__AES_256_GCM:256
 609   #   TLS1.3:ECDHE_PSK_SECP256R1__AES_256_GCM__AEAD:256
 610   #
 611   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 612   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 613   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 614   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 615   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_256_GCM:256
 616   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_128_CBC__SHA256:128
 617   #   TLS1.2:ECDHE_SECP256R1__ECDSA_SHA512__AES_256_GCM:256
 618   #   TLS1.2:ECDHE_SECP256R1__AES_256_GCM:256           (3.6.7 resumption)
 619   #   TLS1.2:ECDHE_RSA_SECP256R1__AES_256_GCM:256       (! 3.5.18 !)
 620   #   TLS1.2:RSA__CAMELLIA_256_GCM:256                  (leave the cipher name)
 621   #   TLS1.2-PKIX:RSA__AES_128_GCM__AEAD:128            (the -PKIX seems to be a 3.1.20 thing)
 622   #   TLS1.2-PKIX:ECDHE_RSA_SECP521R1__AES_256_GCM__AEAD:256
 623   #
 624   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 625   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 626   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 627   #   X=TLS1.0:RSA_AES_256_CBC_SHA1:256
 628   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 629   #   X=TLS1.0-PKIX:RSA__AES_256_CBC__SHA1:256
 630   # and as stand-alone cipher:
 631   #   ECDHE-RSA-AES256-SHA
 632   #   DHE-RSA-AES256-SHA256
 633   #   DHE-RSA-AES256-SHA
 634   # picking latter as canonical simply because regex easier that way.
 635   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
 636   s/TLS1.[0123](-PKIX)?:                                                # TLS version
 637     ((EC)?DHE(_((?<psk>PSK)_)?((?<auth>RSA|ECDSA)_)?
 638                                 (SECP(256|521)R1|X25519))?__?)?         # key-exchange
 639     ((?<auth>RSA|ECDSA)((_PSS_RSAE)?_SHA(512|256))?__?)?                # authentication
 640     AES_(256|128)_(CBC|GCM)                                             # cipher
 641     (__?AEAD)?                                                          # pseudo-MAC
 642     (__?SHA(1|256|384))?                                                # PRF
 643     :(256|128)                                                          # cipher strength
 644     /"TLS1.x:ke-"
 645         . (defined($+{psk}) ? $+{psk} : "")
 646         . (defined($+{auth}) ? $+{auth} : "")
 647         . "-AES256-SHAnnn:xxx"/gex;
 648   s/TLS1.2:RSA__CAMELLIA_256_GCM(_SHA384)?:256/TLS1.2:RSA_CAMELLIA_256_GCM-SHAnnn:256/g;
 649   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
 650
 651   # GnuTLS library error message changes
 652   s/(No certificate was found|Certificate is required)/The peer did not send any certificate/g;
 653 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 654   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 655   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 656
 657   # (this new one is a generic channel-read error, but the testsuite
 658   # only hits it in one place)
 659   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 660
 661   # (replace old with new, hoping that old only happens in one situation)
 662   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 663   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 664
 665   # signature algorithm names
 666   s/RSA-SHA1/RSA-SHA/;
 667
 668
 669   # ======== Caller's login, uid, gid, home, gecos ========
 670
 671   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 672   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 673   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 674
 675   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 676   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 677
 678   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 679   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 680
 681   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 682
 683   # When looking at spool files with -Mvh, we will find not only the caller
 684   # login, but also the uid and gid. It seems that $) in some Perls gives all
 685   # the auxiliary gids as well, so don't bother checking for that.
 686
 687   s/^CALLER $> \d+$/CALLER UID GID/;
 688
 689   # There is one case where the caller's login is forced to something else,
 690   # in order to test the processing of logins that contain spaces. Weird what
 691   # some people do, isn't it?
 692
 693   s/^spaced user $> \d+$/CALLER UID GID/;
 694
 695
 696   # ======== Exim's login ========
 697   # For messages received by the daemon, this is in the -H file, which some
 698   # tests inspect. For bounce messages, this will appear on the U= lines in
 699   # logs and also after Received: and in addresses. In one pipe test it appears
 700   # after "Running as:". It also appears in addresses, and in the names of lock
 701   # files.
 702
 703   s/U=$parm_eximuser/U=EXIMUSER/;
 704   s/user=$parm_eximuser/user=EXIMUSER/;
 705   s/login=$parm_eximuser/login=EXIMUSER/;
 706   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 707   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 708   s/\b$parm_eximuser@/EXIMUSER@/;
 709   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 710
 711   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 712   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 713
 714   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 715   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 716
 717   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 718
 719
 720   # ======== General uids, gids, and pids ========
 721   # Note: this must come after munges for caller's and exim's uid/gid
 722
 723   # These are for systems where long int is 64
 724   s/\buid=4294967295/uid=-1/;
 725   s/\beuid=4294967295/euid=-1/;
 726   s/\bgid=4294967295/gid=-1/;
 727   s/\begid=4294967295/egid=-1/;
 728
 729   s/\bgid=\d+/gid=gggg/;
 730   s/\begid=\d+/egid=gggg/;
 731   s/\b(pid=|PID: )\d+/$1pppp/;
 732   s/\buid=\d+/uid=uuuu/;
 733   s/\beuid=\d+/euid=uuuu/;
 734   s/set_process_info:\s+\d+/set_process_info: pppp/;
 735   s/queue run pid \d+/queue run pid ppppp/;
 736   s/process \d+ running as transport filter/process pppp running as transport filter/;
 737   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 738   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 739   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 740
 741   # Pid in temp file in appendfile transport
 742   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 743
 744   # Optional pid in log lines
 745   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 746     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 747
 748   # Optional pid in syslog test lines
 749   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 750     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 751
 752   # Detect a daemon stderr line with a pid and save the pid for subsequent
 753   # removal from following lines.
 754   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 755   s/^$spid //;
 756
 757   # Queue runner waiting messages
 758   s/waiting for children of \d+/waiting for children of pppp/;
 759   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 760
 761   # ======== Port numbers ========
 762   # Incoming port numbers may vary, but not in daemon startup line.
 763
 764   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 765   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 766
 767   # This handles "connection from" and the like, when the port is given
 768   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 769       && !/\*>/ && !/Connection refused/)
 770     {
 771     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 772     }
 773
 774   # Port in host address in spool file output from -Mvh
 775   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 776
 777   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 778     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 779   }
 780
 781
 782   # ======== Local IP addresses ========
 783   # The amount of space between "host" and the address in verification output
 784   # depends on the length of the host name. We therefore reduce it to one space
 785   # for all of them.
 786   # Also, the length of space at the end of the host line is dependent
 787   # on the length of the longest line, so strip it also on otherwise
 788   # un-rewritten lines like localhost
 789
 790   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 791   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 792   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 793   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 794   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 795   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 796   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 797   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 798   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 799   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 800
 801
 802   # ======== Test network IP addresses ========
 803   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 804   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 805
 806
 807   # ======== IP error numbers and messages ========
 808   # These vary between operating systems
 809   s/Can't assign requested address/Network Error/;
 810   s/Cannot assign requested address/Network Error/;
 811   s/Operation timed out/Connection timed out/;
 812   s/Address family not supported by protocol family/Network Error/;
 813   s/Network is unreachable/Network Error/;
 814   s/Invalid argument/Network Error/;
 815
 816   s/\(\d+\): Network/(dd): Network/;
 817   s/\(\d+\): Connection refused/(dd): Connection refused/;
 818   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 819   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 820   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 821
 822
 823   # ======== Other error numbers ========
 824   s/errno=\d+/errno=dd/g;
 825
 826   # ======== System Error Messages ======
 827   # depending on the underlaying file system the error message seems to differ
 828   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 829
 830   # ======== Output from ls ========
 831   # Different operating systems use different spacing on long output
 832   #s/ +/ /g if /^[-rwd]{10} /;
 833   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 834   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 835   # unfortunately matches a non-ls linefull of dashes.
 836   # Allow the case where we've already picked out the file protection bits.
 837   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 838     s/ +/ /g;
 839   }
 840
 841
 842   # ======== Message sizes =========
 843   # Message sizes vary, owing to different logins and host names that get
 844   # automatically inserted. I can't think of any way of even approximately
 845   # comparing these.
 846
 847   s/([\s,])S=\d+\b/$1S=sss/;
 848   s/:S\d+\b/:Ssss/;
 849   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 850   s/\sSIZE=\d+\b/ SIZE=ssss/;
 851   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 852   s/old size = \d+\b/old size = sssss/;
 853   s/message size = \d+\b/message size = sss/;
 854   s/this message = \d+\b/this message = sss/;
 855   s/Size of headers = \d+/Size of headers = sss/;
 856   s/sum=(?!0)\d+/sum=dddd/;
 857   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 858   s/(?<=sum=0 )count=\d+\b/count=dd/;
 859   s/,S is \d+\b/,S is ddddd/;
 860   s/\+0100,\d+;/+0100,ddd;/;
 861   s/\(\d+ bytes written\)/(ddd bytes written)/;
 862   s/added '\d+ 1'/added 'ddd 1'/;
 863   s/Received\s+\d+/Received               nnn/;
 864   s/Delivered\s+\d+/Delivered              nnn/;
 865
 866
 867   # ======== Values in spool space failure message ========
 868   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 869
 870
 871   # ======== Filter sizes ========
 872   # The sizes of filter files may vary because of the substitution of local
 873   # filenames, logins, etc.
 874
 875   s/^\d+(?= bytes read from )/ssss/;
 876
 877
 878   # ======== OpenSSL error messages ========
 879   # Different releases of the OpenSSL libraries seem to give different error
 880   # numbers, or handle specific bad conditions in different ways, leading to
 881   # different wording in the error messages, so we cannot compare them.
 882
 883 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 884 #    but I can't work out how to deal with that.
 885   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 886   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 887   next if /SSL verify error: depth=0 error=certificate not trusted/;
 888
 889   # ======== Maildir things ========
 890   # timestamp output in maildir processing
 891   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 892
 893   # maildir delivery files appearing in log lines (in cases of error)
 894   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 895
 896   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 897
 898   # Maildir file names in general
 899   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 900
 901   # Maildirsize data
 902   while (/^\d+S,\d+C\s*$/)
 903     {
 904     print MUNGED;
 905     while (<IN>)
 906       {
 907       last if !/^\d+ \d+\s*$/;
 908       print MUNGED "ddd d\n";
 909       }
 910     last if !defined $_;
 911     }
 912   last if !defined $_;
 913
 914
 915   # ======== Output from the "fd" program about open descriptors ========
 916   # The statuses seem to be different on different operating systems, but
 917   # at least we'll still be checking the number of open fd's.
 918
 919   s/max fd = \d+/max fd = dddd/;
 920   s/status=0 RDONLY/STATUS/g;
 921   s/status=1 WRONLY/STATUS/g;
 922   s/status=2 RDWR/STATUS/g;
 923
 924
 925   # ======== Contents of spool files ========
 926   # A couple of tests dump the contents of the -H file. The length fields
 927   # will be wrong because of different user names, etc.
 928   s/^\d\d\d(?=[PFS*])/ddd/;
 929
 930
 931   # ========= Exim lookups ==================
 932   # Lookups have a char which depends on the number of lookup types compiled in,
 933   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 934   # other output is fragile; perhaps the debug output should be revised instead.
 935   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 936
 937   # ==========================================================
 938   # MIME boundaries in RFC3461 DSN messages
 939   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 940
 941   # ==========================================================
 942   # Some munging is specific to the specific file types
 943
 944   # ======== stdout ========
 945
 946   if ($is_stdout)
 947     {
 948     # Skip translate_ip_address and use_classresources in -bP output because
 949     # they aren't always there.
 950
 951     next if /translate_ip_address =/;
 952     next if /use_classresources/;
 953
 954     # In certain filter tests, remove initial filter lines because they just
 955     # clog up by repetition.
 956
 957     if ($rmfiltertest)
 958       {
 959       next if /^(Sender\staken\sfrom|
 960                  Return-path\scopied\sfrom|
 961                  Sender\s+=|
 962                  Recipient\s+=)/x;
 963       if (/^Testing \S+ filter/)
 964         {
 965         $_ = <IN>;    # remove blank line
 966         next;
 967         }
 968       }
 969
 970     # remote IPv6 addrs vary
 971     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 972
 973     # openssl version variances
 974   # Error lines on stdout from SSL contain process id values and file names.
 975   # They also contain a source file name and line number, which may vary from
 976   # release to release.
 977
 978     next if /^SSL info:/;
 979     next if /SSL verify error: depth=0 error=certificate not trusted/;
 980     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 981     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
 982     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
 983     s/^error:[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/error:dddddddd:$1/;
 984
 985     # gnutls version variances
 986     next if /^Error in the pull function./;
 987
 988     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
 989     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
 990     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
 991
 992     # subsecond timstamp info in reported header-files
 993     s/^(-received_time_usec \.)\d{6}$/$1uuuuuu/;
 994
 995     # Postgres server takes varible time to shut down; lives in various places
 996     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
 997     s/^\/.*postgres /POSTGRES /;
 998
 999     # DMARC is not always supported by the build
1000     next if /^dmarc_tld_file =/;
1001
1002     # ARC is not always supported by the build
1003     next if /^arc_sign =/;
1004
1005     # TLS resumption is not always supported by the build
1006     next if /^tls_resumption_hosts =/;
1007     next if /^-tls_resumption/;
1008     }
1009
1010   # ======== stderr ========
1011
1012   elsif ($is_stderr)
1013     {
1014     # The very first line of debugging output will vary
1015
1016     s/^Exim version .*/Exim version x.yz ..../;
1017
1018     # Debugging lines for Exim terminations and process-generation
1019
1020     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
1021     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
1022
1023     # IP address lookups use gethostbyname() when IPv6 is not supported,
1024     # and gethostbyname2() or getipnodebyname() when it is.
1025
1026     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
1027
1028     # we don't care what TZ enviroment the testhost was running
1029     next if /^Reset TZ to/;
1030
1031     # drop gnutls version strings
1032     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1033     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1034
1035     # drop openssl version strings
1036     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1037     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1038
1039     # drop lookups
1040     next if /^Lookups \(built-in\):/;
1041     next if /^Loading lookup modules from/;
1042     next if /^Loaded \d+ lookup modules/;
1043     next if /^Total \d+ lookups/;
1044
1045     # drop compiler information
1046     next if /^Compiler:/;
1047
1048     # and the ugly bit
1049     # different libraries will have different numbers (possibly 0) of follow-up
1050     # lines, indenting with more data
1051     if (/^Library version:/) {
1052       while (1) {
1053         $_ = <IN>;
1054         next if /^\s/;
1055         goto RESET_AFTER_EXTRA_LINE_READ;
1056       }
1057     }
1058
1059     # drop other build-time controls emitted for debugging
1060     next if /^WHITELIST_D_MACROS:/;
1061     next if /^TRUSTED_CONFIG_LIST:/;
1062
1063     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1064     # with -be, privileges will have been dropped, so this will always
1065     # be the case
1066     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1067
1068     # We might not keep this check; rather than change all the tests, just
1069     # ignore it as long as it succeeds; then we only need to change the
1070     # TLS tests where tls_require_ciphers has been set.
1071     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1072       my $discard = <IN>;
1073       next;
1074     }
1075     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1076
1077     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1078     next if /^macros_trusted overridden to true by whitelisting/;
1079
1080     # We have to omit the localhost ::1 address so that all is well in
1081     # the IPv4-only case.
1082
1083     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1084       if (/looked up these IP addresses/);
1085     next if /name=localhost address=::1/;
1086
1087     # drop pdkim debugging header
1088     next if /^PDKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1089
1090     # Various other IPv6 lines must be omitted too
1091
1092     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1093     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1094     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1095     next if / in dns_ipv4_lookup?/;
1096
1097     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1098       {
1099       $_= <IN>;     # Gets "returning DNS_NODATA"
1100       next;
1101       }
1102
1103     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1104     # are unset, because tls ain't always there.
1105
1106     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1107                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1108
1109     # Skip auxiliary group lists because they will vary.
1110
1111     next if /auxiliary group list:/;
1112
1113     # Skip "extracted from gecos field" because the gecos field varies
1114
1115     next if /extracted from gecos field/;
1116
1117     # Skip "waiting for data on socket" and "read response data: size=" lines
1118     # because some systems pack more stuff into packets than others.
1119
1120     next if /waiting for data on socket/;
1121     next if /read response data: size=/;
1122
1123     # If Exim is compiled with readline support but it can't find the library
1124     # to load, there will be an extra debug line. Omit it.
1125
1126     next if /failed to load readline:/;
1127
1128     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1129     # O_CREAT; other's don't. In the latter case there is some debugging output
1130     # which is not present in the former. Skip the relevant lines (there are
1131     # three of them).
1132
1133     if (/returned from EXIM_DBOPEN: \(nil\)/)
1134       {
1135       $_ .= <IN>;
1136       s?\Q$parm_cwd\E?TESTSUITE?g;
1137       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1138         { $_ = <IN>; next; }
1139       }
1140
1141     # Some tests turn on +expand debugging to check on expansions.
1142     # Unfortunately, the Received: expansion varies, depending on whether TLS
1143     # is compiled or not. So we must remove the relevant debugging if it is.
1144
1145     if (/^condition: def:tls_cipher/)
1146       {
1147       while (<IN>) { last if /^condition: def:sender_address/; }
1148       }
1149     elsif (/^expanding: Received: /)
1150       {
1151       while (<IN>) { last if !/^\s/; }
1152       }
1153
1154     # remote port numbers vary
1155     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1156
1157     # Platform-dependent error strings
1158     s/Operation timed out/Connection timed out/;
1159
1160     # Skip hosts_require_dane checks when the options
1161     # are unset, because dane ain't always there.
1162     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1163
1164     # DISABLE_OCSP
1165     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1166
1167     # SUPPORT_PROXY
1168     next if /host in hosts_proxy\?/;
1169
1170     # PIPE_CONNECT
1171     next if / in (pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1172
1173     # Experimental_International
1174     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1175
1176     # Experimental_REQUIRETLS
1177     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1178
1179     # TCP Fast Open
1180     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1181
1182     # Environment cleaning
1183     next if /\w+ in keep_environment\? (yes|no)/;
1184
1185     # Sizes vary with test hostname
1186     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1187
1188     # Spool filesystem free space changes on different systems.
1189     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1190
1191     # Non-TLS builds have different expansions for received_header_text
1192     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1193       {
1194       $_ .= <IN>;
1195       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1196       }
1197     if (/^ ├──condition: def:tls_cipher$/)
1198       {
1199       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1200       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1201       }
1202
1203     # Not all platforms build with DKIM enabled
1204     next if /^PDKIM >> Body data for hash, canonicalized/;
1205
1206     # Not all platforms have sendfile support
1207     next if /^cannot use sendfile for body: no support$/;
1208
1209     #  Parts of DKIM-specific debug output depend on the time/date
1210     next if /^date:\w+,\{SP\}/;
1211     next if /^PDKIM \[[^[]+\] (Header hash|b) computed:/;
1212
1213     # Not all platforms support TCP Fast Open, and the compile omits the check
1214     if (s/\S+ in hosts_try_fastopen\? (no \(option unset\)|yes \(matched "\*"\))\n$//)
1215       {
1216       $_ .= <IN>;
1217       s/ \.\.\. >>> / ... /;
1218       if (s/ non-TFO mode connection attempt to 224.0.0.0, 0 data\b$//) { $_ .= <IN>; }
1219       s/Address family not supported by protocol family/Network Error/;
1220       s/Network is unreachable/Network Error/;
1221       }
1222     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1223     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1224
1225     if (/^([0-9: ]*                                             # possible timestamp
1226         Connecting\ to\ [^ ]+\ [^ ]+(\ from\ [^ ]+)?)\ \.\.\.
1227         \ .*TFO\ mode\
1228         (sendto,\ no\ data:\ EINPROGRESS                        # Linux
1229         |connection\ attempt\ to\ [^,]+,\ 0\ data)              # MacOS & no-support
1230         $/x)
1231       {
1232       $_ = $1 . " ... " . <IN>;
1233       s/^(.* \.\.\.) [0-9: ]*connected$/$1  connected/;
1234
1235       if (/^Connecting to .* \.\.\.  connected$/)
1236         {
1237         $_ .= <IN>;
1238         if (/^(Connecting to .* \.\.\.  )connected\n\s+SMTP(\(close\)>>|\(Connection refused\)<<)$/)
1239           {
1240           $_ = $1 . "failed: Connection refused\n" . <IN>;
1241           s/^(Connecting .*)\n\s+SMTP\(close\)>>$/$1/;
1242           }
1243         elsif (/^(Connecting to .* \.\.\.  connected\n)read response data: size=/)
1244           { $_ = $1; }
1245
1246         # Date/time in SMTP banner
1247         s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
1248           /Tue, 2 Mar 1999 09:44:33 +0000/gx;
1249         }
1250       }
1251
1252     # Specific pointer values reported for DB operations change from run to run
1253     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1254     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1255
1256     # Platform-dependent output during MySQL startup
1257     next if /PerconaFT file system space/;
1258     next if /^Waiting for MySQL server to answer/;
1259     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1260
1261     # Not all builds include DMARC
1262     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1263
1264     # TLS resumption is not always supported by the build
1265     next if /in tls_resumption_hosts\?/;
1266
1267     # Platform differences in errno strings
1268     s/  SMTP\(Operation timed out\)<</  SMTP(Connection timed out)<</;
1269
1270     # When Exim is checking the size of directories for maildir, it uses
1271     # the check_dir_size() function to scan directories. Of course, the order
1272     # of the files that are obtained using readdir() varies from system to
1273     # system. We therefore buffer up debugging lines from check_dir_size()
1274     # and sort them before outputting them.
1275
1276     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1277       {
1278       push @saved, $_;
1279       }
1280     else
1281       {
1282       if (@saved > 0)
1283         {
1284         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1285           "to ensure consistency\n";
1286         @saved = sort(@saved);
1287         print MUNGED @saved;
1288         @saved = ();
1289         }
1290
1291       # Skip some lines that Exim puts out at the start of debugging output
1292       # because they will be different in different binaries.
1293
1294       print MUNGED
1295         unless (/^Berkeley DB: / ||
1296                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1297                 /^Authenticators:/ ||
1298                 /^Lookups:/ ||
1299                 /^Support for:/ ||
1300                 /^Routers:/ ||
1301                 /^Transports:/ ||
1302                 /^Malware:/ ||
1303                 /^log selectors =/ ||
1304                 /^cwd=/ ||
1305                 /^Fixed never_users:/ ||
1306                 /^Configure owner:/ ||
1307                 /^Size of off_t:/
1308                 );
1309
1310
1311       }
1312
1313     next;
1314     }
1315
1316   # ======== log ========
1317
1318   elsif ($is_log)
1319     {
1320     # Berkeley DB version differences
1321     next if / Berkeley DB error: /;
1322
1323     # CHUNKING: exact sizes depend on hostnames in headers
1324     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1325
1326     # openssl version variances
1327     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1328     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1329     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1330     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:(PEM routines):get_name:(no start line)/0906D06C:$1:PEM_read_bio:$2/;
1331
1332     # gnutls version variances
1333     if (/TLS error on connection \(recv\): .* (Decode error|peer did not send any certificate)/)
1334       {
1335       my $prev = $_;
1336       $_ = <IN>;
1337       if (/error on first read/)
1338         {
1339         s/TLS session: \Kerror on first read:/(gnutls_handshake): A TLS fatal alert has been received.:/;
1340         goto RESET_AFTER_EXTRA_LINE_READ;
1341         }
1342       else
1343         { $_ = $prev; }
1344       }
1345     # translate gnutls error into the openssl one
1346     s/ARC: AMS signing: privkey PEM-block import: \KThe requested data were not available.$/error:0906D06C:PEM routines:PEM_read_bio:no start line/;
1347
1348     # DKIM timestamps
1349     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1350       {
1351       my ($prefix, $t_diff) = ($1, $3 - $2);
1352       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1353       }
1354
1355     # port numbers
1356     s/(?:\[[^\]]*\]:|port )\K$parm_port_d/PORT_D/;
1357     s/(?:\[[^\]]*\]:|port )\K$parm_port_d2/PORT_D2/;
1358     s/(?:\[[^\]]*\]:|port )\K$parm_port_d3/PORT_D3/;
1359     s/(?:\[[^\]]*\]:|port )\K$parm_port_d4/PORT_D4/;
1360     s/(?:\[[^\]]*\]:|port )\K$parm_port_s/PORT_S/;
1361     s/(?:\[[^\]]*\]:|port )\K$parm_port_n/PORT_N/;
1362     s/I=\[[^\]]*\]:\K\d+/ppppp/;
1363
1364     }
1365
1366   # ======== mail ========
1367
1368   elsif ($is_mail)
1369     {
1370     # DKIM timestamps, and signatures depending thereon
1371     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1372       {
1373       my ($indent, $t_diff) = ($1, $3 - $2);
1374       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1375       <IN>;
1376       <IN>;
1377       }
1378     }
1379
1380   # ======== All files other than stderr ========
1381
1382   print MUNGED;
1383   }
1384
1385 close(IN);
1386 return $yield;
1387 }
1388
1389
1390
1391
1392 ##################################################
1393 #        Subroutine to interact with caller      #
1394 ##################################################
1395
1396 # Arguments: [0] the prompt string
1397 #            [1] if there is a U in the prompt and $force_update is true
1398 #            [2] if there is a C in the prompt and $force_continue is true
1399 # Returns:   returns the answer
1400
1401 sub interact {
1402   my ($prompt, $have_u, $have_c) = @_;
1403
1404   print $prompt;
1405
1406   if ($have_u) {
1407     print "... update forced\n";
1408     return 'u';
1409   }
1410
1411   if ($have_c) {
1412     print "... continue forced\n";
1413     return 'c';
1414   }
1415
1416   return lc <T>;
1417 }
1418
1419
1420
1421 ##################################################
1422 #    Subroutine to log in force_continue mode    #
1423 ##################################################
1424
1425 # In force_continue mode, we just want a terse output to a statically
1426 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1427 # all have mismatches, it will log multiple times.
1428 #
1429 # Arguments: [0] the logfile to append to
1430 #            [1] the testno that failed
1431 # Returns:   nothing
1432
1433
1434
1435 sub log_failure {
1436   my ($logfile, $testno, $detail) = @_;
1437
1438   open(my $fh, '>>', $logfile) or return;
1439
1440   print $fh "Test $testno "
1441         . (defined $detail ? "$detail " : '')
1442         . "failed\n";
1443 }
1444
1445 # Computer-readable summary results logfile
1446
1447 sub log_test {
1448   my ($logfile, $testno, $resultchar) = @_;
1449
1450   open(my $fh, '>>', $logfile) or return;
1451   print $fh "$testno $resultchar\n";
1452 }
1453
1454
1455
1456 ##################################################
1457 #    Subroutine to compare one output file       #
1458 ##################################################
1459
1460 # When an Exim server is part of the test, its output is in separate files from
1461 # an Exim client. The server data is concatenated with the client data as part
1462 # of the munging operation.
1463 #
1464 # Arguments:  [0] the name of the main raw output file
1465 #             [1] the name of the server raw output file or undef
1466 #             [2] where to put the munged copy
1467 #             [3] the name of the saved file
1468 #             [4] TRUE if this is a log file whose deliveries must be sorted
1469 #             [5] optionally, a custom munge command
1470 #
1471 # Returns:    0 comparison succeeded
1472 #             1 comparison failed; differences to be ignored
1473 #             2 comparison failed; files may have been updated (=> re-compare)
1474 #
1475 # Does not return if the user replies "Q" to a prompt.
1476
1477 sub check_file{
1478 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1479
1480 # If there is no saved file, the raw files must either not exist, or be
1481 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1482
1483 # we check if there is a flavour specific file, but we remember
1484 # the original file name as "generic"
1485 $sf_generic = $sf;
1486 $sf_flavour = "$sf_generic.$flavour";
1487 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1488
1489 if (! -e $sf_current)
1490   {
1491   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1492
1493   print "\n";
1494   print "** $rf is not empty\n" if (-s $rf);
1495   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1496
1497   for (;;)
1498     {
1499     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1500     tests_exit(1) if /^q?$/;
1501     if (/^c$/ && $force_continue) {
1502       log_failure($log_failed_filename, $testno, $rf);
1503       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1504     }
1505     return 1 if /^c$/i && $rf !~ /paniclog/ && $rsf !~ /paniclog/;
1506     last if (/^[sc]$/);
1507     }
1508
1509   foreach $f ($rf, $rsf)
1510     {
1511     if (defined $f && -s $f)
1512       {
1513       print "\n";
1514       print "------------ $f -----------\n"
1515         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1516       system("$more '$f'");
1517       }
1518     }
1519
1520   print "\n";
1521   for (;;)
1522     {
1523     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1524     tests_exit(1) if /^q?$/;
1525     if (/^c$/ && $force_continue) {
1526       log_failure($log_failed_filename, $testno, $rf);
1527       log_test($log_summary_filename, $testno, 'F')
1528     }
1529     return 1 if /^c$/i;
1530     last if (/^u$/i);
1531     }
1532   }
1533
1534 #### $_
1535
1536 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1537 # was a request to create a saved file. First, create the munged file from any
1538 # data that does exist.
1539
1540 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1541 my($truncated) = munge($rf, $extra) if -e $rf;
1542
1543 # Append the raw server log, if it is non-empty
1544 if (defined $rsf && -e $rsf)
1545   {
1546   print MUNGED "\n******** SERVER ********\n";
1547   $truncated |= munge($rsf, $extra);
1548   }
1549 close(MUNGED);
1550
1551 # If a saved file exists, do the comparison. There are two awkward cases:
1552 #
1553 # If "*** truncated ***" was found in the new file, it means that a log line
1554 # was overlong, and truncated. The problem is that it may be truncated at
1555 # different points on different systems, because of different user name
1556 # lengths. We reload the file and the saved file, and remove lines from the new
1557 # file that precede "*** truncated ***" until we reach one that matches the
1558 # line that precedes it in the saved file.
1559 #
1560 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1561 # for an individual message might vary in their order from system to system, as
1562 # a result of parallel deliveries. We load the munged file and sort sequences
1563 # of delivery lines.
1564
1565 if (-e $sf_current)
1566   {
1567   # Deal with truncated text items
1568
1569   if ($truncated)
1570     {
1571     my(@munged, @saved, $i, $j, $k);
1572
1573     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1574     @munged = <MUNGED>;
1575     close(MUNGED);
1576     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1577     @saved = <SAVED>;
1578     close(SAVED);
1579
1580     $j = 0;
1581     for ($i = 0; $i < @munged; $i++)
1582       {
1583       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1584         {
1585         for (; $j < @saved; $j++)
1586           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1587         last if $j >= @saved;     # not found in saved
1588
1589         for ($k = $i - 1; $k >= 0; $k--)
1590           { last if $munged[$k] eq $saved[$j - 1]; }
1591
1592         last if $k <= 0;          # failed to find previous match
1593         splice @munged, $k + 1, $i - $k - 1;
1594         $i = $k + 1;
1595         }
1596       }
1597
1598     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1599     for ($i = 0; $i < @munged; $i++)
1600       { print MUNGED $munged[$i]; }
1601     close(MUNGED);
1602     }
1603
1604   # Deal with log sorting
1605
1606   if ($sortfile)
1607     {
1608     my(@munged, $i, $j);
1609
1610     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1611     @munged = <MUNGED>;
1612     close(MUNGED);
1613
1614     for ($i = 0; $i < @munged; $i++)
1615       {
1616       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1617         {
1618         for ($j = $i + 1; $j < @munged; $j++)
1619           {
1620           last if $munged[$j] !~
1621             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1622           }
1623         @temp = splice(@munged, $i, $j - $i);
1624         @temp = sort(@temp);
1625         splice(@munged, $i, 0, @temp);
1626         }
1627       }
1628
1629     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1630     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1631     for ($i = 0; $i < @munged; $i++)
1632       { print MUNGED $munged[$i]; }
1633     close(MUNGED);
1634     }
1635
1636   # Do the comparison
1637
1638   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1639
1640   # Handle comparison failure
1641
1642   print "** Comparison of $mf with $sf_current failed";
1643   system("$more test-cf");
1644
1645   print "\n";
1646   for (;;)
1647     {
1648     $_ = interact('Continue, Retry, Update current'
1649         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1650         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1651     tests_exit(1) if /^q?$/;
1652     if (/^c$/ && $force_continue) {
1653       log_failure($log_failed_filename, $testno, $sf_current);
1654       log_test($log_summary_filename, $testno, 'F')
1655     }
1656     return 1 if /^c$/i;
1657     return 2 if /^r$/i;
1658     last if (/^[us]$/i);
1659     }
1660   }
1661
1662 # Update or delete the saved file, and give the appropriate return code.
1663
1664 if (-s $mf)
1665   {
1666     my $sf = /^u/i ? $sf_current : $sf_flavour;
1667     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1668   }
1669 else
1670   {
1671     # if we deal with a flavour file, we can't delete it, because next time the generic
1672     # file would be used again
1673     if ($sf_current eq $sf_flavour) {
1674       open(FOO, ">$sf_current");
1675       close(FOO);
1676     }
1677     else {
1678       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1679     }
1680   }
1681
1682 return 2;
1683 }
1684
1685
1686
1687 ##################################################
1688 # Custom munges
1689 # keyed by name of munge; value is a ref to a hash
1690 # which is keyed by file, value a string to look for.
1691 # Usable files are:
1692 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1693 # Search strings starting with 's' do substitutions;
1694 # with '/' do line-skips.
1695 # Triggered by a scriptfile line "munge <name>"
1696 ##################################################
1697 $munges =
1698   { 'dnssec' =>
1699     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1700
1701     'gnutls_unexpected' =>
1702     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1703
1704     'gnutls_handshake' =>
1705     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1706
1707     'gnutls_bad_clientcert' =>
1708     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1709       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1710     },
1711
1712     'optional_events' =>
1713     { 'stdout' => '/event_action =/' },
1714
1715     'optional_ocsp' =>
1716     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1717
1718     'optional_cert_hostnames' =>
1719     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1720
1721     'loopback' =>
1722     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1723
1724     'scanfile_size' =>
1725     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1726
1727     'delay_1500' =>
1728     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1729
1730     'tls_anycipher' =>
1731     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1732                       s! DN="C=! DN="/C=!;
1733                       s! DN="[^,"]*\K,!/!;
1734                       s! DN="[^,"]*\K,!/!;
1735                       s! DN="[^,"]*\K,!/!;
1736                      ',
1737       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1738       'mail'      => 's/^\s+by .+ with .+ \K tls TLS_.+$/(TLS_proto_and_cipher)/;
1739                       s/ \(TLS[^)]*\)/ (TLS_proto_and_cipher)/;
1740                      ',
1741     },
1742
1743     'debug_pid' =>
1744     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1745
1746     'optional_dsn_info' =>
1747     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1748     },
1749
1750     'optional_config' =>
1751     { 'stdout' => '/^(
1752                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1753                   |gnutls_require_(kx|mac|protocols)
1754                   |hosts_pipe_connect
1755                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1756                   |dane_require_tls_ciphers
1757                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1758                   |pipelining_connect_advertise_hosts
1759                   |socks_proxy
1760                   |tls_[^ ]*
1761                   |utf8_downconvert
1762                   )($|[ ]=)/x'
1763     },
1764
1765     'sys_bindir' =>
1766     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1767
1768     'sync_check_data' =>
1769     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1770       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1771
1772     'debuglog_stdout' =>
1773     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1774                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1775     },
1776
1777     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1778     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1779
1780     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1781     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1782
1783     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1784     { 'stdout' => 's%^> X/X$%> X%' },
1785   };
1786
1787
1788 sub max {
1789   my ($a, $b) = @_;
1790   return $a if ($a > $b);
1791   return $b;
1792 }
1793
1794 ##################################################
1795 #    Subroutine to check the output of a test    #
1796 ##################################################
1797
1798 # This function is called when the series of subtests is complete. It makes
1799 # use of check_file(), whose arguments are:
1800 #
1801 #  [0] the name of the main raw output file
1802 #  [1] the name of the server raw output file or undef
1803 #  [2] where to put the munged copy
1804 #  [3] the name of the saved file
1805 #  [4] TRUE if this is a log file whose deliveries must be sorted
1806 #  [5] an optional custom munge command
1807 #
1808 # Arguments: Optionally, name of a single custom munge to run.
1809 # Returns:   0 if the output compared equal
1810 #            1 if comparison failed; differences to be ignored
1811 #            2 if re-run needed (files may have been updated)
1812
1813 sub check_output{
1814 my($mungename) = $_[0];
1815 my($yield) = 0;
1816 my($munge) = $munges->{$mungename} if defined $mungename;
1817
1818 $yield = max($yield,  check_file("spool/log/paniclog",
1819                        "spool/log/serverpaniclog",
1820                        "test-paniclog-munged",
1821                        "paniclog/$testno", 0,
1822                        $munge->{paniclog}));
1823
1824 $yield = max($yield,  check_file("spool/log/rejectlog",
1825                        "spool/log/serverrejectlog",
1826                        "test-rejectlog-munged",
1827                        "rejectlog/$testno", 0,
1828                        $munge->{rejectlog}));
1829
1830 $yield = max($yield,  check_file("spool/log/mainlog",
1831                        "spool/log/servermainlog",
1832                        "test-mainlog-munged",
1833                        "log/$testno", $sortlog,
1834                        $munge->{mainlog}));
1835
1836 if (!$stdout_skip)
1837   {
1838   $yield = max($yield,  check_file("test-stdout",
1839                        "test-stdout-server",
1840                        "test-stdout-munged",
1841                        "stdout/$testno", 0,
1842                        $munge->{stdout}));
1843   }
1844
1845 if (!$stderr_skip)
1846   {
1847   $yield = max($yield,  check_file("test-stderr",
1848                        "test-stderr-server",
1849                        "test-stderr-munged",
1850                        "stderr/$testno", 0,
1851                        $munge->{stderr}));
1852   }
1853
1854 # Compare any delivered messages, unless this test is skipped.
1855
1856 if (! $message_skip)
1857   {
1858   my($msgno) = 0;
1859
1860   # Get a list of expected mailbox files for this script. We don't bother with
1861   # directories, just the files within them.
1862
1863   foreach $oldmail (@oldmails)
1864     {
1865     next unless $oldmail =~ /^mail\/$testno\./;
1866     print ">> EXPECT $oldmail\n" if $debug;
1867     $expected_mails{$oldmail} = 1;
1868     }
1869
1870   # If there are any files in test-mail, compare them. Note that "." and
1871   # ".." are automatically omitted by list_files_below().
1872
1873   @mails = list_files_below("test-mail");
1874
1875   foreach $mail (@mails)
1876     {
1877     next if $mail eq "test-mail/oncelog";
1878
1879     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1880     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1881
1882     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1883       {
1884       $msgno++;
1885       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1886       }
1887
1888     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1889     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1890       "mail/$testno.$saved_mail", 0,
1891       $munge->{mail}));
1892     delete $expected_mails{"mail/$testno.$saved_mail"};
1893     }
1894
1895   # Complain if not all expected mails have been found
1896
1897   if (scalar(keys %expected_mails) != 0)
1898     {
1899     foreach $key (keys %expected_mails)
1900       { print "** no test file found for $key\n"; }
1901
1902     for (;;)
1903       {
1904       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1905       tests_exit(1) if /^q?$/;
1906       if (/^c$/ && $force_continue) {
1907         log_failure($log_failed_filename, $testno, "missing email");
1908         log_test($log_summary_filename, $testno, 'F')
1909       }
1910       last if /^c$/;
1911
1912       # For update, we not only have to unlink the file, but we must also
1913       # remove it from the @oldmails vector, as otherwise it will still be
1914       # checked for when we re-run the test.
1915
1916       if (/^u$/)
1917         {
1918         foreach $key (keys %expected_mails)
1919           {
1920           my($i);
1921           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1922           for ($i = 0; $i < @oldmails; $i++)
1923             {
1924             if ($oldmails[$i] eq $key)
1925               {
1926               splice @oldmails, $i, 1;
1927               last;
1928               }
1929             }
1930           }
1931         last;
1932         }
1933       }
1934     }
1935   }
1936
1937 # Compare any remaining message logs, unless this test is skipped.
1938
1939 if (! $msglog_skip)
1940   {
1941   # Get a list of expected msglog files for this test
1942
1943   foreach $oldmsglog (@oldmsglogs)
1944     {
1945     next unless $oldmsglog =~ /^$testno\./;
1946     $expected_msglogs{$oldmsglog} = 1;
1947     }
1948
1949   # If there are any files in spool/msglog, compare them. However, we have
1950   # to munge the file names because they are message ids, which are
1951   # time dependent.
1952
1953   if (opendir(DIR, "spool/msglog"))
1954     {
1955     @msglogs = sort readdir(DIR);
1956     closedir(DIR);
1957
1958     foreach $msglog (@msglogs)
1959       {
1960       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1961       ($munged_msglog = $msglog) =~
1962         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1963           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1964       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
1965         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1966         $munge->{msglog}));
1967       delete $expected_msglogs{"$testno.$munged_msglog"};
1968       }
1969     }
1970
1971   # Complain if not all expected msglogs have been found
1972
1973   if (scalar(keys %expected_msglogs) != 0)
1974     {
1975     foreach $key (keys %expected_msglogs)
1976       {
1977       print "** no test msglog found for msglog/$key\n";
1978       ($msgid) = $key =~ /^\d+\.(.*)$/;
1979       foreach $cachekey (keys %cache)
1980         {
1981         if ($cache{$cachekey} eq $msgid)
1982           {
1983           print "** original msgid $cachekey\n";
1984           last;
1985           }
1986         }
1987       }
1988
1989     for (;;)
1990       {
1991       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1992       tests_exit(1) if /^q?$/;
1993       if (/^c$/ && $force_continue) {
1994         log_failure($log_failed_filename, $testno, "missing msglog");
1995         log_test($log_summary_filename, $testno, 'F')
1996       }
1997       last if /^c$/;
1998       if (/^u$/)
1999         {
2000         foreach $key (keys %expected_msglogs)
2001           {
2002           tests_exit(-1, "Failed to unlink msglog/$key")
2003             if !unlink("msglog/$key");
2004           }
2005         last;
2006         }
2007       }
2008     }
2009   }
2010
2011 return $yield;
2012 }
2013
2014
2015
2016 ##################################################
2017 #     Subroutine to run one "system" command     #
2018 ##################################################
2019
2020 # We put this in a subroutine so that the command can be reflected when
2021 # debugging.
2022 #
2023 # Argument: the command to be run
2024 # Returns:  nothing
2025
2026 sub run_system {
2027 my($cmd) = $_[0];
2028 if ($debug)
2029   {
2030   my($prcmd) = $cmd;
2031   $prcmd =~ s/; /;\n>> /;
2032   print ">> $prcmd\n";
2033   }
2034 system("$cmd");
2035 }
2036
2037
2038
2039 ##################################################
2040 #      Subroutine to run one script command      #
2041 ##################################################
2042
2043 # The <SCRIPT> file is open for us to read an optional return code line,
2044 # followed by the command line and any following data lines for stdin. The
2045 # command line can be continued by the use of \. Data lines are not continued
2046 # in this way. In all lines, the following substitutions are made:
2047 #
2048 # DIR    => the current directory
2049 # CALLER => the caller of this script
2050 #
2051 # Arguments: the current test number
2052 #            reference to the subtest number, holding previous value
2053 #            reference to the expected return code value
2054 #            reference to where to put the command name (for messages)
2055 #            auxiliary information returned from a previous run
2056 #
2057 # Returns:   0 the command was executed inline, no subprocess was run
2058 #            1 a non-exim command was run and waited for
2059 #            2 an exim command was run and waited for
2060 #            3 a command was run and not waited for (daemon, server, exim_lock)
2061 #            4 EOF was encountered after an initial return code line
2062 # Optionally also a second parameter, a hash-ref, with auxiliary information:
2063 #            exim_pid: pid of a run process
2064 #            munge: name of a post-script results munger
2065
2066 sub run_command{
2067 my($testno) = $_[0];
2068 my($subtestref) = $_[1];
2069 my($commandnameref) = $_[3];
2070 my($aux_info) = $_[4];
2071 my($yield) = 1;
2072
2073 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
2074
2075 if (/^(\d+)\s*$/)                # Handle unusual return code
2076   {
2077   my($r) = $_[2];
2078   $$r = $1 << 8;
2079   $_ = <SCRIPT>;
2080   return 4 if !defined $_;       # Missing command
2081   $lineno++;
2082   }
2083
2084 chomp;
2085 $wait_time = 0;
2086
2087 # Handle concatenated command lines
2088
2089 s/\s+$//;
2090 while (substr($_, -1) eq"\\")
2091   {
2092   my($temp);
2093   $_ = substr($_, 0, -1);
2094   chomp($temp = <SCRIPT>);
2095   if (defined $temp)
2096     {
2097     $lineno++;
2098     $temp =~ s/\s+$//;
2099     $temp =~ s/^\s+//;
2100     $_ .= $temp;
2101     }
2102   }
2103
2104 # Do substitutions
2105
2106 do_substitute($testno);
2107 if ($debug) { printf ">> $_\n"; }
2108
2109 # Pass back the command name (for messages)
2110
2111 ($$commandnameref) = /^(\S+)/;
2112
2113 # Here follows code for handling the various different commands that are
2114 # supported by this script. The first group of commands are all freestanding
2115 # in that they share no common code and are not followed by any data lines.
2116
2117
2118 ###################
2119 ###################
2120
2121 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2122 # utility and to make DBM files for testing DBM lookups.
2123
2124 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2125   {
2126   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2127          "echo exim_dbmbuild exit code = \$?)" .
2128          ">>test-stdout");
2129   return 1;
2130   }
2131
2132
2133 # The "dump" command runs exim_dumpdb. On different systems, the output for
2134 # some types of dump may appear in a different order because it's just hauled
2135 # out of the DBM file. We can solve this by sorting. Ignore the leading
2136 # date/time, as it will be flattened later during munging.
2137
2138 if (/^dump\s+(\S+)/)
2139   {
2140   my($which) = $1;
2141   my(@temp);
2142   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2143   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
2144   open(OUT, ">>test-stdout");
2145   print OUT "+++++++++++++++++++++++++++\n";
2146
2147   if ($which eq "retry")
2148     {
2149     $/ = "\n  ";
2150     @temp = <IN>;
2151     $/ = "\n";
2152
2153     @temp = sort {
2154                    my($aa) = split(' ', $a);
2155                    my($bb) = split(' ', $b);
2156                    return $aa cmp $bb;
2157                  } @temp;
2158
2159     foreach $item (@temp)
2160       {
2161       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2162       print OUT "  $item\n";
2163       }
2164     }
2165   else
2166     {
2167     @temp = <IN>;
2168     if ($which eq "callout")
2169       {
2170       @temp = sort {
2171                    my($aa) = substr $a, 21;
2172                    my($bb) = substr $b, 21;
2173                    return $aa cmp $bb;
2174                    } @temp;
2175       }
2176     print OUT @temp;
2177     }
2178
2179   close(IN);
2180   close(OUT);
2181   return 1;
2182   }
2183
2184
2185 # verbose comments start with ###
2186 if (/^###\s/) {
2187   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2188     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2189     say {$fh} $_;
2190   }
2191   return 0;
2192 }
2193
2194 # The "echo" command is a way of writing comments to the screen.
2195 if (/^echo\s+(.*)$/)
2196   {
2197   print "$1\n";
2198   return 0;
2199   }
2200
2201
2202 # The "exim_lock" command runs exim_lock in the same manner as "server",
2203 # but it doesn't use any input.
2204
2205 if (/^exim_lock\s+(.*)$/)
2206   {
2207   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2208   $server_pid = open SERVERCMD, "|$cmd" ||
2209     tests_exit(-1, "Failed to run $cmd\n");
2210
2211   # This gives the process time to get started; otherwise the next
2212   # process may not find it there when it expects it.
2213
2214   select(undef, undef, undef, 0.1);
2215   return 3;
2216   }
2217
2218
2219 # The "exinext" command runs exinext
2220
2221 if (/^exinext\s+(.*)/)
2222   {
2223   run_system("(./eximdir/exinext " .
2224     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2225     "-C $parm_cwd/test-config $1;" .
2226     "echo exinext exit code = \$?)" .
2227     ">>test-stdout");
2228   return 1;
2229   }
2230
2231
2232 # The "exigrep" command runs exigrep on the current mainlog
2233
2234 if (/^exigrep\s+(.*)/)
2235   {
2236   run_system("(./eximdir/exigrep " .
2237     "$1 $parm_cwd/spool/log/mainlog;" .
2238     "echo exigrep exit code = \$?)" .
2239     ">>test-stdout");
2240   return 1;
2241   }
2242
2243
2244 # The "eximstats" command runs eximstats on the current mainlog
2245
2246 if (/^eximstats\s+(.*)/)
2247   {
2248   run_system("(./eximdir/eximstats " .
2249     "$1 $parm_cwd/spool/log/mainlog;" .
2250     "echo eximstats exit code = \$?)" .
2251     ">>test-stdout");
2252   return 1;
2253   }
2254
2255
2256 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2257 # spool directory, to save Exim from re-creating it each time.
2258
2259 if (/^gnutls/)
2260   {
2261   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2262   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2263          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2264          "sudo chmod 0400 $gen_fn";
2265   return 1;
2266   }
2267
2268
2269 # The "killdaemon" command should ultimately follow the starting of any Exim
2270 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2271 # it outputting "Terminated" to the terminal when not in the background.
2272
2273 if (/^killdaemon/)
2274   {
2275   my $return_extra = {};
2276   if (exists $aux_info->{exim_pid})
2277     {
2278     $pid = $aux_info->{exim_pid};
2279     $return_extra->{exim_pid} = undef;
2280     print ">> killdaemon: recovered pid $pid\n" if $debug;
2281     if ($pid)
2282       {
2283       run_system("sudo /bin/kill -INT $pid");
2284       wait;
2285       }
2286     } else {
2287     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2288     if ($pid)
2289       {
2290       run_system("sudo /bin/kill -INT $pid");
2291       close DAEMONCMD;                                   # Waits for process
2292       }
2293     }
2294     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2295   return (1, $return_extra);
2296   }
2297
2298
2299 # The "millisleep" command is like "sleep" except that its argument is in
2300 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2301 # is used for.
2302
2303 elsif (/^millisleep\s+(.*)$/)
2304   {
2305   select(undef, undef, undef, $1/1000);
2306   return 0;
2307   }
2308
2309
2310 # The "munge" command selects one of a hardwired set of test-result modifications
2311 # to be made before result compares are run against the golden set.  This lets
2312 # us account for test-system dependent things which only affect a few, but known,
2313 # test-cases.
2314 # Currently only the last munge takes effect.
2315
2316 if (/^munge\s+(.*)$/)
2317   {
2318   return (0, { munge => $1 });
2319   }
2320
2321
2322 # The "sleep" command does just that. For sleeps longer than 1 second we
2323 # tell the user what's going on.
2324
2325 if (/^sleep\s+(.*)$/)
2326   {
2327   if ($1 == 1)
2328     {
2329     sleep(1);
2330     }
2331   else
2332     {
2333     printf("  Test %d sleep $1 ", $$subtestref);
2334     for (1..$1)
2335       {
2336       print ".";
2337       sleep(1);
2338       }
2339     printf("\r  Test %d                            $cr", $$subtestref);
2340     }
2341   return 0;
2342   }
2343
2344
2345 # Various Unix management commands are recognized
2346
2347 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2348     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2349   {
2350   run_system("$_ >>test-stdout 2>>test-stderr");
2351   return 1;
2352   }
2353
2354
2355
2356 ###################
2357 ###################
2358
2359 # The next group of commands are also freestanding, but they are all followed
2360 # by data lines.
2361
2362
2363 # The "server" command starts up a script-driven server that runs in parallel
2364 # with the following exim command. Therefore, we want to run a subprocess and
2365 # not yet wait for it to complete. The waiting happens after the next exim
2366 # command, triggered by $server_pid being non-zero. The server sends its output
2367 # to a different file. The variable $server_opts, if not empty, contains
2368 # options to disable IPv4 or IPv6 if necessary.
2369 # This works because "server" swallows its stdin before waiting for a connection.
2370
2371 if (/^server\s+(.*)$/)
2372   {
2373   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2374   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2375   print ">> $cmd\n" if ($debug);
2376   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2377   SERVERCMD->autoflush(1);
2378   print ">> Server pid is $server_pid\n" if $debug;
2379   while (<SCRIPT>)
2380     {
2381     $lineno++;
2382     last if /^\*{4}\s*$/;
2383     print SERVERCMD;
2384     }
2385   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2386                             # because close() waits for the process.
2387
2388   # Interlock the server startup; otherwise the next
2389   # process may not find it there when it expects it.
2390   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2391   return 3;
2392   }
2393
2394
2395 # The "write" command is a way of creating files of specific sizes for
2396 # buffering tests, or containing specific data lines from within the script
2397 # (rather than hold lots of little files). The "catwrite" command does the
2398 # same, but it also copies the lines to test-stdout.
2399
2400 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2401   {
2402   my($cat) = defined $1;
2403   @sizes = ();
2404   @sizes = split /\s+/, $3 if defined $3;
2405   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2406
2407   if ($cat)
2408     {
2409     open CAT, ">>test-stdout" ||
2410       tests_exit(-1, "Failed to open test-stdout: $!");
2411     print CAT "==========\n";
2412     }
2413
2414   if (scalar @sizes > 0)
2415     {
2416     # Pre-data
2417
2418     while (<SCRIPT>)
2419       {
2420       $lineno++;
2421       last if /^\+{4}\s*$/;
2422       print FILE;
2423       print CAT if $cat;
2424       }
2425
2426     # Sized data
2427
2428     while (scalar @sizes > 0)
2429       {
2430       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2431       $leadin = '' if !defined $leadin;
2432       $leadin =~ s/_/ /g;
2433       $len -= length($leadin) + 1;
2434       while ($count-- > 0)
2435         {
2436         print FILE $leadin, "a" x $len, "\n";
2437         print CAT $leadin, "a" x $len, "\n" if $cat;
2438         }
2439       }
2440     }
2441
2442   # Post data, or only data if no sized data
2443
2444   while (<SCRIPT>)
2445     {
2446     $lineno++;
2447     last if /^\*{4}\s*$/;
2448     print FILE;
2449     print CAT if $cat;
2450     }
2451   close FILE;
2452
2453   if ($cat)
2454     {
2455     print CAT "==========\n";
2456     close CAT;
2457     }
2458
2459   return 0;
2460   }
2461
2462
2463 ###################
2464 ###################
2465
2466 # From this point on, script commands are implemented by setting up a shell
2467 # command in the variable $cmd. Shared code to run this command and handle its
2468 # input and output follows.
2469
2470 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2471 # program that plays the part of an email client. We also have the availability
2472 # of running Perl for doing one-off special things. Note that all these
2473 # commands expect stdin data to be supplied.
2474
2475 if (/^client/ || /^(sudo\s+)?perl\b/)
2476   {
2477   s"client"./bin/client";
2478   $cmd = "$_ >>test-stdout 2>>test-stderr";
2479   }
2480
2481 # For the "exim" command, replace the text "exim" with the path for the test
2482 # binary, plus -D options to pass over various parameters, and a -C option for
2483 # the testing configuration file. When running in the test harness, Exim does
2484 # not drop privilege when -C and -D options are present. To run the exim
2485 # command as root, we use sudo.
2486
2487 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2488   {
2489   $args = $6;
2490   my($envset) = (defined $1)? $1      : '';
2491   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2492   my($special)= (defined $5)? $5      : '';
2493   $wait_time  = (defined $2)? $2      : 0;
2494
2495   # Return 2 rather than 1 afterwards
2496
2497   $yield = 2;
2498
2499   # Update the test number
2500
2501   $$subtestref = $$subtestref + 1;
2502   printf("  Test %d       $cr", $$subtestref);
2503
2504   # Copy the configuration file, making the usual substitutions.
2505
2506   open (IN, "$parm_cwd/confs/$testno") ||
2507     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2508   open (OUT, ">test-config") ||
2509     tests_exit(-1, "Couldn't open test-config: $!\n");
2510   while (<IN>)
2511     {
2512     do_substitute($testno);
2513     print OUT;
2514     }
2515   close(IN);
2516   close(OUT);
2517
2518   # The string $msg1 in args substitutes the message id of the first
2519   # message on the queue, and so on. */
2520
2521   if ($args =~ /\$msg/)
2522     {
2523     my @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2524                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2525                    -C => "$parm_cwd/test-config");
2526     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2527     # We need the message ids sorted in ascending order.
2528     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2529     # PIDs are randomized, so sorting just the whole PID doesn't work.
2530     # We do the Schartz' transformation here (sort on
2531     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2532     my @msglist =
2533       map { $_->[1] }                                   # extract the values
2534       sort { $a->[0] cmp $b->[0] }                      # sort by key
2535       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2536       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2537
2538     # Done backwards just in case there are more than 9
2539
2540     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2541     if ( $args =~ /\$msg\d/ )
2542       {
2543       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2544         unless $force_continue;
2545       }
2546     }
2547
2548   # If -d is specified in $optargs, remove it from $args; i.e. let
2549   # the command line for runtest override. Then run Exim.
2550
2551   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2552
2553   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2554
2555   $cmd = "$envset$sudo$opt_valgrind" .
2556          "$parm_cwd/eximdir/exim$special$optargs " .
2557          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2558          "-C $parm_cwd/test-config $args " .
2559          ">>test-stdout 2>>test-stderr";
2560   # If the command is starting an Exim daemon, we run it in the same
2561   # way as the "server" command above, that is, we don't want to wait
2562   # for the process to finish. That happens when "killdaemon" is obeyed later
2563   # in the script. We also send the stderr output to test-stderr-server. The
2564   # daemon has its log files put in a different place too (by configuring with
2565   # log_file_path). This requires the  directory to be set up in advance.
2566   #
2567   # There are also times when we want to run a non-daemon version of Exim
2568   # (e.g. a queue runner) with the server configuration. In this case,
2569   # we also define -DNOTDAEMON.
2570
2571   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2572     {
2573     if ($debug) { printf ">> daemon: $cmd\n"; }
2574     run_system("sudo mkdir spool/log 2>/dev/null");
2575     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2576
2577     # Before running the command, convert the -bd option into -bdf so that an
2578     # Exim daemon doesn't double fork. This means that when we wait close
2579     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2580     # file is written to the spool directory, in case the Exim binary was
2581     # built with PID_FILE_PATH pointing somewhere else.
2582
2583     if ($cmd =~ /\s-oP\s/)
2584       {
2585       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2586       $cmd =~ s!\s-bd\s! -bdf !;
2587       }
2588     else
2589       {
2590       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2591       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2592       }
2593     print ">> |${cmd}-server\n" if ($debug);
2594     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2595     DAEMONCMD->autoflush(1);
2596     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2597
2598     # Interlock with daemon startup
2599     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2600       { select(undef, undef, undef, 0.3); }
2601     return 3;                                     # Don't wait
2602     }
2603   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2604     {
2605
2606     # The port and the $dynamic_socket was already allocated while parsing the
2607     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2608
2609     my $listen_port = $1;
2610     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2611     run_system("sudo mkdir spool/log 2>/dev/null");
2612     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2613
2614     my $pid = fork();
2615     if (not defined $pid) { die "** fork failed: $!\n" }
2616     if (not $pid) {
2617       close(STDIN);
2618       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2619       close($dynamic_socket);
2620       print "[$$]>> ${cmd}-server\n" if ($debug);
2621       exec "exec ${cmd}-server";
2622       die "Can't exec ${cmd}-server: $!\n";
2623     }
2624     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2625     select(undef, undef, undef, 0.3);             # Let the daemon get going
2626     return (3, { exim_pid => $pid });             # Don't wait
2627     }
2628   }
2629
2630 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2631 # One script line is read and fork-exec'd.  The PID is stored for a later
2632 # killdaemon.
2633
2634 elsif (/^background$/)
2635   {
2636   my $line;
2637 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2638
2639   $_ = <SCRIPT>; $lineno++;
2640   chomp;
2641   do_substitute($testno);
2642   $line = $_;
2643   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2644
2645   my $pid = fork();
2646   if (not defined $pid) { die "** fork failed: $!\n" }
2647   if (not $pid) {
2648     print "[$$]>> ${line}\n" if ($debug);
2649     close(STDIN);
2650     open(STDIN, "<", "test-stdout");
2651     close(STDOUT);
2652     open(STDOUT, ">>", "test-stdout");
2653     close(STDERR);
2654     open(STDERR, ">>", "test-stderr-server");
2655     exec "exec ${line}";
2656     exit(1);
2657   }
2658
2659 #  open(my $fh, ">", $pidfile) ||
2660 #      tests_exit(-1, "Failed to open $pidfile: $!");
2661 #  printf($fh, "%d\n", $pid);
2662 #  close($fh);
2663
2664   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2665   select(undef, undef, undef, 0.3);             # Let the daemon get going
2666   return (3, { exim_pid => $pid });             # Don't wait
2667   }
2668
2669
2670
2671 # Unknown command
2672
2673 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2674
2675
2676 # Run the command, with stdin connected to a pipe, and write the stdin data
2677 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2678 # the terminating newline (and the \NONL\). If the command contains
2679 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2680 # for the stderr file. See comment above about the use of -DSERVER.
2681
2682 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2683 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2684 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2685
2686 CMD->autoflush(1);
2687 while (<SCRIPT>)
2688   {
2689   $lineno++;
2690   last if /^\*{4}\s*$/;
2691   do_substitute($testno);
2692   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2693   }
2694
2695 # For timeout tests, wait before closing the pipe; we expect a
2696 # SIGPIPE error in this case.
2697
2698 if ($wait_time > 0)
2699   {
2700   printf("  Test %d sleep $wait_time ", $$subtestref);
2701   while ($wait_time-- > 0)
2702     {
2703     print ".";
2704     sleep(1);
2705     }
2706   printf("\r  Test %d                                       $cr", $$subtestref);
2707   }
2708
2709 $sigpipehappened = 0;
2710 close CMD;                # Waits for command to finish
2711 return $yield;            # Ran command and waited
2712 }
2713
2714
2715
2716
2717 ###############################################################################
2718 ###############################################################################
2719
2720 # Here begins the Main Program ...
2721
2722 ###############################################################################
2723 ###############################################################################
2724
2725
2726 autoflush STDOUT 1;
2727 print "Exim tester $testversion\n";
2728
2729 # extend the PATH with .../sbin
2730 # we map all (.../bin) to (.../sbin:.../bin)
2731 $ENV{PATH} = do {
2732   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2733   join ':' => map { m{(.*)/bin$}
2734                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2735                 : ($_) }
2736       split /:/, $ENV{PATH};
2737 };
2738
2739 ##################################################
2740 #      Some tests check created file modes       #
2741 ##################################################
2742
2743 umask 022;
2744
2745
2746 ##################################################
2747 #       Check for the "less" command             #
2748 ##################################################
2749
2750 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2751
2752
2753
2754 ##################################################
2755 #      See if an Exim binary has been given      #
2756 ##################################################
2757
2758 # If the first character of the first argument is '/', the argument is taken
2759 # as the path to the binary. If the first argument does not start with a
2760 # '/' but exists in the file system, it's assumed to be the Exim binary.
2761
2762
2763 ##################################################
2764 # Sort out options and which tests are to be run #
2765 ##################################################
2766
2767 # There are a few possible options for the test script itself; after these, any
2768 # options are passed on to Exim calls within the tests. Typically, this is used
2769 # to turn on Exim debugging while setting up a test.
2770
2771 Getopt::Long::Configure qw(no_getopt_compat);
2772 GetOptions(
2773     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2774     'diff'     => sub { $cf             = 'diff -u' },
2775     'continue' => sub { $force_continue = 1; $more = 'cat' },
2776     'update'   => \$force_update,
2777     'ipv4!'    => \$have_ipv4,
2778     'ipv6!'    => \$have_ipv6,
2779     'keep'     => \$save_output,
2780     'slow'     => \$slow,
2781     'valgrind' => \$valgrind,
2782     'range=s{2}'       => \my @range_wanted,
2783     'test=i@'          => \my @tests_wanted,
2784     'flavor|flavour=s' => \$flavour,
2785     'help'             => sub { pod2usage(-exit => 0) },
2786     'man'              => sub {
2787         pod2usage(
2788             -exit      => 0,
2789             -verbose   => 2,
2790             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2791         );
2792     },
2793 ) or pod2usage;
2794
2795 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2796 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2797
2798
2799 my @wanted = sort numerically uniq
2800   @tests_wanted ? @tests_wanted : (),
2801   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
2802   @ARGV ? @ARGV == 1 ? $ARGV[0] :
2803           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
2804           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
2805         : ();
2806 @wanted = 1..TEST_TOP if not @wanted;
2807
2808 ##################################################
2809 #        Check for sudo access to root           #
2810 ##################################################
2811
2812 print "You need to have sudo access to root to run these tests. Checking ...\n";
2813 if (system('sudo true >/dev/null') != 0)
2814   {
2815   die "** Test for sudo failed: testing abandoned.\n";
2816   }
2817 else
2818   {
2819   print "Test for sudo OK\n";
2820   }
2821
2822
2823
2824
2825 ##################################################
2826 #      Make the command's directory current      #
2827 ##################################################
2828
2829 # After doing so, we find its absolute path name.
2830
2831 $cwd = $0;
2832 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2833 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2834 $parm_cwd = Cwd::getcwd();
2835
2836
2837 ##################################################
2838 #     Search for an Exim binary to test          #
2839 ##################################################
2840
2841 # If an Exim binary hasn't been provided, try to find one. We can handle the
2842 # case where exim-testsuite is installed alongside Exim source directories. For
2843 # PH's private convenience, if there's a directory just called "exim4", that
2844 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2845 # releases.
2846
2847 # If $parm_exim is still empty, ask the caller
2848
2849 if (not $parm_exim)
2850   {
2851   print "** Did not find an Exim binary to test\n";
2852   for ($i = 0; $i < 5; $i++)
2853     {
2854     my($trybin);
2855     print "** Enter pathname for Exim binary: ";
2856     chomp($trybin = <STDIN>);
2857     if (-e $trybin)
2858       {
2859       $parm_exim = $trybin;
2860       last;
2861       }
2862     else
2863       {
2864       print "** $trybin does not exist\n";
2865       }
2866     }
2867   die "** Too many tries\n" if $parm_exim eq '';
2868   }
2869
2870
2871
2872 ##################################################
2873 #          Find what is in the binary            #
2874 ##################################################
2875
2876 # deal with TRUSTED_CONFIG_LIST restrictions
2877 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2878 open (IN, "$parm_cwd/confs/0000") ||
2879   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2880 open (OUT, ">test-config") ||
2881   tests_exit(-1, "Couldn't open test-config: $!\n");
2882 while (<IN>) { print OUT; }
2883 close(IN);
2884 close(OUT);
2885
2886 print("Probing with config file: $parm_cwd/test-config\n");
2887
2888 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2889 chomp(my @eximinfo = `$eximinfo 2>&1`);
2890 die "$0: Can't run $eximinfo\n" if $? == -1;
2891
2892 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2893 foreach (@eximinfo)
2894   {
2895   if (my ($version) = /^Exim version (\S+)/) {
2896     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2897     if (defined $git and $? == 0) {
2898       chomp $git;
2899       $git =~ s/^exim-//i;
2900       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2901       print <<___
2902
2903 *** Version mismatch
2904 *** Exim binary: $version
2905 *** Git        : $git
2906
2907 ___
2908         if not $version eq $git;
2909     }
2910   }
2911   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2912   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2913   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2914   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2915         if /^Configure owner:\s*(\d+):(\d+)/;
2916   print if /wrong owner/;
2917   }
2918
2919 if (not defined $parm_eximuser) {
2920   die <<XXX, map { "|$_\n" } @eximinfo;
2921 Unable to extract exim_user from binary.
2922 Check if Exim refused to run; if so, consider:
2923   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2924 If debug permission denied, are you in the exim group?
2925 Failing to get information from binary.
2926 Output from $eximinfo:
2927 XXX
2928
2929 }
2930
2931 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2932 else { $parm_exim_uid = getpwnam($parm_eximuser); }
2933
2934 if (defined $parm_eximgroup)
2935   {
2936   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2937     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2938   }
2939
2940 # check the permissions on the TRUSTED_CONFIG_LIST
2941 if (defined $parm_trusted_config_list)
2942   {
2943   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2944     if not -f $parm_trusted_config_list;
2945
2946   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2947     if 02 & (stat _)[2];
2948
2949   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2950   (stat _)[1],
2951     scalar(getgrgid 0), scalar(getgrgid $>)
2952     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2953
2954   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2955   scalar(getpwuid 0), scalar(getpwuid $>)
2956      if (not (-o _ or (stat _)[4] == 0));
2957
2958   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2959   my $test_config = getcwd() . '/test-config';
2960   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2961   if not grep { /^\Q$test_config\E$/ } <TCL>;
2962   }
2963 else
2964   {
2965   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2966   }
2967
2968 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2969         if $parm_configure_owner != $>;
2970
2971 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2972         if 0020 & (stat "$parm_cwd/test-config")[2]
2973         and $parm_configure_group != $);
2974
2975 die "aux-fixed file is group-writeable; best to strip them all, recursively\n"
2976         if 0020 & (stat "aux-fixed/0037.f-1")[2];
2977
2978
2979 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2980   die "** Cannot run $parm_exim: $!\n";
2981
2982 print "-" x 78, "\n";
2983
2984 while (<EXIMINFO>)
2985   {
2986   my(@temp);
2987
2988   if (/^(Exim|Library) version/) { print; }
2989   if (/Runtime: /) {print; }
2990
2991   elsif (/^Size of off_t: (\d+)/)
2992     {
2993     print;
2994     $have_largefiles = 1 if $1 > 4;
2995     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2996         if ($1 > 32);
2997     }
2998
2999   elsif (/^Support for: (.*)/)
3000     {
3001     print;
3002     @temp = split /(\s+)/, $1;
3003     push(@temp, ' ');
3004     %parm_support = @temp;
3005     }
3006
3007   elsif (/^Lookups \(built-in\): (.*)/)
3008     {
3009     print;
3010     @temp = split /(\s+)/, $1;
3011     push(@temp, ' ');
3012     %parm_lookups = @temp;
3013     }
3014
3015   elsif (/^Authenticators: (.*)/)
3016     {
3017     print;
3018     @temp = split /(\s+)/, $1;
3019     push(@temp, ' ');
3020     %parm_authenticators = @temp;
3021     }
3022
3023   elsif (/^Routers: (.*)/)
3024     {
3025     print;
3026     @temp = split /(\s+)/, $1;
3027     push(@temp, ' ');
3028     %parm_routers = @temp;
3029     }
3030
3031   # Some transports have options, e.g. appendfile/maildir. For those, ensure
3032   # that the basic transport name is set, and then the name with each of the
3033   # options.
3034
3035   elsif (/^Transports: (.*)/)
3036     {
3037     print;
3038     @temp = split /(\s+)/, $1;
3039     my($i,$k);
3040     push(@temp, ' ');
3041     %parm_transports = @temp;
3042     foreach $k (keys %parm_transports)
3043       {
3044       if ($k =~ "/")
3045         {
3046         @temp = split /\//, $k;
3047         $parm_transports{$temp[0]} = " ";
3048         for ($i = 1; $i < @temp; $i++)
3049           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
3050         }
3051       }
3052     }
3053
3054   elsif (/^Malware: (.*)/)
3055     {
3056     print;
3057     @temp = split /(\s+)/, $1;
3058     push(@temp, ' ');
3059     %parm_malware = @temp;
3060     }
3061
3062   }
3063 close(EXIMINFO);
3064 print "-" x 78, "\n";
3065
3066 unlink("$parm_cwd/test-config");
3067
3068 ##################################################
3069 #    Check for SpamAssassin and ClamAV           #
3070 ##################################################
3071
3072 # These are crude tests. If they aren't good enough, we'll have to improve
3073 # them, for example by actually passing a message through spamc or clamscan.
3074
3075 if (defined $parm_support{Content_Scanning})
3076   {
3077   my $sock = new FileHandle;
3078
3079   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
3080     {
3081     print "The spamc command works:\n";
3082
3083     # This test for an active SpamAssassin is courtesy of John Jetmore.
3084     # The tests are hard coded to localhost:783, so no point in making
3085     # this test flexible like the clamav test until the test scripts are
3086     # changed.  spamd doesn't have the nice PING/PONG protocol that
3087     # clamd does, but it does respond to errors in an informative manner,
3088     # so use that.
3089
3090     my($sint,$sport) = ('127.0.0.1',783);
3091     eval
3092       {
3093       my $sin = sockaddr_in($sport, inet_aton($sint))
3094           or die "** Failed packing $sint:$sport\n";
3095       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3096           or die "** Unable to open socket $sint:$sport\n";
3097
3098       local $SIG{ALRM} =
3099           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3100       alarm(5);
3101       connect($sock, $sin)
3102           or die "** Unable to connect to socket $sint:$sport\n";
3103       alarm(0);
3104
3105       select((select($sock), $| = 1)[0]);
3106       print $sock "bad command\r\n";
3107
3108       $SIG{ALRM} =
3109           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3110       alarm(10);
3111       my $res = <$sock>;
3112       alarm(0);
3113
3114       $res =~ m|^SPAMD/|
3115           or die "** Did not get SPAMD from socket $sint:$sport. "
3116                 ."It said: $res\n";
3117       };
3118     alarm(0);
3119     if($@)
3120       {
3121       print "  $@";
3122       print "  Assume SpamAssassin (spamd) is not running\n";
3123       }
3124     else
3125       {
3126       $parm_running{SpamAssassin} = ' ';
3127       print "  SpamAssassin (spamd) seems to be running\n";
3128       }
3129     }
3130   else
3131     {
3132     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3133     }
3134
3135   # For ClamAV, we need to find the clamd socket for use in the Exim
3136   # configuration. Search for the clamd configuration file.
3137
3138   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3139     {
3140     my($f, $clamconf, $test_prefix);
3141
3142     print "The clamscan command works";
3143
3144     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3145     $test_prefix = '' if !defined $test_prefix;
3146
3147     foreach $f ("$test_prefix/etc/clamd.conf",
3148                 "$test_prefix/usr/local/etc/clamd.conf",
3149                 "$test_prefix/etc/clamav/clamd.conf", '')
3150       {
3151       if (-e $f)
3152         {
3153         $clamconf = $f;
3154         last;
3155         }
3156       }
3157
3158     # Read the ClamAV configuration file and find the socket interface.
3159
3160     if ($clamconf ne '')
3161       {
3162       my $socket_domain;
3163       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3164       while (<IN>)
3165         {
3166         if (/^LocalSocket\s+(.*)/)
3167           {
3168           $parm_clamsocket = $1;
3169           $socket_domain = AF_UNIX;
3170           last;
3171           }
3172         if (/^TCPSocket\s+(\d+)/)
3173           {
3174           if (defined $parm_clamsocket)
3175             {
3176             $parm_clamsocket .= " $1";
3177             $socket_domain = AF_INET;
3178             last;
3179             }
3180           else
3181             {
3182             $parm_clamsocket = " $1";
3183             }
3184           }
3185         elsif (/^TCPAddr\s+(\S+)/)
3186           {
3187           if (defined $parm_clamsocket)
3188             {
3189             $parm_clamsocket = $1 . $parm_clamsocket;
3190             $socket_domain = AF_INET;
3191             last;
3192             }
3193           else
3194             {
3195             $parm_clamsocket = $1;
3196             }
3197           }
3198         }
3199       close(IN);
3200
3201       if (defined $socket_domain)
3202         {
3203         print ":\n  The clamd socket is $parm_clamsocket\n";
3204         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3205         eval
3206           {
3207           my $socket;
3208           if ($socket_domain == AF_UNIX)
3209             {
3210             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3211             }
3212           elsif ($socket_domain == AF_INET)
3213             {
3214             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3215             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3216             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3217             }
3218           else
3219             {
3220             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3221             }
3222           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3223           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3224           alarm(5);
3225           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3226           alarm(0);
3227
3228           my $ofh = select $sock; $| = 1; select $ofh;
3229           print $sock "PING\n";
3230
3231           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3232           alarm(10);
3233           my $res = <$sock>;
3234           alarm(0);
3235
3236           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3237           };
3238         alarm(0);
3239
3240         if($@)
3241           {
3242           print "  $@";
3243           print "  Assume ClamAV is not running\n";
3244           }
3245         else
3246           {
3247           $parm_running{ClamAV} = ' ';
3248           print "  ClamAV seems to be running\n";
3249           }
3250         }
3251       else
3252         {
3253         print ", but the socket for clamd could not be determined\n";
3254         print "Assume ClamAV is not running\n";
3255         }
3256       }
3257
3258     else
3259       {
3260       print ", but I can't find a configuration for clamd\n";
3261       print "Assume ClamAV is not running\n";
3262       }
3263     }
3264   }
3265
3266
3267 ##################################################
3268 #       Check for redis                          #
3269 ##################################################
3270 if (defined $parm_lookups{redis})
3271   {
3272   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3273     {
3274     print "The redis-server command works\n";
3275     $parm_running{redis} = ' ';
3276     }
3277   else
3278     {
3279     print "The redis-server command failed: assume Redis not installed\n";
3280     }
3281   }
3282
3283 ##################################################
3284 #         Test for the basic requirements        #
3285 ##################################################
3286
3287 # This test suite assumes that Exim has been built with at least the "usual"
3288 # set of routers, transports, and lookups. Ensure that this is so.
3289
3290 $missing = '';
3291
3292 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3293
3294 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3295 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3296 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3297 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3298
3299 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3300 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3301 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3302 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3303
3304 if ($missing ne '')
3305   {
3306   print "\n";
3307   print "** Many features can be included or excluded from Exim binaries.\n";
3308   print "** This test suite requires that Exim is built to contain a certain\n";
3309   print "** set of basic facilities. It seems that some of these are missing\n";
3310   print "** from the binary that is under test, so the test cannot proceed.\n";
3311   print "** The missing facilities are:\n";
3312   print "$missing";
3313   die "** Test script abandoned\n";
3314   }
3315
3316
3317 ##################################################
3318 #      Check for the auxiliary programs          #
3319 ##################################################
3320
3321 # These are always required:
3322
3323 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3324            "fakens", "iefbr14", "server")
3325   {
3326   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3327   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3328   if (!-e "bin/$prog")
3329     {
3330     print "\n";
3331     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3332     die "** Test script abandoned\n";
3333     }
3334   }
3335
3336 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3337 # compiled on systems where we don't know how to. However, if Exim does not
3338 # have that functionality compiled, we needn't bother.
3339
3340 $dlfunc_deleted = 0;
3341 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3342   {
3343   delete $parm_support{Expand_dlfunc};
3344   $dlfunc_deleted = 1;
3345   }
3346
3347
3348 ##################################################
3349 #          Find environmental details            #
3350 ##################################################
3351
3352 # Find the caller of this program.
3353
3354 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3355  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3356
3357 $pwpw = $pwpw;       # Kill Perl warnings
3358 $pwquota = $pwquota;
3359 $pwcomm = $pwcomm;
3360
3361 $parm_caller_group = getgrgid($parm_caller_gid);
3362
3363 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3364 print "Home directory is $parm_caller_home\n";
3365
3366 unless (defined $parm_eximgroup)
3367   {
3368   print "Unable to derive \$parm_eximgroup.\n";
3369   die "** ABANDONING.\n";
3370   }
3371
3372 if ($parm_caller_home eq $parm_cwd)
3373   {
3374   print "will confuse working dir with homedir; change homedir\n";
3375   die "** ABANDONING.\n";
3376   }
3377
3378 print "You need to be in the Exim group to run these tests. Checking ...";
3379
3380 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3381   {
3382   print " OK\n";
3383   }
3384 else
3385   {
3386   print "\nOh dear, you are not in the Exim group.\n";
3387   die "** Testing abandoned.\n";
3388   }
3389
3390 # Find this host's IP addresses - there may be many, of course, but we keep
3391 # one of each type (IPv4 and IPv6).
3392
3393 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3394   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3395 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3396   {
3397   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3398     {
3399     next if $1 =~ /^(?:127|10)\./;
3400     $parm_ipv4 = $1;
3401     }
3402
3403   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:%[^ \/]+)?(?:\/\d+)?/i)
3404     {
3405     next if $1 eq '::1' or $1 =~ /^fe80/i;
3406     $parm_ipv6 = $1;
3407     }
3408   }
3409 close(IFCONFIG);
3410
3411 # Use private IP addresses if there are no public ones.
3412
3413 # If either type of IP address is missing, we need to set the value to
3414 # something other than empty, because that wrecks the substitutions. The value
3415 # is reflected, so use a meaningful string. Set appropriate options for the
3416 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3417 # available, so things will go wrong if there is no IPv4 address. The lack
3418 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3419 # and $have_ipv6 false.
3420
3421 if (not $parm_ipv4)
3422   {
3423   $have_ipv4 = 0;
3424   $parm_ipv4 = "<no IPv4 address found>";
3425   $server_opts .= " -noipv4";
3426   }
3427 elsif ($have_ipv4 == 0)
3428   {
3429   $parm_ipv4 = "<IPv4 testing disabled>";
3430   $server_opts .= " -noipv4";
3431   }
3432 else
3433   {
3434   $parm_running{IPv4} = " ";
3435   }
3436
3437 if (not $parm_ipv6)
3438   {
3439   $have_ipv6 = 0;
3440   $parm_ipv6 = "<no IPv6 address found>";
3441   $server_opts .= " -noipv6";
3442   delete($parm_support{IPv6});
3443   }
3444 elsif ($have_ipv6 == 0)
3445   {
3446   $parm_ipv6 = "<IPv6 testing disabled>";
3447   $server_opts .= " -noipv6";
3448   delete($parm_support{IPv6});
3449   }
3450 elsif (!defined $parm_support{IPv6})
3451   {
3452   $have_ipv6 = 0;
3453   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3454   $server_opts .= " -noipv6";
3455   }
3456 else
3457   {
3458   $parm_running{IPv6} = " ";
3459   }
3460
3461 print "IPv4 address is $parm_ipv4\n";
3462 print "IPv6 address is $parm_ipv6\n";
3463 $parm_ipv6 =~ /^[^%\/]*/;
3464
3465 # For munging test output, we need the reversed IP addresses.
3466
3467 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3468   join(".", reverse(split /\./, $parm_ipv4));
3469
3470 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3471 if ($parm_ipv6 =~ /^[\da-f]/)
3472   {
3473   my(@comps) = split /:/, $parm_ipv6;
3474   my(@nibbles);
3475   foreach $comp (@comps)
3476     {
3477     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3478     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3479     }
3480   $parm_ipv6r = join(".", reverse(@nibbles));
3481   }
3482
3483 # Find the host name, fully qualified.
3484
3485 chomp($temp = `hostname`);
3486 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3487 if ($temp =~ /\./)
3488   {
3489   $parm_hostname = $temp;
3490   }
3491 else
3492   {
3493   $parm_hostname = (gethostbyname($temp))[0];
3494   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3495   }
3496 print "Hostname is $parm_hostname\n";
3497
3498 if ($parm_hostname !~ /\./)
3499   {
3500   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3501   }
3502
3503 if ($parm_hostname =~ /[[:upper:]]/)
3504   {
3505   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3506   }
3507
3508 if ($parm_hostname =~ /\.example\.com$/)
3509   {
3510   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3511         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3512   }
3513
3514
3515
3516 ##################################################
3517 #     Create a testing version of Exim           #
3518 ##################################################
3519
3520 # We want to be able to run Exim with a variety of configurations. Normally,
3521 # the use of -C to change configuration causes Exim to give up its root
3522 # privilege (unless the caller is exim or root). For these tests, we do not
3523 # want this to happen. Also, we want Exim to know that it is running in its
3524 # test harness.
3525
3526 # We achieve this by copying the binary and patching it as we go. The new
3527 # binary knows it is a testing copy, and it allows -C and -D without loss of
3528 # privilege. Clearly, this file is dangerous to have lying around on systems
3529 # where there are general users with login accounts. To protect against this,
3530 # we put the new binary in a special directory that is accessible only to the
3531 # caller of this script, who is known to have sudo root privilege from the test
3532 # that was done above. Furthermore, we ensure that the binary is deleted at the
3533 # end of the test. First ensure the directory exists.
3534
3535 if (-d "eximdir")
3536   { unlink "eximdir/exim"; }     # Just in case
3537 else
3538   {
3539   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3540   system("sudo chgrp $parm_eximgroup eximdir");
3541   }
3542
3543 # The construction of the patched binary must be done as root, so we use
3544 # a separate script. As well as indicating that this is a test-harness binary,
3545 # the version number is patched to "x.yz" so that its length is always the
3546 # same. Otherwise, when it appears in Received: headers, it affects the length
3547 # of the message, which breaks certain comparisons.
3548
3549 die "** Unable to make patched exim: $!\n"
3550   if (system("sudo ./patchexim $parm_exim") != 0);
3551
3552 # From this point on, exits from the program must go via the subroutine
3553 # tests_exit(), so that suitable cleaning up can be done when required.
3554 # Arrange to catch interrupting signals, to assist with this.
3555
3556 $SIG{INT} = \&inthandler;
3557 $SIG{PIPE} = \&pipehandler;
3558
3559 # For some tests, we need another copy of the binary that is setuid exim rather
3560 # than root.
3561
3562 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3563        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3564        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3565        "sudo chmod 06755 eximdir/exim_exim");
3566
3567 ##################################################
3568 #     Make copies of utilities we might need     #
3569 ##################################################
3570
3571 # Certain of the tests make use of some of Exim's utilities. We do not need
3572 # to be root to copy these.
3573
3574 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3575
3576 $dbm_build_deleted = 0;
3577 if (defined $parm_lookups{dbm} &&
3578     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3579   {
3580   delete $parm_lookups{dbm};
3581   $dbm_build_deleted = 1;
3582   }
3583
3584 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3585   {
3586   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3587   }
3588
3589 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3590   {
3591   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3592   }
3593
3594 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3595   {
3596   tests_exit(-1, "Failed to make a copy of exinext: $!");
3597   }
3598
3599 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3600   {
3601   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3602   }
3603
3604 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3605   {
3606   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3607   }
3608
3609 # Collect some version information
3610 print '-' x 78, "\n";
3611 print "Perl version for runtest: $]\n";
3612 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3613   # fold (or unfold?) multiline output into a one-liner
3614   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3615 }
3616 print '-' x 78, "\n";
3617
3618
3619 ##################################################
3620 #    Check that the Exim user can access stuff   #
3621 ##################################################
3622
3623 # We delay this test till here so that we can check access to the actual test
3624 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3625
3626 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3627 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3628
3629 if ($parm_caller_uid eq $parm_exim_uid) {
3630   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3631                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3632 }
3633 if ($parm_caller_gid eq $parm_exim_gid) {
3634   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3635                 ."the same as caller's ($parm_caller) group as it confuses "
3636                 ."results analysis");
3637 }
3638
3639 print "The Exim user needs access to the test suite directory. Checking ...";
3640
3641 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3642   {
3643   my($why) = "unknown failure $rc";
3644   $rc >>= 8;
3645   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3646   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3647   $why = "Couldn't read auxiliary group list" if $rc == 3;
3648   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3649   $why = "Couldn't set gid" if $rc == 5;
3650   $why = "Couldn't set uid" if $rc == 6;
3651   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3652   print "\n** $why\n";
3653   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3654   }
3655 else
3656   {
3657   print " OK\n";
3658   }
3659
3660 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3661   if not unlink($log_summary_filename) and -e $log_summary_filename;
3662
3663 ##################################################
3664 #        Create a list of available tests        #
3665 ##################################################
3666
3667 # The scripts directory contains a number of subdirectories whose names are
3668 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3669 # from the first requires certain optional features to be included in the Exim
3670 # binary. These requirements are contained in a file called "REQUIRES" within
3671 # the directory. We scan all these tests, discarding those that cannot be run
3672 # because the current binary does not support the right facilities, and also
3673 # those that are outside the numerical range selected.
3674
3675 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3676   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3677
3678 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3679   if $dlfunc_deleted;
3680 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3681   if $dbm_build_deleted;
3682
3683
3684 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3685   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3686
3687 # Scan for relevant tests
3688 # HS12: Needs to be reworked.
3689 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3690   {
3691   my($testdir) = $test_dirs[$i];
3692   my($wantthis) = 1;
3693
3694   print ">>Checking $testdir\n" if $debug;
3695
3696   # Skip this directory if the first test is equal or greater than the first
3697   # test in the next directory.
3698
3699   next DIR if ($i < @test_dirs - 1) &&
3700           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3701
3702   # No need to carry on if the end test is less than the first test in this
3703   # subdirectory.
3704
3705   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3706
3707   # Check requirements, if any.
3708
3709   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3710     {
3711     while (<$requires>)
3712       {
3713       next if /^\s*$/;
3714       s/\s+$//;
3715       if (/^support (.*)$/)
3716         {
3717         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3718         }
3719       elsif (/^running (.*)$/)
3720         {
3721         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3722         }
3723       elsif (/^lookup (.*)$/)
3724         {
3725         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3726         }
3727       elsif (/^authenticators? (.*)$/)
3728         {
3729         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3730         }
3731       elsif (/^router (.*)$/)
3732         {
3733         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3734         }
3735       elsif (/^transport (.*)$/)
3736         {
3737         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3738         }
3739       elsif (/^malware (.*)$/)
3740         {
3741         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3742         }
3743       elsif (/^feature (.*)$/)
3744         {
3745         # move to a subroutine?
3746         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3747
3748         open (IN, "$parm_cwd/confs/0000") ||
3749           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3750         open (OUT, ">test-config") ||
3751           tests_exit(-1, "Couldn't open test-config: $!\n");
3752         while (<IN>)
3753           {
3754           do_substitute($testno);
3755           print OUT;
3756           }
3757         close(IN);
3758         close(OUT);
3759
3760         system($eximinfo . " >/dev/null 2>&1");
3761         if ($? != 0) {
3762           unlink("$parm_cwd/test-config");
3763           $wantthis = 0;
3764           $_ = "feature $1";
3765           last;
3766         }
3767         unlink("$parm_cwd/test-config");
3768         }
3769       else
3770         {
3771         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3772         }
3773       }
3774     }
3775   else
3776     {
3777     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3778       unless $!{ENOENT};
3779     }
3780
3781   # Loop if we do not want the tests in this subdirectory.
3782
3783   if (!$wantthis)
3784     {
3785     chomp;
3786     print "Omitting tests in $testdir (missing $_)\n";
3787     }
3788
3789   # We want the tests from this subdirectory, provided they are in the
3790   # range that was selected.
3791
3792   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3793   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3794     if not @testlist;
3795
3796   foreach $test (@testlist)
3797     {
3798     if (!$wantthis)
3799       {
3800       log_test($log_summary_filename, $test, '.');
3801       }
3802     else
3803       {
3804       push @test_list, "$testdir/$test";
3805       }
3806     }
3807   }
3808
3809 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
3810
3811
3812 ##################################################
3813 #         Munge variable auxiliary data          #
3814 ##################################################
3815
3816 # Some of the auxiliary data files have to refer to the current testing
3817 # directory and other parameter data. The generic versions of these files are
3818 # stored in the aux-var-src directory. At this point, we copy each of them
3819 # to the aux-var directory, making appropriate substitutions. There aren't very
3820 # many of them, so it's easiest just to do this every time. Ensure the mode
3821 # is standardized, as this path is used as a test for the ${stat: expansion.
3822
3823 # A similar job has to be done for the files in the dnszones-src directory, to
3824 # make the fake DNS zones for testing. Most of the zone files are copied to
3825 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3826 # networks that are defined by parameter.
3827
3828 foreach $basedir ("aux-var", "dnszones")
3829   {
3830   system("sudo rm -rf $parm_cwd/$basedir");
3831   mkdir("$parm_cwd/$basedir", 0777);
3832   chmod(0755, "$parm_cwd/$basedir");
3833
3834   opendir(AUX, "$parm_cwd/$basedir-src") ||
3835     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3836   my(@filelist) = readdir(AUX);
3837   close(AUX);
3838
3839   foreach $file (@filelist)
3840     {
3841     my($outfile) = $file;
3842     next if $file =~ /^\./;
3843
3844     if ($file eq "db.ip4.V4NET")
3845       {
3846       $outfile = "db.ip4.$parm_ipv4_test_net";
3847       }
3848     elsif ($file eq "db.ip6.V6NET")
3849       {
3850       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3851       $" = '.';
3852       $outfile = "db.ip6.@nibbles";
3853       $" = ' ';
3854       }
3855
3856     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3857     open(IN, "$parm_cwd/$basedir-src/$file") ||
3858       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3859     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3860       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3861     while (<IN>)
3862       {
3863       do_substitute(0);
3864       print OUT;
3865       }
3866     close(IN);
3867     close(OUT);
3868     }
3869   }
3870
3871 # Set a user's shell, distinguishable from /bin/sh
3872
3873 symlink('/bin/sh' => 'aux-var/sh');
3874 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3875
3876 ##################################################
3877 #     Create fake DNS zones for this host        #
3878 ##################################################
3879
3880 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3881 # sure that there are forward and reverse registrations for this host, using
3882 # its real IP addresses. Dynamically created zone files achieve this.
3883
3884 if ($have_ipv4 || $have_ipv6)
3885   {
3886   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3887   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3888     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3889   print OUT "; This is a dynamically constructed fake zone file.\n" .
3890     "; The following line causes fakens to return PASS_ON\n" .
3891     "; for queries that it cannot answer\n\n" .
3892     "PASS ON NOT FOUND\n\n";
3893   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3894   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3895   print OUT "\n; End\n";
3896   close(OUT);
3897   }
3898
3899 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3900   {
3901   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3902   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3903     tests_exit(-1,
3904       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3905   print OUT "; This is a dynamically constructed fake zone file.\n" .
3906     "; The zone is $components[0].in-addr.arpa.\n\n" .
3907     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3908     "; End\n";
3909   close(OUT);
3910   }
3911
3912 if ($have_ipv6 && $parm_ipv6 ne "::1")
3913   {
3914   my($exp_v6) = $parm_ipv6;
3915   $exp_v6 =~ s/[^:]//g;
3916   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3917     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3918   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3919     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3920   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3921     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3922   } else {
3923     $exp_v6 = $parm_ipv6;
3924   }
3925   my(@components) = split /:/, $exp_v6;
3926   my(@nibbles) = reverse (split /\s*/, shift @components);
3927   my($sep) =  '';
3928
3929   $" = ".";
3930   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3931     tests_exit(-1,
3932       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3933   print OUT "; This is a dynamically constructed fake zone file.\n" .
3934     "; The zone is @nibbles.ip6.arpa.\n\n";
3935
3936   @components = reverse @components;
3937   foreach $c (@components)
3938     {
3939     $c = "0$c" until $c =~ /^..../;
3940     @nibbles = reverse(split /\s*/, $c);
3941     print OUT "$sep@nibbles";
3942     $sep = ".";
3943     }
3944
3945   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3946   close(OUT);
3947   $" = " ";
3948   }
3949
3950
3951
3952 ##################################################
3953 #    Create lists of mailboxes and message logs  #
3954 ##################################################
3955
3956 # We use these lists to check that a test has created the expected files. It
3957 # should be faster than looking for the file each time. For mailboxes, we have
3958 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3959 # is just a flat list of files.
3960
3961 @oldmails = list_files_below("mail");
3962 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3963 @oldmsglogs = readdir(DIR);
3964 closedir(DIR);
3965
3966
3967
3968 ##################################################
3969 #         Run the required tests                 #
3970 ##################################################
3971
3972 # Each test script contains a number of tests, separated by a line that
3973 # contains ****. We open input from the terminal so that we can read responses
3974 # to prompts.
3975
3976 if (not $force_continue) {
3977   # runtest needs to interact if we're not in continue
3978   # mode. It does so by communicate to /dev/tty
3979   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
3980   print "\nPress RETURN to run the tests: ";
3981   <T>;
3982 }
3983
3984
3985 foreach $test (@test_list)
3986   {
3987   state $lasttestdir = '';
3988
3989   local $lineno     = 0;
3990   local $commandno  = 0;
3991   local $subtestno  = 0;
3992   local $sortlog    = 0;
3993
3994   (local $testno = $test) =~ s|.*/||;
3995
3996   # Leaving traces in the process table and in the environment
3997   # gives us a chance to identify hanging processes (exim daemons)
3998   local $0 = "[runtest $testno]";
3999   local $ENV{EXIM_TEST_NUMBER} = $testno;
4000
4001   my $gnutls   = 0;
4002   my $docheck  = 1;
4003   my $thistestdir  = substr($test, 0, -5);
4004
4005   $dynamic_socket->close() if $dynamic_socket;
4006
4007   if ($lasttestdir ne $thistestdir)
4008     {
4009     $gnutls = 0;
4010     if (-s "scripts/$thistestdir/REQUIRES")
4011       {
4012       my $indent = '';
4013       print "\n>>> The following tests require: ";
4014       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
4015         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
4016       while (<$requires>)
4017         {
4018         $gnutls = 1 if /^support GnuTLS/;
4019         print $indent, $_;
4020         $indent = ">>>                              ";
4021         }
4022       }
4023       $lasttestdir = $thistestdir;
4024     }
4025
4026   # Remove any debris in the spool directory and the test-mail directory
4027   # and also the files for collecting stdout and stderr. Then put back
4028   # the test-mail directory for appendfile deliveries.
4029
4030   system "sudo /bin/rm -rf spool test-*";
4031   system "mkdir test-mail 2>/dev/null";
4032
4033   # A privileged Exim will normally make its own spool directory, but some of
4034   # the tests run in unprivileged modes that don't always work if the spool
4035   # directory isn't already there. What is more, we want anybody to be able
4036   # to read it in order to find the daemon's pid.
4037
4038   system "mkdir spool; " .
4039          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
4040          "sudo chmod 0755 spool";
4041
4042   # Empty the cache that keeps track of things like message id mappings, and
4043   # set up the initial sequence strings.
4044
4045   undef %cache;
4046   $next_msgid = "aX";
4047   $next_pid = 1234;
4048   $next_port = 1111;
4049   $message_skip = 0;
4050   $msglog_skip = 0;
4051   $stderr_skip = 0;
4052   $stdout_skip = 0;
4053   $rmfiltertest = 0;
4054   $is_ipv6test = 0;
4055   $TEST_STATE->{munge} = '';
4056
4057   # Remove the associative arrays used to hold checked mail files and msglogs
4058
4059   undef %expected_mails;
4060   undef %expected_msglogs;
4061
4062   # Open the test's script
4063   open(SCRIPT, "scripts/$test") ||
4064     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
4065   # Run through the script once to set variables which should be global
4066   while (<SCRIPT>)
4067     {
4068     if (/^no_message_check/) { $message_skip = 1; next; }
4069     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4070     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4071     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4072     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4073     if (/^sortlog/)          { $sortlog = 1; next; }
4074     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
4075     }
4076   # Reset to beginning of file for per test interpreting/processing
4077   seek(SCRIPT, 0, 0);
4078
4079   # The first line in the script must be a comment that is used to identify
4080   # the set of tests as a whole.
4081
4082   $_ = <SCRIPT>;
4083   $lineno++;
4084   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
4085   printf("%s %s", (substr $test, 5), (substr $_, 2));
4086
4087   # Loop for each of the subtests within the script. The variable $server_pid
4088   # is used to remember the pid of a "server" process, for which we do not
4089   # wait until we have waited for a subsequent command.
4090
4091   local($server_pid) = 0;
4092   for ($commandno = 1; !eof SCRIPT; $commandno++)
4093     {
4094     # Skip further leading comments and blank lines, handle the flag setting
4095     # commands, and deal with tests for IP support.
4096
4097     while (<SCRIPT>)
4098       {
4099       $lineno++;
4100       # Could remove these variable settings because they are already
4101       # set above, but doesn't hurt to leave them here.
4102       if (/^no_message_check/) { $message_skip = 1; next; }
4103       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4104       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4105       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4106       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4107       if (/^sortlog/)          { $sortlog = 1; next; }
4108
4109       if (/^need_largefiles/)
4110         {
4111         next if $have_largefiles;
4112         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4113         $docheck = 0;      # don't check output
4114         undef $_;          # pretend EOF
4115         last;
4116         }
4117
4118       if (/^need_ipv4/)
4119         {
4120         next if $have_ipv4;
4121         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4122         $docheck = 0;      # don't check output
4123         undef $_;          # pretend EOF
4124         last;
4125         }
4126
4127       if (/^need_ipv6/)
4128         {
4129         if ($have_ipv6)
4130           {
4131           $is_ipv6test = 1;
4132           next;
4133           }
4134         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4135         $docheck = 0;      # don't check output
4136         undef $_;          # pretend EOF
4137         last;
4138         }
4139
4140       if (/^need_move_frozen_messages/)
4141         {
4142         next if defined $parm_support{move_frozen_messages};
4143         print ">>> move frozen message support is needed for test $testno, " .
4144           "but is not\n>>> available: skipping\n";
4145         $docheck = 0;      # don't check output
4146         undef $_;          # pretend EOF
4147         last;
4148         }
4149
4150       last unless /^(?:#(?!##\s)|\s*$)/;
4151       }
4152     last if !defined $_;  # Hit EOF
4153
4154     my($subtest_startline) = $lineno;
4155
4156     # Now run the command. The function returns 0 for an inline command,
4157     # 1 if a non-exim command was run and waited for, 2 if an exim
4158     # command was run and waited for, and 3 if a command
4159     # was run and not waited for (usually a daemon or server startup).
4160
4161     my($commandname) = '';
4162     my($expectrc) = 0;
4163     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4164     my($cmdrc) = $?;
4165
4166     if ($debug) {
4167       print ">> rc=$rc cmdrc=$cmdrc\n";
4168       if (defined $run_extra) {
4169         foreach my $k (keys %$run_extra) {
4170           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4171           print ">>   $k -> $v\n";
4172         }
4173       }
4174     }
4175     $run_extra = {} unless defined $run_extra;
4176     foreach my $k (keys %$run_extra) {
4177       if (exists $TEST_STATE->{$k}) {
4178         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4179         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4180       }
4181       if (defined $run_extra->{$k}) {
4182         $TEST_STATE->{$k} = $run_extra->{$k};
4183       } elsif (exists $TEST_STATE->{$k}) {
4184         delete $TEST_STATE->{$k};
4185       }
4186     }
4187
4188     # Hit EOF after an initial return code number
4189
4190     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4191
4192     # Carry on with the next command if we did not wait for this one. $rc == 0
4193     # if no subprocess was run; $rc == 3 if we started a process but did not
4194     # wait for it.
4195
4196     next if ($rc == 0 || $rc == 3);
4197
4198     # We ran and waited for a command. Check for the expected result unless
4199     # it died.
4200
4201     if ($cmdrc != $expectrc && !$sigpipehappened)
4202       {
4203       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4204       if (($cmdrc & 0xff) == 0)
4205         {
4206         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4207         }
4208       elsif (($cmdrc & 0xff00) == 0)
4209         { printf("** Killed by signal %d", $cmdrc & 255); }
4210       else
4211         { printf("** Status %x", $cmdrc); }
4212
4213       for (;;)
4214         {
4215         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4216         $_ = $force_continue ? "c" : <T>;
4217         tests_exit(1) if /^q?$/i;
4218         if (/^c$/ && $force_continue) {
4219           log_failure($log_failed_filename, $testno, "exit code unexpected");
4220           log_test($log_summary_filename, $testno, 'F')
4221         }
4222         if ($force_continue)
4223           {
4224           print "\nstdout tail:\n";
4225           print "==================>\n";
4226           system("tail -20 test-stdout");
4227           print "===================\n";
4228           print "stderr tail:\n";
4229           print "==================>\n";
4230           system("tail -20 test-stderr");
4231           print "===================\n";
4232           print "... continue forced\n";
4233           }
4234
4235         last if /^[rc]$/i;
4236         if (/^e$/i)
4237           {
4238           system("$more test-stderr");
4239           }
4240         elsif (/^o$/i)
4241           {
4242           system("$more test-stdout");
4243           }
4244         }
4245
4246       $retry = 1 if /^r$/i;
4247       $docheck = 0;
4248       }
4249
4250     # If the command was exim, and a listening server is running, we can now
4251     # close its input, which causes us to wait for it to finish, which is why
4252     # we didn't close it earlier.
4253
4254     if ($rc == 2 && $server_pid != 0)
4255       {
4256       close SERVERCMD;
4257       $server_pid = 0;
4258       if ($? != 0)
4259         {
4260         if (($? & 0xff) == 0)
4261           { printf("Server return code %d for test %d starting line %d", $?/256,
4262                 $testno, $subtest_startline); }
4263         elsif (($? & 0xff00) == 0)
4264           { printf("Server killed by signal %d", $? & 255); }
4265         else
4266           { printf("Server status %x", $?); }
4267
4268         for (;;)
4269           {
4270           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4271           $_ = $force_continue ? "c" : <T>;
4272           tests_exit(1) if /^q?$/i;
4273           if (/^c$/ && $force_continue) {
4274             log_failure($log_failed_filename, $testno, "exit code unexpected");
4275             log_test($log_summary_filename, $testno, 'F')
4276           }
4277           print "... continue forced\n" if $force_continue;
4278           last if /^[rc]$/i;
4279
4280           if (/^s$/i)
4281             {
4282             open(S, "test-stdout-server") ||
4283               tests_exit(-1, "Failed to open test-stdout-server: $!");
4284             print while <S>;
4285             close(S);
4286             }
4287           }
4288         $retry = 1 if /^r$/i;
4289         }
4290       }
4291     }
4292
4293   close SCRIPT;
4294
4295   # The script has finished. Check the all the output that was generated. The
4296   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4297   # rerun the test (the files # have been updated).
4298   # It does not return if the user responds Q to a prompt.
4299
4300   if ($retry)
4301     {
4302     $retry = '0';
4303     print (("#" x 79) . "\n");
4304     redo;
4305     }
4306
4307   if ($docheck)
4308     {
4309     sleep 1 if $slow;
4310     my $rc = check_output($TEST_STATE->{munge});
4311     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4312     if ($rc < 2)
4313       {
4314       print ("  Script completed\n");
4315       }
4316     else
4317       {
4318       print (("#" x 79) . "\n");
4319       redo;
4320       }
4321     }
4322   }
4323
4324
4325 ##################################################
4326 #         Exit from the test script              #
4327 ##################################################
4328
4329 tests_exit(-1, "No runnable tests selected") if not @test_list;
4330 tests_exit(0);
4331
4332 __END__
4333
4334 =head1 NAME
4335
4336  runtest - run the exim testsuite
4337
4338 =head1 SYNOPSIS
4339
4340  runtest [exim-path] [options] [test0 [test1]]
4341
4342 =head1 DESCRIPTION
4343
4344 B<runtest> runs the Exim testsuite.
4345
4346 =head1 OPTIONS
4347
4348 For legacy reasons the options are not case sensitive.
4349
4350 =over
4351
4352 =item B<--continue>
4353
4354 Do not stop for user interaction or on errors. (default: off)
4355
4356 =item B<--debug>
4357
4358 This option enables the output of debug information when running the
4359 various test commands. (default: off)
4360
4361 =item B<--diff>
4362
4363 Use C<diff -u> for comparing the expected output with the produced
4364 output. (default: use a built-in routine)
4365
4366 =item B<--flavor>|B<--flavour> I<flavour>
4367
4368 Override the expected results for results for a specific (OS) flavour.
4369 (default: unused)
4370
4371 =item B<--[no]ipv4>
4372
4373 Skip IPv4 related setup and tests (default: use ipv4)
4374
4375 =item B<--[no]ipv6>
4376
4377 Skip IPv6 related setup and tests (default: use ipv6)
4378
4379 =item B<--keep>
4380
4381 Keep the various output files produced during a test run. (default: don't keep)
4382
4383 =item B<--range> I<n0> I<n1>
4384
4385 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4386 test available".
4387
4388 =item B<--slow>
4389
4390 Insert some delays to compensate for a slow host system. (default: off)
4391
4392 =item B<--test> I<n>
4393
4394 Run the specified test. This option may used multiple times.
4395
4396 =item B<--update>
4397
4398 Automatically update the recorded (expected) data on mismatch. (default: off)
4399
4400 =item B<--valgrind>
4401
4402 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4403
4404 =back
4405
4406 =cut
4407
4408
4409 # End of runtest script