templates/wrapper.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4
   5    <!-- Define display/content information -->
   6       <xsl:output indent="yes"/>
   7       <xsl:output encoding="UTF-8"/>
   8       <xsl:output media-type="text/html"/>
   9       <xsl:output omit-xml-declaration="yes"/>
  10       <xsl:output doctype-public="XSLT-compat"/>
  11
  12    <!-- Define some variables -->
  13       <xsl:variable name="docroot"/>
  14       <xsl:variable name="html.head.title"/>
  15       <xsl:variable name="html.head.description" select="'Exim is a message transfer agent (MTA) developed at the University of Cambridge for use on Unix systems connected to the Internet.'"/>
  16       <xsl:variable name="html.head.keywords" select="'exim,smtp,mta,email'"/>
  17       <xsl:variable name="html.head.robots" select="'noodp,noydir,index,follow'"/>
  18       <xsl:variable name="html.head.append"/>
  19       <xsl:variable name="html.body.append"/>
  20       <xsl:variable name="html.body.outer.append"/>
  21
  22    <!-- The main template code -->
  23       <xsl:template match="/">
  24          <html lang="en-GB">
  25             <head>
  26                <link rel="stylesheet" type="text/css" href="{$staticroot}/css/common.css"/>
  27
  28                <meta name="author"      content="The Exim Project. &lt;https://www.exim.org/&gt;"/>
  29                <meta name="copyright"   content="Copyright ©1995-2012 The Exim Project. All rights reserved"/>
  30                <meta name="description" content="{$html.head.description}"/>
  31                <meta name="keywords"    content="{$html.head.keywords}"/>
  32                <meta name="robots"      content="{$html.head.robots}"/>
  33
  34                <!-- Mobile Safari (iPhone) - Reduce viewport to physical size of device -->
  35                   <meta name="viewport" content="width=device-width"/>
  36
  37                <title>
  38                   <xsl:value-of select="$html.head.title"/>
  39                </title>
  40
  41                <xsl:copy-of select="$html.head.append"/>
  42             </head>
  43             <body class="no-js">
  44                 <!-- Changed body classname from "no-js" to "with-js" for styling purposes -->
  45
  46                    <script type="text/javascript"><![CDATA[document.body.className=(' '+document.body.className+' ').replace('no-js','with-js');]]></script>
  47
  48                 <!-- Header -->
  49
  50                    <h1 id="header">
  51                       <a href="{$docroot}">Exim Internet Mailer</a>
  52                    </h1>
  53
  54                 <!-- Outer Container -->
  55
  56                    <div id="outer">
  57
  58                       <!-- Navigation -->
  59
  60                          <ul id="nav_flow" class="nav">
  61                             <li> <a href="{$docroot}/index.html">Home</a> </li>
  62                             <li> <a href="{$docroot}/mirrors.html">Download</a> </li>
  63                             <li> <a href="{$docroot}/docs.html">Documentation</a> </li>
  64                             <li> <a href="{$docroot}/maillist.html">Mailing Lists</a> </li>
  65                             <li> <a href="http://wiki.exim.org/">Wiki</a> </li>
  66                             <li> <a href="https://bugs.exim.org/">Bugs</a> </li>
  67                             <li> <a href="{$docroot}/static/doc/security">Security</a> </li>
  68                             <li> <a href="{$docroot}/credits.html">Credits</a> </li>
  69                             <li> <a href="{$docroot}/legal.html">Legal</a> </li>
  70
  71                             <!-- Search Field -->
  72
  73                                <li class="search">
  74                                   <form action="https://encrypted.google.com/search" method="get">
  75                                      <span class="search_field_container">
  76                                         <input type="search" name="q" placeholder="Search Docs" class="search_field"/>
  77                                      </span>
  78                                      <input type="hidden" name="hl" value="en"/>
  79                                      <input type="hidden" name="ie" value="UTF-8"/>
  80                                      <input type="hidden" name="as_qdr" value="all"/>
  81                                      <input type="hidden" name="q" value="site:www.exim.org"/>
  82                                      <input type="hidden" name="q" value="inurl:exim-html-current"/>
  83                                   </form>
  84                                </li>
  85                          </ul>
  86
  87                       <!-- MAIN CONTENT. This is the div that wraps around the other stylesheets -->
  88                          <div id="inner">
  89                             <div id="content">
  90                               <xsl:call-template name="content"/>
  91                            </div>
  92                          </div>
  93
  94                       <!-- Branding -->
  95                          <iframe id="branding" name="branding" src="{$docroot}/branding/branding.html" height="0" frameborder="no" scrolling="no"/>
  96
  97                       <!-- Footer -->
  98
  99                          <div id="footer">
 100                             <xsl:text>Website design by </xsl:text>
 101                             <a href="https://www.grepular.com/">Mike Cardwell</a>
 102                             <xsl:text>.</xsl:text>
 103                          </div>
 104
 105                       <!-- Side Bars -->
 106                          <div class="left_bar"/>
 107                          <div class="right_bar"/>
 108
 109                       <!-- Append anything to the outer container? -->
 110                          <xsl:copy-of select="$html.body.outer.append"/>
 111                    </div>
 112
 113                 <!-- Load latest version of jQuery 1.6 from the Google CDN -->
 114                    <script type="text/javascript" src="//ajax.googleapis.com/ajax/libs/jquery/1.6/jquery.min.js"></script>
 115
 116                 <!-- Local JavaScript -->
 117                    <script type="text/javascript" src="{$staticroot}/js/common.js"></script>
 118
 119                    <xsl:copy-of select="$html.body.append"/>
 120
 121              </body>
 122
 123          </html>
 124       </xsl:template>
 125
 126    <!-- Quote Element -->
 127       <xsl:template match="quote">
 128          <xsl:text>&#8220;</xsl:text><xsl:apply-templates match="*"/><xsl:text>&#8221;</xsl:text>
 129       </xsl:template>
 130
 131    <!-- Random Docbook Elements -->
 132       <xsl:template match="filename | emphasis | option | command | function">
 133          <span class="docbook_{name()}"> <xsl:apply-templates/> </span>
 134       </xsl:template>
 135
 136    <!-- Literal Element -->
 137       <xsl:template match="literal">
 138          <code class="docbook_literal"> <xsl:apply-templates/> </code>
 139       </xsl:template>
 140       <xsl:template match="literallayout">
 141          <div class="docbook_literallayout"> <pre> <xsl:apply-templates/> </pre> </div>
 142       </xsl:template>
 143
 144    <!-- ULink Element -->
 145       <xsl:template match="ulink">
 146          <a href="{text()}"> <xsl:value-of select="text()"/> </a>
 147       </xsl:template>
 148
 149    <!-- XREF (Fixed up in the Perl) -->
 150       <xsl:template match="xref">
 151          <a href="{@url}" title="{@chapter_id}. {@chapter_title}">
 152             <xsl:choose>
 153                <xsl:when test="@section_id">
 154                   <xsl:choose>
 155                      <xsl:when test="@longref">
 156                         <xsl:value-of select="@chapter_title"/>
 157                         <small>
 158                            <xsl:value-of select="concat(' [',@section_title,']')"/>
 159                         </small>
 160                      </xsl:when>
 161                      <xsl:otherwise>
 162                         <xsl:value-of select="concat(@chapter_id,'.',@section_id)"/>
 163                      </xsl:otherwise>
 164                   </xsl:choose>
 165                </xsl:when>
 166                <xsl:otherwise>
 167                   <xsl:choose>
 168                      <xsl:when test="@longref">
 169                         <xsl:value-of select="@chapter_title"/>
 170                      </xsl:when>
 171                      <xsl:otherwise>
 172                         <xsl:value-of select="@chapter_id"/>
 173                      </xsl:otherwise>
 174                   </xsl:choose>
 175                </xsl:otherwise>
 176             </xsl:choose>
 177          </a>
 178       </xsl:template>
 179
 180    <!-- Para -->
 181       <xsl:template match="para">
 182          <p>
 183             <xsl:if test="@revisionflag!=''"><xsl:attribute name="class">changed</xsl:attribute></xsl:if>
 184             <xsl:apply-templates/>
 185          </p>
 186       </xsl:template>
 187
 188    <!-- Lists -->
 189       <xsl:template match="itemizedlist">                        <ul> <xsl:apply-templates/> </ul> </xsl:template>
 190       <xsl:template match="itemizedlist/listitem">               <li> <xsl:apply-templates/> </li> </xsl:template>
 191       <xsl:template match="orderedlist">                         <ol> <xsl:apply-templates/> </ol> </xsl:template>
 192       <xsl:template match="orderedlist/listitem">                <li> <xsl:apply-templates/> </li> </xsl:template>
 193       <xsl:template match="variablelist">                        <dl> <xsl:apply-templates/> </dl> </xsl:template>
 194       <xsl:template match="variablelist/varlistentry/term">      <dt> <xsl:apply-templates/> </dt> </xsl:template>
 195       <xsl:template match="variablelist/varlistentry/listitem">  <dd> <xsl:apply-templates/> </dd> </xsl:template>
 196
 197    <!-- Table -->
 198       <xsl:template match="informaltable"> <table> <xsl:apply-templates/> </table> </xsl:template>
 199       <xsl:template match="tbody/row">     <tr>    <xsl:apply-templates/> </tr>    </xsl:template>
 200       <xsl:template match="row/entry">     <td>    <xsl:apply-templates/> </td>    </xsl:template>
 201       <xsl:template match="tgroup|tbody"> <xsl:apply-templates/> </xsl:template>
 202
 203    <!-- Ignore -->
 204       <xsl:template match="indexterm|title|titleabbrev|current_version"/>
 205
 206 </xsl:stylesheet>