Testsuite: more care munging debug time/pid line header
[exim.git] / test / runtest
1 #! /usr/bin/env perl
2 # We use env, because in some environments of our build farm
3 # the Perl 5.010 interpreter is only reachable via $PATH
4
5 ###############################################################################
6 # This is the controlling script for the "new" test suite for Exim. It should #
7 # be possible to export this suite for running on a wide variety of hosts, in #
8 # contrast to the old suite, which was very dependent on the environment of   #
9 # Philip Hazel's desktop computer. This implementation inspects the version   #
10 # of Exim that it finds, and tests only those features that are included. The #
11 # surrounding environment is also tested to discover what is available. See   #
12 # the README file for details of how it all works.                            #
13 #                                                                             #
14 # Implementation started: 03 August 2005 by Philip Hazel                      #
15 # Placed in the Exim CVS: 06 February 2006                                    #
16 ###############################################################################
17
18 #use strict;
19 use v5.10.1;
20 use warnings;
21 use if $^V >= v5.19.11, experimental => 'smartmatch';
22
23 use Errno;
24 use FileHandle;
25 use Socket;
26 use Time::Local;
27 use Cwd;
28 use File::Basename;
29 use Pod::Usage;
30 use Getopt::Long;
31 use FindBin qw'$RealBin';
32 use File::Copy;
33
34 use lib "$RealBin/lib";
35 use Exim::Runtest;
36 use Exim::Utils qw(uniq numerically cp);
37
38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
39 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
40
41 use constant TEST_TOP => 8999;
42 use constant TEST_SPECIAL_TOP => 9999;
43
44
45 # Start by initializing some global variables
46
47 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
48
49 # This gets embedded in the D-H params filename, and the value comes
50 # from asking GnuTLS for "normal", but there appears to be no way to
51 # use certtool/... to ask what that value currently is.  *sigh*
52 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
53 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
54 # normal = 2432   tls_dh_max_bits = 2236
55 my $gnutls_dh_bits_normal = 2236;
56
57 my $cf = 'bin/cf -exact';
58 my $cr = "\r";
59 my $debug = 0;
60 my $flavour = do {
61   my $f = Exim::Runtest::flavour() // '';
62   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
63 };
64 my $force_continue = 0;
65 my $force_update = 0;
66 my $log_failed_filename = 'failed-summary.log';
67 my $log_summary_filename = 'run-summary.log';
68 my @more = qw'less -XF';
69 my $optargs = '';
70 my $save_output = 0;
71 my $server_opts = '';
72 my $slow = 0;
73 my $valgrind = 0;
74
75 my $have_ipv4 = 1;
76 my $have_ipv6 = 1;
77 my $have_largefiles = 0;
78
79 my @test_list = ();
80
81
82 # Networks to use for DNS tests. We need to choose some networks that will
83 # never be used so that there is no chance that the host on which we are
84 # running is actually in one of the test networks. Private networks such as
85 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
86 # Rather than use some unassigned numbers (that might become assigned later),
87 # I have chosen some multicast networks, in the belief that such addresses
88 # won't ever be assigned to hosts. This is the only place where these numbers
89 # are defined, so it is trivially possible to change them should that ever
90 # become necessary.
91
92 my $parm_ipv4_test_net = 224;
93 my $parm_ipv6_test_net = 'ff00';
94
95 # Port numbers are currently hard-wired
96
97 my $parm_port_n = 1223;         # Nothing listening on this port
98 my $parm_port_s = 1224;         # Used for the "server" command
99 my $parm_port_d = 1225;         # Used for the Exim daemon
100 my $parm_port_d2 = 1226;        # Additional for daemon
101 my $parm_port_d3 = 1227;        # Additional for daemon
102 my $parm_port_d4 = 1228;        # Additional for daemon
103 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
104
105 # Find a suiteable group name for test (currently only 0001
106 # uses a group name. A numeric group id would do
107 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
108
109 # Manually set locale
110 $ENV{LC_ALL} = 'C';
111
112 # In some environments USER does not exist, but we need it for some test(s)
113 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
114
115 my ($parm_configure_owner, $parm_configure_group);
116 my ($parm_ipv4, $parm_ipv6, $parm_ipv6_stripped);
117 my $parm_hostname;
118
119 ###############################################################################
120 ###############################################################################
121
122 # Define a number of subroutines
123
124 ###############################################################################
125 ###############################################################################
126
127
128 ##################################################
129 #              Handle signals                    #
130 ##################################################
131
132 sub pipehandler { $sigpipehappened = 1; }
133
134 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
135
136
137 ##################################################
138 #       Do global macro substitutions            #
139 ##################################################
140
141 # This function is applied to configurations, command lines and data lines in
142 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
143 # directory. It takes one argument: the current test number, or zero when
144 # setting up files before running any tests.
145
146 sub do_substitute{
147 s?\bCALLER\b?$parm_caller?g;
148 s?\bCALLERGROUP\b?$parm_caller_group?g;
149 s?\bCALLER_UID\b?$parm_caller_uid?g;
150 s?\bCALLER_GID\b?$parm_caller_gid?g;
151 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
152 s?\bDIR/?$parm_cwd/?g;
153 s?\bEXIMGROUP\b?$parm_eximgroup?g;
154 s?\bEXIMUSER\b?$parm_eximuser?g;
155 s?\bHOSTIPV4\b?$parm_ipv4?g;
156 s?\bHOSTIPV6\b?$parm_ipv6?g;
157 s?\bHOSTNAME\b?$parm_hostname?g;
158 s?\bPORT_D\b?$parm_port_d?g;
159 s?\bPORT_D2\b?$parm_port_d2?g;
160 s?\bPORT_D3\b?$parm_port_d3?g;
161 s?\bPORT_D4\b?$parm_port_d4?g;
162 s?\bPORT_N\b?$parm_port_n?g;
163 s?\bPORT_S\b?$parm_port_s?g;
164 s?\bTESTNUM\b?$_[0]?g;
165 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
166 s?\bV6NET:?$parm_ipv6_test_net:?g;
167 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
168 s?\bMAILGROUP\b?$parm_mailgroup?g;
169 }
170
171
172 ##################################################
173 #     Any state to be preserved across tests     #
174 ##################################################
175
176 my $TEST_STATE = {};
177
178
179 ##################################################
180 #        Subroutine to tidy up and exit          #
181 ##################################################
182
183 # In all cases, we check for any Exim daemons that have been left running, and
184 # kill them. Then remove all the spool data, test output, and the modified Exim
185 # binary if we are ending normally.
186
187 # Arguments:
188 #    $_[0] = 0 for a normal exit; full cleanup done
189 #    $_[0] > 0 for an error exit; no files cleaned up
190 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
191
192 sub tests_exit{
193 my($rc) = $_[0];
194 my($spool);
195
196 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
197 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
198 # the background.
199
200 if (exists $TEST_STATE->{exim_pid})
201   {
202   $pid = $TEST_STATE->{exim_pid};
203   print "Tidyup: killing wait-mode daemon pid=$pid\n";
204   system("sudo kill -INT $pid");
205   }
206
207 if (opendir(DIR, "spool"))
208   {
209   my(@spools) = sort readdir(DIR);
210   closedir(DIR);
211   foreach $spool (@spools)
212     {
213     next if $spool !~ /^exim-daemon./;
214     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
215     chomp($pid = <PID>);
216     close(PID);
217     print "Tidyup: killing daemon pid=$pid\n";
218     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
219     }
220   }
221 else
222   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
223
224 # Close the terminal input and remove the test files if all went well, unless
225 # the option to save them is set. Always remove the patched Exim binary. Then
226 # exit normally, or die.
227
228 close(T);
229 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
230   if ($rc == 0 && !$save_output);
231
232 system("sudo /bin/rm -rf ./eximdir/*")
233   if (!$save_output);
234
235 print "\nYou were in test $test at the end there.\n\n" if defined $test;
236 exit $rc if ($rc >= 0);
237 die "** runtest error: $_[1]\n";
238 }
239
240
241
242 ##################################################
243 #   Subroutines used by the munging subroutine   #
244 ##################################################
245
246 # This function is used for things like message ids, where we want to generate
247 # more than one value, but keep a consistent mapping throughout.
248 #
249 # Arguments:
250 #   $oldid        the value from the file
251 #   $base         a base string into which we insert a sequence
252 #   $sequence     the address of the current sequence counter
253
254 sub new_value {
255 my($oldid, $base, $sequence) = @_;
256 my($newid) = $cache{$oldid};
257 if (! defined $newid)
258   {
259   $newid = sprintf($base, $$sequence++);
260   $cache{$oldid} = $newid;
261   }
262 return $newid;
263 }
264
265
266 # This is used while munging the output from exim_dumpdb.
267 # May go wrong across DST changes.
268
269 sub date_seconds {
270 my($day,$month,$year,$hour,$min,$sec) =
271   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
272 my($mon);
273 if   ($month =~ /Jan/) {$mon = 0;}
274 elsif($month =~ /Feb/) {$mon = 1;}
275 elsif($month =~ /Mar/) {$mon = 2;}
276 elsif($month =~ /Apr/) {$mon = 3;}
277 elsif($month =~ /May/) {$mon = 4;}
278 elsif($month =~ /Jun/) {$mon = 5;}
279 elsif($month =~ /Jul/) {$mon = 6;}
280 elsif($month =~ /Aug/) {$mon = 7;}
281 elsif($month =~ /Sep/) {$mon = 8;}
282 elsif($month =~ /Oct/) {$mon = 9;}
283 elsif($month =~ /Nov/) {$mon = 10;}
284 elsif($month =~ /Dec/) {$mon = 11;}
285 return timelocal($sec,$min,$hour,$day,$mon,$year);
286 }
287
288
289 # This is a subroutine to sort maildir files into time-order. The second field
290 # is the microsecond field, and may vary in length, so must be compared
291 # numerically.
292
293 sub maildirsort {
294 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
295 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
296 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
297 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
298 }
299
300
301
302 ##################################################
303 #   Subroutine list files below a directory      #
304 ##################################################
305
306 # This is used to build up a list of expected mail files below a certain path
307 # in the directory tree. It has to be recursive in order to deal with multiple
308 # maildir mailboxes.
309
310 sub list_files_below {
311 my($dir) = $_[0];
312 my(@yield) = ();
313 my(@sublist, $file);
314
315 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
316 @sublist = sort maildirsort readdir(DIR);
317 closedir(DIR);
318
319 foreach $file (@sublist)
320   {
321   next if $file eq "." || $file eq ".." || $file eq "CVS";
322   if (-d "$dir/$file")
323     { @yield = (@yield, list_files_below("$dir/$file")); }
324   else
325     { push @yield, "$dir/$file"; }
326   }
327
328 return @yield;
329 }
330
331
332
333 ##################################################
334 #         Munge a file before comparing          #
335 ##################################################
336
337 # The pre-processing turns all dates, times, Exim versions, message ids, and so
338 # on into standard values, so that the compare works. Perl's substitution with
339 # an expression provides a neat way to do some of these changes.
340
341 # We keep a global associative array for repeatedly turning the same values
342 # into the same standard values throughout the data from a single test.
343 # Message ids get this treatment (can't be made reliable for times), and
344 # times in dumped retry databases are also handled in a special way, as are
345 # incoming port numbers.
346
347 # On entry to the subroutine, the file to write to is already opened with the
348 # name MUNGED. The input file name is the only argument to the subroutine.
349 # Certain actions are taken only when the name contains "stderr", "stdout",
350 # or "log". The yield of the function is 1 if a line matching "*** truncated
351 # ***" is encountered; otherwise it is 0.
352
353 sub munge {
354 my($file) = $_[0];
355 my($extra) = $_[1];
356 my($yield) = 0;
357 my(@saved) = ();
358
359 local $_;
360
361 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
362
363 my($is_log) = $file =~ /log/;
364 my($is_stdout) = $file =~ /stdout/;
365 my($is_stderr) = $file =~ /stderr/;
366 my($is_mail) = $file =~ /mail/;
367
368 # Date pattern
369
370 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
371
372 # Debug time & pid
373
374 $time_pid = "(?:\\d{2}:\\d{2}:\\d{2}\\s+\\d+\\s)";
375
376 # Pattern for matching pids at start of stderr lines; initially something
377 # that won't match.
378
379 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
380
381 # Scan the file and make the changes. Near the bottom there are some changes
382 # that are specific to certain file types, though there are also some of those
383 # inline too.
384
385 LINE: while(<IN>)
386   {
387 RESET_AFTER_EXTRA_LINE_READ:
388   # Custom munges
389   if ($extra)
390     {
391     next if $extra =~ m%^/%  &&  eval $extra;
392     eval $extra if $extra =~ m/^s/;
393     }
394
395   # Check for "*** truncated ***"
396   $yield = 1 if /\*\*\* truncated \*\*\*/;
397
398   # Replace the name of this host
399   s/\Q$parm_hostname\E/the.local.host.name/g;
400
401   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
402   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
403
404   # The name of the shell may vary
405   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
406
407   # Replace the path to the testsuite directory
408   s?\Q$parm_cwd\E?TESTSUITE?g;
409
410   # Replace the Exim version number (may appear in various places)
411   # patchexim should have fixed this for us
412   #s/Exim \K\d+[._]\d+[\w_-]*/x.yz/i;
413
414   # Replace Exim message ids by a unique series
415   s/(\d[^\W_]{5}-[^\W_]{6}-[^\W_]{2})
416     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
417
418   # The names of lock files appear in some error and debug messages
419   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
420
421   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
422   # port" message, because it is not always the same.
423   s/port (\d+) \([^)]+\)/port $1/g
424     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
425
426   # Challenges in SPA authentication
427   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
428
429   # PRVS values
430   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
431   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
432
433   # There are differences in error messages between OpenSSL versions
434   s/SSL_CTX_set_cipher_list/SSL_connect/;
435
436   # One error test in expansions mentions base 62 or 36
437   s/is not a base (36|62) number/is not a base 36\/62 number/;
438
439   # This message sometimes has a different number of seconds
440   s/forced fail after \d seconds/forced fail after d seconds/;
441
442   # This message may contain a different DBM library name
443   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
444
445   # The message for a non-listening FIFO varies
446   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
447
448   # Debugging output of lists of hosts may have different sort keys
449   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
450
451   # Random local part in callout cache testing
452   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
453   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
454
455   # File descriptor numbers may vary
456   s/^writing data block fd=\d+/writing data block fd=dddd/;
457   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
458
459
460   # ======== Dumpdb output ========
461   # This must be before the general date/date munging.
462   # Time data lines, which look like this:
463   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
464   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
465     {
466     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
467     $expired = '' if !defined $expired;
468
469     # Round the time-difference up to nearest even value
470     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
471
472     # We used to use globally unique replacement values, but timing
473     # differences make this impossible. Just show the increment on the
474     # last one.
475
476     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
477       $increment, $expired);
478     next;
479     }
480
481   # more_errno values in exim_dumpdb output which are times
482   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
483
484   # port numbers in dumpdb output
485   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
486
487   # port numbers in stderr
488   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
489   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
490
491
492   # ======== Dates and times ========
493
494   # Dates and times are all turned into the same value - trying to turn
495   # them into different ones cannot be done repeatedly because they are
496   # real time stamps generated while running the test. The actual date and
497   # time used was fixed when I first started running automatic Exim tests.
498
499   # Date/time in header lines and SMTP responses
500   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
501     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
502   # and in a French locale
503   s/\S{4},\s\d\d?\s[^,]+\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
504     /dim., 10 f\xE9vr 2019 20:05:49 +0000/gx;
505
506   # Date/time in logs and in one instance of a filter test
507   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
508   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
509   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
510   # Date/time in syslog test
511   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
512   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
513   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
514   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
515
516   s/((D|[RQD]T)=)\d+s/$1qqs/g;
517   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
518
519   # Date/time in message separators
520   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
521     /Tue Mar 02 09:44:33 1999/gx;
522
523   # Date of message arrival in spool file as shown by -Mvh
524   s/^\d{9,10}\s0$/ddddddddd 0/;
525
526   # Date/time in mbx mailbox files
527   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
528
529   # Dates/times in debugging output for writing retry records
530   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
531     {
532     my($next) = $3 - $2;
533     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
534     }
535   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
536   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
537
538   # Time to retry may vary
539   s/time to retry = \S+/time to retry = tttt/;
540   s/retry record exists: age=\S+/retry record exists: age=ttt/;
541   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
542
543   # Date/time in exim -bV output
544   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
545
546   # Eximstats heading
547   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
548     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
549
550   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
551   # us the former on a new connection.
552   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
553
554   # ======== TLS certificate algorithms ========
555   #
556   # In Received: headers, convert RFC 8314 style ciphersuite to
557   # the older (comment) style, keeping only the Auth element
558   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
559   # element (and no _WITH); insert a spurious "RSA".
560   # Also in $tls_X_cipher_std reporting.
561
562   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-$1-AES256-SHAnnn:xxx)/;
563   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
564
565   s/ cipher_ TLS_.*?([^_]+)_WITH.+$/ cipher_ TLS1.x:ke_$1_WITH_ci_mac/;
566   s/ cipher_ TLS_.*$/ cipher_ TLS1.x:ke_RSA_WITH_ci_mac/;
567
568   # Test machines might have various different TLS library versions supporting
569   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
570   # treat the standard algorithms the same.
571   #
572   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : bits
573   #
574   # So far, have seen:
575   #   TLSv1:AES128-GCM-SHA256:128
576   #   TLSv1:AES256-SHA:256
577   #   TLSv1.1:AES256-SHA:256
578   #   TLSv1.2:AES256-GCM-SHA384:256
579   #   TLSv1.2:DHE-RSA-AES256-SHA:256
580   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
581   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
582   # We also need to handle the ciphersuite without the TLS part present, for
583   # client-ssl's output.  We also see some older forced ciphersuites, but
584   # negotiating TLS 1.2 instead of 1.0.
585   # Mail headers (...), log-lines X=..., client-ssl output ...
586   # (and \b doesn't match between ' ' and '(' )
587   #
588   # Retain the authentication algorith field as we want to test that.
589
590   s/( (?: (?:\b|\s) [\(=] ) | \s )TLS1(\.[123])?:/$1TLS1.x:/xg;
591   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
592   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
593
594   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
595   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
596   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
597   #
598   # TLSversion : "TLS" - C_iph_er - MAC : ???
599   #
600   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
601   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
602
603   # LibreSSL
604   # TLSv1:AES256-GCM-SHA384:256
605   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
606   # TLS1.3:AEAD-AES256-GCM-SHA384:256
607   #
608   # ECDHE-RSA-CHACHA20-POLY1305
609   # AES256-GCM-SHA384
610
611   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
612   s/AEAD-(AES256-GCM-SHA384)/RSA-$1/g;
613   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
614   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
615
616   # GnuTLS have seen:
617   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
618   #   TLS1.3:ECDHE_SECP256R1__RSA_PSS_RSAE_SHA256__AES_256_GCM__AEAD:256
619   #   TLS1.3:ECDHE_X25519__RSA_PSS_RSAE_SHA256__AES_256_GCM:256
620   #   TLS1.3:ECDHE_PSK_SECP256R1__AES_256_GCM__AEAD:256
621   #
622   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
623   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
624   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
625   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
626   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_256_GCM:256
627   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_128_CBC__SHA256:128
628   #   TLS1.2:ECDHE_SECP256R1__ECDSA_SHA512__AES_256_GCM:256
629   #   TLS1.2:ECDHE_SECP256R1__AES_256_GCM:256           (3.6.7 resumption)
630   #   TLS1.2:ECDHE_RSA_SECP256R1__AES_256_GCM:256       (! 3.5.18 !)
631   #   TLS1.2:RSA__CAMELLIA_256_GCM:256                  (leave the cipher name)
632   #   TLS1.2-PKIX:RSA__AES_128_GCM__AEAD:128            (the -PKIX seems to be a 3.1.20 thing)
633   #   TLS1.2-PKIX:ECDHE_RSA_SECP521R1__AES_256_GCM__AEAD:256
634   #
635   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
636   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
637   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
638   #   X=TLS1.0:RSA_AES_256_CBC_SHA1:256
639   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
640   #   X=TLS1.0-PKIX:RSA__AES_256_CBC__SHA1:256
641   # and as stand-alone cipher:
642   #   ECDHE-RSA-AES256-SHA
643   #   DHE-RSA-AES256-SHA256
644   #   DHE-RSA-AES256-SHA
645   # picking latter as canonical simply because regex easier that way.
646   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
647   s/TLS1.[x0123](-PKIX)?:                                               # TLS version
648     ((EC)?DHE(_((?<psk>PSK)_)?((?<auth>RSA|ECDSA)_)?
649                                 (SECP(256|521)R1|X25519))?__?)?         # key-exchange
650     ((?<auth>RSA|ECDSA)((_PSS_RSAE)?_SHA(512|256))?__?)?                # authentication
651     (?<with>WITH_)?                                                     # stdname-with
652     AES_(256|128)_(CBC|GCM)                                             # cipher
653     (__?AEAD)?                                                          # pseudo-MAC
654     (__?SHA(1|256|384))?                                                # PRF
655     :(256|128)                                                          # cipher strength
656     /"TLS1.x:ke-"
657         . (defined($+{psk}) ? $+{psk} : "")
658         . (defined($+{auth}) ? $+{auth} : "")
659         . (defined($+{with}) ? $+{with} : "")
660         . "-AES256-SHAnnn:xxx"/gex;
661   s/TLS1.2:RSA__CAMELLIA_256_GCM(_SHA384)?:256/TLS1.2:RSA_CAMELLIA_256_GCM-SHAnnn:256/g;
662   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
663
664   # Separate reporting of TLS version
665   s/ver:    TLS1(\.[0-3])?$/ver:    TLS1.x/;
666   s/ \(TLS1(\.[0-3])?\) / (TLS1.x) /;
667
668   # GnuTLS library error message changes
669   s/(No certificate was found|Certificate is required)/The peer did not send any certificate/g;
670 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
671   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
672   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
673
674   # (this new one is a generic channel-read error, but the testsuite
675   # only hits it in one place)
676   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
677
678   # (replace old with new, hoping that old only happens in one situation)
679   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
680   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
681
682   # signature algorithm names
683   s/RSA-SHA1/RSA-SHA/;
684
685
686   # ======== Caller's login, uid, gid, home, gecos ========
687
688   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
689   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
690   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
691
692   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
693   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
694
695   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
696   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
697
698   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
699
700   # When looking at spool files with -Mvh, we will find not only the caller
701   # login, but also the uid and gid. It seems that $) in some Perls gives all
702   # the auxiliary gids as well, so don't bother checking for that.
703
704   s/^CALLER $> \d+$/CALLER UID GID/;
705
706   # There is one case where the caller's login is forced to something else,
707   # in order to test the processing of logins that contain spaces. Weird what
708   # some people do, isn't it?
709
710   s/^spaced user $> \d+$/CALLER UID GID/;
711
712
713   # ======== Exim's login ========
714   # For messages received by the daemon, this is in the -H file, which some
715   # tests inspect. For bounce messages, this will appear on the U= lines in
716   # logs and also after Received: and in addresses. In one pipe test it appears
717   # after "Running as:". It also appears in addresses, and in the names of lock
718   # files.
719
720   s/U=$parm_eximuser/U=EXIMUSER/;
721   s/user=$parm_eximuser/user=EXIMUSER/;
722   s/login=$parm_eximuser/login=EXIMUSER/;
723   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
724   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
725   s/\b$parm_eximuser@/EXIMUSER@/;
726   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
727
728   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
729   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
730
731   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
732   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
733
734   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
735
736
737   # ======== General uids, gids, and pids ========
738   # Note: this must come after munges for caller's and exim's uid/gid
739
740   # These are for systems where long int is 64
741   s/\buid=4294967295/uid=-1/;
742   s/\beuid=4294967295/euid=-1/;
743   s/\bgid=4294967295/gid=-1/;
744   s/\begid=4294967295/egid=-1/;
745
746   s/\bgid=\d+/gid=gggg/;
747   s/\begid=\d+/egid=gggg/;
748   s/\b(pid=|pid |PID: )\d+/$1pppp/;
749   s/\buid=\d+/uid=uuuu/;
750   s/\beuid=\d+/euid=uuuu/;
751   s/set_process_info:\s+\d+/set_process_info: pppp/;
752   s/process \d+ running as transport filter/process pppp running as transport filter/;
753   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
754   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
755   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
756
757   # Pid in temp file in appendfile transport
758   s"test-mail/(subdir/)?temp\K\.\d+\.".pppp.";
759
760   # Optional pid in log lines
761   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
762     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
763
764   # Optional pid in syslog test lines
765   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
766     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
767
768   # Detect a daemon stderr line with a pid and save the pid for subsequent
769   # removal from following lines.
770   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
771   s/^$spid //;
772
773   # Queue runner waiting messages
774   s/waiting for children of \d+/waiting for children of pppp/;
775   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
776
777   # Most builds are without HAVE_LOCAL_SCAN
778   next if /^calling local_scan\(\); timeout=300$/;
779   next if /^local_scan\(\) returned 0 NULL$/;
780
781   # ======== Port numbers ========
782   # Incoming port numbers may vary, but not in daemon startup line.
783
784   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
785   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
786
787   # This handles "connection from" and the like, when the port is given
788   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
789       && !/\*>/&& !/==/  && !/\*\*/ && !/Connection refused/ && !/in response to/)
790     {
791     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
792     }
793
794   # Port in host address in spool file output from -Mvh
795   s/^(--?host_address) (.*)\.\d+/$1 $2.9999/;
796
797   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
798     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
799   }
800
801
802   # ======== Local IP addresses ========
803   # The amount of space between "host" and the address in verification output
804   # depends on the length of the host name. We therefore reduce it to one space
805   # for all of them.
806   # Also, the length of space at the end of the host line is dependent
807   # on the length of the longest line, so strip it also on otherwise
808   # un-rewritten lines like localhost
809   #
810   # host 127.0.0.1     [127.0.0.1]
811   # host 10.0.0.1      [10.0.0.1]-
812   #
813   # host 127.0.0.1     [127.0.0.1]--
814   # host 169.16.16.16  [169.16.16.10]
815
816   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
817   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
818   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
819   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
820   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
821   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
822   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
823   s/(^|\W)\K\Q$parm_ipv6_stripped\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
824   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
825   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
826   s/^\s+host\s\S+\s+\[\S+\]\K +$//;     # strip, not collapse the trailing whitespace
827
828
829   # ======== Test network IP addresses ========
830   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
831   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
832
833
834   # ======== IP error numbers and messages ========
835   # These vary between operating systems
836   s/Can(no|')t assign requested address/Network Error/;
837   s/Operation timed out/Connection timed out/;
838   s/Address family not supported by protocol family/Network Error/;
839   s/Network( is)? unreachable/Network Error/;
840   s/Invalid argument/Network Error/;
841
842   s/\(\d+\): Network/(dd): Network/;
843   s/\(\d+\): Connection refused/(dd): Connection refused/;
844   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
845   s/\d+ 65 Connection refused/dd 65 Connection refused/;
846   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
847
848
849   # ======== Other error numbers ========
850   s/errno=\d+/errno=dd/g;
851
852   # ======== System Error Messages ======
853   # depending on the underlaying file system the error message seems to differ
854   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
855
856   # ======== Output from ls ========
857   # Different operating systems use different spacing on long output
858   #s/ +/ /g if /^[-rwd]{10} /;
859   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
860   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
861   # unfortunately matches a non-ls linefull of dashes.
862   # Allow the case where we've already picked out the file protection bits.
863   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
864     s/ +/ /g;
865   }
866
867
868   # ======== Message sizes =========
869   # Message sizes vary, owing to different logins and host names that get
870   # automatically inserted. I can't think of any way of even approximately
871   # comparing these.
872
873   s/([\s,])S=\d+\b/$1S=sss/;
874   s/:S\d+\b/:Ssss/;
875   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
876   s/\sSIZE=\d+\b/ SIZE=ssss/;
877   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
878   s/old size = \d+\b/old size = sssss/;
879   s/message size = \d+\b/message size = sss/;
880   s/this message = \d+\b/this message = sss/;
881   s/Size of headers = \d+/Size of headers = sss/;
882   s/sum=(?!0)\d+/sum=dddd/;
883   s/(?<=sum=dddd )count=\d+\b/count=dd/;
884   s/(?<=sum=0 )count=\d+\b/count=dd/;
885   s/,S is \d+\b/,S is ddddd/;
886   s/\+0100,\d+;/+0100,ddd;/;
887   s/\(\d+ bytes written\)/(ddd bytes written)/;
888   s/added '\d+ 1'/added 'ddd 1'/;
889   s/Received\s+\d+/Received               nnn/;
890   s/Delivered\s+\d+/Delivered              nnn/;
891
892
893   # ======== Values in spool space failure message ========
894   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
895
896
897   # ======== Filter sizes ========
898   # The sizes of filter files may vary because of the substitution of local
899   # filenames, logins, etc.
900
901   s/^\d+(?= (\(tainted\) )?bytes read from )/ssss/;
902
903
904   # ======== OpenSSL error messages ========
905   # Different releases of the OpenSSL libraries seem to give different error
906   # numbers, or handle specific bad conditions in different ways, leading to
907   # different wording in the error messages, so we cannot compare them.
908
909 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
910 #    but I can't work out how to deal with that.
911   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
912   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
913   next if /SSL verify error: depth=0 error=certificate not trusted/;
914
915   # OpenSSL 3.0.0
916   s/TLS error \(D-H param setting .* error:\K.*dh key too small/xxxxxxxx:SSL routines::dh key too small/;
917
918   # ======== Maildir things ========
919   # timestamp output in maildir processing
920   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
921
922   # maildir delivery files appearing in log lines (in cases of error)
923   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
924
925   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
926
927   # Maildir file names in general
928   s/\b\d+\.M\d+P\d+\b/dddddddddd.HddddddPddddd/;
929
930   # Maildirsize data
931   while (/^\d+S,\d+C\s*$/)
932     {
933     print MUNGED;
934     while (<IN>)
935       {
936       last if !/^\d+ \d+\s*$/;
937       print MUNGED "ddd d\n";
938       }
939     last if !defined $_;
940     }
941   last if !defined $_;
942
943
944   # SRS timestamps and signatures vary by hostname and from run to run
945
946   s/(?i)SRS0=....=.[^=]?=([^=]+)=([^@]+)\@([^ ]+)/SRS0=ZZZZ=YY=$1=$2\@$3/g;
947
948
949   # ======== Output from the "fd" program about open descriptors ========
950   # The statuses seem to be different on different operating systems, but
951   # at least we'll still be checking the number of open fd's.
952
953   s/max fd = \d+/max fd = dddd/;
954   s/status=[0-9a-f]+ (?:RDONLY|WRONLY|RDWR)/STATUS/g;
955
956
957   # ======== Contents of spool files ========
958   # A couple of tests dump the contents of the -H file. The length fields
959   # will be wrong because of different user names, etc.
960   s/^\d\d\d(?=[PFS*])/ddd/;
961
962
963   # ==========================================================
964   # MIME boundaries in RFC3461 DSN messages
965   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
966
967   # ==========================================================
968   # Some munging is specific to the specific file types
969
970   # ======== stdout ========
971
972   if ($is_stdout)
973     {
974     # Skip translate_ip_address and use_classresources in -bP output because
975     # they aren't always there.
976
977     next if /translate_ip_address =/;
978     next if /use_classresources/;
979
980     # In certain filter tests, remove initial filter lines because they just
981     # clog up by repetition.
982
983     if ($rmfiltertest)
984       {
985       next if /^(Sender\staken\sfrom|
986                  Return-path\scopied\sfrom|
987                  Sender\s+=|
988                  Recipient\s+=)/x;
989       if (/^Testing \S+ filter/)
990         {
991         $_ = <IN>;    # remove blank line
992         next;
993         }
994       }
995
996     # remote IPv6 addrs vary
997     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
998
999     # openssl version variances
1000   # Error lines on stdout from SSL contain process id values and file names.
1001   # They also contain a source file name and line number, which may vary from
1002   # release to release.
1003
1004     next if /^SSL info:/;
1005     next if /SSL verify error: depth=0 error=certificate not trusted/;
1006     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
1007     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
1008     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
1009     s/^error:[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/error:dddddddd:$1/;
1010
1011     # gnutls version variances
1012     next if /^Error in the pull function./;
1013
1014     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
1015     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
1016     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
1017
1018     # subsecond timstamp info in reported header-files
1019     s/^-received_time_usec \.\K\d{6}$/uuuuuu/;
1020     s/^-received_time_complete \K\d+\.\d{6}$/tttt.uuuuuu/;
1021
1022     # Postgres server takes varible time to shut down; lives in various places
1023     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
1024     s/^\/.*postgres /POSTGRES /;
1025
1026     # DMARC is not always supported by the build
1027     next if /^dmarc_tld_file =/;
1028
1029     # ARC is not always supported by the build
1030     next if /^arc_sign =/;
1031
1032     # LIMITS is not always supported by the build
1033     next if /^limits_advertise_hosts =/;
1034
1035     # TLS resumption is not always supported by the build
1036     next if /^tls_resumption_hosts =/;
1037     next if /^-tls_resumption/;
1038
1039     # gsasl library version may not support some methods
1040     s/250-AUTH ANONYMOUS PLAIN SCRAM-SHA-1\K SCRAM-SHA-256//;
1041     }
1042
1043   # ======== stderr ========
1044
1045   elsif ($is_stderr)
1046     {
1047     # The very first line of debugging output will vary
1048
1049     s/^Exim version .*/Exim version x.yz ..../;
1050
1051     # Debugging lines for Exim terminations and process-generation
1052
1053     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
1054     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
1055     s/^(?:\s*\d+ )(exec .* -oPX)$/pppp $1/;
1056     next if /(?:postfork: | fork(?:ing|ed) for )/;
1057
1058     # IP address lookups use gethostbyname() when IPv6 is not supported,
1059     # and gethostbyname2() or getipnodebyname() when it is.
1060
1061     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
1062
1063     # Extra lookups done when ipv6 is supported
1064     next if /^host_fake_gethostbyname\(af=inet6\) returned 1 \(HOST_NOT_FOUND\)$/;
1065
1066     # we don't care what TZ enviroment the testhost was running
1067     next if /^Reset TZ to/;
1068
1069     # ========= Exim lookups ==================
1070     # Lookups have a char which depends on the number of lookup types compiled in,
1071     # in stderr output.  Replace with a "0".  Recognising this while avoiding
1072     # other output is fragile; perhaps the debug output should be revised instead.
1073     s%^\s+(:?closing )?\K[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
1074
1075     # drop gnutls version strings
1076     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1077     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1078
1079     # drop openssl version strings
1080     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1081     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1082
1083     # this is timing-dependent
1084     next if /^OpenSSL: creating STEK$/;
1085     next if /^selfsign cert rotate$/;
1086
1087     # TLS preload
1088     # only OpenSSL speaks of these
1089     next if /^TLS: (preloading (DH params|ECDH curve|CA bundle) for server|generating selfsigned server cert)/;
1090     next if /^Diffie-Hellman initialized from default/;
1091     next if /^ECDH OpenSSL (< )?[\d.+]+: temp key parameter settings:/;
1092     next if /^ECDH: .*'prime256v1'/;
1093     next if /^tls_verify_certificates: system$/;
1094     next if /^tls_set_watch: .*\/cert.pem/;
1095     next if /^Generating 2048 bit RSA key/;
1096
1097     # TLS preload
1098     # only GnuTLS speaks of these
1099     next if /^GnuTLS global init required$/;
1100     next if /^TLS: basic cred init, server/;
1101     next if /^TLS: preloading cipher list for server: NULL$/;
1102     s/^GnuTLS using default session cipher\/priority "NORMAL"$/TLS: not preloading cipher list for server/;
1103     next if /^GnuTLS<2>: added \d+ protocols, \d+ ciphersuites, \d+ sig algos and \d+ groups into priority list$/;
1104     next if /^GnuTLS<2>: (Disabling X.509 extensions|signing structure using RSA-SHA256)/;
1105     next if /^GnuTLS.*(wrap_nettle_mpi_print|gnutls_subject_alt_names_get|get_alt_name)/;
1106     next if /^GnuTLS<[23]>: (p11|ASSERT: pkcs11.c|Initializing needed PKCS #11 modules)/;
1107     next if /^GnuTLS<2>: Intel (AES|GCM) accelerator was detected/;
1108     next if /^Added \d{3} certificate authorities/;
1109     next if /^TLS: not preloading CRL for server/;
1110
1111     # only kevent platforms (FreeBSD, OpenBSD) say this
1112     next if /^watch dir/;
1113     next if /^watch file .*\/usr\/local/;
1114     next if /^watch file .*\/etc\/ssl/;
1115     next if /^closing watch fd:/;
1116
1117     # TLS preload
1118     # there happen in different orders for OpenSSL/GnuTLS/noTLS
1119     next if /^TLS: generating selfsigned server cert/;
1120     next if /^TLS: not preloading (CA bundle|cipher list) for server$/;
1121     next if /^TLS: not preloading server certs$/;
1122
1123     # drop lookups
1124     next if /^$time_pid?(?: Lookups\ \(built-in\):
1125                                         | Loading\ lookup\ modules\ from
1126                                         | Loaded\ \d+\ lookup\ modules
1127                                         | Total\ \d+\ lookups)/x;
1128
1129     # drop compiler information
1130     next if /^$time_pid?Compiler:/;
1131
1132     # and the ugly bit
1133     # different libraries will have different numbers (possibly 0) of follow-up
1134     # lines, indenting with more data
1135     if (/^$time_pid?Library version:/) {
1136       while (1) {
1137         $_ = <IN>;
1138         next if /^$time_pid?\s/;
1139         goto RESET_AFTER_EXTRA_LINE_READ;
1140       }
1141     }
1142
1143     # drop other build-time controls emitted for debugging
1144     next if /^$time_pid?WHITELIST_D_MACROS:/;
1145     next if /^$time_pid?TRUSTED_CONFIG_LIST:/;
1146
1147     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1148     # with -be, privileges will have been dropped, so this will always
1149     # be the case
1150     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1151
1152     # We might not keep this check; rather than change all the tests, just
1153     # ignore it as long as it succeeds; then we only need to change the
1154     # TLS tests where tls_require_ciphers has been set.
1155     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1156       my $discard = <IN>;
1157       next;
1158     }
1159     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1160
1161     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1162     next if /^macros_trusted overridden to true by whitelisting/;
1163
1164     # We have to omit the localhost ::1 address so that all is well in
1165     # the IPv4-only case.
1166
1167     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1168       if (/looked up these IP addresses/);
1169     next if /name=localhost address=::1/;
1170
1171     # drop pdkim debugging header
1172     next if /^DKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1173
1174     # Some platforms have TIOCOUTome do not
1175     next if /\d+ bytes remain in socket output buffer$/;
1176     # Various other IPv6 lines must be omitted too
1177
1178     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1179     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1180     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1181     next if / in dns_ipv4_lookup?/;
1182     next if / writing neg-cache entry for .*AAAA/;
1183     next if /^faking res_search\(AAAA\) response length as 65535/;
1184
1185     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1186       {
1187       $_= <IN>;     # Gets "returning DNS_NODATA"
1188       next;
1189       }
1190
1191     # Non-TLS builds have a different default Recieved: header expansion
1192     s/^((.*)\t}}}}by \$primary_hostname \$\{if def:received_protocol \{with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_ver        { (\$tls_in_ver)}}\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1193     s/^((\s*).*considering: with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_ver        { (\$tls_in_ver)}}\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1194     if (/condition: def:tls_in_ver$/)
1195       {
1196       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1197       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1198       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1199       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1200       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>; next;
1201       }
1202
1203
1204     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1205     # are unset, because tls ain't always there.
1206
1207     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1208                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1209
1210     # Skip auxiliary group lists because they will vary.
1211
1212     next if /auxiliary group list:/;
1213
1214     # Skip "extracted from gecos field" because the gecos field varies
1215
1216     next if /extracted from gecos field/;
1217
1218     # Skip "waiting for data on socket" and "read response data: size=" lines
1219     # because some systems pack more stuff into packets than others.
1220
1221     next if /waiting for data on socket/;
1222     next if /read response data: size=/;
1223
1224     # If Exim is compiled with readline support but it can't find the library
1225     # to load, there will be an extra debug line. Omit it.
1226
1227     next if /failed to load readline:/;
1228
1229     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1230     # O_CREAT; other's don't. In the latter case there is some debugging output
1231     # which is not present in the former. Skip the relevant lines (there are
1232     # three of them).
1233
1234     if (/returned from EXIM_DBOPEN: \(nil\)/)
1235       {
1236       $_ .= <IN>;
1237       s?\Q$parm_cwd\E?TESTSUITE?g;
1238       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1239         { $_ = <IN>; next; }
1240       }
1241
1242     # Some tests turn on +expand debugging to check on expansions.
1243     # Unfortunately, the Received: expansion varies, depending on whether TLS
1244     # is compiled or not. So we must remove the relevant debugging if it is.
1245
1246     if (/^condition: def:tls_cipher/)
1247       {
1248       while (<IN>) { last if /^condition: def:sender_address/; }
1249       }
1250     elsif (/^expanding: Received: /)
1251       {
1252       while (<IN>) { last if !/^\s/; }
1253       }
1254
1255     # remote port numbers vary
1256     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1257
1258     # Platform-dependent error strings
1259     s/Operation timed out/Connection timed out/;
1260
1261     # Platform differences on disconnect
1262     s/unexpected disconnection while reading SMTP command from \[127.0.0.1\] \K\(error: Connection reset by peer\) //;
1263
1264     # Platform-dependent resolver option bits
1265     s/^ (?:writing|update) neg-cache entry for [^,]+-\K[0-9a-f]+, ttl/xxxx, ttl/;
1266
1267     # timing variance, run-to-run
1268     s/^time on queue = \K1s/0s/;
1269
1270     # content-scan: file order can vary in directory
1271     s%unspool_mbox\(\): unlinking 'TESTSUITE/spool/scan/[^/]*/\K[^\']*%FFFFFFFFF%;
1272
1273     # Skip hosts_require_dane checks when the options
1274     # are unset, because dane ain't always there.
1275     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1276
1277     # daemon notifier socket
1278     s/^(\s*\d+|ppppp) (creating notifier socket)$/ppppp $2/;
1279     s/^ \@(.*exim_daemon_notify)$/ $1/;
1280     s/^(\s*\d+|ppppp)  \@?(.*exim_daemon_notify)$/ppppp  $2/;
1281     next if /unlinking notifier socket/;
1282
1283     # daemon notifier socket
1284     # Timing variance over runs.  Collapse repeated memssages.
1285     if (/notify triggered queue run/)
1286       {
1287       my $line = $_;
1288       while (/notify triggered queue run/) { $_ = <IN>; }
1289       $_ = $line . $_;
1290       }
1291
1292     # Different builds will have different lookup types included
1293     s/^search_type \K\d+ \((\w+)\) quoting -1 \(none\)$/NN ($1) quoting -1 (none)/;
1294
1295     # DISABLE_OCSP
1296     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1297
1298     # SUPPORT_PROXY
1299     next if /host in hosts_proxy\?/;
1300
1301     # PIPE_CONNECT
1302     next if / in (pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1303
1304     # Experimental_International
1305     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1306
1307     # Experimental_REQUIRETLS
1308     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1309
1310     # Experimental_LIMITS
1311     next if / in limits_advertise_hosts?\? no \(matched "!\*"\)/;
1312
1313     # TCP Fast Open
1314     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1315
1316     # Environment cleaning
1317     next if /\w+ in keep_environment\? (yes|no)/;
1318
1319     # Sizes vary with test hostname
1320     s/^cmd buf flush \d+ bytes/cmd buf flush ddd bytes/;
1321
1322     # Spool filesystem free space changes on different systems.
1323     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1324
1325     # Non-TLS builds have different expansions for received_header_text
1326     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1327       {
1328       $_ .= <IN>;
1329       s/[\sâ•Ž]+\}\}(?=\(Exim )/\}\} /;
1330       }
1331     if (/^ â”œâ”€â”€condition: def:tls_cipher$/)
1332       {
1333       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1334       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1335       }
1336
1337     # Not all platforms build with DKIM enabled
1338     next if /^DKIM >> Body data for hash, canonicalized/;
1339
1340     # Not all platforms build with SPF enabled
1341     next if /^(spf_conn_init|SPF_dns_exim_new|spf_compile\.c)/;
1342
1343     # Not all platforms have sendfile support
1344     next if /^cannot use sendfile for body: no support$/;
1345
1346     #  Parts of DKIM-specific debug output depend on the time/date
1347     next if /^date:\w+,\{SP\}/;
1348     next if /^DKIM \[[^[]+\] (Header hash|b) computed:/;
1349
1350     # Not all platforms support TCP Fast Open, and the compile omits the check
1351     if (s/\S+ in hosts_try_fastopen\? (no \(option unset\)|no \(end of list\)|yes \(matched "\*"\))\n$//)
1352       {
1353       chomp;
1354       $_ .= <IN>;
1355       s/ \.\.\. >>> / ... /;
1356       if (s/ non-TFO mode connection attempt to 224.0.0.0, 0 data\b$//) { chomp; $_ .= <IN>; }
1357       s/Address family not supported by protocol family/Network Error/;
1358       s/Network is unreachable/Network Error/;
1359       }
1360     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1361     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1362
1363     if (/^([0-9: ]*                                             # possible timestamp
1364         Connecting\ to\ [^ ]+\ [^ ]+(\ from\ [^ ]+)?)\ \.\.\.
1365         \ .*TFO\ mode\x20
1366         (sendto,\ no\ data:\ EINPROGRESS                        # Linux
1367         |connection\ attempt\ to\ [^,]+,\ 0\ data)              # MacOS & no-support
1368         $/x)
1369       {
1370       $_ = $1 . " ... " . <IN>;
1371       s/^(.* \.\.\.) [0-9: ]*connected$/$1  connected/;
1372
1373       if (/^Connecting to .* \.\.\.  connected$/)
1374         {
1375         $_ .= <IN>;
1376         if (/^(Connecting to .* \.\.\.  )connected\n\s+SMTP(\(close\)>>|\(Connection refused\)<<)$/)
1377           {
1378           $_ = $1 . "failed: Connection refused\n" . <IN>;
1379           s/^(Connecting .*)\n\s+SMTP\(close\)>>$/$1/;
1380           }
1381         elsif (/^(Connecting to .* \.\.\.  connected\n)read response data: size=/)
1382           { $_ = $1; }
1383
1384         # Date/time in SMTP banner
1385         s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
1386           /Tue, 2 Mar 1999 09:44:33 +0000/gx;
1387         }
1388       }
1389
1390     # Specific pointer values reported for DB operations change from run to run
1391     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1392     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1393
1394     # Platform-dependent output during MySQL startup
1395     next if /PerconaFT file system space/;
1396     next if /^Waiting for MySQL server to answer/;
1397     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1398
1399     # Postgres version-dependent differences
1400     s/^initdb: warning: (enabling "trust" authentication for local connections)$/\nWARNING: $1/;
1401
1402     # Not all builds include DMARC
1403     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1404
1405     # TLS resumption is not always supported by the build
1406     next if /in tls_resumption_hosts\?/;
1407
1408     # Platform differences in errno strings
1409     s/  SMTP\(Operation timed out\)<</  SMTP(Connection timed out)<</;
1410
1411     # Platform differences for errno values (eg. Hurd)
1412     s/^errno = \d+$/errno = EEE/;
1413     s/^writing error \d+: /writing error EEE: /;
1414
1415     # Time-only, in debug output
1416     # we have to handle double lines from the DBOPEN, hence placed down here and /mg
1417     s/^\d\d:\d\d:\d\d\s+/01:01:01 /mg;
1418
1419     # pid in debug lines
1420     s/^(\d\d:\d\d:\d\d)(\s+\d+\s)/"$1 " . new_value($2, "%s", \$next_pid) . " "/mgxe;
1421     s/(?<!post-)[Pp]rocess\K(\s\d+ )/new_value($1, "%s", \$next_pid) . " "/gxe;
1422
1423     # When Exim is checking the size of directories for maildir, it uses
1424     # the check_dir_size() function to scan directories. Of course, the order
1425     # of the files that are obtained using readdir() varies from system to
1426     # system. We therefore buffer up debugging lines from check_dir_size()
1427     # and sort them before outputting them.
1428
1429     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1430       {
1431       push @saved, $_;
1432       }
1433     else
1434       {
1435       if (@saved > 0)
1436         {
1437         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1438           "to ensure consistency\n";
1439         @saved = sort(@saved);
1440         print MUNGED @saved;
1441         @saved = ();
1442         }
1443
1444       # Skip some lines that Exim puts out at the start of debugging output
1445       # because they will be different in different binaries.
1446
1447       next if /^$time_pid?
1448                   (?: Berkeley\ DB:\s
1449                     | Probably\ (?:Berkeley\ DB|ndbm|GDBM)
1450                     | Authenticators:
1451                     | Lookups(?:\(built-in\))?:
1452                     | Support\ for:
1453                     | Routers:
1454                     | Transports:
1455                     | Malware:
1456                     | log\ selectors\ =
1457                     | cwd=
1458                     | Fixed\ never_users
1459                     | Configure\ owner
1460                     | Size\ of\ off_t:
1461                   )
1462                 /x;
1463
1464       print MUNGED;
1465       }
1466
1467     next;
1468     }
1469
1470   # ======== log ========
1471
1472   elsif ($is_log)
1473     {
1474     # Berkeley DB version differences
1475     next if / Berkeley DB error: /;
1476
1477     # CHUNKING: exact sizes depend on hostnames in headers
1478     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1479
1480     # openssl version variances
1481     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1482     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(?:(?i)ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1483     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1484     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:(PEM routines):get_name:(no start line)/0906D06C:$1:PEM_read_bio:$2/;
1485
1486     # gnutls version variances
1487     if (/TLS error on connection \(recv\): .* (Decode error|peer did not send any certificate)/)
1488       {
1489       my $prev = $_;
1490       $_ = <IN>;
1491       if (/error on first read/)
1492         {
1493         s/TLS session: \Kerror on first read:/(gnutls_handshake): A TLS fatal alert has been received.:/;
1494         goto RESET_AFTER_EXTRA_LINE_READ;
1495         }
1496       else
1497         { $_ = $prev; }
1498       }
1499     # translate gnutls error into the openssl one
1500     s/ARC: AMS signing: privkey PEM-block import: \KThe requested data were not available.$/error:0906D06C:PEM routines:PEM_read_bio:no start line/;
1501
1502     # DKIM timestamps
1503     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1504       {
1505       my ($prefix, $t_diff) = ($1, $3 - $2);
1506       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1507       }
1508     # GnuTLS reports a different keysize vs. OpenSSL, for ed25519 keys
1509     s/signer: [^ ]* bits:\K 256/ 253/;
1510     s/public key too short:\K 256 bits/ 253 bits/;
1511
1512     # port numbers
1513     s/(?:\[[^\]]*\]:|port )\K$parm_port_d/PORT_D/;
1514     s/(?:\[[^\]]*\]:|port )\K$parm_port_d2/PORT_D2/;
1515     s/(?:\[[^\]]*\]:|port )\K$parm_port_d3/PORT_D3/;
1516     s/(?:\[[^\]]*\]:|port )\K$parm_port_d4/PORT_D4/;
1517     s/(?:\[[^\]]*\]:|port )\K$parm_port_s/PORT_S/;
1518     s/(?:\[[^\]]*\]:|port )\K$parm_port_n/PORT_N/;
1519     s/I=\[[^\]]*\]:\K\d+/ppppp/;
1520
1521     # Platform differences for errno values (eg. Hurd).  Leave 0 and negative numbers alone.
1522     s/R=\w+ T=\w+ defer\K \([1-9]\d*\): / (EEE): /;
1523
1524     # Platform differences in errno strings
1525     s/Arg list too long/Argument list too long/;
1526
1527     # OpenSSL vs. GnuTLS
1528     s/session: \K\((SSL_connect|gnutls_handshake)\): timed out/(tls lib connect fn): timed out/;
1529     s/TLS error on connection from .*\K\((SSL_accept|gnutls_handshake)\): timed out/(tls lib accept fn): timed out/;
1530     s/TLS error on connection from .*\K(SSL_accept: TCP connection closed by peer|\(gnutls_handshake\): The TLS connection was non-properly terminated.)/(tls lib accept fn): TCP connection closed by peer/;
1531     s/TLS session: \K\(gnutls_handshake\): No supported application protocol could be negotiated/(SSL_connect): error: <<detail omitted>>/;
1532     s/\(gnutls_handshake\): No common application protocol could be negotiated./(SSL_accept): error: <<detail omitted>>/;
1533     }
1534
1535   # ======== mail ========
1536
1537   elsif ($is_mail)
1538     {
1539     # DKIM timestamps, and signatures depending thereon
1540     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1541       {
1542       my ($indent, $t_diff) = ($1, $3 - $2);
1543       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1544       <IN>;
1545       <IN>;
1546       }
1547     }
1548
1549   # ======== All files other than stderr ========
1550
1551   print MUNGED;
1552   }
1553
1554 close(IN);
1555 return $yield;
1556 }
1557
1558
1559
1560
1561 ##################################################
1562 #        Subroutine to interact with caller      #
1563 ##################################################
1564
1565 # Arguments: [0] the prompt string
1566 #            [1] if there is a U in the prompt and $force_update is true
1567 #            [2] if there is a C in the prompt and $force_continue is true
1568 # Returns:   returns the answer
1569
1570 sub interact {
1571   my ($prompt, $have_u, $have_c) = @_;
1572
1573   print $prompt;
1574
1575   if ($have_u) {
1576     print "... update forced\n";
1577     return 'u';
1578   }
1579
1580   if ($have_c) {
1581     print "... continue forced\n";
1582     return 'c';
1583   }
1584
1585   return lc <T>;
1586 }
1587
1588
1589
1590 ##################################################
1591 #    Subroutine to log in force_continue mode    #
1592 ##################################################
1593
1594 # In force_continue mode, we just want a terse output to a statically
1595 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1596 # all have mismatches, it will log multiple times.
1597 #
1598 # Arguments: [0] the logfile to append to
1599 #            [1] the testno that failed
1600 # Returns:   nothing
1601
1602
1603
1604 sub log_failure {
1605   my ($logfile, $testno, $detail) = @_;
1606
1607   open(my $fh, '>>', $logfile) or return;
1608
1609   print $fh "Test $testno "
1610         . (defined $detail ? "$detail " : '')
1611         . "failed\n";
1612 }
1613
1614 # Computer-readable summary results logfile
1615
1616 sub log_test {
1617   my ($logfile, $testno, $resultchar) = @_;
1618
1619   open(my $fh, '>>', $logfile) or return;
1620   print $fh "$testno $resultchar\n";
1621 }
1622
1623
1624
1625 ##################################################
1626 #    Subroutine to compare one output file       #
1627 ##################################################
1628
1629 # When an Exim server is part of the test, its output is in separate files from
1630 # an Exim client. The server data is concatenated with the client data as part
1631 # of the munging operation.
1632 #
1633 # Arguments:  [0] the name of the main raw output file
1634 #             [1] the name of the server raw output file or undef
1635 #             [2] where to put the munged copy
1636 #             [3] the name of the saved file
1637 #             [4] TRUE if this is a log file whose deliveries must be sorted
1638 #             [5] optionally, a custom munge command
1639 #
1640 # Returns:    0 comparison succeeded
1641 #             1 comparison failed; differences to be ignored
1642 #             2 comparison failed; files may have been updated (=> re-compare)
1643 #
1644 # Does not return if the user replies "Q" to a prompt.
1645
1646 sub check_file{
1647 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1648
1649 # If there is no saved file, the raw files must either not exist, or be
1650 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1651
1652 # we check if there is a flavour specific file, but we remember
1653 # the original file name as "generic"
1654 $sf_generic = $sf;
1655 $sf_flavour = "$sf_generic.$flavour";
1656 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1657
1658 if (! -e $sf_current)
1659   {
1660   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1661
1662   print "\n";
1663   print "** $rf is not empty\n" if (-s $rf);
1664   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1665
1666   for (;;)
1667     {
1668     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1669     tests_exit(1) if /^q?$/;
1670     if (/^c$/ && $force_continue) {
1671       log_failure($log_failed_filename, $testno, $rf);
1672       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1673     }
1674     return 1 if /^c$/i && $rf !~ /paniclog/ && (!defined $rsf || $rsf !~ /paniclog/);
1675     last if (/^[sc]$/);
1676     }
1677
1678   foreach $f ($rf, $rsf)
1679     {
1680     if (defined $f && -s $f)
1681       {
1682       print "\n";
1683       print "------------ $f -----------\n"
1684         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1685       system @more => $f;
1686       }
1687     }
1688
1689   print "\n";
1690   for (;;)
1691     {
1692     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1693     tests_exit(1) if /^q?$/;
1694     if (/^c$/ && $force_continue) {
1695       log_failure($log_failed_filename, $testno, $rf);
1696       log_test($log_summary_filename, $testno, 'F')
1697     }
1698     return 1 if /^c$/i;
1699     last if (/^u$/i);
1700     }
1701   }
1702
1703 #### $_
1704
1705 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1706 # was a request to create a saved file. First, create the munged file from any
1707 # data that does exist.
1708
1709 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1710 my($truncated) = munge($rf, $extra) if -e $rf;
1711
1712 # Append the raw server log, if it is non-empty
1713 if (defined $rsf && -e $rsf)
1714   {
1715   print MUNGED "\n******** SERVER ********\n";
1716   $truncated |= munge($rsf, $extra);
1717   }
1718 close(MUNGED);
1719
1720 # If a saved file exists, do the comparison. There are two awkward cases:
1721 #
1722 # If "*** truncated ***" was found in the new file, it means that a log line
1723 # was overlong, and truncated. The problem is that it may be truncated at
1724 # different points on different systems, because of different user name
1725 # lengths. We reload the file and the saved file, and remove lines from the new
1726 # file that precede "*** truncated ***" until we reach one that matches the
1727 # line that precedes it in the saved file.
1728 #
1729 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1730 # for an individual message might vary in their order from system to system, as
1731 # a result of parallel deliveries. We load the munged file and sort sequences
1732 # of delivery lines.
1733
1734 if (-e $sf_current)
1735   {
1736   # Deal with truncated text items
1737
1738   if ($truncated)
1739     {
1740     my(@munged, @saved, $i, $j, $k);
1741
1742     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1743     @munged = <MUNGED>;
1744     close(MUNGED);
1745     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1746     @saved = <SAVED>;
1747     close(SAVED);
1748
1749     $j = 0;
1750     for ($i = 0; $i < @munged; $i++)
1751       {
1752       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1753         {
1754         for (; $j < @saved; $j++)
1755           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1756         last if $j >= @saved;     # not found in saved
1757
1758         for ($k = $i - 1; $k >= 0; $k--)
1759           { last if $munged[$k] eq $saved[$j - 1]; }
1760
1761         last if $k <= 0;          # failed to find previous match
1762         splice @munged, $k + 1, $i - $k - 1;
1763         $i = $k + 1;
1764         }
1765       }
1766
1767     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1768     print $fh @munged;
1769     }
1770
1771   # Deal with log sorting
1772
1773   if ($sortfile)
1774     {
1775
1776     my @munged = do {
1777       open(my $fh, '<', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1778       <$fh>;
1779     };
1780
1781     for (my $i = 0; $i < @munged; $i++)
1782       {
1783       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1784         {
1785         my $j;
1786         for ($j = $i + 1; $j < @munged; $j++)
1787           {
1788           last if $munged[$j] !~
1789             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1790           }
1791         @temp = splice(@munged, $i, $j - $i);
1792         @temp = sort(@temp);
1793         splice(@munged, $i, 0, @temp);
1794         }
1795       }
1796
1797     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1798     print $fh "**NOTE: The delivery lines in this file have been sorted.\n";
1799     print $fh @munged;
1800     }
1801
1802   # Do the comparison
1803
1804   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1805
1806   # Handle comparison failure
1807
1808   print "** Comparison of $mf with $sf_current failed";
1809   system @more => 'test-cf';
1810
1811   print "\n";
1812   for (;;)
1813     {
1814     $_ = interact('Continue, Retry, Update current'
1815         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1816         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1817     tests_exit(1) if /^q?$/;
1818     if (/^c$/ && $force_continue) {
1819       log_failure($log_failed_filename, $testno, $sf_current);
1820       log_test($log_summary_filename, $testno, 'F')
1821     }
1822     return 1 if /^c$/i;
1823     return 2 if /^r$/i;
1824     last if (/^[us]$/i);
1825     }
1826   }
1827
1828 # Update or delete the saved file, and give the appropriate return code.
1829
1830 if (-s $mf)
1831   {
1832     my $sf = /^u/i ? $sf_current : $sf_flavour;
1833     copy($mf, $sf) or tests_exit(-1, "Failed to copy $mf $sf");
1834   }
1835 else
1836   {
1837     # if we deal with a flavour file, we can't delete it, because next time the generic
1838     # file would be used again
1839     if ($sf_current eq $sf_flavour) {
1840       open(my $fh, '>', $sf_current);
1841     }
1842     else {
1843       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1844     }
1845   }
1846
1847 return 2;
1848 }
1849
1850
1851
1852 ##################################################
1853 # Custom munges
1854 # keyed by name of munge; value is a ref to a hash
1855 # which is keyed by file, value a string to look for.
1856 # Usable files are:
1857 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1858 # Search strings starting with 's' do substitutions;
1859 # with '/' do line-skips.
1860 # Triggered by a scriptfile line "munge <name>"
1861 ##################################################
1862 $munges =
1863   { 'dnssec' =>
1864     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1865
1866     'gnutls_unexpected' =>
1867     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1868
1869     'gnutls_handshake' =>
1870     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1871
1872     'gnutls_bad_clientcert' =>
1873     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1874       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1875     },
1876
1877     'optional_events' =>
1878     { 'stdout' => '/event_action =/' },
1879
1880     'optional_ocsp' =>
1881     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1882
1883     'optional_cert_hostnames' =>
1884     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1885
1886     'loopback' =>
1887     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1888
1889     'scanfile_size' =>
1890     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1891
1892     'delay_1500' =>
1893     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1894
1895     'tls_anycipher' =>
1896     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1897                       s! DN="C=! DN="/C=!;
1898                       s! DN="[^,"]*\K,!/!;
1899                       s! DN="[^,"]*\K,!/!;
1900                       s! DN="[^,"]*\K,!/!;
1901                      ',
1902       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1903     },
1904
1905     'debug_pid' =>
1906     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d+/ppppp/g' },
1907
1908     'optional_dsn_info' =>
1909     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1910     },
1911
1912     'optional_config' =>
1913     { 'stdout' => '/^(
1914                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1915                   |gnutls_require_(kx|mac|protocols)
1916                   |hosts_pipe_connect
1917                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1918                   |dane_require_tls_ciphers
1919                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1920                   |pipelining_connect_advertise_hosts
1921                   |socks_proxy
1922                   |tls_[^ ]*
1923                   |utf8_downconvert
1924                   )($|[ ]=)/x'
1925     },
1926
1927     'sys_bindir' =>
1928     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1929
1930     'sync_check_data' =>
1931     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1932       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1933
1934     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1935     { 'mainlog' => 's/((?:host|message) deferral .* errno) <\d+> /$1 <EEE> /' },
1936
1937     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1938     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1939
1940     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1941     { 'stdout' => 's%^> X/X$%> X%' },
1942   };
1943
1944
1945 sub max {
1946   my ($a, $b) = @_;
1947   return $a if ($a > $b);
1948   return $b;
1949 }
1950
1951 ##################################################
1952 #    Subroutine to check the output of a test    #
1953 ##################################################
1954
1955 # This function is called when the series of subtests is complete. It makes
1956 # use of check_file(), whose arguments are:
1957 #
1958 #  [0] the name of the main raw output file
1959 #  [1] the name of the server raw output file or undef
1960 #  [2] where to put the munged copy
1961 #  [3] the name of the saved file
1962 #  [4] TRUE if this is a log file whose deliveries must be sorted
1963 #  [5] an optional custom munge command
1964 #
1965 # Arguments: Optionally, name of a single custom munge to run.
1966 # Returns:   0 if the output compared equal
1967 #            1 if comparison failed; differences to be ignored
1968 #            2 if re-run needed (files may have been updated)
1969
1970 sub check_output{
1971 my($mungename) = $_[0];
1972 my($yield) = 0;
1973 my($munge) = $munges->{$mungename} if defined $mungename;
1974
1975 $yield = max($yield,  check_file("spool/log/paniclog",
1976                        "spool/log/serverpaniclog",
1977                        "test-paniclog-munged",
1978                        "paniclog/$testno", 0,
1979                        $munge->{paniclog}));
1980
1981 $yield = max($yield,  check_file("spool/log/rejectlog",
1982                        "spool/log/serverrejectlog",
1983                        "test-rejectlog-munged",
1984                        "rejectlog/$testno", 0,
1985                        $munge->{rejectlog}));
1986
1987 $yield = max($yield,  check_file("spool/log/mainlog",
1988                        "spool/log/servermainlog",
1989                        "test-mainlog-munged",
1990                        "log/$testno", $sortlog,
1991                        $munge->{mainlog}));
1992
1993 if (!$stdout_skip)
1994   {
1995   $yield = max($yield,  check_file("test-stdout",
1996                        "test-stdout-server",
1997                        "test-stdout-munged",
1998                        "stdout/$testno", 0,
1999                        $munge->{stdout}));
2000   }
2001
2002 if (!$stderr_skip)
2003   {
2004   $yield = max($yield,  check_file("test-stderr",
2005                        "test-stderr-server",
2006                        "test-stderr-munged",
2007                        "stderr/$testno", 0,
2008                        $munge->{stderr}));
2009   }
2010
2011 # Compare any delivered messages, unless this test is skipped.
2012
2013 if (! $message_skip)
2014   {
2015   my($msgno) = 0;
2016
2017   # Get a list of expected mailbox files for this script. We don't bother with
2018   # directories, just the files within them.
2019
2020   foreach $oldmail (@oldmails)
2021     {
2022     next unless $oldmail =~ /^mail\/$testno\./;
2023     print ">> EXPECT $oldmail\n" if $debug;
2024     $expected_mails{$oldmail} = 1;
2025     }
2026
2027   # If there are any files in test-mail, compare them. Note that "." and
2028   # ".." are automatically omitted by list_files_below().
2029
2030   @mails = list_files_below("test-mail");
2031
2032   foreach $mail (@mails)
2033     {
2034     next if $mail eq "test-mail/oncelog";
2035
2036     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
2037     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
2038
2039     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
2040       {
2041       $msgno++;
2042       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
2043       }
2044
2045     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
2046     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
2047       "mail/$testno.$saved_mail", 0,
2048       $munge->{mail}));
2049     delete $expected_mails{"mail/$testno.$saved_mail"};
2050     }
2051
2052   # Complain if not all expected mails have been found
2053
2054   if (scalar(keys %expected_mails) != 0)
2055     {
2056     foreach $key (keys %expected_mails)
2057       { print "** no test file found for $key\n"; }
2058
2059     for (;;)
2060       {
2061       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
2062       tests_exit(1) if /^q?$/;
2063       if (/^c$/ && $force_continue) {
2064         log_failure($log_failed_filename, $testno, "missing email");
2065         log_test($log_summary_filename, $testno, 'F')
2066       }
2067       last if /^c$/;
2068
2069       # For update, we not only have to unlink the file, but we must also
2070       # remove it from the @oldmails vector, as otherwise it will still be
2071       # checked for when we re-run the test.
2072
2073       if (/^u$/)
2074         {
2075         foreach $key (keys %expected_mails)
2076           {
2077           my($i);
2078           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
2079           for ($i = 0; $i < @oldmails; $i++)
2080             {
2081             if ($oldmails[$i] eq $key)
2082               {
2083               splice @oldmails, $i, 1;
2084               last;
2085               }
2086             }
2087           }
2088         last;
2089         }
2090       }
2091     }
2092   }
2093
2094 # Compare any remaining message logs, unless this test is skipped.
2095
2096 if (! $msglog_skip)
2097   {
2098   # Get a list of expected msglog files for this test
2099
2100   foreach $oldmsglog (@oldmsglogs)
2101     {
2102     next unless $oldmsglog =~ /^$testno\./;
2103     $expected_msglogs{$oldmsglog} = 1;
2104     }
2105
2106   # If there are any files in spool/msglog, compare them. However, we have
2107   # to munge the file names because they are message ids, which are
2108   # time dependent.
2109
2110   if (opendir(DIR, "spool/msglog"))
2111     {
2112     @msglogs = sort readdir(DIR);
2113     closedir(DIR);
2114
2115     foreach $msglog (@msglogs)
2116       {
2117       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
2118       ($munged_msglog = $msglog) =~
2119         s/((?:[^\W_]{6}-){2}[^\W_]{2})
2120           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
2121       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
2122         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
2123         $munge->{msglog}));
2124       delete $expected_msglogs{"$testno.$munged_msglog"};
2125       }
2126     }
2127
2128   # Complain if not all expected msglogs have been found
2129
2130   if (scalar(keys %expected_msglogs) != 0)
2131     {
2132     foreach $key (keys %expected_msglogs)
2133       {
2134       print "** no test msglog found for msglog/$key\n";
2135       ($msgid) = $key =~ /^\d+\.(.*)$/;
2136       foreach $cachekey (keys %cache)
2137         {
2138         if ($cache{$cachekey} eq $msgid)
2139           {
2140           print "** original msgid $cachekey\n";
2141           last;
2142           }
2143         }
2144       }
2145
2146     for (;;)
2147       {
2148       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
2149       tests_exit(1) if /^q?$/;
2150       if (/^c$/ && $force_continue) {
2151         log_failure($log_failed_filename, $testno, "missing msglog");
2152         log_test($log_summary_filename, $testno, 'F')
2153       }
2154       last if /^c$/;
2155       if (/^u$/)
2156         {
2157         foreach $key (keys %expected_msglogs)
2158           {
2159           tests_exit(-1, "Failed to unlink msglog/$key")
2160             if !unlink("msglog/$key");
2161           }
2162         last;
2163         }
2164       }
2165     }
2166   }
2167
2168 return $yield;
2169 }
2170
2171
2172
2173 ##################################################
2174 #     Subroutine to run one "system" command     #
2175 ##################################################
2176
2177 # We put this in a subroutine so that the command can be reflected when
2178 # debugging.
2179 #
2180 # Argument: the command to be run
2181 # Returns:  nothing
2182
2183 sub run_system {
2184 my($cmd) = $_[0];
2185 if ($debug)
2186   {
2187   my($prcmd) = $cmd;
2188   $prcmd =~ s/; /;\n>> /;
2189   print ">> $prcmd\n";
2190   }
2191 system($cmd);
2192 }
2193
2194
2195
2196 ##################################################
2197 #      Subroutine to run one script command      #
2198 ##################################################
2199
2200 # The <SCRIPT> file is open for us to read an optional return code line,
2201 # followed by the command line and any following data lines for stdin. The
2202 # command line can be continued by the use of \. Data lines are not continued
2203 # in this way. In all lines, the following substitutions are made:
2204 #
2205 # DIR    => the current directory
2206 # CALLER => the caller of this script
2207 #
2208 # Arguments: the current test number
2209 #            reference to the subtest number, holding previous value
2210 #            reference to the expected return code value
2211 #            reference to where to put the command name (for messages)
2212 #            auxiliary information returned from a previous run
2213 #
2214 # Returns:   0 the command was executed inline, no subprocess was run
2215 #            1 a non-exim command was run and waited for
2216 #            2 an exim command was run and waited for
2217 #            3 a command was run and not waited for (daemon, server, exim_lock)
2218 #            4 EOF was encountered after an initial return code line
2219 # Optionally also a second parameter, a hash-ref, with auxiliary information:
2220 #            exim_pid: pid of a run process
2221 #            munge: name of a post-script results munger
2222
2223 sub run_command{
2224 my($testno) = $_[0];
2225 my($subtestref) = $_[1];
2226 my($commandnameref) = $_[3];
2227 my($aux_info) = $_[4];
2228 my($yield) = 1;
2229
2230 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
2231
2232 if (/^(\d+)\s*$/)                # Handle unusual return code
2233   {
2234   my($r) = $_[2];
2235   $$r = $1 << 8;
2236   $_ = <SCRIPT>;
2237   return 4 if !defined $_;       # Missing command
2238   $lineno++;
2239   }
2240
2241 chomp;
2242 $wait_time = 0;
2243
2244 # Handle concatenated command lines
2245
2246 s/\s+$//;
2247 while (substr($_, -1) eq"\\")
2248   {
2249   my($temp);
2250   $_ = substr($_, 0, -1);
2251   chomp($temp = <SCRIPT>);
2252   if (defined $temp)
2253     {
2254     $lineno++;
2255     $temp =~ s/\s+$//;
2256     $temp =~ s/^\s+//;
2257     $_ .= $temp;
2258     }
2259   }
2260
2261 # Do substitutions
2262
2263 do_substitute($testno);
2264 if ($debug) { printf ">> $_\n"; }
2265
2266 # Pass back the command name (for messages)
2267
2268 ($$commandnameref) = /^(\S+)/;
2269
2270 # Here follows code for handling the various different commands that are
2271 # supported by this script. The first group of commands are all freestanding
2272 # in that they share no common code and are not followed by any data lines.
2273
2274
2275 ###################
2276 ###################
2277
2278 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2279 # utility and to make DBM files for testing DBM lookups.
2280
2281 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2282   {
2283   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2284          "echo exim_dbmbuild exit code = \$?)" .
2285          ">>test-stdout");
2286   return 1;
2287   }
2288
2289
2290 # The "dump" command runs exim_dumpdb. On different systems, the output for
2291 # some types of dump may appear in a different order because it's just hauled
2292 # out of the DBM file. We can solve this by sorting. Ignore the leading
2293 # date/time, as it will be flattened later during munging.
2294
2295 if (/^dump\s+(\S+)/)
2296   {
2297   my $which  = $1;
2298   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2299   open(my $in, "-|", './eximdir/exim_dumpdb', "$parm_cwd/spool", $which) or die "Can't run exim_dumpdb: $!";
2300   open(my $out, ">>test-stdout");
2301   print $out "+++++++++++++++++++++++++++\n";
2302
2303   if ($which eq "retry")
2304     {
2305     # the sort key is the first part of the retry db dump line, but for
2306     # sorting we (temporarly) replace the own hosts ipv4 with a munged
2307     # version, which matches the munging that is done later
2308     # Why? We must ensure sure, that 127.0.0.1 always sorts first
2309     # map-sort-map: Schwartz's transformation
2310     # test 0099
2311     my @temp = map  { $_->[1] }
2312                sort { $a->[0] cmp $b->[0] }
2313                #map  { [ (split)[0] =~ s/\Q$parm_ipv4/ip4.ip4.ip4.ip4/gr, $_ ] }  # this is too modern for 5.10.1
2314                map  {
2315                 (my $k = (split)[0]) =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/g;
2316                 [ $k, $_ ]
2317                }
2318                do { local $/ = "\n  "; <$in> };
2319     foreach $item (@temp)
2320       {
2321       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2322       print $out "  $item\n";
2323       }
2324     }
2325   else
2326     {
2327     my @temp = <$in>;
2328     if ($which eq "callout")
2329       {
2330       @temp = sort {
2331                    my($aa) = substr $a, 21;
2332                    my($bb) = substr $b, 21;
2333                    return $aa cmp $bb;
2334                    } @temp;
2335       }
2336     elsif ($which eq "seen")
2337       {
2338       @temp = sort {
2339                    (my $aa = $a) =~ s/^([\d.]+)/$1/;
2340                    (my $bb = $b) =~ s/^([\d.]+)/$1/;
2341                    $aa =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/;
2342                    $bb =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/;
2343                    return $aa cmp $bb;
2344                    } @temp;
2345       }
2346     print $out @temp;
2347     }
2348   close($in); # close it explicitly, otherwise $? does not get set
2349   return 1;
2350   }
2351
2352
2353 # verbose comments start with ###
2354 if (/^###\s/) {
2355   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2356     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2357     say {$fh} $_;
2358   }
2359   return 0;
2360 }
2361
2362 # The "echo" command is a way of writing comments to the screen.
2363 if (/^echo\s+(.*)$/)
2364   {
2365   print "$1\n";
2366   return 0;
2367   }
2368
2369
2370 # The "exim_lock" command runs exim_lock in the same manner as "server",
2371 # but it doesn't use any input.
2372
2373 if (/^exim_lock\s+(.*)$/)
2374   {
2375   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2376   $server_pid = open SERVERCMD, "|$cmd" ||
2377     tests_exit(-1, "Failed to run $cmd\n");
2378
2379   # This gives the process time to get started; otherwise the next
2380   # process may not find it there when it expects it.
2381
2382   select(undef, undef, undef, 0.1);
2383   return 3;
2384   }
2385
2386
2387 # The "exinext" command runs exinext
2388
2389 if (/^exinext\s+(.*)/)
2390   {
2391   run_system("(./eximdir/exinext " .
2392     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2393     "-C $parm_cwd/test-config $1;" .
2394     "echo exinext exit code = \$?)" .
2395     ">>test-stdout");
2396   return 1;
2397   }
2398
2399
2400 # The "exigrep" command runs exigrep on the current mainlog
2401
2402 if (/^exigrep\s+(.*)/)
2403   {
2404   run_system("(./eximdir/exigrep " .
2405     "$1 $parm_cwd/spool/log/mainlog;" .
2406     "echo exigrep exit code = \$?)" .
2407     ">>test-stdout");
2408   return 1;
2409   }
2410
2411
2412 # The "eximstats" command runs eximstats on the current mainlog
2413
2414 if (/^eximstats\s+(.*)/)
2415   {
2416   run_system("(./eximdir/eximstats " .
2417     "$1 $parm_cwd/spool/log/mainlog;" .
2418     "echo eximstats exit code = \$?)" .
2419     ">>test-stdout");
2420   return 1;
2421   }
2422
2423
2424 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2425 # spool directory, to save Exim from re-creating it each time.
2426
2427 if (/^gnutls/)
2428   {
2429   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2430   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2431          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2432          "sudo chmod 0400 $gen_fn";
2433   return 1;
2434   }
2435
2436
2437 # The "killdaemon" command should ultimately follow the starting of any Exim
2438 # daemon with the -bd option.
2439
2440 if (/^killdaemon/)
2441   {
2442   my $return_extra = {};
2443   if (exists $aux_info->{exim_pid})
2444     {
2445     $pid = $aux_info->{exim_pid};
2446     $return_extra->{exim_pid} = undef;
2447     print ">> killdaemon: recovered pid $pid\n" if $debug;
2448     if ($pid)
2449       {
2450       run_system("sudo /bin/kill -TERM $pid");
2451       wait;
2452       }
2453     } else {
2454     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2455     if ($pid)
2456       {
2457       run_system("sudo /bin/kill -TERM $pid");
2458       close DAEMONCMD;                                   # Waits for process
2459       }
2460     }
2461     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2462   return (1, $return_extra);
2463   }
2464
2465
2466 # The "millisleep" command is like "sleep" except that its argument is in
2467 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2468 # is used for.
2469
2470 elsif (/^millisleep\s+(.*)$/)
2471   {
2472   select(undef, undef, undef, $1/1000);
2473   return 0;
2474   }
2475
2476
2477 # The "munge" command selects one of a hardwired set of test-result modifications
2478 # to be made before result compares are run against the golden set.  This lets
2479 # us account for test-system dependent things which only affect a few, but known,
2480 # test-cases.
2481 # Currently only the last munge takes effect.
2482
2483 if (/^munge\s+(.*)$/)
2484   {
2485   return (0, { munge => $1 });
2486   }
2487
2488
2489 # The "sleep" command does just that. For sleeps longer than 1 second we
2490 # tell the user what's going on.
2491
2492 if (/^sleep\s+(.*)$/)
2493   {
2494   if ($1 == 1)
2495     {
2496     sleep(1);
2497     }
2498   else
2499     {
2500     printf("  Test %d sleep $1 ", $$subtestref);
2501     for (1..$1)
2502       {
2503       print ".";
2504       sleep(1);
2505       }
2506     printf("\r  Test %d                            $cr", $$subtestref);
2507     }
2508   return 0;
2509   }
2510
2511
2512 # Various Unix management commands are recognized
2513
2514 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2515     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2516   {
2517   run_system("$_ >>test-stdout 2>>test-stderr");
2518   return 1;
2519   }
2520
2521
2522
2523 ###################
2524 ###################
2525
2526 # The next group of commands are also freestanding, but they are all followed
2527 # by data lines.
2528
2529
2530 # The "server" command starts up a script-driven server that runs in parallel
2531 # with the following exim command. Therefore, we want to run a subprocess and
2532 # not yet wait for it to complete. The waiting happens after the next exim
2533 # command, triggered by $server_pid being non-zero. The server sends its output
2534 # to a different file. The variable $server_opts, if not empty, contains
2535 # options to disable IPv4 or IPv6 if necessary.
2536 # This works because "server" swallows its stdin before waiting for a connection.
2537
2538 if (/^server\s+(.*)$/)
2539   {
2540   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2541   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2542   print ">> $cmd\n" if ($debug);
2543   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2544   SERVERCMD->autoflush(1);
2545   print ">> Server pid is $server_pid\n" if $debug;
2546   while (<SCRIPT>)
2547     {
2548     $lineno++;
2549     last if /^\*{4}\s*$/;
2550     print SERVERCMD;
2551     }
2552   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2553                             # because close() waits for the process.
2554
2555   # Interlock the server startup; otherwise the next
2556   # process may not find it there when it expects it.
2557   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2558   return 3;
2559   }
2560
2561
2562 # The "write" command is a way of creating files of specific sizes for
2563 # buffering tests, or containing specific data lines from within the script
2564 # (rather than hold lots of little files). The "catwrite" command does the
2565 # same, but it also copies the lines to test-stdout.
2566
2567 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2568   {
2569   my($cat) = defined $1;
2570   @sizes = ();
2571   @sizes = split /\s+/, $3 if defined $3;
2572   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2573
2574   if ($cat)
2575     {
2576     open CAT, ">>test-stdout" ||
2577       tests_exit(-1, "Failed to open test-stdout: $!");
2578     print CAT "==========\n";
2579     }
2580
2581   if (scalar @sizes > 0)
2582     {
2583     # Pre-data
2584
2585     while (<SCRIPT>)
2586       {
2587       $lineno++;
2588       last if /^\+{4}\s*$/;
2589       print FILE;
2590       print CAT if $cat;
2591       }
2592
2593     # Sized data
2594
2595     while (scalar @sizes > 0)
2596       {
2597       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2598       $leadin = '' if !defined $leadin;
2599       $leadin =~ s/_/ /g;
2600       $len -= length($leadin) + 1;
2601       while ($count-- > 0)
2602         {
2603         print FILE $leadin, "a" x $len, "\n";
2604         print CAT $leadin, "a" x $len, "\n" if $cat;
2605         }
2606       }
2607     }
2608
2609   # Post data, or only data if no sized data
2610
2611   while (<SCRIPT>)
2612     {
2613     $lineno++;
2614     last if /^\*{4}\s*$/;
2615     print FILE;
2616     print CAT if $cat;
2617     }
2618   close FILE;
2619
2620   if ($cat)
2621     {
2622     print CAT "==========\n";
2623     close CAT;
2624     }
2625
2626   return 0;
2627   }
2628
2629
2630 ###################
2631 ###################
2632
2633 # From this point on, script commands are implemented by setting up a shell
2634 # command in the variable $cmd. Shared code to run this command and handle its
2635 # input and output follows.
2636
2637 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2638 # program that plays the part of an email client. We also have the availability
2639 # of running Perl for doing one-off special things. Note that all these
2640 # commands expect stdin data to be supplied.
2641
2642 if (/^client/ || /^(sudo\s+)?perl\b/)
2643   {
2644   s"client"./bin/client";
2645   $cmd = "$_ >>test-stdout 2>>test-stderr";
2646   }
2647
2648 # For the "exim" command, replace the text "exim" with the path for the test
2649 # binary, plus -D options to pass over various parameters, and a -C option for
2650 # the testing configuration file. When running in the test harness, Exim does
2651 # not drop privilege when -C and -D options are present. To run the exim
2652 # command as root, we use sudo.
2653
2654 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2655   {
2656   $args = $6;
2657   my($envset) = (defined $1)? $1      : '';
2658   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2659   my($special)= (defined $5)? $5      : '';
2660   $wait_time  = (defined $2)? $2      : 0;
2661
2662   # Return 2 rather than 1 afterwards
2663
2664   $yield = 2;
2665
2666   # Update the test number
2667
2668   $$subtestref = $$subtestref + 1;
2669   printf("  Test %d       $cr", $$subtestref);
2670
2671   # Copy the configuration file, making the usual substitutions.
2672
2673   open (IN, "$parm_cwd/confs/$testno") ||
2674     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2675   open (OUT, ">test-config") ||
2676     tests_exit(-1, "Couldn't open test-config: $!\n");
2677   while (<IN>)
2678     {
2679     do_substitute($testno);
2680     print OUT;
2681     }
2682   close(IN);
2683   close(OUT);
2684
2685   # The string $msg1 in args substitutes the message id of the first
2686   # message on the queue, and so on. */
2687
2688   if ($args =~ /\$msg/)
2689     {
2690     my($queuespec);
2691     if ($args =~ /-qG\w+/) { $queuespec = $&; }
2692
2693     my @listcmd;
2694
2695     if (defined $queuespec)
2696       {
2697       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2698                    $queuespec,
2699                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2700                    -C => "$parm_cwd/test-config");
2701       }
2702     else
2703       {
2704       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2705                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2706                    -C => "$parm_cwd/test-config");
2707       }
2708     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2709     # We need the message ids sorted in ascending order.
2710     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2711     # PIDs are randomized, so sorting just the whole PID doesn't work.
2712     # We do the Schartz' transformation here (sort on
2713     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2714     my @msglist =
2715       map { $_->[1] }                                   # extract the values
2716       sort { $a->[0] cmp $b->[0] }                      # sort by key
2717       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2718       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2719
2720     # Done backwards just in case there are more than 9
2721
2722     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2723     if ( $args =~ /\$msg\d/ )
2724       {
2725       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2726         unless $force_continue;
2727       }
2728     }
2729
2730   # If -d is specified in $optargs, remove it from $args; i.e. let
2731   # the command line for runtest override. Then run Exim.
2732
2733   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2734
2735   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2736
2737   $cmd = "$envset$sudo$opt_valgrind" .
2738          "$parm_cwd/eximdir/exim$special$optargs " .
2739          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2740          "-C $parm_cwd/test-config $args " .
2741          ">>test-stdout 2>>test-stderr";
2742   # If the command is starting an Exim daemon, we run it in the same
2743   # way as the "server" command above, that is, we don't want to wait
2744   # for the process to finish. That happens when "killdaemon" is obeyed later
2745   # in the script. We also send the stderr output to test-stderr-server. The
2746   # daemon has its log files put in a different place too (by configuring with
2747   # log_file_path). This requires the  directory to be set up in advance.
2748   #
2749   # There are also times when we want to run a non-daemon version of Exim
2750   # (e.g. a queue runner) with the server configuration. In this case,
2751   # we also define -DNOTDAEMON.
2752
2753   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2754     {
2755     if ($debug) { printf ">> daemon: $cmd\n"; }
2756     run_system("sudo mkdir spool/log 2>/dev/null");
2757     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2758
2759     # Before running the command, convert the -bd option into -bdf so that an
2760     # Exim daemon doesn't double fork. This means that when we wait close
2761     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2762     # file is written to the spool directory, in case the Exim binary was
2763     # built with PID_FILE_PATH pointing somewhere else.
2764
2765     if ($cmd =~ /\s-oP\s/)
2766       {
2767       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2768       $cmd =~ s!\s-bd\s! -bdf !;
2769       }
2770     else
2771       {
2772       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2773       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2774       }
2775     print ">> |${cmd}-server\n" if ($debug);
2776     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2777     DAEMONCMD->autoflush(1);
2778     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2779
2780     # Interlock with daemon startup
2781     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2782       { select(undef, undef, undef, 0.3); }
2783     return 3;                                     # Don't wait
2784     }
2785   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2786     {
2787
2788     # The port and the $dynamic_socket was already allocated while parsing the
2789     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2790
2791     my $listen_port = $1;
2792     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2793     run_system("sudo mkdir spool/log 2>/dev/null");
2794     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2795
2796     my $pid = fork();
2797     if (not defined $pid) { die "** fork failed: $!\n" }
2798     if (not $pid) {
2799       close(STDIN);
2800       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2801       close($dynamic_socket);
2802       print "[$$]>> ${cmd}-server\n" if ($debug);
2803       exec "exec ${cmd}-server";
2804       die "Can't exec ${cmd}-server: $!\n";
2805     }
2806     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2807     select(undef, undef, undef, 0.3);             # Let the daemon get going
2808     return (3, { exim_pid => $pid });             # Don't wait
2809     }
2810   }
2811
2812 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2813 # One script line is read and fork-exec'd.  The PID is stored for a later
2814 # killdaemon.
2815
2816 elsif (/^background$/)
2817   {
2818   my $line;
2819 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2820
2821   $_ = <SCRIPT>; $lineno++;
2822   chomp;
2823   do_substitute($testno);
2824   $line = $_;
2825   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2826
2827   my $pid = fork();
2828   if (not defined $pid) { die "** fork failed: $!\n" }
2829   if (not $pid) {
2830     print "[$$]>> ${line}\n" if ($debug);
2831     close(STDIN);
2832     open(STDIN, "<", "test-stdout");
2833     close(STDOUT);
2834     open(STDOUT, ">>", "test-stdout");
2835     close(STDERR);
2836     open(STDERR, ">>", "test-stderr-server");
2837     exec "exec ${line}";
2838     exit(1);
2839   }
2840
2841 #  open(my $fh, ">", $pidfile) ||
2842 #      tests_exit(-1, "Failed to open $pidfile: $!");
2843 #  printf($fh, "%d\n", $pid);
2844 #  close($fh);
2845
2846   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2847   select(undef, undef, undef, 0.3);             # Let the daemon get going
2848   return (3, { exim_pid => $pid });             # Don't wait
2849   }
2850
2851
2852
2853 # Unknown command
2854
2855 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2856
2857
2858 # Run the command, with stdin connected to a pipe, and write the stdin data
2859 # to it, with appropriate substitutions. If a starts with '>>> ', process it
2860 # via Perl's string eval().
2861 # If the command contains
2862 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2863 # for the stderr file. See comment above about the use of -DSERVER.
2864
2865 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2866 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2867 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2868
2869 CMD->autoflush(1);
2870 LINE: while (<SCRIPT>)
2871   {
2872   $lineno++;
2873   last if /^\*{4}\s*$/;
2874   do_substitute($testno);
2875   if (my ($cmd, $line) = /^(:\S+?:)(.*)/) {
2876     $_ = $line;
2877       {
2878       $cmd eq ':eval:' and do {
2879         $_ = eval "\"$_\"";
2880         last;
2881       };
2882       $cmd eq ':noeol:' and do {
2883         s/[\r\n]*$//;
2884         last;
2885       };
2886       $cmd eq ':sleep:' and do {
2887         sleep $_;
2888         next LINE;
2889       };
2890     }
2891   }
2892   print CMD;
2893   }
2894
2895 # For timeout tests, wait before closing the pipe; we expect a
2896 # SIGPIPE error in this case.
2897
2898 if ($wait_time > 0)
2899   {
2900   printf("  Test %d sleep $wait_time ", $$subtestref);
2901   while ($wait_time-- > 0)
2902     {
2903     print ".";
2904     sleep(1);
2905     }
2906   printf("\r  Test %d                                       $cr", $$subtestref);
2907   }
2908
2909 $sigpipehappened = 0;
2910 close CMD;                # Waits for command to finish
2911 return $yield;            # Ran command and waited
2912 }
2913
2914
2915
2916
2917 ###############################################################################
2918 ###############################################################################
2919
2920 # Here begins the Main Program ...
2921
2922 ###############################################################################
2923 ###############################################################################
2924
2925
2926 autoflush STDOUT 1;
2927 print "Exim tester $testversion\n";
2928
2929 # extend the PATH with .../sbin
2930 # we map all (.../bin) to (.../sbin:.../bin)
2931 $ENV{PATH} = do {
2932   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2933   join ':' => map { m{(.*)/bin$}
2934                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2935                 : ($_) }
2936       split /:/, $ENV{PATH};
2937 };
2938
2939 ##################################################
2940 #      Some tests check created file modes       #
2941 ##################################################
2942
2943 umask 022;
2944
2945
2946 ##################################################
2947 #       Check for the "less" command             #
2948 ##################################################
2949
2950 @more = 'more' if system('which less >/dev/null 2>&1') != 0;
2951
2952
2953
2954 ##################################################
2955 #      See if an Exim binary has been given      #
2956 ##################################################
2957
2958 # If the first character of the first argument is '/', the argument is taken
2959 # as the path to the binary. If the first argument does not start with a
2960 # '/' but exists in the file system, it's assumed to be the Exim binary.
2961
2962
2963 ##################################################
2964 # Sort out options and which tests are to be run #
2965 ##################################################
2966
2967 # There are a few possible options for the test script itself; after these, any
2968 # options are passed on to Exim calls within the tests. Typically, this is used
2969 # to turn on Exim debugging while setting up a test.
2970
2971 Getopt::Long::Configure qw(no_getopt_compat);
2972 GetOptions(
2973     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2974     'diff'     => sub { $cf             = 'diff -u' },
2975     'continue' => sub { $force_continue = 1; @more = 'cat' },
2976     'update'   => \$force_update,
2977     'ipv4!'    => \$have_ipv4,
2978     'ipv6!'    => \$have_ipv6,
2979     'keep'     => \$save_output,
2980     'slow'     => \$slow,
2981     'valgrind' => \$valgrind,
2982     'range=s{2}'       => \my @range_wanted,
2983     'test=i@'          => \my @tests_wanted,
2984     'fail-any!'        => \my $fail_any,
2985     'flavor|flavour=s' => \$flavour,
2986     'help'             => sub { pod2usage(-exit => 0) },
2987     'man'              => sub {
2988         pod2usage(
2989             -exit      => 0,
2990             -verbose   => 2,
2991             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2992         );
2993     },
2994 ) or pod2usage;
2995
2996 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2997 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2998
2999
3000 my @wanted = sort numerically uniq
3001   @tests_wanted ? @tests_wanted : (),
3002   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
3003   @ARGV ? @ARGV == 1 ? $ARGV[0] :
3004           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
3005           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
3006         : ();
3007 @wanted = 1..TEST_TOP if not @wanted;
3008
3009 ##################################################
3010 #        Check for sudo access to root           #
3011 ##################################################
3012
3013 print "You need to have sudo access to root to run these tests. Checking ...\n";
3014 if (system('sudo true >/dev/null') != 0)
3015   {
3016   die "** Test for sudo failed: testing abandoned.\n";
3017   }
3018 else
3019   {
3020   print "Test for sudo OK\n";
3021   }
3022
3023
3024
3025
3026 ##################################################
3027 #      Make the command's directory current      #
3028 ##################################################
3029
3030 # After doing so, we find its absolute path name.
3031
3032 $cwd = $0;
3033 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
3034 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
3035 $parm_cwd = Cwd::getcwd();
3036
3037
3038 ##################################################
3039 #     Search for an Exim binary to test          #
3040 ##################################################
3041
3042 # If an Exim binary hasn't been provided, try to find one. We can handle the
3043 # case where exim-testsuite is installed alongside Exim source directories. For
3044 # PH's private convenience, if there's a directory just called "exim4", that
3045 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
3046 # releases.
3047
3048 # If $parm_exim is still empty, ask the caller
3049
3050 if (not $parm_exim)
3051   {
3052   print "** Did not find an Exim binary to test\n";
3053   for ($i = 0; $i < 5; $i++)
3054     {
3055     my($trybin);
3056     print "** Enter pathname for Exim binary: ";
3057     chomp($trybin = <STDIN>);
3058     if (-e $trybin)
3059       {
3060       $parm_exim = $trybin;
3061       last;
3062       }
3063     else
3064       {
3065       print "** $trybin does not exist\n";
3066       }
3067     }
3068   die "** Too many tries\n" if $parm_exim eq '';
3069   }
3070
3071
3072
3073 ##################################################
3074 #          Find what is in the binary            #
3075 ##################################################
3076
3077 # deal with TRUSTED_CONFIG_LIST restrictions
3078 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
3079 open (IN, "$parm_cwd/confs/0000") ||
3080   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3081 open (OUT, ">test-config") ||
3082   tests_exit(-1, "Couldn't open test-config: $!\n");
3083 while (<IN>) { print OUT; }
3084 close(IN);
3085 close(OUT);
3086
3087 print("Probing with config file: $parm_cwd/test-config\n");
3088
3089 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
3090 chomp(my @eximinfo = `$eximinfo 2>&1`);
3091 die "$0: Can't run $eximinfo\n" if $? == -1;
3092
3093 warn 'Got ' . ($?>>8) . " from $eximinfo\n" if $?;
3094 foreach (@eximinfo)
3095   {
3096   if (my ($version) = /^Exim version (\S+)/) {
3097     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
3098     if (defined $git and $? == 0) {
3099       chomp $git;
3100       $git =~ s/^exim-//i;
3101       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
3102       print <<___
3103
3104 *** Version mismatch
3105 *** Exim binary: $version
3106 *** Git        : $git
3107
3108 ___
3109         if not $version eq $git;
3110     }
3111   }
3112   $parm_eximuser = $1 if /^exim_user = (.*)$/;
3113   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
3114   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
3115   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
3116         if /^Configure owner:\s*(\d+):(\d+)/;
3117   print if /wrong owner/;
3118   }
3119
3120 if (not defined $parm_eximuser) {
3121   die <<XXX, map { "|$_\n" } @eximinfo;
3122 Unable to extract exim_user from binary.
3123 Check if Exim refused to run; if so, consider:
3124   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
3125 If debug permission denied, are you in the exim group?
3126 Failing to get information from binary.
3127 Output from $eximinfo:
3128 XXX
3129
3130 }
3131
3132 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
3133 else { $parm_exim_uid = getpwnam($parm_eximuser); }
3134
3135 if (defined $parm_eximgroup)
3136   {
3137   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
3138     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
3139   }
3140
3141 # check the permissions on the TRUSTED_CONFIG_LIST
3142 if (defined $parm_trusted_config_list)
3143   {
3144   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
3145     if not -f $parm_trusted_config_list;
3146
3147   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
3148     if 02 & (stat _)[2];
3149
3150   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
3151   (stat _)[1],
3152     scalar(getgrgid 0), scalar(getgrgid $>)
3153     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
3154
3155   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
3156   scalar(getpwuid 0), scalar(getpwuid $>)
3157      if (not (-o _ or (stat _)[4] == 0));
3158
3159   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
3160   my $test_config = getcwd() . '/test-config';
3161   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
3162     if not grep { /^\Q$test_config\E$/ } <TCL>;
3163   }
3164 else
3165   {
3166   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
3167   }
3168
3169 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
3170         if $parm_configure_owner != $>;
3171
3172 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
3173         if 0020 & (stat "$parm_cwd/test-config")[2]
3174         and $parm_configure_group != $);
3175
3176 die "aux-fixed file is group-writeable; best to strip them all, recursively\n"
3177         if 0020 & (stat "aux-fixed/0037.f-1")[2];
3178
3179
3180 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
3181   die "** Cannot run $parm_exim: $!\n";
3182
3183 print "-" x 78, "\n";
3184
3185 while (<EXIMINFO>)
3186   {
3187   my(@temp);
3188
3189   if (/^(Exim|Library) version/) { print; }
3190   if (/Runtime: /) {print; }
3191
3192   elsif (/^Size of off_t: (\d+)/)
3193     {
3194     print;
3195     $have_largefiles = 1 if $1 > 4;
3196     die "** Size of off_t > 32 which seems improbable, not running tests\n"
3197         if ($1 > 32);
3198     }
3199
3200   elsif (/^Support for: (.*)/)
3201     {
3202     print;
3203     @temp = split /(\s+)/, $1;
3204     push(@temp, ' ');
3205     %parm_support = @temp;
3206     }
3207
3208   elsif (/^Lookups \(built-in\): (.*)/)
3209     {
3210     print;
3211     @temp = split /(\s+)/, $1;
3212     push(@temp, ' ');
3213     %parm_lookups = @temp;
3214     }
3215
3216   elsif (/^Authenticators: (.*)/)
3217     {
3218     print;
3219     @temp = split /(\s+)/, $1;
3220     push(@temp, ' ');
3221     %parm_authenticators = @temp;
3222     }
3223
3224   elsif (/^Routers: (.*)/)
3225     {
3226     print;
3227     @temp = split /(\s+)/, $1;
3228     push(@temp, ' ');
3229     %parm_routers = @temp;
3230     }
3231
3232   # Some transports have options, e.g. appendfile/maildir. For those, ensure
3233   # that the basic transport name is set, and then the name with each of the
3234   # options.
3235
3236   elsif (/^Transports: (.*)/)
3237     {
3238     print;
3239     @temp = split /(\s+)/, $1;
3240     my($i,$k);
3241     push(@temp, ' ');
3242     %parm_transports = @temp;
3243     foreach $k (keys %parm_transports)
3244       {
3245       if ($k =~ "/")
3246         {
3247         @temp = split /\//, $k;
3248         $parm_transports{$temp[0]} = " ";
3249         for ($i = 1; $i < @temp; $i++)
3250           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
3251         }
3252       }
3253     }
3254
3255   elsif (/^Malware: (.*)/)
3256     {
3257     print;
3258     @temp = split /(\s+)/, $1;
3259     push(@temp, ' ');
3260     %parm_malware = @temp;
3261     }
3262
3263   }
3264 close(EXIMINFO);
3265 print "-" x 78, "\n";
3266
3267 unlink("$parm_cwd/test-config");
3268
3269 ##################################################
3270 #    Check for SpamAssassin and ClamAV           #
3271 ##################################################
3272
3273 # These are crude tests. If they aren't good enough, we'll have to improve
3274 # them, for example by actually passing a message through spamc or clamscan.
3275
3276 if (defined $parm_support{Content_Scanning})
3277   {
3278   my $sock = new FileHandle;
3279
3280   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
3281     {
3282     print "The spamc command works:\n";
3283
3284     # This test for an active SpamAssassin is courtesy of John Jetmore.
3285     # The tests are hard coded to localhost:783, so no point in making
3286     # this test flexible like the clamav test until the test scripts are
3287     # changed.  spamd doesn't have the nice PING/PONG protocol that
3288     # clamd does, but it does respond to errors in an informative manner,
3289     # so use that.
3290
3291     my($sint,$sport) = ('127.0.0.1',783);
3292     eval
3293       {
3294       my $sin = sockaddr_in($sport, inet_aton($sint))
3295           or die "** Failed packing $sint:$sport\n";
3296       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3297           or die "** Unable to open socket $sint:$sport\n";
3298
3299       local $SIG{ALRM} =
3300           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3301       alarm(5);
3302       connect($sock, $sin)
3303           or die "** Unable to connect to socket $sint:$sport\n";
3304       alarm(0);
3305
3306       select((select($sock), $| = 1)[0]);
3307       print $sock "bad command\r\n";
3308
3309       $SIG{ALRM} =
3310           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3311       alarm(10);
3312       my $res = <$sock>;
3313       alarm(0);
3314
3315       $res =~ m|^SPAMD/|
3316           or die "** Did not get SPAMD from socket $sint:$sport. "
3317                 ."It said: $res\n";
3318       };
3319     alarm(0);
3320     if($@)
3321       {
3322       print "  $@";
3323       print "  Assume SpamAssassin (spamd) is not running\n";
3324       }
3325     else
3326       {
3327       $parm_running{SpamAssassin} = ' ';
3328       print "  SpamAssassin (spamd) seems to be running\n";
3329       }
3330     }
3331   else
3332     {
3333     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3334     }
3335
3336   # For ClamAV, we need to find the clamd socket for use in the Exim
3337   # configuration. Search for the clamd configuration file.
3338
3339   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3340     {
3341     my($f, $clamconf, $test_prefix);
3342
3343     print "The clamscan command works";
3344
3345     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3346     $test_prefix = '' if !defined $test_prefix;
3347
3348     foreach $f ("$test_prefix/etc/clamd.conf",
3349                 "$test_prefix/usr/local/etc/clamd.conf",
3350                 "$test_prefix/etc/clamav/clamd.conf", '')
3351       {
3352       if (-e $f)
3353         {
3354         $clamconf = $f;
3355         last;
3356         }
3357       }
3358
3359     # Read the ClamAV configuration file and find the socket interface.
3360
3361     if ($clamconf ne '')
3362       {
3363       my $socket_domain;
3364       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3365       while (<IN>)
3366         {
3367         if (/^LocalSocket\s+(.*)/)
3368           {
3369           $parm_clamsocket = $1;
3370           $socket_domain = AF_UNIX;
3371           last;
3372           }
3373         if (/^TCPSocket\s+(\d+)/)
3374           {
3375           if (defined $parm_clamsocket)
3376             {
3377             $parm_clamsocket .= " $1";
3378             $socket_domain = AF_INET;
3379             last;
3380             }
3381           else
3382             {
3383             $parm_clamsocket = " $1";
3384             }
3385           }
3386         elsif (/^TCPAddr\s+(\S+)/)
3387           {
3388           if (defined $parm_clamsocket)
3389             {
3390             $parm_clamsocket = $1 . $parm_clamsocket;
3391             $socket_domain = AF_INET;
3392             last;
3393             }
3394           else
3395             {
3396             $parm_clamsocket = $1;
3397             }
3398           }
3399         }
3400       close(IN);
3401
3402       if (defined $socket_domain)
3403         {
3404         print ":\n  The clamd socket is $parm_clamsocket\n";
3405         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3406         eval
3407           {
3408           my $socket;
3409           if ($socket_domain == AF_UNIX)
3410             {
3411             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3412             }
3413           elsif ($socket_domain == AF_INET)
3414             {
3415             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3416             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3417             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3418             }
3419           else
3420             {
3421             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3422             }
3423           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3424           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3425           alarm(5);
3426           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3427           alarm(0);
3428
3429           my $ofh = select $sock; $| = 1; select $ofh;
3430           print $sock "PING\n";
3431
3432           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3433           alarm(10);
3434           my $res = <$sock>;
3435           alarm(0);
3436
3437           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3438           };
3439         alarm(0);
3440
3441         if($@)
3442           {
3443           print "  $@";
3444           print "  Assume ClamAV is not running\n";
3445           }
3446         else
3447           {
3448           $parm_running{ClamAV} = ' ';
3449           print "  ClamAV seems to be running\n";
3450           }
3451         }
3452       else
3453         {
3454         print ", but the socket for clamd could not be determined\n";
3455         print "Assume ClamAV is not running\n";
3456         }
3457       }
3458
3459     else
3460       {
3461       print ", but I can't find a configuration for clamd\n";
3462       print "Assume ClamAV is not running\n";
3463       }
3464     }
3465   }
3466
3467
3468 ##################################################
3469 #       Check for redis                          #
3470 ##################################################
3471 if (defined $parm_lookups{redis})
3472   {
3473   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3474     {
3475     print "The redis-server command works\n";
3476     $parm_running{redis} = ' ';
3477     }
3478   else
3479     {
3480     print "The redis-server command failed: assume Redis not installed\n";
3481     }
3482   }
3483
3484 ##################################################
3485 #         Test for the basic requirements        #
3486 ##################################################
3487
3488 # This test suite assumes that Exim has been built with at least the "usual"
3489 # set of routers, transports, and lookups. Ensure that this is so.
3490
3491 $missing = '';
3492
3493 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3494
3495 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3496 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3497 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3498 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3499
3500 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3501 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3502 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3503 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3504
3505 if ($missing ne '')
3506   {
3507   print "\n";
3508   print "** Many features can be included or excluded from Exim binaries.\n";
3509   print "** This test suite requires that Exim is built to contain a certain\n";
3510   print "** set of basic facilities. It seems that some of these are missing\n";
3511   print "** from the binary that is under test, so the test cannot proceed.\n";
3512   print "** The missing facilities are:\n";
3513   print "$missing";
3514   die "** Test script abandoned\n";
3515   }
3516
3517
3518 ##################################################
3519 #      Check for the auxiliary programs          #
3520 ##################################################
3521
3522 # These are always required:
3523
3524 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3525            "fakens", "iefbr14", "server")
3526   {
3527   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3528   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3529   if (!-e "bin/$prog")
3530     {
3531     print "\n";
3532     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3533     die "** Test script abandoned\n";
3534     }
3535   }
3536
3537 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3538 # compiled on systems where we don't know how to. However, if Exim does not
3539 # have that functionality compiled, we needn't bother.
3540
3541 $dlfunc_deleted = 0;
3542 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3543   {
3544   delete $parm_support{Expand_dlfunc};
3545   $dlfunc_deleted = 1;
3546   }
3547
3548
3549 ##################################################
3550 #          Find environmental details            #
3551 ##################################################
3552
3553 # Find the caller of this program.
3554
3555 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3556  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3557
3558 $pwpw = $pwpw;       # Kill Perl warnings
3559 $pwquota = $pwquota;
3560 $pwcomm = $pwcomm;
3561
3562 $parm_caller_group = getgrgid($parm_caller_gid);
3563
3564 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3565 print "Home directory is $parm_caller_home\n";
3566
3567 unless (defined $parm_eximgroup)
3568   {
3569   print "Unable to derive \$parm_eximgroup.\n";
3570   die "** ABANDONING.\n";
3571   }
3572
3573 if ($parm_caller_home eq $parm_cwd)
3574   {
3575   print "will confuse working dir with homedir; change homedir\n";
3576   die "** ABANDONING.\n";
3577   }
3578
3579 print "You need to be in the Exim group to run these tests. Checking ...";
3580
3581 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3582   {
3583   print " OK\n";
3584   }
3585 else
3586   {
3587   print "\nOh dear, you are not in the Exim group.\n";
3588   die "** Testing abandoned.\n";
3589   }
3590
3591 # Find this host's IP addresses - there may be many, of course, but we keep
3592 # one of each type (IPv4 and IPv6).
3593 #XXX it would be good to avoid non-UP interfaces
3594
3595 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3596   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3597 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3598   {
3599   if (/^(?:[0-9]+: )?([a-z0-9]+): /) { $ifname = $1; }
3600
3601   if (not $parm_ipv4 and /^\s*inet(?:\saddr(?:ess))?:?\s*(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3602     {
3603     # It would be nice to be able to vary the /16 used for manyhome; we could take
3604     # an option to runtest used here - but we'd also have to pass it on to fakens.
3605     # Possibly an environment variable?
3606     next if $1 eq '0.0.0.0' or $1 =~ /^(?:127|10\.250)\./;
3607     $parm_ipv4 = $1;
3608     }
3609
3610   if (   (not $parm_ipv6 or $parm_ipv6 =~ /%/)
3611      and /^\s*inet6(?:\saddr(?:ess))?:?\s*([abcdef\d:]+)(?:%[^ \/]+)?(?:\/\d+)?/i)
3612     {
3613     next if $1 eq '::' or $1 eq '::1' or $1 =~ /^ff00/i or $1 =~ /^fe80::1/i;
3614     $parm_ipv6 = $1;
3615     if ($1 =~ /^fe80/i) { $parm_ipv6 .= '%' . $ifname; }
3616     }
3617   }
3618 close(IFCONFIG);
3619
3620 # Use private IP addresses if there are no public ones.
3621
3622 # If either type of IP address is missing, we need to set the value to
3623 # something other than empty, because that wrecks the substitutions. The value
3624 # is reflected, so use a meaningful string. Set appropriate options for the
3625 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3626 # available, so things will go wrong if there is no IPv4 address. The lack
3627 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3628 # and $have_ipv6 false.
3629
3630 if (not $parm_ipv4)
3631   {
3632   $have_ipv4 = 0;
3633   $parm_ipv4 = "<no IPv4 address found>";
3634   $server_opts .= " -noipv4";
3635   }
3636 elsif ($have_ipv4 == 0)
3637   {
3638   $parm_ipv4 = "<IPv4 testing disabled>";
3639   $server_opts .= " -noipv4";
3640   }
3641 else
3642   {
3643   $parm_running{IPv4} = " ";
3644   }
3645
3646 if (not $parm_ipv6)
3647   {
3648   $have_ipv6 = 0;
3649   $parm_ipv6 = "<no IPv6 address found>";
3650   $server_opts .= " -noipv6";
3651   delete($parm_support{IPv6});
3652   }
3653 elsif ($have_ipv6 == 0)
3654   {
3655   $parm_ipv6 = "<IPv6 testing disabled>";
3656   $server_opts .= " -noipv6";
3657   delete($parm_support{IPv6});
3658   }
3659 elsif (!defined $parm_support{IPv6})
3660   {
3661   $have_ipv6 = 0;
3662   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3663   $server_opts .= " -noipv6";
3664   }
3665 else
3666   {
3667   $parm_running{IPv6} = " ";
3668   }
3669
3670 print "IPv4 address is $parm_ipv4\n";
3671 print "IPv6 address is $parm_ipv6\n";
3672 $parm_ipv6 =~ /^[^%\/]*/;
3673 # drop any %scope from the ipv6, for some uses
3674 ($parm_ipv6_stripped = $parm_ipv6) =~ s/%.*//g;
3675
3676 # For munging test output, we need the reversed IP addresses.
3677
3678 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3679   join(".", reverse(split /\./, $parm_ipv4));
3680
3681 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3682 if ($parm_ipv6 =~ /^[\da-f]/)
3683   {
3684   my(@comps) = split /:/, $parm_ipv6_stripped;
3685   my(@nibbles);
3686   foreach $comp (@comps)
3687     {
3688     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3689     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3690     }
3691   $parm_ipv6r = join(".", reverse(@nibbles));
3692   }
3693
3694 # Find the host name, fully qualified.
3695
3696 chomp($temp = `hostname`);
3697 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3698 if ($temp =~ /\./)
3699   {
3700   $parm_hostname = $temp;
3701   }
3702 else
3703   {
3704   $parm_hostname = (gethostbyname($temp))[0];
3705   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3706   }
3707 print "Hostname is $parm_hostname\n";
3708
3709 if ($parm_hostname !~ /\./)
3710   {
3711   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3712   }
3713
3714 if ($parm_hostname =~ /[[:upper:]]/)
3715   {
3716   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3717   }
3718
3719 if ($parm_hostname =~ /\.example\.com$/)
3720   {
3721   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3722         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3723   }
3724
3725
3726
3727 ##################################################
3728 #     Create a testing version of Exim           #
3729 ##################################################
3730
3731 # We want to be able to run Exim with a variety of configurations. Normally,
3732 # the use of -C to change configuration causes Exim to give up its root
3733 # privilege (unless the caller is exim or root). For these tests, we do not
3734 # want this to happen. Also, we want Exim to know that it is running in its
3735 # test harness.
3736
3737 # We achieve this by copying the binary and patching it as we go. The new
3738 # binary knows it is a testing copy, and it allows -C and -D without loss of
3739 # privilege. Clearly, this file is dangerous to have lying around on systems
3740 # where there are general users with login accounts. To protect against this,
3741 # we put the new binary in a special directory that is accessible only to the
3742 # caller of this script, who is known to have sudo root privilege from the test
3743 # that was done above. Furthermore, we ensure that the binary is deleted at the
3744 # end of the test. First ensure the directory exists.
3745
3746 if (-d "eximdir")
3747   { unlink "eximdir/exim"; }     # Just in case
3748 else
3749   {
3750   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3751   system("sudo chgrp $parm_eximgroup eximdir");
3752   }
3753
3754 # The construction of the patched binary must be done as root, so we use
3755 # a separate script. As well as indicating that this is a test-harness binary,
3756 # the version number is patched to "x.yz" so that its length is always the
3757 # same. Otherwise, when it appears in Received: headers, it affects the length
3758 # of the message, which breaks certain comparisons.
3759
3760 die "** Unable to make patched exim: $!\n"
3761   if (system("sudo ./patchexim $parm_exim") != 0);
3762
3763 # From this point on, exits from the program must go via the subroutine
3764 # tests_exit(), so that suitable cleaning up can be done when required.
3765 # Arrange to catch interrupting signals, to assist with this.
3766
3767 $SIG{INT} = \&inthandler;
3768 $SIG{PIPE} = \&pipehandler;
3769
3770 # For some tests, we need another copy of the binary that is setuid exim rather
3771 # than root.
3772
3773 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3774        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3775        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3776        "sudo chmod 06755 eximdir/exim_exim");
3777
3778 ##################################################
3779 #     Make copies of utilities we might need     #
3780 ##################################################
3781
3782 # Certain of the tests make use of some of Exim's utilities. We do not need
3783 # to be root to copy these.
3784
3785 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3786
3787 $dbm_build_deleted = 0;
3788 if (defined $parm_lookups{dbm} && not cp("$parm_exim_dir/exim_dbmbuild", "eximdir/exim_dbmbuild"))
3789   {
3790   delete $parm_lookups{dbm};
3791   $dbm_build_deleted = 1;
3792   }
3793
3794 foreach my $tool (qw(exim_dumpdb exim_lock exinext exigrep eximstats)) {
3795   cp("$parm_exim_dir/$tool" => "eximdir/$tool")
3796     or tests_exit(-1, "Failed to make a copy of $tool: $!");
3797 }
3798
3799 # Collect some version information
3800 print '-' x 78, "\n";
3801 print "Perl version for runtest: $]\n";
3802 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3803   # fold (or unfold?) multiline output into a one-liner
3804   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3805 }
3806 print '-' x 78, "\n";
3807
3808
3809 ##################################################
3810 #    Check that the Exim user can access stuff   #
3811 ##################################################
3812
3813 # We delay this test till here so that we can check access to the actual test
3814 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3815
3816 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3817 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3818
3819 if ($parm_caller_uid eq $parm_exim_uid) {
3820   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3821                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3822 }
3823 if ($parm_caller_gid eq $parm_exim_gid) {
3824   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3825                 ."the same as caller's ($parm_caller) group as it confuses "
3826                 ."results analysis");
3827 }
3828
3829 print "The Exim user needs access to the test suite directory. Checking ...";
3830
3831 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3832   {
3833   my($why) = "unknown failure $rc";
3834   $rc >>= 8;
3835   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3836   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3837   $why = "Couldn't read auxiliary group list" if $rc == 3;
3838   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3839   $why = "Couldn't set gid" if $rc == 5;
3840   $why = "Couldn't set uid" if $rc == 6;
3841   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3842   print "\n** $why\n";
3843   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3844   }
3845 else
3846   {
3847   print " OK\n";
3848   }
3849
3850 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3851   if not unlink($log_summary_filename) and -e $log_summary_filename;
3852
3853 ##################################################
3854 #        Create a list of available tests        #
3855 ##################################################
3856
3857 # The scripts directory contains a number of subdirectories whose names are
3858 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3859 # from the first requires certain optional features to be included in the Exim
3860 # binary. These requirements are contained in a file called "REQUIRES" within
3861 # the directory. We scan all these tests, discarding those that cannot be run
3862 # because the current binary does not support the right facilities, and also
3863 # those that are outside the numerical range selected.
3864
3865 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3866   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3867
3868 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3869   if $dlfunc_deleted;
3870 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3871   if $dbm_build_deleted;
3872
3873
3874 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3875   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3876
3877 # Scan for relevant tests
3878 # HS12: Needs to be reworked.
3879 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3880   {
3881   my($testdir) = $test_dirs[$i];
3882   my($wantthis) = 1;
3883
3884   print ">>Checking $testdir\n" if $debug;
3885
3886   # Skip this directory if the first test is equal or greater than the first
3887   # test in the next directory.
3888
3889   next DIR if ($i < @test_dirs - 1) &&
3890           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3891
3892   # No need to carry on if the end test is less than the first test in this
3893   # subdirectory.
3894
3895   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3896
3897   # Check requirements, if any.
3898
3899   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3900     {
3901     while (<$requires>)
3902       {
3903       next if /^\s*$/;
3904       s/\s+$//;
3905       if (/^support (.*)$/)
3906         {
3907         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3908         }
3909       elsif (/^running (.*)$/)
3910         {
3911         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3912         }
3913       elsif (/^lookup (.*)$/)
3914         {
3915         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3916         }
3917       elsif (/^authenticators? (.*)$/)
3918         {
3919         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3920         }
3921       elsif (/^router (.*)$/)
3922         {
3923         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3924         }
3925       elsif (/^transport (.*)$/)
3926         {
3927         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3928         }
3929       elsif (/^malware (.*)$/)
3930         {
3931         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3932         }
3933       elsif (/^feature (.*)$/)
3934         {
3935         # move to a subroutine?
3936         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3937
3938         open (IN, "$parm_cwd/confs/0000") ||
3939           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3940         open (OUT, ">test-config") ||
3941           tests_exit(-1, "Couldn't open test-config: $!\n");
3942         while (<IN>)
3943           {
3944           do_substitute($testno);
3945           print OUT;
3946           }
3947         close(IN);
3948         close(OUT);
3949
3950         system($eximinfo . " >/dev/null 2>&1");
3951         if ($? != 0) {
3952           unlink("$parm_cwd/test-config");
3953           $wantthis = 0;
3954           $_ = "feature $1";
3955           last;
3956         }
3957         unlink("$parm_cwd/test-config");
3958         }
3959       elsif (/^ipv6-non-linklocal/)
3960         {
3961         if ($parm_ipv6 =~ /%/) { $wantthis = 0; last; }
3962         }
3963       else
3964         {
3965         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3966         }
3967       }
3968     }
3969   else
3970     {
3971     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3972       unless $!{ENOENT};
3973     }
3974
3975   # Loop if we do not want the tests in this subdirectory.
3976
3977   if (!$wantthis)
3978     {
3979     chomp;
3980     print "Omitting tests in $testdir (missing $_)\n";
3981     }
3982
3983   # We want the tests from this subdirectory, provided they are in the
3984   # range that was selected.
3985
3986   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3987   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3988     if not @testlist;
3989
3990   foreach $test (@testlist)
3991     {
3992     if (!$wantthis)
3993       {
3994       log_test($log_summary_filename, $test, '.');
3995       }
3996     else
3997       {
3998       push @test_list, "$testdir/$test";
3999       }
4000     }
4001   }
4002
4003 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
4004
4005
4006 ##################################################
4007 #         Munge variable auxiliary data          #
4008 ##################################################
4009
4010 # Some of the auxiliary data files have to refer to the current testing
4011 # directory and other parameter data. The generic versions of these files are
4012 # stored in the aux-var-src directory. At this point, we copy each of them
4013 # to the aux-var directory, making appropriate substitutions. There aren't very
4014 # many of them, so it's easiest just to do this every time. Ensure the mode
4015 # is standardized, as this path is used as a test for the ${stat: expansion.
4016
4017 # A similar job has to be done for the files in the dnszones-src directory, to
4018 # make the fake DNS zones for testing. Most of the zone files are copied to
4019 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
4020 # networks that are defined by parameter.
4021
4022 foreach $basedir ("aux-var", "dnszones")
4023   {
4024   system("sudo rm -rf $parm_cwd/$basedir");
4025   mkdir("$parm_cwd/$basedir", 0777);
4026   chmod(0755, "$parm_cwd/$basedir");
4027
4028   opendir(AUX, "$parm_cwd/$basedir-src") ||
4029     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
4030   my(@filelist) = readdir(AUX);
4031   close(AUX);
4032
4033   foreach $file (@filelist)
4034     {
4035     my($outfile) = $file;
4036     next if $file =~ /^\./;
4037
4038     if ($file eq "db.ip4.V4NET")
4039       {
4040       $outfile = "db.ip4.$parm_ipv4_test_net";
4041       }
4042     elsif ($file eq "db.ip6.V6NET")
4043       {
4044       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
4045       $" = '.';
4046       $outfile = "db.ip6.@nibbles";
4047       $" = ' ';
4048       }
4049
4050     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
4051     open(IN, "$parm_cwd/$basedir-src/$file") ||
4052       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
4053     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
4054       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
4055     while (<IN>)
4056       {
4057       do_substitute(0);
4058       print OUT;
4059       }
4060     close(IN);
4061     close(OUT);
4062     }
4063   }
4064
4065 # Set a user's shell, distinguishable from /bin/sh
4066
4067 symlink('/bin/sh' => 'aux-var/sh');
4068 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
4069
4070 ##################################################
4071 #     Create fake DNS zones for this host        #
4072 ##################################################
4073
4074 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
4075 # sure that there are forward and reverse registrations for this host, using
4076 # its real IP addresses. Dynamically created zone files achieve this.
4077
4078 if ($have_ipv4 || $have_ipv6)
4079   {
4080   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
4081   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
4082     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
4083   print OUT "; This is a dynamically constructed fake zone file.\n" .
4084     "; The following line causes fakens to return PASS_ON\n" .
4085     "; for queries that it cannot answer\n\n" .
4086     "PASS ON NOT FOUND\n\n";
4087   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
4088   print OUT "$shortname  AAAA  $parm_ipv6_stripped\n" if $have_ipv6;
4089   print OUT "\n; End\n";
4090   close(OUT);
4091   }
4092
4093 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
4094   {
4095   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
4096
4097   if ($components[0]=='10')
4098     {
4099     open(OUT, ">>$parm_cwd/dnszones/db.ip4.$components[0]") ||
4100       tests_exit(-1, "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4101     print OUT "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n";
4102     close(OUT);
4103     }
4104   else
4105     {
4106     open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
4107       tests_exit(-1,
4108         "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4109     print OUT "; This is a dynamically constructed fake zone file.\n" .
4110       "; The zone is $components[0].in-addr.arpa.\n\n" .
4111       "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
4112       "; End\n";
4113     close(OUT);
4114     }
4115   }
4116
4117 if ($have_ipv6 && $parm_ipv6_stripped ne "::1")
4118   {
4119   my($exp_v6) = $parm_ipv6_stripped;
4120   $exp_v6 =~ s/[^:]//g;
4121   if ( $parm_ipv6_stripped =~ /^([^:].+)::$/ ) {
4122     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
4123   } elsif ( $parm_ipv6_stripped =~ /^(.+)::(.+)$/ ) {
4124     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
4125   } elsif ( $parm_ipv6_stripped =~ /^::(.+[^:])$/ ) {
4126     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
4127   } else {
4128     $exp_v6 = $parm_ipv6_stripped;
4129   }
4130   my(@components) = split /:/, $exp_v6;
4131   my(@nibbles) = reverse (split /\s*/, shift @components);
4132   my($sep) =  '';
4133
4134   $" = ".";
4135   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
4136     tests_exit(-1,
4137       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
4138   print OUT "; This is a dynamically constructed fake zone file.\n" .
4139     "; The zone is @nibbles.ip6.arpa.\n\n";
4140
4141   @components = reverse @components;
4142   foreach $c (@components)
4143     {
4144     $c = "0$c" until $c =~ /^..../;
4145     @nibbles = reverse(split /\s*/, $c);
4146     print OUT "$sep@nibbles";
4147     $sep = ".";
4148     }
4149
4150   print OUT "  PTR  $parm_hostname.\n\n; End\n";
4151   close(OUT);
4152   $" = " ";
4153   }
4154
4155
4156
4157 ##################################################
4158 #    Create lists of mailboxes and message logs  #
4159 ##################################################
4160
4161 # We use these lists to check that a test has created the expected files. It
4162 # should be faster than looking for the file each time. For mailboxes, we have
4163 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
4164 # is just a flat list of files.
4165
4166 @oldmails = list_files_below("mail");
4167 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
4168 @oldmsglogs = readdir(DIR);
4169 closedir(DIR);
4170
4171
4172
4173 ##################################################
4174 #         Run the required tests                 #
4175 ##################################################
4176
4177 # Each test script contains a number of tests, separated by a line that
4178 # contains ****. We open input from the terminal so that we can read responses
4179 # to prompts.
4180
4181 if (not $force_continue) {
4182   # runtest needs to interact if we're not in continue
4183   # mode. It does so by communicate to /dev/tty
4184   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
4185   print "\nPress RETURN to run the tests: ";
4186   <T>;
4187 }
4188
4189
4190 my $failures = 0;
4191 foreach $test (@test_list)
4192   {
4193   state $lasttestdir = '';
4194
4195   local $lineno     = 0;
4196   local $commandno  = 0;
4197   local $subtestno  = 0;
4198   local $sortlog    = 0;
4199
4200   (local $testno = $test) =~ s|.*/||;
4201
4202   # Leaving traces in the process table and in the environment
4203   # gives us a chance to identify hanging processes (exim daemons)
4204   local $0 = "[runtest $testno]";
4205   local $ENV{EXIM_TEST_NUMBER} = $testno;
4206
4207   my $gnutls   = 0;
4208   my $docheck  = 1;
4209   my $thistestdir  = substr($test, 0, -5);
4210
4211   $dynamic_socket->close() if $dynamic_socket;
4212
4213   if ($lasttestdir ne $thistestdir)
4214     {
4215     $gnutls = 0;
4216     if (-s "scripts/$thistestdir/REQUIRES")
4217       {
4218       my $indent = '';
4219       print "\n>>> The following tests require: ";
4220       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
4221         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
4222       while (<$requires>)
4223         {
4224         $gnutls = 1 if /^support GnuTLS/;
4225         print $indent, $_;
4226         $indent = ">>>                              ";
4227         }
4228       }
4229       $lasttestdir = $thistestdir;
4230     }
4231
4232   # Remove any debris in the spool directory and the test-mail directory
4233   # and also the files for collecting stdout and stderr. Then put back
4234   # the test-mail directory for appendfile deliveries.
4235
4236   system "sudo /bin/rm -rf spool test-*";
4237   mkdir "test-mail";
4238
4239   # A privileged Exim will normally make its own spool directory, but some of
4240   # the tests run in unprivileged modes that don't always work if the spool
4241   # directory isn't already there. What is more, we want anybody to be able
4242   # to read it in order to find the daemon's pid.
4243
4244   mkdir "spool";
4245   system "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
4246          "sudo chmod 0755 spool";
4247
4248   # Empty the cache that keeps track of things like message id mappings, and
4249   # set up the initial sequence strings.
4250
4251   undef %cache;
4252   $next_msgid = "aX";
4253   $next_pid = 1234;
4254   $next_port = 1111;
4255   $message_skip = 0;
4256   $msglog_skip = 0;
4257   $stderr_skip = 0;
4258   $stdout_skip = 0;
4259   $rmfiltertest = 0;
4260   $is_ipv6test = 0;
4261   $TEST_STATE->{munge} = '';
4262
4263   # Remove the associative arrays used to hold checked mail files and msglogs
4264
4265   undef %expected_mails;
4266   undef %expected_msglogs;
4267
4268   # Open the test's script
4269   open(SCRIPT, "scripts/$test") ||
4270     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
4271   # Run through the script once to set variables which should be global
4272   while (<SCRIPT>)
4273     {
4274     if (/^no_message_check/) { $message_skip = 1; next; }
4275     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4276     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4277     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4278     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4279     if (/^sortlog/)          { $sortlog = 1; next; }
4280     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
4281     }
4282   # Reset to beginning of file for per test interpreting/processing
4283   seek(SCRIPT, 0, 0);
4284
4285   # The first line in the script must be a comment that is used to identify
4286   # the set of tests as a whole.
4287
4288   $_ = <SCRIPT>;
4289   $lineno++;
4290   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
4291   printf("%s %s", (substr $test, 5), (substr $_, 2));
4292
4293   # Loop for each of the subtests within the script. The variable $server_pid
4294   # is used to remember the pid of a "server" process, for which we do not
4295   # wait until we have waited for a subsequent command.
4296
4297   local($server_pid) = 0;
4298   for ($commandno = 1; !eof SCRIPT; $commandno++)
4299     {
4300     # Skip further leading comments and blank lines, handle the flag setting
4301     # commands, and deal with tests for IP support.
4302
4303     while (<SCRIPT>)
4304       {
4305       $lineno++;
4306       # Could remove these variable settings because they are already
4307       # set above, but doesn't hurt to leave them here.
4308       if (/^no_message_check/) { $message_skip = 1; next; }
4309       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4310       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4311       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4312       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4313       if (/^sortlog/)          { $sortlog = 1; next; }
4314
4315       if (/^need_largefiles/)
4316         {
4317         next if $have_largefiles;
4318         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4319         $docheck = 0;      # don't check output
4320         undef $_;          # pretend EOF
4321         last;
4322         }
4323
4324       if (/^need_ipv4/)
4325         {
4326         next if $have_ipv4;
4327         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4328         $docheck = 0;      # don't check output
4329         undef $_;          # pretend EOF
4330         last;
4331         }
4332
4333       if (/^need_ipv6/)
4334         {
4335         if ($have_ipv6)
4336           {
4337           $is_ipv6test = 1;
4338           next;
4339           }
4340         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4341         $docheck = 0;      # don't check output
4342         undef $_;          # pretend EOF
4343         last;
4344         }
4345
4346       if (/^need_move_frozen_messages/)
4347         {
4348         next if defined $parm_support{move_frozen_messages};
4349         print ">>> move frozen message support is needed for test $testno, " .
4350           "but is not\n>>> available: skipping\n";
4351         $docheck = 0;      # don't check output
4352         undef $_;          # pretend EOF
4353         last;
4354         }
4355
4356       last unless /^(?:#(?!##\s)|\s*$)/;
4357       }
4358     last if !defined $_;  # Hit EOF
4359
4360     my($subtest_startline) = $lineno;
4361
4362     # Now run the command. The function returns 0 for an inline command,
4363     # 1 if a non-exim command was run and waited for, 2 if an exim
4364     # command was run and waited for, and 3 if a command
4365     # was run and not waited for (usually a daemon or server startup).
4366
4367     my($commandname) = '';
4368     my($expectrc) = 0;
4369     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4370     my($cmdrc) = $?;
4371
4372     if ($debug) {
4373       print ">> rc=$rc cmdrc=$cmdrc\n";
4374       if (defined $run_extra) {
4375         foreach my $k (keys %$run_extra) {
4376           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4377           print ">>   $k -> $v\n";
4378         }
4379       }
4380     }
4381     $run_extra = {} unless defined $run_extra;
4382     foreach my $k (keys %$run_extra) {
4383       if (exists $TEST_STATE->{$k}) {
4384         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4385         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4386       }
4387       if (defined $run_extra->{$k}) {
4388         $TEST_STATE->{$k} = $run_extra->{$k};
4389       } elsif (exists $TEST_STATE->{$k}) {
4390         delete $TEST_STATE->{$k};
4391       }
4392     }
4393
4394     # Hit EOF after an initial return code number
4395
4396     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4397
4398     # Carry on with the next command if we did not wait for this one. $rc == 0
4399     # if no subprocess was run; $rc == 3 if we started a process but did not
4400     # wait for it.
4401
4402     next if ($rc == 0 || $rc == 3);
4403
4404     # We ran and waited for a command. Check for the expected result unless
4405     # it died.
4406
4407     if ($cmdrc != $expectrc && !$sigpipehappened)
4408       {
4409       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4410       if (($cmdrc & 0xff) == 0)
4411         {
4412         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4413         }
4414       elsif (($cmdrc & 0xff00) == 0)
4415         { printf("** Killed by signal %d", $cmdrc & 255); }
4416       else
4417         { printf("** Status %x", $cmdrc); }
4418
4419       for (;;)
4420         {
4421         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4422         $_ = $force_continue ? "c" : <T>;
4423         tests_exit(1) if /^q?$/i;
4424         if (/^c$/ && $force_continue)
4425           {
4426           log_failure($log_failed_filename, $testno, "exit code unexpected");
4427           log_test($log_summary_filename, $testno, 'F');
4428           $failures++;
4429           }
4430         if ($force_continue)
4431           {
4432           print "\nstdout tail:\n";
4433           print "==================>\n";
4434           system("tail -20 test-stdout");
4435           print "===================\n";
4436
4437           print "stderr tail:\n";
4438           print "==================>\n";
4439           system("tail -30 test-stderr");
4440           print "===================\n";
4441
4442           print "stdout-server tail:\n";
4443           print "==================>\n";
4444           system("tail -20 test-stdout-server");
4445           print "===================\n";
4446
4447           print "stderr-server tail:\n";
4448           print "==================>\n";
4449           system("tail -30 test-stderr-server");
4450           print "===================\n";
4451
4452           print "... continue forced\n";
4453           }
4454
4455         last if /^[rc]$/i;
4456         if (/^e$/i)
4457           {
4458           system @more => 'test-stderr';
4459           }
4460         elsif (/^o$/i)
4461           {
4462           system @more => 'test-stdout';
4463           }
4464         }
4465
4466       $retry = 1 if /^r$/i;
4467       $docheck = 0;
4468       }
4469
4470     # If the command was exim, and a listening server is running, we can now
4471     # close its input, which causes us to wait for it to finish, which is why
4472     # we didn't close it earlier.
4473
4474     if ($rc == 2 && $server_pid != 0)
4475       {
4476       close SERVERCMD;
4477       $server_pid = 0;
4478       if ($? != 0)
4479         {
4480         if (($? & 0xff) == 0)
4481           { printf("Server return code %d for test %d starting line %d", $?/256,
4482                 $testno, $subtest_startline); }
4483         elsif (($? & 0xff00) == 0)
4484           { printf("Server killed by signal %d", $? & 255); }
4485         else
4486           { printf("Server status %x", $?); }
4487
4488         for (;;)
4489           {
4490           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4491           $_ = $force_continue ? "c" : <T>;
4492           tests_exit(1) if /^q?$/i;
4493           if (/^c$/ && $force_continue)
4494             {
4495             log_failure($log_failed_filename, $testno, "exit code unexpected");
4496             log_test($log_summary_filename, $testno, 'F');
4497             $failures++;
4498             }
4499           print "... continue forced\n" if $force_continue;
4500           last if /^[rc]$/i;
4501
4502           if (/^s$/i)
4503             {
4504             open(S, "test-stdout-server") ||
4505               tests_exit(-1, "Failed to open test-stdout-server: $!");
4506             print while <S>;
4507             close(S);
4508             }
4509           }
4510         $retry = 1 if /^r$/i;
4511         }
4512       }
4513     }
4514
4515   close SCRIPT;
4516
4517   # The script has finished. Check the all the output that was generated. The
4518   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4519   # rerun the test (the files # have been updated).
4520   # It does not return if the user responds Q to a prompt.
4521
4522   if ($retry)
4523     {
4524     $retry = '0';
4525     print (("#" x 79) . "\n");
4526     redo;
4527     }
4528
4529   if ($docheck)
4530     {
4531     sleep 1 if $slow;
4532     my $rc = check_output($TEST_STATE->{munge});
4533     if ($rc == 0)
4534       {
4535       log_test($log_summary_filename, $testno, 'P');
4536       }
4537     else
4538       {
4539       $failures++;
4540       }
4541     if ($rc < 2)
4542       {
4543       print ("  Script completed\n");
4544       }
4545     else
4546       {
4547       print (("#" x 79) . "\n");
4548       redo;
4549       }
4550     }
4551   }
4552
4553
4554 ##################################################
4555 #         Exit from the test script              #
4556 ##################################################
4557
4558 tests_exit(-1, "No runnable tests selected") if not @test_list;
4559 tests_exit($fail_any ? $failures : 0);
4560
4561 __END__
4562
4563 =head1 NAME
4564
4565  runtest - run the exim testsuite
4566
4567 =head1 SYNOPSIS
4568
4569  runtest [exim-path] [options] [test0 [test1]]
4570
4571 =head1 DESCRIPTION
4572
4573 B<runtest> runs the Exim testsuite.
4574
4575 =head1 OPTIONS
4576
4577 For legacy reasons the options are not case sensitive.
4578
4579 =over
4580
4581 =item B<--continue>
4582
4583 Do not stop for user interaction or on errors. (default: off)
4584
4585 =item B<--debug>
4586
4587 This option enables the output of debug information when running the
4588 various test commands. (default: off)
4589
4590 =item B<--diff>
4591
4592 Use C<diff -u> for comparing the expected output with the produced
4593 output. (default: use a built-in routine)
4594
4595 =item B<--flavor>|B<--flavour> I<flavour>
4596
4597 Override the expected results for results for a specific (OS) flavour.
4598 (default: unused)
4599
4600 =item B<--[no]ipv4>
4601
4602 Skip IPv4 related setup and tests (default: use ipv4)
4603
4604 =item B<--[no]ipv6>
4605
4606 Skip IPv6 related setup and tests (default: use ipv6)
4607
4608 =item B<--keep>
4609
4610 Keep the various output files produced during a test run. (default: don't keep)
4611
4612 =item B<--range> I<n0> I<n1>
4613
4614 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4615 test available".
4616
4617 =item B<--slow>
4618
4619 Insert some delays to compensate for a slow host system. (default: off)
4620
4621 =item B<--test> I<n>
4622
4623 Run the specified test. This option may used multiple times.
4624
4625 =item B<--update>
4626
4627 Automatically update the recorded (expected) data on mismatch. (default: off)
4628
4629 =item B<--valgrind>
4630
4631 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4632
4633 =back
4634
4635 =cut
4636
4637
4638 # End of runtest script