templates/wrapper.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4
   5    <!-- Define display/content information -->
   6       <xsl:output indent="yes"/>
   7       <xsl:output encoding="UTF-8"/>
   8       <xsl:output media-type="text/html"/>
   9       <xsl:output omit-xml-declaration="yes"/>
  10       <xsl:output doctype-public="XSLT-compat"/>
  11
  12    <!-- Define some variables -->
  13       <xsl:variable name="docroot"/>
  14       <xsl:variable name="html.head.title"/>
  15       <xsl:variable name="html.head.description" select="'Exim is a message transfer agent (MTA) developed at the University of Cambridge for use on Unix systems connected to the Internet.'"/>
  16       <xsl:variable name="html.head.keywords" select="'exim,smtp,mta,email'"/>
  17       <xsl:variable name="html.head.robots" select="'noodp,noydir,index,follow'"/>
  18       <xsl:variable name="html.head.append"/>
  19       <xsl:variable name="html.body.append"/>
  20       <xsl:variable name="html.body.outer.append"/>
  21
  22    <!-- The main template code -->
  23       <xsl:template match="/">
  24          <html lang="en-GB">
  25             <head>
  26                <link rel="stylesheet" type="text/css" href="{$docroot}/common.css"/>
  27
  28                <meta name="author"      content="The Exim Project. &lt;http://www.exim.org/&gt;"/>
  29                <meta name="copyright"   content="Copyright ©2010The Exim Project. All rights reserved"/>
  30                <meta name="description" content="{$html.head.description}"/>
  31                <meta name="keywords"    content="{$html.head.keywords}"/>
  32                <meta name="robots"      content="{$html.head.robots}"/>
  33
  34                <!-- Mobile Safari (iPhone) - Reduce viewport to physical size of device -->
  35                   <meta name="viewport" content="width=device-width"/>
  36
  37                <title>
  38                   <xsl:value-of select="$html.head.title"/>
  39                </title>
  40
  41                <xsl:copy-of select="$html.head.append"/>
  42             </head>
  43             <body>
  44
  45                 <!-- Header -->
  46
  47                    <h1 id="header">
  48                       <a href="{$docroot}">Exim Internet Mailer</a>
  49                    </h1>
  50
  51                 <!-- Outer Container -->
  52
  53                    <div id="outer">
  54
  55                       <!-- Navigation -->
  56
  57                          <ul class="navigation">
  58                             <li> <a href="{$docroot}/mirrors.html">Download</a> </li>
  59                             <li> <a href="{$docroot}/docs.html">Documentation</a> </li>
  60                             <li> <a href="{$docroot}/maillist.html">Mailing Lists</a> </li>
  61                             <li> <a href="http://wiki.exim.org/">Wiki</a> </li>
  62                             <li> <a href="http://www.exim.org/bugzilla/">Bugs</a> </li>
  63                             <li> <a href="{$docroot}/credits.html">Credits</a> </li>
  64
  65                             <!-- Search Field -->
  66
  67                                <li class="search">
  68                                   <form action="http://www.google.com/search" method="get">
  69                                      <span class="search_field_container">
  70                                         <input type="search" name="q" placeholder="Search Docs" class="search_field"/>
  71                                      </span>
  72                                      <input type="hidden" name="hl" value="en"/>
  73                                      <input type="hidden" name="ie" value="UTF-8"/>
  74                                      <input type="hidden" name="as_qdr" value="all"/>
  75                                      <input type="hidden" name="q" value="site:www.exim.org"/>
  76                                      <input type="hidden" name="q" value="inurl:exim-html-current"/>
  77                                   </form>
  78                                </li>
  79                          </ul>
  80
  81                       <!-- MAIN CONTENT. This is the div that wraps around the other stylesheets -->
  82                          <div id="inner">
  83                             <xsl:call-template name="content"/>
  84                          </div>
  85
  86                       <!-- Branding -->
  87                          <iframe id="branding" name="branding" src="{$docroot}/branding/branding.html" height="0" frameborder="no" scrolling="no"/>
  88
  89                       <!-- Footer -->
  90
  91                          <div id="footer">
  92                             <xsl:text>Website design by </xsl:text>
  93                             <a href="https://secure.grepular.com/">Mike Cardwell</a>
  94                             <xsl:text>, of </xsl:text>
  95                             <a href="http://cardwellit.com/">Cardwell IT Ltd.</a>
  96                          </div>
  97
  98                       <!-- Side Bars -->
  99                          <div class="left_bar"/>
 100                          <div class="right_bar"/>
 101
 102                       <!-- Append anything to the outer container? -->
 103                          <xsl:copy-of select="$html.body.outer.append"/>
 104                    </div>
 105
 106                 <!-- Load latest version of jQuery 1.4 from the Google CDN -->
 107                    <script type="text/javascript" src="http://ajax.googleapis.com/ajax/libs/jquery/1.4/jquery.min.js"></script>
 108
 109                 <!-- Local JavaScript -->
 110                    <script type="text/javascript" src="{$docroot}/common.js"></script>
 111
 112                    <xsl:copy-of select="$html.body.append"/>
 113
 114              </body>
 115
 116          </html>
 117       </xsl:template>
 118
 119    <!-- Quote Element -->
 120       <xsl:template match="quote">
 121          <xsl:text>&#8220;</xsl:text><xsl:apply-templates match="*"/><xsl:text>&#8221;</xsl:text>
 122       </xsl:template>
 123
 124    <!-- Random Docbook Elements -->
 125       <xsl:template match="filename | emphasis | option | command | function">
 126          <span class="docbook_{name()}"> <xsl:apply-templates/> </span>
 127       </xsl:template>
 128
 129    <!-- Literal Element -->
 130       <xsl:template match="literal">
 131          <code class="docbook_literal"> <xsl:apply-templates/> </code>
 132       </xsl:template>
 133       <xsl:template match="literallayout">
 134          <div class="docbook_literallayout"> <pre> <xsl:apply-templates/> </pre> </div>
 135       </xsl:template>
 136
 137    <!-- ULink Element -->
 138       <xsl:template match="ulink">
 139          <a href="{text()}"> <xsl:value-of select="text()"/> </a>
 140       </xsl:template>
 141
 142    <!-- XREF (Fixed up in the Perl) -->
 143       <xsl:template match="xref">
 144          <a href="{@url}" title="{@chapter_id}. {@chapter_title}">
 145             <xsl:choose>
 146                <xsl:when test="@section_id">
 147                   <xsl:choose>
 148                      <xsl:when test="@longref">
 149                         <xsl:value-of select="@chapter_title"/>
 150                         <small>
 151                            <xsl:value-of select="concat(' [',@section_title,']')"/>
 152                         </small>
 153                      </xsl:when>
 154                      <xsl:otherwise>
 155                         <xsl:value-of select="concat(@chapter_id,'.',@section_id)"/>
 156                      </xsl:otherwise>
 157                   </xsl:choose>
 158                </xsl:when>
 159                <xsl:otherwise>
 160                   <xsl:choose>
 161                      <xsl:when test="@longref">
 162                         <xsl:value-of select="@chapter_title"/>
 163                      </xsl:when>
 164                      <xsl:otherwise>
 165                         <xsl:value-of select="@chapter_id"/>
 166                      </xsl:otherwise>
 167                   </xsl:choose>
 168                </xsl:otherwise>
 169             </xsl:choose>
 170          </a>
 171       </xsl:template>
 172
 173    <!-- Para -->
 174       <xsl:template match="para"> <p> <xsl:apply-templates/> </p> </xsl:template>
 175
 176    <!-- Lists -->
 177       <xsl:template match="itemizedlist">                        <ul> <xsl:apply-templates/> </ul> </xsl:template>
 178       <xsl:template match="itemizedlist/listitem">               <li> <xsl:apply-templates/> </li> </xsl:template>
 179       <xsl:template match="orderedlist">                         <ol> <xsl:apply-templates/> </ol> </xsl:template>
 180       <xsl:template match="orderedlist/listitem">                <li> <xsl:apply-templates/> </li> </xsl:template>
 181       <xsl:template match="variablelist">                        <dl> <xsl:apply-templates/> </dl> </xsl:template>
 182       <xsl:template match="variablelist/varlistentry/term">      <dt> <xsl:apply-templates/> </dt> </xsl:template>
 183       <xsl:template match="variablelist/varlistentry/listitem">  <dd> <xsl:apply-templates/> </dd> </xsl:template>
 184
 185    <!-- Table -->
 186       <xsl:template match="informaltable"> <table> <xsl:apply-templates/> </table> </xsl:template>
 187       <xsl:template match="tbody/row">     <tr>    <xsl:apply-templates/> </tr>    </xsl:template>
 188       <xsl:template match="row/entry">     <td>    <xsl:apply-templates/> </td>    </xsl:template>
 189       <xsl:template match="tgroup|tbody"> <xsl:apply-templates/> </xsl:template>
 190
 191    <!-- Ignore -->
 192       <xsl:template match="indexterm|title|titleabbrev|current_version"/>
 193
 194 </xsl:stylesheet>