script/gen.pl

   1 #!/usr/bin/env perl
   2 #
   3 use strict;
   4 use warnings;
   5
   6 use CSS::Minifier::XS 0.07;
   7 use File::Copy;
   8 use File::Find;
   9 use File::Path qw(make_path);
  10 use File::Slurp;
  11 use File::Spec;
  12 use Getopt::Long;
  13 use JavaScript::Minifier::XS;
  14 use Pod::Usage;
  15 use XML::LibXML;
  16 use XML::LibXSLT;
  17
  18 my $canonical_url = 'http://www.exim.org/';
  19
  20 ## Parse arguments
  21 my %opt = parse_arguments();
  22
  23 ## Generate the pages
  24 my %cache; # General cache object
  25 do_doc( 'spec',   $_ ) foreach @{ $opt{spec}   || [] };
  26 do_doc( 'filter', $_ ) foreach @{ $opt{filter} || [] };
  27 do_web() if exists $opt{web};
  28
  29 ## Add the exim-html-current symlink
  30 print "Symlinking exim-html-current to exim-html-$opt{latest}\n";
  31 unlink("$opt{docroot}/exim-html-current") if ( -l "$opt{docroot}/exim-html-current" );
  32 symlink( "exim-html-$opt{latest}", "$opt{docroot}/exim-html-current" )
  33     || die "symlink to $opt{docroot}/exim-html-current failed";
  34
  35 ## Generate the website files
  36 sub do_web {
  37
  38     ## Make sure the template web directory exists
  39     die "No such directory: $opt{tmpl}/web\n" unless -d "$opt{tmpl}/web";
  40
  41     ## Scan the web templates
  42     find(
  43         sub {
  44             my ($path) =
  45                 substr( $File::Find::name, length("$opt{tmpl}/web"), length($File::Find::name) ) =~ m#^/*(.*)$#;
  46
  47             if ( -d "$opt{tmpl}/web/$path" ) {
  48
  49                 ## Create the directory in the doc root if it doesn't exist
  50                 if ( !-d "$opt{docroot}/$path" ) {
  51                     mkdir("$opt{docroot}/$path") or die "Unable to make $opt{docroot}/$path: $!\n";
  52                 }
  53
  54             }
  55             else {
  56
  57                 ## Build HTML from XSL files and simply copy static files which have changed
  58                 if ( $path =~ /(.+)\.xsl$/ ) {
  59                     print "Generating  : docroot:/$1.html\n" if ( $opt{verbose} );
  60                     transform( undef, "$opt{tmpl}/web/$path", "$opt{docroot}/$1.html" );
  61                 }
  62                 elsif ( -f "$opt{tmpl}/web/$path" ) {
  63
  64                     ## Skip if the file hasn't changed (mtime based)
  65                     return
  66                         if -f "$opt{docroot}/$path"
  67                             && ( stat("$opt{tmpl}/web/$path") )[9] == ( stat("$opt{docroot}/$path") )[9];
  68
  69                     if ( $path =~ /(.+)\.css$/ ) {
  70                         print "CSS to  : docroot:/$path\n" if ( $opt{verbose} );
  71                         my $content = read_file("$opt{tmpl}/web/$path");
  72                         write_file( "$opt{docroot}/$path",
  73                             $opt{minify} ? CSS::Minifier::XS::minify($content) : $content );
  74                     }
  75                     elsif ( $path =~ /(.+)\.js$/ ) {
  76                         print "JS to  : docroot:/$path\n" if ( $opt{verbose} );
  77                         my $content = read_file("$opt{tmpl}/web/$path");
  78                         write_file( "$opt{docroot}/$path",
  79                             $opt{minify} ? JavaScript::Minifier::XS::minify($content) : $content );
  80                     }
  81                     else {
  82                         ## Copy
  83                         print "Copying to  : docroot:/$path\n" if ( $opt{verbose} );
  84                         copy( "$opt{tmpl}/web/$path", "$opt{docroot}/$path" ) or die "$path: $!";
  85                     }
  86                     ## Set mtime
  87                     utime( time, ( stat("$opt{tmpl}/web/$path") )[9], "$opt{docroot}/$path" );
  88                 }
  89             }
  90
  91         },
  92         "$opt{tmpl}/web"
  93     );
  94 }
  95
  96 ## Generate index/chapter files for a doc
  97 sub do_doc {
  98     my ( $type, $xml_path ) = @_;
  99
 100     ## Read and validate the XML file
 101     my $xml = XML::LibXML->new()->parse_file($xml_path) or die $!;
 102
 103     ## Get the version number
 104     my $version = $xml->findvalue('/book/bookinfo/revhistory/revision/revnumber');
 105     die "Unable to get version number\n" unless defined $version && $version =~ /^\d+(\.\d+)*$/;
 106
 107     ## Prepend chapter filenames?
 108     my $prepend_chapter = $type eq 'filter' ? 'filter_' : '';
 109
 110     ## Add the canonical url for this document
 111     $xml->documentElement()
 112         ->appendTextChild( 'canonical_url',
 113         "${canonical_url}exim-html-current/doc/html/spec_html/" . ( $type eq 'spec' ? 'index' : 'filter' ) . ".html" );
 114
 115     ## Add a url for the latest version of this document
 116     if( $version ne $opt{latest} ){
 117        $xml->documentElement()
 118            ->appendTextChild( 'current_url',
 119            "../../../../exim-html-current/doc/html/spec_html/" . ( $type eq 'spec' ? 'index' : 'filter' ) . ".html" );
 120     }
 121
 122     ## Fixup the XML
 123     xref_fixup( $xml, $prepend_chapter );
 124
 125     ## Generate the front page
 126     {
 127         my $path = "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? $type : 'index' ) . ".html";
 128         print "Generating  : docroot:/$path\n";
 129         transform( $xml, "$opt{tmpl}/doc/index.xsl", "$opt{docroot}/$path", );
 130     }
 131
 132     ## Generate a Table of Contents XML file
 133     {
 134         my $path =
 135             "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? 'filter_toc' : 'index_toc' ) . ".xml";
 136         print "Generating  : docroot:/$path\n" if ( $opt{verbose} );
 137         transform( $xml, "$opt{tmpl}/doc/toc.xsl", "$opt{docroot}/$path", );
 138     }
 139
 140     ## Generate the chapters
 141     my $counter = 0;
 142     my @chapters = map { $_->cloneNode(1) } $xml->findnodes('/book/chapter');
 143     foreach my $chapter ( @chapters ) {
 144
 145         ## Add a <chapter_id>N</chapter_id> node for the stylesheet to use
 146         $chapter->appendTextChild( 'chapter_id', ++$counter );
 147
 148         ## Add previous/next/canonical urls for nav
 149         {
 150             $chapter->appendTextChild( 'prev_url',
 151                   $counter == 1
 152                 ? $type eq 'filter'
 153                         ? 'filter.html'
 154                         : 'index.html'
 155                 : sprintf( '%sch%02d.html', $prepend_chapter, $counter - 1 ) );
 156             $chapter->appendTextChild( 'next_url', sprintf( '%sch%02d.html', $prepend_chapter, $counter + 1 ) ) unless int(@chapters) == $counter;
 157             $chapter->appendTextChild(
 158                 'canonical_url',
 159                 sprintf(
 160                     'http://www.exim.org/exim-html-current/doc/html/spec_html/%sch%02d.html',
 161                     $prepend_chapter, $counter
 162                 )
 163             );
 164             if( $version ne $opt{latest} ){
 165                $chapter->appendTextChild(
 166                   'current_url',
 167                   sprintf(
 168                      '../../../../exim-html-current/doc/html/spec_html/%sch%02d.html',
 169                      $prepend_chapter, $counter
 170                   )
 171                );
 172            }
 173         }
 174
 175         ## Create an XML document from the chapter
 176         my $doc = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );
 177         $doc->setDocumentElement($chapter);
 178
 179         ## Transform the chapter into html
 180         {
 181             my $path = sprintf( 'exim-html-%s/doc/html/spec_html/%sch%02d.html', $version, $prepend_chapter, $counter );
 182             print "Generating  : docroot:/$path\n" if ( $opt{verbose} );
 183             transform( $doc, "$opt{tmpl}/doc/chapter.xsl", "$opt{docroot}/$path", );
 184         }
 185     }
 186 }
 187
 188 ## Fixup xref tags
 189 sub xref_fixup {
 190     my ( $xml, $prepend_chapter ) = @_;
 191
 192     my %index = ();
 193
 194     ## Add the "prepend_chapter" info
 195     ( $xml->findnodes('/book') )[0]->appendTextChild( 'prepend_chapter', $prepend_chapter );
 196
 197     ## Iterate over each chapter
 198     my $chapter_counter = 0;
 199     foreach my $chapter ( $xml->findnodes('/book/chapter') ) {
 200         ++$chapter_counter;
 201
 202         my $chapter_id = $chapter->getAttribute('id');
 203         unless ($chapter_id) {    # synthesise missing id
 204             $chapter_id = sprintf( 'chapter_noid_%04d', $chapter_counter );
 205             $chapter->setAttribute( 'id', $chapter_id );
 206         }
 207         my $chapter_title = $chapter->findvalue('title');
 208
 209         $index{$chapter_id} = { chapter_id => $chapter_counter, chapter_title => $chapter_title };
 210
 211         ## Iterate over each section
 212         my $section_counter = 0;
 213         foreach my $section ( $chapter->findnodes('section') ) {
 214             ++$section_counter;
 215
 216             my $section_id = $section->getAttribute('id');
 217             unless ($section_id) {    # synthesise missing id
 218                 $section_id = sprintf( 'section_noid_%04d_%04d', $chapter_counter, $section_counter );
 219                 $section->setAttribute( 'id', $section_id );
 220             }
 221             my $section_title = $section->findvalue('title');
 222
 223             $index{$section_id} = {
 224                 chapter_id    => $chapter_counter,
 225                 chapter_title => $chapter_title,
 226                 section_id    => $section_counter,
 227                 section_title => $section_title
 228             };
 229         }
 230     }
 231     ## Build indexes as new chapters
 232     build_indexes( $xml, $prepend_chapter, \%index );
 233
 234     ## Replace all of the xrefs in the XML
 235     foreach my $xref ( $xml->findnodes('//xref') ) {
 236         my $linkend = $xref->getAttribute('linkend');
 237         if ( exists $index{$linkend} ) {
 238             $xref->setAttribute( 'chapter_id',    $index{$linkend}{'chapter_id'} );
 239             $xref->setAttribute( 'chapter_title', $index{$linkend}{'chapter_title'} );
 240             $xref->setAttribute( 'section_id', $index{$linkend}{'section_id'} ) if ( $index{$linkend}{'section_id'} );
 241             $xref->setAttribute( 'section_title', $index{$linkend}{'section_title'} )
 242                 if ( $index{$linkend}{'section_title'} );
 243             $xref->setAttribute( 'url',
 244                 sprintf( '%sch%02d.html', $prepend_chapter, $index{$linkend}{'chapter_id'} )
 245                     . ( $index{$linkend}{'section_id'} ? '#' . $linkend : '' ) );
 246         }
 247     }
 248 }
 249
 250 ## Build indexes
 251 sub build_indexes {
 252     my ( $xml, $prepend_chapter, $xref ) = @_;
 253
 254     my $index_hash = {};
 255     my $current_id;
 256     foreach my $node ( $xml->findnodes('//section | //chapter | //indexterm') ) {
 257         if ( $node->nodeName eq 'indexterm' ) {
 258             my $role      = $node->getAttribute('role') || 'concept';
 259             my $primary   = $node->findvalue('child::primary');
 260             my $first     = ( $primary =~ /^[A-Za-z]/ ) ? uc( substr( $primary, 0, 1 ) ) : '';  # first letter or marker
 261             my $secondary = $node->findvalue('child::secondary') || '';
 262             next unless ( $primary || $secondary );    # skip blank entries for now...
 263             $index_hash->{$role}{$first}{$primary}{$secondary} ||= [];
 264             push @{ $index_hash->{$role}{$first}{$primary}{$secondary} }, $current_id;
 265         }
 266         else {
 267             $current_id = $node->getAttribute('id');
 268         }
 269     }
 270
 271     # now we build a set of new chapters with the index data in
 272     my $book = ( $xml->findnodes('/book') )[0];
 273     foreach my $role ( sort { $a cmp $b } keys %{$index_hash} ) {
 274         my $chapter = XML::LibXML::Element->new('chapter');
 275         $book->appendChild($chapter);
 276         $chapter->setAttribute( 'id', join( '_', 'index', $role ) );
 277         $chapter->setAttribute( 'class', 'index' );
 278         $chapter->appendTextChild( 'title', ( ucfirst($role) . ' Index' ) );
 279         foreach my $first ( sort { $a cmp $b } keys %{ $index_hash->{$role} } ) {
 280             my $section = XML::LibXML::Element->new('section');
 281             my $list    = XML::LibXML::Element->new('variablelist');
 282             $chapter->appendChild($section);
 283             $section->setAttribute( 'id', join( '_', 'index', $role, $first ) );
 284             $section->setAttribute( 'class', 'index' );
 285             $section->appendTextChild( 'title', $first ? $first : 'Symbols' );
 286             $section->appendChild($list);
 287             foreach my $primary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first} } ) {
 288                 my $entry = XML::LibXML::Element->new('varlistentry');
 289                 my $item  = XML::LibXML::Element->new('listitem');
 290                 $list->appendChild($entry)->appendTextChild( 'term', $primary );
 291                 $entry->appendChild($item);
 292                 my $slist;
 293                 foreach my $secondary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first}{$primary} } ) {
 294                     my $para = XML::LibXML::Element->new('para');
 295                     if ( $secondary eq '' ) {
 296                         $item->appendChild($para);    # skip having extra layer of heirarchy
 297                     }
 298                     else {
 299                         unless ($slist) {
 300                             $slist = XML::LibXML::Element->new('variablelist');
 301                             $item->appendChild($slist);
 302                         }
 303                         my $sentry = XML::LibXML::Element->new('varlistentry');
 304                         my $sitem  = XML::LibXML::Element->new('listitem');
 305                         $slist->appendChild($sentry)->appendTextChild( 'term', $secondary );
 306                         $sentry->appendChild($sitem)->appendChild($para);
 307                     }
 308                     my $count = 0;
 309                     foreach my $ref ( @{ $index_hash->{$role}{$first}{$primary}{$secondary} } ) {
 310                         $para->appendText(', ')
 311                             if ( $count++ );
 312                         my $xrefel = XML::LibXML::Element->new('xref');
 313                         $xrefel->setAttribute( linkend => $ref );
 314                         $xrefel->setAttribute( longref => 1 );
 315                         $para->appendChild($xrefel);
 316                     }
 317                 }
 318             }
 319         }
 320     }
 321 }
 322
 323 ## Handle the transformation
 324 sub transform {
 325     my ( $xml, $xsl_path, $out_path ) = @_;
 326
 327     ## Build an empty XML structure if an undefined $xml was passed
 328     unless ( defined $xml ) {
 329         $xml = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );
 330         $xml->setDocumentElement( $xml->createElement('content') );
 331     }
 332
 333     ## Add the current version of Exim to the XML
 334     $xml->documentElement()->appendTextChild( 'current_version', $opt{latest} );
 335
 336     ## Add the old versions of Exim to the XML
 337     $xml->documentElement()->appendTextChild( 'old_versions', $_ ) foreach old_docs_versions();
 338
 339     ## Parse the ".xsl" file as XML
 340     my $xsl = XML::LibXML->new()->parse_file($xsl_path) or die $!;
 341
 342     ## Generate a stylesheet from the ".xsl" XML.
 343     my $stylesheet = XML::LibXSLT->new()->parse_stylesheet($xsl);
 344
 345     ## Generate a doc from the XML transformed with the XSL
 346     my $doc = $stylesheet->transform($xml);
 347
 348     ## Make the containing directory if it doesn't exist
 349     make_path( ( $out_path =~ /^(.+)\/.+$/ )[0], { verbose => 1 } );
 350
 351     ## Write out the document
 352     open my $out, '>', $out_path or die "Unable to write $out_path - $!";
 353     print $out $stylesheet->output_as_bytes($doc);
 354     close $out;
 355 }
 356
 357 ## Look in the docroot for old versions of the documentation
 358 sub old_docs_versions {
 359    if( !exists $cache{old_docs_versions} ){
 360       my @versions;
 361       foreach( glob("$opt{docroot}/exim-html-*") ){
 362          push @versions, $1 if /-(\d+(?:\.\d+)?)$/ && $1 < $opt{latest} && -d $_;
 363       }
 364       $cache{old_docs_versions} = [reverse sort {$a<=>$b} @versions];
 365    }
 366    return @{$cache{old_docs_versions}};
 367 }
 368
 369 ## error_help
 370 sub error_help {
 371     my $msg = shift;
 372
 373     warn $msg;
 374     pod2usage( -exitval => 1, -verbose => 0 );
 375 }
 376
 377 ## Parse arguments
 378 sub parse_arguments {
 379
 380     my %opt = ( spec => [], filter => [], help => 0, man => 0, web => 0, minify => 1, verbose => 0 );
 381     GetOptions(
 382         \%opt,      'help|h!', 'man!',      'web!',    'spec=s{1,}', 'filter=s{1,}',
 383         'latest=s', 'tmpl=s',  'docroot=s', 'minify!', 'verbose!'
 384     ) || pod2usage( -exitval => 1, -verbose => 0 );
 385
 386     ## --help
 387     pod2usage(0) if ( $opt{help} );
 388     pod2usage( -verbose => 2 ) if ( $opt{man} );
 389
 390     ## --spec and --filter lists
 391     foreach my $set (qw[spec filter]) {
 392         $opt{$set} =
 393             [ map { my $f = File::Spec->rel2abs($_); help( 1, 'No such file: ' . $_ ) unless -f $f; $f }
 394                 @{ $opt{$set} } ];
 395     }
 396     ## --latest
 397     error_help('Missing value for latest') unless ( exists( $opt{latest} ) && defined( $opt{latest} ) );
 398     error_help('Invalid value for latest') unless $opt{latest} =~ /^\d+(?:\.\d+)*$/;
 399
 400     ## --tmpl and --docroot
 401     foreach my $set (qw[tmpl docroot]) {
 402         error_help( 'Missing value for ' . $set ) unless ( exists( $opt{$set} ) && defined( $opt{$set} ) );
 403         my $f = File::Spec->rel2abs( $opt{$set} );
 404         error_help( 'No such directory: ' . $opt{$set} ) unless -d $f;
 405         $opt{$set} = $f;
 406     }
 407     error_help('Excess arguments') if ( scalar(@ARGV) );
 408
 409     error_help('Must include at least one of --web, --spec or --filter')
 410         unless ( $opt{web} || scalar( @{ $opt{spec} || [] } ) || scalar( @{ $opt{filter} || [] } ) );
 411
 412     return %opt;
 413 }
 414
 415 1;
 416
 417 __END__
 418
 419 =head1 NAME
 420
 421 gen.pl - Generate exim html documentation and website
 422
 423 =head1 SYNOPSIS
 424
 425 gen.pl [options]
 426
 427  Options:
 428    --help              display this help and exits
 429    --man               displays man page
 430    --spec file...      spec docbook/XML source files
 431    --filter file...    filter docbook/XML source files
 432    --web               Generate the general website pages
 433    --latest VERSION    Required. Specify the latest stable version of Exim.
 434    --tmpl PATH         Required. Path to the templates directory
 435    --docroot PATH      Required. Path to the website document root
 436    --[no-]minify       [Don't] minify CSS and Javascript
 437
 438 =head1 OPTIONS
 439
 440 =over 4
 441
 442 =item B<--help>
 443
 444 Display help and exits
 445
 446 =item B<--man>
 447
 448 Display man page
 449
 450 =item B<--spec> I<file...>
 451
 452 List of files that make up the specification documentation
 453 docbook/XML source files.
 454
 455 =item B<--filter> I<file...>
 456
 457 List of files that make up the filter documentation docbook/XML
 458 source files.
 459
 460 =item B<--web>
 461
 462 Generate the website from the template files.
 463
 464 =item B<--latest> I<version>
 465
 466 Specify the current exim version. This is used to create links to
 467 the current documentation.
 468
 469 This option is I<required>
 470
 471 =item B<--tmpl> I<directory>
 472
 473 Specify the directory that the templates are kept in.
 474
 475 This option is I<required>
 476
 477 =item B<--docroot> I<directory>
 478
 479 Specify the directory that the output should be generated into.
 480 This is the website C<docroot> directory.
 481
 482 This option is I<required>
 483
 484 =item B<--minify>
 485
 486 If this option is set then both the CSS and Javascript files
 487 processed are minified using L<CSS::Minifier::XS> and
 488 L<JavaScript::Minifier::XS> respectively.
 489
 490 This option is set by default - to disable it specify C<--no-minify>
 491
 492 =back
 493
 494 =head1 DESCRIPTION
 495
 496 Generates the exim website and HTML documentation.
 497
 498 =head1 EXAMPLE
 499
 500     script/gen.pl \
 501       --web \
 502       --spec docbook/*/spec.xml \
 503       --filter  docbook/*/filter.xml \
 504       --latest 4.72 \
 505       --tmpl templates \
 506       --docroot /tmp/website
 507
 508 =head1 AUTHOR
 509
 510 Mike Cardwell
 511
 512 Nigel Metheringham <nigel@exim.org> - mostly broke the framework
 513 Mike produced.
 514
 515 =head1 COPYRIGHT
 516
 517 Copyright 2010-2011 Exim Maintainers. All rights reserved.
 518
 519 =cut