templates/wrapper.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4
   5    <!-- Define display/content information -->
   6       <xsl:output indent="yes"/>
   7       <xsl:output encoding="UTF-8"/>
   8       <xsl:output media-type="text/html"/>
   9       <xsl:output omit-xml-declaration="yes"/>
  10       <xsl:output doctype-public="XSLT-compat"/>
  11
  12    <!-- Define some variables -->
  13       <xsl:variable name="docroot"/>
  14       <xsl:variable name="html.head.title"/>
  15       <xsl:variable name="html.head.description" select="'Exim is a message transfer agent (MTA) developed at the University of Cambridge for use on Unix systems connected to the Internet.'"/>
  16       <xsl:variable name="html.head.keywords" select="'exim,smtp,mta,email'"/>
  17       <xsl:variable name="html.head.robots" select="'noodp,noydir,index,follow'"/>
  18       <xsl:variable name="html.head.append"/>
  19       <xsl:variable name="html.body.append"/>
  20       <xsl:variable name="html.body.outer.append"/>
  21
  22    <!-- The main template code -->
  23       <xsl:template match="/">
  24          <html lang="en-GB">
  25             <head>
  26                <link rel="stylesheet" type="text/css" href="{$staticroot}/css/common.css"/>
  27
  28                <meta name="author"      content="The Exim Project. &lt;https://www.exim.org/&gt;"/>
  29                <meta name="copyright"   content="Copyright ©1995-2012 The Exim Project. All rights reserved"/>
  30                <meta name="description" content="{$html.head.description}"/>
  31                <meta name="keywords"    content="{$html.head.keywords}"/>
  32                <meta name="robots"      content="{$html.head.robots}"/>
  33
  34                <!-- Mobile Safari (iPhone) - Reduce viewport to physical size of device -->
  35                   <meta name="viewport" content="width=device-width"/>
  36
  37                <title>
  38                   <xsl:value-of select="$html.head.title"/>
  39                </title>
  40
  41                <xsl:copy-of select="$html.head.append"/>
  42             </head>
  43             <body class="no-js">
  44                 <!-- Changed body classname from "no-js" to "with-js" for styling purposes -->
  45
  46                    <script type="text/javascript"><![CDATA[document.body.className=(' '+document.body.className+' ').replace('no-js','with-js');]]></script>
  47
  48                 <!-- Header -->
  49
  50                    <h1 id="header">
  51                       <a href="{$docroot}">Exim Internet Mailer</a>
  52                    </h1>
  53
  54                 <!-- Outer Container -->
  55
  56                    <div id="outer">
  57
  58                       <!-- Navigation -->
  59
  60                          <ul id="nav_flow" class="nav">
  61                             <li> <a href="{$docroot}/index.html">Home</a> </li>
  62                             <li> <a href="{$docroot}/mirrors.html">Download</a> </li>
  63                             <li> <a href="{$docroot}/docs.html">Documentation</a> </li>
  64                             <li> <a href="{$docroot}/maillist.html">Mailing Lists</a> </li>
  65                             <li> <a href="http://wiki.exim.org/">Wiki</a> </li>
  66                             <li> <a href="https://bugs.exim.org/">Bugs</a> </li>
  67                             <li> <a href="{$docroot}/static/doc/security">Security</a> </li>
  68                             <li> <a href="{$docroot}/credits.html">Credits</a> </li>
  69
  70                             <!-- Search Field -->
  71
  72                                <li class="search">
  73                                   <form action="https://encrypted.google.com/search" method="get">
  74                                      <span class="search_field_container">
  75                                         <input type="search" name="q" placeholder="Search Docs" class="search_field"/>
  76                                      </span>
  77                                      <input type="hidden" name="hl" value="en"/>
  78                                      <input type="hidden" name="ie" value="UTF-8"/>
  79                                      <input type="hidden" name="as_qdr" value="all"/>
  80                                      <input type="hidden" name="q" value="site:www.exim.org"/>
  81                                      <input type="hidden" name="q" value="inurl:exim-html-current"/>
  82                                   </form>
  83                                </li>
  84                          </ul>
  85
  86                       <!-- MAIN CONTENT. This is the div that wraps around the other stylesheets -->
  87                          <div id="inner">
  88                             <div id="content">
  89                               <xsl:call-template name="content"/>
  90                            </div>
  91                          </div>
  92
  93                       <!-- Branding -->
  94                          <iframe id="branding" name="branding" src="{$docroot}/branding/branding.html" height="0" frameborder="no" scrolling="no"/>
  95
  96                       <!-- Footer -->
  97
  98                          <div id="footer">
  99                             <xsl:text>Website design by </xsl:text>
 100                             <a href="https://www.grepular.com/">Mike Cardwell</a>
 101                             <xsl:text>.</xsl:text>
 102                          </div>
 103
 104                       <!-- Side Bars -->
 105                          <div class="left_bar"/>
 106                          <div class="right_bar"/>
 107
 108                       <!-- Append anything to the outer container? -->
 109                          <xsl:copy-of select="$html.body.outer.append"/>
 110                    </div>
 111
 112                 <!-- Load latest version of jQuery 1.6 from the Google CDN -->
 113                    <script type="text/javascript" src="//ajax.googleapis.com/ajax/libs/jquery/1.6/jquery.min.js"></script>
 114
 115                 <!-- Local JavaScript -->
 116                    <script type="text/javascript" src="{$staticroot}/js/common.js"></script>
 117
 118                    <xsl:copy-of select="$html.body.append"/>
 119
 120              </body>
 121
 122          </html>
 123       </xsl:template>
 124
 125    <!-- Quote Element -->
 126       <xsl:template match="quote">
 127          <xsl:text>&#8220;</xsl:text><xsl:apply-templates match="*"/><xsl:text>&#8221;</xsl:text>
 128       </xsl:template>
 129
 130    <!-- Random Docbook Elements -->
 131       <xsl:template match="filename | emphasis | option | command | function">
 132          <span class="docbook_{name()}"> <xsl:apply-templates/> </span>
 133       </xsl:template>
 134
 135    <!-- Literal Element -->
 136       <xsl:template match="literal">
 137          <code class="docbook_literal"> <xsl:apply-templates/> </code>
 138       </xsl:template>
 139       <xsl:template match="literallayout">
 140          <div class="docbook_literallayout"> <pre> <xsl:apply-templates/> </pre> </div>
 141       </xsl:template>
 142
 143    <!-- ULink Element -->
 144       <xsl:template match="ulink">
 145          <a href="{text()}"> <xsl:value-of select="text()"/> </a>
 146       </xsl:template>
 147
 148    <!-- XREF (Fixed up in the Perl) -->
 149       <xsl:template match="xref">
 150          <a href="{@url}" title="{@chapter_id}. {@chapter_title}">
 151             <xsl:choose>
 152                <xsl:when test="@section_id">
 153                   <xsl:choose>
 154                      <xsl:when test="@longref">
 155                         <xsl:value-of select="@chapter_title"/>
 156                         <small>
 157                            <xsl:value-of select="concat(' [',@section_title,']')"/>
 158                         </small>
 159                      </xsl:when>
 160                      <xsl:otherwise>
 161                         <xsl:value-of select="concat(@chapter_id,'.',@section_id)"/>
 162                      </xsl:otherwise>
 163                   </xsl:choose>
 164                </xsl:when>
 165                <xsl:otherwise>
 166                   <xsl:choose>
 167                      <xsl:when test="@longref">
 168                         <xsl:value-of select="@chapter_title"/>
 169                      </xsl:when>
 170                      <xsl:otherwise>
 171                         <xsl:value-of select="@chapter_id"/>
 172                      </xsl:otherwise>
 173                   </xsl:choose>
 174                </xsl:otherwise>
 175             </xsl:choose>
 176          </a>
 177       </xsl:template>
 178
 179    <!-- Para -->
 180       <xsl:template match="para">
 181          <p>
 182             <xsl:if test="@revisionflag!=''"><xsl:attribute name="class">changed</xsl:attribute></xsl:if>
 183             <xsl:apply-templates/>
 184          </p>
 185       </xsl:template>
 186
 187    <!-- Lists -->
 188       <xsl:template match="itemizedlist">                        <ul> <xsl:apply-templates/> </ul> </xsl:template>
 189       <xsl:template match="itemizedlist/listitem">               <li> <xsl:apply-templates/> </li> </xsl:template>
 190       <xsl:template match="orderedlist">                         <ol> <xsl:apply-templates/> </ol> </xsl:template>
 191       <xsl:template match="orderedlist/listitem">                <li> <xsl:apply-templates/> </li> </xsl:template>
 192       <xsl:template match="variablelist">                        <dl> <xsl:apply-templates/> </dl> </xsl:template>
 193       <xsl:template match="variablelist/varlistentry/term">      <dt> <xsl:apply-templates/> </dt> </xsl:template>
 194       <xsl:template match="variablelist/varlistentry/listitem">  <dd> <xsl:apply-templates/> </dd> </xsl:template>
 195
 196    <!-- Table -->
 197       <xsl:template match="informaltable"> <table> <xsl:apply-templates/> </table> </xsl:template>
 198       <xsl:template match="tbody/row">     <tr>    <xsl:apply-templates/> </tr>    </xsl:template>
 199       <xsl:template match="row/entry">     <td>    <xsl:apply-templates/> </td>    </xsl:template>
 200       <xsl:template match="tgroup|tbody"> <xsl:apply-templates/> </xsl:template>
 201
 202    <!-- Ignore -->
 203       <xsl:template match="indexterm|title|titleabbrev|current_version"/>
 204
 205 </xsl:stylesheet>