test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32 use File::Copy;
  33
  34 use lib "$RealBin/lib";
  35 use Exim::Runtest;
  36 use Exim::Utils qw(uniq numerically cp);
  37
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  39 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  40
  41 use constant TEST_TOP => 8999;
  42 use constant TEST_SPECIAL_TOP => 9999;
  43
  44
  45 # Start by initializing some global variables
  46
  47 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  48
  49 # This gets embedded in the D-H params filename, and the value comes
  50 # from asking GnuTLS for "normal", but there appears to be no way to
  51 # use certtool/... to ask what that value currently is.  *sigh*
  52 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  53 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  54 # normal = 2432   tls_dh_max_bits = 2236
  55 my $gnutls_dh_bits_normal = 2236;
  56
  57 my $cf = 'bin/cf -exact';
  58 my $cr = "\r";
  59 my $debug = 0;
  60 my $flavour = do {
  61   my $f = Exim::Runtest::flavour() // '';
  62   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  63 };
  64 my $force_continue = 0;
  65 my $force_update = 0;
  66 my $log_failed_filename = 'failed-summary.log';
  67 my $log_summary_filename = 'run-summary.log';
  68 my @more = qw'less -XF';
  69 my $optargs = '';
  70 my $save_output = 0;
  71 my $server_opts = '';
  72 my $slow = 0;
  73 my $valgrind = 0;
  74
  75 my $have_ipv4 = 1;
  76 my $have_ipv6 = 1;
  77 my $have_largefiles = 0;
  78
  79 my @test_list = ();
  80
  81
  82 # Networks to use for DNS tests. We need to choose some networks that will
  83 # never be used so that there is no chance that the host on which we are
  84 # running is actually in one of the test networks. Private networks such as
  85 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  86 # Rather than use some unassigned numbers (that might become assigned later),
  87 # I have chosen some multicast networks, in the belief that such addresses
  88 # won't ever be assigned to hosts. This is the only place where these numbers
  89 # are defined, so it is trivially possible to change them should that ever
  90 # become necessary.
  91
  92 my $parm_ipv4_test_net = 224;
  93 my $parm_ipv6_test_net = 'ff00';
  94
  95 # Port numbers are currently hard-wired
  96
  97 my $parm_port_n = 1223;         # Nothing listening on this port
  98 my $parm_port_s = 1224;         # Used for the "server" command
  99 my $parm_port_d = 1225;         # Used for the Exim daemon
 100 my $parm_port_d2 = 1226;        # Additional for daemon
 101 my $parm_port_d3 = 1227;        # Additional for daemon
 102 my $parm_port_d4 = 1228;        # Additional for daemon
 103 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 104
 105 # Find a suiteable group name for test (currently only 0001
 106 # uses a group name. A numeric group id would do
 107 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 108
 109 # Manually set locale
 110 $ENV{LC_ALL} = 'C';
 111
 112 # In some environments USER does not exist, but we need it for some test(s)
 113 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 114
 115 my ($parm_configure_owner, $parm_configure_group);
 116 my ($parm_ipv4, $parm_ipv6, $parm_ipv6_stripped);
 117 my $parm_hostname;
 118
 119 ###############################################################################
 120 ###############################################################################
 121
 122 # Define a number of subroutines
 123
 124 ###############################################################################
 125 ###############################################################################
 126
 127
 128 ##################################################
 129 #              Handle signals                    #
 130 ##################################################
 131
 132 sub pipehandler { $sigpipehappened = 1; }
 133
 134 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 135
 136
 137 ##################################################
 138 #       Do global macro substitutions            #
 139 ##################################################
 140
 141 # This function is applied to configurations, command lines and data lines in
 142 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 143 # directory. It takes one argument: the current test number, or zero when
 144 # setting up files before running any tests.
 145
 146 sub do_substitute{
 147 s?\bCALLER\b?$parm_caller?g;
 148 s?\bCALLERGROUP\b?$parm_caller_group?g;
 149 s?\bCALLER_UID\b?$parm_caller_uid?g;
 150 s?\bCALLER_GID\b?$parm_caller_gid?g;
 151 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 152 s?\bDIR/?$parm_cwd/?g;
 153 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 154 s?\bEXIMUSER\b?$parm_eximuser?g;
 155 s?\bHOSTIPV4\b?$parm_ipv4?g;
 156 s?\bHOSTIPV6\b?$parm_ipv6?g;
 157 s?\bHOSTNAME\b?$parm_hostname?g;
 158 s?\bPORT_D\b?$parm_port_d?g;
 159 s?\bPORT_D2\b?$parm_port_d2?g;
 160 s?\bPORT_D3\b?$parm_port_d3?g;
 161 s?\bPORT_D4\b?$parm_port_d4?g;
 162 s?\bPORT_N\b?$parm_port_n?g;
 163 s?\bPORT_S\b?$parm_port_s?g;
 164 s?\bTESTNUM\b?$_[0]?g;
 165 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 166 s?\bV6NET:?$parm_ipv6_test_net:?g;
 167 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 168 s?\bMAILGROUP\b?$parm_mailgroup?g;
 169 }
 170
 171
 172 ##################################################
 173 #     Any state to be preserved across tests     #
 174 ##################################################
 175
 176 my $TEST_STATE = {};
 177
 178
 179 ##################################################
 180 #        Subroutine to tidy up and exit          #
 181 ##################################################
 182
 183 # In all cases, we check for any Exim daemons that have been left running, and
 184 # kill them. Then remove all the spool data, test output, and the modified Exim
 185 # binary if we are ending normally.
 186
 187 # Arguments:
 188 #    $_[0] = 0 for a normal exit; full cleanup done
 189 #    $_[0] > 0 for an error exit; no files cleaned up
 190 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 191
 192 sub tests_exit{
 193 my($rc) = $_[0];
 194 my($spool);
 195
 196 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 197 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 198 # the background.
 199
 200 if (exists $TEST_STATE->{exim_pid})
 201   {
 202   $pid = $TEST_STATE->{exim_pid};
 203   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 204   system("sudo kill -INT $pid");
 205   }
 206
 207 if (opendir(DIR, "spool"))
 208   {
 209   my(@spools) = sort readdir(DIR);
 210   closedir(DIR);
 211   foreach $spool (@spools)
 212     {
 213     next if $spool !~ /^exim-daemon./;
 214     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 215     chomp($pid = <PID>);
 216     close(PID);
 217     print "Tidyup: killing daemon pid=$pid\n";
 218     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 219     }
 220   }
 221 else
 222   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 223
 224 # Close the terminal input and remove the test files if all went well, unless
 225 # the option to save them is set. Always remove the patched Exim binary. Then
 226 # exit normally, or die.
 227
 228 close(T);
 229 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 230   if ($rc == 0 && !$save_output);
 231
 232 system("sudo /bin/rm -rf ./eximdir/*")
 233   if (!$save_output);
 234
 235 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 236 exit $rc if ($rc >= 0);
 237 die "** runtest error: $_[1]\n";
 238 }
 239
 240
 241
 242 ##################################################
 243 #   Subroutines used by the munging subroutine   #
 244 ##################################################
 245
 246 # This function is used for things like message ids, where we want to generate
 247 # more than one value, but keep a consistent mapping throughout.
 248 #
 249 # Arguments:
 250 #   $oldid        the value from the file
 251 #   $base         a base string into which we insert a sequence
 252 #   $sequence     the address of the current sequence counter
 253
 254 sub new_value {
 255 my($oldid, $base, $sequence) = @_;
 256 my($newid) = $cache{$oldid};
 257 print ">> replace  $oldid -> $newid\n" if ($debug && defined $newid);
 258 if (! defined $newid)
 259   {
 260   $newid = sprintf($base, $$sequence++);
 261   print ">> new      $oldid -> $newid\n" if $debug;
 262   $cache{$oldid} = $newid;
 263   }
 264 return $newid;
 265 }
 266
 267
 268 # This is used while munging the output from exim_dumpdb.
 269 # May go wrong across DST changes.
 270
 271 sub date_seconds {
 272 my($day,$month,$year,$hour,$min,$sec) =
 273   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 274 my($mon);
 275 if   ($month =~ /Jan/) {$mon = 0;}
 276 elsif($month =~ /Feb/) {$mon = 1;}
 277 elsif($month =~ /Mar/) {$mon = 2;}
 278 elsif($month =~ /Apr/) {$mon = 3;}
 279 elsif($month =~ /May/) {$mon = 4;}
 280 elsif($month =~ /Jun/) {$mon = 5;}
 281 elsif($month =~ /Jul/) {$mon = 6;}
 282 elsif($month =~ /Aug/) {$mon = 7;}
 283 elsif($month =~ /Sep/) {$mon = 8;}
 284 elsif($month =~ /Oct/) {$mon = 9;}
 285 elsif($month =~ /Nov/) {$mon = 10;}
 286 elsif($month =~ /Dec/) {$mon = 11;}
 287 return timelocal($sec,$min,$hour,$day,$mon,$year);
 288 }
 289
 290
 291 # This is a subroutine to sort maildir files into time-order. The second field
 292 # is the microsecond field, and may vary in length, so must be compared
 293 # numerically.
 294
 295 sub maildirsort {
 296 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 297 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 298 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 299 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 300 }
 301
 302
 303
 304 ##################################################
 305 #   Subroutine list files below a directory      #
 306 ##################################################
 307
 308 # This is used to build up a list of expected mail files below a certain path
 309 # in the directory tree. It has to be recursive in order to deal with multiple
 310 # maildir mailboxes.
 311
 312 sub list_files_below {
 313 my($dir) = $_[0];
 314 my(@yield) = ();
 315 my(@sublist, $file);
 316
 317 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 318 @sublist = sort maildirsort readdir(DIR);
 319 closedir(DIR);
 320
 321 foreach $file (@sublist)
 322   {
 323   next if $file eq "." || $file eq ".." || $file eq "CVS";
 324   if (-d "$dir/$file")
 325     { @yield = (@yield, list_files_below("$dir/$file")); }
 326   else
 327     { push @yield, "$dir/$file"; }
 328   }
 329
 330 return @yield;
 331 }
 332
 333
 334
 335 ##################################################
 336 #         Munge a file before comparing          #
 337 ##################################################
 338
 339 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 340 # on into standard values, so that the compare works. Perl's substitution with
 341 # an expression provides a neat way to do some of these changes.
 342
 343 # We keep a global associative array for repeatedly turning the same values
 344 # into the same standard values throughout the data from a single test.
 345 # Message ids get this treatment (can't be made reliable for times), and
 346 # times in dumped retry databases are also handled in a special way, as are
 347 # incoming port numbers and PIDs.
 348
 349 # On entry to the subroutine, the file to write to is already opened with the
 350 # name MUNGED. The input file name is the only argument to the subroutine.
 351 # Certain actions are taken only when the name contains "stderr", "stdout",
 352 # or "log". The yield of the function is 1 if a line matching "*** truncated
 353 # ***" is encountered; otherwise it is 0.
 354
 355 sub munge {
 356 my($file) = $_[0];
 357 my($extra) = $_[1];
 358 my($yield) = 0;
 359 my(@saved) = ();
 360
 361 local $_;
 362
 363 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 364
 365 my($is_log) = $file =~ /log/;
 366 my($is_stdout) = $file =~ /stdout/;
 367 my($is_stderr) = $file =~ /stderr/;
 368 my($is_mail) = $file =~ /mail/;
 369
 370 # Date pattern
 371
 372 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 373
 374 # Debug time & pid
 375
 376 $time_pid = "(?:\\d{2}:\\d{2}:\\d{2}\\s+\\d+\\s)";
 377
 378 # Pattern for matching pids at start of stderr lines; initially something
 379 # that won't match.
 380
 381 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 382
 383 # Scan the file and make the changes. Near the bottom there are some changes
 384 # that are specific to certain file types, though there are also some of those
 385 # inline too.
 386
 387 LINE: while(<IN>)
 388   {
 389 RESET_AFTER_EXTRA_LINE_READ:
 390   if ($munge_skip)
 391     {
 392     # Munging is a no-op.
 393     # Useful when testing exim_msgdate so that
 394     # we compare unmunged dates and message-ids.
 395     print MUNGED;
 396     next;
 397     }
 398
 399   # Custom munges
 400   if ($extra)
 401     {
 402     next if $extra =~ m%^/%  &&  eval $extra;
 403     eval $extra if $extra =~ m/^s/;
 404     eval substr($extra, 1) if $extra =~ m/^R/;
 405     }
 406
 407   # Check for "*** truncated ***"
 408   $yield = 1 if /\*\*\* truncated \*\*\*/;
 409
 410   # Replace the name of this host
 411   s/\Q$parm_hostname\E/the.local.host.name/g;
 412
 413   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 414   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 415
 416   # The name of the shell may vary
 417   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 418
 419   # Replace the path to the testsuite directory
 420   s?\Q$parm_cwd\E?TESTSUITE?g;
 421
 422   # Replace the Exim version number (may appear in various places)
 423   # patchexim should have fixed this for us
 424   #s/Exim \K\d+[._]\d+[\w_-]*/x.yz/i;
 425
 426   # Replace Exim message ids by a unique series.
 427   # Both old and new formats, with separate replace series, for now.
 428   s/(\d[^\W_]{5}-[^\W_]{6}-[^\W_]{2})
 429     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid_old)/egx;
 430   s/(\d[^\W_]{5}-[^\W_]{11}-[^\W_]{4})
 431     /new_value($1, "10Hm%s-000000005vi-0000", \$next_msgid)/egx;
 432
 433   # The names of lock files appear in some error and debug messages
 434   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 435
 436   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 437   # port" message, because it is not always the same.
 438   s/port (\d+) \([^)]+\)/port $1/g
 439     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 440
 441   # Challenges in SPA authentication
 442   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 443
 444   # PRVS values
 445   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 446   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 447
 448   # There are differences in error messages between OpenSSL versions
 449   s/SSL_CTX_set_cipher_list/SSL_connect/;
 450   s/error=\Kauthority and subject key identifier mismatch/self signed certificate/;
 451   s/error=\Kself-signed certificate/self signed certificate/;
 452
 453   # One error test in expansions mentions base 62 or 36
 454   s/is not a base (36|62) number/is not a base 36\/62 number/;
 455
 456   # This message sometimes has a different number of seconds
 457   s/forced fail after \d seconds/forced fail after d seconds/;
 458
 459   # This message may contain a different DBM library name
 460   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 461
 462   # The message for a non-listening FIFO varies
 463   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 464
 465   # Debugging output of lists of hosts may have different sort keys
 466   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 467
 468   # Random local part in callout cache testing
 469   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 470   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 471
 472   # File descriptor numbers may vary
 473   s/^writing data block fd=\d+/writing data block fd=dddd/;
 474   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 475
 476
 477   # ======== Dumpdb output ========
 478   # This must be before the general date/date munging.
 479   # Time data lines, which look like this:
 480   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 481   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 482     {
 483     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 484     $expired = '' if !defined $expired;
 485
 486     # Round the time-difference up to nearest even value
 487     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
 488
 489     # We used to use globally unique replacement values, but timing
 490     # differences make this impossible. Just show the increment on the
 491     # last one.
 492
 493     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 494       $increment, $expired);
 495     next;
 496     }
 497
 498   # more_errno values in exim_dumpdb output which are times
 499   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 500
 501   # port numbers in dumpdb output
 502   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
 503
 504   # port numbers in stderr
 505   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
 506   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
 507
 508
 509   # ======== Dates and times ========
 510
 511   # Dates and times are all turned into the same value - trying to turn
 512   # them into different ones cannot be done repeatedly because they are
 513   # real time stamps generated while running the test. The actual date and
 514   # time used was fixed when I first started running automatic Exim tests.
 515
 516   # Date/time in header lines and SMTP responses
 517   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 518     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 519   # and in a French locale
 520   s/\S{4},\s\d\d?\s[^,]+\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 521     /dim., 10 f\xE9vr 2019 20:05:49 +0000/gx;
 522
 523   # Date/time in logs and in one instance of a filter test
 524   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 525   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(?:\s(?:[+-]\d\d\d\d|[A-Z]{2}T))?\s/2017-07-30 18:51:05.712 /gx;
 526   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 527   # Date/time in syslog test
 528   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 529   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 530   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 531   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 532
 533   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 534   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 535
 536   # Date/time in message separators
 537   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 538     /Tue Mar 02 09:44:33 1999/gx;
 539
 540   # Date of message arrival in spool file as shown by -Mvh
 541   s/^\d{9,10}\s0$/ddddddddd 0/;
 542
 543   # Date/time in mbx mailbox files
 544   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 545
 546   # Dates/times in debugging output for writing retry records
 547   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 548     {
 549     my($next) = $3 - $2;
 550     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 551     }
 552   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 553   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 554
 555   # Time to retry may vary
 556   s/time to retry = \S+/time to retry = tttt/;
 557   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 558   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 559
 560   # Date/time in exim -bV output
 561   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 562
 563   # Eximstats heading
 564   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 565     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 566
 567   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 568   # us the former on a new connection.
 569   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 570
 571   # ======== TLS certificate algorithms ========
 572   #
 573   # In Received: headers, convert RFC 8314 style ciphersuite to
 574   # the older (comment) style, keeping only the Auth element
 575   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
 576   # element (and no _WITH); insert a spurious "RSA".
 577   # Also in $tls_X_cipher_std reporting.
 578
 579   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-$1-AES256-SHAnnn:xxx)/;
 580   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
 581
 582   s/ cipher_ TLS_.*?([^_]+)_WITH.+$/ cipher_ TLS1.x:ke_$1_WITH_ci_mac/;
 583   s/ cipher_ TLS_.*$/ cipher_ TLS1.x:ke_RSA_WITH_ci_mac/;
 584
 585   # Test machines might have various different TLS library versions supporting
 586   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 587   # treat the standard algorithms the same.
 588   #
 589   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : bits
 590   #
 591   # So far, have seen:
 592   #   TLSv1:AES128-GCM-SHA256:128
 593   #   TLSv1:AES256-SHA:256
 594   #   TLSv1.1:AES256-SHA:256
 595   #   TLSv1.2:AES256-GCM-SHA384:256
 596   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 597   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 598   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 599   # We also need to handle the ciphersuite without the TLS part present, for
 600   # client-ssl's output.  We also see some older forced ciphersuites, but
 601   # negotiating TLS 1.2 instead of 1.0.
 602   # Mail headers (...), log-lines X=..., client-ssl output ...
 603   # (and \b doesn't match between ' ' and '(' )
 604   #
 605   # Retain the authentication algorith field as we want to test that.
 606
 607   s/( (?: (?:\b|\s) [\(=] ) | \s )TLS1(\.[123])?:/$1TLS1.x:/xg;
 608   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
 609   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
 610
 611   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 612   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
 613   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
 614   #
 615   # TLSversion : "TLS" - C_iph_er - MAC : ???
 616   #
 617   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
 618   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
 619
 620   # LibreSSL
 621   # TLSv1:AES256-GCM-SHA384:256
 622   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 623   # TLS1.3:AEAD-AES256-GCM-SHA384:256
 624   #
 625   # ECDHE-RSA-CHACHA20-POLY1305
 626   # AES256-GCM-SHA384
 627
 628   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 629   s/AEAD-(AES256-GCM-SHA384)/RSA-$1/g;
 630   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
 631   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
 632
 633   # GnuTLS have seen:
 634   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
 635   #   TLS1.3:ECDHE_SECP256R1__RSA_PSS_RSAE_SHA256__AES_256_GCM__AEAD:256
 636   #   TLS1.3:ECDHE_X25519__RSA_PSS_RSAE_SHA256__AES_256_GCM:256
 637   #   TLS1.3:ECDHE_PSK_SECP256R1__AES_256_GCM__AEAD:256
 638   #
 639   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 640   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 641   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 642   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 643   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_256_GCM:256
 644   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_128_CBC__SHA256:128
 645   #   TLS1.2:ECDHE_SECP256R1__ECDSA_SHA512__AES_256_GCM:256
 646   #   TLS1.2:ECDHE_SECP256R1__AES_256_GCM:256           (3.6.7 resumption)
 647   #   TLS1.2:ECDHE_RSA_SECP256R1__AES_256_GCM:256       (! 3.5.18 !)
 648   #   TLS1.2:RSA__CAMELLIA_256_GCM:256                  (leave the cipher name)
 649   #   TLS1.2-PKIX:RSA__AES_128_GCM__AEAD:128            (the -PKIX seems to be a 3.1.20 thing)
 650   #   TLS1.2-PKIX:ECDHE_RSA_SECP521R1__AES_256_GCM__AEAD:256
 651   #
 652   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 653   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 654   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 655   #   X=TLS1.0:RSA_AES_256_CBC_SHA1:256
 656   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 657   #   X=TLS1.0-PKIX:RSA__AES_256_CBC__SHA1:256
 658   # and as stand-alone cipher:
 659   #   ECDHE-RSA-AES256-SHA
 660   #   DHE-RSA-AES256-SHA256
 661   #   DHE-RSA-AES256-SHA
 662   # picking latter as canonical simply because regex easier that way.
 663   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
 664   s/TLS1.[x0123](-PKIX)?:                                               # TLS version
 665     ((EC)?DHE(_((?<psk>PSK)_)?((?<auth>RSA|ECDSA)_)?
 666                                 (SECP(256|521)R1|X25519))?__?)?         # key-exchange
 667     ((?<auth>RSA|ECDSA)((_PSS_RSAE)?_SHA(512|256))?__?)?                # authentication
 668     (?<with>WITH_)?                                                     # stdname-with
 669     AES_(256|128)_(CBC|GCM)                                             # cipher
 670     (__?AEAD)?                                                          # pseudo-MAC
 671     (__?SHA(1|256|384))?                                                # PRF
 672     :(256|128)                                                          # cipher strength
 673     /"TLS1.x:ke-"
 674         . (defined($+{psk}) ? $+{psk} : "")
 675         . (defined($+{auth}) ? $+{auth} : "")
 676         . (defined($+{with}) ? $+{with} : "")
 677         . "-AES256-SHAnnn:xxx"/gex;
 678   s/TLS1.2:RSA__CAMELLIA_256_GCM(_SHA384)?:256/TLS1.2:RSA_CAMELLIA_256_GCM-SHAnnn:256/g;
 679   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
 680
 681   # Separate reporting of TLS version
 682   s/ver:    TLS1(\.[0-3])?$/ver:    TLS1.x/;
 683   s/ \(TLS1(\.[0-3])?\) / (TLS1.x) /;
 684
 685   # GnuTLS library error message changes
 686   s/(No certificate was found|Certificate is required)/The peer did not send any certificate/g;
 687 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 688   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 689   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 690
 691   # (this new one is a generic channel-read error, but the testsuite
 692   # only hits it in one place)
 693   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 694
 695   # (replace old with new, hoping that old only happens in one situation)
 696   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 697   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 698
 699   # signature algorithm names
 700   s/RSA-SHA1/RSA-SHA/;
 701
 702
 703   # ======== Caller's login, uid, gid, home, gecos ========
 704
 705   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 706   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 707   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 708
 709   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 710   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 711
 712   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 713   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 714
 715   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 716
 717   # When looking at spool files with -Mvh, we will find not only the caller
 718   # login, but also the uid and gid. It seems that $) in some Perls gives all
 719   # the auxiliary gids as well, so don't bother checking for that.
 720
 721   s/^CALLER $> \d+$/CALLER UID GID/;
 722
 723   # There is one case where the caller's login is forced to something else,
 724   # in order to test the processing of logins that contain spaces. Weird what
 725   # some people do, isn't it?
 726
 727   s/^spaced user $> \d+$/CALLER UID GID/;
 728
 729
 730   # ======== Exim's login ========
 731   # For messages received by the daemon, this is in the -H file, which some
 732   # tests inspect. For bounce messages, this will appear on the U= lines in
 733   # logs and also after Received: and in addresses. In one pipe test it appears
 734   # after "Running as:". It also appears in addresses, and in the names of lock
 735   # files.
 736
 737   s/U=$parm_eximuser/U=EXIMUSER/;
 738   s/user=$parm_eximuser/user=EXIMUSER/;
 739   s/login=$parm_eximuser/login=EXIMUSER/;
 740   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 741   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 742   s/\b$parm_eximuser@/EXIMUSER@/;
 743   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 744
 745   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 746   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 747
 748   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 749   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 750
 751   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 752
 753
 754   # ======== General uids, gids, and pids ========
 755   # Note: this must come after munges for caller's and exim's uid/gid
 756
 757   # These are for systems where long int is 64
 758   s/\buid=4294967295/uid=-1/;
 759   s/\beuid=4294967295/euid=-1/;
 760   s/\bgid=4294967295/gid=-1/;
 761   s/\begid=4294967295/egid=-1/;
 762
 763   s/\bgid=\d+/gid=gggg/;
 764   s/\begid=\d+/egid=gggg/;
 765   s/\b(?:pid=|pid\s|PID:\s|Process\s|child\s)\K(\d+)/new_value($1, "p%s", \$next_pid)/gxe;
 766   s/\buid=\d+/uid=uuuu/;
 767   s/\beuid=\d+/euid=uuuu/;
 768   s/set_process_info:\s+\d+/set_process_info: pppp/;
 769   s/process \d+ running as transport filter/process pppp running as transport filter/;
 770   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 771   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 772   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 773
 774   # Pid in temp file in appendfile transport
 775   s"test-mail/(subdir/)?temp\K\.\d+\.".pppp.";
 776
 777   # Optional pid in log lines
 778   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 779     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 780
 781   # Optional pid in syslog test lines
 782   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 783     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 784
 785   # Detect a daemon stderr line with a pid and save the pid for subsequent
 786   # removal from following lines.
 787   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 788   s/^$spid //;
 789
 790   # Queue runner waiting messages
 791   s/waiting for children of \d+/waiting for children of pppp/;
 792   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 793
 794   # Most builds are without HAVE_LOCAL_SCAN
 795   next if /^calling local_scan\(\); timeout=300$/;
 796   next if /^local_scan\(\) returned 0 NULL$/;
 797
 798   # ======== Port numbers ========
 799   # Incoming port numbers may vary, but not in daemon startup line.
 800
 801   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 802   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 803
 804   # This handles "connection from" and the like, when the port is given
 805   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 806       && !/\*>/&& !/==/  && !/\*\*/ && !/Connection refused/ && !/in response to/)
 807     {
 808     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 809     }
 810
 811   # Port in host address in spool file output from -Mvh
 812   s/^(--?host_address) (.*[:.])\d+$/$1 ${2}9999/;
 813
 814   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 815     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 816   }
 817
 818
 819   # ======== Local IP addresses ========
 820   # The amount of space between "host" and the address in verification output
 821   # depends on the length of the host name. We therefore reduce it to one space
 822   # for all of them.
 823   # Also, the length of space at the end of the host line is dependent
 824   # on the length of the longest line, so strip it also on otherwise
 825   # un-rewritten lines like localhost
 826   #
 827   # host 127.0.0.1     [127.0.0.1]
 828   # host 10.0.0.1      [10.0.0.1]-
 829   #
 830   # host 127.0.0.1     [127.0.0.1]--
 831   # host 169.16.16.16  [169.16.16.10]
 832
 833   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 834   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 835   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 836   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 837   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 838   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 839   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 840   s/(^|\W)\K\Q$parm_ipv6_stripped\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 841   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 842   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 843   s/^\s+host\s\S+\s+\[\S+\]\K +$//;     # strip, not collapse the trailing whitespace
 844
 845
 846   # ======== Test network IP addresses ========
 847   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 848   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 849
 850
 851   # ======== IP error numbers and messages ========
 852   # These vary between operating systems
 853   s/Can(no|')t assign requested address/Netwk addr not available/;
 854   s/Operation timed out/Connection timed out/;
 855   s/Address family not supported by protocol family/Network Error/;
 856   s/Network( is)? unreachable/Network unreachable/;
 857   s/Invalid argument/Network Error/;
 858
 859   s/\(\d+\): Network/(dd): Network/;
 860   s/\(\d+\): Connection refused/(dd): Connection refused/;
 861   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 862   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 863   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 864
 865
 866   # ======== Other error numbers ========
 867   s/errno=\d+/errno=dd/g;
 868
 869   # ======== System Error Messages ======
 870   # depending on the underlaying file system the error message seems to differ
 871   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 872
 873   # ======== Output from ls ========
 874   # Different operating systems use different spacing on long output
 875   #s/ +/ /g if /^[-rwd]{10} /;
 876   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 877   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 878   # unfortunately matches a non-ls linefull of dashes.
 879   # Allow the case where we've already picked out the file protection bits.
 880   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 881     s/ +/ /g;
 882   }
 883
 884
 885   # ======== Message sizes =========
 886   # Message sizes vary, owing to different logins and host names that get
 887   # automatically inserted. I can't think of any way of even approximately
 888   # comparing these.
 889
 890   s/([\s,])S=\d+\b/$1S=sss/;
 891   s/:S\d+\b/:Ssss/;
 892   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{23} <)/$1sss$2/i if $is_stdout;
 893   s/\sSIZE=\d+\b/ SIZE=ssss/;
 894   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 895   s/old size = \d+\b/old size = sssss/;
 896   s/message size = \d+\b/message size = sss/;
 897   s/this message = \d+\b/this message = sss/;
 898   s/Size of headers = \d+/Size of headers = sss/;
 899   s/sum=(?!0)\d+/sum=dddd/;
 900   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 901   s/(?<=sum=0 )count=\d+\b/count=dd/;
 902   s/,S is \d+\b/,S is ddddd/;
 903   s/\+0100,\d+;/+0100,ddd;/;
 904   s/\(\d+ bytes written\)/(ddd bytes written)/;
 905   s/added '\d+ 1'/added 'ddd 1'/;
 906   s/Received\s+\d+/Received               nnn/;
 907   s/Delivered\s+\d+/Delivered              nnn/;
 908
 909
 910   # ======== Values in spool space failure message ========
 911   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 912
 913
 914   # ======== Filter sizes ========
 915   # The sizes of filter files may vary because of the substitution of local
 916   # filenames, logins, etc.
 917
 918   s/^\d+(?= (\(tainted\) )?bytes read from )/ssss/;
 919
 920
 921   # ======== OpenSSL error messages ========
 922   # Different releases of the OpenSSL libraries seem to give different error
 923   # numbers, or handle specific bad conditions in different ways, leading to
 924   # different wording in the error messages, so we cannot compare them.
 925
 926 #XXX This loses any trailing "delivering unencypted to" which is unfortunate
 927 #    but I can't work out how to deal with that.
 928   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 929   s/TLS error on connection from .*\K\(SSL_accept\): error:.*:unexpected eof while reading$/(tls lib accept fn): TCP connection closed by peer/;
 930   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 931   next if /SSL verify error: depth=0 error=certificate not trusted/;
 932
 933   # OpenSSL 3.0.0
 934   s/TLS error \(D-H param setting .* error:\K.*dh key too small/xxxxxxxx:SSL routines::dh key too small/;
 935
 936   # OpenSSL 1.1.1
 937   s/error:\K0B080074:x509 certificate routines:X509_check_private_key(?=:key values mismatch$)/05800074:x509 certificate routines:/;
 938   s/error:\K02001002:system library:fopen(?=:No such file or directory$)/80000002:system library:/;
 939   s/error:\K0909006C:PEM routines:get_name(?=:no start line$)/0480006C:PEM routines:/;
 940
 941   # ======== Maildir things ========
 942   # timestamp output in maildir processing
 943   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 944
 945   # maildir delivery files appearing in log lines (in cases of error)
 946   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 947
 948   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 949
 950   # Maildir file names in general
 951   s/\b\d+\.M\d+P\d+\b/dddddddddd.HddddddPddddd/;
 952
 953   # Maildirsize data
 954   while (/^\d+S,\d+C\s*$/)
 955     {
 956     print MUNGED;
 957     while (<IN>)
 958       {
 959       last if !/^\d+ \d+\s*$/;
 960       print MUNGED "ddd d\n";
 961       }
 962     last if !defined $_;
 963     }
 964   last if !defined $_;
 965
 966
 967   # SRS timestamps and signatures vary by hostname and from run to run
 968
 969   s/(?i)SRS0=....=.[^=]?=([^=]+)=([^@]+)\@([^ ]+)/SRS0=ZZZZ=YY=$1=$2\@$3/g;
 970
 971
 972   # ======== Output from the "fd" program about open descriptors ========
 973   # The statuses seem to be different on different operating systems, but
 974   # at least we'll still be checking the number of open fd's.
 975
 976   s/max fd = \d+/max fd = dddd/;
 977   s/status=[0-9a-f]+ (?:RDONLY|WRONLY|RDWR)/STATUS/g;
 978
 979
 980   # ======== Contents of spool files ========
 981   # A couple of tests dump the contents of the -H file. The length fields
 982   # will be wrong because of different user names, etc.
 983   s/^\d\d\d(?=[PFS*])/ddd/;
 984
 985
 986   # ==========================================================
 987   # MIME boundaries in RFC3461 DSN messages
 988   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 989
 990   # Cyrus SASL library version differences (rejectlog)
 991   s/Cyrus SASL permanent failure: \Kuser not found$/generic failure/;
 992
 993   # ==========================================================
 994   # Some munging is specific to the specific file types
 995
 996   # ======== stdout ========
 997
 998   if ($is_stdout)
 999     {
1000     # Skip translate_ip_address and use_classresources in -bP output because
1001     # they aren't always there.
1002
1003     next if /translate_ip_address =/;
1004     next if /use_classresources/;
1005
1006     # In certain filter tests, remove initial filter lines because they just
1007     # clog up by repetition.
1008
1009     if ($rmfiltertest)
1010       {
1011       next if /^(Sender\staken\sfrom|
1012                  Return-path\scopied\sfrom|
1013                  Sender\s+=|
1014                  Recipient\s+=)/x;
1015       if (/^Testing \S+ filter/)
1016         {
1017         $_ = <IN>;    # remove blank line
1018         next;
1019         }
1020       }
1021
1022     # remote IPv6 addrs vary
1023     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
1024
1025     # openssl version variances
1026   # Error lines on stdout from SSL contain process id values and file names.
1027   # They also contain a source file name and line number, which may vary from
1028   # release to release.
1029
1030     next if /^SSL info:/;
1031     next if /SSL verify error: depth=0 error=certificate not trusted/;
1032     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
1033     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
1034     s/^[[:xdigit:]]+:error:[[:xdigit:]]+(?:E[[:xdigit:]]+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
1035     s/^error:\K[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/dddddddd:$1/;
1036     s/^error:\K[[:xdigit:]]+:SSL routines::(tlsv13 alert certificate required)$/dddddddd:SSL routines:ssl3_read_bytes:$1/;
1037     s/^error:\K[[:xdigit:]]+:SSL routines::((tlsv1|sslv3) alert (unknown ca|certificate revoked))$/dddddddd:SSL routines:ssl3_read_bytes:$1/;
1038
1039     # gnutls version variances
1040     next if /^Error in the pull function./;
1041
1042     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
1043     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
1044     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
1045
1046     # subsecond timstamp info in reported header-files
1047     s/^-received_time_usec \.\K\d{6}$/uuuuuu/;
1048     s/^-received_time_complete \K\d+\.\d{6}$/tttt.uuuuuu/;
1049
1050     # Postgres server takes varible time to shut down; lives in various places
1051     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
1052     s/^\/.*postgres /POSTGRES /;
1053
1054     # DMARC is not always supported by the build
1055     next if /^dmarc_tld_file =/;
1056
1057     # ARC is not always supported by the build
1058     next if /^arc_sign =/;
1059
1060     # LIMITS is not always supported by the build
1061     next if /^limits_advertise_hosts =/;
1062
1063     # TLS resumption is not always supported by the build
1064     next if /^tls_resumption_hosts =/;
1065     next if /^-tls_resumption/;
1066     next if /^host_name_extract = /;
1067
1068     # gsasl library version may not support some methods
1069     s/250-AUTH ANONYMOUS PLAIN SCRAM-SHA-1\K SCRAM-SHA-256//;
1070
1071     # mailq times change with when the run is done, vs. static-source spoolfiles
1072     #s/\s*\d*[hd](?=   317 [0-9A-Za-z\-]{23} <nobody@test.ex>)/DDd/;
1073     s/^\s*\d*[hd](?=   317 [0-9A-Za-z\-]{23} <nobody@test.)/DDd/;
1074     }
1075
1076   # ======== stderr ========
1077
1078   elsif ($is_stderr)
1079     {
1080     # The very first line of debugging output will vary
1081     s/^Exim version .*/Exim version x.yz ..../;
1082
1083     # Skip some lines that Exim puts out at the start of debugging output
1084     # because they will be different in different binaries.
1085
1086     next if /^$time_pid?
1087                 (?: Berkeley\ DB:\s
1088                   | Probably\ (?:Berkeley\ DB|ndbm|GDBM)
1089                   | Using\ tdb
1090                   | Authenticators:
1091                   | Lookups(?:\(built-in\))?:
1092                   | Support\ for:
1093                   | Routers:
1094                   | Transports:
1095                   | Malware:
1096                   | log\ selectors\ =
1097                   | cwd=
1098                   | Fixed\ never_users
1099                   | Configure\ owner
1100                   | Size\ of\ off_t:
1101                 )
1102               /x;
1103
1104     # Lines with a leading pid.  Only handle >= 4-digit PIDs to avoid converting SMTP respose codes
1105     s/^\s*(\d{4,})\s(?!(?:previous message|in\s|bytes remain in|SMTP accept process running))/new_value($1, "p%s", \$next_pid) . ' '/e;
1106
1107     # Debugging lines for Exim terminations and process-generation
1108     next if /(?:postfork: | fork(?:ing|ed) for )/;
1109
1110     # IP address lookups use gethostbyname() when IPv6 is not supported,
1111     # and gethostbyname2() or getipnodebyname() when it is.
1112
1113     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
1114
1115     # Extra lookups done when ipv6 is supported
1116     next if /^host_fake_gethostbyname\(af=inet6\) returned 1 \(HOST_NOT_FOUND\)$/;
1117
1118     # we don't care what TZ enviroment the testhost was running
1119     next if /^Reset TZ to/;
1120
1121     # port numbers
1122     s/(?:\[[^\]]*\]:|V4NET\.0\.0\.0:|localhost::?|127\.0\.0\.1[.:]:?|port[= ])\K$parm_port_d/PORT_D/;
1123     s/(?:\[[^\]]*\]:|V4NET\.0\.0\.0:|localhost::?|127\.0\.0\.1[.:]:?|port[= ])\K$parm_port_d2/PORT_D2/;
1124     s/(?:\[[^\]]*\]:|V4NET\.0\.0\.0:|localhost::?|127\.0\.0\.1[.:]:?|port[= ])\K$parm_port_d3/PORT_D3/;
1125     s/(?:\[[^\]]*\]:|V4NET\.0\.0\.0:|localhost::?|127\.0\.0\.1[.:]:?|port[= ])\K$parm_port_d4/PORT_D4/;
1126     s/(?:\[[^\]]*\]:|V4NET\.0\.0\.0:|localhost::?|127\.0\.0\.1[.:]:?|port[= ])\K$parm_port_s/PORT_S/;
1127     s/(?:\[[^\]]*\]:|V4NET\.0\.0\.0:|localhost::?|127\.0\.0\.1[.:]:?|port[= ])\K$parm_port_n/PORT_N/;
1128
1129     # ========= Exim lookups ==================
1130     # Lookups have a char which depends on the number of lookup types compiled in,
1131     # in stderr output.  Replace with a "0".  Recognising this while avoiding
1132     # other output is fragile; perhaps the debug output should be revised instead.
1133     s%^\s+(:?closing )?\K[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
1134
1135     # drop gnutls version strings
1136     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1137     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1138     # and unwanted debug
1139     next if /^GnuTLS<2>: FIPS140-2 (context is not set|operation mode switched from initial to not-approved)$/;
1140     next if /^GnuTLS<3>: ASSERT: sign.c\[_gnutls_sign_is_secure2\]:\d+$/;
1141     next if /^GnuTLS<3>: ASSERT: \.\.\/\.\.\/lib\/pkcs11.c\[find_multi_objs_cb\]:/;
1142     next if /^GnuTLS<3>: ASSERT: \.\.\/\.\.\/lib\/pkcs11.c\[gnutls_pkcs11_obj_list_import_url3\]:/;
1143
1144     # drop openssl version strings
1145     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1146     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1147
1148     # this is timing-dependent
1149     next if /^OpenSSL: creating STEK$/;
1150     next if /^selfsign cert rotate$/;
1151
1152     # TLS preload
1153     # only OpenSSL speaks of these
1154     next if /^TLS: (preloading (DH params \S+|ECDH curve \S+|CA bundle) for server|generating selfsigned server cert)/;
1155     next if /^ Diffie-Hellman initialized from default/;
1156     next if /^ ECDH OpenSSL (< )?[\d.+]+: temp key parameter settings:/;
1157     next if /^ ECDH: .*'prime256v1'/;
1158     next if /^tls_verify_certificates: system$/;
1159     next if /^tls_set_watch: .*\/cert.pem/;
1160     next if /^Generating 2048 bit RSA key/;
1161
1162     # TLS preload
1163     # only GnuTLS speaks of these
1164     next if /^GnuTLS global init required$/;
1165     next if /^TLS: basic cred init, server/;
1166     next if /^TLS: preloading cipher list for server: NULL$/;
1167     s/^GnuTLS using default session cipher\/priority "NORMAL"$/TLS: not preloading cipher list for server/;
1168     next if /^GnuTLS<2>: added \d+ protocols, \d+ ciphersuites, \d+ sig algos and \d+ groups into priority list$/;
1169     next if /^GnuTLS<2>: (Disabling X.509 extensions|signing structure using RSA-SHA256)/;
1170     next if /^GnuTLS.*(wrap_nettle_mpi_print|gnutls_subject_alt_names_get|get_alt_name)/;
1171     next if /^GnuTLS<[23]>: (p11|ASSERT: pkcs11.c|Initializing needed PKCS #11 modules)/;
1172     next if /^GnuTLS<2>: Intel (AES|GCM) accelerator was detected/;
1173     next if /^Added \d{3} certificate authorities/;
1174     next if /^TLS: not preloading CRL for server/;
1175     next if /^GnuTLS<3>: ASSERT: extensions.c\[_gnutls_get_extension/;
1176     next if /^GnuTLS<3>: ASSERT: \.\.\/\.\.\/\.\.\/lib\/x509\//;
1177     next if /^GnuTLS<2>: Initializing PKCS #11 modules/;
1178
1179
1180     # only kevent platforms (FreeBSD, OpenBSD) say this
1181     next if /^watch dir/;
1182     next if /^watch file .*\/usr\/local/;
1183     next if /^watch file .*\/etc\/ssl/;
1184     next if /^closing watch fd:/;
1185
1186     # TLS preload
1187     # there happen in different orders for OpenSSL/GnuTLS/noTLS
1188     next if /^TLS: generating selfsigned server cert/;
1189     next if /^TLS: not preloading (CA bundle|cipher list) for server$/;
1190     next if /^TLS: not preloading server certs$/;
1191
1192     # some plaatforms are missing the standard CA bundle file
1193     next if /^tls_set_watch\(\) fail on '\/usr\/lib\/ssl\/cert.pem': No such file or directory$/;
1194
1195     # drop lookups
1196     next if /^$time_pid?(?: Lookups\ \(built-in\):
1197                                         | Loading\ lookup\ modules\ from
1198                                         | Loaded\ \d+\ lookup\ modules
1199                                         | Total\ \d+\ lookups)/x;
1200
1201     # drop compiler information
1202     next if /^$time_pid?Compiler:/;
1203
1204     # and the ugly bit
1205     # different libraries will have different numbers (possibly 0) of follow-up
1206     # lines, indenting with more data
1207     if (/^$time_pid?Library version:/) {
1208       while (1) {
1209         $_ = <IN>;
1210         next if /^$time_pid?\s/;
1211         goto RESET_AFTER_EXTRA_LINE_READ;
1212       }
1213     }
1214
1215     # drop other build-time controls emitted for debugging
1216     next if /^$time_pid?WHITELIST_D_MACROS:/;
1217     next if /^$time_pid?TRUSTED_CONFIG_LIST:/;
1218
1219     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1220     # with -be, privileges will have been dropped, so this will always
1221     # be the case
1222     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1223
1224     # We might not keep this check; rather than change all the tests, just
1225     # ignore it as long as it succeeds; then we only need to change the
1226     # TLS tests where tls_require_ciphers has been set.
1227     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1228       my $discard = <IN>;
1229       next;
1230     }
1231     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1232
1233     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1234     next if /^macros_trusted overridden to true by whitelisting/;
1235
1236     # We have to omit the localhost ::1 address so that all is well in
1237     # the IPv4-only case.
1238
1239     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1240       if (/looked up these IP addresses/);
1241     next if /name=localhost address=::1/;
1242
1243     # drop pdkim debugging header
1244     next if /^DKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1245
1246     # Some platforms have TIOCOUTome do not
1247     next if /\d+ bytes remain in socket output buffer$/;
1248     # Various other IPv6 lines must be omitted too
1249
1250     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1251     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1252     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1253     next if / in dns_ipv4_lookup?/;
1254     next if / writing neg-cache entry for .*AAAA/;
1255     next if /^faking res_search\(AAAA\) response length as 65535/;
1256
1257     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1258       {
1259       $_= <IN>;     # Gets "returning DNS_NODATA"
1260       next;
1261       }
1262
1263     # Non-TLS builds have a different default Recieved: header expansion
1264     s/^((.*)\t}}}}by \$primary_hostname \$\{if def:received_protocol \{with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_ver        { (\$tls_in_ver)}}\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1265     s/^((\s*).*considering: with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_ver        { (\$tls_in_ver)}}\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1266     if (/condition: def:tls_in_ver$/)
1267       {
1268       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1269       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1270       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1271       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1272       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>; next;
1273       }
1274
1275
1276     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1277     # are unset, because tls ain't always there.
1278
1279     next if /^((>>>)?\s*host)? in tls_advertise_hosts\?$/;
1280     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1281                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1282
1283     # Skip auxiliary group lists because they will vary.
1284
1285     next if /auxiliary group list:/;
1286
1287     # Skip "extracted from gecos field" because the gecos field varies
1288
1289     next if /extracted from gecos field/;
1290
1291     # Skip "waiting for data on socket" and "read response data: size=" lines
1292     # because some systems pack more stuff into packets than others.
1293
1294     next if /waiting for data on socket/;
1295     next if /read response data: size=/;
1296
1297     # If Exim is compiled with readline support but it can't find the library
1298     # to load, there will be an extra debug line. Omit it.
1299
1300     next if /failed to load readline:/;
1301
1302     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1303     # O_CREAT; other's don't. In the latter case there is some debugging output
1304     # which is not present in the former. Skip the relevant lines (there are
1305     # three of them).
1306
1307     if (/returned from EXIM_DBOPEN: \(nil\)/)
1308       {
1309       $_ .= <IN>;
1310       s?\Q$parm_cwd\E?TESTSUITE?g;
1311       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1312         { $_ = <IN>; next; }
1313       }
1314
1315     # Some tests turn on +expand debugging to check on expansions.
1316     # Unfortunately, the Received: expansion varies, depending on whether TLS
1317     # is compiled or not. So we must remove the relevant debugging if it is.
1318
1319     if (/^condition: def:tls_cipher/)
1320       {
1321       while (<IN>) { last if /^condition: def:sender_address/; }
1322       }
1323     elsif (/^expanding: Received: /)
1324       {
1325       while (<IN>) { last if !/^\s/; }
1326       }
1327
1328     # remote port numbers vary
1329     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1330
1331     # Platform-dependent error strings
1332     s/Operation timed out/Connection timed out/;
1333
1334     # Platform differences on disconnect
1335     s/unexpected disconnection while reading SMTP command from \[127.0.0.1\] \K\(error: Connection reset by peer\) //;
1336
1337     # Platform-dependent resolver option bits
1338     s/^ (?:writing|update) neg-cache entry for [^,]+-\K[0-9a-f]+, ttl/xxxx, ttl/;
1339
1340     # timing variance, run-to-run
1341     s/^time on queue = \K1s/0s/;
1342
1343     # content-scan: file order can vary in directory
1344     s%unspool_mbox\(\): unlinking 'TESTSUITE/spool/scan/[^/]*/\K[^\']*%FFFFFFFFF%;
1345
1346     # Skip hosts_require_dane checks when the options
1347     # are unset, because dane ain't always there.
1348     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1349
1350     # daemon notifier socket
1351     s% \@(?=[^ @]+/spool/exim_daemon_notify$)% %;
1352     next if /unlinking notifier socket/;
1353
1354     # daemon notifier socket
1355     # Timing variance over runs.  Collapse repeated memssages.
1356     if (/notify triggered queue run/)
1357       {
1358       my $line = $_;
1359       while (/notify triggered queue run/) { $_ = <IN>; }
1360       $_ = $line . $_;
1361       }
1362
1363     # Different builds will have different lookup types included
1364     s/^\s*search_type \K\d+ \((\w+)\) quoting -1 \(none\)$/NN ($1) quoting -1 (none)/;
1365     # and different numbers of lookup types result in different type-code letters,
1366     # so convert them all to "0"
1367     s%(?<!lsearch)[^ ](?=TESTSUITE/aux-fixed/(?:0414.list[12]|0464.domains)$)%0%;
1368
1369     # DISABLE_OCSP
1370     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1371
1372     # SUPPORT_PROXY
1373     next if /host in hosts_proxy\?/;
1374
1375     # PIPE_CONNECT
1376     if ( /^(>>>)?\s*host in pipelining_connect_advertise_hosts\?$/ )
1377       {
1378       $_ = <IN>;
1379       while ( /^(>>>)?\s*list element:/ ) { $_ = <IN>; }
1380       goto RESET_AFTER_EXTRA_LINE_READ;
1381       }
1382     next if / in (?:pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1383
1384     # Experimental_International
1385     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1386
1387     # Experimental_REQUIRETLS
1388     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1389
1390     # Experimental_LIMITS
1391     if ( /^((>>>)?\s*host)? in limits_advertise_hosts\?$/ )
1392       {
1393       $_ = <IN>;
1394       while ( /^(>>>)?\s*list element: !\*$/ ) { $_ = <IN>; }
1395       goto RESET_AFTER_EXTRA_LINE_READ;
1396       }
1397     next if / in limits_advertise_hosts?\? no \(matched "!\*"\)/;
1398
1399     # Experimental_XCLIENT
1400     next if / in hosts_xclient?\? no \(option unset\)/;
1401
1402     # TCP Fast Open
1403     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1404
1405     # DISABLE_TLS_RESUME
1406     # TLS resumption is not always supported by the build
1407     next if /in tls_resumption_hosts\?/;
1408     next if /RE '.outlook.com/;
1409
1410     # Environment cleaning
1411     next if /\w+ in keep_environment\? (yes|no)/;
1412
1413     # Sizes vary with test hostname
1414     s/^cmd buf flush \d+ bytes/cmd buf flush ddd bytes/;
1415
1416     # Spool filesystem free space changes on different systems.
1417     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1418
1419     # Non-TLS builds have different expansions for received_header_text
1420     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1421       {
1422       $_ .= <IN>;
1423       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1424       }
1425     if (/^ ├──condition: def:tls_cipher$/)
1426       {
1427       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1428       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1429       }
1430
1431     # Not all platforms build with DKIM enabled
1432     next if /^DKIM >> Body data for hash, canonicalized/;
1433
1434     # Not all platforms build with SPF enabled
1435     next if /^(spf_conn_init|SPF_dns_exim_new|spf_compile\.c)/;
1436
1437     # Not all platforms have sendfile support
1438     next if /^cannot use sendfile for body: no support$/;
1439
1440     #  Parts of DKIM-specific debug output depend on the time/date
1441     next if /^date:\w+,\{SP\}/;
1442     next if /^DKIM \[[^[]+\] (Header hash|b) computed:/;
1443
1444     # Not all platforms support TCP Fast Open, and the compile omits the check
1445     if (s/\S+ in hosts_try_fastopen\? (no \(option unset\)|no \(end of list\)|yes \(matched "\*"\))\n$//)
1446       {
1447       chomp;
1448       $_ .= <IN>;
1449       s/ \.\.\. >>> / ... /;
1450       if (s/ non-TFO mode connection attempt to 224.0.0.0, 0 data\b$//) { chomp; $_ .= <IN>; }
1451       s/Address family not supported by protocol family/Network Error/;
1452       s/Network is unreachable/Network Error/;
1453       }
1454     next if /^(ppppp |\d+ )?setsockopt FASTOPEN: Protocol not available$/;
1455     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1456
1457     if (/^([0-9: ]*                                             # possible timestamp
1458         Connecting\ to\ [^ ]+\ [^ ]+(\ from\ [^ ]+)?)\ \.\.\.
1459         \ .*TFO\ mode\x20
1460         (sendto,\ no\ data:\ EINPROGRESS                        # Linux
1461         |connection\ attempt\ to\ [^,]+,\ 0\ data)              # MacOS & no-support
1462         $/x)
1463       {
1464       $_ = $1 . " ... " . <IN>;
1465       s/^(.* \.\.\.) [0-9: ]*connected$/$1  connected/;
1466
1467       if (/^Connecting to .* \.\.\.  connected$/)
1468         {
1469         $_ .= <IN>;
1470         if (/^(Connecting to .* \.\.\.  )connected\n\s+SMTP(\(close\)>>|\(Connection refused\)<<)$/)
1471           {
1472           $_ = $1 . "failed: Connection refused\n" . <IN>;
1473           s/^(Connecting .*)\n\s+SMTP\(close\)>>$/$1/;
1474           }
1475         elsif (/^(Connecting to .* \.\.\.  connected\n)read response data: size=/)
1476           { $_ = $1; }
1477
1478         # Date/time in SMTP banner
1479         s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
1480           /Tue, 2 Mar 1999 09:44:33 +0000/gx;
1481         }
1482       }
1483
1484     # Specific pointer values reported for DB operations change from run to run
1485     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1486     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1487
1488     # Platform-dependent output during MySQL startup
1489     next if /PerconaFT file system space/;
1490     next if /^Waiting for MySQL server to answer/;
1491     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1492
1493     # Postgres version-dependent differences
1494     s/^initdb: warning: (enabling "trust" authentication for local connections)$/\nWARNING: $1/;
1495     # Postgre DB server PID
1496     s/ \[\d+\] (?=(LOG:  redirecting log|HINT:  Future log output))/ [pppp] /;
1497
1498     # Not all builds include DMARC
1499     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1500
1501     # Platform differences in errno strings
1502     s/  SMTP\(Operation timed out\)<</  SMTP(Connection timed out)<</;
1503
1504     # Platform differences for errno values (eg. Hurd)
1505     s/^errno = \d+$/errno = EEE/;
1506     s/^writing error \d+: /writing error EEE: /;
1507
1508     # Time-only, in debug output
1509     # we have to handle double lines from the DBOPEN, hence placed down here and /mg
1510     s/^\d\d:\d\d:\d\d\s+/01:01:01 /mg;
1511
1512     # pid in debug lines
1513     s/^(\d\d:\d\d:\d\d\s+)(\d+)/$1 . new_value($2, "p%s", \$next_pid) . " "/mgxe;
1514     s/(?<!post-)[Pp]rocess\K(\s\d+ )/new_value($1, "p%s", \$next_pid) . " "/gxe;
1515
1516     # Path in environment varies
1517     s/ PATH=\K.*$/<munged>/;
1518
1519     # When Exim is checking the size of directories for maildir, it uses
1520     # the check_dir_size() function to scan directories. Of course, the order
1521     # of the files that are obtained using readdir() varies from system to
1522     # system. We therefore buffer up debugging lines from check_dir_size()
1523     # and sort them before outputting them.
1524
1525     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1526       {
1527       push @saved, $_;
1528       }
1529     else
1530       {
1531       if (@saved > 0)
1532         {
1533         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1534           "to ensure consistency\n";
1535         @saved = sort(@saved);
1536         print MUNGED @saved;
1537         @saved = ();
1538         }
1539
1540       print MUNGED;
1541       }
1542
1543     next;
1544     }
1545
1546   # ======== log ========
1547
1548   elsif ($is_log)
1549     {
1550     # Berkeley DB version differences
1551     next if / Berkeley DB error: /;
1552
1553     # CHUNKING: exact sizes depend on hostnames in headers
1554     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1555
1556     # OpenSSL version variances
1557     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)|):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1558     next if /TLS error \(SSL_read\): error:0A000126:SSL routines::unexpected eof while reading$/ ;
1559     s/EVDATA: \K\(SSL_accept\): error:0A000126:SSL routines::unexpected eof while reading/SSL_accept: TCP connection closed by peer/;
1560     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(?:(?i)ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT|)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1561     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1562     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:(PEM routines):get_name:(no start line)/0906D06C:$1:PEM_read_bio:$2/;
1563
1564     # GnuTLS version variances
1565     if (/TLS error on connection \(recv\): .* (Decode error|peer did not send any certificate)/)
1566       {
1567       my $prev = $_;
1568       $_ = <IN>;
1569       if (/error on first read/)
1570         {
1571         s/TLS session: \Kerror on first read:/(gnutls_handshake): A TLS fatal alert has been received.:/;
1572         goto RESET_AFTER_EXTRA_LINE_READ;
1573         }
1574       else
1575         { $_ = $prev; }
1576       }
1577     # translate GnuTLS error into the OpenSSL one
1578     s/ARC: AMS signing: privkey PEM-block import: \KThe requested data were not available.$/error:0906D06C:PEM routines:PEM_read_bio:no start line/;
1579     # and then both into the OpenSSL 3.x one
1580     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:PEM routines:PEM_read_bio:no start line$/1E08010C:DECODER routines::unsupported/;
1581
1582     # DKIM timestamps
1583     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1584       {
1585       my ($prefix, $t_diff) = ($1, $3 - $2);
1586       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1587       }
1588     # GnuTLS reports a different keysize vs. OpenSSL, for ed25519 keys
1589     s/signer: [^ ]* bits:\K 256/ 253/;
1590     s/public key too short:\K 256 bits/ 253 bits/;
1591
1592     # with GnuTLS we cannot log single bad ALPN.  So ignore the with-OpenSSL log line.
1593     # next if /TLS ALPN (http) rejected$/;
1594
1595     # port numbers
1596     s/(?:\[[^\]]*\]:|port )\K$parm_port_d/PORT_D/;
1597     s/(?:\[[^\]]*\]:|port )\K$parm_port_d2/PORT_D2/;
1598     s/(?:\[[^\]]*\]:|port )\K$parm_port_d3/PORT_D3/;
1599     s/(?:\[[^\]]*\]:|port )\K$parm_port_d4/PORT_D4/;
1600     s/(?:\[[^\]]*\]:|port )\K$parm_port_s/PORT_S/;
1601     s/(?:\[[^\]]*\]:|port )\K$parm_port_n/PORT_N/;
1602     s/I=\[[^\]]*\]:\K\d+/ppppp/;
1603
1604     # Platform differences for errno values (eg. Hurd).  Leave 0 and negative numbers alone.
1605     s/R=\w+ T=\w+ defer\K \([1-9]\d*\): / (EEE): /;
1606
1607     # Platform differences in errno strings
1608     s/Arg list too long/Argument list too long/;
1609
1610     # OpenSSL vs. GnuTLS
1611     s/session: \K\((SSL_connect|gnutls_handshake)\): timed out/(tls lib connect fn): timed out/;
1612     s/TLS error on connection from .*\K\((SSL_accept|gnutls_handshake)\): timed out/(tls lib accept fn): timed out/;
1613     s/TLS error on connection from .*\K(SSL_accept: TCP connection closed by peer|\(gnutls_handshake\): The TLS connection was non-properly terminated.)/(tls lib accept fn): TCP connection closed by peer/;
1614     s/TLS session: \K\(gnutls_handshake\): rxd alert: No supported application protocol could be negotiated/(SSL_connect): error: <<detail omitted>>/;
1615     s/\(gnutls_handshake\): No common application protocol could be negotiated./(SSL_accept): error: <<detail omitted>>/;
1616     }
1617
1618   # ======== mail ========
1619
1620   elsif ($is_mail)
1621     {
1622     # DKIM timestamps, and signatures depending thereon
1623     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1624       {
1625       my ($indent, $t_diff) = ($1, $3 - $2);
1626       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1627       <IN>;
1628       <IN>;
1629       }
1630     }
1631
1632   # ======== All files other than stderr ========
1633
1634   print MUNGED;
1635   }
1636
1637 close(IN);
1638 return $yield;
1639 }
1640
1641
1642
1643
1644 ##################################################
1645 #        Subroutine to interact with caller      #
1646 ##################################################
1647
1648 # Arguments: [0] the prompt string
1649 #            [1] if there is a U in the prompt and $force_update is true
1650 #            [2] if there is a C in the prompt and $force_continue is true
1651 # Returns:   returns the answer
1652
1653 sub interact {
1654   my ($prompt, $have_u, $have_c) = @_;
1655
1656   print $prompt;
1657
1658   if ($have_u) {
1659     print "... update forced\n";
1660     return 'u';
1661   }
1662
1663   if ($have_c) {
1664     print "... continue forced\n";
1665     return 'c';
1666   }
1667
1668   return lc <T>;
1669 }
1670
1671
1672
1673 ##################################################
1674 #    Subroutine to log in force_continue mode    #
1675 ##################################################
1676
1677 # In force_continue mode, we just want a terse output to a statically
1678 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1679 # all have mismatches, it will log multiple times.
1680 #
1681 # Arguments: [0] the logfile to append to
1682 #            [1] the testno that failed
1683 # Returns:   nothing
1684
1685
1686
1687 sub log_failure {
1688   my ($logfile, $testno, $detail) = @_;
1689
1690   open(my $fh, '>>', $logfile) or return;
1691
1692   print $fh "Test $testno "
1693         . (defined $detail ? "$detail " : '')
1694         . "failed\n";
1695 }
1696
1697 # Computer-readable summary results logfile
1698
1699 sub log_test {
1700   my ($logfile, $testno, $resultchar) = @_;
1701
1702   open(my $fh, '>>', $logfile) or return;
1703   print $fh "$testno $resultchar\n";
1704 }
1705
1706
1707
1708 ##################################################
1709 #    Subroutine to compare one output file       #
1710 ##################################################
1711
1712 # When an Exim server is part of the test, its output is in separate files from
1713 # an Exim client. The server data is concatenated with the client data as part
1714 # of the munging operation.
1715 #
1716 # Arguments:  [0] the name of the main raw output file
1717 #             [1] the name of the server raw output file or undef
1718 #             [2] where to put the munged copy
1719 #             [3] the name of the saved file
1720 #             [4] TRUE if this is a log file whose deliveries must be sorted
1721 #             [5] optionally, a custom munge command
1722 #
1723 # Returns:    0 comparison succeeded
1724 #             1 comparison failed; differences to be ignored
1725 #             2 comparison failed; files may have been updated (=> re-compare)
1726 #
1727 # Does not return if the user replies "Q" to a prompt.
1728
1729 sub check_file{
1730 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1731
1732 # If there is no saved file, the raw files must either not exist, or be
1733 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1734
1735 # we check if there is a flavour specific file, but we remember
1736 # the original file name as "generic"
1737 $sf_generic = $sf;
1738 $sf_flavour = "$sf_generic.$flavour";
1739 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1740
1741 if (! -e $sf_current)
1742   {
1743   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1744
1745   print "\n";
1746   print "** $rf is not empty\n" if (-s $rf);
1747   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1748
1749   for (;;)
1750     {
1751     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1752     tests_exit(1) if /^q?$/;
1753     if (/^c$/ && $force_continue) {
1754       log_failure($log_failed_filename, $testno, $rf);
1755       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1756     }
1757     return 1 if /^c$/i && $rf !~ /paniclog/ && (!defined $rsf || $rsf !~ /paniclog/);
1758     last if (/^[sc]$/);
1759     }
1760
1761   foreach $f ($rf, $rsf)
1762     {
1763     if (defined $f && -s $f)
1764       {
1765       print "\n";
1766       print "------------ $f -----------\n"
1767         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1768       system @more => $f;
1769       }
1770     }
1771
1772   print "\n";
1773   for (;;)
1774     {
1775     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1776     tests_exit(1) if /^q?$/;
1777     if (/^c$/ && $force_continue) {
1778       log_failure($log_failed_filename, $testno, $rf);
1779       log_test($log_summary_filename, $testno, 'F')
1780     }
1781     return 1 if /^c$/i;
1782     last if (/^u$/i);
1783     }
1784   }
1785
1786 #### $_
1787
1788 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1789 # was a request to create a saved file. First, create the munged file from any
1790 # data that does exist.
1791
1792 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1793 my($truncated) = munge($rf, $extra) if -e $rf;
1794
1795 # Append the raw server log, if it is non-empty
1796 if (defined $rsf && -e $rsf)
1797   {
1798   print MUNGED "\n******** SERVER ********\n";
1799   $truncated |= munge($rsf, $extra);
1800   }
1801 close(MUNGED);
1802
1803 # If a saved file exists, do the comparison. There are two awkward cases:
1804 #
1805 # If "*** truncated ***" was found in the new file, it means that a log line
1806 # was overlong, and truncated. The problem is that it may be truncated at
1807 # different points on different systems, because of different user name
1808 # lengths. We reload the file and the saved file, and remove lines from the new
1809 # file that precede "*** truncated ***" until we reach one that matches the
1810 # line that precedes it in the saved file.
1811 #
1812 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1813 # for an individual message might vary in their order from system to system, as
1814 # a result of parallel deliveries. We load the munged file and sort sequences
1815 # of delivery lines.
1816
1817 if (-e $sf_current)
1818   {
1819   # Deal with truncated text items
1820
1821   if ($truncated)
1822     {
1823     my(@munged, @saved, $i, $j, $k);
1824
1825     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1826     @munged = <MUNGED>;
1827     close(MUNGED);
1828     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1829     @saved = <SAVED>;
1830     close(SAVED);
1831
1832     $j = 0;
1833     for ($i = 0; $i < @munged; $i++)
1834       {
1835       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1836         {
1837         for (; $j < @saved; $j++)
1838           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1839         last if $j >= @saved;     # not found in saved
1840
1841         for ($k = $i - 1; $k >= 0; $k--)
1842           { last if $munged[$k] eq $saved[$j - 1]; }
1843
1844         last if $k <= 0;          # failed to find previous match
1845         splice @munged, $k + 1, $i - $k - 1;
1846         $i = $k + 1;
1847         }
1848       }
1849
1850     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1851     print $fh @munged;
1852     }
1853
1854   # Deal with log sorting
1855
1856   if ($sortfile)
1857     {
1858
1859     my @munged = do {
1860       open(my $fh, '<', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1861       <$fh>;
1862     };
1863
1864     for (my $i = 0; $i < @munged; $i++)
1865       {
1866       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1867         {
1868         my $j;
1869         for ($j = $i + 1; $j < @munged; $j++)
1870           {
1871           last if $munged[$j] !~
1872             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1873           }
1874         @temp = splice(@munged, $i, $j - $i);
1875         @temp = sort(@temp);
1876         splice(@munged, $i, 0, @temp);
1877         }
1878       }
1879
1880     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1881     print $fh "**NOTE: The delivery lines in this file have been sorted.\n";
1882     print $fh @munged;
1883     }
1884
1885   # Do the comparison
1886
1887   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1888
1889   # Handle comparison failure
1890
1891   print "** Comparison of $mf with $sf_current failed";
1892   system @more => 'test-cf';
1893
1894   print "\n";
1895   for (;;)
1896     {
1897     $_ = interact('Continue, Retry, Update current'
1898         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1899         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1900     tests_exit(1) if /^q?$/;
1901     if (/^c$/ && $force_continue) {
1902       log_failure($log_failed_filename, $testno, $sf_current);
1903       log_test($log_summary_filename, $testno, 'F')
1904     }
1905     return 1 if /^c$/i;
1906     return 2 if /^r$/i;
1907     last if (/^[us]$/i);
1908     }
1909   }
1910
1911 # Update or delete the saved file, and give the appropriate return code.
1912
1913 if (-s $mf)
1914   {
1915     my $sf = /^u/i ? $sf_current : $sf_flavour;
1916     copy($mf, $sf) or tests_exit(-1, "Failed to copy $mf $sf");
1917   }
1918 else
1919   {
1920     # if we deal with a flavour file, we can't delete it, because next time the generic
1921     # file would be used again
1922     if ($sf_current eq $sf_flavour) {
1923       open(my $fh, '>', $sf_current);
1924     }
1925     else {
1926       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1927     }
1928   }
1929
1930 return 2;
1931 }
1932
1933
1934
1935 ##################################################
1936 # Custom munges
1937 # keyed by name of munge; value is a ref to a hash
1938 # which is keyed by file, value a string to look for.
1939 # Usable files are:
1940 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1941 # Search strings starting with 's' do substitutions;
1942 # with '/' do line-skips,
1943 # with 'R' run given code.
1944 # Triggered by a scriptfile line "munge <name>"
1945 ##################################################
1946 $munges =
1947   { 'dnssec' =>
1948     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1949
1950     'gnutls_unexpected' =>
1951     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1952
1953     'gnutls_handshake' =>
1954     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1955
1956     'gnutls_bad_clientcert' =>
1957     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1958       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1959     },
1960
1961     'optional_events' =>
1962     { 'stdout' => '/event_action =/' },
1963
1964     'optional_ocsp' =>
1965     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1966
1967     'optional_cert_hostnames' =>
1968     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1969
1970     'loopback' =>
1971     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1972
1973     'scanfile_size' =>
1974     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1975
1976     'delay_1500' =>
1977     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1978
1979     'tls_anycipher' =>
1980     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1981                       s! DN="C=! DN="/C=!;
1982                       s! DN="[^,"]*\K,!/!;
1983                       s! DN="[^,"]*\K,!/!;
1984                       s! DN="[^,"]*\K,!/!;
1985                      ',
1986       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1987     },
1988
1989     'optional_dsn_info' =>
1990     { 'mail' => 'Rif (/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/) {
1991                     while (1) {
1992                       $_ = <IN>;
1993                       next if /^ /;
1994                       goto RESET_AFTER_EXTRA_LINE_READ;
1995                     }
1996                   }'
1997     },
1998
1999     'optional_config' =>
2000     { 'stdout' => '/^(
2001                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
2002                   |gnutls_require_(kx|mac|protocols)
2003                   |hosts_pipe_connect
2004                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
2005                   |dane_require_tls_ciphers
2006                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
2007                   |pipelining_connect_advertise_hosts
2008                   |socks_proxy
2009                   |tls_[^ ]*
2010                   |utf8_downconvert
2011                   )($|[ ]=)/x'
2012     },
2013
2014     'sys_bindir' =>
2015     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
2016
2017     'sync_check_data' =>
2018     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
2019       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
2020
2021     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
2022     { 'mainlog' => 's/((?:host|message) deferral .* errno) <\d+> /$1 <EEE> /' },
2023
2024     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
2025     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
2026
2027     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
2028     { 'stdout' => 's%^> X/X$%> X%' },
2029   };
2030
2031
2032 sub max {
2033   my ($a, $b) = @_;
2034   return $a if ($a > $b);
2035   return $b;
2036 }
2037
2038 ##################################################
2039 #    Subroutine to check the output of a test    #
2040 ##################################################
2041
2042 # This function is called when the series of subtests is complete. It makes
2043 # use of check_file(), whose arguments are:
2044 #
2045 #  [0] the name of the main raw output file
2046 #  [1] the name of the server raw output file or undef
2047 #  [2] where to put the munged copy
2048 #  [3] the name of the saved file
2049 #  [4] TRUE if this is a log file whose deliveries must be sorted
2050 #  [5] an optional custom munge command
2051 #
2052 # Arguments: Optionally, name of a single custom munge to run.
2053 # Returns:   0 if the output compared equal
2054 #            1 if comparison failed; differences to be ignored
2055 #            2 if re-run needed (files may have been updated)
2056
2057 sub check_output{
2058 my($mungename) = $_[0];
2059 my($yield) = 0;
2060 my($munge) = $munges->{$mungename} if defined $mungename;
2061
2062 $yield = max($yield,  check_file("spool/log/paniclog",
2063                        "spool/log/serverpaniclog",
2064                        "test-paniclog-munged",
2065                        "paniclog/$testno", 0,
2066                        $munge->{paniclog}));
2067
2068 $yield = max($yield,  check_file("spool/log/rejectlog",
2069                        "spool/log/serverrejectlog",
2070                        "test-rejectlog-munged",
2071                        "rejectlog/$testno", 0,
2072                        $munge->{rejectlog}));
2073
2074 $yield = max($yield,  check_file("spool/log/mainlog",
2075                        "spool/log/servermainlog",
2076                        "test-mainlog-munged",
2077                        "log/$testno", $sortlog,
2078                        $munge->{mainlog}));
2079
2080 if (!$stdout_skip)
2081   {
2082   $yield = max($yield,  check_file("test-stdout",
2083                        "test-stdout-server",
2084                        "test-stdout-munged",
2085                        "stdout/$testno", 0,
2086                        $munge->{stdout}));
2087   }
2088
2089 if (!$stderr_skip)
2090   {
2091   $yield = max($yield,  check_file("test-stderr",
2092                        "test-stderr-server",
2093                        "test-stderr-munged",
2094                        "stderr/$testno", 0,
2095                        $munge->{stderr}));
2096   }
2097
2098 # Compare any delivered messages, unless this test is skipped.
2099
2100 if (! $message_skip)
2101   {
2102   my($msgno) = 0;
2103
2104   # Get a list of expected mailbox files for this script. We don't bother with
2105   # directories, just the files within them.
2106
2107   foreach $oldmail (@oldmails)
2108     {
2109     next unless $oldmail =~ /^mail\/$testno\./;
2110     print ">> EXPECT $oldmail\n" if $debug;
2111     $expected_mails{$oldmail} = 1;
2112     }
2113
2114   # If there are any files in test-mail, compare them. Note that "." and
2115   # ".." are automatically omitted by list_files_below().
2116
2117   @mails = list_files_below("test-mail");
2118
2119   foreach $mail (@mails)
2120     {
2121     next if $mail =~ /^test-mail\/oncelog(.(dir|pag|db))?$/;
2122
2123     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
2124     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
2125
2126     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
2127       {
2128       $msgno++;
2129       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
2130       }
2131
2132     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
2133     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
2134       "mail/$testno.$saved_mail", 0,
2135       $munge->{mail}));
2136     delete $expected_mails{"mail/$testno.$saved_mail"};
2137     }
2138
2139   # Complain if not all expected mails have been found
2140
2141   if (scalar(keys %expected_mails) != 0)
2142     {
2143     foreach $key (keys %expected_mails)
2144       { print "** no test file found for $key\n"; }
2145
2146     for (;;)
2147       {
2148       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
2149       tests_exit(1) if /^q?$/;
2150       if (/^c$/ && $force_continue) {
2151         log_failure($log_failed_filename, $testno, "missing email");
2152         log_test($log_summary_filename, $testno, 'F')
2153       }
2154       last if /^c$/;
2155
2156       # For update, we not only have to unlink the file, but we must also
2157       # remove it from the @oldmails vector, as otherwise it will still be
2158       # checked for when we re-run the test.
2159
2160       if (/^u$/)
2161         {
2162         foreach $key (keys %expected_mails)
2163           {
2164           my($i);
2165           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
2166           for ($i = 0; $i < @oldmails; $i++)
2167             {
2168             if ($oldmails[$i] eq $key)
2169               {
2170               splice @oldmails, $i, 1;
2171               last;
2172               }
2173             }
2174           }
2175         last;
2176         }
2177       }
2178     }
2179   }
2180
2181 # Compare any remaining message logs, unless this test is skipped.
2182
2183 if (! $msglog_skip)
2184   {
2185   # Get a list of expected msglog files for this test
2186
2187   foreach $oldmsglog (@oldmsglogs)
2188     {
2189     next unless $oldmsglog =~ /^$testno\./;
2190     $expected_msglogs{$oldmsglog} = 1;
2191     }
2192
2193   # If there are any files in spool/msglog, compare them. However, we have
2194   # to munge the file names because they are message ids, which are
2195   # time dependent.
2196
2197   if (opendir(DIR, "spool/msglog"))
2198     {
2199     @msglogs = sort readdir(DIR);
2200     closedir(DIR);
2201
2202     foreach $msglog (@msglogs)
2203       {
2204       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
2205
2206       ($munged_msglog = $msglog) =~
2207         s/((?:[^\W_]{6}-){2}[^\W_]{2})
2208           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid_old)/egx;
2209
2210       $munged_msglog =~
2211         s/([^\W_]{6}-[^\W_]{11}-[^\W_]{4})
2212           /new_value($1, "10Hm%s-000000005vi-0000", \$next_msgid)/egx;
2213
2214       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
2215         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
2216         $munge->{msglog}));
2217       delete $expected_msglogs{"$testno.$munged_msglog"};
2218       }
2219     }
2220
2221   # Complain if not all expected msglogs have been found
2222
2223   if (scalar(keys %expected_msglogs) != 0)
2224     {
2225     foreach $key (keys %expected_msglogs)
2226       {
2227       print "** no test msglog found for msglog/$key\n";
2228       ($msgid) = $key =~ /^\d+\.(.*)$/;
2229       foreach $cachekey (keys %cache)
2230         {
2231         if ($cache{$cachekey} eq $msgid)
2232           {
2233           print "** original msgid $cachekey\n";
2234           last;
2235           }
2236         }
2237       }
2238
2239     for (;;)
2240       {
2241       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
2242       tests_exit(1) if /^q?$/;
2243       if (/^c$/ && $force_continue) {
2244         log_failure($log_failed_filename, $testno, "missing msglog");
2245         log_test($log_summary_filename, $testno, 'F')
2246       }
2247       last if /^c$/;
2248       if (/^u$/)
2249         {
2250         foreach $key (keys %expected_msglogs)
2251           {
2252           tests_exit(-1, "Failed to unlink msglog/$key")
2253             if !unlink("msglog/$key");
2254           }
2255         last;
2256         }
2257       }
2258     }
2259   }
2260
2261 return $yield;
2262 }
2263
2264
2265
2266 ##################################################
2267 #     Subroutine to run one "system" command     #
2268 ##################################################
2269
2270 # We put this in a subroutine so that the command can be reflected when
2271 # debugging.
2272 #
2273 # Argument: the command to be run
2274 # Returns:  nothing
2275
2276 sub run_system {
2277 my($cmd) = $_[0];
2278 if ($debug)
2279   {
2280   my($prcmd) = $cmd;
2281   $prcmd =~ s/; /;\n>> /;
2282   print ">> $prcmd\n";
2283   }
2284 system($cmd);
2285 }
2286
2287
2288
2289 ##################################################
2290 #      Subroutine to run one script command      #
2291 ##################################################
2292
2293 # The <SCRIPT> file is open for us to read an optional return code line,
2294 # followed by the command line and any following data lines for stdin. The
2295 # command line can be continued by the use of \. Data lines are not continued
2296 # in this way. In all lines, the following substitutions are made:
2297 #
2298 # DIR    => the current directory
2299 # CALLER => the caller of this script
2300 #
2301 # Arguments: the current test number
2302 #            reference to the subtest number, holding previous value
2303 #            reference to the expected return code value
2304 #            reference to where to put the command name (for messages)
2305 #            auxiliary information returned from a previous run
2306 #
2307 # Returns:   0 the command was executed inline, no subprocess was run
2308 #            1 a non-exim command was run and waited for
2309 #            2 an exim command was run and waited for
2310 #            3 a command was run and not waited for (daemon, server, exim_lock)
2311 #            4 EOF was encountered after an initial return code line
2312 # Optionally also a second parameter, a hash-ref, with auxiliary information:
2313 #            exim_pid: pid of a run process
2314 #            munge: name of a post-script results munger
2315
2316 sub run_command{
2317 my($testno) = $_[0];
2318 my($subtestref) = $_[1];
2319 my($commandnameref) = $_[3];
2320 my($aux_info) = $_[4];
2321 my($yield) = 1;
2322
2323 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
2324
2325 if (/^(\d+)\s*(?:([A-Z]+)=(\S+))?$/)                # Handle unusual return code
2326   {
2327   my($r) = $_[2];
2328   $$r = $1 << 8;
2329   $ENV{$2} = $3 if (defined $2);
2330   $_ = <SCRIPT>;
2331   return 4 if !defined $_;       # Missing command
2332   $lineno++;
2333   }
2334
2335 chomp;
2336 $wait_time = 0;
2337
2338 # Handle concatenated command lines
2339
2340 s/\s+$//;
2341 while (substr($_, -1) eq"\\")
2342   {
2343   my($temp);
2344   $_ = substr($_, 0, -1);
2345   chomp($temp = <SCRIPT>);
2346   if (defined $temp)
2347     {
2348     $lineno++;
2349     $temp =~ s/\s+$//;
2350     $temp =~ s/^\s+//;
2351     $_ .= $temp;
2352     }
2353   }
2354
2355 # Do substitutions
2356
2357 do_substitute($testno);
2358 if ($debug) { printf ">> $_\n"; }
2359
2360 # Pass back the command name (for messages)
2361
2362 ($$commandnameref) = /^(\S+)/;
2363
2364 # Here follows code for handling the various different commands that are
2365 # supported by this script. The first group of commands are all freestanding
2366 # in that they share no common code and are not followed by any data lines.
2367
2368
2369 ###################
2370 ###################
2371
2372 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2373 # utility and to make DBM files for testing DBM lookups.
2374
2375 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2376   {
2377   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2378          "echo exim_dbmbuild exit code = \$?)" .
2379          ">>test-stdout");
2380   return 1;
2381   }
2382
2383
2384 # The "dump" command runs exim_dumpdb. On different systems, the output for
2385 # some types of dump may appear in a different order because it's just hauled
2386 # out of the DBM file. We can solve this by sorting. Ignore the leading
2387 # date/time, as it will be flattened later during munging.
2388
2389 if (/^dump\s+(\S+)/)
2390   {
2391   my $which  = $1;
2392   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2393   open(my $in, "-|", './eximdir/exim_dumpdb', "$parm_cwd/spool", $which) or die "Can't run exim_dumpdb: $!";
2394   open(my $out, ">>test-stdout");
2395   print $out "+++++++++++++++++++++++++++\n";
2396
2397   if ($which eq "retry")
2398     {
2399     # the sort key is the first part of the retry db dump line, but for
2400     # sorting we (temporarly) replace the own hosts ipv4 with a munged
2401     # version, which matches the munging that is done later
2402     # Why? We must ensure sure, that 127.0.0.1 always sorts first
2403     # map-sort-map: Schwartz's transformation
2404     # test 0099
2405     my @temp = map  { $_->[1] }
2406                sort { $a->[0] cmp $b->[0] }
2407                #map  { [ (split)[0] =~ s/\Q$parm_ipv4/ip4.ip4.ip4.ip4/gr, $_ ] }  # this is too modern for 5.10.1
2408                map  {
2409                 (my $k = (split)[0]) =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/g;
2410                 [ $k, $_ ]
2411                }
2412                do { local $/ = "\n  "; <$in> };
2413     foreach $item (@temp)
2414       {
2415       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2416       print $out "  $item\n";
2417       }
2418     }
2419   else
2420     {
2421     my @temp = <$in>;
2422     if ($which eq "callout")
2423       {
2424       @temp = sort {
2425                    my($aa) = substr $a, 21;
2426                    my($bb) = substr $b, 21;
2427                    return $aa cmp $bb;
2428                    } @temp;
2429       }
2430     elsif ($which eq "seen")
2431       {
2432       @temp = sort {
2433                    (my $aa = $a) =~ s/^([\d.]+)/$1/;
2434                    (my $bb = $b) =~ s/^([\d.]+)/$1/;
2435                    $aa =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/;
2436                    $bb =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/;
2437                    return $aa cmp $bb;
2438                    } @temp;
2439       }
2440     print $out @temp;
2441     }
2442   close($in); # close it explicitly, otherwise $? does not get set
2443   return 1;
2444   }
2445
2446
2447 # verbose comments start with ###
2448 if (/^###\s/) {
2449   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2450     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2451     say {$fh} $_;
2452   }
2453   return 0;
2454 }
2455
2456 # The "echo" command is a way of writing comments to the screen.
2457 if (/^echo\s+(.*)$/)
2458   {
2459   print "$1\n";
2460   return 0;
2461   }
2462
2463
2464 # The "exim_lock" command runs exim_lock in the same manner as "server",
2465 # but it doesn't use any input.
2466
2467 if (/^exim_lock\s+(.*)$/)
2468   {
2469   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2470   $server_pid = open SERVERCMD, "|$cmd" ||
2471     tests_exit(-1, "Failed to run $cmd\n");
2472
2473   # This gives the process time to get started; otherwise the next
2474   # process may not find it there when it expects it.
2475
2476   select(undef, undef, undef, 0.1);
2477   return 3;
2478   }
2479
2480
2481 # The "exinext" command runs exinext
2482
2483 if (/^exinext\s+(.*)/)
2484   {
2485   run_system("(./eximdir/exinext " .
2486     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2487     "-C $parm_cwd/test-config $1;" .
2488     "echo exinext exit code = \$?)" .
2489     ">>test-stdout");
2490   return 1;
2491   }
2492
2493
2494 # The "exigrep" command runs exigrep on the current mainlog
2495
2496 if (/^exigrep\s+(.*)/)
2497   {
2498   run_system("(./eximdir/exigrep " .
2499     "$1 $parm_cwd/spool/log/mainlog;" .
2500     "echo exigrep exit code = \$?)" .
2501     ">>test-stdout");
2502   return 1;
2503   }
2504
2505
2506 # The "exiqgrep" command runs exiqgrep on the current spool
2507
2508 if (/^exiqgrep(\s+.*)?/)
2509   {
2510   run_system("(./eximdir/exiqgrep -E ./eximdir/exim -C $parm_cwd/test-config" . ($1 || '') . ";" .
2511     "echo exiqgrep exit code = \$?)" .
2512     ">>test-stdout");
2513   return 1;
2514   }
2515
2516
2517 # The "eximstats" command runs eximstats on the current mainlog
2518
2519 if (/^eximstats\s+(.*)/)
2520   {
2521   run_system("(./eximdir/eximstats " .
2522     "$1 $parm_cwd/spool/log/mainlog;" .
2523     "echo eximstats exit code = \$?)" .
2524     ">>test-stdout");
2525   return 1;
2526   }
2527
2528
2529 # The "exim_id_update" command runs exim_id_update on the current spool
2530
2531 if (/^exim_id_update(\s+.*)?$/)
2532   {
2533   run_system("(sudo ./eximdir/exim_id_update" . ($1 || '') . " $parm_cwd/spool/input;" .
2534     "echo exim_id_update exit code = \$?)" .
2535     ">>test-stdout 2>>test-stderr");
2536   return 1;
2537   }
2538
2539
2540 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2541 # spool directory, to save Exim from re-creating it each time.
2542
2543 if (/^gnutls/)
2544   {
2545   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2546   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2547          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2548          "sudo chmod 0400 $gen_fn";
2549   return 1;
2550   }
2551
2552
2553 # The "killdaemon" command should ultimately follow the starting of any Exim
2554 # daemon with the -bd option.
2555
2556 if (/^killdaemon/)
2557   {
2558   my $return_extra = {};
2559   if (exists $aux_info->{exim_pid})
2560     {
2561     $pid = $aux_info->{exim_pid};
2562     $return_extra->{exim_pid} = undef;
2563     print ">> killdaemon: recovered pid $pid\n" if $debug;
2564     if ($pid)
2565       {
2566       run_system("sudo /bin/kill -TERM $pid");
2567       wait;
2568       }
2569     } else {
2570     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2571     if ($pid)
2572       {
2573       run_system("sudo /bin/kill -TERM $pid");
2574       close DAEMONCMD;                                   # Waits for process
2575       }
2576     }
2577     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2578   return (1, $return_extra);
2579   }
2580
2581
2582 # The "millisleep" command is like "sleep" except that its argument is in
2583 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2584 # is used for.
2585
2586 elsif (/^millisleep\s+(.*)$/)
2587   {
2588   select(undef, undef, undef, $1/1000);
2589   return 0;
2590   }
2591
2592
2593 # The "munge" command selects one of a hardwired set of test-result modifications
2594 # to be made before result compares are run against the golden set.  This lets
2595 # us account for test-system dependent things which only affect a few, but known,
2596 # test-cases.
2597 # Currently only the last munge takes effect.
2598
2599 if (/^munge\s+(.*)$/)
2600   {
2601   return (0, { munge => $1 });
2602   }
2603
2604
2605 # The "sleep" command does just that. For sleeps longer than 1 second we
2606 # tell the user what's going on.
2607
2608 if (/^sleep\s+(.*)$/)
2609   {
2610   if ($1 == 1)
2611     {
2612     sleep(1);
2613     }
2614   else
2615     {
2616     printf("  Test %d sleep $1 ", $$subtestref);
2617     for (1..$1)
2618       {
2619       print ".";
2620       sleep(1);
2621       }
2622     printf("\r  Test %d                            $cr", $$subtestref);
2623     }
2624   return 0;
2625   }
2626
2627
2628 # Various Unix management commands are recognized
2629
2630 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2631     /^sudo\s(mkdir|rmdir|rm|mv|cp|chown|chmod)\s/)
2632   {
2633   run_system("$_ >>test-stdout 2>>test-stderr");
2634   return 1;
2635   }
2636
2637
2638
2639 ###################
2640 ###################
2641
2642 # The next group of commands are also freestanding, but they are all followed
2643 # by data lines.
2644
2645
2646 # The "server" command starts up a script-driven server that runs in parallel
2647 # with the following exim command. Therefore, we want to run a subprocess and
2648 # not yet wait for it to complete. The waiting happens after the next exim
2649 # command, triggered by $server_pid being non-zero. The server sends its output
2650 # to a different file. The variable $server_opts, if not empty, contains
2651 # options to disable IPv4 or IPv6 if necessary.
2652 # This works because "server" swallows its stdin before waiting for a connection.
2653
2654 if (/^server\s+(.*)$/)
2655   {
2656   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2657   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2658   print ">> $cmd\n" if ($debug);
2659   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2660   SERVERCMD->autoflush(1);
2661   print ">> Server pid is $server_pid\n" if $debug;
2662   while (<SCRIPT>)
2663     {
2664     $lineno++;
2665     last if /^\*{4}\s*$/;
2666     print SERVERCMD;
2667     }
2668   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2669                             # because close() waits for the process.
2670
2671   # Interlock the server startup; otherwise the next
2672   # process may not find it there when it expects it.
2673   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2674   return 3;
2675   }
2676
2677
2678 # The "write" command is a way of creating files of specific sizes for
2679 # buffering tests, or containing specific data lines from within the script
2680 # (rather than hold lots of little files). The "catwrite" command does the
2681 # same, but it also copies the lines to test-stdout.
2682
2683 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2684   {
2685   my($cat) = defined $1;
2686   @sizes = ();
2687   @sizes = split /\s+/, $3 if defined $3;
2688   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2689
2690   if ($cat)
2691     {
2692     open CAT, ">>test-stdout" ||
2693       tests_exit(-1, "Failed to open test-stdout: $!");
2694     print CAT "==========\n";
2695     }
2696
2697   if (scalar @sizes > 0)
2698     {
2699     # Pre-data
2700
2701     while (<SCRIPT>)
2702       {
2703       $lineno++;
2704       last if /^\+{4}\s*$/;
2705       print FILE;
2706       print CAT if $cat;
2707       }
2708
2709     # Sized data
2710
2711     while (scalar @sizes > 0)
2712       {
2713       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2714       $leadin = '' if !defined $leadin;
2715       $leadin =~ s/_/ /g;
2716       $len -= length($leadin) + 1;
2717       while ($count-- > 0)
2718         {
2719         print FILE $leadin, "a" x $len, "\n";
2720         print CAT $leadin, "a" x $len, "\n" if $cat;
2721         }
2722       }
2723     }
2724
2725   # Post data, or only data if no sized data
2726
2727   while (<SCRIPT>)
2728     {
2729     $lineno++;
2730     last if /^\*{4}\s*$/;
2731     print FILE;
2732     print CAT if $cat;
2733     }
2734   close FILE;
2735
2736   if ($cat)
2737     {
2738     print CAT "==========\n";
2739     close CAT;
2740     }
2741
2742   return 0;
2743   }
2744
2745
2746 ###################
2747 ###################
2748
2749 # From this point on, script commands are implemented by setting up a shell
2750 # command in the variable $cmd. Shared code to run this command and handle its
2751 # input and output follows.
2752
2753 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2754 # program that plays the part of an email client. We also have the availability
2755 # of running Perl for doing one-off special things. Note that all these
2756 # commands expect stdin data to be supplied.
2757
2758 if (/^client/ || /^(sudo\s+)?perl\b/)
2759   {
2760   s"client"./bin/client";
2761   $cmd = "$_ >>test-stdout 2>>test-stderr";
2762   }
2763
2764 # For the "exim" command, replace the text "exim" with the path for the test
2765 # binary, plus -D options to pass over various parameters, and a -C option for
2766 # the testing configuration file. When running in the test harness, Exim does
2767 # not drop privilege when -C and -D options are present. To run the exim
2768 # command as root, we use sudo.
2769
2770 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2771   {
2772   $args = $6;
2773   my($envset) = (defined $1)? $1      : '';
2774   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2775   my($special)= (defined $5)? $5      : '';
2776   $wait_time  = (defined $2)? $2      : 0;
2777
2778   # Return 2 rather than 1 afterwards
2779
2780   $yield = 2;
2781
2782   # Update the test number
2783
2784   $$subtestref = $$subtestref + 1;
2785   printf("  Test %d       $cr", $$subtestref);
2786
2787   # Copy the configuration file, making the usual substitutions.
2788
2789   open (IN, "$parm_cwd/confs/$testno") ||
2790     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2791   open (OUT, ">test-config") ||
2792     tests_exit(-1, "Couldn't open test-config: $!\n");
2793   while (<IN>)
2794     {
2795     do_substitute($testno);
2796     print OUT;
2797     }
2798   close(IN);
2799   close(OUT);
2800
2801   # The string $msg1 in args substitutes the message id of the first
2802   # message on the queue, and so on. */
2803
2804   if ($args =~ /\$msg/)
2805     {
2806     my($queuespec);
2807     if ($args =~ /-qG\w+/) { $queuespec = $&; }
2808
2809     my @listcmd;
2810
2811     if (defined $queuespec)
2812       {
2813       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2814                    $queuespec,
2815                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2816                    -C => "$parm_cwd/test-config");
2817       }
2818     else
2819       {
2820       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2821                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2822                    -C => "$parm_cwd/test-config");
2823       }
2824     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2825     # We need the message ids sorted in ascending order.
2826     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2827     # PIDs are randomized, so sorting just the whole PID doesn't work.
2828     # We do the Schartz' transformation here (sort on
2829     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2830     my @msglist =
2831       map { $_->[1] }                                   # extract the values
2832       sort { $a->[0] cmp $b->[0] }                      # sort by key
2833       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2834       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2835
2836     # Done backwards just in case there are more than 9
2837
2838     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2839     if ( $args =~ /\$msg\d/ )
2840       {
2841       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2842         unless $force_continue;
2843       }
2844     }
2845
2846   # If -d is specified in $optargs, remove it from $args; i.e. let
2847   # the command line for runtest override. Then run Exim.
2848
2849   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2850
2851   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2852
2853   $cmd = "$envset$sudo$opt_valgrind" .
2854          "$parm_cwd/eximdir/exim$special$optargs " .
2855          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2856          "-C $parm_cwd/test-config $args " .
2857          ">>test-stdout 2>>test-stderr";
2858   # If the command is starting an Exim daemon, we run it in the same
2859   # way as the "server" command above, that is, we don't want to wait
2860   # for the process to finish. That happens when "killdaemon" is obeyed later
2861   # in the script. We also send the stderr output to test-stderr-server. The
2862   # daemon has its log files put in a different place too (by configuring with
2863   # log_file_path). This requires the  directory to be set up in advance.
2864   #
2865   # There are also times when we want to run a non-daemon version of Exim
2866   # (e.g. a queue runner) with the server configuration. In this case,
2867   # we also define -DNOTDAEMON.
2868
2869   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2870     {
2871     if ($debug) { printf ">> daemon: $cmd\n"; }
2872     run_system("sudo mkdir spool/log 2>/dev/null");
2873     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2874
2875     # Before running the command, convert the -bd option into -bdf so that an
2876     # Exim daemon doesn't double fork. This means that when we wait close
2877     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2878     # file is written to the spool directory, in case the Exim binary was
2879     # built with PID_FILE_PATH pointing somewhere else.
2880
2881     if ($cmd =~ /\s-oP\s/)
2882       {
2883       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2884       $cmd =~ s!\s-bd\s! -bdf !;
2885       }
2886     else
2887       {
2888       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2889       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2890       }
2891     print ">> |${cmd}-server\n" if ($debug);
2892     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2893     DAEMONCMD->autoflush(1);
2894     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2895
2896     # Interlock with daemon startup
2897     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2898       { select(undef, undef, undef, 0.3); }
2899     return 3;                                     # Don't wait
2900     }
2901   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2902     {
2903
2904     # The port and the $dynamic_socket was already allocated while parsing the
2905     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2906
2907     my $listen_port = $1;
2908     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2909     run_system("sudo mkdir spool/log 2>/dev/null");
2910     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2911
2912     my $pid = fork();
2913     if (not defined $pid) { die "** fork failed: $!\n" }
2914     if (not $pid) {
2915       close(STDIN);
2916       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2917       close($dynamic_socket);
2918       print "[$$]>> ${cmd}-server\n" if ($debug);
2919       exec "exec ${cmd}-server";
2920       die "Can't exec ${cmd}-server: $!\n";
2921     }
2922     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2923     select(undef, undef, undef, 0.3);             # Let the daemon get going
2924     return (3, { exim_pid => $pid });             # Don't wait
2925     }
2926   }
2927
2928 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2929 # One script line is read and fork-exec'd.  The PID is stored for a later
2930 # killdaemon.
2931
2932 elsif (/^background$/)
2933   {
2934   my $line;
2935 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2936
2937   $_ = <SCRIPT>; $lineno++;
2938   chomp;
2939   do_substitute($testno);
2940   $line = $_;
2941   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2942
2943   my $pid = fork();
2944   if (not defined $pid) { die "** fork failed: $!\n" }
2945   if (not $pid) {
2946     print "[$$]>> ${line}\n" if ($debug);
2947     close(STDIN);
2948     open(STDIN, "<", "test-stdout");
2949     close(STDOUT);
2950     open(STDOUT, ">>", "test-stdout");
2951     close(STDERR);
2952     open(STDERR, ">>", "test-stderr-server");
2953     exec "exec ${line}";
2954     exit(1);
2955   }
2956
2957 #  open(my $fh, ">", $pidfile) ||
2958 #      tests_exit(-1, "Failed to open $pidfile: $!");
2959 #  printf($fh, "%d\n", $pid);
2960 #  close($fh);
2961
2962   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2963   select(undef, undef, undef, 0.3);             # Let the daemon get going
2964   return (3, { exim_pid => $pid });             # Don't wait
2965   }
2966
2967
2968
2969 # Unknown command
2970
2971 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2972
2973
2974 # Run the command, with stdin connected to a pipe, and write the stdin data
2975 # to it, with appropriate substitutions. If a starts with '>>> ', process it
2976 # via Perl's string eval().
2977 # If the command contains
2978 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2979 # for the stderr file. See comment above about the use of -DSERVER.
2980
2981 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2982 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2983 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2984
2985 CMD->autoflush(1);
2986 LINE: while (<SCRIPT>)
2987   {
2988   $lineno++;
2989   last if /^\*{4}\s*$/;
2990   do_substitute($testno);
2991   if (my ($cmd, $line) = /^(:\S+?:)(.*)/) {
2992     $_ = $line;
2993       {
2994       $cmd eq ':eval:' and do {
2995         $_ = eval "\"$_\"";
2996         last;
2997       };
2998       $cmd eq ':noeol:' and do {
2999         s/[\r\n]*$//;
3000         last;
3001       };
3002       $cmd eq ':sleep:' and do {
3003         sleep $_;
3004         next LINE;
3005       };
3006     }
3007   }
3008   print CMD;
3009   }
3010
3011 # For timeout tests, wait before closing the pipe; we expect a
3012 # SIGPIPE error in this case.
3013
3014 if ($wait_time > 0)
3015   {
3016   printf("  Test %d sleep $wait_time ", $$subtestref);
3017   while ($wait_time-- > 0)
3018     {
3019     print ".";
3020     sleep(1);
3021     }
3022   printf("\r  Test %d                                       $cr", $$subtestref);
3023   }
3024
3025 $sigpipehappened = 0;
3026 close CMD;                # Waits for command to finish
3027 return $yield;            # Ran command and waited
3028 }
3029
3030
3031
3032
3033 ###############################################################################
3034 ###############################################################################
3035
3036 ##################################################
3037 #    Check for SpamAssassin and ClamAV           #
3038 ##################################################
3039
3040 # These are crude tests. If they aren't good enough, we'll have to improve
3041 # them, for example by actually passing a message through spamc or clamscan.
3042
3043 sub check_running_spamassassin
3044 {
3045 my $sock = new FileHandle;
3046
3047 if (system("spamc -h 2>/dev/null >/dev/null") == 0)
3048   {
3049   print "The spamc command works:\n";
3050
3051   # This test for an active SpamAssassin is courtesy of John Jetmore.
3052   # The tests are hard coded to localhost:783, so no point in making
3053   # this test flexible like the clamav test until the test scripts are
3054   # changed.  spamd doesn't have the nice PING/PONG protocol that
3055   # clamd does, but it does respond to errors in an informative manner,
3056   # so use that.
3057
3058   my($sint,$sport) = ('127.0.0.1',783);
3059   eval
3060     {
3061     my $sin = sockaddr_in($sport, inet_aton($sint))
3062         or die "** Failed packing $sint:$sport\n";
3063     socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3064         or die "** Unable to open socket $sint:$sport\n";
3065
3066     local $SIG{ALRM} =
3067         sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3068     alarm(5);
3069     connect($sock, $sin)
3070         or die "** Unable to connect to socket $sint:$sport\n";
3071     alarm(0);
3072
3073     select((select($sock), $| = 1)[0]);
3074     print $sock "bad command\r\n";
3075
3076     $SIG{ALRM} =
3077         sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3078     alarm(10);
3079     my $res = <$sock>;
3080     alarm(0);
3081
3082     $res =~ m|^SPAMD/|
3083         or die "** Did not get SPAMD from socket $sint:$sport. "
3084               ."It said: $res\n";
3085     };
3086   alarm(0);
3087   if($@)
3088     {
3089     print "  $@";
3090     print "  Assume SpamAssassin (spamd) is not running\n";
3091     }
3092   else
3093     {
3094     $parm_running{SpamAssassin} = ' ';
3095     print "  SpamAssassin (spamd) seems to be running\n";
3096     }
3097   }
3098 else
3099   {
3100   print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3101   }
3102 }
3103
3104 sub check_running_clamav
3105 {
3106 my $sock;
3107
3108 # For ClamAV, we need to find the clamd socket for use in the Exim
3109 # configuration. Search for the clamd configuration file.
3110
3111 if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3112   {
3113   my($f, $clamconf, $test_prefix);
3114
3115   print "The clamscan command works";
3116
3117   $test_prefix = $ENV{EXIM_TEST_PREFIX};
3118   $test_prefix = '' if !defined $test_prefix;
3119
3120   foreach $f ("$test_prefix/etc/clamd.conf",
3121               "$test_prefix/usr/local/etc/clamd.conf",
3122               "$test_prefix/etc/clamav/clamd.conf", '')
3123     {
3124     if (-e $f)
3125       {
3126       $clamconf = $f;
3127       last;
3128       }
3129     }
3130
3131   # Read the ClamAV configuration file and find the socket interface.
3132
3133   if ($clamconf ne '')
3134     {
3135     my $socket_domain;
3136     open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3137     while (<IN>)
3138       {
3139       if (/^LocalSocket\s+(.*)/)
3140         {
3141         $parm_clamsocket = $1;
3142         $socket_domain = AF_UNIX;
3143         last;
3144         }
3145       if (/^TCPSocket\s+(\d+)/)
3146         {
3147         if (defined $parm_clamsocket)
3148           {
3149           $parm_clamsocket .= " $1";
3150           $socket_domain = AF_INET;
3151           last;
3152           }
3153         else
3154           {
3155           $parm_clamsocket = " $1";
3156           }
3157         }
3158       elsif (/^TCPAddr\s+(\S+)/)
3159         {
3160         if (defined $parm_clamsocket)
3161           {
3162           $parm_clamsocket = $1 . $parm_clamsocket;
3163           $socket_domain = AF_INET;
3164           last;
3165           }
3166         else
3167           {
3168           $parm_clamsocket = $1;
3169           }
3170         }
3171       }
3172     close(IN);
3173
3174     if (defined $socket_domain)
3175       {
3176       print ":\n  The clamd socket is $parm_clamsocket\n";
3177       # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3178       eval
3179         {
3180         my $socket;
3181         if ($socket_domain == AF_UNIX)
3182           {
3183           $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3184           }
3185         elsif ($socket_domain == AF_INET)
3186           {
3187           my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3188           my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3189           $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3190           }
3191         else
3192           {
3193           die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3194           }
3195         socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3196         local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3197         alarm(5);
3198         connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3199         alarm(0);
3200
3201         my $ofh = select $sock; $| = 1; select $ofh;
3202         print $sock "PING\n";
3203
3204         $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3205         alarm(10);
3206         my $res = <$sock>;
3207         alarm(0);
3208
3209         $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3210         };
3211       alarm(0);
3212
3213       if($@)
3214         {
3215         print "  $@";
3216         print "  Assume ClamAV is not running\n";
3217         }
3218       else
3219         {
3220         $parm_running{ClamAV} = ' ';
3221         print "  ClamAV seems to be running\n";
3222         }
3223       }
3224     else
3225       {
3226       print ", but the socket for clamd could not be determined\n";
3227       print "Assume ClamAV is not running\n";
3228       }
3229     }
3230
3231   else
3232     {
3233     print ", but I can't find a configuration for clamd\n";
3234     print "Assume ClamAV is not running\n";
3235     }
3236   }
3237 }
3238
3239
3240 sub check_running_redis
3241 {
3242 if (defined $parm_lookups{redis})
3243   {
3244   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3245     {
3246     print "The redis-server command works\n";
3247     $parm_running{redis} = ' ';
3248     }
3249   else
3250     {
3251     print "The redis-server command failed: assume Redis not installed\n";
3252     }
3253   }
3254 }
3255
3256 sub check_running_dovecot
3257 {
3258 system('dovecot --version >/dev/null');
3259 if ($? == 0)
3260   {
3261   print "Dovecot appears to be available\n";
3262   $parm_running{dovecot} = ' ';
3263   }
3264 else
3265   {
3266   print "Dovecot not found\n";
3267   }
3268 }
3269
3270
3271
3272 ###############################################################################
3273 ###############################################################################
3274
3275 # Here begins the Main Program ...
3276
3277 ###############################################################################
3278 ###############################################################################
3279
3280
3281 autoflush STDOUT 1;
3282 print "Exim tester $testversion\n";
3283
3284 # extend the PATH with .../sbin
3285 # we map all (.../bin) to (.../sbin:.../bin)
3286 $ENV{PATH} = do {
3287   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
3288   join ':' => map { m{(.*)/bin$}
3289                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
3290                 : ($_) }
3291       split /:/, $ENV{PATH};
3292 };
3293
3294 ##################################################
3295 #      Some tests check created file modes       #
3296 ##################################################
3297
3298 umask 022;
3299
3300
3301 ##################################################
3302 #       Check for the "less" command             #
3303 ##################################################
3304
3305 @more = 'more' if system('which less >/dev/null 2>&1') != 0;
3306
3307
3308
3309 ##################################################
3310 #      See if an Exim binary has been given      #
3311 ##################################################
3312
3313 # If the first character of the first argument is '/', the argument is taken
3314 # as the path to the binary. If the first argument does not start with a
3315 # '/' but exists in the file system, it's assumed to be the Exim binary.
3316
3317
3318 ##################################################
3319 # Sort out options and which tests are to be run #
3320 ##################################################
3321
3322 # There are a few possible options for the test script itself; after these, any
3323 # options are passed on to Exim calls within the tests. Typically, this is used
3324 # to turn on Exim debugging while setting up a test.
3325
3326 Getopt::Long::Configure qw(no_getopt_compat);
3327 GetOptions(
3328     'debug'    => sub { $debug          = 1; $cr   = "\n" },
3329     'diff'     => sub { $cf             = 'diff -u' },
3330     'continue' => sub { $force_continue = 1; @more = 'cat' },
3331     'update'   => \$force_update,
3332     'ipv4!'    => \$have_ipv4,
3333     'ipv6!'    => \$have_ipv6,
3334     'keep'     => \$save_output,
3335     'slow'     => \$slow,
3336     'valgrind' => \$valgrind,
3337     'range=s{2}'       => \my @range_wanted,
3338     'test=i@'          => \my @tests_wanted,
3339     'fail-any!'        => \my $fail_any,
3340     'flavor|flavour=s' => \$flavour,
3341     'help'             => sub { pod2usage(-exit => 0) },
3342     'man'              => sub {
3343         pod2usage(
3344             -exit      => 0,
3345             -verbose   => 2,
3346             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
3347         );
3348     },
3349 ) or pod2usage;
3350
3351 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
3352 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
3353
3354
3355 my @wanted = sort numerically uniq
3356   @tests_wanted ? @tests_wanted : (),
3357   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
3358   @ARGV ? @ARGV == 1 ? $ARGV[0] :
3359           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
3360           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
3361         : ();
3362 @wanted = 1..TEST_TOP if not @wanted;
3363
3364 ##################################################
3365 #        Check for sudo access to root           #
3366 ##################################################
3367
3368 print "You need to have sudo access to root to run these tests. Checking ...\n";
3369 if (system('sudo true >/dev/null') != 0)
3370   {
3371   die "** Test for sudo failed: testing abandoned.\n";
3372   }
3373 else
3374   {
3375   print "Test for sudo OK\n";
3376   }
3377
3378
3379
3380
3381 ##################################################
3382 #      Make the command's directory current      #
3383 ##################################################
3384
3385 # After doing so, we find its absolute path name.
3386
3387 $cwd = $0;
3388 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
3389 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
3390 $parm_cwd = Cwd::getcwd();
3391
3392
3393 ##################################################
3394 #     Search for an Exim binary to test          #
3395 ##################################################
3396
3397 # If an Exim binary hasn't been provided, try to find one. We can handle the
3398 # case where exim-testsuite is installed alongside Exim source directories. For
3399 # PH's private convenience, if there's a directory just called "exim4", that
3400 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
3401 # releases.
3402
3403 # If $parm_exim is still empty, ask the caller
3404
3405 if (not $parm_exim)
3406   {
3407   print "** Did not find an Exim binary to test\n";
3408   for ($i = 0; $i < 5; $i++)
3409     {
3410     my($trybin);
3411     print "** Enter pathname for Exim binary: ";
3412     chomp($trybin = <STDIN>);
3413     if (-e $trybin)
3414       {
3415       $parm_exim = $trybin;
3416       last;
3417       }
3418     else
3419       {
3420       print "** $trybin does not exist\n";
3421       }
3422     }
3423   die "** Too many tries\n" if $parm_exim eq '';
3424   }
3425
3426
3427
3428 ##################################################
3429 #          Find what is in the binary            #
3430 ##################################################
3431
3432 # deal with TRUSTED_CONFIG_LIST restrictions
3433 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
3434 open (IN, "$parm_cwd/confs/0000") ||
3435   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3436 open (OUT, ">test-config") ||
3437   tests_exit(-1, "Couldn't open test-config: $!\n");
3438 while (<IN>) { print OUT; }
3439 close(IN);
3440 close(OUT);
3441
3442 print("Probing with config file: $parm_cwd/test-config\n");
3443
3444 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
3445 chomp(my @eximinfo = `$eximinfo 2>&1`);
3446 die "$0: Can't run $eximinfo\n" if $? == -1;
3447
3448 warn 'Got ' . ($?>>8) . " from $eximinfo\n" if $?;
3449 foreach (@eximinfo)
3450   {
3451   if (my ($version) = /^Exim version (\S+)/) {
3452     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
3453     if (defined $git and $? == 0) {
3454       chomp $git;
3455       $git =~ s/^exim-//i;
3456       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
3457       print <<___
3458
3459 *** Version mismatch
3460 *** Exim binary: $version
3461 *** Git        : $git
3462
3463 ___
3464         if not $version eq $git;
3465     }
3466   }
3467   $parm_eximuser = $1 if /^exim_user = (.*)$/;
3468   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
3469   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
3470   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
3471         if /^Configure owner:\s*(\d+):(\d+)/;
3472   print if /wrong owner/;
3473   }
3474
3475 if (not defined $parm_eximuser) {
3476   die <<XXX, map { "|$_\n" } @eximinfo;
3477 Unable to extract exim_user from binary.
3478 Check if Exim refused to run; if so, consider:
3479   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
3480 If debug permission denied, are you in the exim group?
3481 Failing to get information from binary.
3482 Output from $eximinfo:
3483 XXX
3484
3485 }
3486
3487 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
3488 else { $parm_exim_uid = getpwnam($parm_eximuser); }
3489
3490 if (defined $parm_eximgroup)
3491   {
3492   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
3493     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
3494   }
3495
3496 # check the permissions on the TRUSTED_CONFIG_LIST
3497 if (defined $parm_trusted_config_list)
3498   {
3499   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
3500     if not -f $parm_trusted_config_list;
3501
3502   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
3503     if 02 & (stat _)[2];
3504
3505   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
3506   (stat _)[1],
3507     scalar(getgrgid 0), scalar(getgrgid $>)
3508     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
3509
3510   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
3511   scalar(getpwuid 0), scalar(getpwuid $>)
3512      if (not (-o _ or (stat _)[4] == 0));
3513
3514   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
3515   my $test_config = getcwd() . '/test-config';
3516   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
3517     if not grep { /^\Q$test_config\E$/ } <TCL>;
3518   }
3519 else
3520   {
3521   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
3522   }
3523
3524 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
3525         if $parm_configure_owner != $>;
3526
3527 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
3528         if 0020 & (stat "$parm_cwd/test-config")[2]
3529         and $parm_configure_group != $);
3530
3531 die "aux-fixed file is group-writeable; best to strip them all, recursively\n"
3532         if 0020 & (stat "aux-fixed/0037.f-1")[2];
3533
3534
3535 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
3536   die "** Cannot run $parm_exim: $!\n";
3537
3538 print "-" x 78, "\n";
3539
3540 while (<EXIMINFO>)
3541   {
3542   my(@temp);
3543
3544   if (/^(Exim|Library) version/) { print; }
3545   if (/Runtime: /) {print; }
3546
3547   elsif (/^Size of off_t: (\d+)/)
3548     {
3549     print;
3550     $have_largefiles = 1 if $1 > 4;
3551     die "** Size of off_t > 32 which seems improbable, not running tests\n"
3552         if ($1 > 32);
3553     }
3554
3555   elsif (/^Support for: (.*)/)
3556     {
3557     print;
3558     @temp = split /(\s+)/, $1;
3559     push(@temp, ' ');
3560     %parm_support = @temp;
3561     }
3562
3563   elsif (/^Lookups \(built-in\): (.*)/)
3564     {
3565     print;
3566     @temp = split /(\s+)/, $1;
3567     push(@temp, ' ');
3568     %parm_lookups = @temp;
3569     }
3570
3571   elsif (/^Authenticators: (.*)/)
3572     {
3573     print;
3574     @temp = split /(\s+)/, $1;
3575     push(@temp, ' ');
3576     %parm_authenticators = @temp;
3577     }
3578
3579   elsif (/^Routers: (.*)/)
3580     {
3581     print;
3582     @temp = split /(\s+)/, $1;
3583     push(@temp, ' ');
3584     %parm_routers = @temp;
3585     }
3586
3587   # Some transports have options, e.g. appendfile/maildir. For those, ensure
3588   # that the basic transport name is set, and then the name with each of the
3589   # options.
3590
3591   elsif (/^Transports: (.*)/)
3592     {
3593     print;
3594     @temp = split /(\s+)/, $1;
3595     my($i,$k);
3596     push(@temp, ' ');
3597     %parm_transports = @temp;
3598     foreach $k (keys %parm_transports)
3599       {
3600       if ($k =~ "/")
3601         {
3602         @temp = split /\//, $k;
3603         $parm_transports{$temp[0]} = " ";
3604         for ($i = 1; $i < @temp; $i++)
3605           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
3606         }
3607       }
3608     }
3609
3610   elsif (/^Malware: (.*)/)
3611     {
3612     print;
3613     @temp = split /(\s+)/, $1;
3614     push(@temp, ' ');
3615     %parm_malware = @temp;
3616     }
3617
3618   }
3619 close(EXIMINFO);
3620 print "-" x 78, "\n";
3621
3622 unlink("$parm_cwd/test-config");
3623
3624
3625
3626 if (defined $parm_support{Content_Scanning})
3627   {
3628   check_running_spamassassin();
3629   check_running_clamav();
3630   }
3631 check_running_redis();
3632 check_running_dovecot();
3633
3634 ##################################################
3635 #         Test for the basic requirements        #
3636 ##################################################
3637
3638 # This test suite assumes that Exim has been built with at least the "usual"
3639 # set of routers, transports, and lookups. Ensure that this is so.
3640
3641 $missing = '';
3642
3643 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3644
3645 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3646 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3647 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3648 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3649
3650 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3651 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3652 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3653 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3654
3655 if ($missing ne '')
3656   {
3657   print "\n";
3658   print "** Many features can be included or excluded from Exim binaries.\n";
3659   print "** This test suite requires that Exim is built to contain a certain\n";
3660   print "** set of basic facilities. It seems that some of these are missing\n";
3661   print "** from the binary that is under test, so the test cannot proceed.\n";
3662   print "** The missing facilities are:\n";
3663   print "$missing";
3664   die "** Test script abandoned\n";
3665   }
3666
3667
3668 ##################################################
3669 #      Check for the auxiliary programs          #
3670 ##################################################
3671
3672 # These are always required:
3673
3674 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3675            "fakens", "iefbr14", "server")
3676   {
3677   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3678   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3679   if (!-e "bin/$prog")
3680     {
3681     print "\n";
3682     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3683     die "** Test script abandoned\n";
3684     }
3685   }
3686
3687 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3688 # compiled on systems where we don't know how to. However, if Exim does not
3689 # have that functionality compiled, we needn't bother.
3690
3691 $dlfunc_deleted = 0;
3692 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3693   {
3694   delete $parm_support{Expand_dlfunc};
3695   $dlfunc_deleted = 1;
3696   }
3697
3698
3699 ##################################################
3700 #          Find environmental details            #
3701 ##################################################
3702
3703 # Find the caller of this program.
3704
3705 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3706  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3707
3708 $pwpw = $pwpw;       # Kill Perl warnings
3709 $pwquota = $pwquota;
3710 $pwcomm = $pwcomm;
3711
3712 $parm_caller_group = getgrgid($parm_caller_gid);
3713
3714 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3715 print "Home directory is $parm_caller_home\n";
3716
3717 unless (defined $parm_eximgroup)
3718   {
3719   print "Unable to derive \$parm_eximgroup.\n";
3720   die "** ABANDONING.\n";
3721   }
3722
3723 if ($parm_caller_home eq $parm_cwd)
3724   {
3725   print "will confuse working dir with homedir; change homedir\n";
3726   die "** ABANDONING.\n";
3727   }
3728
3729 print "You need to be in the Exim group to run these tests. Checking ...";
3730
3731 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3732   {
3733   print " OK\n";
3734   }
3735 else
3736   {
3737   print "\nOh dear, you are not in the Exim group.\n";
3738   die "** Testing abandoned.\n";
3739   }
3740
3741 # Find this host's IP addresses - there may be many, of course, but we keep
3742 # one of each type (IPv4 and IPv6).
3743 #XXX it would be good to avoid non-UP interfaces
3744
3745 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3746   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3747 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3748   {
3749   if (/^(?:[0-9]+: )?([a-z0-9]+): /) { $ifname = $1; }
3750
3751   if (not $parm_ipv4 and /^\s*inet(?:\saddr(?:ess))?:?\s*(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3752     {
3753     # It would be nice to be able to vary the /16 used for manyhome; we could take
3754     # an option to runtest used here - but we'd also have to pass it on to fakens.
3755     # Possibly an environment variable?
3756     next if $1 eq '0.0.0.0' or $1 =~ /^(?:127|10\.250)\./;
3757     $parm_ipv4 = $1;
3758     }
3759
3760   if (   (not $parm_ipv6 or $parm_ipv6 =~ /%/)
3761      and /^\s*inet6(?:\saddr(?:ess))?:?\s*([abcdef\d:]+)(?:%[^ \/]+)?(?:\/\d+)?/i)
3762     {
3763     next if $1 eq '::' or $1 eq '::1' or $1 =~ /^ff00/i or $1 =~ /^fe80::1/i;
3764     $parm_ipv6 = $1;
3765     if ($1 =~ /^fe80/i) { $parm_ipv6 .= '%' . $ifname; }
3766     }
3767   }
3768 close(IFCONFIG);
3769
3770 # Use private IP addresses if there are no public ones.
3771
3772 # If either type of IP address is missing, we need to set the value to
3773 # something other than empty, because that wrecks the substitutions. The value
3774 # is reflected, so use a meaningful string. Set appropriate options for the
3775 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3776 # available, so things will go wrong if there is no IPv4 address. The lack
3777 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3778 # and $have_ipv6 false.
3779
3780 if (not $parm_ipv4)
3781   {
3782   $have_ipv4 = 0;
3783   $parm_ipv4 = "<no IPv4 address found>";
3784   $server_opts .= " -noipv4";
3785   }
3786 elsif ($have_ipv4 == 0)
3787   {
3788   $parm_ipv4 = "<IPv4 testing disabled>";
3789   $server_opts .= " -noipv4";
3790   }
3791 else
3792   {
3793   $parm_running{IPv4} = " ";
3794   }
3795
3796 if (not $parm_ipv6)
3797   {
3798   $have_ipv6 = 0;
3799   $parm_ipv6 = "<no IPv6 address found>";
3800   $server_opts .= " -noipv6";
3801   delete($parm_support{IPv6});
3802   }
3803 elsif ($have_ipv6 == 0)
3804   {
3805   $parm_ipv6 = "<IPv6 testing disabled>";
3806   $server_opts .= " -noipv6";
3807   delete($parm_support{IPv6});
3808   }
3809 elsif (!defined $parm_support{IPv6})
3810   {
3811   $have_ipv6 = 0;
3812   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3813   $server_opts .= " -noipv6";
3814   }
3815 else
3816   {
3817   $parm_running{IPv6} = " ";
3818   }
3819
3820 print "IPv4 address is $parm_ipv4\n";
3821 print "IPv6 address is $parm_ipv6\n";
3822 $parm_ipv6 =~ /^[^%\/]*/;
3823 # drop any %scope from the ipv6, for some uses
3824 ($parm_ipv6_stripped = $parm_ipv6) =~ s/%.*//g;
3825
3826 # For munging test output, we need the reversed IP addresses.
3827
3828 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3829   join(".", reverse(split /\./, $parm_ipv4));
3830
3831 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3832 if ($parm_ipv6 =~ /^[\da-f]/)
3833   {
3834   my(@comps) = split /:/, $parm_ipv6_stripped;
3835   my(@nibbles);
3836   foreach $comp (@comps)
3837     {
3838     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3839     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3840     }
3841   $parm_ipv6r = join(".", reverse(@nibbles));
3842   }
3843
3844 # Find the host name, fully qualified.
3845
3846 chomp($temp = `hostname`);
3847 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3848 if ($temp =~ /\./)
3849   {
3850   $parm_hostname = $temp;
3851   }
3852 else
3853   {
3854   $parm_hostname = (gethostbyname($temp))[0];
3855   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3856   }
3857 print "Hostname is $parm_hostname\n";
3858
3859 if ($parm_hostname !~ /\./)
3860   {
3861   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3862   }
3863
3864 if ($parm_hostname =~ /[[:upper:]]/)
3865   {
3866   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3867   }
3868
3869 if ($parm_hostname =~ /\.example\.com$/)
3870   {
3871   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3872         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3873   }
3874
3875
3876
3877 ##################################################
3878 #     Create a testing version of Exim           #
3879 ##################################################
3880
3881 # We want to be able to run Exim with a variety of configurations. Normally,
3882 # the use of -C to change configuration causes Exim to give up its root
3883 # privilege (unless the caller is exim or root). For these tests, we do not
3884 # want this to happen. Also, we want Exim to know that it is running in its
3885 # test harness.
3886
3887 # We achieve this by copying the binary and patching it as we go. The new
3888 # binary knows it is a testing copy, and it allows -C and -D without loss of
3889 # privilege. Clearly, this file is dangerous to have lying around on systems
3890 # where there are general users with login accounts. To protect against this,
3891 # we put the new binary in a special directory that is accessible only to the
3892 # caller of this script, who is known to have sudo root privilege from the test
3893 # that was done above. Furthermore, we ensure that the binary is deleted at the
3894 # end of the test. First ensure the directory exists.
3895
3896 if (-d "eximdir")
3897   { unlink "eximdir/exim"; }     # Just in case
3898 else
3899   {
3900   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3901   system("sudo chgrp $parm_eximgroup eximdir");
3902   }
3903
3904 # The construction of the patched binary must be done as root, so we use
3905 # a separate script. As well as indicating that this is a test-harness binary,
3906 # the version number is patched to "x.yz" so that its length is always the
3907 # same. Otherwise, when it appears in Received: headers, it affects the length
3908 # of the message, which breaks certain comparisons.
3909
3910 die "** Unable to make patched exim: $!\n"
3911   if (system("sudo ./patchexim $parm_exim") != 0);
3912
3913 # From this point on, exits from the program must go via the subroutine
3914 # tests_exit(), so that suitable cleaning up can be done when required.
3915 # Arrange to catch interrupting signals, to assist with this.
3916
3917 $SIG{INT} = \&inthandler;
3918 $SIG{PIPE} = \&pipehandler;
3919
3920 # For some tests, we need another copy of the binary that is setuid exim rather
3921 # than root.
3922
3923 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3924        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3925        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3926        "sudo chmod 06755 eximdir/exim_exim");
3927
3928 ##################################################
3929 #     Make copies of utilities we might need     #
3930 ##################################################
3931
3932 # Certain of the tests make use of some of Exim's utilities. We do not need
3933 # to be root to copy these.
3934
3935 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3936
3937 $dbm_build_deleted = 0;
3938 if (defined $parm_lookups{dbm} && not cp("$parm_exim_dir/exim_dbmbuild", "eximdir/exim_dbmbuild"))
3939   {
3940   delete $parm_lookups{dbm};
3941   $dbm_build_deleted = 1;
3942   }
3943
3944 foreach my $tool (qw(exim_dumpdb exim_lock exinext exigrep eximstats exiqgrep exim_msgdate exim_id_update)) {
3945   cp("$parm_exim_dir/$tool" => "eximdir/$tool")
3946     or tests_exit(-1, "Failed to make a copy of $tool: $!");
3947 }
3948
3949 # Collect some version information
3950 print '-' x 78, "\n";
3951 print "Perl version for runtest: $]\n";
3952 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats exiqgrep exim_msgdate)) {
3953   # fold (or unfold?) multiline output into a one-liner
3954   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3955 }
3956 print '-' x 78, "\n";
3957
3958
3959 ##################################################
3960 #    Check that the Exim user can access stuff   #
3961 ##################################################
3962
3963 # We delay this test till here so that we can check access to the actual test
3964 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3965
3966 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3967 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3968
3969 if ($parm_caller_uid eq $parm_exim_uid) {
3970   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3971                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3972 }
3973 if ($parm_caller_gid eq $parm_exim_gid) {
3974   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3975                 ."the same as caller's ($parm_caller) group as it confuses "
3976                 ."results analysis");
3977 }
3978
3979 print "The Exim user needs access to the test suite directory. Checking ...";
3980
3981 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3982   {
3983   my($why) = "unknown failure $rc";
3984   $rc >>= 8;
3985   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3986   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3987   $why = "Couldn't read auxiliary group list" if $rc == 3;
3988   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3989   $why = "Couldn't set gid" if $rc == 5;
3990   $why = "Couldn't set uid" if $rc == 6;
3991   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3992   print "\n** $why\n";
3993   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3994   }
3995 else
3996   {
3997   print " OK\n";
3998   }
3999
4000 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
4001   if not unlink($log_summary_filename) and -e $log_summary_filename;
4002
4003 ##################################################
4004 #        Create a list of available tests        #
4005 ##################################################
4006
4007 # The scripts directory contains a number of subdirectories whose names are
4008 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
4009 # from the first requires certain optional features to be included in the Exim
4010 # binary. These requirements are contained in a file called "REQUIRES" within
4011 # the directory. We scan all these tests, discarding those that cannot be run
4012 # because the current binary does not support the right facilities, and also
4013 # those that are outside the numerical range selected.
4014
4015 printf "\nWill run %d tests between %d and %d for flavour %s\n",
4016   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
4017
4018 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
4019   if $dlfunc_deleted;
4020 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
4021   if $dbm_build_deleted;
4022
4023
4024 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
4025   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
4026
4027 # Scan for relevant tests
4028 # HS12: Needs to be reworked.
4029 DIR: for (my $i = 0; $i < @test_dirs; $i++)
4030   {
4031   my($testdir) = $test_dirs[$i];
4032   my($wantthis) = 1;
4033
4034   print ">>Checking $testdir\n" if $debug;
4035
4036   # Skip this directory if the first test is equal or greater than the first
4037   # test in the next directory.
4038
4039   next DIR if ($i < @test_dirs - 1) &&
4040           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
4041
4042   # No need to carry on if the end test is less than the first test in this
4043   # subdirectory.
4044
4045   last DIR if $wanted[-1] < substr($testdir, 0, 4);
4046
4047   # Check requirements, if any.
4048
4049   if (open(my $requires, "scripts/$testdir/REQUIRES"))
4050     {
4051     while (<$requires>)
4052       {
4053       next if /^\s*$/;
4054       s/\s+$//;
4055       if (/^support (.*)$/)
4056         {
4057         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
4058         }
4059       elsif (/^running (.*)$/)
4060         {
4061         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
4062         }
4063       elsif (/^lookup (.*)$/)
4064         {
4065         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
4066         }
4067       elsif (/^authenticators? (.*)$/)
4068         {
4069         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
4070         }
4071       elsif (/^router (.*)$/)
4072         {
4073         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
4074         }
4075       elsif (/^transport (.*)$/)
4076         {
4077         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
4078         }
4079       elsif (/^malware (.*)$/)
4080         {
4081         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
4082         }
4083       elsif (/^(not )?feature (.*)$/)
4084         {
4085         # move to a subroutine?
4086         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $2";
4087
4088         open (IN, "$parm_cwd/confs/0000") ||
4089           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
4090         open (OUT, ">test-config") ||
4091           tests_exit(-1, "Couldn't open test-config: $!\n");
4092         while (<IN>)
4093           {
4094           do_substitute($testno);
4095           print OUT;
4096           }
4097         close(IN);
4098         close(OUT);
4099
4100         system($eximinfo . " >/dev/null 2>&1");
4101         if (!defined $1 && $? != 0 || defined $1 && $? == 0) {
4102           $wantthis = 0;
4103           unlink("$parm_cwd/test-config");
4104           $_ = $1 || "" . "feature $2";
4105           last;
4106         }
4107         unlink("$parm_cwd/test-config");
4108         }
4109       elsif (/^ipv6-non-linklocal/)
4110         {
4111         if ($parm_ipv6 =~ /%/) { $wantthis = 0; last; }
4112         }
4113       else
4114         {
4115         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
4116         }
4117       }
4118     }
4119   else
4120     {
4121     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
4122       unless $!{ENOENT};
4123     }
4124
4125   # Loop if we do not want the tests in this subdirectory.
4126
4127   if (!$wantthis)
4128     {
4129     chomp;
4130     print "Omitting tests in $testdir (missing $_)\n";
4131     }
4132
4133   # We want the tests from this subdirectory, provided they are in the
4134   # range that was selected.
4135
4136   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
4137   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
4138     if not @testlist;
4139
4140   foreach $test (@testlist)
4141     {
4142     if (!$wantthis)
4143       {
4144       log_test($log_summary_filename, $test, '.');
4145       }
4146     else
4147       {
4148       push @test_list, "$testdir/$test";
4149       }
4150     }
4151   }
4152
4153 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
4154
4155
4156 ##################################################
4157 #         Munge variable auxiliary data          #
4158 ##################################################
4159
4160 # Some of the auxiliary data files have to refer to the current testing
4161 # directory and other parameter data. The generic versions of these files are
4162 # stored in the aux-var-src directory. At this point, we copy each of them
4163 # to the aux-var directory, making appropriate substitutions. There aren't very
4164 # many of them, so it's easiest just to do this every time. Ensure the mode
4165 # is standardized, as this path is used as a test for the ${stat: expansion.
4166
4167 # A similar job has to be done for the files in the dnszones-src directory, to
4168 # make the fake DNS zones for testing. Most of the zone files are copied to
4169 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
4170 # networks that are defined by parameter.
4171
4172 foreach $basedir ("aux-var", "dnszones")
4173   {
4174   system("sudo rm -rf $parm_cwd/$basedir");
4175   mkdir("$parm_cwd/$basedir", 0777);
4176   chmod(0755, "$parm_cwd/$basedir");
4177
4178   opendir(AUX, "$parm_cwd/$basedir-src") ||
4179     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
4180   my(@filelist) = readdir(AUX);
4181   close(AUX);
4182
4183   foreach $file (@filelist)
4184     {
4185     my($outfile) = $file;
4186     next if $file =~ /^\./;
4187
4188     if ($file eq "db.ip4.V4NET")
4189       {
4190       $outfile = "db.ip4.$parm_ipv4_test_net";
4191       }
4192     elsif ($file eq "db.ip6.V6NET")
4193       {
4194       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
4195       $" = '.';
4196       $outfile = "db.ip6.@nibbles";
4197       $" = ' ';
4198       }
4199
4200     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
4201     open(IN, "$parm_cwd/$basedir-src/$file") ||
4202       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
4203     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
4204       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
4205     while (<IN>)
4206       {
4207       do_substitute(0);
4208       print OUT;
4209       }
4210     close(IN);
4211     close(OUT);
4212     }
4213   }
4214
4215 # Set a user's shell, distinguishable from /bin/sh
4216
4217 symlink('/bin/sh' => 'aux-var/sh');
4218 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
4219
4220 ##################################################
4221 #     Create fake DNS zones for this host        #
4222 ##################################################
4223
4224 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
4225 # sure that there are forward and reverse registrations for this host, using
4226 # its real IP addresses. Dynamically created zone files achieve this.
4227
4228 if ($have_ipv4 || $have_ipv6)
4229   {
4230   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
4231   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
4232     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
4233   print OUT "; This is a dynamically constructed fake zone file.\n" .
4234     "; The following line causes fakens to return PASS_ON\n" .
4235     "; for queries that it cannot answer\n\n" .
4236     "PASS ON NOT FOUND\n\n";
4237   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
4238   print OUT "$shortname  AAAA  $parm_ipv6_stripped\n" if $have_ipv6;
4239   print OUT "\n; End\n";
4240   close(OUT);
4241   }
4242
4243 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
4244   {
4245   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
4246
4247   if ($components[0]=='10')
4248     {
4249     open(OUT, ">>$parm_cwd/dnszones/db.ip4.$components[0]") ||
4250       tests_exit(-1, "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4251     print OUT "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n";
4252     close(OUT);
4253     }
4254   else
4255     {
4256     open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
4257       tests_exit(-1,
4258         "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4259     print OUT "; This is a dynamically constructed fake zone file.\n" .
4260       "; The zone is $components[0].in-addr.arpa.\n\n" .
4261       "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
4262       "; End\n";
4263     close(OUT);
4264     }
4265   }
4266
4267 if ($have_ipv6 && $parm_ipv6_stripped ne "::1")
4268   {
4269   my($exp_v6) = $parm_ipv6_stripped;
4270   $exp_v6 =~ s/[^:]//g;
4271   if ( $parm_ipv6_stripped =~ /^([^:].+)::$/ ) {
4272     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
4273   } elsif ( $parm_ipv6_stripped =~ /^(.+)::(.+)$/ ) {
4274     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
4275   } elsif ( $parm_ipv6_stripped =~ /^::(.+[^:])$/ ) {
4276     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
4277   } else {
4278     $exp_v6 = $parm_ipv6_stripped;
4279   }
4280   my(@components) = split /:/, $exp_v6;
4281   my(@nibbles) = reverse (split /\s*/, shift @components);
4282   my($sep) =  '';
4283
4284   $" = ".";
4285   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
4286     tests_exit(-1,
4287       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
4288   print OUT "; This is a dynamically constructed fake zone file.\n" .
4289     "; The zone is @nibbles.ip6.arpa.\n\n";
4290
4291   @components = reverse @components;
4292   foreach $c (@components)
4293     {
4294     $c = "0$c" until $c =~ /^..../;
4295     @nibbles = reverse(split /\s*/, $c);
4296     print OUT "$sep@nibbles";
4297     $sep = ".";
4298     }
4299
4300   print OUT "  PTR  $parm_hostname.\n\n; End\n";
4301   close(OUT);
4302   $" = " ";
4303   }
4304
4305
4306
4307 ##################################################
4308 #    Create lists of mailboxes and message logs  #
4309 ##################################################
4310
4311 # We use these lists to check that a test has created the expected files. It
4312 # should be faster than looking for the file each time. For mailboxes, we have
4313 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
4314 # is just a flat list of files.
4315
4316 @oldmails = list_files_below("mail");
4317 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
4318 @oldmsglogs = readdir(DIR);
4319 closedir(DIR);
4320
4321
4322
4323 ##################################################
4324 #         Run the required tests                 #
4325 ##################################################
4326
4327 # Each test script contains a number of tests, separated by a line that
4328 # contains ****. We open input from the terminal so that we can read responses
4329 # to prompts.
4330
4331 if (not $force_continue) {
4332   # runtest needs to interact if we're not in continue
4333   # mode. It does so by communicate to /dev/tty
4334   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
4335   print "\nPress RETURN to run the tests: ";
4336   <T>;
4337 }
4338
4339
4340 my $failures = 0;
4341 foreach $test (@test_list)
4342   {
4343   state $lasttestdir = '';
4344
4345   local $lineno     = 0;
4346   local $commandno  = 0;
4347   local $subtestno  = 0;
4348   local $sortlog    = 0;
4349
4350   (local $testno = $test) =~ s|.*/||;
4351
4352   # Leaving traces in the process table and in the environment
4353   # gives us a chance to identify hanging processes (exim daemons)
4354   local $0 = "[runtest $testno]";
4355   local $ENV{EXIM_TEST_NUMBER} = $testno;
4356
4357   my $gnutls   = 0;
4358   my $docheck  = 1;
4359   my $thistestdir  = substr($test, 0, -5);
4360
4361   $dynamic_socket->close() if $dynamic_socket;
4362
4363   if ($lasttestdir ne $thistestdir)
4364     {
4365     $gnutls = 0;
4366     if (-s "scripts/$thistestdir/REQUIRES")
4367       {
4368       my $indent = '';
4369       print "\n>>> The following tests require: ";
4370       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
4371         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
4372       while (<$requires>)
4373         {
4374         $gnutls = 1 if /^support GnuTLS/;
4375         print $indent, $_;
4376         $indent = ">>>                              ";
4377         }
4378       }
4379       $lasttestdir = $thistestdir;
4380     }
4381
4382   # Remove any debris in the spool directory and the test-mail directory
4383   # and also the files for collecting stdout and stderr. Then put back
4384   # the test-mail directory for appendfile deliveries.
4385
4386   system "sudo /bin/rm -rf spool test-*";
4387   mkdir "test-mail";
4388
4389   # A privileged Exim will normally make its own spool directory, but some of
4390   # the tests run in unprivileged modes that don't always work if the spool
4391   # directory isn't already there. What is more, we want anybody to be able
4392   # to read it in order to find the daemon's pid.
4393
4394   mkdir "spool";
4395   system "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
4396          "sudo chmod 0755 spool";
4397
4398   # Empty the cache that keeps track of things like message id mappings, and
4399   # set up the initial sequence strings.
4400
4401   undef %cache;
4402   $next_msgid_old = "aX";
4403   $next_msgid = "aX";
4404   $next_pid = 1234;
4405   $next_port = 1111;
4406   $message_skip = 0;
4407   $msglog_skip = 0;
4408   $munge_skip = 0;
4409   $stderr_skip = 0;
4410   $stdout_skip = 0;
4411   $rmfiltertest = 0;
4412   $is_ipv6test = 0;
4413   $TEST_STATE->{munge} = '';
4414
4415   # Remove the associative arrays used to hold checked mail files and msglogs
4416
4417   undef %expected_mails;
4418   undef %expected_msglogs;
4419
4420   # Open the test's script
4421   open(SCRIPT, "scripts/$test") ||
4422     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
4423   # Run through the script once to set variables which should be global
4424   while (<SCRIPT>)
4425     {
4426     if (/^no_message_check/) { $message_skip = 1; next; }
4427     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4428     if (/^no_munge/)         { $munge_skip = 1; next; }
4429     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4430     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4431     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4432     if (/^sortlog/)          { $sortlog = 1; next; }
4433     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
4434     }
4435   # Reset to beginning of file for per test interpreting/processing
4436   seek(SCRIPT, 0, 0);
4437
4438   # The first line in the script must be a comment that is used to identify
4439   # the set of tests as a whole.
4440
4441   $_ = <SCRIPT>;
4442   $lineno++;
4443   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
4444   printf("%s %s", (substr $test, 5), (substr $_, 2));
4445
4446   # Loop for each of the subtests within the script. The variable $server_pid
4447   # is used to remember the pid of a "server" process, for which we do not
4448   # wait until we have waited for a subsequent command.
4449
4450   local($server_pid) = 0;
4451   for ($commandno = 1; !eof SCRIPT; $commandno++)
4452     {
4453     # Skip further leading comments and blank lines, handle the flag setting
4454     # commands, and deal with tests for IP support.
4455
4456     while (<SCRIPT>)
4457       {
4458       $lineno++;
4459       # Could remove these variable settings because they are already
4460       # set above, but doesn't hurt to leave them here.
4461       if (/^no_message_check/) { $message_skip = 1; next; }
4462       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4463       if (/^no_munge/)         { $munge_skip = 1; next; }
4464       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4465       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4466       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4467       if (/^sortlog/)          { $sortlog = 1; next; }
4468
4469       if (/^need_largefiles/)
4470         {
4471         next if $have_largefiles;
4472         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4473         $docheck = 0;      # don't check output
4474         undef $_;          # pretend EOF
4475         last;
4476         }
4477
4478       if (/^need_ipv4/)
4479         {
4480         next if $have_ipv4;
4481         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4482         $docheck = 0;      # don't check output
4483         undef $_;          # pretend EOF
4484         last;
4485         }
4486
4487       if (/^need_ipv6/)
4488         {
4489         if ($have_ipv6)
4490           {
4491           $is_ipv6test = 1;
4492           next;
4493           }
4494         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4495         $docheck = 0;      # don't check output
4496         undef $_;          # pretend EOF
4497         last;
4498         }
4499
4500       if (/^need_move_frozen_messages/)
4501         {
4502         next if defined $parm_support{move_frozen_messages};
4503         print ">>> move frozen message support is needed for test $testno, " .
4504           "but is not\n>>> available: skipping\n";
4505         $docheck = 0;      # don't check output
4506         undef $_;          # pretend EOF
4507         last;
4508         }
4509
4510       last unless /^(?:#(?!##\s)|\s*$)/;
4511       }
4512     last if !defined $_;  # Hit EOF
4513
4514     my($subtest_startline) = $lineno;
4515
4516     # Now run the command. The function returns 0 for an inline command,
4517     # 1 if a non-exim command was run and waited for, 2 if an exim
4518     # command was run and waited for, and 3 if a command
4519     # was run and not waited for (usually a daemon or server startup).
4520
4521     my($commandname) = '';
4522     my($expectrc) = 0;
4523     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4524     my($cmdrc) = $?;
4525
4526     if ($debug) {
4527       print ">> rc=$rc cmdrc=$cmdrc\n";
4528       if (defined $run_extra) {
4529         foreach my $k (keys %$run_extra) {
4530           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4531           print ">>   $k -> $v\n";
4532         }
4533       }
4534     }
4535     $run_extra = {} unless defined $run_extra;
4536     foreach my $k (keys %$run_extra) {
4537       if (exists $TEST_STATE->{$k}) {
4538         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4539         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4540       }
4541       if (defined $run_extra->{$k}) {
4542         $TEST_STATE->{$k} = $run_extra->{$k};
4543       } elsif (exists $TEST_STATE->{$k}) {
4544         delete $TEST_STATE->{$k};
4545       }
4546     }
4547
4548     # Hit EOF after an initial return code number
4549
4550     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4551
4552     # Carry on with the next command if we did not wait for this one. $rc == 0
4553     # if no subprocess was run; $rc == 3 if we started a process but did not
4554     # wait for it.
4555
4556     next if ($rc == 0 || $rc == 3);
4557
4558     # We ran and waited for a command. Check for the expected result unless
4559     # it died.
4560
4561     if ($cmdrc != $expectrc && !$sigpipehappened)
4562       {
4563       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4564       if (($cmdrc & 0xff) == 0)
4565         {
4566         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4567         }
4568       elsif (($cmdrc & 0xff00) == 0)
4569         { printf("** Killed by signal %d", $cmdrc & 255); }
4570       else
4571         { printf("** Status %x", $cmdrc); }
4572
4573       for (;;)
4574         {
4575         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4576         $_ = $force_continue ? "c" : <T>;
4577         tests_exit(1) if /^q?$/i;
4578         if (/^c$/ && $force_continue)
4579           {
4580           log_failure($log_failed_filename, $testno, "exit code unexpected");
4581           log_test($log_summary_filename, $testno, 'F');
4582           $failures++;
4583           }
4584         if ($force_continue)
4585           {
4586           print "\nstdout tail:\n";
4587           print "==================>\n";
4588           system("tail -20 test-stdout");
4589           print "===================\n";
4590
4591           print "stderr tail:\n";
4592           print "==================>\n";
4593           system("tail -30 test-stderr");
4594           print "===================\n";
4595
4596           print "stdout-server tail:\n";
4597           print "==================>\n";
4598           system("tail -20 test-stdout-server");
4599           print "===================\n";
4600
4601           print "stderr-server tail:\n";
4602           print "==================>\n";
4603           system("tail -30 test-stderr-server");
4604           print "===================\n";
4605
4606           print "... continue forced\n";
4607           }
4608
4609         last if /^[rc]$/i;
4610         if (/^e$/i)
4611           {
4612           system @more => 'test-stderr';
4613           }
4614         elsif (/^o$/i)
4615           {
4616           system @more => 'test-stdout';
4617           }
4618         }
4619
4620       $retry = 1 if /^r$/i;
4621       $docheck = 0;
4622       }
4623
4624     # If the command was exim, and a listening server is running, we can now
4625     # close its input, which causes us to wait for it to finish, which is why
4626     # we didn't close it earlier.
4627
4628     if ($rc == 2 && $server_pid != 0)
4629       {
4630       close SERVERCMD;
4631       $server_pid = 0;
4632       if ($? != 0)
4633         {
4634         if (($? & 0xff) == 0)
4635           { printf("Server return code %d for test %d starting line %d", $?/256,
4636                 $testno, $subtest_startline); }
4637         elsif (($? & 0xff00) == 0)
4638           { printf("Server killed by signal %d", $? & 255); }
4639         else
4640           { printf("Server status %x", $?); }
4641
4642         for (;;)
4643           {
4644           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4645           $_ = $force_continue ? "c" : <T>;
4646           tests_exit(1) if /^q?$/i;
4647           if (/^c$/ && $force_continue)
4648             {
4649             log_failure($log_failed_filename, $testno, "exit code unexpected");
4650             log_test($log_summary_filename, $testno, 'F');
4651             $failures++;
4652             }
4653           print "... continue forced\n" if $force_continue;
4654           last if /^[rc]$/i;
4655
4656           if (/^s$/i)
4657             {
4658             open(S, "test-stdout-server") ||
4659               tests_exit(-1, "Failed to open test-stdout-server: $!");
4660             print while <S>;
4661             close(S);
4662             }
4663           }
4664         $retry = 1 if /^r$/i;
4665         }
4666       }
4667     }
4668
4669   close SCRIPT;
4670
4671   # The script has finished. Check the all the output that was generated. The
4672   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4673   # rerun the test (the files # have been updated).
4674   # It does not return if the user responds Q to a prompt.
4675
4676   if ($retry)
4677     {
4678     $retry = '0';
4679     print (("#" x 79) . "\n");
4680     redo;
4681     }
4682
4683   if ($docheck)
4684     {
4685     sleep 1 if $slow;
4686     my $rc = check_output($TEST_STATE->{munge});
4687     if ($rc == 0)
4688       {
4689       log_test($log_summary_filename, $testno, 'P');
4690       }
4691     else
4692       {
4693       $failures++;
4694       }
4695     if ($rc < 2)
4696       {
4697       print ("  Script completed\n");
4698       }
4699     else
4700       {
4701       print (("#" x 79) . "\n");
4702       redo;
4703       }
4704     }
4705   }
4706
4707
4708 ##################################################
4709 #         Exit from the test script              #
4710 ##################################################
4711
4712 tests_exit(-1, "No runnable tests selected") if not @test_list;
4713 tests_exit($fail_any ? $failures : 0);
4714
4715 __END__
4716
4717 =head1 NAME
4718
4719  runtest - run the exim testsuite
4720
4721 =head1 SYNOPSIS
4722
4723  runtest [exim-path] [options] [test0 [test1]]
4724
4725 =head1 DESCRIPTION
4726
4727 B<runtest> runs the Exim testsuite.
4728
4729 =head1 OPTIONS
4730
4731 For legacy reasons the options are not case sensitive.
4732
4733 =over
4734
4735 =item B<--continue>
4736
4737 Do not stop for user interaction or on errors. (default: off)
4738
4739 =item B<--debug>
4740
4741 This option enables the output of debug information when running the
4742 various test commands. (default: off)
4743
4744 =item B<--diff>
4745
4746 Use C<diff -u> for comparing the expected output with the produced
4747 output. (default: use a built-in routine)
4748
4749 =item B<--flavor>|B<--flavour> I<flavour>
4750
4751 Override the expected results for results for a specific (OS) flavour.
4752 (default: unused)
4753
4754 =item B<--[no]ipv4>
4755
4756 Skip IPv4 related setup and tests (default: use ipv4)
4757
4758 =item B<--[no]ipv6>
4759
4760 Skip IPv6 related setup and tests (default: use ipv6)
4761
4762 =item B<--keep>
4763
4764 Keep the various output files produced during a test run. (default: don't keep)
4765
4766 =item B<--range> I<n0> I<n1>
4767
4768 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4769 test available".
4770
4771 =item B<--slow>
4772
4773 Insert some delays to compensate for a slow host system. (default: off)
4774
4775 =item B<--test> I<n>
4776
4777 Run the specified test. This option may used multiple times.
4778
4779 =item B<--update>
4780
4781 Automatically update the recorded (expected) data on mismatch. (default: off)
4782
4783 =item B<--valgrind>
4784
4785 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4786
4787 =back
4788
4789 =cut
4790
4791
4792 # End of runtest script