src/src/exigrep.src

   1 #! PERL_COMMAND
   2
   3 use warnings;
   4 use strict;
   5
   6 # Copyright (c) 2007-2015 University of Cambridge.
   7 # See the file NOTICE for conditions of use and distribution.
   8
   9 # Except when they appear in comments, the following placeholders in this
  10 # source are replaced when it is turned into a runnable script:
  11 #
  12 # PERL_COMMAND
  13 # ZCAT_COMMAND
  14 # COMPRESS_SUFFIX
  15
  16 # PROCESSED_FLAG
  17
  18 # This is a perl script which extracts from an Exim log all entries
  19 # for all messages that have an entry that matches a given pattern.
  20 # If *any* entry for a particular message matches the pattern, *all*
  21 # entries for that message are displayed.
  22
  23 # We buffer up information on a per-message basis. It is done this way rather
  24 # than reading the input twice so that the input can be a pipe.
  25
  26 # There must be one argument, which is the pattern. Subsequent arguments
  27 # are the files to scan; if none, the standard input is read. If any file
  28 # appears to be compressed, it is passed through zcat. We can't just do this
  29 # for all files, because zcat chokes on non-compressed files.
  30
  31 # Performance optimized in 02/02/2007 by Jori Hamalainen
  32 # Typical run time acceleration: 4 times
  33
  34
  35 use Getopt::Std qw(getopts);
  36 use POSIX qw(mktime);
  37
  38
  39 # This subroutine converts a time/date string from an Exim log line into
  40 # the number of seconds since the epoch. It handles optional timezone
  41 # information.
  42
  43 sub seconds {
  44 my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
  45   $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?>\s([+-])(\d\d)(\d\d))?/o;
  46
  47 my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;
  48
  49 if (defined $tzs)
  50   {
  51   $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
  52   $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
  53   }
  54
  55 return $seconds;
  56 }
  57
  58
  59 # This subroutine processes a single line (in $_) from a log file. Program
  60 # defensively against short lines finding their way into the log.
  61
  62 my (%saved, %id_list, $pattern, $queue_time, $insensitive, $invert);
  63
  64 # If using "related" option, have to track extra message IDs
  65 my $related;
  66 my $related_re='';
  67 my @Mids = ();
  68
  69 sub do_line {
  70
  71 # Convert syslog lines to mainlog format, as in eximstats.
  72
  73 if (!/^\d{4}-/o) { $_ =~ s/^.*? exim\b.*?: //o; }
  74
  75 return unless
  76   my($date,$id) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?(\w{6}\-\w{6}\-\w{2})?/o;
  77
  78 # Handle the case when the log line belongs to a specific message. We save
  79 # lines for specific messages until the message is complete. Then either print
  80 # or discard.
  81
  82 if (defined $id)
  83   {
  84   $saved{$id} = '' unless defined($saved{$id});
  85
  86   # Save up the data for this message in case it becomes interesting later.
  87
  88   $saved{$id} .= $_;
  89
  90   # Are we interested in this id ? Short circuit if we already were interested.
  91
  92   if ($invert)
  93     {
  94     $id_list{$id} = 1 if (!defined($id_list{$id}));
  95     $id_list{$id} = 0 if (($insensitive && /$pattern/io) || /$pattern/o);
  96     }
  97   else
  98     {
  99     if (defined $id_list{$id} ||
 100       ($insensitive && /$pattern/io) || /$pattern/o)
 101       {
 102       $id_list{$id} = 1;
 103       get_related_ids($id) if $related;
 104       }
 105     elsif ($related && $related_re)
 106       {
 107       grep_for_related($_, $id);
 108       }
 109     }
 110
 111   # See if this is a completion for some message. If it is interesting,
 112   # print it, but in any event, throw away what was saved.
 113
 114   if (index($_, 'Completed') != -1 ||
 115       index($_, 'SMTP data timeout') != -1 ||
 116         (index($_, 'rejected') != -1 &&
 117           /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?\w{6}\-\w{6}\-\w{2} rejected/o))
 118     {
 119     if ($queue_time != -1 &&
 120         $saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)/o)
 121       {
 122       my $old_sec = &seconds($1);
 123       my $sec = &seconds($date);
 124       $id_list{$id} = 0 if $id_list{$id} && $sec - $old_sec <= $queue_time;
 125       }
 126
 127     print "$saved{$id}\n" if ($id_list{$id});
 128     delete $id_list{$id};
 129     delete $saved{$id};
 130     }
 131   }
 132
 133 # Handle the case where the log line does not belong to a specific message.
 134 # Print it if it is interesting.
 135
 136 elsif ( ($invert && (($insensitive && !/$pattern/io) || !/$pattern/o)) ||
 137        (!$invert && (($insensitive &&  /$pattern/io) ||  /$pattern/o)) )
 138   { print "$_\n"; }
 139 }
 140
 141 # Rotated log files are frequently compressed and there are a variety of
 142 # formats it could be compressed with. Rather than use just one that is
 143 # detected and hardcoded at Exim compile time, detect and use what the
 144 # logfile is compressed with on the fly.
 145 #
 146 # List of known compression extensions and their associated commands:
 147 my $compressors = {
 148   gz   => { cmd => 'zcat',  args => '' },
 149   bz2  => { cmd => 'bzcat', args => '' },
 150   xz   => { cmd => 'xzcat', args => '' },
 151   lzma => { cmd => 'lzma',  args => '-dc' }
 152 };
 153 my $csearch = 0;
 154
 155 sub detect_compressor_bin
 156   {
 157   my $ext = shift();
 158   my $c = $compressors->{$ext}->{cmd};
 159   $compressors->{$ext}->{bin} = `which $c 2>/dev/null`;
 160   chomp($compressors->{$ext}->{bin});
 161   }
 162
 163 sub detect_compressor_capable
 164   {
 165   my $filename = shift();
 166   map { &detect_compressor_bin($_) } keys %$compressors
 167     if (!$csearch);
 168   $csearch = 1;
 169   return undef
 170     unless (grep {$filename =~ /\.(?:$_)$/} keys %$compressors);
 171   # Loop through them, figure out which one it detected,
 172   # and build the commandline.
 173   my $cmdline = undef;
 174   foreach my $ext (keys %$compressors)
 175     {
 176     if ($filename =~ /\.(?:$ext)$/)
 177       {
 178       # Just die if compressor not found; if this occurs in the middle of
 179       # two valid files with a lot of matches, error could easily be missed.
 180       die("Didn't find $ext decompressor for $filename\n")
 181         if ($compressors->{$ext}->{bin} eq '');
 182       $cmdline = $compressors->{$ext}->{bin} ." ".
 183                    $compressors->{$ext}->{args};
 184       last;
 185       }
 186     }
 187   return $cmdline;
 188   }
 189
 190 sub grep_for_related {
 191   my ($line,$id) = @_;
 192   $id_list{$id} = 1 if $line =~ m/$related_re/;
 193 }
 194
 195 sub get_related_ids {
 196   my ($id) = @_;
 197   push @Mids, $id unless grep /\b$id\b/, @Mids;
 198   my $re = join '|', @Mids;
 199   $related_re = qr/$re/;
 200 }
 201
 202 # The main program. Extract the pattern and make sure any relevant characters
 203 # are quoted if the -l flag is given. The -t flag gives a time-on-queue value
 204 # which is an additional condition. The -M flag will also display "related"
 205 # loglines (msgid from matched lines is searched in following lines).
 206
 207 getopts('Ilvt:M',\my %args);
 208 $queue_time  = $args{'t'}? $args{'t'} : -1;
 209 $insensitive = $args{'I'}? 0 : 1;
 210 $invert      = $args{'v'}? 1 : 0;
 211 $related     = $args{'M'}? 1 : 0;
 212
 213 die "usage: exigrep [-I] [-l] [-M] [-t <seconds>] [-v] <pattern> [<log file>]...\n"
 214   if ($#ARGV < 0);
 215
 216 $pattern = shift @ARGV;
 217 $pattern = quotemeta $pattern if $args{l};
 218
 219
 220 # If file arguments are given, open each one and process according as it is
 221 # is compressed or not.
 222
 223 if (@ARGV)
 224   {
 225   foreach (@ARGV)
 226     {
 227     my $filename = $_;
 228     if (-x 'ZCAT_COMMAND' && $filename =~ /\.(?:COMPRESS_SUFFIX)$/o)
 229       {
 230       open(LOG, "ZCAT_COMMAND $filename |") ||
 231         die "Unable to zcat $filename: $!\n";
 232       }
 233     elsif (my $cmdline = &detect_compressor_capable($filename))
 234       {
 235       open(LOG, "$cmdline $filename |") ||
 236         die "Unable to decompress $filename: $!\n";
 237       }
 238     else
 239       {
 240       open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
 241       }
 242     do_line() while (<LOG>);
 243     close(LOG);
 244     }
 245   }
 246
 247 # If no files are named, process STDIN only
 248
 249 else { do_line() while (<STDIN>); }
 250
 251 # At the end of processing all the input, print any uncompleted messages.
 252
 253 for (keys %id_list)
 254   {
 255   print "+++ $_ has not completed +++\n$saved{$_}\n";
 256   }
 257
 258 # End of exigrep