test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use 5.010;
  20 use feature 'state';    # included in 5.010
  21 use warnings;
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use FindBin qw'$RealBin';
  30
  31 use lib "$RealBin/lib";
  32 use Exim::Runtest;
  33
  34 use if $ENV{DEBUG} && $ENV{DEBUG} =~ /\bruntest\b/ => ('Smart::Comments' => '####');
  35
  36
  37 # Start by initializing some global variables
  38
  39 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  40
  41 # This gets embedded in the D-H params filename, and the value comes
  42 # from asking GnuTLS for "normal", but there appears to be no way to
  43 # use certtool/... to ask what that value currently is.  *sigh*
  44 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  45 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  46 # normal = 2432   tls_dh_max_bits = 2236
  47 my $gnutls_dh_bits_normal = 2236;
  48
  49 my $cf = 'bin/cf -exact';
  50 my $cr = "\r";
  51 my $debug = 0;
  52 my $flavour = do {
  53   my $f = Exim::Runtest::flavour() // '';
  54   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  55 };
  56 my $force_continue = 0;
  57 my $force_update = 0;
  58 my $log_failed_filename = 'failed-summary.log';
  59 my $log_summary_filename = 'run-summary.log';
  60 my $more = 'less -XF';
  61 my $optargs = '';
  62 my $save_output = 0;
  63 my $server_opts = '';
  64 my $valgrind = 0;
  65
  66 my $have_ipv4 = 1;
  67 my $have_ipv6 = 1;
  68 my $have_largefiles = 0;
  69
  70 my $test_start = 1;
  71 my $test_end = $test_top = 8999;
  72 my $test_special_top = 9999;
  73 my @test_list = ();
  74 my @test_dirs = ();
  75
  76
  77 # Networks to use for DNS tests. We need to choose some networks that will
  78 # never be used so that there is no chance that the host on which we are
  79 # running is actually in one of the test networks. Private networks such as
  80 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  81 # Rather than use some unassigned numbers (that might become assigned later),
  82 # I have chosen some multicast networks, in the belief that such addresses
  83 # won't ever be assigned to hosts. This is the only place where these numbers
  84 # are defined, so it is trivially possible to change them should that ever
  85 # become necessary.
  86
  87 my $parm_ipv4_test_net = 224;
  88 my $parm_ipv6_test_net = 'ff00';
  89
  90 # Port numbers are currently hard-wired
  91
  92 my $parm_port_n = 1223;         # Nothing listening on this port
  93 my $parm_port_s = 1224;         # Used for the "server" command
  94 my $parm_port_d = 1225;         # Used for the Exim daemon
  95 my $parm_port_d2 = 1226;        # Additional for daemon
  96 my $parm_port_d3 = 1227;        # Additional for daemon
  97 my $parm_port_d4 = 1228;        # Additional for daemon
  98 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
  99
 100 # Find a suiteable group name for test (currently only 0001
 101 # uses a group name. A numeric group id would do
 102 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 103
 104 # Manually set locale
 105 $ENV{LC_ALL} = 'C';
 106
 107 # In some environments USER does not exist, but we need it for some test(s)
 108 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 109
 110 my ($parm_configure_owner, $parm_configure_group);
 111 my ($parm_ipv4, $parm_ipv6);
 112 my $parm_hostname;
 113
 114 ###############################################################################
 115 ###############################################################################
 116
 117 # Define a number of subroutines
 118
 119 ###############################################################################
 120 ###############################################################################
 121
 122
 123 ##################################################
 124 #              Handle signals                    #
 125 ##################################################
 126
 127 sub pipehandler { $sigpipehappened = 1; }
 128
 129 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 130
 131
 132 ##################################################
 133 #       Do global macro substitutions            #
 134 ##################################################
 135
 136 # This function is applied to configurations, command lines and data lines in
 137 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 138 # directory. It takes one argument: the current test number, or zero when
 139 # setting up files before running any tests.
 140
 141 sub do_substitute{
 142 s?\bCALLER\b?$parm_caller?g;
 143 s?\bCALLERGROUP\b?$parm_caller_group?g;
 144 s?\bCALLER_UID\b?$parm_caller_uid?g;
 145 s?\bCALLER_GID\b?$parm_caller_gid?g;
 146 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 147 s?\bDIR/?$parm_cwd/?g;
 148 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 149 s?\bEXIMUSER\b?$parm_eximuser?g;
 150 s?\bHOSTIPV4\b?$parm_ipv4?g;
 151 s?\bHOSTIPV6\b?$parm_ipv6?g;
 152 s?\bHOSTNAME\b?$parm_hostname?g;
 153 s?\bPORT_D\b?$parm_port_d?g;
 154 s?\bPORT_D2\b?$parm_port_d2?g;
 155 s?\bPORT_D3\b?$parm_port_d3?g;
 156 s?\bPORT_D4\b?$parm_port_d4?g;
 157 s?\bPORT_N\b?$parm_port_n?g;
 158 s?\bPORT_S\b?$parm_port_s?g;
 159 s?\bTESTNUM\b?$_[0]?g;
 160 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 161 s?\bV6NET:?$parm_ipv6_test_net:?g;
 162 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 163 s?\bMAILGROUP\b?$parm_mailgroup?g;
 164 }
 165
 166
 167 ##################################################
 168 #     Any state to be preserved across tests     #
 169 ##################################################
 170
 171 my $TEST_STATE = {};
 172
 173
 174 ##################################################
 175 #        Subroutine to tidy up and exit          #
 176 ##################################################
 177
 178 # In all cases, we check for any Exim daemons that have been left running, and
 179 # kill them. Then remove all the spool data, test output, and the modified Exim
 180 # binary if we are ending normally.
 181
 182 # Arguments:
 183 #    $_[0] = 0 for a normal exit; full cleanup done
 184 #    $_[0] > 0 for an error exit; no files cleaned up
 185 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 186
 187 sub tests_exit{
 188 my($rc) = $_[0];
 189 my($spool);
 190
 191 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 192 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 193 # the background.
 194
 195 if (exists $TEST_STATE->{exim_pid})
 196   {
 197   $pid = $TEST_STATE->{exim_pid};
 198   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 199   system("sudo kill -INT $pid");
 200   }
 201
 202 if (opendir(DIR, "spool"))
 203   {
 204   my(@spools) = sort readdir(DIR);
 205   closedir(DIR);
 206   foreach $spool (@spools)
 207     {
 208     next if $spool !~ /^exim-daemon./;
 209     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 210     chomp($pid = <PID>);
 211     close(PID);
 212     print "Tidyup: killing daemon pid=$pid\n";
 213     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 214     }
 215   }
 216 else
 217   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 218
 219 # Close the terminal input and remove the test files if all went well, unless
 220 # the option to save them is set. Always remove the patched Exim binary. Then
 221 # exit normally, or die.
 222
 223 close(T);
 224 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 225   if ($rc == 0 && !$save_output);
 226
 227 system("sudo /bin/rm -rf ./eximdir/*")
 228   if (!$save_output);
 229
 230 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 231 exit $rc if ($rc >= 0);
 232 die "** runtest error: $_[1]\n";
 233 }
 234
 235
 236
 237 ##################################################
 238 #   Subroutines used by the munging subroutine   #
 239 ##################################################
 240
 241 # This function is used for things like message ids, where we want to generate
 242 # more than one value, but keep a consistent mapping throughout.
 243 #
 244 # Arguments:
 245 #   $oldid        the value from the file
 246 #   $base         a base string into which we insert a sequence
 247 #   $sequence     the address of the current sequence counter
 248
 249 sub new_value {
 250 my($oldid, $base, $sequence) = @_;
 251 my($newid) = $cache{$oldid};
 252 if (! defined $newid)
 253   {
 254   $newid = sprintf($base, $$sequence++);
 255   $cache{$oldid} = $newid;
 256   }
 257 return $newid;
 258 }
 259
 260
 261 # This is used while munging the output from exim_dumpdb.
 262 # May go wrong across DST changes.
 263
 264 sub date_seconds {
 265 my($day,$month,$year,$hour,$min,$sec) =
 266   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 267 my($mon);
 268 if   ($month =~ /Jan/) {$mon = 0;}
 269 elsif($month =~ /Feb/) {$mon = 1;}
 270 elsif($month =~ /Mar/) {$mon = 2;}
 271 elsif($month =~ /Apr/) {$mon = 3;}
 272 elsif($month =~ /May/) {$mon = 4;}
 273 elsif($month =~ /Jun/) {$mon = 5;}
 274 elsif($month =~ /Jul/) {$mon = 6;}
 275 elsif($month =~ /Aug/) {$mon = 7;}
 276 elsif($month =~ /Sep/) {$mon = 8;}
 277 elsif($month =~ /Oct/) {$mon = 9;}
 278 elsif($month =~ /Nov/) {$mon = 10;}
 279 elsif($month =~ /Dec/) {$mon = 11;}
 280 return timelocal($sec,$min,$hour,$day,$mon,$year);
 281 }
 282
 283
 284 # This is a subroutine to sort maildir files into time-order. The second field
 285 # is the microsecond field, and may vary in length, so must be compared
 286 # numerically.
 287
 288 sub maildirsort {
 289 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 290 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 291 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 292 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 293 }
 294
 295
 296
 297 ##################################################
 298 #   Subroutine list files below a directory      #
 299 ##################################################
 300
 301 # This is used to build up a list of expected mail files below a certain path
 302 # in the directory tree. It has to be recursive in order to deal with multiple
 303 # maildir mailboxes.
 304
 305 sub list_files_below {
 306 my($dir) = $_[0];
 307 my(@yield) = ();
 308 my(@sublist, $file);
 309
 310 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 311 @sublist = sort maildirsort readdir(DIR);
 312 closedir(DIR);
 313
 314 foreach $file (@sublist)
 315   {
 316   next if $file eq "." || $file eq ".." || $file eq "CVS";
 317   if (-d "$dir/$file")
 318     { @yield = (@yield, list_files_below("$dir/$file")); }
 319   else
 320     { push @yield, "$dir/$file"; }
 321   }
 322
 323 return @yield;
 324 }
 325
 326
 327
 328 ##################################################
 329 #         Munge a file before comparing          #
 330 ##################################################
 331
 332 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 333 # on into standard values, so that the compare works. Perl's substitution with
 334 # an expression provides a neat way to do some of these changes.
 335
 336 # We keep a global associative array for repeatedly turning the same values
 337 # into the same standard values throughout the data from a single test.
 338 # Message ids get this treatment (can't be made reliable for times), and
 339 # times in dumped retry databases are also handled in a special way, as are
 340 # incoming port numbers.
 341
 342 # On entry to the subroutine, the file to write to is already opened with the
 343 # name MUNGED. The input file name is the only argument to the subroutine.
 344 # Certain actions are taken only when the name contains "stderr", "stdout",
 345 # or "log". The yield of the function is 1 if a line matching "*** truncated
 346 # ***" is encountered; otherwise it is 0.
 347
 348 sub munge {
 349 my($file) = $_[0];
 350 my($extra) = $_[1];
 351 my($yield) = 0;
 352 my(@saved) = ();
 353
 354 local $_;
 355
 356 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 357
 358 my($is_log) = $file =~ /log/;
 359 my($is_stdout) = $file =~ /stdout/;
 360 my($is_stderr) = $file =~ /stderr/;
 361 my($is_mail) = $file =~ /mail/;
 362
 363 # Date pattern
 364
 365 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 366
 367 # Pattern for matching pids at start of stderr lines; initially something
 368 # that won't match.
 369
 370 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 371
 372 # Scan the file and make the changes. Near the bottom there are some changes
 373 # that are specific to certain file types, though there are also some of those
 374 # inline too.
 375
 376 LINE: while(<IN>)
 377   {
 378 RESET_AFTER_EXTRA_LINE_READ:
 379   # Custom munges
 380   if ($extra)
 381     {
 382     next if $extra =~ m%^/%  &&  eval $extra;
 383     eval $extra if $extra =~ m/^s/;
 384     }
 385
 386   # Check for "*** truncated ***"
 387   $yield = 1 if /\*\*\* truncated \*\*\*/;
 388
 389   # Replace the name of this host
 390   s/\Q$parm_hostname\E/the.local.host.name/g;
 391
 392   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 393   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 394
 395   # The name of the shell may vary
 396   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 397
 398   # Replace the path to the testsuite directory
 399   s?\Q$parm_cwd\E?TESTSUITE?g;
 400
 401   # Replace the Exim version number (may appear in various places)
 402   # patchexim should have fixed this for us
 403   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 404
 405   # Replace Exim message ids by a unique series
 406   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 407     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 408
 409   # The names of lock files appear in some error and debug messages
 410   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 411
 412   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 413   # port" message, because it is not always the same.
 414   s/port (\d+) \([^)]+\)/port $1/g
 415     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 416
 417   # Challenges in SPA authentication
 418   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 419
 420   # PRVS values
 421   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 422   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 423
 424   # There are differences in error messages between OpenSSL versions
 425   s/SSL_CTX_set_cipher_list/SSL_connect/;
 426
 427   # One error test in expansions mentions base 62 or 36
 428   s/is not a base (36|62) number/is not a base 36\/62 number/;
 429
 430   # This message sometimes has a different number of seconds
 431   s/forced fail after \d seconds/forced fail after d seconds/;
 432
 433   # This message may contain a different DBM library name
 434   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 435
 436   # The message for a non-listening FIFO varies
 437   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 438
 439   # Debugging output of lists of hosts may have different sort keys
 440   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 441
 442   # Random local part in callout cache testing
 443   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 444   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 445
 446   # File descriptor numbers may vary
 447   s/^writing data block fd=\d+/writing data block fd=dddd/;
 448   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 449
 450
 451   # ======== Dumpdb output ========
 452   # This must be before the general date/date munging.
 453   # Time data lines, which look like this:
 454   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 455   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 456     {
 457     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 458     $expired = '' if !defined $expired;
 459     my($increment) = date_seconds($date3) - date_seconds($date2);
 460
 461     # We used to use globally unique replacement values, but timing
 462     # differences make this impossible. Just show the increment on the
 463     # last one.
 464
 465     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 466       $increment, $expired);
 467     next;
 468     }
 469
 470   # more_errno values in exim_dumpdb output which are times
 471   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 472
 473
 474   # ======== Dates and times ========
 475
 476   # Dates and times are all turned into the same value - trying to turn
 477   # them into different ones cannot be done repeatedly because they are
 478   # real time stamps generated while running the test. The actual date and
 479   # time used was fixed when I first started running automatic Exim tests.
 480
 481   # Date/time in header lines and SMTP responses
 482   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 483     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 484
 485   # Date/time in logs and in one instance of a filter test
 486   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 487   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 488
 489   # Date/time in message separators
 490   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 491     /Tue Mar 02 09:44:33 1999/gx;
 492
 493   # Date of message arrival in spool file as shown by -Mvh
 494   s/^\d{9,10}\s0$/ddddddddd 0/;
 495
 496   # Date/time in mbx mailbox files
 497   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 498
 499   # Dates/times in debugging output for writing retry records
 500   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 501     {
 502     my($next) = $3 - $2;
 503     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 504     }
 505   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 506   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 507
 508   # Time to retry may vary
 509   s/time to retry = \S+/time to retry = tttt/;
 510   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 511   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 512
 513   # Date/time in exim -bV output
 514   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 515
 516   # Time on queue tolerance
 517   s/(QT|D)=1s/$1=0s/;
 518
 519   # Eximstats heading
 520   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 521     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 522
 523   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 524   # us the former on a new connection.
 525   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 526
 527   # ======== TLS certificate algorithms ========
 528   # Test machines might have various different TLS library versions supporting
 529   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 530   # treat the standard algorithms the same.
 531   # So far, have seen:
 532   #   TLSv1:AES128-GCM-SHA256:128
 533   #   TLSv1:AES256-SHA:256
 534   #   TLSv1.1:AES256-SHA:256
 535   #   TLSv1.2:AES256-GCM-SHA384:256
 536   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 537   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 538   # We also need to handle the ciphersuite without the TLS part present, for
 539   # client-ssl's output.  We also see some older forced ciphersuites, but
 540   # negotiating TLS 1.2 instead of 1.0.
 541   # Mail headers (...), log-lines X=..., client-ssl output ...
 542   # (and \b doesn't match between ' ' and '(' )
 543
 544   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 545   s/\bAES128-GCM-SHA256:128\b/AES256-SHA:256/g;
 546   s/\bAES128-GCM-SHA256\b/AES256-SHA/g;
 547   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 548   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 549
 550   # LibreSSL
 551   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 552   s/\bECDHE-RSA-CHACHA20-POLY1305\b/AES256-SHA/g;
 553
 554   # GnuTLS have seen:
 555   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 556   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 557   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 558   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 559   #
 560   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 561   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 562   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 563   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 564   # and as stand-alone cipher:
 565   #   ECDHE-RSA-AES256-SHA
 566   #   DHE-RSA-AES256-SHA256
 567   #   DHE-RSA-AES256-SHA
 568   # picking latter as canonical simply because regex easier that way.
 569   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 570   s/TLS1.[012]:((EC)?DHE_)?RSA_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 571   s/\b(ECDHE-RSA-AES256-SHA|DHE-RSA-AES256-SHA256)\b/AES256-SHA/g;
 572
 573   # GnuTLS library error message changes
 574   s/No certificate was found/The peer did not send any certificate/g;
 575 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 576   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 577
 578   # (this new one is a generic channel-read error, but the testsuite
 579   # only hits it in one place)
 580   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 581
 582   # (replace old with new, hoping that old only happens in one situation)
 583   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 584   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 585
 586   # signature algorithm names
 587   s/RSA-SHA1/RSA-SHA/;
 588
 589
 590   # ======== Caller's login, uid, gid, home, gecos ========
 591
 592   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 593   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 594   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 595
 596   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 597   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 598
 599   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 600   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 601
 602   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 603
 604   # When looking at spool files with -Mvh, we will find not only the caller
 605   # login, but also the uid and gid. It seems that $) in some Perls gives all
 606   # the auxiliary gids as well, so don't bother checking for that.
 607
 608   s/^CALLER $> \d+$/CALLER UID GID/;
 609
 610   # There is one case where the caller's login is forced to something else,
 611   # in order to test the processing of logins that contain spaces. Weird what
 612   # some people do, isn't it?
 613
 614   s/^spaced user $> \d+$/CALLER UID GID/;
 615
 616
 617   # ======== Exim's login ========
 618   # For messages received by the daemon, this is in the -H file, which some
 619   # tests inspect. For bounce messages, this will appear on the U= lines in
 620   # logs and also after Received: and in addresses. In one pipe test it appears
 621   # after "Running as:". It also appears in addresses, and in the names of lock
 622   # files.
 623
 624   s/U=$parm_eximuser/U=EXIMUSER/;
 625   s/user=$parm_eximuser/user=EXIMUSER/;
 626   s/login=$parm_eximuser/login=EXIMUSER/;
 627   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 628   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 629   s/\b$parm_eximuser@/EXIMUSER@/;
 630   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 631
 632   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 633   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 634
 635   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 636   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 637
 638   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 639
 640
 641   # ======== General uids, gids, and pids ========
 642   # Note: this must come after munges for caller's and exim's uid/gid
 643
 644   # These are for systems where long int is 64
 645   s/\buid=4294967295/uid=-1/;
 646   s/\beuid=4294967295/euid=-1/;
 647   s/\bgid=4294967295/gid=-1/;
 648   s/\begid=4294967295/egid=-1/;
 649
 650   s/\bgid=\d+/gid=gggg/;
 651   s/\begid=\d+/egid=gggg/;
 652   s/\bpid=\d+/pid=pppp/;
 653   s/\buid=\d+/uid=uuuu/;
 654   s/\beuid=\d+/euid=uuuu/;
 655   s/set_process_info:\s+\d+/set_process_info: pppp/;
 656   s/queue run pid \d+/queue run pid ppppp/;
 657   s/process \d+ running as transport filter/process pppp running as transport filter/;
 658   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 659   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 660   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 661
 662   # Pid in temp file in appendfile transport
 663   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 664
 665   # Optional pid in log lines
 666   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 667     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 668
 669   # Detect a daemon stderr line with a pid and save the pid for subsequent
 670   # removal from following lines.
 671   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 672   s/^$spid //;
 673
 674   # Queue runner waiting messages
 675   s/waiting for children of \d+/waiting for children of pppp/;
 676   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 677
 678   # The spool header file name varies with PID
 679   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 680
 681   # ======== Port numbers ========
 682   # Incoming port numbers may vary, but not in daemon startup line.
 683
 684   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 685   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 686
 687   # This handles "connection from" and the like, when the port is given
 688   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 689       && !/\*>/ && !/Connection refused/)
 690     {
 691     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 692     }
 693
 694   # Port in host address in spool file output from -Mvh
 695   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 696
 697   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 698     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 699   }
 700
 701
 702   # ======== Local IP addresses ========
 703   # The amount of space between "host" and the address in verification output
 704   # depends on the length of the host name. We therefore reduce it to one space
 705   # for all of them.
 706   # Also, the length of space at the end of the host line is dependent
 707   # on the length of the longest line, so strip it also on otherwise
 708   # un-rewritten lines like localhost
 709
 710   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 711   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 712   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 713   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 714   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 715   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 716   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 717   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 718   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 719   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 720
 721
 722   # ======== Test network IP addresses ========
 723   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 724   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 725
 726
 727   # ======== IP error numbers and messages ========
 728   # These vary between operating systems
 729   s/Can't assign requested address/Network Error/;
 730   s/Cannot assign requested address/Network Error/;
 731   s/Operation timed out/Connection timed out/;
 732   s/Address family not supported by protocol family/Network Error/;
 733   s/Network is unreachable/Network Error/;
 734   s/Invalid argument/Network Error/;
 735
 736   s/\(\d+\): Network/(dd): Network/;
 737   s/\(\d+\): Connection refused/(dd): Connection refused/;
 738   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 739   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 740   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 741
 742
 743   # ======== Other error numbers ========
 744   s/errno=\d+/errno=dd/g;
 745
 746   # ======== System Error Messages ======
 747   # depending on the underlaying file system the error message seems to differ
 748   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 749
 750   # ======== Output from ls ========
 751   # Different operating systems use different spacing on long output
 752   #s/ +/ /g if /^[-rwd]{10} /;
 753   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 754   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 755   # unfortunately matches a non-ls linefull of dashes.
 756   # Allow the case where we've already picked out the file protection bits.
 757   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 758     s/ +/ /g;
 759   }
 760
 761
 762   # ======== Message sizes =========
 763   # Message sizes vary, owing to different logins and host names that get
 764   # automatically inserted. I can't think of any way of even approximately
 765   # comparing these.
 766
 767   s/([\s,])S=\d+\b/$1S=sss/;
 768   s/:S\d+\b/:Ssss/;
 769   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 770   s/\sSIZE=\d+\b/ SIZE=ssss/;
 771   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 772   s/old size = \d+\b/old size = sssss/;
 773   s/message size = \d+\b/message size = sss/;
 774   s/this message = \d+\b/this message = sss/;
 775   s/Size of headers = \d+/Size of headers = sss/;
 776   s/sum=(?!0)\d+/sum=dddd/;
 777   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 778   s/(?<=sum=0 )count=\d+\b/count=dd/;
 779   s/,S is \d+\b/,S is ddddd/;
 780   s/\+0100,\d+;/+0100,ddd;/;
 781   s/\(\d+ bytes written\)/(ddd bytes written)/;
 782   s/added '\d+ 1'/added 'ddd 1'/;
 783   s/Received\s+\d+/Received               nnn/;
 784   s/Delivered\s+\d+/Delivered              nnn/;
 785
 786
 787   # ======== Values in spool space failure message ========
 788   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 789
 790
 791   # ======== Filter sizes ========
 792   # The sizes of filter files may vary because of the substitution of local
 793   # filenames, logins, etc.
 794
 795   s/^\d+(?= bytes read from )/ssss/;
 796
 797
 798   # ======== OpenSSL error messages ========
 799   # Different releases of the OpenSSL libraries seem to give different error
 800   # numbers, or handle specific bad conditions in different ways, leading to
 801   # different wording in the error messages, so we cannot compare them.
 802
 803   s/(TLS error on connection (?:from .* )?\(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 804   next if /SSL verify error: depth=0 error=certificate not trusted/;
 805
 806   # ======== Maildir things ========
 807   # timestamp output in maildir processing
 808   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 809
 810   # maildir delivery files appearing in log lines (in cases of error)
 811   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 812
 813   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 814
 815   # Maildir file names in general
 816   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 817
 818   # Maildirsize data
 819   while (/^\d+S,\d+C\s*$/)
 820     {
 821     print MUNGED;
 822     while (<IN>)
 823       {
 824       last if !/^\d+ \d+\s*$/;
 825       print MUNGED "ddd d\n";
 826       }
 827     last if !defined $_;
 828     }
 829   last if !defined $_;
 830
 831
 832   # ======== Output from the "fd" program about open descriptors ========
 833   # The statuses seem to be different on different operating systems, but
 834   # at least we'll still be checking the number of open fd's.
 835
 836   s/max fd = \d+/max fd = dddd/;
 837   s/status=0 RDONLY/STATUS/g;
 838   s/status=1 WRONLY/STATUS/g;
 839   s/status=2 RDWR/STATUS/g;
 840
 841
 842   # ======== Contents of spool files ========
 843   # A couple of tests dump the contents of the -H file. The length fields
 844   # will be wrong because of different user names, etc.
 845   s/^\d\d\d(?=[PFS*])/ddd/;
 846
 847
 848   # ========= Exim lookups ==================
 849   # Lookups have a char which depends on the number of lookup types compiled in,
 850   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 851   # other output is fragile; perhaps the debug output should be revised instead.
 852   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 853
 854   # ==========================================================
 855   # MIME boundaries in RFC3461 DSN messages
 856   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 857
 858   # ==========================================================
 859   # Some munging is specific to the specific file types
 860
 861   # ======== stdout ========
 862
 863   if ($is_stdout)
 864     {
 865     # Skip translate_ip_address and use_classresources in -bP output because
 866     # they aren't always there.
 867
 868     next if /translate_ip_address =/;
 869     next if /use_classresources/;
 870
 871     # In certain filter tests, remove initial filter lines because they just
 872     # clog up by repetition.
 873
 874     if ($rmfiltertest)
 875       {
 876       next if /^(Sender\staken\sfrom|
 877                  Return-path\scopied\sfrom|
 878                  Sender\s+=|
 879                  Recipient\s+=)/x;
 880       if (/^Testing \S+ filter/)
 881         {
 882         $_ = <IN>;    # remove blank line
 883         next;
 884         }
 885       }
 886
 887     # remote IPv6 addrs vary
 888     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 889
 890     # openssl version variances
 891   # Error lines on stdout from SSL contain process id values and file names.
 892   # They also contain a source file name and line number, which may vary from
 893   # release to release.
 894
 895     next if /^SSL info:/;
 896     next if /SSL verify error: depth=0 error=certificate not trusted/;
 897     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 898     s/^\d+:error:\d+(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
 899
 900     # gnutls version variances
 901     next if /^Error in the pull function./;
 902
 903     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
 904     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
 905     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
 906     }
 907
 908   # ======== stderr ========
 909
 910   elsif ($is_stderr)
 911     {
 912     # The very first line of debugging output will vary
 913
 914     s/^Exim version .*/Exim version x.yz ..../;
 915
 916     # Debugging lines for Exim terminations
 917
 918     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 919
 920     # IP address lookups use gethostbyname() when IPv6 is not supported,
 921     # and gethostbyname2() or getipnodebyname() when it is.
 922
 923     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 924
 925     # drop gnutls version strings
 926     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 927     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 928
 929     # drop openssl version strings
 930     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 931     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 932
 933     # drop lookups
 934     next if /^Lookups \(built-in\):/;
 935     next if /^Loading lookup modules from/;
 936     next if /^Loaded \d+ lookup modules/;
 937     next if /^Total \d+ lookups/;
 938
 939     # drop compiler information
 940     next if /^Compiler:/;
 941
 942     # and the ugly bit
 943     # different libraries will have different numbers (possibly 0) of follow-up
 944     # lines, indenting with more data
 945     if (/^Library version:/) {
 946       while (1) {
 947         $_ = <IN>;
 948         next if /^\s/;
 949         goto RESET_AFTER_EXTRA_LINE_READ;
 950       }
 951     }
 952
 953     # drop other build-time controls emitted for debugging
 954     next if /^WHITELIST_D_MACROS:/;
 955     next if /^TRUSTED_CONFIG_LIST:/;
 956
 957     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 958     # with -be, privileges will have been dropped, so this will always
 959     # be the case
 960     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 961
 962     # We might not keep this check; rather than change all the tests, just
 963     # ignore it as long as it succeeds; then we only need to change the
 964     # TLS tests where tls_require_ciphers has been set.
 965     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 966       my $discard = <IN>;
 967       next;
 968     }
 969     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 970
 971     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
 972     next if /^macros_trusted overridden to true by whitelisting/;
 973
 974     # We have to omit the localhost ::1 address so that all is well in
 975     # the IPv4-only case.
 976
 977     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 978       if (/looked up these IP addresses/);
 979     next if /name=localhost address=::1/;
 980
 981     # drop pdkim debugging header
 982     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 983
 984     # Various other IPv6 lines must be omitted too
 985
 986     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 987     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 988     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 989     next if / in dns_ipv4_lookup?/;
 990
 991     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 992       {
 993       $_= <IN>;     # Gets "returning DNS_NODATA"
 994       next;
 995       }
 996
 997     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 998     # are unset, because tls ain't always there.
 999
1000     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1001                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1002
1003     # Skip auxiliary group lists because they will vary.
1004
1005     next if /auxiliary group list:/;
1006
1007     # Skip "extracted from gecos field" because the gecos field varies
1008
1009     next if /extracted from gecos field/;
1010
1011     # Skip "waiting for data on socket" and "read response data: size=" lines
1012     # because some systems pack more stuff into packets than others.
1013
1014     next if /waiting for data on socket/;
1015     next if /read response data: size=/;
1016
1017     # If Exim is compiled with readline support but it can't find the library
1018     # to load, there will be an extra debug line. Omit it.
1019
1020     next if /failed to load readline:/;
1021
1022     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1023     # O_CREAT; other's don't. In the latter case there is some debugging output
1024     # which is not present in the former. Skip the relevant lines (there are
1025     # two of them).
1026
1027     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1028       {
1029       $_ = <IN>;
1030       next;
1031       }
1032
1033     # Some tests turn on +expand debugging to check on expansions.
1034     # Unfortunately, the Received: expansion varies, depending on whether TLS
1035     # is compiled or not. So we must remove the relevant debugging if it is.
1036
1037     if (/^condition: def:tls_cipher/)
1038       {
1039       while (<IN>) { last if /^condition: def:sender_address/; }
1040       }
1041     elsif (/^expanding: Received: /)
1042       {
1043       while (<IN>) { last if !/^\s/; }
1044       }
1045
1046     # remote port numbers vary
1047     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1048
1049     # Skip hosts_require_dane checks when the options
1050     # are unset, because dane ain't always there.
1051
1052     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1053
1054     # SUPPORT_PROXY
1055     next if /host in hosts_proxy\?/;
1056
1057     # Experimental_International
1058     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1059
1060     # Environment cleaning
1061     next if /\w+ in keep_environment\? (yes|no)/;
1062
1063     # Sizes vary with test hostname
1064     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1065
1066     # Spool filesystem free space changes on different systems.
1067     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1068
1069     # Non-TLS builds have different expansions for received_header_text
1070     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1071       {
1072       $_ .= <IN>;
1073       s/\s+\}\}(?=\(Exim )/\}\} /;
1074       }
1075     if (/^  condition: def:tls_cipher$/)
1076       {
1077       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1078       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1079       }
1080
1081     # Not all platforms build with DKIM enabled
1082     next if /^PDKIM >> Body data for hash, canonicalized/;
1083
1084     #  Parts of DKIM-specific debug output depend on the time/date
1085     next if /^date:\w+,\{SP\}/;
1086     next if /^PDKIM \[[^[]+\] (Header hash|b) computed:/;
1087
1088     # Not all platforms support TCP Fast Open, and the compile omits the check
1089     if (s/\S+ in hosts_try_fastopen\? no \(option unset\)\n$//)
1090       {
1091       $_ .= <IN>;
1092       s/ \.\.\. >>> / ... /;
1093       s/Address family not supported by protocol family/Network Error/;
1094       s/Network is unreachable/Network Error/;
1095       }
1096
1097     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1098
1099     # When Exim is checking the size of directories for maildir, it uses
1100     # the check_dir_size() function to scan directories. Of course, the order
1101     # of the files that are obtained using readdir() varies from system to
1102     # system. We therefore buffer up debugging lines from check_dir_size()
1103     # and sort them before outputting them.
1104
1105     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1106       {
1107       push @saved, $_;
1108       }
1109     else
1110       {
1111       if (@saved > 0)
1112         {
1113         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1114           "to ensure consistency\n";
1115         @saved = sort(@saved);
1116         print MUNGED @saved;
1117         @saved = ();
1118         }
1119
1120       # Skip some lines that Exim puts out at the start of debugging output
1121       # because they will be different in different binaries.
1122
1123       print MUNGED
1124         unless (/^Berkeley DB: / ||
1125                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1126                 /^Authenticators:/ ||
1127                 /^Lookups:/ ||
1128                 /^Support for:/ ||
1129                 /^Routers:/ ||
1130                 /^Transports:/ ||
1131                 /^log selectors =/ ||
1132                 /^cwd=/ ||
1133                 /^Fixed never_users:/ ||
1134                 /^Configure owner:/ ||
1135                 /^Size of off_t:/
1136                 );
1137
1138
1139       }
1140
1141     next;
1142     }
1143
1144   # ======== log ========
1145
1146   elsif ($is_log)
1147     {
1148     # Berkeley DB version differences
1149     next if / Berkeley DB error: /;
1150     }
1151
1152   # ======== All files other than stderr ========
1153
1154   print MUNGED;
1155   }
1156
1157 close(IN);
1158 return $yield;
1159 }
1160
1161
1162
1163
1164 ##################################################
1165 #        Subroutine to interact with caller      #
1166 ##################################################
1167
1168 # Arguments: [0] the prompt string
1169 #            [1] if there is a U in the prompt and $force_update is true
1170 #            [2] if there is a C in the prompt and $force_continue is true
1171 # Returns:   returns the answer
1172
1173 sub interact {
1174   my ($prompt, $have_u, $have_c) = @_;
1175
1176   print $prompt;
1177
1178   if ($have_u) {
1179     print "... update forced\n";
1180     return 'u';
1181   }
1182
1183   if ($have_c) {
1184     print "... continue forced\n";
1185     return 'c';
1186   }
1187
1188   return lc <T>;
1189 }
1190
1191
1192
1193 ##################################################
1194 #    Subroutine to log in force_continue mode    #
1195 ##################################################
1196
1197 # In force_continue mode, we just want a terse output to a statically
1198 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1199 # all have mismatches, it will log multiple times.
1200 #
1201 # Arguments: [0] the logfile to append to
1202 #            [1] the testno that failed
1203 # Returns:   nothing
1204
1205
1206
1207 sub log_failure {
1208   my ($logfile, $testno, $detail) = @_;
1209
1210   open(my $fh, '>>', $logfile) or return;
1211
1212   print $fh "Test $testno "
1213         . (defined $detail ? "$detail " : '')
1214         . "failed\n";
1215 }
1216
1217 # Computer-readable summary results logfile
1218
1219 sub log_test {
1220   my ($logfile, $testno, $resultchar) = @_;
1221
1222   open(my $fh, '>>', $logfile) or return;
1223   print $fh "$testno $resultchar\n";
1224 }
1225
1226
1227
1228 ##################################################
1229 #    Subroutine to compare one output file       #
1230 ##################################################
1231
1232 # When an Exim server is part of the test, its output is in separate files from
1233 # an Exim client. The server data is concatenated with the client data as part
1234 # of the munging operation.
1235 #
1236 # Arguments:  [0] the name of the main raw output file
1237 #             [1] the name of the server raw output file or undef
1238 #             [2] where to put the munged copy
1239 #             [3] the name of the saved file
1240 #             [4] TRUE if this is a log file whose deliveries must be sorted
1241 #             [5] optionally, a custom munge command
1242 #
1243 # Returns:    0 comparison succeeded
1244 #             1 comparison failed; differences to be ignored
1245 #             2 comparison failed; files may have been updated (=> re-compare)
1246 #
1247 # Does not return if the user replies "Q" to a prompt.
1248
1249 sub check_file{
1250 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1251
1252 # If there is no saved file, the raw files must either not exist, or be
1253 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1254
1255 # we check if there is a flavour specific file, but we remember
1256 # the original file name as "generic"
1257 $sf_generic = $sf;
1258 $sf_flavour = "$sf_generic.$flavour";
1259 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1260
1261 if (! -e $sf_current)
1262   {
1263   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1264
1265   print "\n";
1266   print "** $rf is not empty\n" if (-s $rf);
1267   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1268
1269   for (;;)
1270     {
1271     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1272     tests_exit(1) if /^q?$/;
1273     if (/^c$/ && $force_continue) {
1274       log_failure($log_failed_filename, $testno, $rf);
1275       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1276     }
1277     return 1 if /^c$/i;
1278     last if (/^s$/);
1279     }
1280
1281   foreach $f ($rf, $rsf)
1282     {
1283     if (defined $f && -s $f)
1284       {
1285       print "\n";
1286       print "------------ $f -----------\n"
1287         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1288       system("$more '$f'");
1289       }
1290     }
1291
1292   print "\n";
1293   for (;;)
1294     {
1295     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1296     tests_exit(1) if /^q?$/;
1297     if (/^c$/ && $force_continue) {
1298       log_failure($log_failed_filename, $testno, $rf);
1299       log_test($log_summary_filename, $testno, 'F')
1300     }
1301     return 1 if /^c$/i;
1302     last if (/^u$/i);
1303     }
1304   }
1305
1306 #### $_
1307
1308 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1309 # was a request to create a saved file. First, create the munged file from any
1310 # data that does exist.
1311
1312 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1313 my($truncated) = munge($rf, $extra) if -e $rf;
1314
1315 # Append the raw server log, if it is non-empty
1316 if (defined $rsf && -e $rsf)
1317   {
1318   print MUNGED "\n******** SERVER ********\n";
1319   $truncated |= munge($rsf, $extra);
1320   }
1321 close(MUNGED);
1322
1323 # If a saved file exists, do the comparison. There are two awkward cases:
1324 #
1325 # If "*** truncated ***" was found in the new file, it means that a log line
1326 # was overlong, and truncated. The problem is that it may be truncated at
1327 # different points on different systems, because of different user name
1328 # lengths. We reload the file and the saved file, and remove lines from the new
1329 # file that precede "*** truncated ***" until we reach one that matches the
1330 # line that precedes it in the saved file.
1331 #
1332 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1333 # for an individual message might vary in their order from system to system, as
1334 # a result of parallel deliveries. We load the munged file and sort sequences
1335 # of delivery lines.
1336
1337 if (-e $sf_current)
1338   {
1339   # Deal with truncated text items
1340
1341   if ($truncated)
1342     {
1343     my(@munged, @saved, $i, $j, $k);
1344
1345     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1346     @munged = <MUNGED>;
1347     close(MUNGED);
1348     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1349     @saved = <SAVED>;
1350     close(SAVED);
1351
1352     $j = 0;
1353     for ($i = 0; $i < @munged; $i++)
1354       {
1355       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1356         {
1357         for (; $j < @saved; $j++)
1358           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1359         last if $j >= @saved;     # not found in saved
1360
1361         for ($k = $i - 1; $k >= 0; $k--)
1362           { last if $munged[$k] eq $saved[$j - 1]; }
1363
1364         last if $k <= 0;          # failed to find previous match
1365         splice @munged, $k + 1, $i - $k - 1;
1366         $i = $k + 1;
1367         }
1368       }
1369
1370     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1371     for ($i = 0; $i < @munged; $i++)
1372       { print MUNGED $munged[$i]; }
1373     close(MUNGED);
1374     }
1375
1376   # Deal with log sorting
1377
1378   if ($sortfile)
1379     {
1380     my(@munged, $i, $j);
1381
1382     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1383     @munged = <MUNGED>;
1384     close(MUNGED);
1385
1386     for ($i = 0; $i < @munged; $i++)
1387       {
1388       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1389         {
1390         for ($j = $i + 1; $j < @munged; $j++)
1391           {
1392           last if $munged[$j] !~
1393             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1394           }
1395         @temp = splice(@munged, $i, $j - $i);
1396         @temp = sort(@temp);
1397         splice(@munged, $i, 0, @temp);
1398         }
1399       }
1400
1401     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1402     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1403     for ($i = 0; $i < @munged; $i++)
1404       { print MUNGED $munged[$i]; }
1405     close(MUNGED);
1406     }
1407
1408   # Do the comparison
1409
1410   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1411
1412   # Handle comparison failure
1413
1414   print "** Comparison of $mf with $sf_current failed";
1415   system("$more test-cf");
1416
1417   print "\n";
1418   for (;;)
1419     {
1420     $_ = interact('Continue, Retry, Update current'
1421         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1422         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1423     tests_exit(1) if /^q?$/;
1424     if (/^c$/ && $force_continue) {
1425       log_failure($log_failed_filename, $testno, $sf_current);
1426       log_test($log_summary_filename, $testno, 'F')
1427     }
1428     return 1 if /^c$/i;
1429     return 2 if /^r$/i;
1430     last if (/^[us]$/i);
1431     }
1432   }
1433
1434 # Update or delete the saved file, and give the appropriate return code.
1435
1436 if (-s $mf)
1437   {
1438     my $sf = /^u/i ? $sf_current : $sf_flavour;
1439     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1440   }
1441 else
1442   {
1443     # if we deal with a flavour file, we can't delete it, because next time the generic
1444     # file would be used again
1445     if ($sf_current eq $sf_flavour) {
1446       open(FOO, ">$sf_current");
1447       close(FOO);
1448     }
1449     else {
1450       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1451     }
1452   }
1453
1454 return 2;
1455 }
1456
1457
1458
1459 ##################################################
1460 # Custom munges
1461 # keyed by name of munge; value is a ref to a hash
1462 # which is keyed by file, value a string to look for.
1463 # Usable files are:
1464 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1465 # Search strings starting with 's' do substitutions;
1466 # with '/' do line-skips.
1467 # Triggered by a scriptfile line "munge <name>"
1468 ##################################################
1469 $munges =
1470   { 'dnssec' =>
1471     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1472
1473     'gnutls_unexpected' =>
1474     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1475
1476     'gnutls_handshake' =>
1477     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1478
1479     'optional_events' =>
1480     { 'stdout' => '/event_action =/' },
1481
1482     'optional_ocsp' =>
1483     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1484
1485     'optional_cert_hostnames' =>
1486     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1487
1488     'loopback' =>
1489     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1490
1491     'scanfile_size' =>
1492     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1493
1494     'delay_1500' =>
1495     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1496
1497     'tls_anycipher' =>
1498     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1499
1500     'debug_pid' =>
1501     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1502
1503     'optional_dsn_info' =>
1504     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1505     },
1506
1507     'optional_config' =>
1508     { 'stdout' => '/^(
1509                   dkim_(canon|domain|private_key|selector|sign_headers|strict)
1510                   |gnutls_require_(kx|mac|protocols)
1511                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1512                   |hosts_(avoid|nopass|require|verify_avoid)_tls
1513                   |socks_proxy
1514                   |tls_[^ ]*
1515                   )($|[ ]=)/x' },
1516
1517     'sys_bindir' =>
1518     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1519
1520     'sync_check_data' =>
1521     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1522       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1523
1524     'debuglog_stdout' =>
1525     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1526                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1527     },
1528
1529     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1530     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1531   };
1532
1533
1534 sub max {
1535   my ($a, $b) = @_;
1536   return $a if ($a > $b);
1537   return $b;
1538 }
1539
1540 ##################################################
1541 #    Subroutine to check the output of a test    #
1542 ##################################################
1543
1544 # This function is called when the series of subtests is complete. It makes
1545 # use of check_file(), whose arguments are:
1546 #
1547 #  [0] the name of the main raw output file
1548 #  [1] the name of the server raw output file or undef
1549 #  [2] where to put the munged copy
1550 #  [3] the name of the saved file
1551 #  [4] TRUE if this is a log file whose deliveries must be sorted
1552 #  [5] an optional custom munge command
1553 #
1554 # Arguments: Optionally, name of a single custom munge to run.
1555 # Returns:   0 if the output compared equal
1556 #            1 if comparison failed; differences to be ignored
1557 #            2 if re-run needed (files may have been updated)
1558
1559 sub check_output{
1560 my($mungename) = $_[0];
1561 my($yield) = 0;
1562 my($munge) = $munges->{$mungename} if defined $mungename;
1563
1564 $yield = max($yield,  check_file("spool/log/paniclog",
1565                        "spool/log/serverpaniclog",
1566                        "test-paniclog-munged",
1567                        "paniclog/$testno", 0,
1568                        $munge->{paniclog}));
1569
1570 $yield = max($yield,  check_file("spool/log/rejectlog",
1571                        "spool/log/serverrejectlog",
1572                        "test-rejectlog-munged",
1573                        "rejectlog/$testno", 0,
1574                        $munge->{rejectlog}));
1575
1576 $yield = max($yield,  check_file("spool/log/mainlog",
1577                        "spool/log/servermainlog",
1578                        "test-mainlog-munged",
1579                        "log/$testno", $sortlog,
1580                        $munge->{mainlog}));
1581
1582 if (!$stdout_skip)
1583   {
1584   $yield = max($yield,  check_file("test-stdout",
1585                        "test-stdout-server",
1586                        "test-stdout-munged",
1587                        "stdout/$testno", 0,
1588                        $munge->{stdout}));
1589   }
1590
1591 if (!$stderr_skip)
1592   {
1593   $yield = max($yield,  check_file("test-stderr",
1594                        "test-stderr-server",
1595                        "test-stderr-munged",
1596                        "stderr/$testno", 0,
1597                        $munge->{stderr}));
1598   }
1599
1600 # Compare any delivered messages, unless this test is skipped.
1601
1602 if (! $message_skip)
1603   {
1604   my($msgno) = 0;
1605
1606   # Get a list of expected mailbox files for this script. We don't bother with
1607   # directories, just the files within them.
1608
1609   foreach $oldmail (@oldmails)
1610     {
1611     next unless $oldmail =~ /^mail\/$testno\./;
1612     print ">> EXPECT $oldmail\n" if $debug;
1613     $expected_mails{$oldmail} = 1;
1614     }
1615
1616   # If there are any files in test-mail, compare them. Note that "." and
1617   # ".." are automatically omitted by list_files_below().
1618
1619   @mails = list_files_below("test-mail");
1620
1621   foreach $mail (@mails)
1622     {
1623     next if $mail eq "test-mail/oncelog";
1624
1625     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1626     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1627
1628     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1629       {
1630       $msgno++;
1631       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1632       }
1633
1634     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1635     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1636       "mail/$testno.$saved_mail", 0,
1637       $munge->{mail}));
1638     delete $expected_mails{"mail/$testno.$saved_mail"};
1639     }
1640
1641   # Complain if not all expected mails have been found
1642
1643   if (scalar(keys %expected_mails) != 0)
1644     {
1645     foreach $key (keys %expected_mails)
1646       { print "** no test file found for $key\n"; }
1647
1648     for (;;)
1649       {
1650       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1651       tests_exit(1) if /^q?$/;
1652       if (/^c$/ && $force_continue) {
1653         log_failure($log_failed_filename, $testno, "missing email");
1654         log_test($log_summary_filename, $testno, 'F')
1655       }
1656       last if /^c$/;
1657
1658       # For update, we not only have to unlink the file, but we must also
1659       # remove it from the @oldmails vector, as otherwise it will still be
1660       # checked for when we re-run the test.
1661
1662       if (/^u$/)
1663         {
1664         foreach $key (keys %expected_mails)
1665           {
1666           my($i);
1667           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1668           for ($i = 0; $i < @oldmails; $i++)
1669             {
1670             if ($oldmails[$i] eq $key)
1671               {
1672               splice @oldmails, $i, 1;
1673               last;
1674               }
1675             }
1676           }
1677         last;
1678         }
1679       }
1680     }
1681   }
1682
1683 # Compare any remaining message logs, unless this test is skipped.
1684
1685 if (! $msglog_skip)
1686   {
1687   # Get a list of expected msglog files for this test
1688
1689   foreach $oldmsglog (@oldmsglogs)
1690     {
1691     next unless $oldmsglog =~ /^$testno\./;
1692     $expected_msglogs{$oldmsglog} = 1;
1693     }
1694
1695   # If there are any files in spool/msglog, compare them. However, we have
1696   # to munge the file names because they are message ids, which are
1697   # time dependent.
1698
1699   if (opendir(DIR, "spool/msglog"))
1700     {
1701     @msglogs = sort readdir(DIR);
1702     closedir(DIR);
1703
1704     foreach $msglog (@msglogs)
1705       {
1706       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1707       ($munged_msglog = $msglog) =~
1708         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1709           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1710       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
1711         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1712         $munge->{msglog}));
1713       delete $expected_msglogs{"$testno.$munged_msglog"};
1714       }
1715     }
1716
1717   # Complain if not all expected msglogs have been found
1718
1719   if (scalar(keys %expected_msglogs) != 0)
1720     {
1721     foreach $key (keys %expected_msglogs)
1722       {
1723       print "** no test msglog found for msglog/$key\n";
1724       ($msgid) = $key =~ /^\d+\.(.*)$/;
1725       foreach $cachekey (keys %cache)
1726         {
1727         if ($cache{$cachekey} eq $msgid)
1728           {
1729           print "** original msgid $cachekey\n";
1730           last;
1731           }
1732         }
1733       }
1734
1735     for (;;)
1736       {
1737       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1738       tests_exit(1) if /^q?$/;
1739       if (/^c$/ && $force_continue) {
1740         log_failure($log_failed_filename, $testno, "missing msglog");
1741         log_test($log_summary_filename, $testno, 'F')
1742       }
1743       last if /^c$/;
1744       if (/^u$/)
1745         {
1746         foreach $key (keys %expected_msglogs)
1747           {
1748           tests_exit(-1, "Failed to unlink msglog/$key")
1749             if !unlink("msglog/$key");
1750           }
1751         last;
1752         }
1753       }
1754     }
1755   }
1756
1757 return $yield;
1758 }
1759
1760
1761
1762 ##################################################
1763 #     Subroutine to run one "system" command     #
1764 ##################################################
1765
1766 # We put this in a subroutine so that the command can be reflected when
1767 # debugging.
1768 #
1769 # Argument: the command to be run
1770 # Returns:  nothing
1771
1772 sub run_system {
1773 my($cmd) = $_[0];
1774 if ($debug)
1775   {
1776   my($prcmd) = $cmd;
1777   $prcmd =~ s/; /;\n>> /;
1778   print ">> $prcmd\n";
1779   }
1780 system("$cmd");
1781 }
1782
1783
1784
1785 ##################################################
1786 #      Subroutine to run one script command      #
1787 ##################################################
1788
1789 # The <SCRIPT> file is open for us to read an optional return code line,
1790 # followed by the command line and any following data lines for stdin. The
1791 # command line can be continued by the use of \. Data lines are not continued
1792 # in this way. In all lines, the following substitutions are made:
1793 #
1794 # DIR    => the current directory
1795 # CALLER => the caller of this script
1796 #
1797 # Arguments: the current test number
1798 #            reference to the subtest number, holding previous value
1799 #            reference to the expected return code value
1800 #            reference to where to put the command name (for messages)
1801 #            auxiliary information returned from a previous run
1802 #
1803 # Returns:   0 the command was executed inline, no subprocess was run
1804 #            1 a non-exim command was run and waited for
1805 #            2 an exim command was run and waited for
1806 #            3 a command was run and not waited for (daemon, server, exim_lock)
1807 #            4 EOF was encountered after an initial return code line
1808 # Optionally also a second parameter, a hash-ref, with auxiliary information:
1809 #            exim_pid: pid of a run process
1810 #            munge: name of a post-script results munger
1811
1812 sub run_command{
1813 my($testno) = $_[0];
1814 my($subtestref) = $_[1];
1815 my($commandnameref) = $_[3];
1816 my($aux_info) = $_[4];
1817 my($yield) = 1;
1818
1819 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1820
1821 if (/^(\d+)\s*$/)                # Handle unusual return code
1822   {
1823   my($r) = $_[2];
1824   $$r = $1 << 8;
1825   $_ = <SCRIPT>;
1826   return 4 if !defined $_;       # Missing command
1827   $lineno++;
1828   }
1829
1830 chomp;
1831 $wait_time = 0;
1832
1833 # Handle concatenated command lines
1834
1835 s/\s+$//;
1836 while (substr($_, -1) eq"\\")
1837   {
1838   my($temp);
1839   $_ = substr($_, 0, -1);
1840   chomp($temp = <SCRIPT>);
1841   if (defined $temp)
1842     {
1843     $lineno++;
1844     $temp =~ s/\s+$//;
1845     $temp =~ s/^\s+//;
1846     $_ .= $temp;
1847     }
1848   }
1849
1850 # Do substitutions
1851
1852 do_substitute($testno);
1853 if ($debug) { printf ">> $_\n"; }
1854
1855 # Pass back the command name (for messages)
1856
1857 ($$commandnameref) = /^(\S+)/;
1858
1859 # Here follows code for handling the various different commands that are
1860 # supported by this script. The first group of commands are all freestanding
1861 # in that they share no common code and are not followed by any data lines.
1862
1863
1864 ###################
1865 ###################
1866
1867 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1868 # utility and to make DBM files for testing DBM lookups.
1869
1870 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1871   {
1872   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1873          "echo exim_dbmbuild exit code = \$?)" .
1874          ">>test-stdout");
1875   return 1;
1876   }
1877
1878
1879 # The "dump" command runs exim_dumpdb. On different systems, the output for
1880 # some types of dump may appear in a different order because it's just hauled
1881 # out of the DBM file. We can solve this by sorting. Ignore the leading
1882 # date/time, as it will be flattened later during munging.
1883
1884 if (/^dump\s+(\S+)/)
1885   {
1886   my($which) = $1;
1887   my(@temp);
1888   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1889   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1890   open(OUT, ">>test-stdout");
1891   print OUT "+++++++++++++++++++++++++++\n";
1892
1893   if ($which eq "retry")
1894     {
1895     $/ = "\n  ";
1896     @temp = <IN>;
1897     $/ = "\n";
1898
1899     @temp = sort {
1900                    my($aa) = split(' ', $a);
1901                    my($bb) = split(' ', $b);
1902                    return $aa cmp $bb;
1903                  } @temp;
1904
1905     foreach $item (@temp)
1906       {
1907       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1908       print OUT "  $item\n";
1909       }
1910     }
1911   else
1912     {
1913     @temp = <IN>;
1914     if ($which eq "callout")
1915       {
1916       @temp = sort {
1917                    my($aa) = substr $a, 21;
1918                    my($bb) = substr $b, 21;
1919                    return $aa cmp $bb;
1920                    } @temp;
1921       }
1922     print OUT @temp;
1923     }
1924
1925   close(IN);
1926   close(OUT);
1927   return 1;
1928   }
1929
1930
1931 # verbose comments start with ###
1932 if (/^###\s/) {
1933   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
1934     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
1935     say {$fh} $_;
1936   }
1937   return 0;
1938 }
1939
1940 # The "echo" command is a way of writing comments to the screen.
1941 if (/^echo\s+(.*)$/)
1942   {
1943   print "$1\n";
1944   return 0;
1945   }
1946
1947
1948 # The "exim_lock" command runs exim_lock in the same manner as "server",
1949 # but it doesn't use any input.
1950
1951 if (/^exim_lock\s+(.*)$/)
1952   {
1953   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1954   $server_pid = open SERVERCMD, "|$cmd" ||
1955     tests_exit(-1, "Failed to run $cmd\n");
1956
1957   # This gives the process time to get started; otherwise the next
1958   # process may not find it there when it expects it.
1959
1960   select(undef, undef, undef, 0.1);
1961   return 3;
1962   }
1963
1964
1965 # The "exinext" command runs exinext
1966
1967 if (/^exinext\s+(.*)/)
1968   {
1969   run_system("(./eximdir/exinext " .
1970     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1971     "-C $parm_cwd/test-config $1;" .
1972     "echo exinext exit code = \$?)" .
1973     ">>test-stdout");
1974   return 1;
1975   }
1976
1977
1978 # The "exigrep" command runs exigrep on the current mainlog
1979
1980 if (/^exigrep\s+(.*)/)
1981   {
1982   run_system("(./eximdir/exigrep " .
1983     "$1 $parm_cwd/spool/log/mainlog;" .
1984     "echo exigrep exit code = \$?)" .
1985     ">>test-stdout");
1986   return 1;
1987   }
1988
1989
1990 # The "eximstats" command runs eximstats on the current mainlog
1991
1992 if (/^eximstats\s+(.*)/)
1993   {
1994   run_system("(./eximdir/eximstats " .
1995     "$1 $parm_cwd/spool/log/mainlog;" .
1996     "echo eximstats exit code = \$?)" .
1997     ">>test-stdout");
1998   return 1;
1999   }
2000
2001
2002 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2003 # spool directory, to save Exim from re-creating it each time.
2004
2005 if (/^gnutls/)
2006   {
2007   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2008   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2009          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2010          "sudo chmod 0400 $gen_fn";
2011   return 1;
2012   }
2013
2014
2015 # The "killdaemon" command should ultimately follow the starting of any Exim
2016 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2017 # it outputting "Terminated" to the terminal when not in the background.
2018
2019 if (/^killdaemon/)
2020   {
2021   my $return_extra = {};
2022   if (exists $aux_info->{exim_pid})
2023     {
2024     $pid = $aux_info->{exim_pid};
2025     $return_extra->{exim_pid} = undef;
2026     print ">> killdaemon: recovered pid $pid\n" if $debug;
2027     if ($pid)
2028       {
2029       run_system("sudo /bin/kill -INT $pid");
2030       wait;
2031       }
2032     } else {
2033     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2034     if ($pid)
2035       {
2036       run_system("sudo /bin/kill -INT $pid");
2037       close DAEMONCMD;                                   # Waits for process
2038       }
2039     }
2040     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2041   return (1, $return_extra);
2042   }
2043
2044
2045 # The "millisleep" command is like "sleep" except that its argument is in
2046 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2047 # is used for.
2048
2049 elsif (/^millisleep\s+(.*)$/)
2050   {
2051   select(undef, undef, undef, $1/1000);
2052   return 0;
2053   }
2054
2055
2056 # The "munge" command selects one of a hardwired set of test-result modifications
2057 # to be made before result compares are run agains the golden set.  This lets
2058 # us account for test-system dependent things which only affect a few, but known,
2059 # test-cases.
2060 # Currently only the last munge takes effect.
2061
2062 if (/^munge\s+(.*)$/)
2063   {
2064   return (0, { munge => $1 });
2065   }
2066
2067
2068 # The "sleep" command does just that. For sleeps longer than 1 second we
2069 # tell the user what's going on.
2070
2071 if (/^sleep\s+(.*)$/)
2072   {
2073   if ($1 == 1)
2074     {
2075     sleep(1);
2076     }
2077   else
2078     {
2079     printf("  Test %d sleep $1 ", $$subtestref);
2080     for (1..$1)
2081       {
2082       print ".";
2083       sleep(1);
2084       }
2085     printf("\r  Test %d                            $cr", $$subtestref);
2086     }
2087   return 0;
2088   }
2089
2090
2091 # Various Unix management commands are recognized
2092
2093 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2094     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2095   {
2096   run_system("$_ >>test-stdout 2>>test-stderr");
2097   return 1;
2098   }
2099
2100
2101
2102 ###################
2103 ###################
2104
2105 # The next group of commands are also freestanding, but they are all followed
2106 # by data lines.
2107
2108
2109 # The "server" command starts up a script-driven server that runs in parallel
2110 # with the following exim command. Therefore, we want to run a subprocess and
2111 # not yet wait for it to complete. The waiting happens after the next exim
2112 # command, triggered by $server_pid being non-zero. The server sends its output
2113 # to a different file. The variable $server_opts, if not empty, contains
2114 # options to disable IPv4 or IPv6 if necessary.
2115 # This works because "server" swallows its stdin before waiting for a connection.
2116
2117 if (/^server\s+(.*)$/)
2118   {
2119   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2120   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2121   print ">> $cmd\n" if ($debug);
2122   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2123   SERVERCMD->autoflush(1);
2124   print ">> Server pid is $server_pid\n" if $debug;
2125   while (<SCRIPT>)
2126     {
2127     $lineno++;
2128     last if /^\*{4}\s*$/;
2129     print SERVERCMD;
2130     }
2131   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2132                             # because close() waits for the process.
2133
2134   # Interlock the server startup; otherwise the next
2135   # process may not find it there when it expects it.
2136   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2137   return 3;
2138   }
2139
2140
2141 # The "write" command is a way of creating files of specific sizes for
2142 # buffering tests, or containing specific data lines from within the script
2143 # (rather than hold lots of little files). The "catwrite" command does the
2144 # same, but it also copies the lines to test-stdout.
2145
2146 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2147   {
2148   my($cat) = defined $1;
2149   @sizes = ();
2150   @sizes = split /\s+/, $3 if defined $3;
2151   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2152
2153   if ($cat)
2154     {
2155     open CAT, ">>test-stdout" ||
2156       tests_exit(-1, "Failed to open test-stdout: $!");
2157     print CAT "==========\n";
2158     }
2159
2160   if (scalar @sizes > 0)
2161     {
2162     # Pre-data
2163
2164     while (<SCRIPT>)
2165       {
2166       $lineno++;
2167       last if /^\+{4}\s*$/;
2168       print FILE;
2169       print CAT if $cat;
2170       }
2171
2172     # Sized data
2173
2174     while (scalar @sizes > 0)
2175       {
2176       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2177       $leadin = '' if !defined $leadin;
2178       $leadin =~ s/_/ /g;
2179       $len -= length($leadin) + 1;
2180       while ($count-- > 0)
2181         {
2182         print FILE $leadin, "a" x $len, "\n";
2183         print CAT $leadin, "a" x $len, "\n" if $cat;
2184         }
2185       }
2186     }
2187
2188   # Post data, or only data if no sized data
2189
2190   while (<SCRIPT>)
2191     {
2192     $lineno++;
2193     last if /^\*{4}\s*$/;
2194     print FILE;
2195     print CAT if $cat;
2196     }
2197   close FILE;
2198
2199   if ($cat)
2200     {
2201     print CAT "==========\n";
2202     close CAT;
2203     }
2204
2205   return 0;
2206   }
2207
2208
2209 ###################
2210 ###################
2211
2212 # From this point on, script commands are implemented by setting up a shell
2213 # command in the variable $cmd. Shared code to run this command and handle its
2214 # input and output follows.
2215
2216 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2217 # program that plays the part of an email client. We also have the availability
2218 # of running Perl for doing one-off special things. Note that all these
2219 # commands expect stdin data to be supplied.
2220
2221 if (/^client/ || /^(sudo\s+)?perl\b/)
2222   {
2223   s"client"./bin/client";
2224   $cmd = "$_ >>test-stdout 2>>test-stderr";
2225   }
2226
2227 # For the "exim" command, replace the text "exim" with the path for the test
2228 # binary, plus -D options to pass over various parameters, and a -C option for
2229 # the testing configuration file. When running in the test harness, Exim does
2230 # not drop privilege when -C and -D options are present. To run the exim
2231 # command as root, we use sudo.
2232
2233 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2234   {
2235   $args = $6;
2236   my($envset) = (defined $1)? $1      : '';
2237   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2238   my($special)= (defined $5)? $5      : '';
2239   $wait_time  = (defined $2)? $2      : 0;
2240
2241   # Return 2 rather than 1 afterwards
2242
2243   $yield = 2;
2244
2245   # Update the test number
2246
2247   $$subtestref = $$subtestref + 1;
2248   printf("  Test %d       $cr", $$subtestref);
2249
2250   # Copy the configuration file, making the usual substitutions.
2251
2252   open (IN, "$parm_cwd/confs/$testno") ||
2253     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2254   open (OUT, ">test-config") ||
2255     tests_exit(-1, "Couldn't open test-config: $!\n");
2256   while (<IN>)
2257     {
2258     do_substitute($testno);
2259     print OUT;
2260     }
2261   close(IN);
2262   close(OUT);
2263
2264   # The string $msg1 in args substitutes the message id of the first
2265   # message on the queue, and so on. */
2266
2267   if ($args =~ /\$msg/)
2268     {
2269     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
2270                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2271                    "-C $parm_cwd/test-config |";
2272     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
2273     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
2274     my(@msglist) = ();
2275     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
2276     close(QLIST);
2277     # We need the message ids sorted in ascending order.
2278     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2279     # PIDs are randomized, so sorting just the whole PID doesn't work.
2280     # We do the Schartz' transformation here (sort on
2281     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2282     @msglist = map { $_->[0] }
2283                sort { $a->[1] cmp $b->[1] }
2284                map { [$_, join '', (split '-', $_)[0,2]] } @msglist;
2285
2286     # Done backwards just in case there are more than 9
2287
2288     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2289     if ( $args =~ /\$msg\d/ )
2290       {
2291       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2292         unless $force_continue;
2293       }
2294     }
2295
2296   # If -d is specified in $optargs, remove it from $args; i.e. let
2297   # the command line for runtest override. Then run Exim.
2298
2299   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2300
2301   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2302
2303   $cmd = "$envset$sudo$opt_valgrind" .
2304          "$parm_cwd/eximdir/exim$special$optargs " .
2305          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2306          "-C $parm_cwd/test-config $args " .
2307          ">>test-stdout 2>>test-stderr";
2308   # If the command is starting an Exim daemon, we run it in the same
2309   # way as the "server" command above, that is, we don't want to wait
2310   # for the process to finish. That happens when "killdaemon" is obeyed later
2311   # in the script. We also send the stderr output to test-stderr-server. The
2312   # daemon has its log files put in a different place too (by configuring with
2313   # log_file_path). This requires the  directory to be set up in advance.
2314   #
2315   # There are also times when we want to run a non-daemon version of Exim
2316   # (e.g. a queue runner) with the server configuration. In this case,
2317   # we also define -DNOTDAEMON.
2318
2319   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2320     {
2321     $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2322     if ($debug) { printf ">> daemon: $cmd\n"; }
2323     run_system("sudo mkdir spool/log 2>/dev/null");
2324     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2325
2326     # Before running the command, convert the -bd option into -bdf so that an
2327     # Exim daemon doesn't double fork. This means that when we wait close
2328     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2329     # file is written to the spool directory, in case the Exim binary was
2330     # built with PID_FILE_PATH pointing somewhere else.
2331
2332     if ($cmd =~ /\s-oP\s/)
2333       {
2334       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2335       $cmd =~ s!\s-bd\s! -bdf !;
2336       }
2337     else
2338       {
2339       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2340       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2341       }
2342     print ">> |${cmd}-server\n" if ($debug);
2343     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2344     DAEMONCMD->autoflush(1);
2345     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2346
2347     # Interlock with daemon startup
2348     while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2349     return 3;                                     # Don't wait
2350     }
2351   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2352     {
2353
2354     # The port and the $dynamic_socket was already allocated while parsing the
2355     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2356
2357     my $listen_port = $1;
2358     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2359     run_system("sudo mkdir spool/log 2>/dev/null");
2360     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2361
2362     my $pid = fork();
2363     if (not defined $pid) { die "** fork failed: $!\n" }
2364     if (not $pid) {
2365       close(STDIN);
2366       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2367       close($dynamic_socket);
2368       print "[$$]>> ${cmd}-server\n" if ($debug);
2369       exec "exec ${cmd}-server";
2370       die "Can't exec ${cmd}-server: $!\n";
2371     }
2372     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2373     select(undef, undef, undef, 0.3);             # Let the daemon get going
2374     return (3, { exim_pid => $pid });             # Don't wait
2375     }
2376   }
2377
2378 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2379 # One script line is read and fork-exec'd.  The PID is stored for a later
2380 # killdaemon.
2381
2382 elsif (/^background$/)
2383   {
2384   my $line;
2385 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2386
2387   $_ = <SCRIPT>; $lineno++;
2388   chomp;
2389   $line = $_;
2390   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2391
2392   my $pid = fork();
2393   if (not defined $pid) { die "** fork failed: $!\n" }
2394   if (not $pid) {
2395     print "[$$]>> ${line}\n" if ($debug);
2396     close(STDIN);
2397     open(STDIN, "<", "test-stdout");
2398     close(STDOUT);
2399     open(STDOUT, ">>", "test-stdout");
2400     close(STDERR);
2401     open(STDERR, ">>", "test-stderr-server");
2402     exec "exec ${line}";
2403     exit(1);
2404   }
2405
2406 #  open(my $fh, ">", $pidfile) ||
2407 #      tests_exit(-1, "Failed to open $pidfile: $!");
2408 #  printf($fh, "%d\n", $pid);
2409 #  close($fh);
2410
2411   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2412   select(undef, undef, undef, 0.3);             # Let the daemon get going
2413   return (3, { exim_pid => $pid });             # Don't wait
2414   }
2415
2416
2417
2418 # Unknown command
2419
2420 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2421
2422
2423 # Run the command, with stdin connected to a pipe, and write the stdin data
2424 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2425 # the terminating newline (and the \NONL\). If the command contains
2426 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2427 # for the stderr file. See comment above about the use of -DSERVER.
2428
2429 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2430 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2431 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2432
2433 CMD->autoflush(1);
2434 while (<SCRIPT>)
2435   {
2436   $lineno++;
2437   last if /^\*{4}\s*$/;
2438   do_substitute($testno);
2439   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2440   }
2441
2442 # For timeout tests, wait before closing the pipe; we expect a
2443 # SIGPIPE error in this case.
2444
2445 if ($wait_time > 0)
2446   {
2447   printf("  Test %d sleep $wait_time ", $$subtestref);
2448   while ($wait_time-- > 0)
2449     {
2450     print ".";
2451     sleep(1);
2452     }
2453   printf("\r  Test %d                                       $cr", $$subtestref);
2454   }
2455
2456 $sigpipehappened = 0;
2457 close CMD;                # Waits for command to finish
2458 return $yield;            # Ran command and waited
2459 }
2460
2461
2462
2463
2464 ###############################################################################
2465 ###############################################################################
2466
2467 # Here begins the Main Program ...
2468
2469 ###############################################################################
2470 ###############################################################################
2471
2472
2473 autoflush STDOUT 1;
2474 print "Exim tester $testversion\n";
2475
2476 # extend the PATH with .../sbin
2477 # we map all (.../bin) to (.../sbin:.../bin)
2478 $ENV{PATH} = do {
2479   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2480   join ':' => map { m{(.*)/bin$}
2481                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2482                 : ($_) }
2483       split /:/, $ENV{PATH};
2484 };
2485
2486 ##################################################
2487 #      Some tests check created file modes       #
2488 ##################################################
2489
2490 umask 022;
2491
2492
2493 ##################################################
2494 #       Check for the "less" command             #
2495 ##################################################
2496
2497 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2498
2499
2500
2501 ##################################################
2502 #        Check for sudo access to root           #
2503 ##################################################
2504
2505 print "You need to have sudo access to root to run these tests. Checking ...\n";
2506 if (system('sudo true >/dev/null') != 0)
2507   {
2508   die "** Test for sudo failed: testing abandoned.\n";
2509   }
2510 else
2511   {
2512   print "Test for sudo OK\n";
2513   }
2514
2515
2516
2517 ##################################################
2518 #      See if an Exim binary has been given      #
2519 ##################################################
2520
2521 # If the first character of the first argument is '/', the argument is taken
2522 # as the path to the binary. If the first argument does not start with a
2523 # '/' but exists in the file system, it's assumed to be the Exim binary.
2524
2525 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2526 print "Exim binary is $parm_exim\n" if $parm_exim ne '';
2527
2528
2529
2530 ##################################################
2531 # Sort out options and which tests are to be run #
2532 ##################################################
2533
2534 # There are a few possible options for the test script itself; after these, any
2535 # options are passed on to Exim calls within the tests. Typically, this is used
2536 # to turn on Exim debugging while setting up a test.
2537
2538 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2539   {
2540   my($arg) = shift @ARGV;
2541   if ($optargs eq '')
2542     {
2543     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2544     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2545     if ($arg eq "-CONTINUE"){$force_continue = 1;
2546                              $more = "cat";
2547                              next; }
2548     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2549     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2550     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2551     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2552     if ($arg eq "-VALGRIND")   { $valgrind = 1; next; }
2553     if ($arg =~ /^-FLAVOU?R$/) { $flavour = shift; next; }
2554     }
2555   $optargs .= " $arg";
2556   }
2557
2558 # Any subsequent arguments are a range of test numbers.
2559
2560 if (@ARGV > 0)
2561   {
2562   $test_end = $test_start = $ARGV[0];
2563   $test_end = $ARGV[1] if (@ARGV > 1);
2564   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2565     if $test_end eq "+";
2566   die "** Test numbers out of order\n" if ($test_end < $test_start);
2567   }
2568
2569
2570 ##################################################
2571 #      Make the command's directory current      #
2572 ##################################################
2573
2574 # After doing so, we find its absolute path name.
2575
2576 $cwd = $0;
2577 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2578 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2579 $parm_cwd = Cwd::getcwd();
2580
2581
2582 ##################################################
2583 #     Search for an Exim binary to test          #
2584 ##################################################
2585
2586 # If an Exim binary hasn't been provided, try to find one. We can handle the
2587 # case where exim-testsuite is installed alongside Exim source directories. For
2588 # PH's private convenience, if there's a directory just called "exim4", that
2589 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2590 # releases.
2591
2592 # If $parm_exim is still empty, ask the caller
2593
2594 if ($parm_exim eq '')
2595   {
2596   print "** Did not find an Exim binary to test\n";
2597   for ($i = 0; $i < 5; $i++)
2598     {
2599     my($trybin);
2600     print "** Enter pathname for Exim binary: ";
2601     chomp($trybin = <STDIN>);
2602     if (-e $trybin)
2603       {
2604       $parm_exim = $trybin;
2605       last;
2606       }
2607     else
2608       {
2609       print "** $trybin does not exist\n";
2610       }
2611     }
2612   die "** Too many tries\n" if $parm_exim eq '';
2613   }
2614
2615
2616
2617 ##################################################
2618 #          Find what is in the binary            #
2619 ##################################################
2620
2621 # deal with TRUSTED_CONFIG_LIST restrictions
2622 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2623 open (IN, "$parm_cwd/confs/0000") ||
2624   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2625 open (OUT, ">test-config") ||
2626   tests_exit(-1, "Couldn't open test-config: $!\n");
2627 while (<IN>) { print OUT; }
2628 close(IN);
2629 close(OUT);
2630
2631 print("Probing with config file: $parm_cwd/test-config\n");
2632
2633 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2634 chomp(my @eximinfo = `$eximinfo 2>&1`);
2635 die "$0: Can't run $eximinfo\n" if $? == -1;
2636
2637 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2638 foreach (@eximinfo)
2639   {
2640   if (my ($version) = /^Exim version (\S+)/) {
2641     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2642     if (defined $git and $? == 0) {
2643       chomp $git;
2644       $version =~ s/^\d+\K\./_/;
2645       $git =~ s/^exim-//i;
2646       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2647       print <<___
2648
2649 *** Version mismatch
2650 *** Exim binary: $version
2651 *** Git        : $git
2652
2653 ___
2654         if not $version eq $git;
2655     }
2656   }
2657   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2658   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2659   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2660   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2661         if /^Configure owner:\s*(\d+):(\d+)/;
2662   print if /wrong owner/;
2663   }
2664
2665 if (not defined $parm_eximuser) {
2666   die <<XXX, map { "|$_\n" } @eximinfo;
2667 Unable to extract exim_user from binary.
2668 Check if Exim refused to run; if so, consider:
2669   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2670 If debug permission denied, are you in the exim group?
2671 Failing to get information from binary.
2672 Output from $eximinfo:
2673 XXX
2674
2675 }
2676
2677 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2678 else { $parm_exim_uid = getpwnam($parm_eximuser); }
2679
2680 if (defined $parm_eximgroup)
2681   {
2682   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2683     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2684   }
2685
2686 # check the permissions on the TRUSTED_CONFIG_LIST
2687 if (defined $parm_trusted_config_list)
2688   {
2689   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2690     if not -f $parm_trusted_config_list;
2691
2692   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2693     if 02 & (stat _)[2];
2694
2695   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2696   (stat _)[1],
2697     scalar(getgrgid 0), scalar(getgrgid $>)
2698     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2699
2700   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2701   scalar(getpwuid 0), scalar(getpwuid $>)
2702      if (not (-o _ or (stat _)[4] == 0));
2703
2704   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2705   my $test_config = getcwd() . '/test-config';
2706   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2707   if not grep { /^$test_config$/ } <TCL>;
2708   }
2709 else
2710   {
2711   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2712   }
2713
2714 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2715         if $parm_configure_owner != $>;
2716
2717 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2718         if 0020 & (stat "$parm_cwd/test-config")[2]
2719         and $parm_configure_group != $);
2720
2721
2722 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2723   die "** Cannot run $parm_exim: $!\n";
2724
2725 print "-" x 78, "\n";
2726
2727 while (<EXIMINFO>)
2728   {
2729   my(@temp);
2730
2731   if (/^(Exim|Library) version/) { print; }
2732
2733   elsif (/^Size of off_t: (\d+)/)
2734     {
2735     print;
2736     $have_largefiles = 1 if $1 > 4;
2737     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2738         if ($1 > 32);
2739     }
2740
2741   elsif (/^Support for: (.*)/)
2742     {
2743     print;
2744     @temp = split /(\s+)/, $1;
2745     push(@temp, ' ');
2746     %parm_support = @temp;
2747     }
2748
2749   elsif (/^Lookups \(built-in\): (.*)/)
2750     {
2751     print;
2752     @temp = split /(\s+)/, $1;
2753     push(@temp, ' ');
2754     %parm_lookups = @temp;
2755     }
2756
2757   elsif (/^Authenticators: (.*)/)
2758     {
2759     print;
2760     @temp = split /(\s+)/, $1;
2761     push(@temp, ' ');
2762     %parm_authenticators = @temp;
2763     }
2764
2765   elsif (/^Routers: (.*)/)
2766     {
2767     print;
2768     @temp = split /(\s+)/, $1;
2769     push(@temp, ' ');
2770     %parm_routers = @temp;
2771     }
2772
2773   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2774   # that the basic transport name is set, and then the name with each of the
2775   # options.
2776
2777   elsif (/^Transports: (.*)/)
2778     {
2779     print;
2780     @temp = split /(\s+)/, $1;
2781     my($i,$k);
2782     push(@temp, ' ');
2783     %parm_transports = @temp;
2784     foreach $k (keys %parm_transports)
2785       {
2786       if ($k =~ "/")
2787         {
2788         @temp = split /\//, $k;
2789         $parm_transports{$temp[0]} = " ";
2790         for ($i = 1; $i < @temp; $i++)
2791           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2792         }
2793       }
2794     }
2795   }
2796 close(EXIMINFO);
2797 print "-" x 78, "\n";
2798
2799 unlink("$parm_cwd/test-config");
2800
2801 ##################################################
2802 #    Check for SpamAssassin and ClamAV           #
2803 ##################################################
2804
2805 # These are crude tests. If they aren't good enough, we'll have to improve
2806 # them, for example by actually passing a message through spamc or clamscan.
2807
2808 if (defined $parm_support{Content_Scanning})
2809   {
2810   my $sock = new FileHandle;
2811
2812   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2813     {
2814     print "The spamc command works:\n";
2815
2816     # This test for an active SpamAssassin is courtesy of John Jetmore.
2817     # The tests are hard coded to localhost:783, so no point in making
2818     # this test flexible like the clamav test until the test scripts are
2819     # changed.  spamd doesn't have the nice PING/PONG protocol that
2820     # clamd does, but it does respond to errors in an informative manner,
2821     # so use that.
2822
2823     my($sint,$sport) = ('127.0.0.1',783);
2824     eval
2825       {
2826       my $sin = sockaddr_in($sport, inet_aton($sint))
2827           or die "** Failed packing $sint:$sport\n";
2828       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2829           or die "** Unable to open socket $sint:$sport\n";
2830
2831       local $SIG{ALRM} =
2832           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2833       alarm(5);
2834       connect($sock, $sin)
2835           or die "** Unable to connect to socket $sint:$sport\n";
2836       alarm(0);
2837
2838       select((select($sock), $| = 1)[0]);
2839       print $sock "bad command\r\n";
2840
2841       $SIG{ALRM} =
2842           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2843       alarm(10);
2844       my $res = <$sock>;
2845       alarm(0);
2846
2847       $res =~ m|^SPAMD/|
2848           or die "** Did not get SPAMD from socket $sint:$sport. "
2849                 ."It said: $res\n";
2850       };
2851     alarm(0);
2852     if($@)
2853       {
2854       print "  $@";
2855       print "  Assume SpamAssassin (spamd) is not running\n";
2856       }
2857     else
2858       {
2859       $parm_running{SpamAssassin} = ' ';
2860       print "  SpamAssassin (spamd) seems to be running\n";
2861       }
2862     }
2863   else
2864     {
2865     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2866     }
2867
2868   # For ClamAV, we need to find the clamd socket for use in the Exim
2869   # configuration. Search for the clamd configuration file.
2870
2871   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2872     {
2873     my($f, $clamconf, $test_prefix);
2874
2875     print "The clamscan command works";
2876
2877     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2878     $test_prefix = '' if !defined $test_prefix;
2879
2880     foreach $f ("$test_prefix/etc/clamd.conf",
2881                 "$test_prefix/usr/local/etc/clamd.conf",
2882                 "$test_prefix/etc/clamav/clamd.conf", '')
2883       {
2884       if (-e $f)
2885         {
2886         $clamconf = $f;
2887         last;
2888         }
2889       }
2890
2891     # Read the ClamAV configuration file and find the socket interface.
2892
2893     if ($clamconf ne '')
2894       {
2895       my $socket_domain;
2896       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2897       while (<IN>)
2898         {
2899         if (/^LocalSocket\s+(.*)/)
2900           {
2901           $parm_clamsocket = $1;
2902           $socket_domain = AF_UNIX;
2903           last;
2904           }
2905         if (/^TCPSocket\s+(\d+)/)
2906           {
2907           if (defined $parm_clamsocket)
2908             {
2909             $parm_clamsocket .= " $1";
2910             $socket_domain = AF_INET;
2911             last;
2912             }
2913           else
2914             {
2915             $parm_clamsocket = " $1";
2916             }
2917           }
2918         elsif (/^TCPAddr\s+(\S+)/)
2919           {
2920           if (defined $parm_clamsocket)
2921             {
2922             $parm_clamsocket = $1 . $parm_clamsocket;
2923             $socket_domain = AF_INET;
2924             last;
2925             }
2926           else
2927             {
2928             $parm_clamsocket = $1;
2929             }
2930           }
2931         }
2932       close(IN);
2933
2934       if (defined $socket_domain)
2935         {
2936         print ":\n  The clamd socket is $parm_clamsocket\n";
2937         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2938         eval
2939           {
2940           my $socket;
2941           if ($socket_domain == AF_UNIX)
2942             {
2943             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2944             }
2945           elsif ($socket_domain == AF_INET)
2946             {
2947             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2948             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2949             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2950             }
2951           else
2952             {
2953             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2954             }
2955           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2956           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2957           alarm(5);
2958           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2959           alarm(0);
2960
2961           my $ofh = select $sock; $| = 1; select $ofh;
2962           print $sock "PING\n";
2963
2964           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2965           alarm(10);
2966           my $res = <$sock>;
2967           alarm(0);
2968
2969           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2970           };
2971         alarm(0);
2972
2973         if($@)
2974           {
2975           print "  $@";
2976           print "  Assume ClamAV is not running\n";
2977           }
2978         else
2979           {
2980           $parm_running{ClamAV} = ' ';
2981           print "  ClamAV seems to be running\n";
2982           }
2983         }
2984       else
2985         {
2986         print ", but the socket for clamd could not be determined\n";
2987         print "Assume ClamAV is not running\n";
2988         }
2989       }
2990
2991     else
2992       {
2993       print ", but I can't find a configuration for clamd\n";
2994       print "Assume ClamAV is not running\n";
2995       }
2996     }
2997   }
2998
2999
3000 ##################################################
3001 #       Check for redis                          #
3002 ##################################################
3003 if (defined $parm_lookups{redis})
3004   {
3005   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3006     {
3007     print "The redis-server command works\n";
3008     $parm_running{redis} = ' ';
3009     }
3010   else
3011     {
3012     print "The redis-server command failed: assume Redis not installed\n";
3013     }
3014   }
3015
3016 ##################################################
3017 #         Test for the basic requirements        #
3018 ##################################################
3019
3020 # This test suite assumes that Exim has been built with at least the "usual"
3021 # set of routers, transports, and lookups. Ensure that this is so.
3022
3023 $missing = '';
3024
3025 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3026
3027 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3028 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3029 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3030 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3031
3032 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3033 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3034 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3035 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3036
3037 if ($missing ne '')
3038   {
3039   print "\n";
3040   print "** Many features can be included or excluded from Exim binaries.\n";
3041   print "** This test suite requires that Exim is built to contain a certain\n";
3042   print "** set of basic facilities. It seems that some of these are missing\n";
3043   print "** from the binary that is under test, so the test cannot proceed.\n";
3044   print "** The missing facilities are:\n";
3045   print "$missing";
3046   die "** Test script abandoned\n";
3047   }
3048
3049
3050 ##################################################
3051 #      Check for the auxiliary programs          #
3052 ##################################################
3053
3054 # These are always required:
3055
3056 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3057            "fakens", "iefbr14", "server")
3058   {
3059   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3060   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3061   if (!-e "bin/$prog")
3062     {
3063     print "\n";
3064     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3065     die "** Test script abandoned\n";
3066     }
3067   }
3068
3069 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3070 # compiled on systems where we don't know how to. However, if Exim does not
3071 # have that functionality compiled, we needn't bother.
3072
3073 $dlfunc_deleted = 0;
3074 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3075   {
3076   delete $parm_support{Expand_dlfunc};
3077   $dlfunc_deleted = 1;
3078   }
3079
3080
3081 ##################################################
3082 #          Find environmental details            #
3083 ##################################################
3084
3085 # Find the caller of this program.
3086
3087 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3088  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3089
3090 $pwpw = $pwpw;       # Kill Perl warnings
3091 $pwquota = $pwquota;
3092 $pwcomm = $pwcomm;
3093
3094 $parm_caller_group = getgrgid($parm_caller_gid);
3095
3096 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3097 print "Home directory is $parm_caller_home\n";
3098
3099 unless (defined $parm_eximgroup)
3100   {
3101   print "Unable to derive \$parm_eximgroup.\n";
3102   die "** ABANDONING.\n";
3103   }
3104
3105 print "You need to be in the Exim group to run these tests. Checking ...";
3106
3107 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3108   {
3109   print " OK\n";
3110   }
3111 else
3112   {
3113   print "\nOh dear, you are not in the Exim group.\n";
3114   die "** Testing abandoned.\n";
3115   }
3116
3117 # Find this host's IP addresses - there may be many, of course, but we keep
3118 # one of each type (IPv4 and IPv6).
3119
3120 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3121   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3122 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3123   {
3124   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3125     {
3126     next if $1 =~ /^(?:127|10)\./;
3127     $parm_ipv4 = $1;
3128     }
3129
3130   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3131     {
3132     next if $1 eq '::1' or $1 =~ /^fe80/i;
3133     $parm_ipv6 = $1;
3134     }
3135   }
3136 close(IFCONFIG);
3137
3138 # Use private IP addresses if there are no public ones.
3139
3140 # If either type of IP address is missing, we need to set the value to
3141 # something other than empty, because that wrecks the substitutions. The value
3142 # is reflected, so use a meaningful string. Set appropriate options for the
3143 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3144 # available, so things will go wrong if there is no IPv4 address. The lack
3145 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3146 # and $have_ipv6 false.
3147
3148 if (not $parm_ipv4)
3149   {
3150   $have_ipv4 = 0;
3151   $parm_ipv4 = "<no IPv4 address found>";
3152   $server_opts .= " -noipv4";
3153   }
3154 elsif ($have_ipv4 == 0)
3155   {
3156   $parm_ipv4 = "<IPv4 testing disabled>";
3157   $server_opts .= " -noipv4";
3158   }
3159 else
3160   {
3161   $parm_running{IPv4} = " ";
3162   }
3163
3164 if (not $parm_ipv6)
3165   {
3166   $have_ipv6 = 0;
3167   $parm_ipv6 = "<no IPv6 address found>";
3168   $server_opts .= " -noipv6";
3169   delete($parm_support{IPv6});
3170   }
3171 elsif ($have_ipv6 == 0)
3172   {
3173   $parm_ipv6 = "<IPv6 testing disabled>";
3174   $server_opts .= " -noipv6";
3175   delete($parm_support{IPv6});
3176   }
3177 elsif (!defined $parm_support{IPv6})
3178   {
3179   $have_ipv6 = 0;
3180   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3181   $server_opts .= " -noipv6";
3182   }
3183 else
3184   {
3185   $parm_running{IPv6} = " ";
3186   }
3187
3188 print "IPv4 address is $parm_ipv4\n";
3189 print "IPv6 address is $parm_ipv6\n";
3190
3191 # For munging test output, we need the reversed IP addresses.
3192
3193 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3194   join(".", reverse(split /\./, $parm_ipv4));
3195
3196 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3197 if ($parm_ipv6 =~ /^[\da-f]/)
3198   {
3199   my(@comps) = split /:/, $parm_ipv6;
3200   my(@nibbles);
3201   foreach $comp (@comps)
3202     {
3203     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3204     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3205     }
3206   $parm_ipv6r = join(".", reverse(@nibbles));
3207   }
3208
3209 # Find the host name, fully qualified.
3210
3211 chomp($temp = `hostname`);
3212 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3213 if ($temp =~ /\./)
3214   {
3215   $parm_hostname = $temp;
3216   }
3217 else
3218   {
3219   $parm_hostname = (gethostbyname($temp))[0];
3220   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3221   }
3222 print "Hostname is $parm_hostname\n";
3223
3224 if ($parm_hostname !~ /\./)
3225   {
3226   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3227   }
3228
3229 if ($parm_hostname =~ /[[:upper:]]/)
3230   {
3231   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3232   }
3233
3234
3235
3236 ##################################################
3237 #     Create a testing version of Exim           #
3238 ##################################################
3239
3240 # We want to be able to run Exim with a variety of configurations. Normally,
3241 # the use of -C to change configuration causes Exim to give up its root
3242 # privilege (unless the caller is exim or root). For these tests, we do not
3243 # want this to happen. Also, we want Exim to know that it is running in its
3244 # test harness.
3245
3246 # We achieve this by copying the binary and patching it as we go. The new
3247 # binary knows it is a testing copy, and it allows -C and -D without loss of
3248 # privilege. Clearly, this file is dangerous to have lying around on systems
3249 # where there are general users with login accounts. To protect against this,
3250 # we put the new binary in a special directory that is accessible only to the
3251 # caller of this script, who is known to have sudo root privilege from the test
3252 # that was done above. Furthermore, we ensure that the binary is deleted at the
3253 # end of the test. First ensure the directory exists.
3254
3255 if (-d "eximdir")
3256   { unlink "eximdir/exim"; }     # Just in case
3257 else
3258   {
3259   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3260   system("sudo chgrp $parm_eximgroup eximdir");
3261   }
3262
3263 # The construction of the patched binary must be done as root, so we use
3264 # a separate script. As well as indicating that this is a test-harness binary,
3265 # the version number is patched to "x.yz" so that its length is always the
3266 # same. Otherwise, when it appears in Received: headers, it affects the length
3267 # of the message, which breaks certain comparisons.
3268
3269 die "** Unable to make patched exim: $!\n"
3270   if (system("sudo ./patchexim $parm_exim") != 0);
3271
3272 # From this point on, exits from the program must go via the subroutine
3273 # tests_exit(), so that suitable cleaning up can be done when required.
3274 # Arrange to catch interrupting signals, to assist with this.
3275
3276 $SIG{INT} = \&inthandler;
3277 $SIG{PIPE} = \&pipehandler;
3278
3279 # For some tests, we need another copy of the binary that is setuid exim rather
3280 # than root.
3281
3282 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3283        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3284        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3285        "sudo chmod 06755 eximdir/exim_exim");
3286
3287
3288 ##################################################
3289 #     Make copies of utilities we might need     #
3290 ##################################################
3291
3292 # Certain of the tests make use of some of Exim's utilities. We do not need
3293 # to be root to copy these.
3294
3295 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3296
3297 $dbm_build_deleted = 0;
3298 if (defined $parm_lookups{dbm} &&
3299     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3300   {
3301   delete $parm_lookups{dbm};
3302   $dbm_build_deleted = 1;
3303   }
3304
3305 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3306   {
3307   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3308   }
3309
3310 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3311   {
3312   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3313   }
3314
3315 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3316   {
3317   tests_exit(-1, "Failed to make a copy of exinext: $!");
3318   }
3319
3320 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3321   {
3322   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3323   }
3324
3325 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3326   {
3327   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3328   }
3329
3330
3331 ##################################################
3332 #    Check that the Exim user can access stuff   #
3333 ##################################################
3334
3335 # We delay this test till here so that we can check access to the actual test
3336 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3337
3338 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3339 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3340
3341 if ($parm_caller_uid eq $parm_exim_uid) {
3342   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3343                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3344 }
3345 if ($parm_caller_gid eq $parm_exim_gid) {
3346   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3347                 ."the same as caller's ($parm_caller) group as it confuses "
3348                 ."results analysis");
3349 }
3350
3351 print "The Exim user needs access to the test suite directory. Checking ...";
3352
3353 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3354   {
3355   my($why) = "unknown failure $rc";
3356   $rc >>= 8;
3357   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3358   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3359   $why = "Couldn't read auxiliary group list" if $rc == 3;
3360   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3361   $why = "Couldn't set gid" if $rc == 5;
3362   $why = "Couldn't set uid" if $rc == 6;
3363   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3364   print "\n** $why\n";
3365   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3366   }
3367 else
3368   {
3369   print " OK\n";
3370   }
3371
3372
3373 ##################################################
3374 #        Create a list of available tests        #
3375 ##################################################
3376
3377 # The scripts directory contains a number of subdirectories whose names are
3378 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3379 # from the first requires certain optional features to be included in the Exim
3380 # binary. These requirements are contained in a file called "REQUIRES" within
3381 # the directory. We scan all these tests, discarding those that cannot be run
3382 # because the current binary does not support the right facilities, and also
3383 # those that are outside the numerical range selected.
3384
3385 print "\nTest range is $test_start to $test_end (flavour $flavour)\n";
3386 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3387   if $dlfunc_deleted;
3388 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3389   if $dbm_build_deleted;
3390
3391 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
3392 @test_dirs = sort readdir(DIR);
3393 closedir(DIR);
3394
3395 # Remove . and .. and CVS from the list.
3396
3397 for ($i = 0; $i < @test_dirs; $i++)
3398   {
3399   my($d) = $test_dirs[$i];
3400   if ($d eq "." || $d eq ".." || $d eq "CVS")
3401     {
3402     splice @test_dirs, $i, 1;
3403     $i--;
3404     }
3405   }
3406
3407 # Scan for relevant tests
3408
3409 tests_exit(-1, "Failed to unlink $log_summary_filename")
3410   if (-e $log_summary_filename && !unlink($log_summary_filename));
3411 for ($i = 0; $i < @test_dirs; $i++)
3412   {
3413   my($testdir) = $test_dirs[$i];
3414   my($wantthis) = 1;
3415
3416   print ">>Checking $testdir\n" if $debug;
3417
3418   # Skip this directory if the first test is equal or greater than the first
3419   # test in the next directory.
3420
3421   next if ($i < @test_dirs - 1) &&
3422           ($test_start >= substr($test_dirs[$i+1], 0, 4));
3423
3424   # No need to carry on if the end test is less than the first test in this
3425   # subdirectory.
3426
3427   last if $test_end < substr($testdir, 0, 4);
3428
3429   # Check requirements, if any.
3430
3431   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
3432     {
3433     while (<REQUIRES>)
3434       {
3435       next if /^\s*$/;
3436       s/\s+$//;
3437       if (/^support (.*)$/)
3438         {
3439         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3440         }
3441       elsif (/^running (.*)$/)
3442         {
3443         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3444         }
3445       elsif (/^lookup (.*)$/)
3446         {
3447         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3448         }
3449       elsif (/^authenticators? (.*)$/)
3450         {
3451         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3452         }
3453       elsif (/^router (.*)$/)
3454         {
3455         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3456         }
3457       elsif (/^transport (.*)$/)
3458         {
3459         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3460         }
3461       else
3462         {
3463         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3464         }
3465       }
3466     close(REQUIRES);
3467     }
3468   else
3469     {
3470     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3471       unless $!{ENOENT};
3472     }
3473
3474   # Loop if we do not want the tests in this subdirectory.
3475
3476   if (!$wantthis)
3477     {
3478     chomp;
3479     print "Omitting tests in $testdir (missing $_)\n";
3480     }
3481
3482   # We want the tests from this subdirectory, provided they are in the
3483   # range that was selected.
3484
3485   opendir(SUBDIR, "scripts/$testdir") ||
3486     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3487   @testlist = sort readdir(SUBDIR);
3488   close(SUBDIR);
3489
3490   foreach $test (@testlist)
3491     {
3492     next if ($test !~ /^\d{4}(?:\.\d+)?$/);
3493     if (!$wantthis || $test < $test_start || $test > $test_end)
3494       {
3495       log_test($log_summary_filename, $test, '.');
3496       }
3497     else
3498       {
3499       push @test_list, "$testdir/$test";
3500       }
3501     }
3502   }
3503
3504 print ">>Test List: @test_list\n", if $debug;
3505
3506
3507 ##################################################
3508 #         Munge variable auxiliary data          #
3509 ##################################################
3510
3511 # Some of the auxiliary data files have to refer to the current testing
3512 # directory and other parameter data. The generic versions of these files are
3513 # stored in the aux-var-src directory. At this point, we copy each of them
3514 # to the aux-var directory, making appropriate substitutions. There aren't very
3515 # many of them, so it's easiest just to do this every time. Ensure the mode
3516 # is standardized, as this path is used as a test for the ${stat: expansion.
3517
3518 # A similar job has to be done for the files in the dnszones-src directory, to
3519 # make the fake DNS zones for testing. Most of the zone files are copied to
3520 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3521 # networks that are defined by parameter.
3522
3523 foreach $basedir ("aux-var", "dnszones")
3524   {
3525   system("sudo rm -rf $parm_cwd/$basedir");
3526   mkdir("$parm_cwd/$basedir", 0777);
3527   chmod(0755, "$parm_cwd/$basedir");
3528
3529   opendir(AUX, "$parm_cwd/$basedir-src") ||
3530     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3531   my(@filelist) = readdir(AUX);
3532   close(AUX);
3533
3534   foreach $file (@filelist)
3535     {
3536     my($outfile) = $file;
3537     next if $file =~ /^\./;
3538
3539     if ($file eq "db.ip4.V4NET")
3540       {
3541       $outfile = "db.ip4.$parm_ipv4_test_net";
3542       }
3543     elsif ($file eq "db.ip6.V6NET")
3544       {
3545       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3546       $" = '.';
3547       $outfile = "db.ip6.@nibbles";
3548       $" = ' ';
3549       }
3550
3551     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3552     open(IN, "$parm_cwd/$basedir-src/$file") ||
3553       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3554     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3555       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3556     while (<IN>)
3557       {
3558       do_substitute(0);
3559       print OUT;
3560       }
3561     close(IN);
3562     close(OUT);
3563     }
3564   }
3565
3566 # Set a user's shell, distinguishable from /bin/sh
3567
3568 symlink('/bin/sh' => 'aux-var/sh');
3569 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3570
3571 ##################################################
3572 #     Create fake DNS zones for this host        #
3573 ##################################################
3574
3575 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3576 # sure that there are forward and reverse registrations for this host, using
3577 # its real IP addresses. Dynamically created zone files achieve this.
3578
3579 if ($have_ipv4 || $have_ipv6)
3580   {
3581   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3582   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3583     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3584   print OUT "; This is a dynamically constructed fake zone file.\n" .
3585     "; The following line causes fakens to return PASS_ON\n" .
3586     "; for queries that it cannot answer\n\n" .
3587     "PASS ON NOT FOUND\n\n";
3588   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3589   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3590   print OUT "\n; End\n";
3591   close(OUT);
3592   }
3593
3594 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3595   {
3596   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3597   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3598     tests_exit(-1,
3599       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3600   print OUT "; This is a dynamically constructed fake zone file.\n" .
3601     "; The zone is $components[0].in-addr.arpa.\n\n" .
3602     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3603     "; End\n";
3604   close(OUT);
3605   }
3606
3607 if ($have_ipv6 && $parm_ipv6 ne "::1")
3608   {
3609   my($exp_v6) = $parm_ipv6;
3610   $exp_v6 =~ s/[^:]//g;
3611   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3612     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3613   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3614     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3615   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3616     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3617   } else {
3618     $exp_v6 = $parm_ipv6;
3619   }
3620   my(@components) = split /:/, $exp_v6;
3621   my(@nibbles) = reverse (split /\s*/, shift @components);
3622   my($sep) =  '';
3623
3624   $" = ".";
3625   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3626     tests_exit(-1,
3627       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3628   print OUT "; This is a dynamically constructed fake zone file.\n" .
3629     "; The zone is @nibbles.ip6.arpa.\n\n";
3630
3631   @components = reverse @components;
3632   foreach $c (@components)
3633     {
3634     $c = "0$c" until $c =~ /^..../;
3635     @nibbles = reverse(split /\s*/, $c);
3636     print OUT "$sep@nibbles";
3637     $sep = ".";
3638     }
3639
3640   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3641   close(OUT);
3642   $" = " ";
3643   }
3644
3645
3646
3647 ##################################################
3648 #    Create lists of mailboxes and message logs  #
3649 ##################################################
3650
3651 # We use these lists to check that a test has created the expected files. It
3652 # should be faster than looking for the file each time. For mailboxes, we have
3653 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3654 # is just a flat list of files.
3655
3656 @oldmails = list_files_below("mail");
3657 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3658 @oldmsglogs = readdir(DIR);
3659 closedir(DIR);
3660
3661
3662
3663 ##################################################
3664 #         Run the required tests                 #
3665 ##################################################
3666
3667 # Each test script contains a number of tests, separated by a line that
3668 # contains ****. We open input from the terminal so that we can read responses
3669 # to prompts.
3670
3671 if (not $force_continue) {
3672   # runtest needs to interact if we're not in continue
3673   # mode. It does so by communicate to /dev/tty
3674   open(T, "/dev/tty") or tests_exit(-1, "Failed to open /dev/tty: $!");
3675 }
3676
3677
3678 print "\nPress RETURN to run the tests: ";
3679 $_ = $force_continue ? "c" : <T>;
3680 print "\n";
3681
3682 $lasttestdir = '';
3683
3684 foreach $test (@test_list)
3685   {
3686   local($lineno) = 0;
3687   local($commandno) = 0;
3688   local($subtestno) = 0;
3689   (local $testno = $test) =~ s|.*/||;
3690   local($sortlog) = 0;
3691
3692   my($gnutls) = 0;
3693   my($docheck) = 1;
3694   my($thistestdir) = substr($test, 0, -5);
3695
3696   $dynamic_socket->close() if $dynamic_socket;
3697
3698   if ($lasttestdir ne $thistestdir)
3699     {
3700     $gnutls = 0;
3701     if (-s "scripts/$thistestdir/REQUIRES")
3702       {
3703       my($indent) = '';
3704       print "\n>>> The following tests require: ";
3705       open(IN, "scripts/$thistestdir/REQUIRES") ||
3706         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3707       while (<IN>)
3708         {
3709         $gnutls = 1 if /^support GnuTLS/;
3710         print $indent, $_;
3711         $indent = ">>>                              ";
3712         }
3713       close(IN);
3714       }
3715     }
3716   $lasttestdir = $thistestdir;
3717
3718   # Remove any debris in the spool directory and the test-mail directory
3719   # and also the files for collecting stdout and stderr. Then put back
3720   # the test-mail directory for appendfile deliveries.
3721
3722   system "sudo /bin/rm -rf spool test-*";
3723   system "mkdir test-mail 2>/dev/null";
3724
3725   # A privileged Exim will normally make its own spool directory, but some of
3726   # the tests run in unprivileged modes that don't always work if the spool
3727   # directory isn't already there. What is more, we want anybody to be able
3728   # to read it in order to find the daemon's pid.
3729
3730   system "mkdir spool; " .
3731          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3732          "sudo chmod 0755 spool";
3733
3734   # Empty the cache that keeps track of things like message id mappings, and
3735   # set up the initial sequence strings.
3736
3737   undef %cache;
3738   $next_msgid = "aX";
3739   $next_pid = 1234;
3740   $next_port = 1111;
3741   $message_skip = 0;
3742   $msglog_skip = 0;
3743   $stderr_skip = 0;
3744   $stdout_skip = 0;
3745   $rmfiltertest = 0;
3746   $is_ipv6test = 0;
3747   $TEST_STATE->{munge} = '';
3748
3749   # Remove the associative arrays used to hold checked mail files and msglogs
3750
3751   undef %expected_mails;
3752   undef %expected_msglogs;
3753
3754   # Open the test's script
3755   open(SCRIPT, "scripts/$test") ||
3756     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3757   # Run through the script once to set variables which should be global
3758   while (<SCRIPT>)
3759     {
3760     if (/^no_message_check/) { $message_skip = 1; next; }
3761     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3762     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3763     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3764     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3765     if (/^sortlog/)          { $sortlog = 1; next; }
3766     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
3767     }
3768   # Reset to beginning of file for per test interpreting/processing
3769   seek(SCRIPT, 0, 0);
3770
3771   # The first line in the script must be a comment that is used to identify
3772   # the set of tests as a whole.
3773
3774   $_ = <SCRIPT>;
3775   $lineno++;
3776   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3777   printf("%s %s", (substr $test, 5), (substr $_, 2));
3778
3779   # Loop for each of the subtests within the script. The variable $server_pid
3780   # is used to remember the pid of a "server" process, for which we do not
3781   # wait until we have waited for a subsequent command.
3782
3783   local($server_pid) = 0;
3784   for ($commandno = 1; !eof SCRIPT; $commandno++)
3785     {
3786     # Skip further leading comments and blank lines, handle the flag setting
3787     # commands, and deal with tests for IP support.
3788
3789     while (<SCRIPT>)
3790       {
3791       $lineno++;
3792       # Could remove these variable settings because they are already
3793       # set above, but doesn't hurt to leave them here.
3794       if (/^no_message_check/) { $message_skip = 1; next; }
3795       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3796       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3797       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3798       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3799       if (/^sortlog/)          { $sortlog = 1; next; }
3800
3801       if (/^need_largefiles/)
3802         {
3803         next if $have_largefiles;
3804         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3805         $docheck = 0;      # don't check output
3806         undef $_;          # pretend EOF
3807         last;
3808         }
3809
3810       if (/^need_ipv4/)
3811         {
3812         next if $have_ipv4;
3813         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3814         $docheck = 0;      # don't check output
3815         undef $_;          # pretend EOF
3816         last;
3817         }
3818
3819       if (/^need_ipv6/)
3820         {
3821         if ($have_ipv6)
3822           {
3823           $is_ipv6test = 1;
3824           next;
3825           }
3826         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3827         $docheck = 0;      # don't check output
3828         undef $_;          # pretend EOF
3829         last;
3830         }
3831
3832       if (/^need_move_frozen_messages/)
3833         {
3834         next if defined $parm_support{move_frozen_messages};
3835         print ">>> move frozen message support is needed for test $testno, " .
3836           "but is not\n>>> available: skipping\n";
3837         $docheck = 0;      # don't check output
3838         undef $_;          # pretend EOF
3839         last;
3840         }
3841
3842       last unless /^(?:#(?!##\s)|\s*$)/;
3843       }
3844     last if !defined $_;  # Hit EOF
3845
3846     my($subtest_startline) = $lineno;
3847
3848     # Now run the command. The function returns 0 for an inline command,
3849     # 1 if a non-exim command was run and waited for, 2 if an exim
3850     # command was run and waited for, and 3 if a command
3851     # was run and not waited for (usually a daemon or server startup).
3852
3853     my($commandname) = '';
3854     my($expectrc) = 0;
3855     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3856     my($cmdrc) = $?;
3857
3858     $0 = "[runtest $testno]";
3859
3860     if ($debug) {
3861       print ">> rc=$rc cmdrc=$cmdrc\n";
3862       if (defined $run_extra) {
3863         foreach my $k (keys %$run_extra) {
3864           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3865           print ">>   $k -> $v\n";
3866         }
3867       }
3868     }
3869     $run_extra = {} unless defined $run_extra;
3870     foreach my $k (keys %$run_extra) {
3871       if (exists $TEST_STATE->{$k}) {
3872         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3873         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3874       }
3875       if (defined $run_extra->{$k}) {
3876         $TEST_STATE->{$k} = $run_extra->{$k};
3877       } elsif (exists $TEST_STATE->{$k}) {
3878         delete $TEST_STATE->{$k};
3879       }
3880     }
3881
3882     # Hit EOF after an initial return code number
3883
3884     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3885
3886     # Carry on with the next command if we did not wait for this one. $rc == 0
3887     # if no subprocess was run; $rc == 3 if we started a process but did not
3888     # wait for it.
3889
3890     next if ($rc == 0 || $rc == 3);
3891
3892     # We ran and waited for a command. Check for the expected result unless
3893     # it died.
3894
3895     if ($cmdrc != $expectrc && !$sigpipehappened)
3896       {
3897       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3898       if (($cmdrc & 0xff) == 0)
3899         {
3900         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3901         }
3902       elsif (($cmdrc & 0xff00) == 0)
3903         { printf("** Killed by signal %d", $cmdrc & 255); }
3904       else
3905         { printf("** Status %x", $cmdrc); }
3906
3907       for (;;)
3908         {
3909         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3910         $_ = $force_continue ? "c" : <T>;
3911         tests_exit(1) if /^q?$/i;
3912         if (/^c$/ && $force_continue) {
3913           log_failure($log_failed_filename, $testno, "exit code unexpected");
3914           log_test($log_summary_filename, $testno, 'F')
3915         }
3916         if ($force_continue)
3917           {
3918           print "\nstderr tail:\n";
3919           print "===================\n";
3920           system("tail -20 test-stderr");
3921           print "===================\n";
3922           print "... continue forced\n";
3923           }
3924
3925         last if /^[rc]$/i;
3926         if (/^e$/i)
3927           {
3928           system("$more test-stderr");
3929           }
3930         elsif (/^o$/i)
3931           {
3932           system("$more test-stdout");
3933           }
3934         }
3935
3936       $retry = 1 if /^r$/i;
3937       $docheck = 0;
3938       }
3939
3940     # If the command was exim, and a listening server is running, we can now
3941     # close its input, which causes us to wait for it to finish, which is why
3942     # we didn't close it earlier.
3943
3944     if ($rc == 2 && $server_pid != 0)
3945       {
3946       close SERVERCMD;
3947       $server_pid = 0;
3948       if ($? != 0)
3949         {
3950         if (($? & 0xff) == 0)
3951           { printf("Server return code %d for test %d starting line %d", $?/256,
3952                 $testno, $subtest_startline); }
3953         elsif (($? & 0xff00) == 0)
3954           { printf("Server killed by signal %d", $? & 255); }
3955         else
3956           { printf("Server status %x", $?); }
3957
3958         for (;;)
3959           {
3960           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3961           $_ = $force_continue ? "c" : <T>;
3962           tests_exit(1) if /^q?$/i;
3963           if (/^c$/ && $force_continue) {
3964             log_failure($log_failed_filename, $testno, "exit code unexpected");
3965             log_test($log_summary_filename, $testno, 'F')
3966           }
3967           print "... continue forced\n" if $force_continue;
3968           last if /^[rc]$/i;
3969
3970           if (/^s$/i)
3971             {
3972             open(S, "test-stdout-server") ||
3973               tests_exit(-1, "Failed to open test-stdout-server: $!");
3974             print while <S>;
3975             close(S);
3976             }
3977           }
3978         $retry = 1 if /^r$/i;
3979         }
3980       }
3981     }
3982
3983   close SCRIPT;
3984
3985   # The script has finished. Check the all the output that was generated. The
3986   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
3987   # rerun the test (the files # have been updated).
3988   # It does not return if the user responds Q to a prompt.
3989
3990   if ($retry)
3991     {
3992     $retry = '0';
3993     print (("#" x 79) . "\n");
3994     redo;
3995     }
3996
3997   if ($docheck)
3998     {
3999     my $rc = check_output($TEST_STATE->{munge});
4000     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4001     if ($rc < 2)
4002       {
4003       print ("  Script completed\n");
4004       }
4005     else
4006       {
4007       print (("#" x 79) . "\n");
4008       redo;
4009       }
4010     }
4011   }
4012
4013
4014 ##################################################
4015 #         Exit from the test script              #
4016 ##################################################
4017
4018 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
4019 tests_exit(0);
4020
4021 # End of runtest script