test/runtest

   1 #! /usr/bin/perl -w
   2
   3 ###############################################################################
   4 # This is the controlling script for the "new" test suite for Exim. It should #
   5 # be possible to export this suite for running on a wide variety of hosts, in #
   6 # contrast to the old suite, which was very dependent on the environment of   #
   7 # Philip Hazel's desktop computer. This implementation inspects the version   #
   8 # of Exim that it finds, and tests only those features that are included. The #
   9 # surrounding environment is also tested to discover what is available. See   #
  10 # the README file for details of how it all works.                            #
  11 #                                                                             #
  12 # Implementation started: 03 August 2005 by Philip Hazel                      #
  13 # Placed in the Exim CVS: 06 February 2006                                    #
  14 ###############################################################################
  15
  16 #use strict;
  17 #use 5.010;
  18 use Errno;
  19 use FileHandle;
  20 use IO::Socket::INET;
  21 use Socket;
  22 use Time::Local;
  23 use Cwd;
  24 use File::Basename;
  25 use if $ENV{DEBUG} && $ENV{DEBUG} =~ /\bruntest\b/ => ('Smart::Comments' => '####');
  26
  27
  28 # Start by initializing some global variables
  29
  30 $testversion = "4.80 (08-May-12)";
  31
  32 # This gets embedded in the D-H params filename, and the value comes
  33 # from asking GnuTLS for "normal", but there appears to be no way to
  34 # use certtool/... to ask what that value currently is.  *sigh*
  35 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  36 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  37 # normal = 2432   tls_dh_max_bits = 2236
  38 $gnutls_dh_bits_normal = 2236;
  39
  40 $cf = "bin/cf -exact";
  41 $cr = "\r";
  42 $debug = 0;
  43 $flavour = 'FOO';
  44 $force_continue = 0;
  45 $force_update = 0;
  46 $log_failed_filename = "failed-summary.log";
  47 $more = "less -XF";
  48 $optargs = "";
  49 $save_output = 0;
  50 $server_opts = "";
  51 $valgrind = 0;
  52
  53 $have_ipv4 = 1;
  54 $have_ipv6 = 1;
  55 $have_largefiles = 0;
  56
  57 $test_start = 1;
  58 $test_end = $test_top = 8999;
  59 $test_special_top = 9999;
  60 @test_list = ();
  61 @test_dirs = ();
  62
  63
  64 # Networks to use for DNS tests. We need to choose some networks that will
  65 # never be used so that there is no chance that the host on which we are
  66 # running is actually in one of the test networks. Private networks such as
  67 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  68 # Rather than use some unassigned numbers (that might become assigned later),
  69 # I have chosen some multicast networks, in the belief that such addresses
  70 # won't ever be assigned to hosts. This is the only place where these numbers
  71 # are defined, so it is trivially possible to change them should that ever
  72 # become necessary.
  73
  74 $parm_ipv4_test_net = "224";
  75 $parm_ipv6_test_net = "ff00";
  76
  77 # Port numbers are currently hard-wired
  78
  79 $parm_port_n = 1223;         # Nothing listening on this port
  80 $parm_port_s = 1224;         # Used for the "server" command
  81 $parm_port_d = 1225;         # Used for the Exim daemon
  82 $parm_port_d2 = 1226;        # Additional for daemon
  83 $parm_port_d3 = 1227;        # Additional for daemon
  84 $parm_port_d4 = 1228;        # Additional for daemon
  85 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
  86
  87 # Manually set locale
  88 $ENV{LC_ALL} = 'C';
  89
  90 # In some environments USER does not exists, but we
  91 # need it for some test(s)
  92 $ENV{USER} = getpwuid($>)
  93   if not exists $ENV{USER};
  94
  95 my ($parm_configure_owner, $parm_configure_group);
  96 my ($parm_ipv4, $parm_ipv6);
  97 my $parm_hostname;
  98
  99 ###############################################################################
 100 ###############################################################################
 101
 102 # Define a number of subroutines
 103
 104 ###############################################################################
 105 ###############################################################################
 106
 107
 108 ##################################################
 109 #              Handle signals                    #
 110 ##################################################
 111
 112 sub pipehandler { $sigpipehappened = 1; }
 113
 114 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 115
 116
 117 ##################################################
 118 #       Do global macro substitutions            #
 119 ##################################################
 120
 121 # This function is applied to configurations, command lines and data lines in
 122 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 123 # directory. It takes one argument: the current test number, or zero when
 124 # setting up files before running any tests.
 125
 126 sub do_substitute{
 127 s?\bCALLER\b?$parm_caller?g;
 128 s?\bCALLERGROUP\b?$parm_caller_group?g;
 129 s?\bCALLER_UID\b?$parm_caller_uid?g;
 130 s?\bCALLER_GID\b?$parm_caller_gid?g;
 131 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 132 s?\bDIR/?$parm_cwd/?g;
 133 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 134 s?\bEXIMUSER\b?$parm_eximuser?g;
 135 s?\bHOSTIPV4\b?$parm_ipv4?g;
 136 s?\bHOSTIPV6\b?$parm_ipv6?g;
 137 s?\bHOSTNAME\b?$parm_hostname?g;
 138 s?\bPORT_D\b?$parm_port_d?g;
 139 s?\bPORT_D2\b?$parm_port_d2?g;
 140 s?\bPORT_D3\b?$parm_port_d3?g;
 141 s?\bPORT_D4\b?$parm_port_d4?g;
 142 s?\bPORT_N\b?$parm_port_n?g;
 143 s?\bPORT_S\b?$parm_port_s?g;
 144 s?\bTESTNUM\b?$_[0]?g;
 145 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 146 s?\bV6NET:?$parm_ipv6_test_net:?g;
 147 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 148 }
 149
 150
 151 ##################################################
 152 #     Any state to be preserved across tests     #
 153 ##################################################
 154
 155 my $TEST_STATE = {};
 156
 157
 158 ##################################################
 159 #        Subroutine to tidy up and exit          #
 160 ##################################################
 161
 162 # In all cases, we check for any Exim daemons that have been left running, and
 163 # kill them. Then remove all the spool data, test output, and the modified Exim
 164 # binary if we are ending normally.
 165
 166 # Arguments:
 167 #    $_[0] = 0 for a normal exit; full cleanup done
 168 #    $_[0] > 0 for an error exit; no files cleaned up
 169 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 170
 171 sub tests_exit{
 172 my($rc) = $_[0];
 173 my($spool);
 174
 175 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 176 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 177 # the background.
 178
 179 if (exists $TEST_STATE->{exim_pid})
 180   {
 181   $pid = $TEST_STATE->{exim_pid};
 182   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 183   system("sudo kill -INT $pid");
 184   }
 185
 186 if (opendir(DIR, "spool"))
 187   {
 188   my(@spools) = sort readdir(DIR);
 189   closedir(DIR);
 190   foreach $spool (@spools)
 191     {
 192     next if $spool !~ /^exim-daemon./;
 193     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 194     chomp($pid = <PID>);
 195     close(PID);
 196     print "Tidyup: killing daemon pid=$pid\n";
 197     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 198     }
 199   }
 200 else
 201   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 202
 203 # Close the terminal input and remove the test files if all went well, unless
 204 # the option to save them is set. Always remove the patched Exim binary. Then
 205 # exit normally, or die.
 206
 207 close(T);
 208 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 209   if ($rc == 0 && !$save_output);
 210
 211 system("sudo /bin/rm -rf ./eximdir/*")
 212   if (!$save_output);
 213
 214 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 215 exit $rc if ($rc >= 0);
 216 die "** runtest error: $_[1]\n";
 217 }
 218
 219
 220
 221 ##################################################
 222 #   Subroutines used by the munging subroutine   #
 223 ##################################################
 224
 225 # This function is used for things like message ids, where we want to generate
 226 # more than one value, but keep a consistent mapping throughout.
 227 #
 228 # Arguments:
 229 #   $oldid        the value from the file
 230 #   $base         a base string into which we insert a sequence
 231 #   $sequence     the address of the current sequence counter
 232
 233 sub new_value {
 234 my($oldid, $base, $sequence) = @_;
 235 my($newid) = $cache{$oldid};
 236 if (! defined $newid)
 237   {
 238   $newid = sprintf($base, $$sequence++);
 239   $cache{$oldid} = $newid;
 240   }
 241 return $newid;
 242 }
 243
 244
 245 # This is used while munging the output from exim_dumpdb.
 246 # May go wrong across DST changes.
 247
 248 sub date_seconds {
 249 my($day,$month,$year,$hour,$min,$sec) =
 250   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 251 my($mon);
 252 if   ($month =~ /Jan/) {$mon = 0;}
 253 elsif($month =~ /Feb/) {$mon = 1;}
 254 elsif($month =~ /Mar/) {$mon = 2;}
 255 elsif($month =~ /Apr/) {$mon = 3;}
 256 elsif($month =~ /May/) {$mon = 4;}
 257 elsif($month =~ /Jun/) {$mon = 5;}
 258 elsif($month =~ /Jul/) {$mon = 6;}
 259 elsif($month =~ /Aug/) {$mon = 7;}
 260 elsif($month =~ /Sep/) {$mon = 8;}
 261 elsif($month =~ /Oct/) {$mon = 9;}
 262 elsif($month =~ /Nov/) {$mon = 10;}
 263 elsif($month =~ /Dec/) {$mon = 11;}
 264 return timelocal($sec,$min,$hour,$day,$mon,$year);
 265 }
 266
 267
 268 # This is a subroutine to sort maildir files into time-order. The second field
 269 # is the microsecond field, and may vary in length, so must be compared
 270 # numerically.
 271
 272 sub maildirsort {
 273 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 274 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 275 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 276 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 277 }
 278
 279
 280
 281 ##################################################
 282 #   Subroutine list files below a directory      #
 283 ##################################################
 284
 285 # This is used to build up a list of expected mail files below a certain path
 286 # in the directory tree. It has to be recursive in order to deal with multiple
 287 # maildir mailboxes.
 288
 289 sub list_files_below {
 290 my($dir) = $_[0];
 291 my(@yield) = ();
 292 my(@sublist, $file);
 293
 294 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 295 @sublist = sort maildirsort readdir(DIR);
 296 closedir(DIR);
 297
 298 foreach $file (@sublist)
 299   {
 300   next if $file eq "." || $file eq ".." || $file eq "CVS";
 301   if (-d "$dir/$file")
 302     { @yield = (@yield, list_files_below("$dir/$file")); }
 303   else
 304     { push @yield, "$dir/$file"; }
 305   }
 306
 307 return @yield;
 308 }
 309
 310
 311
 312 ##################################################
 313 #         Munge a file before comparing          #
 314 ##################################################
 315
 316 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 317 # on into standard values, so that the compare works. Perl's substitution with
 318 # an expression provides a neat way to do some of these changes.
 319
 320 # We keep a global associative array for repeatedly turning the same values
 321 # into the same standard values throughout the data from a single test.
 322 # Message ids get this treatment (can't be made reliable for times), and
 323 # times in dumped retry databases are also handled in a special way, as are
 324 # incoming port numbers.
 325
 326 # On entry to the subroutine, the file to write to is already opened with the
 327 # name MUNGED. The input file name is the only argument to the subroutine.
 328 # Certain actions are taken only when the name contains "stderr", "stdout",
 329 # or "log". The yield of the function is 1 if a line matching "*** truncated
 330 # ***" is encountered; otherwise it is 0.
 331
 332 sub munge {
 333 my($file) = $_[0];
 334 my($extra) = $_[1];
 335 my($yield) = 0;
 336 my(@saved) = ();
 337
 338 local $_;
 339
 340 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 341
 342 my($is_log) = $file =~ /log/;
 343 my($is_stdout) = $file =~ /stdout/;
 344 my($is_stderr) = $file =~ /stderr/;
 345
 346 # Date pattern
 347
 348 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 349
 350 # Pattern for matching pids at start of stderr lines; initially something
 351 # that won't match.
 352
 353 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 354
 355 # Scan the file and make the changes. Near the bottom there are some changes
 356 # that are specific to certain file types, though there are also some of those
 357 # inline too.
 358
 359 LINE: while(<IN>)
 360   {
 361 RESET_AFTER_EXTRA_LINE_READ:
 362   # Custom munges
 363   if ($extra)
 364     {
 365     next if $extra =~ m%^/%  &&  eval $extra;
 366     eval $extra if $extra =~ m/^s/;
 367     }
 368
 369   # Check for "*** truncated ***"
 370   $yield = 1 if /\*\*\* truncated \*\*\*/;
 371
 372   # Replace the name of this host
 373   s/\Q$parm_hostname\E/the.local.host.name/g;
 374
 375   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 376   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 377
 378   # The name of the shell may vary
 379   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 380
 381   # Replace the path to the testsuite directory
 382   s?\Q$parm_cwd\E?TESTSUITE?g;
 383
 384   # Replace the Exim version number (may appear in various places)
 385   # patchexim should have fixed this for us
 386   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 387
 388   # Replace Exim message ids by a unique series
 389   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 390     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 391
 392   # The names of lock files appear in some error and debug messages
 393   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 394
 395   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 396   # port" message, because it is not always the same.
 397   s/port (\d+) \([^)]+\)/port $1/g
 398     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 399
 400   # Challenges in SPA authentication
 401   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 402
 403   # PRVS values
 404   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 405   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 406
 407   # Error lines on stdout from SSL contain process id values and file names.
 408   # They also contain a source file name and line number, which may vary from
 409   # release to release.
 410   s/^\d+:error:/pppp:error:/;
 411   s/:(?:\/[^\s:]+\/)?([^\/\s]+\.c):\d+:/:$1:dddd:/;
 412
 413   # There are differences in error messages between OpenSSL versions
 414   s/SSL_CTX_set_cipher_list/SSL_connect/;
 415
 416   # One error test in expansions mentions base 62 or 36
 417   s/is not a base (36|62) number/is not a base 36\/62 number/;
 418
 419   # This message sometimes has a different number of seconds
 420   s/forced fail after \d seconds/forced fail after d seconds/;
 421
 422   # This message may contain a different DBM library name
 423   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 424
 425   # The message for a non-listening FIFO varies
 426   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 427
 428   # Debugging output of lists of hosts may have different sort keys
 429   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 430
 431   # Random local part in callout cache testing
 432   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 433   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 434
 435   # File descriptor numbers may vary
 436   s/^writing data block fd=\d+/writing data block fd=dddd/;
 437   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 438
 439
 440   # ======== Dumpdb output ========
 441   # This must be before the general date/date munging.
 442   # Time data lines, which look like this:
 443   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 444   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 445     {
 446     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 447     $expired = "" if !defined $expired;
 448     my($increment) = date_seconds($date3) - date_seconds($date2);
 449
 450     # We used to use globally unique replacement values, but timing
 451     # differences make this impossible. Just show the increment on the
 452     # last one.
 453
 454     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 455       $increment, $expired);
 456     next;
 457     }
 458
 459   # more_errno values in exim_dumpdb output which are times
 460   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 461
 462
 463   # ======== Dates and times ========
 464
 465   # Dates and times are all turned into the same value - trying to turn
 466   # them into different ones cannot be done repeatedly because they are
 467   # real time stamps generated while running the test. The actual date and
 468   # time used was fixed when I first started running automatic Exim tests.
 469
 470   # Date/time in header lines and SMTP responses
 471   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 472     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 473
 474   # Date/time in logs and in one instance of a filter test
 475   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 476   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 477
 478   # Date/time in message separators
 479   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 480     /Tue Mar 02 09:44:33 1999/gx;
 481
 482   # Date of message arrival in spool file as shown by -Mvh
 483   s/^\d{9,10}\s0$/ddddddddd 0/;
 484
 485   # Date/time in mbx mailbox files
 486   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 487
 488   # Dates/times in debugging output for writing retry records
 489   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 490     {
 491     my($next) = $3 - $2;
 492     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 493     }
 494   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 495   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 496
 497   # Time to retry may vary
 498   s/time to retry = \S+/time to retry = tttt/;
 499   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 500   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 501
 502   # Date/time in exim -bV output
 503   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 504
 505   # Time on queue tolerance
 506   s/(QT|D)=1s/$1=0s/;
 507
 508   # Eximstats heading
 509   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 510     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 511
 512   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 513   # us the former on a new connection.
 514   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 515
 516   # ======== TLS certificate algorithms ========
 517   # Test machines might have various different TLS library versions supporting
 518   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 519   # treat the standard algorithms the same.
 520   # So far, have seen:
 521   #   TLSv1:AES128-GCM-SHA256:128
 522   #   TLSv1:AES256-SHA:256
 523   #   TLSv1.1:AES256-SHA:256
 524   #   TLSv1.2:AES256-GCM-SHA384:256
 525   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 526   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 527   # We also need to handle the ciphersuite without the TLS part present, for
 528   # client-ssl's output.  We also see some older forced ciphersuites, but
 529   # negotiating TLS 1.2 instead of 1.0.
 530   # Mail headers (...), log-lines X=..., client-ssl output ...
 531   # (and \b doesn't match between ' ' and '(' )
 532
 533   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 534   s/\bAES128-GCM-SHA256:128\b/AES256-SHA:256/g;
 535   s/\bAES128-GCM-SHA256\b/AES256-SHA/g;
 536   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 537   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 538
 539   # GnuTLS have seen:
 540   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 541   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 542   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 543   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 544   #
 545   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 546   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 547   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 548   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 549   # and as stand-alone cipher:
 550   #   ECDHE-RSA-AES256-SHA
 551   #   DHE-RSA-AES256-SHA256
 552   #   DHE-RSA-AES256-SHA
 553   # picking latter as canonical simply because regex easier that way.
 554   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 555   s/TLS1.[012]:((EC)?DHE_)?RSA_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 556   s/\b(ECDHE-RSA-AES256-SHA|DHE-RSA-AES256-SHA256)\b/AES256-SHA/g;
 557
 558   # GnuTLS library error message changes
 559   s/No certificate was found/The peer did not send any certificate/g;
 560 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 561   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 562
 563   # (this new one is a generic channel-read error, but the testsuite
 564   # only hits it in one place)
 565   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 566
 567   # (replace old with new, hoping that old only happens in one situation)
 568   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 569   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 570
 571   # signature algorithm names
 572   s/RSA-SHA1/RSA-SHA/;
 573
 574
 575   # ======== Caller's login, uid, gid, home, gecos ========
 576
 577   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 578   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 579   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 580
 581   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 582   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 583
 584   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 585   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 586
 587   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 588
 589   # When looking at spool files with -Mvh, we will find not only the caller
 590   # login, but also the uid and gid. It seems that $) in some Perls gives all
 591   # the auxiliary gids as well, so don't bother checking for that.
 592
 593   s/^CALLER $> \d+$/CALLER UID GID/;
 594
 595   # There is one case where the caller's login is forced to something else,
 596   # in order to test the processing of logins that contain spaces. Weird what
 597   # some people do, isn't it?
 598
 599   s/^spaced user $> \d+$/CALLER UID GID/;
 600
 601
 602   # ======== Exim's login ========
 603   # For messages received by the daemon, this is in the -H file, which some
 604   # tests inspect. For bounce messages, this will appear on the U= lines in
 605   # logs and also after Received: and in addresses. In one pipe test it appears
 606   # after "Running as:". It also appears in addresses, and in the names of lock
 607   # files.
 608
 609   s/U=$parm_eximuser/U=EXIMUSER/;
 610   s/user=$parm_eximuser/user=EXIMUSER/;
 611   s/login=$parm_eximuser/login=EXIMUSER/;
 612   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 613   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 614   s/\b$parm_eximuser@/EXIMUSER@/;
 615   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 616
 617   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 618   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 619
 620   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 621   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 622
 623   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 624
 625
 626   # ======== General uids, gids, and pids ========
 627   # Note: this must come after munges for caller's and exim's uid/gid
 628
 629   # These are for systems where long int is 64
 630   s/\buid=4294967295/uid=-1/;
 631   s/\beuid=4294967295/euid=-1/;
 632   s/\bgid=4294967295/gid=-1/;
 633   s/\begid=4294967295/egid=-1/;
 634
 635   s/\bgid=\d+/gid=gggg/;
 636   s/\begid=\d+/egid=gggg/;
 637   s/\bpid=\d+/pid=pppp/;
 638   s/\buid=\d+/uid=uuuu/;
 639   s/\beuid=\d+/euid=uuuu/;
 640   s/set_process_info:\s+\d+/set_process_info: pppp/;
 641   s/queue run pid \d+/queue run pid ppppp/;
 642   s/process \d+ running as transport filter/process pppp running as transport filter/;
 643   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 644   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 645   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 646
 647   # Pid in temp file in appendfile transport
 648   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 649
 650   # Optional pid in log lines
 651   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 652     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 653
 654   # Detect a daemon stderr line with a pid and save the pid for subsequent
 655   # removal from following lines.
 656   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 657   s/^$spid //;
 658
 659   # Queue runner waiting messages
 660   s/waiting for children of \d+/waiting for children of pppp/;
 661   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 662
 663   # The spool header file name varies with PID
 664   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 665
 666   # ======== Port numbers ========
 667   # Incoming port numbers may vary, but not in daemon startup line.
 668
 669   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 670   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 671
 672   # This handles "connection from" and the like, when the port is given
 673   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 674       && !/\*>/ && !/Connection refused/)
 675     {
 676     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 677     }
 678
 679   # Port in host address in spool file output from -Mvh
 680   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 681
 682   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 683     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 684   }
 685
 686
 687   # ======== Local IP addresses ========
 688   # The amount of space between "host" and the address in verification output
 689   # depends on the length of the host name. We therefore reduce it to one space
 690   # for all of them.
 691   # Also, the length of space at the end of the host line is dependent
 692   # on the length of the longest line, so strip it also on otherwise
 693   # un-rewritten lines like localhost
 694
 695   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 696   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 697   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 698   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 699   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 700   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 701   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 702   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 703   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 704   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 705
 706
 707   # ======== Test network IP addresses ========
 708   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 709   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 710
 711
 712   # ======== IP error numbers and messages ========
 713   # These vary between operating systems
 714   s/Can't assign requested address/Network Error/;
 715   s/Cannot assign requested address/Network Error/;
 716   s/Operation timed out/Connection timed out/;
 717   s/Address family not supported by protocol family/Network Error/;
 718   s/Network is unreachable/Network Error/;
 719   s/Invalid argument/Network Error/;
 720
 721   s/\(\d+\): Network/(dd): Network/;
 722   s/\(\d+\): Connection refused/(dd): Connection refused/;
 723   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 724   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 725   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 726
 727
 728   # ======== Other error numbers ========
 729   s/errno=\d+/errno=dd/g;
 730
 731   # ======== System Error Messages ======
 732   # depending on the underlaying file system the error message seems to differ
 733   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 734
 735   # ======== Output from ls ========
 736   # Different operating systems use different spacing on long output
 737   #s/ +/ /g if /^[-rwd]{10} /;
 738   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 739   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 740   # unfortunately matches a non-ls linefull of dashes.
 741   # Allow the case where we've already picked out the file protection bits.
 742   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 743     s/ +/ /g;
 744   }
 745
 746
 747   # ======== Message sizes =========
 748   # Message sizes vary, owing to different logins and host names that get
 749   # automatically inserted. I can't think of any way of even approximately
 750   # comparing these.
 751
 752   s/([\s,])S=\d+\b/$1S=sss/;
 753   s/:S\d+\b/:Ssss/;
 754   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 755   s/\sSIZE=\d+\b/ SIZE=ssss/;
 756   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 757   s/old size = \d+\b/old size = sssss/;
 758   s/message size = \d+\b/message size = sss/;
 759   s/this message = \d+\b/this message = sss/;
 760   s/Size of headers = \d+/Size of headers = sss/;
 761   s/sum=(?!0)\d+/sum=dddd/;
 762   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 763   s/(?<=sum=0 )count=\d+\b/count=dd/;
 764   s/,S is \d+\b/,S is ddddd/;
 765   s/\+0100,\d+;/+0100,ddd;/;
 766   s/\(\d+ bytes written\)/(ddd bytes written)/;
 767   s/added '\d+ 1'/added 'ddd 1'/;
 768   s/Received\s+\d+/Received               nnn/;
 769   s/Delivered\s+\d+/Delivered              nnn/;
 770
 771
 772   # ======== Values in spool space failure message ========
 773   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 774
 775
 776   # ======== Filter sizes ========
 777   # The sizes of filter files may vary because of the substitution of local
 778   # filenames, logins, etc.
 779
 780   s/^\d+(?= bytes read from )/ssss/;
 781
 782
 783   # ======== OpenSSL error messages ========
 784   # Different releases of the OpenSSL libraries seem to give different error
 785   # numbers, or handle specific bad conditions in different ways, leading to
 786   # different wording in the error messages, so we cannot compare them.
 787
 788   s/(TLS error on connection (?:from .* )?\(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 789   next if /SSL verify error: depth=0 error=certificate not trusted/;
 790
 791   # ======== Maildir things ========
 792   # timestamp output in maildir processing
 793   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 794
 795   # maildir delivery files appearing in log lines (in cases of error)
 796   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 797
 798   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 799
 800   # Maildir file names in general
 801   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 802
 803   # Maildirsize data
 804   while (/^\d+S,\d+C\s*$/)
 805     {
 806     print MUNGED;
 807     while (<IN>)
 808       {
 809       last if !/^\d+ \d+\s*$/;
 810       print MUNGED "ddd d\n";
 811       }
 812     last if !defined $_;
 813     }
 814   last if !defined $_;
 815
 816
 817   # ======== Output from the "fd" program about open descriptors ========
 818   # The statuses seem to be different on different operating systems, but
 819   # at least we'll still be checking the number of open fd's.
 820
 821   s/max fd = \d+/max fd = dddd/;
 822   s/status=0 RDONLY/STATUS/g;
 823   s/status=1 WRONLY/STATUS/g;
 824   s/status=2 RDWR/STATUS/g;
 825
 826
 827   # ======== Contents of spool files ========
 828   # A couple of tests dump the contents of the -H file. The length fields
 829   # will be wrong because of different user names, etc.
 830   s/^\d\d\d(?=[PFS*])/ddd/;
 831
 832
 833   # ========= Exim lookups ==================
 834   # Lookups have a char which depends on the number of lookup types compiled in,
 835   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 836   # other output is fragile; perhaps the debug output should be revised instead.
 837   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 838
 839   # ==========================================================
 840   # MIME boundaries in RFC3461 DSN messages
 841   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 842
 843   # ==========================================================
 844   # Some munging is specific to the specific file types
 845
 846   # ======== stdout ========
 847
 848   if ($is_stdout)
 849     {
 850     # Skip translate_ip_address and use_classresources in -bP output because
 851     # they aren't always there.
 852
 853     next if /translate_ip_address =/;
 854     next if /use_classresources/;
 855
 856     # In certain filter tests, remove initial filter lines because they just
 857     # clog up by repetition.
 858
 859     if ($rmfiltertest)
 860       {
 861       next if /^(Sender\staken\sfrom|
 862                  Return-path\scopied\sfrom|
 863                  Sender\s+=|
 864                  Recipient\s+=)/x;
 865       if (/^Testing \S+ filter/)
 866         {
 867         $_ = <IN>;    # remove blank line
 868         next;
 869         }
 870       }
 871
 872     # openssl version variances
 873     next if /^SSL info: unknown state/;
 874     next if /^SSL info: SSLv2\/v3 write client hello A/;
 875     next if /^SSL info: SSLv3 read server key exchange A/;
 876     next if /SSL verify error: depth=0 error=certificate not trusted/;
 877     s/SSL3_READ_BYTES/ssl3_read_bytes/;
 878
 879     # gnutls version variances
 880     next if /^Error in the pull function./;
 881     }
 882
 883   # ======== stderr ========
 884
 885   elsif ($is_stderr)
 886     {
 887     # The very first line of debugging output will vary
 888
 889     s/^Exim version .*/Exim version x.yz ..../;
 890
 891     # Debugging lines for Exim terminations
 892
 893     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 894
 895     # IP address lookups use gethostbyname() when IPv6 is not supported,
 896     # and gethostbyname2() or getipnodebyname() when it is.
 897
 898     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 899
 900     # drop gnutls version strings
 901     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 902     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 903
 904     # drop openssl version strings
 905     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 906     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 907
 908     # drop lookups
 909     next if /^Lookups \(built-in\):/;
 910     next if /^Loading lookup modules from/;
 911     next if /^Loaded \d+ lookup modules/;
 912     next if /^Total \d+ lookups/;
 913
 914     # drop compiler information
 915     next if /^Compiler:/;
 916
 917     # and the ugly bit
 918     # different libraries will have different numbers (possibly 0) of follow-up
 919     # lines, indenting with more data
 920     if (/^Library version:/) {
 921       while (1) {
 922         $_ = <IN>;
 923         next if /^\s/;
 924         goto RESET_AFTER_EXTRA_LINE_READ;
 925       }
 926     }
 927
 928     # drop other build-time controls emitted for debugging
 929     next if /^WHITELIST_D_MACROS:/;
 930     next if /^TRUSTED_CONFIG_LIST:/;
 931
 932     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 933     # with -be, privileges will have been dropped, so this will always
 934     # be the case
 935     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 936
 937     # We might not keep this check; rather than change all the tests, just
 938     # ignore it as long as it succeeds; then we only need to change the
 939     # TLS tests where tls_require_ciphers has been set.
 940     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 941       my $discard = <IN>;
 942       next;
 943     }
 944     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 945
 946     # We invoke Exim with -D, so we hit this new messag as of Exim 4.73:
 947     next if /^macros_trusted overridden to true by whitelisting/;
 948
 949     # We have to omit the localhost ::1 address so that all is well in
 950     # the IPv4-only case.
 951
 952     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 953       if (/looked up these IP addresses/);
 954     next if /name=localhost address=::1/;
 955
 956     # drop pdkim debugging header
 957     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 958
 959     # Various other IPv6 lines must be omitted too
 960
 961     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 962     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 963     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 964     next if / in dns_ipv4_lookup?/;
 965
 966     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 967       {
 968       $_= <IN>;     # Gets "returning DNS_NODATA"
 969       next;
 970       }
 971
 972     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 973     # are unset, because tls ain't always there.
 974
 975     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
 976                 \sno\s\((option\sunset|end\sof\slist)\)/x;
 977
 978     # Skip auxiliary group lists because they will vary.
 979
 980     next if /auxiliary group list:/;
 981
 982     # Skip "extracted from gecos field" because the gecos field varies
 983
 984     next if /extracted from gecos field/;
 985
 986     # Skip "waiting for data on socket" and "read response data: size=" lines
 987     # because some systems pack more stuff into packets than others.
 988
 989     next if /waiting for data on socket/;
 990     next if /read response data: size=/;
 991
 992     # If Exim is compiled with readline support but it can't find the library
 993     # to load, there will be an extra debug line. Omit it.
 994
 995     next if /failed to load readline:/;
 996
 997     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
 998     # O_CREAT; other's don't. In the latter case there is some debugging output
 999     # which is not present in the former. Skip the relevant lines (there are
1000     # two of them).
1001
1002     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1003       {
1004       $_ = <IN>;
1005       next;
1006       }
1007
1008     # Some tests turn on +expand debugging to check on expansions.
1009     # Unfortunately, the Received: expansion varies, depending on whether TLS
1010     # is compiled or not. So we must remove the relevant debugging if it is.
1011
1012     if (/^condition: def:tls_cipher/)
1013       {
1014       while (<IN>) { last if /^condition: def:sender_address/; }
1015       }
1016     elsif (/^expanding: Received: /)
1017       {
1018       while (<IN>) { last if !/^\s/; }
1019       }
1020
1021     # remote port numbers vary
1022     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1023
1024     # Skip hosts_require_dane checks when the options
1025     # are unset, because dane ain't always there.
1026
1027     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1028
1029     # SUPPORT_PROXY
1030     next if /host in hosts_proxy\?/;
1031
1032     # Experimental_International
1033     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1034
1035     # Environment cleaning
1036     next if /\w+ in keep_environment\? (yes|no)/;
1037
1038     # Sizes vary with test hostname
1039     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1040
1041     # Spool filesystem free space changes on different systems.
1042     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1043
1044     # When Exim is checking the size of directories for maildir, it uses
1045     # the check_dir_size() function to scan directories. Of course, the order
1046     # of the files that are obtained using readdir() varies from system to
1047     # system. We therefore buffer up debugging lines from check_dir_size()
1048     # and sort them before outputting them.
1049
1050     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1051       {
1052       push @saved, $_;
1053       }
1054     else
1055       {
1056       if (@saved > 0)
1057         {
1058         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1059           "to ensure consistency\n";
1060         @saved = sort(@saved);
1061         print MUNGED @saved;
1062         @saved = ();
1063         }
1064
1065       # Skip some lines that Exim puts out at the start of debugging output
1066       # because they will be different in different binaries.
1067
1068       print MUNGED
1069         unless (/^Berkeley DB: / ||
1070                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1071                 /^Authenticators:/ ||
1072                 /^Lookups:/ ||
1073                 /^Support for:/ ||
1074                 /^Routers:/ ||
1075                 /^Transports:/ ||
1076                 /^log selectors =/ ||
1077                 /^cwd=/ ||
1078                 /^Fixed never_users:/ ||
1079                 /^Configure owner:/ ||
1080                 /^Size of off_t:/
1081                 );
1082
1083
1084       }
1085
1086     next;
1087     }
1088
1089   # ======== log ========
1090
1091   elsif ($is_log)
1092     {
1093     # Berkeley DB version differences
1094     next if / Berkeley DB error: /;
1095     }
1096
1097   # ======== All files other than stderr ========
1098
1099   print MUNGED;
1100   }
1101
1102 close(IN);
1103 return $yield;
1104 }
1105
1106
1107
1108
1109 ##################################################
1110 #        Subroutine to interact with caller      #
1111 ##################################################
1112
1113 # Arguments: [0] the prompt string
1114 #            [1] if there is a U in the prompt and $force_update is true
1115 #            [2] if there is a C in the prompt and $force_continue is true
1116 # Returns:   returns the answer
1117
1118 sub interact{
1119 print $_[0];
1120 if ($_[1]) { $_ = "u"; print "... update forced\n"; }
1121   elsif ($_[2]) { $_ = "c"; print "... continue forced\n"; }
1122   else { $_ = <T>; }
1123 }
1124
1125
1126
1127 ##################################################
1128 #    Subroutine to log in force_continue mode    #
1129 ##################################################
1130
1131 # In force_continue mode, we just want a terse output to a statically
1132 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1133 # all have mismatches, it will log multiple times.
1134 #
1135 # Arguments: [0] the logfile to append to
1136 #            [1] the testno that failed
1137 # Returns:   nothing
1138
1139
1140
1141 sub log_failure {
1142   my $logfile = shift();
1143   my $testno  = shift();
1144   my $detail  = shift() || '';
1145   if ( open(my $fh, ">>", $logfile) ) {
1146     print $fh "Test $testno $detail failed\n";
1147     close $fh;
1148   }
1149 }
1150
1151
1152
1153 ##################################################
1154 #    Subroutine to compare one output file       #
1155 ##################################################
1156
1157 # When an Exim server is part of the test, its output is in separate files from
1158 # an Exim client. The server data is concatenated with the client data as part
1159 # of the munging operation.
1160 #
1161 # Arguments:  [0] the name of the main raw output file
1162 #             [1] the name of the server raw output file or undef
1163 #             [2] where to put the munged copy
1164 #             [3] the name of the saved file
1165 #             [4] TRUE if this is a log file whose deliveries must be sorted
1166 #             [5] optionally, a custom munge command
1167 #
1168 # Returns:    0 comparison succeeded or differences to be ignored
1169 #             1 comparison failed; files may have been updated (=> re-compare)
1170 #
1171 # Does not return if the user replies "Q" to a prompt.
1172
1173 sub check_file{
1174 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1175
1176 # If there is no saved file, the raw files must either not exist, or be
1177 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1178
1179 # we check if there is a flavour specific file, but we remember
1180 # the original file name as "generic"
1181 $sf_generic = $sf;
1182 $sf_flavour = "$sf_generic.$flavour";
1183 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1184
1185 if (! -e $sf_current)
1186   {
1187   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1188
1189   print "\n";
1190   print "** $rf is not empty\n" if (-s $rf);
1191   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1192
1193   for (;;)
1194     {
1195     print "Continue, Show, or Quit? [Q] ";
1196     $_ = $force_continue ? "c" : <T>;
1197     tests_exit(1) if /^q?$/i;
1198     log_failure($log_failed_filename, $testno, $rf) if (/^c$/i && $force_continue);
1199     return 0 if /^c$/i;
1200     last if (/^s$/);
1201     }
1202
1203   foreach $f ($rf, $rsf)
1204     {
1205     if (defined $f && -s $f)
1206       {
1207       print "\n";
1208       print "------------ $f -----------\n"
1209         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1210       system("$more '$f'");
1211       }
1212     }
1213
1214   print "\n";
1215   for (;;)
1216     {
1217     interact("Continue, Update & retry, Quit? [Q] ", $force_update, $force_continue);
1218     tests_exit(1) if /^q?$/i;
1219     log_failure($log_failed_filename, $testno, $rsf) if (/^c$/i && $force_continue);
1220     return 0 if /^c$/i;
1221     last if (/^u$/i);
1222     }
1223   }
1224
1225 #### $_
1226
1227 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1228 # was a request to create a saved file. First, create the munged file from any
1229 # data that does exist.
1230
1231 open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1232 my($truncated) = munge($rf, $extra) if -e $rf;
1233 if (defined $rsf && -e $rsf)
1234   {
1235   print MUNGED "\n******** SERVER ********\n";
1236   $truncated |= munge($rsf, $extra);
1237   }
1238 close(MUNGED);
1239
1240 # If a saved file exists, do the comparison. There are two awkward cases:
1241 #
1242 # If "*** truncated ***" was found in the new file, it means that a log line
1243 # was overlong, and truncated. The problem is that it may be truncated at
1244 # different points on different systems, because of different user name
1245 # lengths. We reload the file and the saved file, and remove lines from the new
1246 # file that precede "*** truncated ***" until we reach one that matches the
1247 # line that precedes it in the saved file.
1248 #
1249 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1250 # for an individual message might vary in their order from system to system, as
1251 # a result of parallel deliveries. We load the munged file and sort sequences
1252 # of delivery lines.
1253
1254 if (-e $sf_current)
1255   {
1256   # Deal with truncated text items
1257
1258   if ($truncated)
1259     {
1260     my(@munged, @saved, $i, $j, $k);
1261
1262     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1263     @munged = <MUNGED>;
1264     close(MUNGED);
1265     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1266     @saved = <SAVED>;
1267     close(SAVED);
1268
1269     $j = 0;
1270     for ($i = 0; $i < @munged; $i++)
1271       {
1272       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1273         {
1274         for (; $j < @saved; $j++)
1275           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1276         last if $j >= @saved;     # not found in saved
1277
1278         for ($k = $i - 1; $k >= 0; $k--)
1279           { last if $munged[$k] eq $saved[$j - 1]; }
1280
1281         last if $k <= 0;          # failed to find previous match
1282         splice @munged, $k + 1, $i - $k - 1;
1283         $i = $k + 1;
1284         }
1285       }
1286
1287     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1288     for ($i = 0; $i < @munged; $i++)
1289       { print MUNGED $munged[$i]; }
1290     close(MUNGED);
1291     }
1292
1293   # Deal with log sorting
1294
1295   if ($sortfile)
1296     {
1297     my(@munged, $i, $j);
1298
1299     open(MUNGED, "$mf") || tests_exit(-1, "Failed to open $mf: $!");
1300     @munged = <MUNGED>;
1301     close(MUNGED);
1302
1303     for ($i = 0; $i < @munged; $i++)
1304       {
1305       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1306         {
1307         for ($j = $i + 1; $j < @munged; $j++)
1308           {
1309           last if $munged[$j] !~
1310             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1311           }
1312         @temp = splice(@munged, $i, $j - $i);
1313         @temp = sort(@temp);
1314         splice(@munged, $i, 0, @temp);
1315         }
1316       }
1317
1318     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1319     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1320     for ($i = 0; $i < @munged; $i++)
1321       { print MUNGED $munged[$i]; }
1322     close(MUNGED);
1323     }
1324
1325   # Do the comparison
1326
1327   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1328
1329   # Handle comparison failure
1330
1331   print "** Comparison of $mf with $sf_current failed";
1332   system("$more test-cf");
1333
1334   print "\n";
1335   for (;;)
1336     {
1337     interact("Continue, Retry, Update current"
1338         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : "")
1339         . " & retry, Quit? [Q] ", $force_update, $force_continue);
1340     tests_exit(1) if /^q?$/i;
1341     log_failure($log_failed_filename, $testno, $sf_current) if (/^c$/i && $force_continue);
1342     return 0 if /^c$/i;
1343     return 1 if /^r$/i;
1344     last if (/^[us]$/i);
1345     }
1346   }
1347
1348 # Update or delete the saved file, and give the appropriate return code.
1349
1350 if (-s $mf)
1351   {
1352         my $sf = /^u/i ? $sf_current : $sf_flavour;
1353                 tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1354   }
1355 else
1356   {
1357         # if we deal with a flavour file, we can't delete it, because next time the generic
1358         # file would be used again
1359         if ($sf_current eq $sf_flavour) {
1360                 open(FOO, ">$sf_current");
1361                 close(FOO);
1362         }
1363         else {
1364                 tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1365         }
1366   }
1367
1368 return 1;
1369 }
1370
1371
1372
1373 ##################################################
1374 # Custom munges
1375 # keyed by name of munge; value is a ref to a hash
1376 # which is keyed by file, value a string to look for.
1377 # Usable files are:
1378 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1379 # Search strings starting with 's' do substitutions;
1380 # with '/' do line-skips.
1381 # Triggered by a scriptfile line "munge <name>"
1382 ##################################################
1383 $munges =
1384   { 'dnssec' =>
1385     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1386
1387     'gnutls_unexpected' =>
1388     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1389
1390     'gnutls_handshake' =>
1391     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1392
1393     'optional_events' =>
1394     { 'stdout' => '/event_action =/' },
1395
1396     'optional_ocsp' =>
1397     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1398
1399     'optional_cert_hostnames' =>
1400     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1401
1402     'loopback' =>
1403     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1404
1405     'scanfile_size' =>
1406     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1407
1408     'delay_1500' =>
1409     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1410
1411     'tls_anycipher' =>
1412     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1413
1414     'debug_pid' =>
1415     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1416
1417     'optional_dsn_info' =>
1418     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1419     },
1420
1421     'optional_config' =>
1422     { 'stdout' => '/^(
1423                   dkim_(canon|domain|private_key|selector|sign_headers|strict)
1424                   |gnutls_require_(kx|mac|protocols)
1425                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1426                   |hosts_(avoid|nopass|require|verify_avoid)_tls
1427                   |socks_proxy
1428                   |tls_[^ ]*
1429                   )($|[ ]=)/x' },
1430
1431     'sys_bindir' =>
1432     { 'mainlog' => 's%/(usr/)?bin/%SYSBINDIR/%' },
1433
1434     'sync_check_data' =>
1435     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1436       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1437
1438     'debuglog_stdout' =>
1439     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1440                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1441     },
1442   };
1443
1444
1445 ##################################################
1446 #    Subroutine to check the output of a test    #
1447 ##################################################
1448
1449 # This function is called when the series of subtests is complete. It makes
1450 # use of check_file(), whose arguments are:
1451 #
1452 #  [0] the name of the main raw output file
1453 #  [1] the name of the server raw output file or undef
1454 #  [2] where to put the munged copy
1455 #  [3] the name of the saved file
1456 #  [4] TRUE if this is a log file whose deliveries must be sorted
1457 #  [5] an optional custom munge command
1458 #
1459 # Arguments: Optionally, name of a single custom munge to run.
1460 # Returns:   0 if the output compared equal
1461 #            1 if re-run needed (files may have been updated)
1462
1463 sub check_output{
1464 my($mungename) = $_[0];
1465 my($yield) = 0;
1466 my($munge) = $munges->{$mungename} if defined $mungename;
1467
1468 $yield = 1 if check_file("spool/log/paniclog",
1469                        "spool/log/serverpaniclog",
1470                        "test-paniclog-munged",
1471                        "paniclog/$testno", 0,
1472                        $munge->{'paniclog'});
1473
1474 $yield = 1 if check_file("spool/log/rejectlog",
1475                        "spool/log/serverrejectlog",
1476                        "test-rejectlog-munged",
1477                        "rejectlog/$testno", 0,
1478                        $munge->{'rejectlog'});
1479
1480 $yield = 1 if check_file("spool/log/mainlog",
1481                        "spool/log/servermainlog",
1482                        "test-mainlog-munged",
1483                        "log/$testno", $sortlog,
1484                        $munge->{'mainlog'});
1485
1486 if (!$stdout_skip)
1487   {
1488   $yield = 1 if check_file("test-stdout",
1489                        "test-stdout-server",
1490                        "test-stdout-munged",
1491                        "stdout/$testno", 0,
1492                        $munge->{'stdout'});
1493   }
1494
1495 if (!$stderr_skip)
1496   {
1497   $yield = 1 if check_file("test-stderr",
1498                        "test-stderr-server",
1499                        "test-stderr-munged",
1500                        "stderr/$testno", 0,
1501                        $munge->{'stderr'});
1502   }
1503
1504 # Compare any delivered messages, unless this test is skipped.
1505
1506 if (! $message_skip)
1507   {
1508   my($msgno) = 0;
1509
1510   # Get a list of expected mailbox files for this script. We don't bother with
1511   # directories, just the files within them.
1512
1513   foreach $oldmail (@oldmails)
1514     {
1515     next unless $oldmail =~ /^mail\/$testno\./;
1516     print ">> EXPECT $oldmail\n" if $debug;
1517     $expected_mails{$oldmail} = 1;
1518     }
1519
1520   # If there are any files in test-mail, compare them. Note that "." and
1521   # ".." are automatically omitted by list_files_below().
1522
1523   @mails = list_files_below("test-mail");
1524
1525   foreach $mail (@mails)
1526     {
1527     next if $mail eq "test-mail/oncelog";
1528
1529     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1530     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1531
1532     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1533       {
1534       $msgno++;
1535       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1536       }
1537
1538     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1539     $yield = 1 if check_file($mail, undef, "test-mail-munged",
1540       "mail/$testno.$saved_mail", 0,
1541       $munge->{'mail'});
1542     delete $expected_mails{"mail/$testno.$saved_mail"};
1543     }
1544
1545   # Complain if not all expected mails have been found
1546
1547   if (scalar(keys %expected_mails) != 0)
1548     {
1549     foreach $key (keys %expected_mails)
1550       { print "** no test file found for $key\n"; }
1551
1552     for (;;)
1553       {
1554       interact("Continue, Update & retry, or Quit? [Q] ", $force_update, $force_continue);
1555       tests_exit(1) if /^q?$/i;
1556       log_failure($log_failed_filename, $testno, "missing email") if (/^c$/i && $force_continue);
1557       last if /^c$/i;
1558
1559       # For update, we not only have to unlink the file, but we must also
1560       # remove it from the @oldmails vector, as otherwise it will still be
1561       # checked for when we re-run the test.
1562
1563       if (/^u$/i)
1564         {
1565         foreach $key (keys %expected_mails)
1566           {
1567           my($i);
1568           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1569           for ($i = 0; $i < @oldmails; $i++)
1570             {
1571             if ($oldmails[$i] eq $key)
1572               {
1573               splice @oldmails, $i, 1;
1574               last;
1575               }
1576             }
1577           }
1578         last;
1579         }
1580       }
1581     }
1582   }
1583
1584 # Compare any remaining message logs, unless this test is skipped.
1585
1586 if (! $msglog_skip)
1587   {
1588   # Get a list of expected msglog files for this test
1589
1590   foreach $oldmsglog (@oldmsglogs)
1591     {
1592     next unless $oldmsglog =~ /^$testno\./;
1593     $expected_msglogs{$oldmsglog} = 1;
1594     }
1595
1596   # If there are any files in spool/msglog, compare them. However, we have
1597   # to munge the file names because they are message ids, which are
1598   # time dependent.
1599
1600   if (opendir(DIR, "spool/msglog"))
1601     {
1602     @msglogs = sort readdir(DIR);
1603     closedir(DIR);
1604
1605     foreach $msglog (@msglogs)
1606       {
1607       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1608       ($munged_msglog = $msglog) =~
1609         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1610           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1611       $yield = 1 if check_file("spool/msglog/$msglog", undef,
1612         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1613         $munge->{'msglog'});
1614       delete $expected_msglogs{"$testno.$munged_msglog"};
1615       }
1616     }
1617
1618   # Complain if not all expected msglogs have been found
1619
1620   if (scalar(keys %expected_msglogs) != 0)
1621     {
1622     foreach $key (keys %expected_msglogs)
1623       {
1624       print "** no test msglog found for msglog/$key\n";
1625       ($msgid) = $key =~ /^\d+\.(.*)$/;
1626       foreach $cachekey (keys %cache)
1627         {
1628         if ($cache{$cachekey} eq $msgid)
1629           {
1630           print "** original msgid $cachekey\n";
1631           last;
1632           }
1633         }
1634       }
1635
1636     for (;;)
1637       {
1638       interact("Continue, Update, or Quit? [Q] ", $force_update, $force_continue);
1639       tests_exit(1) if /^q?$/i;
1640       log_failure($log_failed_filename, $testno, "missing msglog") if (/^c$/i && $force_continue);
1641       last if /^c$/i;
1642       if (/^u$/i)
1643         {
1644         foreach $key (keys %expected_msglogs)
1645           {
1646           tests_exit(-1, "Failed to unlink msglog/$key")
1647             if !unlink("msglog/$key");
1648           }
1649         last;
1650         }
1651       }
1652     }
1653   }
1654
1655 return $yield;
1656 }
1657
1658
1659
1660 ##################################################
1661 #     Subroutine to run one "system" command     #
1662 ##################################################
1663
1664 # We put this in a subroutine so that the command can be reflected when
1665 # debugging.
1666 #
1667 # Argument: the command to be run
1668 # Returns:  nothing
1669
1670 sub run_system {
1671 my($cmd) = $_[0];
1672 if ($debug)
1673   {
1674   my($prcmd) = $cmd;
1675   $prcmd =~ s/; /;\n>> /;
1676   print ">> $prcmd\n";
1677   }
1678 system("$cmd");
1679 }
1680
1681
1682
1683 ##################################################
1684 #      Subroutine to run one script command      #
1685 ##################################################
1686
1687 # The <SCRIPT> file is open for us to read an optional return code line,
1688 # followed by the command line and any following data lines for stdin. The
1689 # command line can be continued by the use of \. Data lines are not continued
1690 # in this way. In all lines, the following substutions are made:
1691 #
1692 # DIR    => the current directory
1693 # CALLER => the caller of this script
1694 #
1695 # Arguments: the current test number
1696 #            reference to the subtest number, holding previous value
1697 #            reference to the expected return code value
1698 #            reference to where to put the command name (for messages)
1699 #            auxilliary information returned from a previous run
1700 #
1701 # Returns:   0 the commmand was executed inline, no subprocess was run
1702 #            1 a non-exim command was run and waited for
1703 #            2 an exim command was run and waited for
1704 #            3 a command was run and not waited for (daemon, server, exim_lock)
1705 #            4 EOF was encountered after an initial return code line
1706 # Optionally alse a second parameter, a hash-ref, with auxilliary information:
1707 #            exim_pid: pid of a run process
1708 #            munge: name of a post-script results munger
1709
1710 sub run_command{
1711 my($testno) = $_[0];
1712 my($subtestref) = $_[1];
1713 my($commandnameref) = $_[3];
1714 my($aux_info) = $_[4];
1715 my($yield) = 1;
1716
1717 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1718
1719 if (/^(\d+)\s*$/)                # Handle unusual return code
1720   {
1721   my($r) = $_[2];
1722   $$r = $1 << 8;
1723   $_ = <SCRIPT>;
1724   return 4 if !defined $_;       # Missing command
1725   $lineno++;
1726   }
1727
1728 chomp;
1729 $wait_time = 0;
1730
1731 # Handle concatenated command lines
1732
1733 s/\s+$//;
1734 while (substr($_, -1) eq"\\")
1735   {
1736   my($temp);
1737   $_ = substr($_, 0, -1);
1738   chomp($temp = <SCRIPT>);
1739   if (defined $temp)
1740     {
1741     $lineno++;
1742     $temp =~ s/\s+$//;
1743     $temp =~ s/^\s+//;
1744     $_ .= $temp;
1745     }
1746   }
1747
1748 # Do substitutions
1749
1750 do_substitute($testno);
1751 if ($debug) { printf ">> $_\n"; }
1752
1753 # Pass back the command name (for messages)
1754
1755 ($$commandnameref) = /^(\S+)/;
1756
1757 # Here follows code for handling the various different commands that are
1758 # supported by this script. The first group of commands are all freestanding
1759 # in that they share no common code and are not followed by any data lines.
1760
1761
1762 ###################
1763 ###################
1764
1765 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1766 # utility and to make DBM files for testing DBM lookups.
1767
1768 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1769   {
1770   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1771          "echo exim_dbmbuild exit code = \$?)" .
1772          ">>test-stdout");
1773   return 1;
1774   }
1775
1776
1777 # The "dump" command runs exim_dumpdb. On different systems, the output for
1778 # some types of dump may appear in a different order because it's just hauled
1779 # out of the DBM file. We can solve this by sorting. Ignore the leading
1780 # date/time, as it will be flattened later during munging.
1781
1782 if (/^dump\s+(\S+)/)
1783   {
1784   my($which) = $1;
1785   my(@temp);
1786   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1787   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1788   open(OUT, ">>test-stdout");
1789   print OUT "+++++++++++++++++++++++++++\n";
1790
1791   if ($which eq "retry")
1792     {
1793     $/ = "\n  ";
1794     @temp = <IN>;
1795     $/ = "\n";
1796
1797     @temp = sort {
1798                    my($aa) = split(' ', $a);
1799                    my($bb) = split(' ', $b);
1800                    return $aa cmp $bb;
1801                  } @temp;
1802
1803     foreach $item (@temp)
1804       {
1805       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1806       print OUT "  $item\n";
1807       }
1808     }
1809   else
1810     {
1811     @temp = <IN>;
1812     if ($which eq "callout")
1813       {
1814       @temp = sort {
1815                    my($aa) = substr $a, 21;
1816                    my($bb) = substr $b, 21;
1817                    return $aa cmp $bb;
1818                    } @temp;
1819       }
1820     print OUT @temp;
1821     }
1822
1823   close(IN);
1824   close(OUT);
1825   return 1;
1826   }
1827
1828
1829 # The "echo" command is a way of writing comments to the screen.
1830
1831 if (/^echo\s+(.*)$/)
1832   {
1833   print "$1\n";
1834   return 0;
1835   }
1836
1837
1838 # The "exim_lock" command runs exim_lock in the same manner as "server",
1839 # but it doesn't use any input.
1840
1841 if (/^exim_lock\s+(.*)$/)
1842   {
1843   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1844   $server_pid = open SERVERCMD, "|$cmd" ||
1845     tests_exit(-1, "Failed to run $cmd\n");
1846
1847   # This gives the process time to get started; otherwise the next
1848   # process may not find it there when it expects it.
1849
1850   select(undef, undef, undef, 0.1);
1851   return 3;
1852   }
1853
1854
1855 # The "exinext" command runs exinext
1856
1857 if (/^exinext\s+(.*)/)
1858   {
1859   run_system("(./eximdir/exinext " .
1860     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1861     "-C $parm_cwd/test-config $1;" .
1862     "echo exinext exit code = \$?)" .
1863     ">>test-stdout");
1864   return 1;
1865   }
1866
1867
1868 # The "exigrep" command runs exigrep on the current mainlog
1869
1870 if (/^exigrep\s+(.*)/)
1871   {
1872   run_system("(./eximdir/exigrep " .
1873     "$1 $parm_cwd/spool/log/mainlog;" .
1874     "echo exigrep exit code = \$?)" .
1875     ">>test-stdout");
1876   return 1;
1877   }
1878
1879
1880 # The "eximstats" command runs eximstats on the current mainlog
1881
1882 if (/^eximstats\s+(.*)/)
1883   {
1884   run_system("(./eximdir/eximstats " .
1885     "$1 $parm_cwd/spool/log/mainlog;" .
1886     "echo eximstats exit code = \$?)" .
1887     ">>test-stdout");
1888   return 1;
1889   }
1890
1891
1892 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
1893 # spool directory, to save Exim from re-creating it each time.
1894
1895 if (/^gnutls/)
1896   {
1897   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
1898   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
1899          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
1900          "sudo chmod 0400 $gen_fn";
1901   return 1;
1902   }
1903
1904
1905 # The "killdaemon" command should ultimately follow the starting of any Exim
1906 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
1907 # it outputting "Terminated" to the terminal when not in the background.
1908
1909 if (/^killdaemon/)
1910   {
1911   my $return_extra = {};
1912   if (exists $aux_info->{exim_pid})
1913     {
1914     $pid = $aux_info->{exim_pid};
1915     $return_extra->{exim_pid} = undef;
1916     print ">> killdaemon: recovered pid $pid\n" if $debug;
1917     if ($pid)
1918       {
1919       run_system("sudo /bin/kill -INT $pid");
1920       wait;
1921       }
1922     } else {
1923     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
1924     if ($pid)
1925       {
1926       run_system("sudo /bin/kill -INT $pid");
1927       close DAEMONCMD;                                   # Waits for process
1928       }
1929     }
1930     run_system("sudo /bin/rm -f spool/exim-daemon.*");
1931   return (1, $return_extra);
1932   }
1933
1934
1935 # The "millisleep" command is like "sleep" except that its argument is in
1936 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
1937 # is used for.
1938
1939 elsif (/^millisleep\s+(.*)$/)
1940   {
1941   select(undef, undef, undef, $1/1000);
1942   return 0;
1943   }
1944
1945
1946 # The "munge" command selects one of a hardwired set of test-result modifications
1947 # to be made before result compares are run agains the golden set.  This lets
1948 # us account for test-system dependent things which only affect a few, but known,
1949 # test-cases.
1950 # Currently only the last munge takes effect.
1951
1952 if (/^munge\s+(.*)$/)
1953   {
1954   return (0, { munge => $1 });
1955   }
1956
1957
1958 # The "sleep" command does just that. For sleeps longer than 1 second we
1959 # tell the user what's going on.
1960
1961 if (/^sleep\s+(.*)$/)
1962   {
1963   if ($1 == 1)
1964     {
1965     sleep(1);
1966     }
1967   else
1968     {
1969     printf("  Test %d sleep $1 ", $$subtestref);
1970     for (1..$1)
1971       {
1972       print ".";
1973       sleep(1);
1974       }
1975     printf("\r  Test %d                            $cr", $$subtestref);
1976     }
1977   return 0;
1978   }
1979
1980
1981 # Various Unix management commands are recognized
1982
1983 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
1984     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
1985   {
1986   run_system("$_ >>test-stdout 2>>test-stderr");
1987   return 1;
1988   }
1989
1990
1991
1992 ###################
1993 ###################
1994
1995 # The next group of commands are also freestanding, but they are all followed
1996 # by data lines.
1997
1998
1999 # The "server" command starts up a script-driven server that runs in parallel
2000 # with the following exim command. Therefore, we want to run a subprocess and
2001 # not yet wait for it to complete. The waiting happens after the next exim
2002 # command, triggered by $server_pid being non-zero. The server sends its output
2003 # to a different file. The variable $server_opts, if not empty, contains
2004 # options to disable IPv4 or IPv6 if necessary.
2005 # This works because "server" swallows its stdin before waiting for a connection.
2006
2007 if (/^server\s+(.*)$/)
2008   {
2009   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2010   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2011   print ">> $cmd\n" if ($debug);
2012   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2013   SERVERCMD->autoflush(1);
2014   print ">> Server pid is $server_pid\n" if $debug;
2015   while (<SCRIPT>)
2016     {
2017     $lineno++;
2018     last if /^\*{4}\s*$/;
2019     print SERVERCMD;
2020     }
2021   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2022                             # because close() waits for the process.
2023
2024   # Interlock the server startup; otherwise the next
2025   # process may not find it there when it expects it.
2026   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2027   return 3;
2028   }
2029
2030
2031 # The "write" command is a way of creating files of specific sizes for
2032 # buffering tests, or containing specific data lines from within the script
2033 # (rather than hold lots of little files). The "catwrite" command does the
2034 # same, but it also copies the lines to test-stdout.
2035
2036 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2037   {
2038   my($cat) = defined $1;
2039   @sizes = ();
2040   @sizes = split /\s+/, $3 if defined $3;
2041   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2042
2043   if ($cat)
2044     {
2045     open CAT, ">>test-stdout" ||
2046       tests_exit(-1, "Failed to open test-stdout: $!");
2047     print CAT "==========\n";
2048     }
2049
2050   if (scalar @sizes > 0)
2051     {
2052     # Pre-data
2053
2054     while (<SCRIPT>)
2055       {
2056       $lineno++;
2057       last if /^\+{4}\s*$/;
2058       print FILE;
2059       print CAT if $cat;
2060       }
2061
2062     # Sized data
2063
2064     while (scalar @sizes > 0)
2065       {
2066       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2067       $leadin = "" if !defined $leadin;
2068       $leadin =~ s/_/ /g;
2069       $len -= length($leadin) + 1;
2070       while ($count-- > 0)
2071         {
2072         print FILE $leadin, "a" x $len, "\n";
2073         print CAT $leadin, "a" x $len, "\n" if $cat;
2074         }
2075       }
2076     }
2077
2078   # Post data, or only data if no sized data
2079
2080   while (<SCRIPT>)
2081     {
2082     $lineno++;
2083     last if /^\*{4}\s*$/;
2084     print FILE;
2085     print CAT if $cat;
2086     }
2087   close FILE;
2088
2089   if ($cat)
2090     {
2091     print CAT "==========\n";
2092     close CAT;
2093     }
2094
2095   return 0;
2096   }
2097
2098
2099 ###################
2100 ###################
2101
2102 # From this point on, script commands are implemented by setting up a shell
2103 # command in the variable $cmd. Shared code to run this command and handle its
2104 # input and output follows.
2105
2106 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2107 # program that plays the part of an email client. We also have the availability
2108 # of running Perl for doing one-off special things. Note that all these
2109 # commands expect stdin data to be supplied.
2110
2111 if (/^client/ || /^(sudo\s+)?perl\b/)
2112   {
2113   s"client"./bin/client";
2114   $cmd = "$_ >>test-stdout 2>>test-stderr";
2115   }
2116
2117 # For the "exim" command, replace the text "exim" with the path for the test
2118 # binary, plus -D options to pass over various parameters, and a -C option for
2119 # the testing configuration file. When running in the test harness, Exim does
2120 # not drop privilege when -C and -D options are present. To run the exim
2121 # command as root, we use sudo.
2122
2123 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2124   {
2125   $args = $6;
2126   my($envset) = (defined $1)? $1      : "";
2127   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":"")  : "";
2128   my($special)= (defined $5)? $5      : "";
2129   $wait_time  = (defined $2)? $2      : 0;
2130
2131   # Return 2 rather than 1 afterwards
2132
2133   $yield = 2;
2134
2135   # Update the test number
2136
2137   $$subtestref = $$subtestref + 1;
2138   printf("  Test %d       $cr", $$subtestref);
2139
2140   # Copy the configuration file, making the usual substitutions.
2141
2142   open (IN, "$parm_cwd/confs/$testno") ||
2143     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2144   open (OUT, ">test-config") ||
2145     tests_exit(-1, "Couldn't open test-config: $!\n");
2146   while (<IN>)
2147     {
2148     do_substitute($testno);
2149     print OUT;
2150     }
2151   close(IN);
2152   close(OUT);
2153
2154   # The string $msg1 in args substitutes the message id of the first
2155   # message on the queue, and so on. */
2156
2157   if ($args =~ /\$msg/)
2158     {
2159     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
2160                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2161                    "-C $parm_cwd/test-config |";
2162     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
2163     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
2164     my(@msglist) = ();
2165     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
2166     close(QLIST);
2167
2168     # Done backwards just in case there are more than 9
2169
2170     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2171     if ( $args =~ /\$msg\d/ )
2172       {
2173       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2174         unless $force_continue;
2175       }
2176     }
2177
2178   # If -d is specified in $optargs, remove it from $args; i.e. let
2179   # the command line for runtest override. Then run Exim.
2180
2181   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2182
2183   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : "";
2184
2185   $cmd = "$envset$sudo$opt_valgrind" .
2186          "$parm_cwd/eximdir/exim$special$optargs " .
2187          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2188          "-C $parm_cwd/test-config $args " .
2189          ">>test-stdout 2>>test-stderr";
2190   # If the command is starting an Exim daemon, we run it in the same
2191   # way as the "server" command above, that is, we don't want to wait
2192   # for the process to finish. That happens when "killdaemon" is obeyed later
2193   # in the script. We also send the stderr output to test-stderr-server. The
2194   # daemon has its log files put in a different place too (by configuring with
2195   # log_file_path). This requires the  directory to be set up in advance.
2196   #
2197   # There are also times when we want to run a non-daemon version of Exim
2198   # (e.g. a queue runner) with the server configuration. In this case,
2199   # we also define -DNOTDAEMON.
2200
2201   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2202     {
2203     $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2204     if ($debug) { printf ">> daemon: $cmd\n"; }
2205     run_system("sudo mkdir spool/log 2>/dev/null");
2206     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2207
2208     # Before running the command, convert the -bd option into -bdf so that an
2209     # Exim daemon doesn't double fork. This means that when we wait close
2210     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2211     # file is written to the spool directory, in case the Exim binary was
2212     # built with PID_FILE_PATH pointing somewhere else.
2213
2214     if ($cmd =~ /\s-oP\s/)
2215       {
2216       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2217       $cmd =~ s!\s-bd\s! -bdf !;
2218       }
2219     else
2220       {
2221       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2222       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2223       }
2224     print ">> |${cmd}-server\n" if ($debug);
2225     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2226     DAEMONCMD->autoflush(1);
2227     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2228
2229     # Interlock with daemon startup
2230     while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2231     return 3;                                     # Don't wait
2232     }
2233   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2234     {
2235
2236     # The port and the $dynamic_socket was already allocated while parsing the
2237     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2238
2239     my $listen_port = $1;
2240     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2241     run_system("sudo mkdir spool/log 2>/dev/null");
2242     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2243
2244     my $pid = fork();
2245     if (not defined $pid) { die "** fork failed: $!\n" }
2246     if (not $pid) {
2247       close(STDIN);
2248       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2249       close($dynamic_socket);
2250       print "[$$]>> ${cmd}-server\n" if ($debug);
2251       exec "exec ${cmd}-server";
2252       die "Can't exec ${cmd}-server: $!\n";
2253     }
2254     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2255     select(undef, undef, undef, 0.3);             # Let the daemon get going
2256     return (3, { exim_pid => $pid });             # Don't wait
2257     }
2258   }
2259
2260 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2261 # One script line is read and fork-exec'd.  The PID is stored for a later
2262 # killdaemon.
2263
2264 elsif (/^background$/)
2265   {
2266   my $line;
2267 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2268
2269   $_ = <SCRIPT>; $lineno++;
2270   chomp;
2271   $line = $_;
2272   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2273
2274   my $pid = fork();
2275   if (not defined $pid) { die "** fork failed: $!\n" }
2276   if (not $pid) {
2277     print "[$$]>> ${line}\n" if ($debug);
2278     close(STDIN);
2279     open(STDIN, "<", "test-stdout");
2280     close(STDOUT);
2281     open(STDOUT, ">>", "test-stdout");
2282     close(STDERR);
2283     open(STDERR, ">>", "test-stderr-server");
2284     exec "exec ${line}";
2285     exit(1);
2286   }
2287
2288 #  open(my $fh, ">", $pidfile) ||
2289 #      tests_exit(-1, "Failed to open $pidfile: $!");
2290 #  printf($fh, "%d\n", $pid);
2291 #  close($fh);
2292
2293   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2294   select(undef, undef, undef, 0.3);             # Let the daemon get going
2295   return (3, { exim_pid => $pid });             # Don't wait
2296   }
2297
2298
2299
2300 # Unknown command
2301
2302 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2303
2304
2305 # Run the command, with stdin connected to a pipe, and write the stdin data
2306 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2307 # the terminating newline (and the \NONL\). If the command contains
2308 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2309 # for the stderr file. See comment above about the use of -DSERVER.
2310
2311 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : "";
2312 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2313 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2314
2315 CMD->autoflush(1);
2316 while (<SCRIPT>)
2317   {
2318   $lineno++;
2319   last if /^\*{4}\s*$/;
2320   do_substitute($testno);
2321   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2322   }
2323
2324 # For timeout tests, wait before closing the pipe; we expect a
2325 # SIGPIPE error in this case.
2326
2327 if ($wait_time > 0)
2328   {
2329   printf("  Test %d sleep $wait_time ", $$subtestref);
2330   while ($wait_time-- > 0)
2331     {
2332     print ".";
2333     sleep(1);
2334     }
2335   printf("\r  Test %d                                       $cr", $$subtestref);
2336   }
2337
2338 $sigpipehappened = 0;
2339 close CMD;                # Waits for command to finish
2340 return $yield;            # Ran command and waited
2341 }
2342
2343
2344
2345
2346 ###############################################################################
2347 ###############################################################################
2348
2349 # Here begins the Main Program ...
2350
2351 ###############################################################################
2352 ###############################################################################
2353
2354
2355 autoflush STDOUT 1;
2356 print "Exim tester $testversion\n";
2357
2358 # extend the PATH with .../sbin
2359 # we map all (.../bin) to (.../sbin:.../bin)
2360 $ENV{PATH} = do {
2361   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2362   join ':' => map { m{(.*)/bin$}
2363                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2364                 : ($_) }
2365       split /:/, $ENV{PATH};
2366 };
2367
2368 ##################################################
2369 #      Some tests check created file modes       #
2370 ##################################################
2371
2372 umask 022;
2373
2374
2375 ##################################################
2376 #       Check for the "less" command             #
2377 ##################################################
2378
2379 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2380
2381
2382
2383 ##################################################
2384 #        Check for sudo access to root           #
2385 ##################################################
2386
2387 print "You need to have sudo access to root to run these tests. Checking ...\n";
2388 if (system('sudo true >/dev/null') != 0)
2389   {
2390   die "** Test for sudo failed: testing abandoned.\n";
2391   }
2392 else
2393   {
2394   print "Test for sudo OK\n";
2395   }
2396
2397
2398
2399 ##################################################
2400 #      See if an Exim binary has been given      #
2401 ##################################################
2402
2403 # If the first character of the first argument is '/', the argument is taken
2404 # as the path to the binary. If the first argument does not start with a
2405 # '/' but exists in the file system, it's assumed to be the Exim binary.
2406
2407 $parm_exim = (@ARGV > 0 && (-x $ARGV[0] or $ARGV[0] =~ m?^/?))? Cwd::abs_path(shift @ARGV) : "";
2408 print "Exim binary is $parm_exim\n" if $parm_exim ne "";
2409
2410
2411
2412 ##################################################
2413 # Sort out options and which tests are to be run #
2414 ##################################################
2415
2416 # There are a few possible options for the test script itself; after these, any
2417 # options are passed on to Exim calls within the tests. Typically, this is used
2418 # to turn on Exim debugging while setting up a test.
2419
2420 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2421   {
2422   my($arg) = shift @ARGV;
2423   if ($optargs eq "")
2424     {
2425     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2426     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2427     if ($arg eq "-CONTINUE"){$force_continue = 1;
2428                              $more = "cat";
2429                              next; }
2430     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2431     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2432     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2433     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2434     if ($arg eq "-VALGRIND")   { $valgrind = 1; next; }
2435     if ($arg =~ /^-FLAVOU?R$/) { $flavour = shift; next; }
2436     }
2437   $optargs .= " $arg";
2438   }
2439
2440 # Any subsequent arguments are a range of test numbers.
2441
2442 if (@ARGV > 0)
2443   {
2444   $test_end = $test_start = $ARGV[0];
2445   $test_end = $ARGV[1] if (@ARGV > 1);
2446   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2447     if $test_end eq "+";
2448   die "** Test numbers out of order\n" if ($test_end < $test_start);
2449   }
2450
2451
2452 ##################################################
2453 #      Make the command's directory current      #
2454 ##################################################
2455
2456 # After doing so, we find its absolute path name.
2457
2458 $cwd = $0;
2459 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2460 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2461 $parm_cwd = Cwd::getcwd();
2462
2463
2464 ##################################################
2465 #     Search for an Exim binary to test          #
2466 ##################################################
2467
2468 # If an Exim binary hasn't been provided, try to find one. We can handle the
2469 # case where exim-testsuite is installed alongside Exim source directories. For
2470 # PH's private convenience, if there's a directory just called "exim4", that
2471 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2472 # releases.
2473
2474 if ($parm_exim eq "")
2475   {
2476   my($use_srcdir) = "";
2477
2478   opendir DIR, ".." || die "** Failed to opendir \"..\": $!\n";
2479   while ($f = readdir(DIR))
2480     {
2481     my($srcdir);
2482
2483     # Try this directory if it is "exim4" or if it is exim-snapshot or exim-n.m
2484     # possibly followed by -RCx where n.m is greater than any previously tried
2485     # directory. Thus, we should choose the highest version of Exim that has
2486     # been compiled.
2487
2488     if ($f eq "exim4" || $f eq "exim-snapshot" || $f eq 'src')
2489       { $srcdir = $f; }
2490     else
2491       { $srcdir = $f
2492         if ($f =~ /^exim-\d+\.\d+(-RC\d+)?$/ && $f gt $use_srcdir); }
2493
2494     # Look for a build directory with a binary in it. If we find a binary,
2495     # accept this source directory.
2496
2497     if ($srcdir)
2498       {
2499       opendir SRCDIR, "../$srcdir" ||
2500         die "** Failed to opendir \"$cwd/../$srcdir\": $!\n";
2501       while ($f = readdir(SRCDIR))
2502         {
2503         if ($f =~ /^build-/ && -e "../$srcdir/$f/exim")
2504           {
2505           $use_srcdir = $srcdir;
2506           $parm_exim = "$cwd/../$srcdir/$f/exim";
2507           $parm_exim =~ s'/[^/]+/\.\./'/';
2508           last;
2509           }
2510         }
2511       closedir(SRCDIR);
2512       }
2513
2514     # If we have found "exim4" or "exim-snapshot", that takes precedence.
2515     # Otherwise, continue to see if there's a later version.
2516
2517     last if $use_srcdir eq "exim4" || $use_srcdir eq "exim-snapshot";
2518     }
2519   closedir(DIR);
2520   print "Exim binary found in $parm_exim\n" if $parm_exim ne "";
2521   }
2522
2523 # If $parm_exim is still empty, ask the caller
2524
2525 if ($parm_exim eq "")
2526   {
2527   print "** Did not find an Exim binary to test\n";
2528   for ($i = 0; $i < 5; $i++)
2529     {
2530     my($trybin);
2531     print "** Enter pathname for Exim binary: ";
2532     chomp($trybin = <STDIN>);
2533     if (-e $trybin)
2534       {
2535       $parm_exim = $trybin;
2536       last;
2537       }
2538     else
2539       {
2540       print "** $trybin does not exist\n";
2541       }
2542     }
2543   die "** Too many tries\n" if $parm_exim eq "";
2544   }
2545
2546
2547
2548 ##################################################
2549 #          Find what is in the binary            #
2550 ##################################################
2551
2552 # deal with TRUSTED_CONFIG_LIST restrictions
2553 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2554 open (IN, "$parm_cwd/confs/0000") ||
2555   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2556 open (OUT, ">test-config") ||
2557   tests_exit(-1, "Couldn't open test-config: $!\n");
2558 while (<IN>) { print OUT; }
2559 close(IN);
2560 close(OUT);
2561
2562 print("Probing with config file: $parm_cwd/test-config\n");
2563 open(EXIMINFO, "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd " .
2564                "-bP exim_user exim_group 2>&1|") ||
2565   die "** Cannot run $parm_exim: $!\n";
2566 while(<EXIMINFO>)
2567   {
2568   if (my ($version) = /^Exim version (\S+)/) {
2569     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2570     if (defined $git and $? == 0) {
2571       chomp $git;
2572       $version =~ s/^\d+\K\./_/;
2573       $git =~ s/^exim-//i;
2574       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2575       print "\n*** Version mismatch (Exim: $version vs. GIT: $git). ***\n\n"
2576         if not $version eq $git;
2577     }
2578   }
2579   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2580   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2581   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2582   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2583         if /^Configure owner:\s*(\d+):(\d+)/;
2584   print "$_" if /wrong owner/;
2585   }
2586 close(EXIMINFO);
2587
2588 if (defined $parm_eximuser)
2589   {
2590   if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2591     else { $parm_exim_uid = getpwnam($parm_eximuser); }
2592   }
2593 else
2594   {
2595   print "Unable to extract exim_user from binary.\n";
2596   print "Check if Exim refused to run; if so, consider:\n";
2597   print "  TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS\n";
2598   die "Failing to get information from binary.\n";
2599   }
2600
2601 if (defined $parm_eximgroup)
2602   {
2603   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2604     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2605   }
2606
2607 # check the permissions on the TRUSTED_CONFIG_LIST
2608 if (defined $parm_trusted_config_list)
2609   {
2610   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2611     if not -f $parm_trusted_config_list;
2612
2613   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2614     if 02 & (stat _)[2];
2615
2616   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2617   (stat _)[1],
2618     scalar(getgrgid 0), scalar(getgrgid $>)
2619     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2620
2621   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2622   scalar(getpwuid 0), scalar(getpwuid $>)
2623      if (not (-o _ or (stat _)[4] == 0));
2624
2625   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2626   my $test_config = getcwd() . '/test-config';
2627   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2628   if not grep { /^$test_config$/ } <TCL>;
2629   }
2630 else
2631   {
2632   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2633   }
2634
2635 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2636         if $parm_configure_owner != $>;
2637
2638 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2639         if 0020 & (stat "$parm_cwd/test-config")[2]
2640         and $parm_configure_group != $);
2641
2642
2643 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2644   die "** Cannot run $parm_exim: $!\n";
2645
2646 print "-" x 78, "\n";
2647
2648 while (<EXIMINFO>)
2649   {
2650   my(@temp);
2651
2652   if (/^(Exim|Library) version/) { print; }
2653
2654   elsif (/^Size of off_t: (\d+)/)
2655     {
2656     print;
2657     $have_largefiles = 1 if $1 > 4;
2658     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2659         if ($1 > 32);
2660     }
2661
2662   elsif (/^Support for: (.*)/)
2663     {
2664     print;
2665     @temp = split /(\s+)/, $1;
2666     push(@temp, ' ');
2667     %parm_support = @temp;
2668     }
2669
2670   elsif (/^Lookups \(built-in\): (.*)/)
2671     {
2672     print;
2673     @temp = split /(\s+)/, $1;
2674     push(@temp, ' ');
2675     %parm_lookups = @temp;
2676     }
2677
2678   elsif (/^Authenticators: (.*)/)
2679     {
2680     print;
2681     @temp = split /(\s+)/, $1;
2682     push(@temp, ' ');
2683     %parm_authenticators = @temp;
2684     }
2685
2686   elsif (/^Routers: (.*)/)
2687     {
2688     print;
2689     @temp = split /(\s+)/, $1;
2690     push(@temp, ' ');
2691     %parm_routers = @temp;
2692     }
2693
2694   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2695   # that the basic transport name is set, and then the name with each of the
2696   # options.
2697
2698   elsif (/^Transports: (.*)/)
2699     {
2700     print;
2701     @temp = split /(\s+)/, $1;
2702     my($i,$k);
2703     push(@temp, ' ');
2704     %parm_transports = @temp;
2705     foreach $k (keys %parm_transports)
2706       {
2707       if ($k =~ "/")
2708         {
2709         @temp = split /\//, $k;
2710         $parm_transports{"$temp[0]"} = " ";
2711         for ($i = 1; $i < @temp; $i++)
2712           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2713         }
2714       }
2715     }
2716   }
2717 close(EXIMINFO);
2718 print "-" x 78, "\n";
2719
2720 unlink("$parm_cwd/test-config");
2721
2722 ##################################################
2723 #    Check for SpamAssassin and ClamAV           #
2724 ##################################################
2725
2726 # These are crude tests. If they aren't good enough, we'll have to improve
2727 # them, for example by actually passing a message through spamc or clamscan.
2728
2729 if (defined $parm_support{'Content_Scanning'})
2730   {
2731   my $sock = new FileHandle;
2732
2733   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2734     {
2735     print "The spamc command works:\n";
2736
2737     # This test for an active SpamAssassin is courtesy of John Jetmore.
2738     # The tests are hard coded to localhost:783, so no point in making
2739     # this test flexible like the clamav test until the test scripts are
2740     # changed.  spamd doesn't have the nice PING/PONG protoccol that
2741     # clamd does, but it does respond to errors in an informative manner,
2742     # so use that.
2743
2744     my($sint,$sport) = ('127.0.0.1',783);
2745     eval
2746       {
2747       my $sin = sockaddr_in($sport, inet_aton($sint))
2748           or die "** Failed packing $sint:$sport\n";
2749       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2750           or die "** Unable to open socket $sint:$sport\n";
2751
2752       local $SIG{ALRM} =
2753           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2754       alarm(5);
2755       connect($sock, $sin)
2756           or die "** Unable to connect to socket $sint:$sport\n";
2757       alarm(0);
2758
2759       select((select($sock), $| = 1)[0]);
2760       print $sock "bad command\r\n";
2761
2762       $SIG{ALRM} =
2763           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2764       alarm(10);
2765       my $res = <$sock>;
2766       alarm(0);
2767
2768       $res =~ m|^SPAMD/|
2769           or die "** Did not get SPAMD from socket $sint:$sport. "
2770                 ."It said: $res\n";
2771       };
2772     alarm(0);
2773     if($@)
2774       {
2775       print "  $@";
2776       print "  Assume SpamAssassin (spamd) is not running\n";
2777       }
2778     else
2779       {
2780       $parm_running{'SpamAssassin'} = ' ';
2781       print "  SpamAssassin (spamd) seems to be running\n";
2782       }
2783     }
2784   else
2785     {
2786     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2787     }
2788
2789   # For ClamAV, we need to find the clamd socket for use in the Exim
2790   # configuration. Search for the clamd configuration file.
2791
2792   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2793     {
2794     my($f, $clamconf, $test_prefix);
2795
2796     print "The clamscan command works";
2797
2798     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2799     $test_prefix = "" if !defined $test_prefix;
2800
2801     foreach $f ("$test_prefix/etc/clamd.conf",
2802                 "$test_prefix/usr/local/etc/clamd.conf",
2803                 "$test_prefix/etc/clamav/clamd.conf", "")
2804       {
2805       if (-e $f)
2806         {
2807         $clamconf = $f;
2808         last;
2809         }
2810       }
2811
2812     # Read the ClamAV configuration file and find the socket interface.
2813
2814     if ($clamconf ne "")
2815       {
2816       my $socket_domain;
2817       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2818       while (<IN>)
2819         {
2820         if (/^LocalSocket\s+(.*)/)
2821           {
2822           $parm_clamsocket = $1;
2823           $socket_domain = AF_UNIX;
2824           last;
2825           }
2826         if (/^TCPSocket\s+(\d+)/)
2827           {
2828           if (defined $parm_clamsocket)
2829             {
2830             $parm_clamsocket .= " $1";
2831             $socket_domain = AF_INET;
2832             last;
2833             }
2834           else
2835             {
2836             $parm_clamsocket = " $1";
2837             }
2838           }
2839         elsif (/^TCPAddr\s+(\S+)/)
2840           {
2841           if (defined $parm_clamsocket)
2842             {
2843             $parm_clamsocket = $1 . $parm_clamsocket;
2844             $socket_domain = AF_INET;
2845             last;
2846             }
2847           else
2848             {
2849             $parm_clamsocket = $1;
2850             }
2851           }
2852         }
2853       close(IN);
2854
2855       if (defined $socket_domain)
2856         {
2857         print ":\n  The clamd socket is $parm_clamsocket\n";
2858         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2859         eval
2860           {
2861           my $socket;
2862           if ($socket_domain == AF_UNIX)
2863             {
2864             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2865             }
2866           elsif ($socket_domain == AF_INET)
2867             {
2868             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2869             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2870             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2871             }
2872           else
2873             {
2874             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2875             }
2876           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2877           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2878           alarm(5);
2879           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2880           alarm(0);
2881
2882           my $ofh = select $sock; $| = 1; select $ofh;
2883           print $sock "PING\n";
2884
2885           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2886           alarm(10);
2887           my $res = <$sock>;
2888           alarm(0);
2889
2890           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2891           };
2892         alarm(0);
2893
2894         if($@)
2895           {
2896           print "  $@";
2897           print "  Assume ClamAV is not running\n";
2898           }
2899         else
2900           {
2901           $parm_running{'ClamAV'} = ' ';
2902           print "  ClamAV seems to be running\n";
2903           }
2904         }
2905       else
2906         {
2907         print ", but the socket for clamd could not be determined\n";
2908         print "Assume ClamAV is not running\n";
2909         }
2910       }
2911
2912     else
2913       {
2914       print ", but I can't find a configuration for clamd\n";
2915       print "Assume ClamAV is not running\n";
2916       }
2917     }
2918   }
2919
2920
2921 ##################################################
2922 #       Check for redis                          #
2923 ##################################################
2924 if (defined $parm_lookups{'redis'})
2925   {
2926   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
2927     {
2928     print "The redis-server command works\n";
2929     $parm_running{'redis'} = ' ';
2930     }
2931   else
2932     {
2933     print "The redis-server command failed: assume Redis not installed\n";
2934     }
2935   }
2936
2937 ##################################################
2938 #         Test for the basic requirements        #
2939 ##################################################
2940
2941 # This test suite assumes that Exim has been built with at least the "usual"
2942 # set of routers, transports, and lookups. Ensure that this is so.
2943
2944 $missing = "";
2945
2946 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{'lsearch'});
2947
2948 $missing .= "     Router: accept\n" if (!defined $parm_routers{'accept'});
2949 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{'dnslookup'});
2950 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{'manualroute'});
2951 $missing .= "     Router: redirect\n" if (!defined $parm_routers{'redirect'});
2952
2953 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{'appendfile'});
2954 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{'autoreply'});
2955 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{'pipe'});
2956 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{'smtp'});
2957
2958 if ($missing ne "")
2959   {
2960   print "\n";
2961   print "** Many features can be included or excluded from Exim binaries.\n";
2962   print "** This test suite requires that Exim is built to contain a certain\n";
2963   print "** set of basic facilities. It seems that some of these are missing\n";
2964   print "** from the binary that is under test, so the test cannot proceed.\n";
2965   print "** The missing facilities are:\n";
2966   print "$missing";
2967   die "** Test script abandoned\n";
2968   }
2969
2970
2971 ##################################################
2972 #      Check for the auxiliary programs          #
2973 ##################################################
2974
2975 # These are always required:
2976
2977 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
2978            "fakens", "iefbr14", "server")
2979   {
2980   next if ($prog eq "client-ssl" && !defined $parm_support{'OpenSSL'});
2981   next if ($prog eq "client-gnutls" && !defined $parm_support{'GnuTLS'});
2982   if (!-e "bin/$prog")
2983     {
2984     print "\n";
2985     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
2986     die "** Test script abandoned\n";
2987     }
2988   }
2989
2990 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
2991 # compiled on systems where we don't know how to. However, if Exim does not
2992 # have that functionality compiled, we needn't bother.
2993
2994 $dlfunc_deleted = 0;
2995 if (defined $parm_support{'Expand_dlfunc'} && !-e "bin/loaded")
2996   {
2997   delete $parm_support{'Expand_dlfunc'};
2998   $dlfunc_deleted = 1;
2999   }
3000
3001
3002 ##################################################
3003 #          Find environmental details            #
3004 ##################################################
3005
3006 # Find the caller of this program.
3007
3008 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3009  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3010
3011 $pwpw = $pwpw;       # Kill Perl warnings
3012 $pwquota = $pwquota;
3013 $pwcomm = $pwcomm;
3014
3015 $parm_caller_group = getgrgid($parm_caller_gid);
3016
3017 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3018 print "Home directory is $parm_caller_home\n";
3019
3020 unless (defined $parm_eximgroup)
3021   {
3022   print "Unable to derive \$parm_eximgroup.\n";
3023   die "** ABANDONING.\n";
3024   }
3025
3026 print "You need to be in the Exim group to run these tests. Checking ...";
3027
3028 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3029   {
3030   print " OK\n";
3031   }
3032 else
3033   {
3034   print "\nOh dear, you are not in the Exim group.\n";
3035   die "** Testing abandoned.\n";
3036   }
3037
3038 # Find this host's IP addresses - there may be many, of course, but we keep
3039 # one of each type (IPv4 and IPv6).
3040
3041 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3042   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3043 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3044   {
3045   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3046     {
3047     next if $1 =~ /^(?:127|10)\./;
3048     $parm_ipv4 = $1;
3049     }
3050
3051   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3052     {
3053     next if $1 eq '::1' or $1 =~ /^fe80/i;
3054     $parm_ipv6 = $1;
3055     }
3056   }
3057 close(IFCONFIG);
3058
3059 # Use private IP addresses if there are no public ones.
3060
3061 # If either type of IP address is missing, we need to set the value to
3062 # something other than empty, because that wrecks the substitutions. The value
3063 # is reflected, so use a meaningful string. Set appropriate options for the
3064 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3065 # available, so things will go wrong if there is no IPv4 address. The lack
3066 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3067 # and $have_ipv6 false.
3068
3069 if (not $parm_ipv4)
3070   {
3071   $have_ipv4 = 0;
3072   $parm_ipv4 = "<no IPv4 address found>";
3073   $server_opts .= " -noipv4";
3074   }
3075 elsif ($have_ipv4 == 0)
3076   {
3077   $parm_ipv4 = "<IPv4 testing disabled>";
3078   $server_opts .= " -noipv4";
3079   }
3080 else
3081   {
3082   $parm_running{"IPv4"} = " ";
3083   }
3084
3085 if (not $parm_ipv6)
3086   {
3087   $have_ipv6 = 0;
3088   $parm_ipv6 = "<no IPv6 address found>";
3089   $server_opts .= " -noipv6";
3090   delete($parm_support{"IPv6"});
3091   }
3092 elsif ($have_ipv6 == 0)
3093   {
3094   $parm_ipv6 = "<IPv6 testing disabled>";
3095   $server_opts .= " -noipv6";
3096   delete($parm_support{"IPv6"});
3097   }
3098 elsif (!defined $parm_support{'IPv6'})
3099   {
3100   $have_ipv6 = 0;
3101   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3102   $server_opts .= " -noipv6";
3103   }
3104 else
3105   {
3106   $parm_running{"IPv6"} = " ";
3107   }
3108
3109 print "IPv4 address is $parm_ipv4\n";
3110 print "IPv6 address is $parm_ipv6\n";
3111
3112 # For munging test output, we need the reversed IP addresses.
3113
3114 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? "" :
3115   join(".", reverse(split /\./, $parm_ipv4));
3116
3117 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3118 if ($parm_ipv6 =~ /^[\da-f]/)
3119   {
3120   my(@comps) = split /:/, $parm_ipv6;
3121   my(@nibbles);
3122   foreach $comp (@comps)
3123     {
3124     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3125     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3126     }
3127   $parm_ipv6r = join(".", reverse(@nibbles));
3128   }
3129
3130 # Find the host name, fully qualified.
3131
3132 chomp($temp = `hostname`);
3133 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3134 $parm_hostname = (gethostbyname($temp))[0];
3135 $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3136 print "Hostname is $parm_hostname\n";
3137
3138 if ($parm_hostname !~ /\./)
3139   {
3140   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3141   }
3142
3143 if ($parm_hostname =~ /[[:upper:]]/)
3144   {
3145   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3146   }
3147
3148
3149
3150 ##################################################
3151 #     Create a testing version of Exim           #
3152 ##################################################
3153
3154 # We want to be able to run Exim with a variety of configurations. Normally,
3155 # the use of -C to change configuration causes Exim to give up its root
3156 # privilege (unless the caller is exim or root). For these tests, we do not
3157 # want this to happen. Also, we want Exim to know that it is running in its
3158 # test harness.
3159
3160 # We achieve this by copying the binary and patching it as we go. The new
3161 # binary knows it is a testing copy, and it allows -C and -D without loss of
3162 # privilege. Clearly, this file is dangerous to have lying around on systems
3163 # where there are general users with login accounts. To protect against this,
3164 # we put the new binary in a special directory that is accessible only to the
3165 # caller of this script, who is known to have sudo root privilege from the test
3166 # that was done above. Furthermore, we ensure that the binary is deleted at the
3167 # end of the test. First ensure the directory exists.
3168
3169 if (-d "eximdir")
3170   { unlink "eximdir/exim"; }     # Just in case
3171 else
3172   {
3173   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3174   system("sudo chgrp $parm_eximgroup eximdir");
3175   }
3176
3177 # The construction of the patched binary must be done as root, so we use
3178 # a separate script. As well as indicating that this is a test-harness binary,
3179 # the version number is patched to "x.yz" so that its length is always the
3180 # same. Otherwise, when it appears in Received: headers, it affects the length
3181 # of the message, which breaks certain comparisons.
3182
3183 die "** Unable to make patched exim: $!\n"
3184   if (system("sudo ./patchexim $parm_exim") != 0);
3185
3186 # From this point on, exits from the program must go via the subroutine
3187 # tests_exit(), so that suitable cleaning up can be done when required.
3188 # Arrange to catch interrupting signals, to assist with this.
3189
3190 $SIG{'INT'} = \&inthandler;
3191 $SIG{'PIPE'} = \&pipehandler;
3192
3193 # For some tests, we need another copy of the binary that is setuid exim rather
3194 # than root.
3195
3196 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3197        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3198        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3199        "sudo chmod 06755 eximdir/exim_exim");
3200
3201
3202 ##################################################
3203 #     Make copies of utilities we might need     #
3204 ##################################################
3205
3206 # Certain of the tests make use of some of Exim's utilities. We do not need
3207 # to be root to copy these.
3208
3209 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3210
3211 $dbm_build_deleted = 0;
3212 if (defined $parm_lookups{'dbm'} &&
3213     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3214   {
3215   delete $parm_lookups{'dbm'};
3216   $dbm_build_deleted = 1;
3217   }
3218
3219 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3220   {
3221   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3222   }
3223
3224 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3225   {
3226   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3227   }
3228
3229 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3230   {
3231   tests_exit(-1, "Failed to make a copy of exinext: $!");
3232   }
3233
3234 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3235   {
3236   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3237   }
3238
3239 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3240   {
3241   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3242   }
3243
3244
3245 ##################################################
3246 #    Check that the Exim user can access stuff   #
3247 ##################################################
3248
3249 # We delay this test till here so that we can check access to the actual test
3250 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3251
3252 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3253 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3254
3255 if ($parm_caller_uid eq $parm_exim_uid) {
3256   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3257                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3258 }
3259 if ($parm_caller_gid eq $parm_exim_gid) {
3260   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3261                 ."the same as caller's ($parm_caller) group as it confuses "
3262                 ."results analysis");
3263 }
3264
3265 print "The Exim user needs access to the test suite directory. Checking ...";
3266
3267 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3268   {
3269   my($why) = "unknown failure $rc";
3270   $rc >>= 8;
3271   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3272   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3273   $why = "Couldn't read auxiliary group list" if $rc == 3;
3274   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3275   $why = "Couldn't set gid" if $rc == 5;
3276   $why = "Couldn't set uid" if $rc == 6;
3277   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3278   print "\n** $why\n";
3279   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3280   }
3281 else
3282   {
3283   print " OK\n";
3284   }
3285
3286
3287 ##################################################
3288 #        Create a list of available tests        #
3289 ##################################################
3290
3291 # The scripts directory contains a number of subdirectories whose names are
3292 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3293 # from the first requires certain optional features to be included in the Exim
3294 # binary. These requirements are contained in a file called "REQUIRES" within
3295 # the directory. We scan all these tests, discarding those that cannot be run
3296 # because the current binary does not support the right facilities, and also
3297 # those that are outside the numerical range selected.
3298
3299 print "\nTest range is $test_start to $test_end (flavour $flavour)\n";
3300 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3301   if $dlfunc_deleted;
3302 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3303   if $dbm_build_deleted;
3304
3305 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
3306 @test_dirs = sort readdir(DIR);
3307 closedir(DIR);
3308
3309 # Remove . and .. and CVS from the list.
3310
3311 for ($i = 0; $i < @test_dirs; $i++)
3312   {
3313   my($d) = $test_dirs[$i];
3314   if ($d eq "." || $d eq ".." || $d eq "CVS")
3315     {
3316     splice @test_dirs, $i, 1;
3317     $i--;
3318     }
3319   }
3320
3321 # Scan for relevant tests
3322
3323 for ($i = 0; $i < @test_dirs; $i++)
3324   {
3325   my($testdir) = $test_dirs[$i];
3326   my($wantthis) = 1;
3327
3328   print ">>Checking $testdir\n" if $debug;
3329
3330   # Skip this directory if the first test is equal or greater than the first
3331   # test in the next directory.
3332
3333   next if ($i < @test_dirs - 1) &&
3334           ($test_start >= substr($test_dirs[$i+1], 0, 4));
3335
3336   # No need to carry on if the end test is less than the first test in this
3337   # subdirectory.
3338
3339   last if $test_end < substr($testdir, 0, 4);
3340
3341   # Check requirements, if any.
3342
3343   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
3344     {
3345     while (<REQUIRES>)
3346       {
3347       next if /^\s*$/;
3348       s/\s+$//;
3349       if (/^support (.*)$/)
3350         {
3351         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3352         }
3353       elsif (/^running (.*)$/)
3354         {
3355         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3356         }
3357       elsif (/^lookup (.*)$/)
3358         {
3359         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3360         }
3361       elsif (/^authenticators? (.*)$/)
3362         {
3363         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3364         }
3365       elsif (/^router (.*)$/)
3366         {
3367         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3368         }
3369       elsif (/^transport (.*)$/)
3370         {
3371         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3372         }
3373       else
3374         {
3375         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3376         }
3377       }
3378     close(REQUIRES);
3379     }
3380   else
3381     {
3382     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3383       unless $!{ENOENT};
3384     }
3385
3386   # Loop if we do not want the tests in this subdirectory.
3387
3388   if (!$wantthis)
3389     {
3390     chomp;
3391     print "Omitting tests in $testdir (missing $_)\n";
3392     next;
3393     }
3394
3395   # We want the tests from this subdirectory, provided they are in the
3396   # range that was selected.
3397
3398   opendir(SUBDIR, "scripts/$testdir") ||
3399     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3400   @testlist = sort readdir(SUBDIR);
3401   close(SUBDIR);
3402
3403   foreach $test (@testlist)
3404     {
3405     next if $test !~ /^\d{4}(?:\.\d+)?$/;
3406     next if $test < $test_start || $test > $test_end;
3407     push @test_list, "$testdir/$test";
3408     }
3409   }
3410
3411 print ">>Test List: @test_list\n", if $debug;
3412
3413
3414 ##################################################
3415 #         Munge variable auxiliary data          #
3416 ##################################################
3417
3418 # Some of the auxiliary data files have to refer to the current testing
3419 # directory and other parameter data. The generic versions of these files are
3420 # stored in the aux-var-src directory. At this point, we copy each of them
3421 # to the aux-var directory, making appropriate substitutions. There aren't very
3422 # many of them, so it's easiest just to do this every time. Ensure the mode
3423 # is standardized, as this path is used as a test for the ${stat: expansion.
3424
3425 # A similar job has to be done for the files in the dnszones-src directory, to
3426 # make the fake DNS zones for testing. Most of the zone files are copied to
3427 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3428 # networks that are defined by parameter.
3429
3430 foreach $basedir ("aux-var", "dnszones")
3431   {
3432   system("sudo rm -rf $parm_cwd/$basedir");
3433   mkdir("$parm_cwd/$basedir", 0777);
3434   chmod(0755, "$parm_cwd/$basedir");
3435
3436   opendir(AUX, "$parm_cwd/$basedir-src") ||
3437     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3438   my(@filelist) = readdir(AUX);
3439   close(AUX);
3440
3441   foreach $file (@filelist)
3442     {
3443     my($outfile) = $file;
3444     next if $file =~ /^\./;
3445
3446     if ($file eq "db.ip4.V4NET")
3447       {
3448       $outfile = "db.ip4.$parm_ipv4_test_net";
3449       }
3450     elsif ($file eq "db.ip6.V6NET")
3451       {
3452       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3453       $" = '.';
3454       $outfile = "db.ip6.@nibbles";
3455       $" = ' ';
3456       }
3457
3458     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3459     open(IN, "$parm_cwd/$basedir-src/$file") ||
3460       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3461     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3462       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3463     while (<IN>)
3464       {
3465       do_substitute(0);
3466       print OUT;
3467       }
3468     close(IN);
3469     close(OUT);
3470     }
3471   }
3472
3473 # Set a user's shell, distinguishable from /bin/sh
3474
3475 symlink("/bin/sh","aux-var/sh");
3476 $ENV{'SHELL'} = $parm_shell = $parm_cwd . "/aux-var/sh";
3477
3478 ##################################################
3479 #     Create fake DNS zones for this host        #
3480 ##################################################
3481
3482 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3483 # sure that there are forward and reverse registrations for this host, using
3484 # its real IP addresses. Dynamically created zone files achieve this.
3485
3486 if ($have_ipv4 || $have_ipv6)
3487   {
3488   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3489   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3490     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3491   print OUT "; This is a dynamically constructed fake zone file.\n" .
3492     "; The following line causes fakens to return PASS_ON\n" .
3493     "; for queries that it cannot answer\n\n" .
3494     "PASS ON NOT FOUND\n\n";
3495   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3496   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3497   print OUT "\n; End\n";
3498   close(OUT);
3499   }
3500
3501 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3502   {
3503   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3504   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3505     tests_exit(-1,
3506       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3507   print OUT "; This is a dynamically constructed fake zone file.\n" .
3508     "; The zone is $components[0].in-addr.arpa.\n\n" .
3509     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3510     "; End\n";
3511   close(OUT);
3512   }
3513
3514 if ($have_ipv6 && $parm_ipv6 ne "::1")
3515   {
3516   my($exp_v6) = $parm_ipv6;
3517   $exp_v6 =~ s/[^:]//g;
3518   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3519     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3520   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3521     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3522   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3523     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3524   } else {
3525     $exp_v6 = $parm_ipv6;
3526   }
3527   my(@components) = split /:/, $exp_v6;
3528   my(@nibbles) = reverse (split /\s*/, shift @components);
3529   my($sep) =  "";
3530
3531   $" = ".";
3532   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3533     tests_exit(-1,
3534       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3535   print OUT "; This is a dynamically constructed fake zone file.\n" .
3536     "; The zone is @nibbles.ip6.arpa.\n\n";
3537
3538   @components = reverse @components;
3539   foreach $c (@components)
3540     {
3541     $c = "0$c" until $c =~ /^..../;
3542     @nibbles = reverse(split /\s*/, $c);
3543     print OUT "$sep@nibbles";
3544     $sep = ".";
3545     }
3546
3547   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3548   close(OUT);
3549   $" = " ";
3550   }
3551
3552
3553
3554 ##################################################
3555 #    Create lists of mailboxes and message logs  #
3556 ##################################################
3557
3558 # We use these lists to check that a test has created the expected files. It
3559 # should be faster than looking for the file each time. For mailboxes, we have
3560 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3561 # is just a flat list of files.
3562
3563 @oldmails = list_files_below("mail");
3564 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3565 @oldmsglogs = readdir(DIR);
3566 closedir(DIR);
3567
3568
3569
3570 ##################################################
3571 #         Run the required tests                 #
3572 ##################################################
3573
3574 # Each test script contains a number of tests, separated by a line that
3575 # contains ****. We open input from the terminal so that we can read responses
3576 # to prompts.
3577
3578 open(T, "/dev/tty") || tests_exit(-1, "Failed to open /dev/tty: $!");
3579
3580 print "\nPress RETURN to run the tests: ";
3581 $_ = $force_continue ? "c" : <T>;
3582 print "\n";
3583
3584 $lasttestdir = "";
3585
3586 foreach $test (@test_list)
3587   {
3588   local($lineno) = 0;
3589   local($commandno) = 0;
3590   local($subtestno) = 0;
3591   (local $testno = $test) =~ s|.*/||;
3592   local($sortlog) = 0;
3593
3594   my($gnutls) = 0;
3595   my($docheck) = 1;
3596   my($thistestdir) = substr($test, 0, -5);
3597
3598   $dynamic_socket->close() if $dynamic_socket;
3599
3600   if ($lasttestdir ne $thistestdir)
3601     {
3602     $gnutls = 0;
3603     if (-s "scripts/$thistestdir/REQUIRES")
3604       {
3605       my($indent) = "";
3606       print "\n>>> The following tests require: ";
3607       open(IN, "scripts/$thistestdir/REQUIRES") ||
3608         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3609       while (<IN>)
3610         {
3611         $gnutls = 1 if /^support GnuTLS/;
3612         print $indent, $_;
3613         $indent = ">>>                              ";
3614         }
3615       close(IN);
3616       }
3617     }
3618   $lasttestdir = $thistestdir;
3619
3620   # Remove any debris in the spool directory and the test-mail directory
3621   # and also the files for collecting stdout and stderr. Then put back
3622   # the test-mail directory for appendfile deliveries.
3623
3624   system "sudo /bin/rm -rf spool test-*";
3625   system "mkdir test-mail 2>/dev/null";
3626
3627   # A privileged Exim will normally make its own spool directory, but some of
3628   # the tests run in unprivileged modes that don't always work if the spool
3629   # directory isn't already there. What is more, we want anybody to be able
3630   # to read it in order to find the daemon's pid.
3631
3632   system "mkdir spool; " .
3633          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3634          "sudo chmod 0755 spool";
3635
3636   # Empty the cache that keeps track of things like message id mappings, and
3637   # set up the initial sequence strings.
3638
3639   undef %cache;
3640   $next_msgid = "aX";
3641   $next_pid = 1234;
3642   $next_port = 1111;
3643   $message_skip = 0;
3644   $msglog_skip = 0;
3645   $stderr_skip = 0;
3646   $stdout_skip = 0;
3647   $rmfiltertest = 0;
3648   $is_ipv6test = 0;
3649   $TEST_STATE->{munge} = "";
3650
3651   # Remove the associative arrays used to hold checked mail files and msglogs
3652
3653   undef %expected_mails;
3654   undef %expected_msglogs;
3655
3656   # Open the test's script
3657   open(SCRIPT, "scripts/$test") ||
3658     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3659   # Run through the script once to set variables which should be global
3660   while (<SCRIPT>)
3661     {
3662     if (/^no_message_check/) { $message_skip = 1; next; }
3663     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3664     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3665     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3666     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3667     if (/^sortlog/)          { $sortlog = 1; next; }
3668     if (/\bPORT_DYNAMIC\b/)  {
3669       for (my $port = 1024; $port < 65000; $port++) {
3670         $dynamic_socket = IO::Socket::INET->new(
3671           LocalHost => '127.0.0.1',
3672           LocalPort => $port,
3673           Listen => 10,
3674           ReuseAddr => 1,
3675         ) and last;
3676       }
3677       }
3678     }
3679   # Reset to beginning of file for per test interpreting/processing
3680   seek(SCRIPT, 0, 0);
3681
3682   # The first line in the script must be a comment that is used to identify
3683   # the set of tests as a whole.
3684
3685   $_ = <SCRIPT>;
3686   $lineno++;
3687   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3688   printf("%s %s", (substr $test, 5), (substr $_, 2));
3689
3690   # Loop for each of the subtests within the script. The variable $server_pid
3691   # is used to remember the pid of a "server" process, for which we do not
3692   # wait until we have waited for a subsequent command.
3693
3694   local($server_pid) = 0;
3695   for ($commandno = 1; !eof SCRIPT; $commandno++)
3696     {
3697     # Skip further leading comments and blank lines, handle the flag setting
3698     # commands, and deal with tests for IP support.
3699
3700     while (<SCRIPT>)
3701       {
3702       $lineno++;
3703       # Could remove these variable settings because they are already
3704       # set above, but doesn't hurt to leave them here.
3705       if (/^no_message_check/) { $message_skip = 1; next; }
3706       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3707       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3708       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3709       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3710       if (/^sortlog/)          { $sortlog = 1; next; }
3711
3712       if (/^need_largefiles/)
3713         {
3714         next if $have_largefiles;
3715         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3716         $docheck = 0;      # don't check output
3717         undef $_;          # pretend EOF
3718         last;
3719         }
3720
3721       if (/^need_ipv4/)
3722         {
3723         next if $have_ipv4;
3724         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3725         $docheck = 0;      # don't check output
3726         undef $_;          # pretend EOF
3727         last;
3728         }
3729
3730       if (/^need_ipv6/)
3731         {
3732         if ($have_ipv6)
3733           {
3734           $is_ipv6test = 1;
3735           next;
3736           }
3737         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3738         $docheck = 0;      # don't check output
3739         undef $_;          # pretend EOF
3740         last;
3741         }
3742
3743       if (/^need_move_frozen_messages/)
3744         {
3745         next if defined $parm_support{"move_frozen_messages"};
3746         print ">>> move frozen message support is needed for test $testno, " .
3747           "but is not\n>>> available: skipping\n";
3748         $docheck = 0;      # don't check output
3749         undef $_;          # pretend EOF
3750         last;
3751         }
3752
3753       last unless /^(#|\s*$)/;
3754       }
3755     last if !defined $_;  # Hit EOF
3756
3757     my($subtest_startline) = $lineno;
3758
3759     # Now run the command. The function returns 0 for an inline command,
3760     # 1 if a non-exim command was run and waited for, 2 if an exim
3761     # command was run and waited for, and 3 if a command
3762     # was run and not waited for (usually a daemon or server startup).
3763
3764     my($commandname) = "";
3765     my($expectrc) = 0;
3766     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3767     my($cmdrc) = $?;
3768
3769 $0 = "[runtest $testno]";
3770
3771     if ($debug) {
3772       print ">> rc=$rc cmdrc=$cmdrc\n";
3773       if (defined $run_extra) {
3774         foreach my $k (keys %$run_extra) {
3775           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3776           print ">>   $k -> $v\n";
3777         }
3778       }
3779     }
3780     $run_extra = {} unless defined $run_extra;
3781     foreach my $k (keys %$run_extra) {
3782       if (exists $TEST_STATE->{$k}) {
3783         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3784         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3785       }
3786       if (defined $run_extra->{$k}) {
3787         $TEST_STATE->{$k} = $run_extra->{$k};
3788       } elsif (exists $TEST_STATE->{$k}) {
3789         delete $TEST_STATE->{$k};
3790       }
3791     }
3792
3793     # Hit EOF after an initial return code number
3794
3795     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3796
3797     # Carry on with the next command if we did not wait for this one. $rc == 0
3798     # if no subprocess was run; $rc == 3 if we started a process but did not
3799     # wait for it.
3800
3801     next if ($rc == 0 || $rc == 3);
3802
3803     # We ran and waited for a command. Check for the expected result unless
3804     # it died.
3805
3806     if ($cmdrc != $expectrc && !$sigpipehappened)
3807       {
3808       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3809       if (($cmdrc & 0xff) == 0)
3810         {
3811         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3812         }
3813       elsif (($cmdrc & 0xff00) == 0)
3814         { printf("** Killed by signal %d", $cmdrc & 255); }
3815       else
3816         { printf("** Status %x", $cmdrc); }
3817
3818       for (;;)
3819         {
3820         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3821         $_ = $force_continue ? "c" : <T>;
3822         tests_exit(1) if /^q?$/i;
3823         log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3824         if ($force_continue)
3825           {
3826           print "\nstderr tail:\n";
3827           print "===================\n";
3828           system("tail -20 test-stderr");
3829           print "===================\n";
3830           print "... continue forced\n";
3831           }
3832
3833         last if /^[rc]$/i;
3834         if (/^e$/i)
3835           {
3836           system("$more test-stderr");
3837           }
3838         elsif (/^o$/i)
3839           {
3840           system("$more test-stdout");
3841           }
3842         }
3843
3844       $retry = 1 if /^r$/i;
3845       $docheck = 0;
3846       }
3847
3848     # If the command was exim, and a listening server is running, we can now
3849     # close its input, which causes us to wait for it to finish, which is why
3850     # we didn't close it earlier.
3851
3852     if ($rc == 2 && $server_pid != 0)
3853       {
3854       close SERVERCMD;
3855       $server_pid = 0;
3856       if ($? != 0)
3857         {
3858         if (($? & 0xff) == 0)
3859           { printf("Server return code %d", $?/256); }
3860         elsif (($? & 0xff00) == 0)
3861           { printf("Server killed by signal %d", $? & 255); }
3862         else
3863           { printf("Server status %x", $?); }
3864
3865         for (;;)
3866           {
3867           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3868           $_ = $force_continue ? "c" : <T>;
3869           tests_exit(1) if /^q?$/i;
3870           log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3871           print "... continue forced\n" if $force_continue;
3872           last if /^[rc]$/i;
3873
3874           if (/^s$/i)
3875             {
3876             open(S, "test-stdout-server") ||
3877               tests_exit(-1, "Failed to open test-stdout-server: $!");
3878             print while <S>;
3879             close(S);
3880             }
3881           }
3882         $retry = 1 if /^r$/i;
3883         }
3884       }
3885     }
3886
3887   close SCRIPT;
3888
3889   # The script has finished. Check the all the output that was generated. The
3890   # function returns 0 if all is well, 1 if we should rerun the test (the files
3891   # function returns 0 if all is well, 1 if we should rerun the test (the files
3892   # have been updated). It does not return if the user responds Q to a prompt.
3893
3894   if ($retry)
3895     {
3896     $retry = '0';
3897     print (("#" x 79) . "\n");
3898     redo;
3899     }
3900
3901   if ($docheck)
3902     {
3903     if (check_output($TEST_STATE->{munge}) != 0)
3904       {
3905       print (("#" x 79) . "\n");
3906       redo;
3907       }
3908     else
3909       {
3910       print ("  Script completed\n");
3911       }
3912     }
3913   }
3914
3915
3916 ##################################################
3917 #         Exit from the test script              #
3918 ##################################################
3919
3920 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
3921 tests_exit(0);
3922
3923 # End of runtest script