test/runtest

   1 #! /usr/bin/perl -w
   2
   3 ###############################################################################
   4 # This is the controlling script for the "new" test suite for Exim. It should #
   5 # be possible to export this suite for running on a wide variety of hosts, in #
   6 # contrast to the old suite, which was very dependent on the environment of   #
   7 # Philip Hazel's desktop computer. This implementation inspects the version   #
   8 # of Exim that it finds, and tests only those features that are included. The #
   9 # surrounding environment is also tested to discover what is available. See   #
  10 # the README file for details of how it all works.                            #
  11 #                                                                             #
  12 # Implementation started: 03 August 2005 by Philip Hazel                      #
  13 # Placed in the Exim CVS: 06 February 2006                                    #
  14 ###############################################################################
  15
  16 #use strict;
  17 use Errno;
  18 use FileHandle;
  19 use Socket;
  20 use Time::Local;
  21 use Cwd;
  22 use File::Basename;
  23 use if $ENV{DEBUG} && $ENV{DEBUG} =~ /\bruntest\b/ => ('Smart::Comments' => '####');
  24
  25
  26 # Start by initializing some global variables
  27
  28 $testversion = "4.80 (08-May-12)";
  29
  30 # This gets embedded in the D-H params filename, and the value comes
  31 # from asking GnuTLS for "normal", but there appears to be no way to
  32 # use certtool/... to ask what that value currently is.  *sigh*
  33 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  34 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  35 # normal = 2432   tls_dh_max_bits = 2236
  36 $gnutls_dh_bits_normal = 2236;
  37
  38 $cf = "bin/cf -exact";
  39 $cr = "\r";
  40 $debug = 0;
  41 $flavour = 'FOO';
  42 $force_continue = 0;
  43 $force_update = 0;
  44 $log_failed_filename = "failed-summary.log";
  45 $more = "less -XF";
  46 $optargs = "";
  47 $save_output = 0;
  48 $server_opts = "";
  49 $valgrind = 0;
  50
  51 $have_ipv4 = 1;
  52 $have_ipv6 = 1;
  53 $have_largefiles = 0;
  54
  55 $test_start = 1;
  56 $test_end = $test_top = 8999;
  57 $test_special_top = 9999;
  58 @test_list = ();
  59 @test_dirs = ();
  60
  61
  62 # Networks to use for DNS tests. We need to choose some networks that will
  63 # never be used so that there is no chance that the host on which we are
  64 # running is actually in one of the test networks. Private networks such as
  65 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  66 # Rather than use some unassigned numbers (that might become assigned later),
  67 # I have chosen some multicast networks, in the belief that such addresses
  68 # won't ever be assigned to hosts. This is the only place where these numbers
  69 # are defined, so it is trivially possible to change them should that ever
  70 # become necessary.
  71
  72 $parm_ipv4_test_net = "224";
  73 $parm_ipv6_test_net = "ff00";
  74
  75 # Port numbers are currently hard-wired
  76
  77 $parm_port_n = 1223;         # Nothing listening on this port
  78 $parm_port_s = 1224;         # Used for the "server" command
  79 $parm_port_d = 1225;         # Used for the Exim daemon
  80 $parm_port_d2 = 1226;        # Additional for daemon
  81 $parm_port_d3 = 1227;        # Additional for daemon
  82 $parm_port_d4 = 1228;        # Additional for daemon
  83
  84 # Manually set locale
  85 $ENV{'LC_ALL'} = 'C';
  86
  87 # In some environments USER does not exists, but we
  88 # need it for some test(s)
  89 $ENV{USER} = getpwuid($>)
  90   if not exists $ENV{USER};
  91
  92
  93 ###############################################################################
  94 ###############################################################################
  95
  96 # Define a number of subroutines
  97
  98 ###############################################################################
  99 ###############################################################################
 100
 101
 102 ##################################################
 103 #              Handle signals                    #
 104 ##################################################
 105
 106 sub pipehandler { $sigpipehappened = 1; }
 107
 108 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 109
 110
 111 ##################################################
 112 #       Do global macro substitutions            #
 113 ##################################################
 114
 115 # This function is applied to configurations, command lines and data lines in
 116 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 117 # directory. It takes one argument: the current test number, or zero when
 118 # setting up files before running any tests.
 119
 120 sub do_substitute{
 121 s?\bCALLER\b?$parm_caller?g;
 122 s?\bCALLERGROUP\b?$parm_caller_group?g;
 123 s?\bCALLER_UID\b?$parm_caller_uid?g;
 124 s?\bCALLER_GID\b?$parm_caller_gid?g;
 125 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 126 s?\bDIR/?$parm_cwd/?g;
 127 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 128 s?\bEXIMUSER\b?$parm_eximuser?g;
 129 s?\bHOSTIPV4\b?$parm_ipv4?g;
 130 s?\bHOSTIPV6\b?$parm_ipv6?g;
 131 s?\bHOSTNAME\b?$parm_hostname?g;
 132 s?\bPORT_D\b?$parm_port_d?g;
 133 s?\bPORT_D2\b?$parm_port_d2?g;
 134 s?\bPORT_D3\b?$parm_port_d3?g;
 135 s?\bPORT_D4\b?$parm_port_d4?g;
 136 s?\bPORT_N\b?$parm_port_n?g;
 137 s?\bPORT_S\b?$parm_port_s?g;
 138 s?\bTESTNUM\b?$_[0]?g;
 139 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 140 s?\bV6NET:?$parm_ipv6_test_net:?g;
 141 }
 142
 143
 144 ##################################################
 145 #     Any state to be preserved across tests     #
 146 ##################################################
 147
 148 my $TEST_STATE = {};
 149
 150
 151 ##################################################
 152 #        Subroutine to tidy up and exit          #
 153 ##################################################
 154
 155 # In all cases, we check for any Exim daemons that have been left running, and
 156 # kill them. Then remove all the spool data, test output, and the modified Exim
 157 # binary if we are ending normally.
 158
 159 # Arguments:
 160 #    $_[0] = 0 for a normal exit; full cleanup done
 161 #    $_[0] > 0 for an error exit; no files cleaned up
 162 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 163
 164 sub tests_exit{
 165 my($rc) = $_[0];
 166 my($spool);
 167
 168 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 169 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 170 # the background.
 171
 172 if (exists $TEST_STATE->{exim_pid})
 173   {
 174   $pid = $TEST_STATE->{exim_pid};
 175   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 176   system("sudo kill -INT $pid");
 177   }
 178
 179 if (opendir(DIR, "spool"))
 180   {
 181   my(@spools) = sort readdir(DIR);
 182   closedir(DIR);
 183   foreach $spool (@spools)
 184     {
 185     next if $spool !~ /^exim-daemon./;
 186     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 187     chomp($pid = <PID>);
 188     close(PID);
 189     print "Tidyup: killing daemon pid=$pid\n";
 190     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 191     }
 192   }
 193 else
 194   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 195
 196 # Close the terminal input and remove the test files if all went well, unless
 197 # the option to save them is set. Always remove the patched Exim binary. Then
 198 # exit normally, or die.
 199
 200 close(T);
 201 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 202   if ($rc == 0 && !$save_output);
 203
 204 system("sudo /bin/rm -rf ./eximdir/*")
 205   if (!$save_output);
 206
 207 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 208 exit $rc if ($rc >= 0);
 209 die "** runtest error: $_[1]\n";
 210 }
 211
 212
 213
 214 ##################################################
 215 #   Subroutines used by the munging subroutine   #
 216 ##################################################
 217
 218 # This function is used for things like message ids, where we want to generate
 219 # more than one value, but keep a consistent mapping throughout.
 220 #
 221 # Arguments:
 222 #   $oldid        the value from the file
 223 #   $base         a base string into which we insert a sequence
 224 #   $sequence     the address of the current sequence counter
 225
 226 sub new_value {
 227 my($oldid, $base, $sequence) = @_;
 228 my($newid) = $cache{$oldid};
 229 if (! defined $newid)
 230   {
 231   $newid = sprintf($base, $$sequence++);
 232   $cache{$oldid} = $newid;
 233   }
 234 return $newid;
 235 }
 236
 237
 238 # This is used while munging the output from exim_dumpdb.
 239 # May go wrong across DST changes.
 240
 241 sub date_seconds {
 242 my($day,$month,$year,$hour,$min,$sec) =
 243   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 244 my($mon);
 245 if   ($month =~ /Jan/) {$mon = 0;}
 246 elsif($month =~ /Feb/) {$mon = 1;}
 247 elsif($month =~ /Mar/) {$mon = 2;}
 248 elsif($month =~ /Apr/) {$mon = 3;}
 249 elsif($month =~ /May/) {$mon = 4;}
 250 elsif($month =~ /Jun/) {$mon = 5;}
 251 elsif($month =~ /Jul/) {$mon = 6;}
 252 elsif($month =~ /Aug/) {$mon = 7;}
 253 elsif($month =~ /Sep/) {$mon = 8;}
 254 elsif($month =~ /Oct/) {$mon = 9;}
 255 elsif($month =~ /Nov/) {$mon = 10;}
 256 elsif($month =~ /Dec/) {$mon = 11;}
 257 return timelocal($sec,$min,$hour,$day,$mon,$year);
 258 }
 259
 260
 261 # This is a subroutine to sort maildir files into time-order. The second field
 262 # is the microsecond field, and may vary in length, so must be compared
 263 # numerically.
 264
 265 sub maildirsort {
 266 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 267 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 268 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 269 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 270 }
 271
 272
 273
 274 ##################################################
 275 #   Subroutine list files below a directory      #
 276 ##################################################
 277
 278 # This is used to build up a list of expected mail files below a certain path
 279 # in the directory tree. It has to be recursive in order to deal with multiple
 280 # maildir mailboxes.
 281
 282 sub list_files_below {
 283 my($dir) = $_[0];
 284 my(@yield) = ();
 285 my(@sublist, $file);
 286
 287 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 288 @sublist = sort maildirsort readdir(DIR);
 289 closedir(DIR);
 290
 291 foreach $file (@sublist)
 292   {
 293   next if $file eq "." || $file eq ".." || $file eq "CVS";
 294   if (-d "$dir/$file")
 295     { @yield = (@yield, list_files_below("$dir/$file")); }
 296   else
 297     { push @yield, "$dir/$file"; }
 298   }
 299
 300 return @yield;
 301 }
 302
 303
 304
 305 ##################################################
 306 #         Munge a file before comparing          #
 307 ##################################################
 308
 309 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 310 # on into standard values, so that the compare works. Perl's substitution with
 311 # an expression provides a neat way to do some of these changes.
 312
 313 # We keep a global associative array for repeatedly turning the same values
 314 # into the same standard values throughout the data from a single test.
 315 # Message ids get this treatment (can't be made reliable for times), and
 316 # times in dumped retry databases are also handled in a special way, as are
 317 # incoming port numbers.
 318
 319 # On entry to the subroutine, the file to write to is already opened with the
 320 # name MUNGED. The input file name is the only argument to the subroutine.
 321 # Certain actions are taken only when the name contains "stderr", "stdout",
 322 # or "log". The yield of the function is 1 if a line matching "*** truncated
 323 # ***" is encountered; otherwise it is 0.
 324
 325 sub munge {
 326 my($file) = $_[0];
 327 my($extra) = $_[1];
 328 my($yield) = 0;
 329 my(@saved) = ();
 330
 331 local $_;
 332
 333 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 334
 335 my($is_log) = $file =~ /log/;
 336 my($is_stdout) = $file =~ /stdout/;
 337 my($is_stderr) = $file =~ /stderr/;
 338
 339 # Date pattern
 340
 341 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 342
 343 # Pattern for matching pids at start of stderr lines; initially something
 344 # that won't match.
 345
 346 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 347
 348 # Scan the file and make the changes. Near the bottom there are some changes
 349 # that are specific to certain file types, though there are also some of those
 350 # inline too.
 351
 352 while(<IN>)
 353   {
 354 RESET_AFTER_EXTRA_LINE_READ:
 355   # Custom munges
 356   if ($extra)
 357     {
 358     next if $extra =~ m%^/%  &&  eval $extra;
 359     eval $extra if $extra =~ m/^s/;
 360     }
 361
 362   # Check for "*** truncated ***"
 363   $yield = 1 if /\*\*\* truncated \*\*\*/;
 364
 365   # Replace the name of this host
 366   s/\Q$parm_hostname\E/the.local.host.name/g;
 367
 368   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 369   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 370
 371   # The name of the shell may vary
 372   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 373
 374   # Replace the path to the testsuite directory
 375   s?\Q$parm_cwd\E?TESTSUITE?g;
 376
 377   # Replace the Exim version number (may appear in various places)
 378   # patchexim should have fixed this for us
 379   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 380
 381   # Replace Exim message ids by a unique series
 382   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 383     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 384
 385   # The names of lock files appear in some error and debug messages
 386   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 387
 388   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 389   # port" message, because it is not always the same.
 390   s/port (\d+) \([^)]+\)/port $1/g
 391     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 392
 393   # Challenges in SPA authentication
 394   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 395
 396   # PRVS values
 397   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 398   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 399
 400   # Error lines on stdout from SSL contain process id values and file names.
 401   # They also contain a source file name and line number, which may vary from
 402   # release to release.
 403   s/^\d+:error:/pppp:error:/;
 404   s/:(?:\/[^\s:]+\/)?([^\/\s]+\.c):\d+:/:$1:dddd:/;
 405
 406   # There are differences in error messages between OpenSSL versions
 407   s/SSL_CTX_set_cipher_list/SSL_connect/;
 408
 409   # One error test in expansions mentions base 62 or 36
 410   s/is not a base (36|62) number/is not a base 36\/62 number/;
 411
 412   # This message sometimes has a different number of seconds
 413   s/forced fail after \d seconds/forced fail after d seconds/;
 414
 415   # This message may contain a different DBM library name
 416   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 417
 418   # The message for a non-listening FIFO varies
 419   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 420
 421   # Debugging output of lists of hosts may have different sort keys
 422   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 423
 424   # Random local part in callout cache testing
 425   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 426   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 427
 428   # File descriptor numbers may vary
 429   s/^writing data block fd=\d+/writing data block fd=dddd/;
 430   s/running as transport filter: write=\d+ read=\d+/running as transport filter: write=dddd read=dddd/;
 431
 432
 433   # ======== Dumpdb output ========
 434   # This must be before the general date/date munging.
 435   # Time data lines, which look like this:
 436   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 437   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 438     {
 439     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 440     $expired = "" if !defined $expired;
 441     my($increment) = date_seconds($date3) - date_seconds($date2);
 442
 443     # We used to use globally unique replacement values, but timing
 444     # differences make this impossible. Just show the increment on the
 445     # last one.
 446
 447     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 448       $increment, $expired);
 449     next;
 450     }
 451
 452   # more_errno values in exim_dumpdb output which are times
 453   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 454
 455
 456   # ======== Dates and times ========
 457
 458   # Dates and times are all turned into the same value - trying to turn
 459   # them into different ones cannot be done repeatedly because they are
 460   # real time stamps generated while running the test. The actual date and
 461   # time used was fixed when I first started running automatic Exim tests.
 462
 463   # Date/time in header lines and SMTP responses
 464   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 465     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 466
 467   # Date/time in logs and in one instance of a filter test
 468   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 469   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 470
 471   # Date/time in message separators
 472   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 473     /Tue Mar 02 09:44:33 1999/gx;
 474
 475   # Date of message arrival in spool file as shown by -Mvh
 476   s/^\d{9,10}\s0$/ddddddddd 0/;
 477
 478   # Date/time in mbx mailbox files
 479   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 480
 481   # Dates/times in debugging output for writing retry records
 482   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 483     {
 484     my($next) = $3 - $2;
 485     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 486     }
 487   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 488   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 489
 490   # Time to retry may vary
 491   s/time to retry = \S+/time to retry = tttt/;
 492   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 493   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 494
 495   # Date/time in exim -bV output
 496   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 497
 498   # Time on queue tolerance
 499   s/(QT|D)=1s/$1=0s/;
 500
 501   # Eximstats heading
 502   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 503     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 504
 505   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 506   # us the former on a new connection.
 507   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 508
 509   # ======== TLS certificate algorithms ========
 510   # Test machines might have various different TLS library versions supporting
 511   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 512   # treat the standard algorithms the same.
 513   # So far, have seen:
 514   #   TLSv1:AES128-GCM-SHA256:128
 515   #   TLSv1:AES256-SHA:256
 516   #   TLSv1.1:AES256-SHA:256
 517   #   TLSv1.2:AES256-GCM-SHA384:256
 518   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 519   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 520   # We also need to handle the ciphersuite without the TLS part present, for
 521   # client-ssl's output.  We also see some older forced ciphersuites, but
 522   # negotiating TLS 1.2 instead of 1.0.
 523   # Mail headers (...), log-lines X=..., client-ssl output ...
 524   # (and \b doesn't match between ' ' and '(' )
 525
 526   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 527   s/\bAES128-GCM-SHA256:128\b/AES256-SHA:256/g;
 528   s/\bAES128-GCM-SHA256\b/AES256-SHA/g;
 529   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 530   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 531
 532   # GnuTLS have seen:
 533   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 534   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 535   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 536   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 537   #
 538   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 539   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 540   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 541   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 542   # and as stand-alone cipher:
 543   #   ECDHE-RSA-AES256-SHA
 544   #   DHE-RSA-AES256-SHA256
 545   #   DHE-RSA-AES256-SHA
 546   # picking latter as canonical simply because regex easier that way.
 547   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 548   s/TLS1.[012]:((EC)?DHE_)?RSA_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 549   s/\b(ECDHE-RSA-AES256-SHA|DHE-RSA-AES256-SHA256)\b/AES256-SHA/g;
 550
 551   # GnuTLS library error message changes
 552   s/No certificate was found/The peer did not send any certificate/g;
 553 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 554   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 555
 556   # (this new one is a generic channel-read error, but the testsuite
 557   # only hits it in one place)
 558   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 559
 560   # (replace old with new, hoping that old only happens in one situation)
 561   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 562   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 563
 564   # signature algorithm names
 565   s/RSA-SHA1/RSA-SHA/;
 566
 567
 568   # ======== Caller's login, uid, gid, home, gecos ========
 569
 570   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 571   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 572   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 573
 574   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 575   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 576
 577   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 578   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 579
 580   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 581
 582   # When looking at spool files with -Mvh, we will find not only the caller
 583   # login, but also the uid and gid. It seems that $) in some Perls gives all
 584   # the auxiliary gids as well, so don't bother checking for that.
 585
 586   s/^CALLER $> \d+$/CALLER UID GID/;
 587
 588   # There is one case where the caller's login is forced to something else,
 589   # in order to test the processing of logins that contain spaces. Weird what
 590   # some people do, isn't it?
 591
 592   s/^spaced user $> \d+$/CALLER UID GID/;
 593
 594
 595   # ======== Exim's login ========
 596   # For messages received by the daemon, this is in the -H file, which some
 597   # tests inspect. For bounce messages, this will appear on the U= lines in
 598   # logs and also after Received: and in addresses. In one pipe test it appears
 599   # after "Running as:". It also appears in addresses, and in the names of lock
 600   # files.
 601
 602   s/U=$parm_eximuser/U=EXIMUSER/;
 603   s/user=$parm_eximuser/user=EXIMUSER/;
 604   s/login=$parm_eximuser/login=EXIMUSER/;
 605   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 606   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 607   s/\b$parm_eximuser@/EXIMUSER@/;
 608   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 609
 610   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 611   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 612
 613   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 614   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 615
 616   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 617
 618
 619   # ======== General uids, gids, and pids ========
 620   # Note: this must come after munges for caller's and exim's uid/gid
 621
 622   # These are for systems where long int is 64
 623   s/\buid=4294967295/uid=-1/;
 624   s/\beuid=4294967295/euid=-1/;
 625   s/\bgid=4294967295/gid=-1/;
 626   s/\begid=4294967295/egid=-1/;
 627
 628   s/\bgid=\d+/gid=gggg/;
 629   s/\begid=\d+/egid=gggg/;
 630   s/\bpid=\d+/pid=pppp/;
 631   s/\buid=\d+/uid=uuuu/;
 632   s/\beuid=\d+/euid=uuuu/;
 633   s/set_process_info:\s+\d+/set_process_info: pppp/;
 634   s/queue run pid \d+/queue run pid ppppp/;
 635   s/process \d+ running as transport filter/process pppp running as transport filter/;
 636   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 637   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 638   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 639
 640   # Pid in temp file in appendfile transport
 641   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 642
 643   # Optional pid in log lines
 644   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 645     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 646
 647   # Detect a daemon stderr line with a pid and save the pid for subsequent
 648   # removal from following lines.
 649   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 650   s/^$spid //;
 651
 652   # Queue runner waiting messages
 653   s/waiting for children of \d+/waiting for children of pppp/;
 654   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 655
 656   # ======== Port numbers ========
 657   # Incoming port numbers may vary, but not in daemon startup line.
 658
 659   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 660   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 661
 662   # This handles "connection from" and the like, when the port is given
 663   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 664       && !/\*>/ && !/Connection refused/)
 665     {
 666     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 667     }
 668
 669   # Port in host address in spool file output from -Mvh
 670   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 671
 672
 673   # ======== Local IP addresses ========
 674   # The amount of space between "host" and the address in verification output
 675   # depends on the length of the host name. We therefore reduce it to one space
 676   # for all of them.
 677   # Also, the length of space at the end of the host line is dependent
 678   # on the length of the longest line, so strip it also on otherwise
 679   # un-rewritten lines like localhost
 680
 681   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 682   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 683   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 684   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 685   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 686   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 687   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 688   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 689   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 690   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 691
 692
 693   # ======== Test network IP addresses ========
 694   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 695   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 696
 697
 698   # ======== IP error numbers and messages ========
 699   # These vary between operating systems
 700   s/Can't assign requested address/Network Error/;
 701   s/Cannot assign requested address/Network Error/;
 702   s/Operation timed out/Connection timed out/;
 703   s/Address family not supported by protocol family/Network Error/;
 704   s/Network is unreachable/Network Error/;
 705   s/Invalid argument/Network Error/;
 706
 707   s/\(\d+\): Network/(dd): Network/;
 708   s/\(\d+\): Connection refused/(dd): Connection refused/;
 709   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 710   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 711   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 712
 713
 714   # ======== Other error numbers ========
 715   s/errno=\d+/errno=dd/g;
 716
 717   # ======== System Error Messages ======
 718   # depending on the underlaying file system the error message seems to differ
 719   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 720
 721   # ======== Output from ls ========
 722   # Different operating systems use different spacing on long output
 723   #s/ +/ /g if /^[-rwd]{10} /;
 724   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 725   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 726   # unfortunately matches a non-ls linefull of dashes.
 727   # Allow the case where we've already picked out the file protection bits.
 728   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 729     s/ +/ /g;
 730   }
 731
 732
 733   # ======== Message sizes =========
 734   # Message sizes vary, owing to different logins and host names that get
 735   # automatically inserted. I can't think of any way of even approximately
 736   # comparing these.
 737
 738   s/([\s,])S=\d+\b/$1S=sss/;
 739   s/:S\d+\b/:Ssss/;
 740   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 741   s/\sSIZE=\d+\b/ SIZE=ssss/;
 742   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 743   s/old size = \d+\b/old size = sssss/;
 744   s/message size = \d+\b/message size = sss/;
 745   s/this message = \d+\b/this message = sss/;
 746   s/Size of headers = \d+/Size of headers = sss/;
 747   s/sum=(?!0)\d+/sum=dddd/;
 748   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 749   s/(?<=sum=0 )count=\d+\b/count=dd/;
 750   s/,S is \d+\b/,S is ddddd/;
 751   s/\+0100,\d+;/+0100,ddd;/;
 752   s/\(\d+ bytes written\)/(ddd bytes written)/;
 753   s/added '\d+ 1'/added 'ddd 1'/;
 754   s/Received\s+\d+/Received               nnn/;
 755   s/Delivered\s+\d+/Delivered              nnn/;
 756
 757
 758   # ======== Values in spool space failure message ========
 759   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 760
 761
 762   # ======== Filter sizes ========
 763   # The sizes of filter files may vary because of the substitution of local
 764   # filenames, logins, etc.
 765
 766   s/^\d+(?= bytes read from )/ssss/;
 767
 768
 769   # ======== OpenSSL error messages ========
 770   # Different releases of the OpenSSL libraries seem to give different error
 771   # numbers, or handle specific bad conditions in different ways, leading to
 772   # different wording in the error messages, so we cannot compare them.
 773
 774   s/(TLS error on connection (?:from .* )?\(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 775   next if /SSL verify error: depth=0 error=certificate not trusted/;
 776
 777   # ======== Maildir things ========
 778   # timestamp output in maildir processing
 779   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 780
 781   # maildir delivery files appearing in log lines (in cases of error)
 782   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 783
 784   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 785
 786   # Maildir file names in general
 787   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 788
 789   # Maildirsize data
 790   while (/^\d+S,\d+C\s*$/)
 791     {
 792     print MUNGED;
 793     while (<IN>)
 794       {
 795       last if !/^\d+ \d+\s*$/;
 796       print MUNGED "ddd d\n";
 797       }
 798     last if !defined $_;
 799     }
 800   last if !defined $_;
 801
 802
 803   # ======== Output from the "fd" program about open descriptors ========
 804   # The statuses seem to be different on different operating systems, but
 805   # at least we'll still be checking the number of open fd's.
 806
 807   s/max fd = \d+/max fd = dddd/;
 808   s/status=0 RDONLY/STATUS/g;
 809   s/status=1 WRONLY/STATUS/g;
 810   s/status=2 RDWR/STATUS/g;
 811
 812
 813   # ======== Contents of spool files ========
 814   # A couple of tests dump the contents of the -H file. The length fields
 815   # will be wrong because of different user names, etc.
 816   s/^\d\d\d(?=[PFS*])/ddd/;
 817
 818
 819   # ========= Exim lookups ==================
 820   # Lookups have a char which depends on the number of lookup types compiled in,
 821   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 822   # other output is fragile; perhaps the debug output should be revised instead.
 823   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 824
 825   # ==========================================================
 826   # MIME boundaries in RFC3461 DSN messages
 827   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 828
 829   # ==========================================================
 830   # Some munging is specific to the specific file types
 831
 832   # ======== stdout ========
 833
 834   if ($is_stdout)
 835     {
 836     # Skip translate_ip_address and use_classresources in -bP output because
 837     # they aren't always there.
 838
 839     next if /translate_ip_address =/;
 840     next if /use_classresources/;
 841
 842     # In certain filter tests, remove initial filter lines because they just
 843     # clog up by repetition.
 844
 845     if ($rmfiltertest)
 846       {
 847       next if /^(Sender\staken\sfrom|
 848                  Return-path\scopied\sfrom|
 849                  Sender\s+=|
 850                  Recipient\s+=)/x;
 851       if (/^Testing \S+ filter/)
 852         {
 853         $_ = <IN>;    # remove blank line
 854         next;
 855         }
 856       }
 857
 858     # openssl version variances
 859     next if /^SSL info: unknown state/;
 860     next if /^SSL info: SSLv2\/v3 write client hello A/;
 861     next if /^SSL info: SSLv3 read server key exchange A/;
 862     next if /SSL verify error: depth=0 error=certificate not trusted/;
 863     s/SSL3_READ_BYTES/ssl3_read_bytes/;
 864
 865     # gnutls version variances
 866     next if /^Error in the pull function./;
 867     }
 868
 869   # ======== stderr ========
 870
 871   elsif ($is_stderr)
 872     {
 873     # The very first line of debugging output will vary
 874
 875     s/^Exim version .*/Exim version x.yz ..../;
 876
 877     # Debugging lines for Exim terminations
 878
 879     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 880
 881     # IP address lookups use gethostbyname() when IPv6 is not supported,
 882     # and gethostbyname2() or getipnodebyname() when it is.
 883
 884     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 885
 886     # drop gnutls version strings
 887     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 888     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 889
 890     # drop openssl version strings
 891     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 892     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 893
 894     # drop lookups
 895     next if /^Lookups \(built-in\):/;
 896     next if /^Loading lookup modules from/;
 897     next if /^Loaded \d+ lookup modules/;
 898     next if /^Total \d+ lookups/;
 899
 900     # drop compiler information
 901     next if /^Compiler:/;
 902
 903     # and the ugly bit
 904     # different libraries will have different numbers (possibly 0) of follow-up
 905     # lines, indenting with more data
 906     if (/^Library version:/) {
 907       while (1) {
 908         $_ = <IN>;
 909         next if /^\s/;
 910         goto RESET_AFTER_EXTRA_LINE_READ;
 911       }
 912     }
 913
 914     # drop other build-time controls emitted for debugging
 915     next if /^WHITELIST_D_MACROS:/;
 916     next if /^TRUSTED_CONFIG_LIST:/;
 917
 918     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 919     # with -be, privileges will have been dropped, so this will always
 920     # be the case
 921     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 922
 923     # We might not keep this check; rather than change all the tests, just
 924     # ignore it as long as it succeeds; then we only need to change the
 925     # TLS tests where tls_require_ciphers has been set.
 926     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 927       my $discard = <IN>;
 928       next;
 929     }
 930     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 931
 932     # We invoke Exim with -D, so we hit this new messag as of Exim 4.73:
 933     next if /^macros_trusted overridden to true by whitelisting/;
 934
 935     # We have to omit the localhost ::1 address so that all is well in
 936     # the IPv4-only case.
 937
 938     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 939       if (/looked up these IP addresses/);
 940     next if /name=localhost address=::1/;
 941
 942     # drop pdkim debugging header
 943     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 944
 945     # Various other IPv6 lines must be omitted too
 946
 947     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 948     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 949     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 950     next if / in dns_ipv4_lookup?/;
 951
 952     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 953       {
 954       $_= <IN>;     # Gets "returning DNS_NODATA"
 955       next;
 956       }
 957
 958     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 959     # are unset, because tls ain't always there.
 960
 961     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
 962                 \sno\s\((option\sunset|end\sof\slist)\)/x;
 963
 964     # Skip auxiliary group lists because they will vary.
 965
 966     next if /auxiliary group list:/;
 967
 968     # Skip "extracted from gecos field" because the gecos field varies
 969
 970     next if /extracted from gecos field/;
 971
 972     # Skip "waiting for data on socket" and "read response data: size=" lines
 973     # because some systems pack more stuff into packets than others.
 974
 975     next if /waiting for data on socket/;
 976     next if /read response data: size=/;
 977
 978     # If Exim is compiled with readline support but it can't find the library
 979     # to load, there will be an extra debug line. Omit it.
 980
 981     next if /failed to load readline:/;
 982
 983     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
 984     # O_CREAT; other's don't. In the latter case there is some debugging output
 985     # which is not present in the former. Skip the relevant lines (there are
 986     # two of them).
 987
 988     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
 989       {
 990       $_ = <IN>;
 991       next;
 992       }
 993
 994     # Some tests turn on +expand debugging to check on expansions.
 995     # Unfortunately, the Received: expansion varies, depending on whether TLS
 996     # is compiled or not. So we must remove the relevant debugging if it is.
 997
 998     if (/^condition: def:tls_cipher/)
 999       {
1000       while (<IN>) { last if /^condition: def:sender_address/; }
1001       }
1002     elsif (/^expanding: Received: /)
1003       {
1004       while (<IN>) { last if !/^\s/; }
1005       }
1006
1007     # When Exim is checking the size of directories for maildir, it uses
1008     # the check_dir_size() function to scan directories. Of course, the order
1009     # of the files that are obtained using readdir() varies from system to
1010     # system. We therefore buffer up debugging lines from check_dir_size()
1011     # and sort them before outputting them.
1012
1013     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1014       {
1015       push @saved, $_;
1016       }
1017     else
1018       {
1019       if (@saved > 0)
1020         {
1021         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1022           "to ensure consistency\n";
1023         @saved = sort(@saved);
1024         print MUNGED @saved;
1025         @saved = ();
1026         }
1027
1028     # remote port numbers vary
1029     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1030
1031     # Skip hosts_require_dane checks when the options
1032     # are unset, because dane ain't always there.
1033
1034     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1035
1036     # SUPPORT_PROXY
1037     next if /host in hosts_proxy\?/;
1038
1039     # Experimental_International
1040     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1041
1042       # Skip some lines that Exim puts out at the start of debugging output
1043       # because they will be different in different binaries.
1044
1045       print MUNGED
1046         unless (/^Berkeley DB: / ||
1047                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1048                 /^Authenticators:/ ||
1049                 /^Lookups:/ ||
1050                 /^Support for:/ ||
1051                 /^Routers:/ ||
1052                 /^Transports:/ ||
1053                 /^log selectors =/ ||
1054                 /^cwd=/ ||
1055                 /^Fixed never_users:/ ||
1056                 /^Size of off_t:/
1057                 );
1058
1059
1060       }
1061
1062     next;
1063     }
1064
1065   # ======== log ========
1066
1067   elsif ($is_log)
1068     {
1069     # Berkeley DB version differences
1070     next if / Berkeley DB error: /;
1071     }
1072
1073   # ======== All files other than stderr ========
1074
1075   print MUNGED;
1076   }
1077
1078 close(IN);
1079 return $yield;
1080 }
1081
1082
1083
1084
1085 ##################################################
1086 #        Subroutine to interact with caller      #
1087 ##################################################
1088
1089 # Arguments: [0] the prompt string
1090 #            [1] if there is a U in the prompt and $force_update is true
1091 #            [2] if there is a C in the prompt and $force_continue is true
1092 # Returns:   returns the answer
1093
1094 sub interact{
1095 print $_[0];
1096 if ($_[1]) { $_ = "u"; print "... update forced\n"; }
1097   elsif ($_[2]) { $_ = "c"; print "... continue forced\n"; }
1098   else { $_ = <T>; }
1099 }
1100
1101
1102
1103 ##################################################
1104 #    Subroutine to log in force_continue mode    #
1105 ##################################################
1106
1107 # In force_continue mode, we just want a terse output to a statically
1108 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1109 # all have mismatches, it will log multiple times.
1110 #
1111 # Arguments: [0] the logfile to append to
1112 #            [1] the testno that failed
1113 # Returns:   nothing
1114
1115
1116
1117 sub log_failure {
1118   my $logfile = shift();
1119   my $testno  = shift();
1120   my $detail  = shift() || '';
1121   if ( open(my $fh, ">>", $logfile) ) {
1122     print $fh "Test $testno $detail failed\n";
1123     close $fh;
1124   }
1125 }
1126
1127
1128
1129 ##################################################
1130 #    Subroutine to compare one output file       #
1131 ##################################################
1132
1133 # When an Exim server is part of the test, its output is in separate files from
1134 # an Exim client. The server data is concatenated with the client data as part
1135 # of the munging operation.
1136 #
1137 # Arguments:  [0] the name of the main raw output file
1138 #             [1] the name of the server raw output file or undef
1139 #             [2] where to put the munged copy
1140 #             [3] the name of the saved file
1141 #             [4] TRUE if this is a log file whose deliveries must be sorted
1142 #             [5] optionally, a custom munge command
1143 #
1144 # Returns:    0 comparison succeeded or differences to be ignored
1145 #             1 comparison failed; files may have been updated (=> re-compare)
1146 #
1147 # Does not return if the user replies "Q" to a prompt.
1148
1149 sub check_file{
1150 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1151
1152 # If there is no saved file, the raw files must either not exist, or be
1153 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1154
1155 # we check if there is a flavour specific file, but we remember
1156 # the original file name as "generic"
1157 $sf_generic = $sf;
1158 $sf_flavour = "$sf_generic.$flavour";
1159 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1160
1161 if (! -e $sf_current)
1162   {
1163   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1164
1165   print "\n";
1166   print "** $rf is not empty\n" if (-s $rf);
1167   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1168
1169   for (;;)
1170     {
1171     print "Continue, Show, or Quit? [Q] ";
1172     $_ = $force_continue ? "c" : <T>;
1173     tests_exit(1) if /^q?$/i;
1174     log_failure($log_failed_filename, $testno, $rf) if (/^c$/i && $force_continue);
1175     return 0 if /^c$/i;
1176     last if (/^s$/);
1177     }
1178
1179   foreach $f ($rf, $rsf)
1180     {
1181     if (defined $f && -s $f)
1182       {
1183       print "\n";
1184       print "------------ $f -----------\n"
1185         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1186       system("$more '$f'");
1187       }
1188     }
1189
1190   print "\n";
1191   for (;;)
1192     {
1193     interact("Continue, Update & retry, Quit? [Q] ", $force_update, $force_continue);
1194     tests_exit(1) if /^q?$/i;
1195     log_failure($log_failed_filename, $testno, $rsf) if (/^c$/i && $force_continue);
1196     return 0 if /^c$/i;
1197     last if (/^u$/i);
1198     }
1199   }
1200
1201 #### $_
1202
1203 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1204 # was a request to create a saved file. First, create the munged file from any
1205 # data that does exist.
1206
1207 open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1208 my($truncated) = munge($rf, $extra) if -e $rf;
1209 if (defined $rsf && -e $rsf)
1210   {
1211   print MUNGED "\n******** SERVER ********\n";
1212   $truncated |= munge($rsf, $extra);
1213   }
1214 close(MUNGED);
1215
1216 # If a saved file exists, do the comparison. There are two awkward cases:
1217 #
1218 # If "*** truncated ***" was found in the new file, it means that a log line
1219 # was overlong, and truncated. The problem is that it may be truncated at
1220 # different points on different systems, because of different user name
1221 # lengths. We reload the file and the saved file, and remove lines from the new
1222 # file that precede "*** truncated ***" until we reach one that matches the
1223 # line that precedes it in the saved file.
1224 #
1225 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1226 # for an individual message might vary in their order from system to system, as
1227 # a result of parallel deliveries. We load the munged file and sort sequences
1228 # of delivery lines.
1229
1230 if (-e $sf_current)
1231   {
1232   # Deal with truncated text items
1233
1234   if ($truncated)
1235     {
1236     my(@munged, @saved, $i, $j, $k);
1237
1238     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1239     @munged = <MUNGED>;
1240     close(MUNGED);
1241     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1242     @saved = <SAVED>;
1243     close(SAVED);
1244
1245     $j = 0;
1246     for ($i = 0; $i < @munged; $i++)
1247       {
1248       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1249         {
1250         for (; $j < @saved; $j++)
1251           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1252         last if $j >= @saved;     # not found in saved
1253
1254         for ($k = $i - 1; $k >= 0; $k--)
1255           { last if $munged[$k] eq $saved[$j - 1]; }
1256
1257         last if $k <= 0;          # failed to find previous match
1258         splice @munged, $k + 1, $i - $k - 1;
1259         $i = $k + 1;
1260         }
1261       }
1262
1263     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1264     for ($i = 0; $i < @munged; $i++)
1265       { print MUNGED $munged[$i]; }
1266     close(MUNGED);
1267     }
1268
1269   # Deal with log sorting
1270
1271   if ($sortfile)
1272     {
1273     my(@munged, $i, $j);
1274
1275     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1276     @munged = <MUNGED>;
1277     close(MUNGED);
1278
1279     for ($i = 0; $i < @munged; $i++)
1280       {
1281       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1282         {
1283         for ($j = $i + 1; $j < @munged; $j++)
1284           {
1285           last if $munged[$j] !~
1286             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1287           }
1288         @temp = splice(@munged, $i, $j - $i);
1289         @temp = sort(@temp);
1290         splice(@munged, $i, 0, @temp);
1291         }
1292       }
1293
1294     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1295     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1296     for ($i = 0; $i < @munged; $i++)
1297       { print MUNGED $munged[$i]; }
1298     close(MUNGED);
1299     }
1300
1301   # Do the comparison
1302
1303   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1304
1305   # Handle comparison failure
1306
1307   print "** Comparison of $mf with $sf_current failed";
1308   system("$more test-cf");
1309
1310   print "\n";
1311   for (;;)
1312     {
1313     interact("Continue, Retry, Update current"
1314         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : "")
1315         . " & retry, Quit? [Q] ", $force_update, $force_continue);
1316     tests_exit(1) if /^q?$/i;
1317     log_failure($log_failed_filename, $testno, $sf_current) if (/^c$/i && $force_continue);
1318     return 0 if /^c$/i;
1319     return 1 if /^r$/i;
1320     last if (/^[us]$/i);
1321     }
1322   }
1323
1324 # Update or delete the saved file, and give the appropriate return code.
1325
1326 if (-s $mf)
1327   {
1328         my $sf = /^u/i ? $sf_current : $sf_flavour;
1329                 tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1330   }
1331 else
1332   {
1333         # if we deal with a flavour file, we can't delete it, because next time the generic
1334         # file would be used again
1335         if ($sf_current eq $sf_flavour) {
1336                 open(FOO, ">$sf_current");
1337                 close(FOO);
1338         }
1339         else {
1340                 tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1341         }
1342   }
1343
1344 return 1;
1345 }
1346
1347
1348
1349 ##################################################
1350 # Custom munges
1351 # keyed by name of munge; value is a ref to a hash
1352 # which is keyed by file, value a string to look for.
1353 # Usable files are:
1354 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1355 # Search strings starting with 's' do substitutions;
1356 # with '/' do line-skips.
1357 # Triggered by a scriptfile line "munge <name>"
1358 ##################################################
1359 $munges =
1360   { 'dnssec' =>
1361     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1362
1363     'gnutls_unexpected' =>
1364     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1365
1366     'gnutls_handshake' =>
1367     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1368
1369     'optional_events' =>
1370     { 'stdout' => '/event_action =/' },
1371
1372     'optional_ocsp' =>
1373     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1374
1375     'optional_cert_hostnames' =>
1376     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1377
1378     'loopback' =>
1379     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1380
1381     'scanfile_size' =>
1382     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1383
1384     'delay_1500' =>
1385     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1386
1387     'tls_anycipher' =>
1388     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1389
1390     'debug_pid' =>
1391     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1392
1393     'optional_dsn_info' =>
1394     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1395     },
1396
1397     'optional_config' =>
1398     { 'stdout' => '/^(
1399                   dkim_(canon|domain|private_key|selector|sign_headers|strict)
1400                   |gnutls_require_(kx|mac|protocols)
1401                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1402                   |hosts_(avoid|nopass|require|verify_avoid)_tls
1403                   |socks_proxy
1404                   |tls_[^ ]*
1405                   )($|[ ]=)/x' },
1406
1407     'sys_bindir' =>
1408     { 'mainlog' => 's%/(usr/)?bin/%SYSBINDIR/%' },
1409
1410     'sync_check_data' =>
1411     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1412       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1413
1414   };
1415
1416
1417 ##################################################
1418 #    Subroutine to check the output of a test    #
1419 ##################################################
1420
1421 # This function is called when the series of subtests is complete. It makes
1422 # use of check_file(), whose arguments are:
1423 #
1424 #  [0] the name of the main raw output file
1425 #  [1] the name of the server raw output file or undef
1426 #  [2] where to put the munged copy
1427 #  [3] the name of the saved file
1428 #  [4] TRUE if this is a log file whose deliveries must be sorted
1429 #  [5] an optional custom munge command
1430 #
1431 # Arguments: Optionally, name of a single custom munge to run.
1432 # Returns:   0 if the output compared equal
1433 #            1 if re-run needed (files may have been updated)
1434
1435 sub check_output{
1436 my($mungename) = $_[0];
1437 my($yield) = 0;
1438 my($munge) = $munges->{$mungename} if defined $mungename;
1439
1440 $yield = 1 if check_file("spool/log/paniclog",
1441                        "spool/log/serverpaniclog",
1442                        "test-paniclog-munged",
1443                        "paniclog/$testno", 0,
1444                        $munge->{'paniclog'});
1445
1446 $yield = 1 if check_file("spool/log/rejectlog",
1447                        "spool/log/serverrejectlog",
1448                        "test-rejectlog-munged",
1449                        "rejectlog/$testno", 0,
1450                        $munge->{'rejectlog'});
1451
1452 $yield = 1 if check_file("spool/log/mainlog",
1453                        "spool/log/servermainlog",
1454                        "test-mainlog-munged",
1455                        "log/$testno", $sortlog,
1456                        $munge->{'mainlog'});
1457
1458 if (!$stdout_skip)
1459   {
1460   $yield = 1 if check_file("test-stdout",
1461                        "test-stdout-server",
1462                        "test-stdout-munged",
1463                        "stdout/$testno", 0,
1464                        $munge->{'stdout'});
1465   }
1466
1467 if (!$stderr_skip)
1468   {
1469   $yield = 1 if check_file("test-stderr",
1470                        "test-stderr-server",
1471                        "test-stderr-munged",
1472                        "stderr/$testno", 0,
1473                        $munge->{'stderr'});
1474   }
1475
1476 # Compare any delivered messages, unless this test is skipped.
1477
1478 if (! $message_skip)
1479   {
1480   my($msgno) = 0;
1481
1482   # Get a list of expected mailbox files for this script. We don't bother with
1483   # directories, just the files within them.
1484
1485   foreach $oldmail (@oldmails)
1486     {
1487     next unless $oldmail =~ /^mail\/$testno\./;
1488     print ">> EXPECT $oldmail\n" if $debug;
1489     $expected_mails{$oldmail} = 1;
1490     }
1491
1492   # If there are any files in test-mail, compare them. Note that "." and
1493   # ".." are automatically omitted by list_files_below().
1494
1495   @mails = list_files_below("test-mail");
1496
1497   foreach $mail (@mails)
1498     {
1499     next if $mail eq "test-mail/oncelog";
1500
1501     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1502     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1503
1504     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1505       {
1506       $msgno++;
1507       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1508       }
1509
1510     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1511     $yield = 1 if check_file($mail, undef, "test-mail-munged",
1512       "mail/$testno.$saved_mail", 0,
1513       $munge->{'mail'});
1514     delete $expected_mails{"mail/$testno.$saved_mail"};
1515     }
1516
1517   # Complain if not all expected mails have been found
1518
1519   if (scalar(keys %expected_mails) != 0)
1520     {
1521     foreach $key (keys %expected_mails)
1522       { print "** no test file found for $key\n"; }
1523
1524     for (;;)
1525       {
1526       interact("Continue, Update & retry, or Quit? [Q] ", $force_update, $force_continue);
1527       tests_exit(1) if /^q?$/i;
1528       log_failure($log_failed_filename, $testno, "missing email") if (/^c$/i && $force_continue);
1529       last if /^c$/i;
1530
1531       # For update, we not only have to unlink the file, but we must also
1532       # remove it from the @oldmails vector, as otherwise it will still be
1533       # checked for when we re-run the test.
1534
1535       if (/^u$/i)
1536         {
1537         foreach $key (keys %expected_mails)
1538           {
1539           my($i);
1540           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1541           for ($i = 0; $i < @oldmails; $i++)
1542             {
1543             if ($oldmails[$i] eq $key)
1544               {
1545               splice @oldmails, $i, 1;
1546               last;
1547               }
1548             }
1549           }
1550         last;
1551         }
1552       }
1553     }
1554   }
1555
1556 # Compare any remaining message logs, unless this test is skipped.
1557
1558 if (! $msglog_skip)
1559   {
1560   # Get a list of expected msglog files for this test
1561
1562   foreach $oldmsglog (@oldmsglogs)
1563     {
1564     next unless $oldmsglog =~ /^$testno\./;
1565     $expected_msglogs{$oldmsglog} = 1;
1566     }
1567
1568   # If there are any files in spool/msglog, compare them. However, we have
1569   # to munge the file names because they are message ids, which are
1570   # time dependent.
1571
1572   if (opendir(DIR, "spool/msglog"))
1573     {
1574     @msglogs = sort readdir(DIR);
1575     closedir(DIR);
1576
1577     foreach $msglog (@msglogs)
1578       {
1579       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1580       ($munged_msglog = $msglog) =~
1581         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1582           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1583       $yield = 1 if check_file("spool/msglog/$msglog", undef,
1584         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1585         $munge->{'msglog'});
1586       delete $expected_msglogs{"$testno.$munged_msglog"};
1587       }
1588     }
1589
1590   # Complain if not all expected msglogs have been found
1591
1592   if (scalar(keys %expected_msglogs) != 0)
1593     {
1594     foreach $key (keys %expected_msglogs)
1595       {
1596       print "** no test msglog found for msglog/$key\n";
1597       ($msgid) = $key =~ /^\d+\.(.*)$/;
1598       foreach $cachekey (keys %cache)
1599         {
1600         if ($cache{$cachekey} eq $msgid)
1601           {
1602           print "** original msgid $cachekey\n";
1603           last;
1604           }
1605         }
1606       }
1607
1608     for (;;)
1609       {
1610       interact("Continue, Update, or Quit? [Q] ", $force_update, $force_continue);
1611       tests_exit(1) if /^q?$/i;
1612       log_failure($log_failed_filename, $testno, "missing msglog") if (/^c$/i && $force_continue);
1613       last if /^c$/i;
1614       if (/^u$/i)
1615         {
1616         foreach $key (keys %expected_msglogs)
1617           {
1618           tests_exit(-1, "Failed to unlink msglog/$key")
1619             if !unlink("msglog/$key");
1620           }
1621         last;
1622         }
1623       }
1624     }
1625   }
1626
1627 return $yield;
1628 }
1629
1630
1631
1632 ##################################################
1633 #     Subroutine to run one "system" command     #
1634 ##################################################
1635
1636 # We put this in a subroutine so that the command can be reflected when
1637 # debugging.
1638 #
1639 # Argument: the command to be run
1640 # Returns:  nothing
1641
1642 sub run_system {
1643 my($cmd) = $_[0];
1644 if ($debug)
1645   {
1646   my($prcmd) = $cmd;
1647   $prcmd =~ s/; /;\n>> /;
1648   print ">> $prcmd\n";
1649   }
1650 system("$cmd");
1651 }
1652
1653
1654
1655 ##################################################
1656 #      Subroutine to run one script command      #
1657 ##################################################
1658
1659 # The <SCRIPT> file is open for us to read an optional return code line,
1660 # followed by the command line and any following data lines for stdin. The
1661 # command line can be continued by the use of \. Data lines are not continued
1662 # in this way. In all lines, the following substutions are made:
1663 #
1664 # DIR    => the current directory
1665 # CALLER => the caller of this script
1666 #
1667 # Arguments: the current test number
1668 #            reference to the subtest number, holding previous value
1669 #            reference to the expected return code value
1670 #            reference to where to put the command name (for messages)
1671 #            auxilliary information returned from a previous run
1672 #
1673 # Returns:   0 the commmand was executed inline, no subprocess was run
1674 #            1 a non-exim command was run and waited for
1675 #            2 an exim command was run and waited for
1676 #            3 a command was run and not waited for (daemon, server, exim_lock)
1677 #            4 EOF was encountered after an initial return code line
1678 # Optionally alse a second parameter, a hash-ref, with auxilliary information:
1679 #            exim_pid: pid of a run process
1680 #            munge: name of a post-script results munger
1681
1682 sub run_command{
1683 my($testno) = $_[0];
1684 my($subtestref) = $_[1];
1685 my($commandnameref) = $_[3];
1686 my($aux_info) = $_[4];
1687 my($yield) = 1;
1688
1689 if (/^(\d+)\s*$/)                # Handle unusual return code
1690   {
1691   my($r) = $_[2];
1692   $$r = $1 << 8;
1693   $_ = <SCRIPT>;
1694   return 4 if !defined $_;       # Missing command
1695   $lineno++;
1696   }
1697
1698 chomp;
1699 $wait_time = 0;
1700
1701 # Handle concatenated command lines
1702
1703 s/\s+$//;
1704 while (substr($_, -1) eq"\\")
1705   {
1706   my($temp);
1707   $_ = substr($_, 0, -1);
1708   chomp($temp = <SCRIPT>);
1709   if (defined $temp)
1710     {
1711     $lineno++;
1712     $temp =~ s/\s+$//;
1713     $temp =~ s/^\s+//;
1714     $_ .= $temp;
1715     }
1716   }
1717
1718 # Do substitutions
1719
1720 do_substitute($testno);
1721 if ($debug) { printf ">> $_\n"; }
1722
1723 # Pass back the command name (for messages)
1724
1725 ($$commandnameref) = /^(\S+)/;
1726
1727 # Here follows code for handling the various different commands that are
1728 # supported by this script. The first group of commands are all freestanding
1729 # in that they share no common code and are not followed by any data lines.
1730
1731
1732 ###################
1733 ###################
1734
1735 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1736 # utility and to make DBM files for testing DBM lookups.
1737
1738 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1739   {
1740   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1741          "echo exim_dbmbuild exit code = \$?)" .
1742          ">>test-stdout");
1743   return 1;
1744   }
1745
1746
1747 # The "dump" command runs exim_dumpdb. On different systems, the output for
1748 # some types of dump may appear in a different order because it's just hauled
1749 # out of the DBM file. We can solve this by sorting. Ignore the leading
1750 # date/time, as it will be flattened later during munging.
1751
1752 if (/^dump\s+(\S+)/)
1753   {
1754   my($which) = $1;
1755   my(@temp);
1756   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1757   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1758   open(OUT, ">>test-stdout");
1759   print OUT "+++++++++++++++++++++++++++\n";
1760
1761   if ($which eq "retry")
1762     {
1763     $/ = "\n  ";
1764     @temp = <IN>;
1765     $/ = "\n";
1766
1767     @temp = sort {
1768                    my($aa) = split(' ', $a);
1769                    my($bb) = split(' ', $b);
1770                    return $aa cmp $bb;
1771                  } @temp;
1772
1773     foreach $item (@temp)
1774       {
1775       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1776       print OUT "  $item\n";
1777       }
1778     }
1779   else
1780     {
1781     @temp = <IN>;
1782     if ($which eq "callout")
1783       {
1784       @temp = sort {
1785                    my($aa) = substr $a, 21;
1786                    my($bb) = substr $b, 21;
1787                    return $aa cmp $bb;
1788                    } @temp;
1789       }
1790     print OUT @temp;
1791     }
1792
1793   close(IN);
1794   close(OUT);
1795   return 1;
1796   }
1797
1798
1799 # The "echo" command is a way of writing comments to the screen.
1800
1801 if (/^echo\s+(.*)$/)
1802   {
1803   print "$1\n";
1804   return 0;
1805   }
1806
1807
1808 # The "exim_lock" command runs exim_lock in the same manner as "server",
1809 # but it doesn't use any input.
1810
1811 if (/^exim_lock\s+(.*)$/)
1812   {
1813   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1814   $server_pid = open SERVERCMD, "|$cmd" ||
1815     tests_exit(-1, "Failed to run $cmd\n");
1816
1817   # This gives the process time to get started; otherwise the next
1818   # process may not find it there when it expects it.
1819
1820   select(undef, undef, undef, 0.1);
1821   return 3;
1822   }
1823
1824
1825 # The "exinext" command runs exinext
1826
1827 if (/^exinext\s+(.*)/)
1828   {
1829   run_system("(./eximdir/exinext " .
1830     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1831     "-C $parm_cwd/test-config $1;" .
1832     "echo exinext exit code = \$?)" .
1833     ">>test-stdout");
1834   return 1;
1835   }
1836
1837
1838 # The "exigrep" command runs exigrep on the current mainlog
1839
1840 if (/^exigrep\s+(.*)/)
1841   {
1842   run_system("(./eximdir/exigrep " .
1843     "$1 $parm_cwd/spool/log/mainlog;" .
1844     "echo exigrep exit code = \$?)" .
1845     ">>test-stdout");
1846   return 1;
1847   }
1848
1849
1850 # The "eximstats" command runs eximstats on the current mainlog
1851
1852 if (/^eximstats\s+(.*)/)
1853   {
1854   run_system("(./eximdir/eximstats " .
1855     "$1 $parm_cwd/spool/log/mainlog;" .
1856     "echo eximstats exit code = \$?)" .
1857     ">>test-stdout");
1858   return 1;
1859   }
1860
1861
1862 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
1863 # spool directory, to save Exim from re-creating it each time.
1864
1865 if (/^gnutls/)
1866   {
1867   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
1868   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
1869          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
1870          "sudo chmod 0400 $gen_fn";
1871   return 1;
1872   }
1873
1874
1875 # The "killdaemon" command should ultimately follow the starting of any Exim
1876 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
1877 # it outputting "Terminated" to the terminal when not in the background.
1878
1879 if (/^killdaemon/)
1880   {
1881   my $return_extra = {};
1882   if (exists $aux_info->{exim_pid})
1883     {
1884     $pid = $aux_info->{exim_pid};
1885     $return_extra->{exim_pid} = undef;
1886     print ">> killdaemon: recovered pid $pid\n" if $debug;
1887     if ($pid)
1888       {
1889       run_system("sudo /bin/kill -INT $pid");
1890       wait;
1891       }
1892     } else {
1893     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
1894     if ($pid)
1895       {
1896       run_system("sudo /bin/kill -INT $pid");
1897       close DAEMONCMD;                                   # Waits for process
1898       }
1899     }
1900     run_system("sudo /bin/rm -f spool/exim-daemon.*");
1901   return (1, $return_extra);
1902   }
1903
1904
1905 # The "millisleep" command is like "sleep" except that its argument is in
1906 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
1907 # is used for.
1908
1909 elsif (/^millisleep\s+(.*)$/)
1910   {
1911   select(undef, undef, undef, $1/1000);
1912   return 0;
1913   }
1914
1915
1916 # The "munge" command selects one of a hardwired set of test-result modifications
1917 # to be made before result compares are run agains the golden set.  This lets
1918 # us account for test-system dependent things which only affect a few, but known,
1919 # test-cases.
1920 # Currently only the last munge takes effect.
1921
1922 if (/^munge\s+(.*)$/)
1923   {
1924   return (0, { munge => $1 });
1925   }
1926
1927
1928 # The "sleep" command does just that. For sleeps longer than 1 second we
1929 # tell the user what's going on.
1930
1931 if (/^sleep\s+(.*)$/)
1932   {
1933   if ($1 == 1)
1934     {
1935     sleep(1);
1936     }
1937   else
1938     {
1939     printf("  Test %d sleep $1 ", $$subtestref);
1940     for (1..$1)
1941       {
1942       print ".";
1943       sleep(1);
1944       }
1945     printf("\r  Test %d                            $cr", $$subtestref);
1946     }
1947   return 0;
1948   }
1949
1950
1951 # Various Unix management commands are recognized
1952
1953 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
1954     /^sudo (rmdir|rm|chown|chmod)\s/)
1955   {
1956   run_system("$_ >>test-stdout 2>>test-stderr");
1957   return 1;
1958   }
1959
1960
1961
1962 ###################
1963 ###################
1964
1965 # The next group of commands are also freestanding, but they are all followed
1966 # by data lines.
1967
1968
1969 # The "server" command starts up a script-driven server that runs in parallel
1970 # with the following exim command. Therefore, we want to run a subprocess and
1971 # not yet wait for it to complete. The waiting happens after the next exim
1972 # command, triggered by $server_pid being non-zero. The server sends its output
1973 # to a different file. The variable $server_opts, if not empty, contains
1974 # options to disable IPv4 or IPv6 if necessary.
1975
1976 if (/^server\s+(.*)$/)
1977   {
1978   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
1979   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
1980   print ">> $cmd\n" if ($debug);
1981   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
1982   SERVERCMD->autoflush(1);
1983   print ">> Server pid is $server_pid\n" if $debug;
1984   while (<SCRIPT>)
1985     {
1986     $lineno++;
1987     last if /^\*{4}\s*$/;
1988     print SERVERCMD;
1989     }
1990   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
1991                             # because close() waits for the process.
1992
1993   # Interlock the server startup; otherwise the next
1994   # process may not find it there when it expects it.
1995   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
1996   return 3;
1997   }
1998
1999
2000 # The "write" command is a way of creating files of specific sizes for
2001 # buffering tests, or containing specific data lines from within the script
2002 # (rather than hold lots of little files). The "catwrite" command does the
2003 # same, but it also copies the lines to test-stdout.
2004
2005 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2006   {
2007   my($cat) = defined $1;
2008   @sizes = ();
2009   @sizes = split /\s+/, $3 if defined $3;
2010   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2011
2012   if ($cat)
2013     {
2014     open CAT, ">>test-stdout" ||
2015       tests_exit(-1, "Failed to open test-stdout: $!");
2016     print CAT "==========\n";
2017     }
2018
2019   if (scalar @sizes > 0)
2020     {
2021     # Pre-data
2022
2023     while (<SCRIPT>)
2024       {
2025       $lineno++;
2026       last if /^\+{4}\s*$/;
2027       print FILE;
2028       print CAT if $cat;
2029       }
2030
2031     # Sized data
2032
2033     while (scalar @sizes > 0)
2034       {
2035       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2036       $leadin = "" if !defined $leadin;
2037       $leadin =~ s/_/ /g;
2038       $len -= length($leadin) + 1;
2039       while ($count-- > 0)
2040         {
2041         print FILE $leadin, "a" x $len, "\n";
2042         print CAT $leadin, "a" x $len, "\n" if $cat;
2043         }
2044       }
2045     }
2046
2047   # Post data, or only data if no sized data
2048
2049   while (<SCRIPT>)
2050     {
2051     $lineno++;
2052     last if /^\*{4}\s*$/;
2053     print FILE;
2054     print CAT if $cat;
2055     }
2056   close FILE;
2057
2058   if ($cat)
2059     {
2060     print CAT "==========\n";
2061     close CAT;
2062     }
2063
2064   return 0;
2065   }
2066
2067
2068 ###################
2069 ###################
2070
2071 # From this point on, script commands are implemented by setting up a shell
2072 # command in the variable $cmd. Shared code to run this command and handle its
2073 # input and output follows.
2074
2075 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2076 # program that plays the part of an email client. We also have the availability
2077 # of running Perl for doing one-off special things. Note that all these
2078 # commands expect stdin data to be supplied.
2079
2080 if (/^client/ || /^(sudo\s+)?perl\b/)
2081   {
2082   s"client"./bin/client";
2083   $cmd = "$_ >>test-stdout 2>>test-stderr";
2084   }
2085
2086 # For the "exim" command, replace the text "exim" with the path for the test
2087 # binary, plus -D options to pass over various parameters, and a -C option for
2088 # the testing configuration file. When running in the test harness, Exim does
2089 # not drop privilege when -C and -D options are present. To run the exim
2090 # command as root, we use sudo.
2091
2092 elsif (/^([A-Z_]+=\S+\s+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2093   {
2094   $args = $6;
2095   my($envset) = (defined $1)? $1      : "";
2096   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":"")  : "";
2097   my($special)= (defined $5)? $5      : "";
2098   $wait_time  = (defined $2)? $2      : 0;
2099
2100   # Return 2 rather than 1 afterwards
2101
2102   $yield = 2;
2103
2104   # Update the test number
2105
2106   $$subtestref = $$subtestref + 1;
2107   printf("  Test %d       $cr", $$subtestref);
2108
2109   # Copy the configuration file, making the usual substitutions.
2110
2111   open (IN, "$parm_cwd/confs/$testno") ||
2112     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2113   open (OUT, ">test-config") ||
2114     tests_exit(-1, "Couldn't open test-config: $!\n");
2115   while (<IN>)
2116     {
2117     do_substitute($testno);
2118     print OUT;
2119     }
2120   close(IN);
2121   close(OUT);
2122
2123   # The string $msg1 in args substitutes the message id of the first
2124   # message on the queue, and so on. */
2125
2126   if ($args =~ /\$msg/)
2127     {
2128     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
2129                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2130                    "-C $parm_cwd/test-config |";
2131     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
2132     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
2133     my(@msglist) = ();
2134     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
2135     close(QLIST);
2136
2137     # Done backwards just in case there are more than 9
2138
2139     my($i);
2140     for ($i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2141     if ( $args =~ /\$msg\d/ )
2142       {
2143       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2144         unless $force_continue;
2145       }
2146     }
2147
2148   # If -d is specified in $optargs, remove it from $args; i.e. let
2149   # the command line for runtest override. Then run Exim.
2150
2151   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2152
2153   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : "";
2154
2155   $cmd = "$envset$sudo$opt_valgrind" .
2156          "$parm_cwd/eximdir/exim$special$optargs " .
2157          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2158          "-C $parm_cwd/test-config $args " .
2159          ">>test-stdout 2>>test-stderr";
2160   # If the command is starting an Exim daemon, we run it in the same
2161   # way as the "server" command above, that is, we don't want to wait
2162   # for the process to finish. That happens when "killdaemon" is obeyed later
2163   # in the script. We also send the stderr output to test-stderr-server. The
2164   # daemon has its log files put in a different place too (by configuring with
2165   # log_file_path). This requires the  directory to be set up in advance.
2166   #
2167   # There are also times when we want to run a non-daemon version of Exim
2168   # (e.g. a queue runner) with the server configuration. In this case,
2169   # we also define -DNOTDAEMON.
2170
2171   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2172     {
2173     $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2174     if ($debug) { printf ">> daemon: $cmd\n"; }
2175     run_system("sudo mkdir spool/log 2>/dev/null");
2176     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2177
2178     # Before running the command, convert the -bd option into -bdf so that an
2179     # Exim daemon doesn't double fork. This means that when we wait close
2180     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2181     # file is written to the spool directory, in case the Exim binary was
2182     # built with PID_FILE_PATH pointing somewhere else.
2183
2184     if ($cmd =~ /\s-oP\s/)
2185       {
2186       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2187       $cmd =~ s!\s-bd\s! -bdf !;
2188       }
2189     else
2190       {
2191       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2192       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2193       }
2194     print ">> |${cmd}-server\n" if ($debug);
2195     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2196     DAEMONCMD->autoflush(1);
2197     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2198
2199     # Interlock with daemon startup
2200     while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2201     return 3;                                     # Don't wait
2202     }
2203   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2204     {
2205     my $listen_port = $1;
2206     my $waitmode_sock = new FileHandle;
2207     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2208     run_system("sudo mkdir spool/log 2>/dev/null");
2209     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2210
2211     my ($s_ip,$s_port) = ('127.0.0.1', $listen_port);
2212     my $sin = sockaddr_in($s_port, inet_aton($s_ip))
2213         or die "** Failed packing $s_ip:$s_port\n";
2214     socket($waitmode_sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2215         or die "** Unable to open socket $s_ip:$s_port: $!\n";
2216     setsockopt($waitmode_sock, SOL_SOCKET, SO_REUSEADDR, 1)
2217         or die "** Unable to setsockopt(SO_REUSEADDR): $!\n";
2218     bind($waitmode_sock, $sin)
2219         or die "** Unable to bind socket ($s_port): $!\n";
2220     listen($waitmode_sock, 5);
2221     my $pid = fork();
2222     if (not defined $pid) { die "** fork failed: $!\n" }
2223     if (not $pid) {
2224       close(STDIN);
2225       open(STDIN, "<&", $waitmode_sock) or die "** dup sock to stdin failed: $!\n";
2226       close($waitmode_sock);
2227       print "[$$]>> ${cmd}-server\n" if ($debug);
2228       exec "exec ${cmd}-server";
2229       exit(1);
2230     }
2231     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2232     select(undef, undef, undef, 0.3);             # Let the daemon get going
2233     return (3, { exim_pid => $pid });             # Don't wait
2234     }
2235   }
2236
2237 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2238 # One script line is read and fork-exec'd.  The PID is stored for a later
2239 # killdaemon.
2240
2241 elsif (/^background$/)
2242   {
2243   my $line;
2244 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2245
2246   $_ = <SCRIPT>; $lineno++;
2247   chomp;
2248   $line = $_;
2249   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2250
2251   my $pid = fork();
2252   if (not defined $pid) { die "** fork failed: $!\n" }
2253   if (not $pid) {
2254     print "[$$]>> ${line}\n" if ($debug);
2255     close(STDIN);
2256     open(STDIN, "<", "test-stdout");
2257     close(STDOUT);
2258     open(STDOUT, ">>", "test-stdout");
2259     close(STDERR);
2260     open(STDERR, ">>", "test-stderr-server");
2261     exec "exec ${line}";
2262     exit(1);
2263   }
2264
2265 #  open(my $fh, ">", $pidfile) ||
2266 #      tests_exit(-1, "Failed to open $pidfile: $!");
2267 #  printf($fh, "%d\n", $pid);
2268 #  close($fh);
2269
2270   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2271   select(undef, undef, undef, 0.3);             # Let the daemon get going
2272   return (3, { exim_pid => $pid });             # Don't wait
2273   }
2274
2275
2276
2277 # Unknown command
2278
2279 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2280
2281
2282 # Run the command, with stdin connected to a pipe, and write the stdin data
2283 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2284 # the terminating newline (and the \NONL\). If the command contains
2285 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2286 # for the stderr file. See comment above about the use of -DSERVER.
2287
2288 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : "";
2289 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2290 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2291
2292 CMD->autoflush(1);
2293 while (<SCRIPT>)
2294   {
2295   $lineno++;
2296   last if /^\*{4}\s*$/;
2297   do_substitute($testno);
2298   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2299   }
2300
2301 # For timeout tests, wait before closing the pipe; we expect a
2302 # SIGPIPE error in this case.
2303
2304 if ($wait_time > 0)
2305   {
2306   printf("  Test %d sleep $wait_time ", $$subtestref);
2307   while ($wait_time-- > 0)
2308     {
2309     print ".";
2310     sleep(1);
2311     }
2312   printf("\r  Test %d                                       $cr", $$subtestref);
2313   }
2314
2315 $sigpipehappened = 0;
2316 close CMD;                # Waits for command to finish
2317 return $yield;            # Ran command and waited
2318 }
2319
2320
2321
2322
2323 ###############################################################################
2324 ###############################################################################
2325
2326 # Here beginneth the Main Program ...
2327
2328 ###############################################################################
2329 ###############################################################################
2330
2331
2332 autoflush STDOUT 1;
2333 print "Exim tester $testversion\n";
2334
2335 # extend the PATH with .../sbin
2336 # we map all (.../bin) to (.../sbin:.../bin)
2337 $ENV{PATH} = do {
2338   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2339   join ':' => map { m{(.*)/bin$}
2340                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2341                 : ($_) }
2342       split /:/, $ENV{PATH};
2343 };
2344
2345 ##################################################
2346 #      Some tests check created file modes       #
2347 ##################################################
2348
2349 umask 022;
2350
2351
2352 ##################################################
2353 #       Check for the "less" command             #
2354 ##################################################
2355
2356 $more = "more" if system("which less >/dev/null 2>&1") != 0;
2357
2358
2359
2360 ##################################################
2361 #        Check for sudo access to root           #
2362 ##################################################
2363
2364 print "You need to have sudo access to root to run these tests. Checking ...\n";
2365 if (system("sudo date >/dev/null") != 0)
2366   {
2367   die "** Test for sudo failed: testing abandoned.\n";
2368   }
2369 else
2370   {
2371   print "Test for sudo OK\n";
2372   }
2373
2374
2375
2376 ##################################################
2377 #      See if an Exim binary has been given      #
2378 ##################################################
2379
2380 # If the first character of the first argument is '/', the argument is taken
2381 # as the path to the binary. If the first argument does not start with a
2382 # '/' but exists in the file system, it's assumed to be the Exim binary.
2383
2384 $parm_exim = (@ARGV > 0 && (-x $ARGV[0] or $ARGV[0] =~ m?^/?))? Cwd::abs_path(shift @ARGV) : "";
2385 print "Exim binary is $parm_exim\n" if $parm_exim ne "";
2386
2387
2388
2389 ##################################################
2390 # Sort out options and which tests are to be run #
2391 ##################################################
2392
2393 # There are a few possible options for the test script itself; after these, any
2394 # options are passed on to Exim calls within the tests. Typically, this is used
2395 # to turn on Exim debugging while setting up a test.
2396
2397 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2398   {
2399   my($arg) = shift @ARGV;
2400   if ($optargs eq "")
2401     {
2402     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2403     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2404     if ($arg eq "-CONTINUE"){$force_continue = 1;
2405                              $more = "cat";
2406                              next; }
2407     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2408     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2409     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2410     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2411     if ($arg eq "-VALGRIND")   { $valgrind = 1; next; }
2412     if ($arg =~ /^-FLAVOU?R$/) { $flavour = shift; next; }
2413     }
2414   $optargs .= " $arg";
2415   }
2416
2417 # Any subsequent arguments are a range of test numbers.
2418
2419 if (@ARGV > 0)
2420   {
2421   $test_end = $test_start = $ARGV[0];
2422   $test_end = $ARGV[1] if (@ARGV > 1);
2423   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2424     if $test_end eq "+";
2425   die "** Test numbers out of order\n" if ($test_end < $test_start);
2426   }
2427
2428
2429 ##################################################
2430 #      Make the command's directory current      #
2431 ##################################################
2432
2433 # After doing so, we find its absolute path name.
2434
2435 $cwd = $0;
2436 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2437 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2438 $parm_cwd = Cwd::getcwd();
2439
2440
2441 ##################################################
2442 #     Search for an Exim binary to test          #
2443 ##################################################
2444
2445 # If an Exim binary hasn't been provided, try to find one. We can handle the
2446 # case where exim-testsuite is installed alongside Exim source directories. For
2447 # PH's private convenience, if there's a directory just called "exim4", that
2448 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2449 # releases.
2450
2451 if ($parm_exim eq "")
2452   {
2453   my($use_srcdir) = "";
2454
2455   opendir DIR, ".." || die "** Failed to opendir \"..\": $!\n";
2456   while ($f = readdir(DIR))
2457     {
2458     my($srcdir);
2459
2460     # Try this directory if it is "exim4" or if it is exim-snapshot or exim-n.m
2461     # possibly followed by -RCx where n.m is greater than any previously tried
2462     # directory. Thus, we should choose the highest version of Exim that has
2463     # been compiled.
2464
2465     if ($f eq "exim4" || $f eq "exim-snapshot" || $f eq 'src')
2466       { $srcdir = $f; }
2467     else
2468       { $srcdir = $f
2469         if ($f =~ /^exim-\d+\.\d+(-RC\d+)?$/ && $f gt $use_srcdir); }
2470
2471     # Look for a build directory with a binary in it. If we find a binary,
2472     # accept this source directory.
2473
2474     if ($srcdir)
2475       {
2476       opendir SRCDIR, "../$srcdir" ||
2477         die "** Failed to opendir \"$cwd/../$srcdir\": $!\n";
2478       while ($f = readdir(SRCDIR))
2479         {
2480         if ($f =~ /^build-/ && -e "../$srcdir/$f/exim")
2481           {
2482           $use_srcdir = $srcdir;
2483           $parm_exim = "$cwd/../$srcdir/$f/exim";
2484           $parm_exim =~ s'/[^/]+/\.\./'/';
2485           last;
2486           }
2487         }
2488       closedir(SRCDIR);
2489       }
2490
2491     # If we have found "exim4" or "exim-snapshot", that takes precedence.
2492     # Otherwise, continue to see if there's a later version.
2493
2494     last if $use_srcdir eq "exim4" || $use_srcdir eq "exim-snapshot";
2495     }
2496   closedir(DIR);
2497   print "Exim binary found in $parm_exim\n" if $parm_exim ne "";
2498   }
2499
2500 # If $parm_exim is still empty, ask the caller
2501
2502 if ($parm_exim eq "")
2503   {
2504   print "** Did not find an Exim binary to test\n";
2505   for ($i = 0; $i < 5; $i++)
2506     {
2507     my($trybin);
2508     print "** Enter pathname for Exim binary: ";
2509     chomp($trybin = <STDIN>);
2510     if (-e $trybin)
2511       {
2512       $parm_exim = $trybin;
2513       last;
2514       }
2515     else
2516       {
2517       print "** $trybin does not exist\n";
2518       }
2519     }
2520   die "** Too many tries\n" if $parm_exim eq "";
2521   }
2522
2523
2524
2525 ##################################################
2526 #          Find what is in the binary            #
2527 ##################################################
2528
2529 # deal with TRUSTED_CONFIG_LIST restrictions
2530 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2531 open (IN, "$parm_cwd/confs/0000") ||
2532   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2533 open (OUT, ">test-config") ||
2534   tests_exit(-1, "Couldn't open test-config: $!\n");
2535 while (<IN>) { print OUT; }
2536 close(IN);
2537 close(OUT);
2538
2539 print("Probing with config file: $parm_cwd/test-config\n");
2540 open(EXIMINFO, "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd " .
2541                "-bP exim_user exim_group 2>&1|") ||
2542   die "** Cannot run $parm_exim: $!\n";
2543 while(<EXIMINFO>)
2544   {
2545   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2546   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2547   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2548   print "$_" if /wrong owner/;
2549   }
2550 close(EXIMINFO);
2551
2552 if (defined $parm_eximuser)
2553   {
2554   if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2555     else { $parm_exim_uid = getpwnam($parm_eximuser); }
2556   }
2557 else
2558   {
2559   print "Unable to extract exim_user from binary.\n";
2560   print "Check if Exim refused to run; if so, consider:\n";
2561   print "  TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS\n";
2562   die "Failing to get information from binary.\n";
2563   }
2564
2565 if (defined $parm_eximgroup)
2566   {
2567   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2568     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2569   }
2570
2571 # check the permissions on the TRUSTED_CONFIG_LIST
2572 if (defined $parm_trusted_config_list)
2573   {
2574   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2575     if not -f $parm_trusted_config_list;
2576
2577   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2578     if 02 & (stat _)[2];
2579
2580   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2581   (stat _)[1],
2582     scalar(getgrgid 0), scalar(getgrgid $>)
2583     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2584
2585   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2586   scalar(getpwuid 0), scalar(getpwuid $>)
2587      if (not (-o _ or (stat _)[4] == 0));
2588
2589   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2590   my $test_config = getcwd() . '/test-config';
2591   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2592   if not grep { /^$test_config$/ } <TCL>;
2593   }
2594 else
2595   {
2596   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2597   }
2598
2599 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2600   die "** Cannot run $parm_exim: $!\n";
2601
2602 print "-" x 78, "\n";
2603
2604 while (<EXIMINFO>)
2605   {
2606   my(@temp);
2607
2608   if (/^(Exim|Library) version/) { print; }
2609
2610   elsif (/^Size of off_t: (\d+)/)
2611     {
2612     print;
2613     $have_largefiles = 1 if $1 > 4;
2614     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2615         if ($1 > 32);
2616     }
2617
2618   elsif (/^Support for: (.*)/)
2619     {
2620     print;
2621     @temp = split /(\s+)/, $1;
2622     push(@temp, ' ');
2623     %parm_support = @temp;
2624     }
2625
2626   elsif (/^Lookups \(built-in\): (.*)/)
2627     {
2628     print;
2629     @temp = split /(\s+)/, $1;
2630     push(@temp, ' ');
2631     %parm_lookups = @temp;
2632     }
2633
2634   elsif (/^Authenticators: (.*)/)
2635     {
2636     print;
2637     @temp = split /(\s+)/, $1;
2638     push(@temp, ' ');
2639     %parm_authenticators = @temp;
2640     }
2641
2642   elsif (/^Routers: (.*)/)
2643     {
2644     print;
2645     @temp = split /(\s+)/, $1;
2646     push(@temp, ' ');
2647     %parm_routers = @temp;
2648     }
2649
2650   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2651   # that the basic transport name is set, and then the name with each of the
2652   # options.
2653
2654   elsif (/^Transports: (.*)/)
2655     {
2656     print;
2657     @temp = split /(\s+)/, $1;
2658     my($i,$k);
2659     push(@temp, ' ');
2660     %parm_transports = @temp;
2661     foreach $k (keys %parm_transports)
2662       {
2663       if ($k =~ "/")
2664         {
2665         @temp = split /\//, $k;
2666         $parm_transports{"$temp[0]"} = " ";
2667         for ($i = 1; $i < @temp; $i++)
2668           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2669         }
2670       }
2671     }
2672   }
2673 close(EXIMINFO);
2674 print "-" x 78, "\n";
2675
2676 unlink("$parm_cwd/test-config");
2677
2678 ##################################################
2679 #    Check for SpamAssassin and ClamAV           #
2680 ##################################################
2681
2682 # These are crude tests. If they aren't good enough, we'll have to improve
2683 # them, for example by actually passing a message through spamc or clamscan.
2684
2685 if (defined $parm_support{'Content_Scanning'})
2686   {
2687   my $sock = new FileHandle;
2688
2689   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2690     {
2691     print "The spamc command works:\n";
2692
2693     # This test for an active SpamAssassin is courtesy of John Jetmore.
2694     # The tests are hard coded to localhost:783, so no point in making
2695     # this test flexible like the clamav test until the test scripts are
2696     # changed.  spamd doesn't have the nice PING/PONG protoccol that
2697     # clamd does, but it does respond to errors in an informative manner,
2698     # so use that.
2699
2700     my($sint,$sport) = ('127.0.0.1',783);
2701     eval
2702       {
2703       my $sin = sockaddr_in($sport, inet_aton($sint))
2704           or die "** Failed packing $sint:$sport\n";
2705       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2706           or die "** Unable to open socket $sint:$sport\n";
2707
2708       local $SIG{ALRM} =
2709           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2710       alarm(5);
2711       connect($sock, $sin)
2712           or die "** Unable to connect to socket $sint:$sport\n";
2713       alarm(0);
2714
2715       select((select($sock), $| = 1)[0]);
2716       print $sock "bad command\r\n";
2717
2718       $SIG{ALRM} =
2719           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2720       alarm(10);
2721       my $res = <$sock>;
2722       alarm(0);
2723
2724       $res =~ m|^SPAMD/|
2725           or die "** Did not get SPAMD from socket $sint:$sport. "
2726                 ."It said: $res\n";
2727       };
2728     alarm(0);
2729     if($@)
2730       {
2731       print "  $@";
2732       print "  Assume SpamAssassin (spamd) is not running\n";
2733       }
2734     else
2735       {
2736       $parm_running{'SpamAssassin'} = ' ';
2737       print "  SpamAssassin (spamd) seems to be running\n";
2738       }
2739     }
2740   else
2741     {
2742     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2743     }
2744
2745   # For ClamAV, we need to find the clamd socket for use in the Exim
2746   # configuration. Search for the clamd configuration file.
2747
2748   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2749     {
2750     my($f, $clamconf, $test_prefix);
2751
2752     print "The clamscan command works";
2753
2754     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2755     $test_prefix = "" if !defined $test_prefix;
2756
2757     foreach $f ("$test_prefix/etc/clamd.conf",
2758                 "$test_prefix/usr/local/etc/clamd.conf",
2759                 "$test_prefix/etc/clamav/clamd.conf", "")
2760       {
2761       if (-e $f)
2762         {
2763         $clamconf = $f;
2764         last;
2765         }
2766       }
2767
2768     # Read the ClamAV configuration file and find the socket interface.
2769
2770     if ($clamconf ne "")
2771       {
2772       my $socket_domain;
2773       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2774       while (<IN>)
2775         {
2776         if (/^LocalSocket\s+(.*)/)
2777           {
2778           $parm_clamsocket = $1;
2779           $socket_domain = AF_UNIX;
2780           last;
2781           }
2782         if (/^TCPSocket\s+(\d+)/)
2783           {
2784           if (defined $parm_clamsocket)
2785             {
2786             $parm_clamsocket .= " $1";
2787             $socket_domain = AF_INET;
2788             last;
2789             }
2790           else
2791             {
2792             $parm_clamsocket = " $1";
2793             }
2794           }
2795         elsif (/^TCPAddr\s+(\S+)/)
2796           {
2797           if (defined $parm_clamsocket)
2798             {
2799             $parm_clamsocket = $1 . $parm_clamsocket;
2800             $socket_domain = AF_INET;
2801             last;
2802             }
2803           else
2804             {
2805             $parm_clamsocket = $1;
2806             }
2807           }
2808         }
2809       close(IN);
2810
2811       if (defined $socket_domain)
2812         {
2813         print ":\n  The clamd socket is $parm_clamsocket\n";
2814         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2815         eval
2816           {
2817           my $socket;
2818           if ($socket_domain == AF_UNIX)
2819             {
2820             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2821             }
2822           elsif ($socket_domain == AF_INET)
2823             {
2824             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2825             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2826             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2827             }
2828           else
2829             {
2830             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2831             }
2832           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2833           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2834           alarm(5);
2835           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2836           alarm(0);
2837
2838           my $ofh = select $sock; $| = 1; select $ofh;
2839           print $sock "PING\n";
2840
2841           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2842           alarm(10);
2843           my $res = <$sock>;
2844           alarm(0);
2845
2846           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2847           };
2848         alarm(0);
2849
2850         if($@)
2851           {
2852           print "  $@";
2853           print "  Assume ClamAV is not running\n";
2854           }
2855         else
2856           {
2857           $parm_running{'ClamAV'} = ' ';
2858           print "  ClamAV seems to be running\n";
2859           }
2860         }
2861       else
2862         {
2863         print ", but the socket for clamd could not be determined\n";
2864         print "Assume ClamAV is not running\n";
2865         }
2866       }
2867
2868     else
2869       {
2870       print ", but I can't find a configuration for clamd\n";
2871       print "Assume ClamAV is not running\n";
2872       }
2873     }
2874   }
2875
2876
2877 ##################################################
2878 #       Check for redis                          #
2879 ##################################################
2880 if (defined $parm_lookups{'redis'})
2881   {
2882   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
2883     {
2884     print "The redis-server command works\n";
2885     $parm_running{'redis'} = ' ';
2886     }
2887   else
2888     {
2889     print "The redis-server command failed: assume Redis not installed\n";
2890     }
2891   }
2892
2893 ##################################################
2894 #         Test for the basic requirements        #
2895 ##################################################
2896
2897 # This test suite assumes that Exim has been built with at least the "usual"
2898 # set of routers, transports, and lookups. Ensure that this is so.
2899
2900 $missing = "";
2901
2902 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{'lsearch'});
2903
2904 $missing .= "     Router: accept\n" if (!defined $parm_routers{'accept'});
2905 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{'dnslookup'});
2906 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{'manualroute'});
2907 $missing .= "     Router: redirect\n" if (!defined $parm_routers{'redirect'});
2908
2909 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{'appendfile'});
2910 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{'autoreply'});
2911 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{'pipe'});
2912 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{'smtp'});
2913
2914 if ($missing ne "")
2915   {
2916   print "\n";
2917   print "** Many features can be included or excluded from Exim binaries.\n";
2918   print "** This test suite requires that Exim is built to contain a certain\n";
2919   print "** set of basic facilities. It seems that some of these are missing\n";
2920   print "** from the binary that is under test, so the test cannot proceed.\n";
2921   print "** The missing facilities are:\n";
2922   print "$missing";
2923   die "** Test script abandoned\n";
2924   }
2925
2926
2927 ##################################################
2928 #      Check for the auxiliary programs          #
2929 ##################################################
2930
2931 # These are always required:
2932
2933 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
2934            "fakens", "iefbr14", "server")
2935   {
2936   next if ($prog eq "client-ssl" && !defined $parm_support{'OpenSSL'});
2937   next if ($prog eq "client-gnutls" && !defined $parm_support{'GnuTLS'});
2938   if (!-e "bin/$prog")
2939     {
2940     print "\n";
2941     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
2942     die "** Test script abandoned\n";
2943     }
2944   }
2945
2946 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
2947 # compiled on systems where we don't know how to. However, if Exim does not
2948 # have that functionality compiled, we needn't bother.
2949
2950 $dlfunc_deleted = 0;
2951 if (defined $parm_support{'Expand_dlfunc'} && !-e "bin/loaded")
2952   {
2953   delete $parm_support{'Expand_dlfunc'};
2954   $dlfunc_deleted = 1;
2955   }
2956
2957
2958 ##################################################
2959 #          Find environmental details            #
2960 ##################################################
2961
2962 # Find the caller of this program.
2963
2964 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
2965  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
2966
2967 $pwpw = $pwpw;       # Kill Perl warnings
2968 $pwquota = $pwquota;
2969 $pwcomm = $pwcomm;
2970
2971 $parm_caller_group = getgrgid($parm_caller_gid);
2972
2973 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
2974 print "Home directory is $parm_caller_home\n";
2975
2976 unless (defined $parm_eximgroup)
2977   {
2978   print "Unable to derive \$parm_eximgroup.\n";
2979   die "** ABANDONING.\n";
2980   }
2981
2982 print "You need to be in the Exim group to run these tests. Checking ...";
2983
2984 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
2985   {
2986   print " OK\n";
2987   }
2988 else
2989   {
2990   print "\nOh dear, you are not in the Exim group.\n";
2991   die "** Testing abandoned.\n";
2992   }
2993
2994 # Find this host's IP addresses - there may be many, of course, but we keep
2995 # one of each type (IPv4 and IPv6).
2996
2997 $parm_ipv4 = "";
2998 $parm_ipv6 = "";
2999
3000 $local_ipv4 = "";
3001 $local_ipv6 = "";
3002
3003 open(IFCONFIG, "ifconfig -a|") || die "** Cannot run \"ifconfig\": $!\n";
3004 while (($parm_ipv4 eq "" || $parm_ipv6 eq "") && ($_ = <IFCONFIG>))
3005   {
3006   my($ip);
3007   if ($parm_ipv4 eq "" &&
3008       $_ =~ /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)\s/i)
3009     {
3010     $ip = $1;
3011     next if ($ip =~ /^127\./ || $ip =~ /^10\./);
3012     $parm_ipv4 = $ip;
3013     }
3014
3015   if ($parm_ipv6 eq "" &&
3016       $_ =~ /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)/i)
3017     {
3018     $ip = $1;
3019     next if ($ip eq "::1" || $ip =~ /^fe80/i);
3020     $parm_ipv6 = $ip;
3021     }
3022   }
3023 close(IFCONFIG);
3024
3025 # Use private IP addresses if there are no public ones.
3026
3027 $parm_ipv4 = $local_ipv4 if ($parm_ipv4 eq "");
3028 $parm_ipv6 = $local_ipv6 if ($parm_ipv6 eq "");
3029
3030 # If either type of IP address is missing, we need to set the value to
3031 # something other than empty, because that wrecks the substitutions. The value
3032 # is reflected, so use a meaningful string. Set appropriate options for the
3033 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3034 # available, so things will go wrong if there is no IPv4 address. The lack
3035 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3036 # and $have_ipv6 false.
3037
3038 if ($parm_ipv4 eq "")
3039   {
3040   $have_ipv4 = 0;
3041   $parm_ipv4 = "<no IPv4 address found>";
3042   $server_opts .= " -noipv4";
3043   }
3044 elsif ($have_ipv4 == 0)
3045   {
3046   $parm_ipv4 = "<IPv4 testing disabled>";
3047   $server_opts .= " -noipv4";
3048   }
3049 else
3050   {
3051   $parm_running{"IPv4"} = " ";
3052   }
3053
3054 if ($parm_ipv6 eq "")
3055   {
3056   $have_ipv6 = 0;
3057   $parm_ipv6 = "<no IPv6 address found>";
3058   $server_opts .= " -noipv6";
3059   delete($parm_support{"IPv6"});
3060   }
3061 elsif ($have_ipv6 == 0)
3062   {
3063   $parm_ipv6 = "<IPv6 testing disabled>";
3064   $server_opts .= " -noipv6";
3065   delete($parm_support{"IPv6"});
3066   }
3067 elsif (!defined $parm_support{'IPv6'})
3068   {
3069   $have_ipv6 = 0;
3070   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3071   $server_opts .= " -noipv6";
3072   }
3073 else
3074   {
3075   $parm_running{"IPv6"} = " ";
3076   }
3077
3078 print "IPv4 address is $parm_ipv4\n";
3079 print "IPv6 address is $parm_ipv6\n";
3080
3081 # For munging test output, we need the reversed IP addresses.
3082
3083 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? "" :
3084   join(".", reverse(split /\./, $parm_ipv4));
3085
3086 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3087 if ($parm_ipv6 =~ /^[\da-f]/)
3088   {
3089   my(@comps) = split /:/, $parm_ipv6;
3090   my(@nibbles);
3091   foreach $comp (@comps)
3092     {
3093     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3094     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3095     }
3096   $parm_ipv6r = join(".", reverse(@nibbles));
3097   }
3098
3099 # Find the host name, fully qualified.
3100
3101 chomp($temp = `hostname`);
3102 $parm_hostname = (gethostbyname($temp))[0];
3103 $parm_hostname = "no.host.name.found" if $parm_hostname eq "";
3104 print "Hostname is $parm_hostname\n";
3105
3106 if ($parm_hostname !~ /\./)
3107   {
3108   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3109   }
3110
3111 if ($parm_hostname =~ /[[:upper:]]/)
3112   {
3113   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3114   }
3115
3116
3117
3118 ##################################################
3119 #     Create a testing version of Exim           #
3120 ##################################################
3121
3122 # We want to be able to run Exim with a variety of configurations. Normally,
3123 # the use of -C to change configuration causes Exim to give up its root
3124 # privilege (unless the caller is exim or root). For these tests, we do not
3125 # want this to happen. Also, we want Exim to know that it is running in its
3126 # test harness.
3127
3128 # We achieve this by copying the binary and patching it as we go. The new
3129 # binary knows it is a testing copy, and it allows -C and -D without loss of
3130 # privilege. Clearly, this file is dangerous to have lying around on systems
3131 # where there are general users with login accounts. To protect against this,
3132 # we put the new binary in a special directory that is accessible only to the
3133 # caller of this script, who is known to have sudo root privilege from the test
3134 # that was done above. Furthermore, we ensure that the binary is deleted at the
3135 # end of the test. First ensure the directory exists.
3136
3137 if (-d "eximdir")
3138   { unlink "eximdir/exim"; }     # Just in case
3139 else
3140   {
3141   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3142   system("sudo chgrp $parm_eximgroup eximdir");
3143   }
3144
3145 # The construction of the patched binary must be done as root, so we use
3146 # a separate script. As well as indicating that this is a test-harness binary,
3147 # the version number is patched to "x.yz" so that its length is always the
3148 # same. Otherwise, when it appears in Received: headers, it affects the length
3149 # of the message, which breaks certain comparisons.
3150
3151 die "** Unable to make patched exim: $!\n"
3152   if (system("sudo ./patchexim $parm_exim") != 0);
3153
3154 # From this point on, exits from the program must go via the subroutine
3155 # tests_exit(), so that suitable cleaning up can be done when required.
3156 # Arrange to catch interrupting signals, to assist with this.
3157
3158 $SIG{'INT'} = \&inthandler;
3159 $SIG{'PIPE'} = \&pipehandler;
3160
3161 # For some tests, we need another copy of the binary that is setuid exim rather
3162 # than root.
3163
3164 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3165        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3166        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3167        "sudo chmod 06755 eximdir/exim_exim");
3168
3169
3170 ##################################################
3171 #     Make copies of utilities we might need     #
3172 ##################################################
3173
3174 # Certain of the tests make use of some of Exim's utilities. We do not need
3175 # to be root to copy these.
3176
3177 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3178
3179 $dbm_build_deleted = 0;
3180 if (defined $parm_lookups{'dbm'} &&
3181     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3182   {
3183   delete $parm_lookups{'dbm'};
3184   $dbm_build_deleted = 1;
3185   }
3186
3187 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3188   {
3189   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3190   }
3191
3192 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3193   {
3194   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3195   }
3196
3197 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3198   {
3199   tests_exit(-1, "Failed to make a copy of exinext: $!");
3200   }
3201
3202 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3203   {
3204   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3205   }
3206
3207 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3208   {
3209   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3210   }
3211
3212
3213 ##################################################
3214 #    Check that the Exim user can access stuff   #
3215 ##################################################
3216
3217 # We delay this test till here so that we can check access to the actual test
3218 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3219
3220 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3221 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3222
3223 if ($parm_caller_uid eq $parm_exim_uid) {
3224   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3225                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3226 }
3227 if ($parm_caller_gid eq $parm_exim_gid) {
3228   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3229                 ."the same as caller's ($parm_caller) group as it confuses "
3230                 ."results analysis");
3231 }
3232
3233 print "The Exim user needs access to the test suite directory. Checking ...";
3234
3235 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3236   {
3237   my($why) = "unknown failure $rc";
3238   $rc >>= 8;
3239   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3240   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3241   $why = "Couldn't read auxiliary group list" if $rc == 3;
3242   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3243   $why = "Couldn't set gid" if $rc == 5;
3244   $why = "Couldn't set uid" if $rc == 6;
3245   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3246   print "\n** $why\n";
3247   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3248   }
3249 else
3250   {
3251   print " OK\n";
3252   }
3253
3254
3255 ##################################################
3256 #        Create a list of available tests        #
3257 ##################################################
3258
3259 # The scripts directory contains a number of subdirectories whose names are
3260 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3261 # from the first requires certain optional features to be included in the Exim
3262 # binary. These requirements are contained in a file called "REQUIRES" within
3263 # the directory. We scan all these tests, discarding those that cannot be run
3264 # because the current binary does not support the right facilities, and also
3265 # those that are outside the numerical range selected.
3266
3267 print "\nTest range is $test_start to $test_end (flavour $flavour)\n";
3268 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3269   if $dlfunc_deleted;
3270 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3271   if $dbm_build_deleted;
3272
3273 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
3274 @test_dirs = sort readdir(DIR);
3275 closedir(DIR);
3276
3277 # Remove . and .. and CVS from the list.
3278
3279 for ($i = 0; $i < @test_dirs; $i++)
3280   {
3281   my($d) = $test_dirs[$i];
3282   if ($d eq "." || $d eq ".." || $d eq "CVS")
3283     {
3284     splice @test_dirs, $i, 1;
3285     $i--;
3286     }
3287   }
3288
3289 # Scan for relevant tests
3290
3291 for ($i = 0; $i < @test_dirs; $i++)
3292   {
3293   my($testdir) = $test_dirs[$i];
3294   my($wantthis) = 1;
3295
3296   print ">>Checking $testdir\n" if $debug;
3297
3298   # Skip this directory if the first test is equal or greater than the first
3299   # test in the next directory.
3300
3301   next if ($i < @test_dirs - 1) &&
3302           ($test_start >= substr($test_dirs[$i+1], 0, 4));
3303
3304   # No need to carry on if the end test is less than the first test in this
3305   # subdirectory.
3306
3307   last if $test_end < substr($testdir, 0, 4);
3308
3309   # Check requirements, if any.
3310
3311   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
3312     {
3313     while (<REQUIRES>)
3314       {
3315       next if /^\s*$/;
3316       s/\s+$//;
3317       if (/^support (.*)$/)
3318         {
3319         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3320         }
3321       elsif (/^running (.*)$/)
3322         {
3323         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3324         }
3325       elsif (/^lookup (.*)$/)
3326         {
3327         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3328         }
3329       elsif (/^authenticators? (.*)$/)
3330         {
3331         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3332         }
3333       elsif (/^router (.*)$/)
3334         {
3335         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3336         }
3337       elsif (/^transport (.*)$/)
3338         {
3339         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3340         }
3341       else
3342         {
3343         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3344         }
3345       }
3346     close(REQUIRES);
3347     }
3348   else
3349     {
3350     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3351       unless $!{ENOENT};
3352     }
3353
3354   # Loop if we do not want the tests in this subdirectory.
3355
3356   if (!$wantthis)
3357     {
3358     chomp;
3359     print "Omitting tests in $testdir (missing $_)\n";
3360     next;
3361     }
3362
3363   # We want the tests from this subdirectory, provided they are in the
3364   # range that was selected.
3365
3366   opendir(SUBDIR, "scripts/$testdir") ||
3367     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3368   @testlist = sort readdir(SUBDIR);
3369   close(SUBDIR);
3370
3371   foreach $test (@testlist)
3372     {
3373     next if $test !~ /^\d{4}(?:\.\d+)?$/;
3374     next if $test < $test_start || $test > $test_end;
3375     push @test_list, "$testdir/$test";
3376     }
3377   }
3378
3379 print ">>Test List: @test_list\n", if $debug;
3380
3381
3382 ##################################################
3383 #         Munge variable auxiliary data          #
3384 ##################################################
3385
3386 # Some of the auxiliary data files have to refer to the current testing
3387 # directory and other parameter data. The generic versions of these files are
3388 # stored in the aux-var-src directory. At this point, we copy each of them
3389 # to the aux-var directory, making appropriate substitutions. There aren't very
3390 # many of them, so it's easiest just to do this every time. Ensure the mode
3391 # is standardized, as this path is used as a test for the ${stat: expansion.
3392
3393 # A similar job has to be done for the files in the dnszones-src directory, to
3394 # make the fake DNS zones for testing. Most of the zone files are copied to
3395 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3396 # networks that are defined by parameter.
3397
3398 foreach $basedir ("aux-var", "dnszones")
3399   {
3400   system("sudo rm -rf $parm_cwd/$basedir");
3401   mkdir("$parm_cwd/$basedir", 0777);
3402   chmod(0755, "$parm_cwd/$basedir");
3403
3404   opendir(AUX, "$parm_cwd/$basedir-src") ||
3405     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3406   my(@filelist) = readdir(AUX);
3407   close(AUX);
3408
3409   foreach $file (@filelist)
3410     {
3411     my($outfile) = $file;
3412     next if $file =~ /^\./;
3413
3414     if ($file eq "db.ip4.V4NET")
3415       {
3416       $outfile = "db.ip4.$parm_ipv4_test_net";
3417       }
3418     elsif ($file eq "db.ip6.V6NET")
3419       {
3420       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3421       $" = '.';
3422       $outfile = "db.ip6.@nibbles";
3423       $" = ' ';
3424       }
3425
3426     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3427     open(IN, "$parm_cwd/$basedir-src/$file") ||
3428       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3429     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3430       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3431     while (<IN>)
3432       {
3433       do_substitute(0);
3434       print OUT;
3435       }
3436     close(IN);
3437     close(OUT);
3438     }
3439   }
3440
3441 # Set a user's shell, distinguishable from /bin/sh
3442
3443 symlink("/bin/sh","aux-var/sh");
3444 $ENV{'SHELL'} = $parm_shell = $parm_cwd . "/aux-var/sh";
3445
3446 ##################################################
3447 #     Create fake DNS zones for this host        #
3448 ##################################################
3449
3450 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3451 # sure that there are forward and reverse registrations for this host, using
3452 # its real IP addresses. Dynamically created zone files achieve this.
3453
3454 if ($have_ipv4 || $have_ipv6)
3455   {
3456   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3457   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3458     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3459   print OUT "; This is a dynamically constructed fake zone file.\n" .
3460     "; The following line causes fakens to return PASS_ON\n" .
3461     "; for queries that it cannot answer\n\n" .
3462     "PASS ON NOT FOUND\n\n";
3463   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3464   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3465   print OUT "\n; End\n";
3466   close(OUT);
3467   }
3468
3469 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3470   {
3471   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3472   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3473     tests_exit(-1,
3474       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3475   print OUT "; This is a dynamically constructed fake zone file.\n" .
3476     "; The zone is $components[0].in-addr.arpa.\n\n" .
3477     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3478     "; End\n";
3479   close(OUT);
3480   }
3481
3482 if ($have_ipv6 && $parm_ipv6 ne "::1")
3483   {
3484   my($exp_v6) = $parm_ipv6;
3485   $exp_v6 =~ s/[^:]//g;
3486   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3487     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3488   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3489     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3490   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3491     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3492   } else {
3493     $exp_v6 = $parm_ipv6;
3494   }
3495   my(@components) = split /:/, $exp_v6;
3496   my(@nibbles) = reverse (split /\s*/, shift @components);
3497   my($sep) =  "";
3498
3499   $" = ".";
3500   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3501     tests_exit(-1,
3502       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3503   print OUT "; This is a dynamically constructed fake zone file.\n" .
3504     "; The zone is @nibbles.ip6.arpa.\n\n";
3505
3506   @components = reverse @components;
3507   foreach $c (@components)
3508     {
3509     $c = "0$c" until $c =~ /^..../;
3510     @nibbles = reverse(split /\s*/, $c);
3511     print OUT "$sep@nibbles";
3512     $sep = ".";
3513     }
3514
3515   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3516   close(OUT);
3517   $" = " ";
3518   }
3519
3520
3521
3522 ##################################################
3523 #    Create lists of mailboxes and message logs  #
3524 ##################################################
3525
3526 # We use these lists to check that a test has created the expected files. It
3527 # should be faster than looking for the file each time. For mailboxes, we have
3528 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3529 # is just a flat list of files.
3530
3531 @oldmails = list_files_below("mail");
3532 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3533 @oldmsglogs = readdir(DIR);
3534 closedir(DIR);
3535
3536
3537
3538 ##################################################
3539 #         Run the required tests                 #
3540 ##################################################
3541
3542 # Each test script contains a number of tests, separated by a line that
3543 # contains ****. We open input from the terminal so that we can read responses
3544 # to prompts.
3545
3546 open(T, "/dev/tty") || tests_exit(-1, "Failed to open /dev/tty: $!");
3547
3548 print "\nPress RETURN to run the tests: ";
3549 $_ = $force_continue ? "c" : <T>;
3550 print "\n";
3551
3552 $lasttestdir = "";
3553
3554 foreach $test (@test_list)
3555   {
3556   local($lineno) = 0;
3557   local($commandno) = 0;
3558   local($subtestno) = 0;
3559   (local $testno = $test) =~ s|.*/||;
3560   local($sortlog) = 0;
3561
3562   my($gnutls) = 0;
3563   my($docheck) = 1;
3564   my($thistestdir) = substr($test, 0, -5);
3565
3566   if ($lasttestdir ne $thistestdir)
3567     {
3568     $gnutls = 0;
3569     if (-s "scripts/$thistestdir/REQUIRES")
3570       {
3571       my($indent) = "";
3572       print "\n>>> The following tests require: ";
3573       open(IN, "scripts/$thistestdir/REQUIRES") ||
3574         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3575       while (<IN>)
3576         {
3577         $gnutls = 1 if /^support GnuTLS/;
3578         print $indent, $_;
3579         $indent = ">>>                              ";
3580         }
3581       close(IN);
3582       }
3583     }
3584   $lasttestdir = $thistestdir;
3585
3586   # Remove any debris in the spool directory and the test-mail directory
3587   # and also the files for collecting stdout and stderr. Then put back
3588   # the test-mail directory for appendfile deliveries.
3589
3590   system "sudo /bin/rm -rf spool test-*";
3591   system "mkdir test-mail 2>/dev/null";
3592
3593   # A privileged Exim will normally make its own spool directory, but some of
3594   # the tests run in unprivileged modes that don't always work if the spool
3595   # directory isn't already there. What is more, we want anybody to be able
3596   # to read it in order to find the daemon's pid.
3597
3598   system "mkdir spool; " .
3599          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3600          "sudo chmod 0755 spool";
3601
3602   # Empty the cache that keeps track of things like message id mappings, and
3603   # set up the initial sequence strings.
3604
3605   undef %cache;
3606   $next_msgid = "aX";
3607   $next_pid = 1234;
3608   $next_port = 1111;
3609   $message_skip = 0;
3610   $msglog_skip = 0;
3611   $stderr_skip = 0;
3612   $stdout_skip = 0;
3613   $rmfiltertest = 0;
3614   $is_ipv6test = 0;
3615   $TEST_STATE->{munge} = "";
3616
3617   # Remove the associative arrays used to hold checked mail files and msglogs
3618
3619   undef %expected_mails;
3620   undef %expected_msglogs;
3621
3622   # Open the test's script
3623   open(SCRIPT, "scripts/$test") ||
3624     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3625   # Run through the script once to set variables which should be global
3626   while (<SCRIPT>)
3627     {
3628     if (/^no_message_check/) { $message_skip = 1; next; }
3629     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3630     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3631     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3632     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3633     if (/^sortlog/)          { $sortlog = 1; next; }
3634     }
3635   # Reset to beginning of file for per test interpreting/processing
3636   seek(SCRIPT, 0, 0);
3637
3638   # The first line in the script must be a comment that is used to identify
3639   # the set of tests as a whole.
3640
3641   $_ = <SCRIPT>;
3642   $lineno++;
3643   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3644   printf("%s %s", (substr $test, 5), (substr $_, 2));
3645
3646   # Loop for each of the subtests within the script. The variable $server_pid
3647   # is used to remember the pid of a "server" process, for which we do not
3648   # wait until we have waited for a subsequent command.
3649
3650   local($server_pid) = 0;
3651   for ($commandno = 1; !eof SCRIPT; $commandno++)
3652     {
3653     # Skip further leading comments and blank lines, handle the flag setting
3654     # commands, and deal with tests for IP support.
3655
3656     while (<SCRIPT>)
3657       {
3658       $lineno++;
3659       # Could remove these variable settings because they are already
3660       # set above, but doesn't hurt to leave them here.
3661       if (/^no_message_check/) { $message_skip = 1; next; }
3662       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3663       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3664       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3665       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3666       if (/^sortlog/)          { $sortlog = 1; next; }
3667
3668       if (/^need_largefiles/)
3669         {
3670         next if $have_largefiles;
3671         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3672         $docheck = 0;      # don't check output
3673         undef $_;          # pretend EOF
3674         last;
3675         }
3676
3677       if (/^need_ipv4/)
3678         {
3679         next if $have_ipv4;
3680         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3681         $docheck = 0;      # don't check output
3682         undef $_;          # pretend EOF
3683         last;
3684         }
3685
3686       if (/^need_ipv6/)
3687         {
3688         if ($have_ipv6)
3689           {
3690           $is_ipv6test = 1;
3691           next;
3692           }
3693         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3694         $docheck = 0;      # don't check output
3695         undef $_;          # pretend EOF
3696         last;
3697         }
3698
3699       if (/^need_move_frozen_messages/)
3700         {
3701         next if defined $parm_support{"move_frozen_messages"};
3702         print ">>> move frozen message support is needed for test $testno, " .
3703           "but is not\n>>> available: skipping\n";
3704         $docheck = 0;      # don't check output
3705         undef $_;          # pretend EOF
3706         last;
3707         }
3708
3709       last unless /^(#|\s*$)/;
3710       }
3711     last if !defined $_;  # Hit EOF
3712
3713     my($subtest_startline) = $lineno;
3714
3715     # Now run the command. The function returns 0 if exim was run and waited
3716     # for, 1 if any other command was run and waited for, and 2 if a command
3717     # was run and not waited for (usually a daemon or server startup).
3718
3719     my($commandname) = "";
3720     my($expectrc) = 0;
3721     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3722     my($cmdrc) = $?;
3723
3724 $0 = "[runtest $testno]";
3725
3726     if ($debug) {
3727       print ">> rc=$rc cmdrc=$cmdrc\n";
3728       if (defined $run_extra) {
3729         foreach my $k (keys %$run_extra) {
3730           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3731           print ">>   $k -> $v\n";
3732         }
3733       }
3734     }
3735     $run_extra = {} unless defined $run_extra;
3736     foreach my $k (keys %$run_extra) {
3737       if (exists $TEST_STATE->{$k}) {
3738         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3739         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3740       }
3741       if (defined $run_extra->{$k}) {
3742         $TEST_STATE->{$k} = $run_extra->{$k};
3743       } elsif (exists $TEST_STATE->{$k}) {
3744         delete $TEST_STATE->{$k};
3745       }
3746     }
3747
3748     # Hit EOF after an initial return code number
3749
3750     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3751
3752     # Carry on with the next command if we did not wait for this one. $rc == 0
3753     # if no subprocess was run; $rc == 3 if we started a process but did not
3754     # wait for it.
3755
3756     next if ($rc == 0 || $rc == 3);
3757
3758     # We ran and waited for a command. Check for the expected result unless
3759     # it died.
3760
3761     if ($cmdrc != $expectrc && !$sigpipehappened)
3762       {
3763       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3764       if (($cmdrc & 0xff) == 0)
3765         {
3766         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3767         }
3768       elsif (($cmdrc & 0xff00) == 0)
3769         { printf("** Killed by signal %d", $cmdrc & 255); }
3770       else
3771         { printf("** Status %x", $cmdrc); }
3772
3773       for (;;)
3774         {
3775         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3776         $_ = $force_continue ? "c" : <T>;
3777         tests_exit(1) if /^q?$/i;
3778         log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3779         if ($force_continue)
3780           {
3781           print "\nstderr tail:\n";
3782           print "===================\n";
3783           system("tail -20 test-stderr");
3784           print "===================\n";
3785           print "... continue forced\n";
3786           }
3787
3788         last if /^[rc]$/i;
3789         if (/^e$/i)
3790           {
3791           system("$more test-stderr");
3792           }
3793         elsif (/^o$/i)
3794           {
3795           system("$more test-stdout");
3796           }
3797         }
3798
3799       $retry = 1 if /^r$/i;
3800       $docheck = 0;
3801       }
3802
3803     # If the command was exim, and a listening server is running, we can now
3804     # close its input, which causes us to wait for it to finish, which is why
3805     # we didn't close it earlier.
3806
3807     if ($rc == 2 && $server_pid != 0)
3808       {
3809       close SERVERCMD;
3810       $server_pid = 0;
3811       if ($? != 0)
3812         {
3813         if (($? & 0xff) == 0)
3814           { printf("Server return code %d", $?/256); }
3815         elsif (($? & 0xff00) == 0)
3816           { printf("Server killed by signal %d", $? & 255); }
3817         else
3818           { printf("Server status %x", $?); }
3819
3820         for (;;)
3821           {
3822           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3823           $_ = $force_continue ? "c" : <T>;
3824           tests_exit(1) if /^q?$/i;
3825           log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3826           print "... continue forced\n" if $force_continue;
3827           last if /^[rc]$/i;
3828
3829           if (/^s$/i)
3830             {
3831             open(S, "test-stdout-server") ||
3832               tests_exit(-1, "Failed to open test-stdout-server: $!");
3833             print while <S>;
3834             close(S);
3835             }
3836           }
3837         $retry = 1 if /^r$/i;
3838         }
3839       }
3840     }
3841
3842   close SCRIPT;
3843
3844   # The script has finished. Check the all the output that was generated. The
3845   # function returns 0 if all is well, 1 if we should rerun the test (the files
3846   # function returns 0 if all is well, 1 if we should rerun the test (the files
3847   # have been updated). It does not return if the user responds Q to a prompt.
3848
3849   if ($retry)
3850     {
3851     $retry = '0';
3852     print (("#" x 79) . "\n");
3853     redo;
3854     }
3855
3856   if ($docheck)
3857     {
3858     if (check_output($TEST_STATE->{munge}) != 0)
3859       {
3860       print (("#" x 79) . "\n");
3861       redo;
3862       }
3863     else
3864       {
3865       print ("  Script completed\n");
3866       }
3867     }
3868   }
3869
3870
3871 ##################################################
3872 #         Exit from the test script              #
3873 ##################################################
3874
3875 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
3876 tests_exit(0);
3877
3878 # End of runtest script
3879 # vim: set sw=2 et :