src/src/exigrep.src

   1 #! PERL_COMMAND
   2
   3 use warnings;
   4 use strict;
   5 BEGIN { pop @INC if $INC[-1] eq '.' };
   6
   7 # Copyright (c) 2007-2015 University of Cambridge.
   8 # See the file NOTICE for conditions of use and distribution.
   9
  10 # Except when they appear in comments, the following placeholders in this
  11 # source are replaced when it is turned into a runnable script:
  12 #
  13 # PERL_COMMAND
  14 # ZCAT_COMMAND
  15 # COMPRESS_SUFFIX
  16
  17 # PROCESSED_FLAG
  18
  19 # This is a perl script which extracts from an Exim log all entries
  20 # for all messages that have an entry that matches a given pattern.
  21 # If *any* entry for a particular message matches the pattern, *all*
  22 # entries for that message are displayed.
  23
  24 # We buffer up information on a per-message basis. It is done this way rather
  25 # than reading the input twice so that the input can be a pipe.
  26
  27 # There must be one argument, which is the pattern. Subsequent arguments
  28 # are the files to scan; if none, the standard input is read. If any file
  29 # appears to be compressed, it is passed through zcat. We can't just do this
  30 # for all files, because zcat chokes on non-compressed files.
  31
  32 # Performance optimized in 02/02/2007 by Jori Hamalainen
  33 # Typical run time acceleration: 4 times
  34
  35
  36 use Getopt::Std qw(getopts);
  37 use POSIX qw(mktime);
  38
  39
  40 # This subroutine converts a time/date string from an Exim log line into
  41 # the number of seconds since the epoch. It handles optional timezone
  42 # information.
  43
  44 sub seconds {
  45 my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
  46   $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?>\s([+-])(\d\d)(\d\d))?/o;
  47
  48 my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;
  49
  50 if (defined $tzs)
  51   {
  52   $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
  53   $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
  54   }
  55
  56 return $seconds;
  57 }
  58
  59
  60 # This subroutine processes a single line (in $_) from a log file. Program
  61 # defensively against short lines finding their way into the log.
  62
  63 my (%saved, %id_list, $pattern, $queue_time, $insensitive, $invert);
  64
  65 # If using "related" option, have to track extra message IDs
  66 my $related;
  67 my $related_re='';
  68 my @Mids = ();
  69
  70 sub do_line {
  71
  72 # Convert syslog lines to mainlog format, as in eximstats.
  73
  74 if (!/^\d{4}-/o) { $_ =~ s/^.*? exim\b.*?: //o; }
  75
  76 return unless
  77   my($date,$id) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?(\w{6}\-\w{6}\-\w{2})?/o;
  78
  79 # Handle the case when the log line belongs to a specific message. We save
  80 # lines for specific messages until the message is complete. Then either print
  81 # or discard.
  82
  83 if (defined $id)
  84   {
  85   $saved{$id} = '' unless defined($saved{$id});
  86
  87   # Save up the data for this message in case it becomes interesting later.
  88
  89   $saved{$id} .= $_;
  90
  91   # Are we interested in this id ? Short circuit if we already were interested.
  92
  93   if ($invert)
  94     {
  95     $id_list{$id} = 1 if (!defined($id_list{$id}));
  96     $id_list{$id} = 0 if (($insensitive && /$pattern/io) || /$pattern/o);
  97     }
  98   else
  99     {
 100     if (defined $id_list{$id} ||
 101       ($insensitive && /$pattern/io) || /$pattern/o)
 102       {
 103       $id_list{$id} = 1;
 104       get_related_ids($id) if $related;
 105       }
 106     elsif ($related && $related_re)
 107       {
 108       grep_for_related($_, $id);
 109       }
 110     }
 111
 112   # See if this is a completion for some message. If it is interesting,
 113   # print it, but in any event, throw away what was saved.
 114
 115   if (index($_, 'Completed') != -1 ||
 116       index($_, 'SMTP data timeout') != -1 ||
 117         (index($_, 'rejected') != -1 &&
 118           /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?\w{6}\-\w{6}\-\w{2} rejected/o))
 119     {
 120     if ($queue_time != -1 &&
 121         $saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)/o)
 122       {
 123       my $old_sec = &seconds($1);
 124       my $sec = &seconds($date);
 125       $id_list{$id} = 0 if $id_list{$id} && $sec - $old_sec <= $queue_time;
 126       }
 127
 128     print "$saved{$id}\n" if ($id_list{$id});
 129     delete $id_list{$id};
 130     delete $saved{$id};
 131     }
 132   }
 133
 134 # Handle the case where the log line does not belong to a specific message.
 135 # Print it if it is interesting.
 136
 137 elsif ( ($invert && (($insensitive && !/$pattern/io) || !/$pattern/o)) ||
 138        (!$invert && (($insensitive &&  /$pattern/io) ||  /$pattern/o)) )
 139   { print "$_\n"; }
 140 }
 141
 142 # Rotated log files are frequently compressed and there are a variety of
 143 # formats it could be compressed with. Rather than use just one that is
 144 # detected and hardcoded at Exim compile time, detect and use what the
 145 # logfile is compressed with on the fly.
 146 #
 147 # List of known compression extensions and their associated commands:
 148 my $compressors = {
 149   gz   => { cmd => 'zcat',  args => '' },
 150   bz2  => { cmd => 'bzcat', args => '' },
 151   xz   => { cmd => 'xzcat', args => '' },
 152   lzma => { cmd => 'lzma',  args => '-dc' }
 153 };
 154 my $csearch = 0;
 155
 156 sub detect_compressor_bin
 157   {
 158   my $ext = shift();
 159   my $c = $compressors->{$ext}->{cmd};
 160   $compressors->{$ext}->{bin} = `which $c 2>/dev/null`;
 161   chomp($compressors->{$ext}->{bin});
 162   }
 163
 164 sub detect_compressor_capable
 165   {
 166   my $filename = shift();
 167   map { &detect_compressor_bin($_) } keys %$compressors
 168     if (!$csearch);
 169   $csearch = 1;
 170   return undef
 171     unless (grep {$filename =~ /\.(?:$_)$/} keys %$compressors);
 172   # Loop through them, figure out which one it detected,
 173   # and build the commandline.
 174   my $cmdline = undef;
 175   foreach my $ext (keys %$compressors)
 176     {
 177     if ($filename =~ /\.(?:$ext)$/)
 178       {
 179       # Just die if compressor not found; if this occurs in the middle of
 180       # two valid files with a lot of matches, error could easily be missed.
 181       die("Didn't find $ext decompressor for $filename\n")
 182         if ($compressors->{$ext}->{bin} eq '');
 183       $cmdline = $compressors->{$ext}->{bin} ." ".
 184                    $compressors->{$ext}->{args};
 185       last;
 186       }
 187     }
 188   return $cmdline;
 189   }
 190
 191 sub grep_for_related {
 192   my ($line,$id) = @_;
 193   $id_list{$id} = 1 if $line =~ m/$related_re/;
 194 }
 195
 196 sub get_related_ids {
 197   my ($id) = @_;
 198   push @Mids, $id unless grep /\b$id\b/, @Mids;
 199   my $re = join '|', @Mids;
 200   $related_re = qr/$re/;
 201 }
 202
 203 # The main program. Extract the pattern and make sure any relevant characters
 204 # are quoted if the -l flag is given. The -t flag gives a time-on-queue value
 205 # which is an additional condition. The -M flag will also display "related"
 206 # loglines (msgid from matched lines is searched in following lines).
 207
 208 getopts('Ilvt:M',\my %args);
 209 $queue_time  = $args{'t'}? $args{'t'} : -1;
 210 $insensitive = $args{'I'}? 0 : 1;
 211 $invert      = $args{'v'}? 1 : 0;
 212 $related     = $args{'M'}? 1 : 0;
 213
 214 die "usage: exigrep [-I] [-l] [-M] [-t <seconds>] [-v] <pattern> [<log file>]...\n"
 215   if ($#ARGV < 0);
 216
 217 $pattern = shift @ARGV;
 218 $pattern = quotemeta $pattern if $args{l};
 219
 220
 221 # If file arguments are given, open each one and process according as it is
 222 # is compressed or not.
 223
 224 if (@ARGV)
 225   {
 226   foreach (@ARGV)
 227     {
 228     my $filename = $_;
 229     if (-x 'ZCAT_COMMAND' && $filename =~ /\.(?:COMPRESS_SUFFIX)$/o)
 230       {
 231       open(LOG, "ZCAT_COMMAND $filename |") ||
 232         die "Unable to zcat $filename: $!\n";
 233       }
 234     elsif (my $cmdline = &detect_compressor_capable($filename))
 235       {
 236       open(LOG, "$cmdline $filename |") ||
 237         die "Unable to decompress $filename: $!\n";
 238       }
 239     else
 240       {
 241       open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
 242       }
 243     do_line() while (<LOG>);
 244     close(LOG);
 245     }
 246   }
 247
 248 # If no files are named, process STDIN only
 249
 250 else { do_line() while (<STDIN>); }
 251
 252 # At the end of processing all the input, print any uncompleted messages.
 253
 254 for (keys %id_list)
 255   {
 256   print "+++ $_ has not completed +++\n$saved{$_}\n";
 257   }
 258
 259 # End of exigrep