test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32
  33 use lib "$RealBin/lib";
  34 use Exim::Runtest;
  35 use Exim::Utils qw(uniq numerically);
  36
  37 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  39
  40 use constant TEST_TOP => 8999;
  41 use constant TEST_SPECIAL_TOP => 9999;
  42
  43
  44 # Start by initializing some global variables
  45
  46 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  47
  48 # This gets embedded in the D-H params filename, and the value comes
  49 # from asking GnuTLS for "normal", but there appears to be no way to
  50 # use certtool/... to ask what that value currently is.  *sigh*
  51 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  52 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  53 # normal = 2432   tls_dh_max_bits = 2236
  54 my $gnutls_dh_bits_normal = 2236;
  55
  56 my $cf = 'bin/cf -exact';
  57 my $cr = "\r";
  58 my $debug = 0;
  59 my $flavour = do {
  60   my $f = Exim::Runtest::flavour() // '';
  61   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  62 };
  63 my $force_continue = 0;
  64 my $force_update = 0;
  65 my $log_failed_filename = 'failed-summary.log';
  66 my $log_summary_filename = 'run-summary.log';
  67 my $more = 'less -XF';
  68 my $optargs = '';
  69 my $save_output = 0;
  70 my $server_opts = '';
  71 my $slow = 0;
  72 my $valgrind = 0;
  73
  74 my $have_ipv4 = 1;
  75 my $have_ipv6 = 1;
  76 my $have_largefiles = 0;
  77
  78 my @test_list = ();
  79
  80
  81 # Networks to use for DNS tests. We need to choose some networks that will
  82 # never be used so that there is no chance that the host on which we are
  83 # running is actually in one of the test networks. Private networks such as
  84 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  85 # Rather than use some unassigned numbers (that might become assigned later),
  86 # I have chosen some multicast networks, in the belief that such addresses
  87 # won't ever be assigned to hosts. This is the only place where these numbers
  88 # are defined, so it is trivially possible to change them should that ever
  89 # become necessary.
  90
  91 my $parm_ipv4_test_net = 224;
  92 my $parm_ipv6_test_net = 'ff00';
  93
  94 # Port numbers are currently hard-wired
  95
  96 my $parm_port_n = 1223;         # Nothing listening on this port
  97 my $parm_port_s = 1224;         # Used for the "server" command
  98 my $parm_port_d = 1225;         # Used for the Exim daemon
  99 my $parm_port_d2 = 1226;        # Additional for daemon
 100 my $parm_port_d3 = 1227;        # Additional for daemon
 101 my $parm_port_d4 = 1228;        # Additional for daemon
 102 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 103
 104 # Find a suiteable group name for test (currently only 0001
 105 # uses a group name. A numeric group id would do
 106 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 107
 108 # Manually set locale
 109 $ENV{LC_ALL} = 'C';
 110
 111 # In some environments USER does not exist, but we need it for some test(s)
 112 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 113
 114 my ($parm_configure_owner, $parm_configure_group);
 115 my ($parm_ipv4, $parm_ipv6);
 116 my $parm_hostname;
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121 # Define a number of subroutines
 122
 123 ###############################################################################
 124 ###############################################################################
 125
 126
 127 ##################################################
 128 #              Handle signals                    #
 129 ##################################################
 130
 131 sub pipehandler { $sigpipehappened = 1; }
 132
 133 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 134
 135
 136 ##################################################
 137 #       Do global macro substitutions            #
 138 ##################################################
 139
 140 # This function is applied to configurations, command lines and data lines in
 141 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 142 # directory. It takes one argument: the current test number, or zero when
 143 # setting up files before running any tests.
 144
 145 sub do_substitute{
 146 s?\bCALLER\b?$parm_caller?g;
 147 s?\bCALLERGROUP\b?$parm_caller_group?g;
 148 s?\bCALLER_UID\b?$parm_caller_uid?g;
 149 s?\bCALLER_GID\b?$parm_caller_gid?g;
 150 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 151 s?\bDIR/?$parm_cwd/?g;
 152 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 153 s?\bEXIMUSER\b?$parm_eximuser?g;
 154 s?\bHOSTIPV4\b?$parm_ipv4?g;
 155 s?\bHOSTIPV6\b?$parm_ipv6?g;
 156 s?\bHOSTNAME\b?$parm_hostname?g;
 157 s?\bPORT_D\b?$parm_port_d?g;
 158 s?\bPORT_D2\b?$parm_port_d2?g;
 159 s?\bPORT_D3\b?$parm_port_d3?g;
 160 s?\bPORT_D4\b?$parm_port_d4?g;
 161 s?\bPORT_N\b?$parm_port_n?g;
 162 s?\bPORT_S\b?$parm_port_s?g;
 163 s?\bTESTNUM\b?$_[0]?g;
 164 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 165 s?\bV6NET:?$parm_ipv6_test_net:?g;
 166 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 167 s?\bMAILGROUP\b?$parm_mailgroup?g;
 168 }
 169
 170
 171 ##################################################
 172 #     Any state to be preserved across tests     #
 173 ##################################################
 174
 175 my $TEST_STATE = {};
 176
 177
 178 ##################################################
 179 #        Subroutine to tidy up and exit          #
 180 ##################################################
 181
 182 # In all cases, we check for any Exim daemons that have been left running, and
 183 # kill them. Then remove all the spool data, test output, and the modified Exim
 184 # binary if we are ending normally.
 185
 186 # Arguments:
 187 #    $_[0] = 0 for a normal exit; full cleanup done
 188 #    $_[0] > 0 for an error exit; no files cleaned up
 189 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 190
 191 sub tests_exit{
 192 my($rc) = $_[0];
 193 my($spool);
 194
 195 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 196 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 197 # the background.
 198
 199 if (exists $TEST_STATE->{exim_pid})
 200   {
 201   $pid = $TEST_STATE->{exim_pid};
 202   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 203   system("sudo kill -INT $pid");
 204   }
 205
 206 if (opendir(DIR, "spool"))
 207   {
 208   my(@spools) = sort readdir(DIR);
 209   closedir(DIR);
 210   foreach $spool (@spools)
 211     {
 212     next if $spool !~ /^exim-daemon./;
 213     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 214     chomp($pid = <PID>);
 215     close(PID);
 216     print "Tidyup: killing daemon pid=$pid\n";
 217     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 218     }
 219   }
 220 else
 221   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 222
 223 # Close the terminal input and remove the test files if all went well, unless
 224 # the option to save them is set. Always remove the patched Exim binary. Then
 225 # exit normally, or die.
 226
 227 close(T);
 228 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 229   if ($rc == 0 && !$save_output);
 230
 231 system("sudo /bin/rm -rf ./eximdir/*")
 232   if (!$save_output);
 233
 234 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 235 exit $rc if ($rc >= 0);
 236 die "** runtest error: $_[1]\n";
 237 }
 238
 239
 240
 241 ##################################################
 242 #   Subroutines used by the munging subroutine   #
 243 ##################################################
 244
 245 # This function is used for things like message ids, where we want to generate
 246 # more than one value, but keep a consistent mapping throughout.
 247 #
 248 # Arguments:
 249 #   $oldid        the value from the file
 250 #   $base         a base string into which we insert a sequence
 251 #   $sequence     the address of the current sequence counter
 252
 253 sub new_value {
 254 my($oldid, $base, $sequence) = @_;
 255 my($newid) = $cache{$oldid};
 256 if (! defined $newid)
 257   {
 258   $newid = sprintf($base, $$sequence++);
 259   $cache{$oldid} = $newid;
 260   }
 261 return $newid;
 262 }
 263
 264
 265 # This is used while munging the output from exim_dumpdb.
 266 # May go wrong across DST changes.
 267
 268 sub date_seconds {
 269 my($day,$month,$year,$hour,$min,$sec) =
 270   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 271 my($mon);
 272 if   ($month =~ /Jan/) {$mon = 0;}
 273 elsif($month =~ /Feb/) {$mon = 1;}
 274 elsif($month =~ /Mar/) {$mon = 2;}
 275 elsif($month =~ /Apr/) {$mon = 3;}
 276 elsif($month =~ /May/) {$mon = 4;}
 277 elsif($month =~ /Jun/) {$mon = 5;}
 278 elsif($month =~ /Jul/) {$mon = 6;}
 279 elsif($month =~ /Aug/) {$mon = 7;}
 280 elsif($month =~ /Sep/) {$mon = 8;}
 281 elsif($month =~ /Oct/) {$mon = 9;}
 282 elsif($month =~ /Nov/) {$mon = 10;}
 283 elsif($month =~ /Dec/) {$mon = 11;}
 284 return timelocal($sec,$min,$hour,$day,$mon,$year);
 285 }
 286
 287
 288 # This is a subroutine to sort maildir files into time-order. The second field
 289 # is the microsecond field, and may vary in length, so must be compared
 290 # numerically.
 291
 292 sub maildirsort {
 293 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 294 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 295 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 296 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 297 }
 298
 299
 300
 301 ##################################################
 302 #   Subroutine list files below a directory      #
 303 ##################################################
 304
 305 # This is used to build up a list of expected mail files below a certain path
 306 # in the directory tree. It has to be recursive in order to deal with multiple
 307 # maildir mailboxes.
 308
 309 sub list_files_below {
 310 my($dir) = $_[0];
 311 my(@yield) = ();
 312 my(@sublist, $file);
 313
 314 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 315 @sublist = sort maildirsort readdir(DIR);
 316 closedir(DIR);
 317
 318 foreach $file (@sublist)
 319   {
 320   next if $file eq "." || $file eq ".." || $file eq "CVS";
 321   if (-d "$dir/$file")
 322     { @yield = (@yield, list_files_below("$dir/$file")); }
 323   else
 324     { push @yield, "$dir/$file"; }
 325   }
 326
 327 return @yield;
 328 }
 329
 330
 331
 332 ##################################################
 333 #         Munge a file before comparing          #
 334 ##################################################
 335
 336 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 337 # on into standard values, so that the compare works. Perl's substitution with
 338 # an expression provides a neat way to do some of these changes.
 339
 340 # We keep a global associative array for repeatedly turning the same values
 341 # into the same standard values throughout the data from a single test.
 342 # Message ids get this treatment (can't be made reliable for times), and
 343 # times in dumped retry databases are also handled in a special way, as are
 344 # incoming port numbers.
 345
 346 # On entry to the subroutine, the file to write to is already opened with the
 347 # name MUNGED. The input file name is the only argument to the subroutine.
 348 # Certain actions are taken only when the name contains "stderr", "stdout",
 349 # or "log". The yield of the function is 1 if a line matching "*** truncated
 350 # ***" is encountered; otherwise it is 0.
 351
 352 sub munge {
 353 my($file) = $_[0];
 354 my($extra) = $_[1];
 355 my($yield) = 0;
 356 my(@saved) = ();
 357
 358 local $_;
 359
 360 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 361
 362 my($is_log) = $file =~ /log/;
 363 my($is_stdout) = $file =~ /stdout/;
 364 my($is_stderr) = $file =~ /stderr/;
 365 my($is_mail) = $file =~ /mail/;
 366
 367 # Date pattern
 368
 369 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 370
 371 # Pattern for matching pids at start of stderr lines; initially something
 372 # that won't match.
 373
 374 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 375
 376 # Scan the file and make the changes. Near the bottom there are some changes
 377 # that are specific to certain file types, though there are also some of those
 378 # inline too.
 379
 380 LINE: while(<IN>)
 381   {
 382 RESET_AFTER_EXTRA_LINE_READ:
 383   # Custom munges
 384   if ($extra)
 385     {
 386     next if $extra =~ m%^/%  &&  eval $extra;
 387     eval $extra if $extra =~ m/^s/;
 388     }
 389
 390   # Check for "*** truncated ***"
 391   $yield = 1 if /\*\*\* truncated \*\*\*/;
 392
 393   # Replace the name of this host
 394   s/\Q$parm_hostname\E/the.local.host.name/g;
 395
 396   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 397   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 398
 399   # The name of the shell may vary
 400   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 401
 402   # Replace the path to the testsuite directory
 403   s?\Q$parm_cwd\E?TESTSUITE?g;
 404
 405   # Replace the Exim version number (may appear in various places)
 406   # patchexim should have fixed this for us
 407   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 408
 409   # Replace Exim message ids by a unique series
 410   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 411     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 412
 413   # The names of lock files appear in some error and debug messages
 414   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 415
 416   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 417   # port" message, because it is not always the same.
 418   s/port (\d+) \([^)]+\)/port $1/g
 419     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 420
 421   # Challenges in SPA authentication
 422   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 423
 424   # PRVS values
 425   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 426   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463     my($increment) = date_seconds($date3) - date_seconds($date2);
 464
 465     # We used to use globally unique replacement values, but timing
 466     # differences make this impossible. Just show the increment on the
 467     # last one.
 468
 469     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 470       $increment, $expired);
 471     next;
 472     }
 473
 474   # more_errno values in exim_dumpdb output which are times
 475   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 476
 477
 478   # ======== Dates and times ========
 479
 480   # Dates and times are all turned into the same value - trying to turn
 481   # them into different ones cannot be done repeatedly because they are
 482   # real time stamps generated while running the test. The actual date and
 483   # time used was fixed when I first started running automatic Exim tests.
 484
 485   # Date/time in header lines and SMTP responses
 486   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 487     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 488
 489   # Date/time in logs and in one instance of a filter test
 490   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 491   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 492   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 493   # Date/time in syslog test
 494   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 495   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 496   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 497   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 498
 499   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 500   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 501
 502   # Date/time in message separators
 503   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 504     /Tue Mar 02 09:44:33 1999/gx;
 505
 506   # Date of message arrival in spool file as shown by -Mvh
 507   s/^\d{9,10}\s0$/ddddddddd 0/;
 508
 509   # Date/time in mbx mailbox files
 510   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 511
 512   # Dates/times in debugging output for writing retry records
 513   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 514     {
 515     my($next) = $3 - $2;
 516     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 517     }
 518   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 519   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 520
 521   # Time to retry may vary
 522   s/time to retry = \S+/time to retry = tttt/;
 523   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 524   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 525
 526   # Date/time in exim -bV output
 527   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 528
 529   # Eximstats heading
 530   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 531     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 532
 533   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 534   # us the former on a new connection.
 535   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 536
 537   # ======== TLS certificate algorithms ========
 538   # Test machines might have various different TLS library versions supporting
 539   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 540   # treat the standard algorithms the same.
 541   # So far, have seen:
 542   #   TLSv1:AES128-GCM-SHA256:128
 543   #   TLSv1:AES256-SHA:256
 544   #   TLSv1.1:AES256-SHA:256
 545   #   TLSv1.2:AES256-GCM-SHA384:256
 546   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 547   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 548   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 549   # We also need to handle the ciphersuite without the TLS part present, for
 550   # client-ssl's output.  We also see some older forced ciphersuites, but
 551   # negotiating TLS 1.2 instead of 1.0.
 552   # Mail headers (...), log-lines X=..., client-ssl output ...
 553   # (and \b doesn't match between ' ' and '(' )
 554   #
 555   # Retain the authentication algorith field as we want to test that.
 556
 557   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[123]:/$1TLSv1:/xg;
 558   s/((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHA/g;
 559   s/((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHA:xxx/g;
 560
 561   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 562   # as it seems the protocol no longer supports a user choice.
 563   s/TLS_AES(_256)_GCM_SHA384:256/TLS-AES256-SHA:xxx/g;
 564
 565   # LibreSSL
 566   # TLSv1:AES256-GCM-SHA384:256
 567   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 568   #
 569   # ECDHE-RSA-CHACHA20-POLY1305
 570   # AES256-GCM-SHA384
 571
 572   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 573   s/((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHA/g;
 574   s/((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHA:xxx/g;
 575
 576   # GnuTLS have seen:
 577   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 578   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 579   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 580   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 581   #
 582   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 583   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 584   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 585   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 586   # and as stand-alone cipher:
 587   #   ECDHE-RSA-AES256-SHA
 588   #   DHE-RSA-AES256-SHA256
 589   #   DHE-RSA-AES256-SHA
 590   # picking latter as canonical simply because regex easier that way.
 591   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 592   s/TLS1.[012]:((EC)?DHE_)?(RSA|ECDSA)_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:ke_$3_AES_256_CBC_SHAnnn:256/g;
 593   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAxx/g;
 594
 595   # GnuTLS library error message changes
 596   s/No certificate was found/The peer did not send any certificate/g;
 597 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 598   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 599   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 600
 601   # (this new one is a generic channel-read error, but the testsuite
 602   # only hits it in one place)
 603   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 604
 605   # (replace old with new, hoping that old only happens in one situation)
 606   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 607   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 608
 609   # signature algorithm names
 610   s/RSA-SHA1/RSA-SHA/;
 611
 612
 613   # ======== Caller's login, uid, gid, home, gecos ========
 614
 615   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 616   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 617   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 618
 619   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 620   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 621
 622   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 623   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 624
 625   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 626
 627   # When looking at spool files with -Mvh, we will find not only the caller
 628   # login, but also the uid and gid. It seems that $) in some Perls gives all
 629   # the auxiliary gids as well, so don't bother checking for that.
 630
 631   s/^CALLER $> \d+$/CALLER UID GID/;
 632
 633   # There is one case where the caller's login is forced to something else,
 634   # in order to test the processing of logins that contain spaces. Weird what
 635   # some people do, isn't it?
 636
 637   s/^spaced user $> \d+$/CALLER UID GID/;
 638
 639
 640   # ======== Exim's login ========
 641   # For messages received by the daemon, this is in the -H file, which some
 642   # tests inspect. For bounce messages, this will appear on the U= lines in
 643   # logs and also after Received: and in addresses. In one pipe test it appears
 644   # after "Running as:". It also appears in addresses, and in the names of lock
 645   # files.
 646
 647   s/U=$parm_eximuser/U=EXIMUSER/;
 648   s/user=$parm_eximuser/user=EXIMUSER/;
 649   s/login=$parm_eximuser/login=EXIMUSER/;
 650   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 651   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 652   s/\b$parm_eximuser@/EXIMUSER@/;
 653   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 654
 655   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 656   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 657
 658   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 659   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 660
 661   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 662
 663
 664   # ======== General uids, gids, and pids ========
 665   # Note: this must come after munges for caller's and exim's uid/gid
 666
 667   # These are for systems where long int is 64
 668   s/\buid=4294967295/uid=-1/;
 669   s/\beuid=4294967295/euid=-1/;
 670   s/\bgid=4294967295/gid=-1/;
 671   s/\begid=4294967295/egid=-1/;
 672
 673   s/\bgid=\d+/gid=gggg/;
 674   s/\begid=\d+/egid=gggg/;
 675   s/\b(pid=|PID: )\d+/$1pppp/;
 676   s/\buid=\d+/uid=uuuu/;
 677   s/\beuid=\d+/euid=uuuu/;
 678   s/set_process_info:\s+\d+/set_process_info: pppp/;
 679   s/queue run pid \d+/queue run pid ppppp/;
 680   s/process \d+ running as transport filter/process pppp running as transport filter/;
 681   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 682   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 683   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 684
 685   # Pid in temp file in appendfile transport
 686   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 687
 688   # Optional pid in log lines
 689   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 690     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 691
 692   # Optional pid in syslog test lines
 693   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 694     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 695
 696   # Detect a daemon stderr line with a pid and save the pid for subsequent
 697   # removal from following lines.
 698   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 699   s/^$spid //;
 700
 701   # Queue runner waiting messages
 702   s/waiting for children of \d+/waiting for children of pppp/;
 703   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 704
 705   # The spool header file name varies with PID
 706   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 707
 708   # ======== Port numbers ========
 709   # Incoming port numbers may vary, but not in daemon startup line.
 710
 711   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 712   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 713
 714   # This handles "connection from" and the like, when the port is given
 715   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 716       && !/\*>/ && !/Connection refused/)
 717     {
 718     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 719     }
 720
 721   # Port in host address in spool file output from -Mvh
 722   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 723
 724   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 725     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 726   }
 727
 728
 729   # ======== Local IP addresses ========
 730   # The amount of space between "host" and the address in verification output
 731   # depends on the length of the host name. We therefore reduce it to one space
 732   # for all of them.
 733   # Also, the length of space at the end of the host line is dependent
 734   # on the length of the longest line, so strip it also on otherwise
 735   # un-rewritten lines like localhost
 736
 737   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 738   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 739   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 740   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 741   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 742   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 743   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 744   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 745   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 746   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 747
 748
 749   # ======== Test network IP addresses ========
 750   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 751   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 752
 753
 754   # ======== IP error numbers and messages ========
 755   # These vary between operating systems
 756   s/Can't assign requested address/Network Error/;
 757   s/Cannot assign requested address/Network Error/;
 758   s/Operation timed out/Connection timed out/;
 759   s/Address family not supported by protocol family/Network Error/;
 760   s/Network is unreachable/Network Error/;
 761   s/Invalid argument/Network Error/;
 762
 763   s/\(\d+\): Network/(dd): Network/;
 764   s/\(\d+\): Connection refused/(dd): Connection refused/;
 765   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 766   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 767   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 768
 769
 770   # ======== Other error numbers ========
 771   s/errno=\d+/errno=dd/g;
 772
 773   # ======== System Error Messages ======
 774   # depending on the underlaying file system the error message seems to differ
 775   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 776
 777   # ======== Output from ls ========
 778   # Different operating systems use different spacing on long output
 779   #s/ +/ /g if /^[-rwd]{10} /;
 780   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 781   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 782   # unfortunately matches a non-ls linefull of dashes.
 783   # Allow the case where we've already picked out the file protection bits.
 784   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 785     s/ +/ /g;
 786   }
 787
 788
 789   # ======== Message sizes =========
 790   # Message sizes vary, owing to different logins and host names that get
 791   # automatically inserted. I can't think of any way of even approximately
 792   # comparing these.
 793
 794   s/([\s,])S=\d+\b/$1S=sss/;
 795   s/:S\d+\b/:Ssss/;
 796   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 797   s/\sSIZE=\d+\b/ SIZE=ssss/;
 798   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 799   s/old size = \d+\b/old size = sssss/;
 800   s/message size = \d+\b/message size = sss/;
 801   s/this message = \d+\b/this message = sss/;
 802   s/Size of headers = \d+/Size of headers = sss/;
 803   s/sum=(?!0)\d+/sum=dddd/;
 804   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 805   s/(?<=sum=0 )count=\d+\b/count=dd/;
 806   s/,S is \d+\b/,S is ddddd/;
 807   s/\+0100,\d+;/+0100,ddd;/;
 808   s/\(\d+ bytes written\)/(ddd bytes written)/;
 809   s/added '\d+ 1'/added 'ddd 1'/;
 810   s/Received\s+\d+/Received               nnn/;
 811   s/Delivered\s+\d+/Delivered              nnn/;
 812
 813
 814   # ======== Values in spool space failure message ========
 815   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 816
 817
 818   # ======== Filter sizes ========
 819   # The sizes of filter files may vary because of the substitution of local
 820   # filenames, logins, etc.
 821
 822   s/^\d+(?= bytes read from )/ssss/;
 823
 824
 825   # ======== OpenSSL error messages ========
 826   # Different releases of the OpenSSL libraries seem to give different error
 827   # numbers, or handle specific bad conditions in different ways, leading to
 828   # different wording in the error messages, so we cannot compare them.
 829
 830 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 831 #    but I can't work out how to deal with that.
 832   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 833   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 834   next if /SSL verify error: depth=0 error=certificate not trusted/;
 835
 836   # ======== Maildir things ========
 837   # timestamp output in maildir processing
 838   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 839
 840   # maildir delivery files appearing in log lines (in cases of error)
 841   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 842
 843   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 844
 845   # Maildir file names in general
 846   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 847
 848   # Maildirsize data
 849   while (/^\d+S,\d+C\s*$/)
 850     {
 851     print MUNGED;
 852     while (<IN>)
 853       {
 854       last if !/^\d+ \d+\s*$/;
 855       print MUNGED "ddd d\n";
 856       }
 857     last if !defined $_;
 858     }
 859   last if !defined $_;
 860
 861
 862   # ======== Output from the "fd" program about open descriptors ========
 863   # The statuses seem to be different on different operating systems, but
 864   # at least we'll still be checking the number of open fd's.
 865
 866   s/max fd = \d+/max fd = dddd/;
 867   s/status=0 RDONLY/STATUS/g;
 868   s/status=1 WRONLY/STATUS/g;
 869   s/status=2 RDWR/STATUS/g;
 870
 871
 872   # ======== Contents of spool files ========
 873   # A couple of tests dump the contents of the -H file. The length fields
 874   # will be wrong because of different user names, etc.
 875   s/^\d\d\d(?=[PFS*])/ddd/;
 876
 877
 878   # ========= Exim lookups ==================
 879   # Lookups have a char which depends on the number of lookup types compiled in,
 880   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 881   # other output is fragile; perhaps the debug output should be revised instead.
 882   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 883
 884   # ==========================================================
 885   # MIME boundaries in RFC3461 DSN messages
 886   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 887
 888   # ==========================================================
 889   # Some munging is specific to the specific file types
 890
 891   # ======== stdout ========
 892
 893   if ($is_stdout)
 894     {
 895     # Skip translate_ip_address and use_classresources in -bP output because
 896     # they aren't always there.
 897
 898     next if /translate_ip_address =/;
 899     next if /use_classresources/;
 900
 901     # In certain filter tests, remove initial filter lines because they just
 902     # clog up by repetition.
 903
 904     if ($rmfiltertest)
 905       {
 906       next if /^(Sender\staken\sfrom|
 907                  Return-path\scopied\sfrom|
 908                  Sender\s+=|
 909                  Recipient\s+=)/x;
 910       if (/^Testing \S+ filter/)
 911         {
 912         $_ = <IN>;    # remove blank line
 913         next;
 914         }
 915       }
 916
 917     # remote IPv6 addrs vary
 918     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
 919
 920     # openssl version variances
 921   # Error lines on stdout from SSL contain process id values and file names.
 922   # They also contain a source file name and line number, which may vary from
 923   # release to release.
 924
 925     next if /^SSL info:/;
 926     next if /SSL verify error: depth=0 error=certificate not trusted/;
 927     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 928     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
 929     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
 930
 931     # gnutls version variances
 932     next if /^Error in the pull function./;
 933
 934     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
 935     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
 936     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
 937
 938     # subsecond timstamp info in reported header-files
 939     s/^(-received_time_usec \.)\d{6}$/$1uuuuuu/;
 940
 941     # Postgres server takes varible time to shut down; lives in various places
 942     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
 943     s/^\/.*postgres /POSTGRES /;
 944
 945     # ARC is not always supported by the build
 946     next if /^arc_sign =/;
 947     }
 948
 949   # ======== stderr ========
 950
 951   elsif ($is_stderr)
 952     {
 953     # The very first line of debugging output will vary
 954
 955     s/^Exim version .*/Exim version x.yz ..../;
 956
 957     # Debugging lines for Exim terminations and process-generation
 958
 959     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 960     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
 961
 962     # IP address lookups use gethostbyname() when IPv6 is not supported,
 963     # and gethostbyname2() or getipnodebyname() when it is.
 964
 965     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 966
 967     # we don't care what TZ enviroment the testhost was running
 968     next if /^Reset TZ to/;
 969
 970     # drop gnutls version strings
 971     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 972     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 973
 974     # drop openssl version strings
 975     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 976     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 977
 978     # drop lookups
 979     next if /^Lookups \(built-in\):/;
 980     next if /^Loading lookup modules from/;
 981     next if /^Loaded \d+ lookup modules/;
 982     next if /^Total \d+ lookups/;
 983
 984     # drop compiler information
 985     next if /^Compiler:/;
 986
 987     # and the ugly bit
 988     # different libraries will have different numbers (possibly 0) of follow-up
 989     # lines, indenting with more data
 990     if (/^Library version:/) {
 991       while (1) {
 992         $_ = <IN>;
 993         next if /^\s/;
 994         goto RESET_AFTER_EXTRA_LINE_READ;
 995       }
 996     }
 997
 998     # drop other build-time controls emitted for debugging
 999     next if /^WHITELIST_D_MACROS:/;
1000     next if /^TRUSTED_CONFIG_LIST:/;
1001
1002     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1003     # with -be, privileges will have been dropped, so this will always
1004     # be the case
1005     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1006
1007     # We might not keep this check; rather than change all the tests, just
1008     # ignore it as long as it succeeds; then we only need to change the
1009     # TLS tests where tls_require_ciphers has been set.
1010     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1011       my $discard = <IN>;
1012       next;
1013     }
1014     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1015
1016     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1017     next if /^macros_trusted overridden to true by whitelisting/;
1018
1019     # We have to omit the localhost ::1 address so that all is well in
1020     # the IPv4-only case.
1021
1022     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1023       if (/looked up these IP addresses/);
1024     next if /name=localhost address=::1/;
1025
1026     # drop pdkim debugging header
1027     next if /^PDKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1028
1029     # Various other IPv6 lines must be omitted too
1030
1031     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1032     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1033     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1034     next if / in dns_ipv4_lookup?/;
1035
1036     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1037       {
1038       $_= <IN>;     # Gets "returning DNS_NODATA"
1039       next;
1040       }
1041
1042     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1043     # are unset, because tls ain't always there.
1044
1045     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1046                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1047
1048     # Skip auxiliary group lists because they will vary.
1049
1050     next if /auxiliary group list:/;
1051
1052     # Skip "extracted from gecos field" because the gecos field varies
1053
1054     next if /extracted from gecos field/;
1055
1056     # Skip "waiting for data on socket" and "read response data: size=" lines
1057     # because some systems pack more stuff into packets than others.
1058
1059     next if /waiting for data on socket/;
1060     next if /read response data: size=/;
1061
1062     # If Exim is compiled with readline support but it can't find the library
1063     # to load, there will be an extra debug line. Omit it.
1064
1065     next if /failed to load readline:/;
1066
1067     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1068     # O_CREAT; other's don't. In the latter case there is some debugging output
1069     # which is not present in the former. Skip the relevant lines (there are
1070     # two of them).
1071
1072     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1073       {
1074       $_ = <IN>;
1075       next;
1076       }
1077
1078     # Some tests turn on +expand debugging to check on expansions.
1079     # Unfortunately, the Received: expansion varies, depending on whether TLS
1080     # is compiled or not. So we must remove the relevant debugging if it is.
1081
1082     if (/^condition: def:tls_cipher/)
1083       {
1084       while (<IN>) { last if /^condition: def:sender_address/; }
1085       }
1086     elsif (/^expanding: Received: /)
1087       {
1088       while (<IN>) { last if !/^\s/; }
1089       }
1090
1091     # remote port numbers vary
1092     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1093
1094     # Skip hosts_require_dane checks when the options
1095     # are unset, because dane ain't always there.
1096
1097     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1098
1099     # SUPPORT_PROXY
1100     next if /host in hosts_proxy\?/;
1101
1102     # Experimental_International
1103     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1104
1105     # Experimental_REQUIRETLS
1106     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1107
1108     # Environment cleaning
1109     next if /\w+ in keep_environment\? (yes|no)/;
1110
1111     # Sizes vary with test hostname
1112     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1113
1114     # Spool filesystem free space changes on different systems.
1115     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1116
1117     # Non-TLS builds have different expansions for received_header_text
1118     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1119       {
1120       $_ .= <IN>;
1121       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1122       }
1123     if (/^ ├──condition: def:tls_cipher$/)
1124       {
1125       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1126       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1127       }
1128
1129     # Not all platforms build with DKIM enabled
1130     next if /^PDKIM >> Body data for hash, canonicalized/;
1131
1132     # Not all platforms have sendfile support
1133     next if /^cannot use sendfile for body: no support$/;
1134
1135     #  Parts of DKIM-specific debug output depend on the time/date
1136     next if /^date:\w+,\{SP\}/;
1137     next if /^PDKIM \[[^[]+\] (Header hash|b) computed:/;
1138
1139     # Not all platforms support TCP Fast Open, and the compile omits the check
1140     if (s/\S+ in hosts_try_fastopen\? no \(option unset\)\n$//)
1141       {
1142       $_ .= <IN>;
1143       s/ \.\.\. >>> / ... /;
1144       s/Address family not supported by protocol family/Network Error/;
1145       s/Network is unreachable/Network Error/;
1146       }
1147
1148     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1149
1150     # Specific pointer values reported for DB operations change from run to run
1151     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1152     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1153
1154     # Platform-dependent output during MySQL startup
1155     next if /PerconaFT file system space/;
1156     next if /^Waiting for MySQL server to answer/;
1157     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1158
1159     # Not all builds include DMARC
1160     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1161
1162     # When Exim is checking the size of directories for maildir, it uses
1163     # the check_dir_size() function to scan directories. Of course, the order
1164     # of the files that are obtained using readdir() varies from system to
1165     # system. We therefore buffer up debugging lines from check_dir_size()
1166     # and sort them before outputting them.
1167
1168     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1169       {
1170       push @saved, $_;
1171       }
1172     else
1173       {
1174       if (@saved > 0)
1175         {
1176         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1177           "to ensure consistency\n";
1178         @saved = sort(@saved);
1179         print MUNGED @saved;
1180         @saved = ();
1181         }
1182
1183       # Skip some lines that Exim puts out at the start of debugging output
1184       # because they will be different in different binaries.
1185
1186       print MUNGED
1187         unless (/^Berkeley DB: / ||
1188                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1189                 /^Authenticators:/ ||
1190                 /^Lookups:/ ||
1191                 /^Support for:/ ||
1192                 /^Routers:/ ||
1193                 /^Transports:/ ||
1194                 /^Malware:/ ||
1195                 /^log selectors =/ ||
1196                 /^cwd=/ ||
1197                 /^Fixed never_users:/ ||
1198                 /^Configure owner:/ ||
1199                 /^Size of off_t:/
1200                 );
1201
1202
1203       }
1204
1205     next;
1206     }
1207
1208   # ======== log ========
1209
1210   elsif ($is_log)
1211     {
1212     # Berkeley DB version differences
1213     next if / Berkeley DB error: /;
1214
1215     # CHUNKING: exact sizes depend on hostnames in headers
1216     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1217
1218     # openssl version variances
1219     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1220     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1221     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1222
1223     # DKIM timestamps
1224     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1225       {
1226       my ($prefix, $t_diff) = ($1, $3 - $2);
1227       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1228       }
1229     }
1230
1231   # ======== mail ========
1232
1233   elsif ($is_mail)
1234     {
1235     # DKIM timestamps, and signatures depending thereon
1236     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1237       {
1238       my ($indent, $t_diff) = ($1, $3 - $2);
1239       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1240       <IN>;
1241       <IN>;
1242       }
1243     }
1244
1245   # ======== All files other than stderr ========
1246
1247   print MUNGED;
1248   }
1249
1250 close(IN);
1251 return $yield;
1252 }
1253
1254
1255
1256
1257 ##################################################
1258 #        Subroutine to interact with caller      #
1259 ##################################################
1260
1261 # Arguments: [0] the prompt string
1262 #            [1] if there is a U in the prompt and $force_update is true
1263 #            [2] if there is a C in the prompt and $force_continue is true
1264 # Returns:   returns the answer
1265
1266 sub interact {
1267   my ($prompt, $have_u, $have_c) = @_;
1268
1269   print $prompt;
1270
1271   if ($have_u) {
1272     print "... update forced\n";
1273     return 'u';
1274   }
1275
1276   if ($have_c) {
1277     print "... continue forced\n";
1278     return 'c';
1279   }
1280
1281   return lc <T>;
1282 }
1283
1284
1285
1286 ##################################################
1287 #    Subroutine to log in force_continue mode    #
1288 ##################################################
1289
1290 # In force_continue mode, we just want a terse output to a statically
1291 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1292 # all have mismatches, it will log multiple times.
1293 #
1294 # Arguments: [0] the logfile to append to
1295 #            [1] the testno that failed
1296 # Returns:   nothing
1297
1298
1299
1300 sub log_failure {
1301   my ($logfile, $testno, $detail) = @_;
1302
1303   open(my $fh, '>>', $logfile) or return;
1304
1305   print $fh "Test $testno "
1306         . (defined $detail ? "$detail " : '')
1307         . "failed\n";
1308 }
1309
1310 # Computer-readable summary results logfile
1311
1312 sub log_test {
1313   my ($logfile, $testno, $resultchar) = @_;
1314
1315   open(my $fh, '>>', $logfile) or return;
1316   print $fh "$testno $resultchar\n";
1317 }
1318
1319
1320
1321 ##################################################
1322 #    Subroutine to compare one output file       #
1323 ##################################################
1324
1325 # When an Exim server is part of the test, its output is in separate files from
1326 # an Exim client. The server data is concatenated with the client data as part
1327 # of the munging operation.
1328 #
1329 # Arguments:  [0] the name of the main raw output file
1330 #             [1] the name of the server raw output file or undef
1331 #             [2] where to put the munged copy
1332 #             [3] the name of the saved file
1333 #             [4] TRUE if this is a log file whose deliveries must be sorted
1334 #             [5] optionally, a custom munge command
1335 #
1336 # Returns:    0 comparison succeeded
1337 #             1 comparison failed; differences to be ignored
1338 #             2 comparison failed; files may have been updated (=> re-compare)
1339 #
1340 # Does not return if the user replies "Q" to a prompt.
1341
1342 sub check_file{
1343 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1344
1345 # If there is no saved file, the raw files must either not exist, or be
1346 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1347
1348 # we check if there is a flavour specific file, but we remember
1349 # the original file name as "generic"
1350 $sf_generic = $sf;
1351 $sf_flavour = "$sf_generic.$flavour";
1352 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1353
1354 if (! -e $sf_current)
1355   {
1356   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1357
1358   print "\n";
1359   print "** $rf is not empty\n" if (-s $rf);
1360   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1361
1362   for (;;)
1363     {
1364     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1365     tests_exit(1) if /^q?$/;
1366     if (/^c$/ && $force_continue) {
1367       log_failure($log_failed_filename, $testno, $rf);
1368       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1369     }
1370     return 1 if /^c$/i && $rf !~ /paniclog/ && $rsf !~ /paniclog/;
1371     last if (/^[sc]$/);
1372     }
1373
1374   foreach $f ($rf, $rsf)
1375     {
1376     if (defined $f && -s $f)
1377       {
1378       print "\n";
1379       print "------------ $f -----------\n"
1380         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1381       system("$more '$f'");
1382       }
1383     }
1384
1385   print "\n";
1386   for (;;)
1387     {
1388     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1389     tests_exit(1) if /^q?$/;
1390     if (/^c$/ && $force_continue) {
1391       log_failure($log_failed_filename, $testno, $rf);
1392       log_test($log_summary_filename, $testno, 'F')
1393     }
1394     return 1 if /^c$/i;
1395     last if (/^u$/i);
1396     }
1397   }
1398
1399 #### $_
1400
1401 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1402 # was a request to create a saved file. First, create the munged file from any
1403 # data that does exist.
1404
1405 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1406 my($truncated) = munge($rf, $extra) if -e $rf;
1407
1408 # Append the raw server log, if it is non-empty
1409 if (defined $rsf && -e $rsf)
1410   {
1411   print MUNGED "\n******** SERVER ********\n";
1412   $truncated |= munge($rsf, $extra);
1413   }
1414 close(MUNGED);
1415
1416 # If a saved file exists, do the comparison. There are two awkward cases:
1417 #
1418 # If "*** truncated ***" was found in the new file, it means that a log line
1419 # was overlong, and truncated. The problem is that it may be truncated at
1420 # different points on different systems, because of different user name
1421 # lengths. We reload the file and the saved file, and remove lines from the new
1422 # file that precede "*** truncated ***" until we reach one that matches the
1423 # line that precedes it in the saved file.
1424 #
1425 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1426 # for an individual message might vary in their order from system to system, as
1427 # a result of parallel deliveries. We load the munged file and sort sequences
1428 # of delivery lines.
1429
1430 if (-e $sf_current)
1431   {
1432   # Deal with truncated text items
1433
1434   if ($truncated)
1435     {
1436     my(@munged, @saved, $i, $j, $k);
1437
1438     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1439     @munged = <MUNGED>;
1440     close(MUNGED);
1441     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1442     @saved = <SAVED>;
1443     close(SAVED);
1444
1445     $j = 0;
1446     for ($i = 0; $i < @munged; $i++)
1447       {
1448       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1449         {
1450         for (; $j < @saved; $j++)
1451           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1452         last if $j >= @saved;     # not found in saved
1453
1454         for ($k = $i - 1; $k >= 0; $k--)
1455           { last if $munged[$k] eq $saved[$j - 1]; }
1456
1457         last if $k <= 0;          # failed to find previous match
1458         splice @munged, $k + 1, $i - $k - 1;
1459         $i = $k + 1;
1460         }
1461       }
1462
1463     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1464     for ($i = 0; $i < @munged; $i++)
1465       { print MUNGED $munged[$i]; }
1466     close(MUNGED);
1467     }
1468
1469   # Deal with log sorting
1470
1471   if ($sortfile)
1472     {
1473     my(@munged, $i, $j);
1474
1475     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1476     @munged = <MUNGED>;
1477     close(MUNGED);
1478
1479     for ($i = 0; $i < @munged; $i++)
1480       {
1481       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1482         {
1483         for ($j = $i + 1; $j < @munged; $j++)
1484           {
1485           last if $munged[$j] !~
1486             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1487           }
1488         @temp = splice(@munged, $i, $j - $i);
1489         @temp = sort(@temp);
1490         splice(@munged, $i, 0, @temp);
1491         }
1492       }
1493
1494     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1495     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1496     for ($i = 0; $i < @munged; $i++)
1497       { print MUNGED $munged[$i]; }
1498     close(MUNGED);
1499     }
1500
1501   # Do the comparison
1502
1503   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1504
1505   # Handle comparison failure
1506
1507   print "** Comparison of $mf with $sf_current failed";
1508   system("$more test-cf");
1509
1510   print "\n";
1511   for (;;)
1512     {
1513     $_ = interact('Continue, Retry, Update current'
1514         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1515         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1516     tests_exit(1) if /^q?$/;
1517     if (/^c$/ && $force_continue) {
1518       log_failure($log_failed_filename, $testno, $sf_current);
1519       log_test($log_summary_filename, $testno, 'F')
1520     }
1521     return 1 if /^c$/i;
1522     return 2 if /^r$/i;
1523     last if (/^[us]$/i);
1524     }
1525   }
1526
1527 # Update or delete the saved file, and give the appropriate return code.
1528
1529 if (-s $mf)
1530   {
1531     my $sf = /^u/i ? $sf_current : $sf_flavour;
1532     tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1533   }
1534 else
1535   {
1536     # if we deal with a flavour file, we can't delete it, because next time the generic
1537     # file would be used again
1538     if ($sf_current eq $sf_flavour) {
1539       open(FOO, ">$sf_current");
1540       close(FOO);
1541     }
1542     else {
1543       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1544     }
1545   }
1546
1547 return 2;
1548 }
1549
1550
1551
1552 ##################################################
1553 # Custom munges
1554 # keyed by name of munge; value is a ref to a hash
1555 # which is keyed by file, value a string to look for.
1556 # Usable files are:
1557 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1558 # Search strings starting with 's' do substitutions;
1559 # with '/' do line-skips.
1560 # Triggered by a scriptfile line "munge <name>"
1561 ##################################################
1562 $munges =
1563   { 'dnssec' =>
1564     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1565
1566     'gnutls_unexpected' =>
1567     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1568
1569     'gnutls_handshake' =>
1570     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1571
1572     'gnutls_bad_clientcert' =>
1573     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1574       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1575     },
1576
1577     'optional_events' =>
1578     { 'stdout' => '/event_action =/' },
1579
1580     'optional_ocsp' =>
1581     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1582
1583     'optional_cert_hostnames' =>
1584     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1585
1586     'loopback' =>
1587     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1588
1589     'scanfile_size' =>
1590     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1591
1592     'delay_1500' =>
1593     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1594
1595     'tls_anycipher' =>
1596     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1597                       s! DN="C=! DN="/C=!;
1598                       s! DN="[^,"]*\K,!/!;
1599                       s! DN="[^,"]*\K,!/!;
1600                       s! DN="[^,"]*\K,!/!;
1601                      ',
1602       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1603       'mail'      => 's/ \(TLS[^)]*\)/ (TLS_proto_and_cipher)/',
1604     },
1605
1606     'debug_pid' =>
1607     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1608
1609     'optional_dsn_info' =>
1610     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1611     },
1612
1613     'optional_config' =>
1614     { 'stdout' => '/^(
1615                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1616                   |gnutls_require_(kx|mac|protocols)
1617                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1618                   |dane_require_tls_ciphers
1619                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1620                   |socks_proxy
1621                   |tls_[^ ]*
1622                   |utf8_downconvert
1623                   )($|[ ]=)/x'
1624     },
1625
1626     'sys_bindir' =>
1627     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1628
1629     'sync_check_data' =>
1630     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1631       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1632
1633     'debuglog_stdout' =>
1634     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1635                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1636     },
1637
1638     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1639     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1640
1641     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1642     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1643
1644     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1645     { 'stdout' => 's%^> X/X$%> X%' },
1646   };
1647
1648
1649 sub max {
1650   my ($a, $b) = @_;
1651   return $a if ($a > $b);
1652   return $b;
1653 }
1654
1655 ##################################################
1656 #    Subroutine to check the output of a test    #
1657 ##################################################
1658
1659 # This function is called when the series of subtests is complete. It makes
1660 # use of check_file(), whose arguments are:
1661 #
1662 #  [0] the name of the main raw output file
1663 #  [1] the name of the server raw output file or undef
1664 #  [2] where to put the munged copy
1665 #  [3] the name of the saved file
1666 #  [4] TRUE if this is a log file whose deliveries must be sorted
1667 #  [5] an optional custom munge command
1668 #
1669 # Arguments: Optionally, name of a single custom munge to run.
1670 # Returns:   0 if the output compared equal
1671 #            1 if comparison failed; differences to be ignored
1672 #            2 if re-run needed (files may have been updated)
1673
1674 sub check_output{
1675 my($mungename) = $_[0];
1676 my($yield) = 0;
1677 my($munge) = $munges->{$mungename} if defined $mungename;
1678
1679 $yield = max($yield,  check_file("spool/log/paniclog",
1680                        "spool/log/serverpaniclog",
1681                        "test-paniclog-munged",
1682                        "paniclog/$testno", 0,
1683                        $munge->{paniclog}));
1684
1685 $yield = max($yield,  check_file("spool/log/rejectlog",
1686                        "spool/log/serverrejectlog",
1687                        "test-rejectlog-munged",
1688                        "rejectlog/$testno", 0,
1689                        $munge->{rejectlog}));
1690
1691 $yield = max($yield,  check_file("spool/log/mainlog",
1692                        "spool/log/servermainlog",
1693                        "test-mainlog-munged",
1694                        "log/$testno", $sortlog,
1695                        $munge->{mainlog}));
1696
1697 if (!$stdout_skip)
1698   {
1699   $yield = max($yield,  check_file("test-stdout",
1700                        "test-stdout-server",
1701                        "test-stdout-munged",
1702                        "stdout/$testno", 0,
1703                        $munge->{stdout}));
1704   }
1705
1706 if (!$stderr_skip)
1707   {
1708   $yield = max($yield,  check_file("test-stderr",
1709                        "test-stderr-server",
1710                        "test-stderr-munged",
1711                        "stderr/$testno", 0,
1712                        $munge->{stderr}));
1713   }
1714
1715 # Compare any delivered messages, unless this test is skipped.
1716
1717 if (! $message_skip)
1718   {
1719   my($msgno) = 0;
1720
1721   # Get a list of expected mailbox files for this script. We don't bother with
1722   # directories, just the files within them.
1723
1724   foreach $oldmail (@oldmails)
1725     {
1726     next unless $oldmail =~ /^mail\/$testno\./;
1727     print ">> EXPECT $oldmail\n" if $debug;
1728     $expected_mails{$oldmail} = 1;
1729     }
1730
1731   # If there are any files in test-mail, compare them. Note that "." and
1732   # ".." are automatically omitted by list_files_below().
1733
1734   @mails = list_files_below("test-mail");
1735
1736   foreach $mail (@mails)
1737     {
1738     next if $mail eq "test-mail/oncelog";
1739
1740     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1741     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1742
1743     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1744       {
1745       $msgno++;
1746       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1747       }
1748
1749     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1750     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
1751       "mail/$testno.$saved_mail", 0,
1752       $munge->{mail}));
1753     delete $expected_mails{"mail/$testno.$saved_mail"};
1754     }
1755
1756   # Complain if not all expected mails have been found
1757
1758   if (scalar(keys %expected_mails) != 0)
1759     {
1760     foreach $key (keys %expected_mails)
1761       { print "** no test file found for $key\n"; }
1762
1763     for (;;)
1764       {
1765       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1766       tests_exit(1) if /^q?$/;
1767       if (/^c$/ && $force_continue) {
1768         log_failure($log_failed_filename, $testno, "missing email");
1769         log_test($log_summary_filename, $testno, 'F')
1770       }
1771       last if /^c$/;
1772
1773       # For update, we not only have to unlink the file, but we must also
1774       # remove it from the @oldmails vector, as otherwise it will still be
1775       # checked for when we re-run the test.
1776
1777       if (/^u$/)
1778         {
1779         foreach $key (keys %expected_mails)
1780           {
1781           my($i);
1782           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1783           for ($i = 0; $i < @oldmails; $i++)
1784             {
1785             if ($oldmails[$i] eq $key)
1786               {
1787               splice @oldmails, $i, 1;
1788               last;
1789               }
1790             }
1791           }
1792         last;
1793         }
1794       }
1795     }
1796   }
1797
1798 # Compare any remaining message logs, unless this test is skipped.
1799
1800 if (! $msglog_skip)
1801   {
1802   # Get a list of expected msglog files for this test
1803
1804   foreach $oldmsglog (@oldmsglogs)
1805     {
1806     next unless $oldmsglog =~ /^$testno\./;
1807     $expected_msglogs{$oldmsglog} = 1;
1808     }
1809
1810   # If there are any files in spool/msglog, compare them. However, we have
1811   # to munge the file names because they are message ids, which are
1812   # time dependent.
1813
1814   if (opendir(DIR, "spool/msglog"))
1815     {
1816     @msglogs = sort readdir(DIR);
1817     closedir(DIR);
1818
1819     foreach $msglog (@msglogs)
1820       {
1821       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1822       ($munged_msglog = $msglog) =~
1823         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1824           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1825       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
1826         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1827         $munge->{msglog}));
1828       delete $expected_msglogs{"$testno.$munged_msglog"};
1829       }
1830     }
1831
1832   # Complain if not all expected msglogs have been found
1833
1834   if (scalar(keys %expected_msglogs) != 0)
1835     {
1836     foreach $key (keys %expected_msglogs)
1837       {
1838       print "** no test msglog found for msglog/$key\n";
1839       ($msgid) = $key =~ /^\d+\.(.*)$/;
1840       foreach $cachekey (keys %cache)
1841         {
1842         if ($cache{$cachekey} eq $msgid)
1843           {
1844           print "** original msgid $cachekey\n";
1845           last;
1846           }
1847         }
1848       }
1849
1850     for (;;)
1851       {
1852       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1853       tests_exit(1) if /^q?$/;
1854       if (/^c$/ && $force_continue) {
1855         log_failure($log_failed_filename, $testno, "missing msglog");
1856         log_test($log_summary_filename, $testno, 'F')
1857       }
1858       last if /^c$/;
1859       if (/^u$/)
1860         {
1861         foreach $key (keys %expected_msglogs)
1862           {
1863           tests_exit(-1, "Failed to unlink msglog/$key")
1864             if !unlink("msglog/$key");
1865           }
1866         last;
1867         }
1868       }
1869     }
1870   }
1871
1872 return $yield;
1873 }
1874
1875
1876
1877 ##################################################
1878 #     Subroutine to run one "system" command     #
1879 ##################################################
1880
1881 # We put this in a subroutine so that the command can be reflected when
1882 # debugging.
1883 #
1884 # Argument: the command to be run
1885 # Returns:  nothing
1886
1887 sub run_system {
1888 my($cmd) = $_[0];
1889 if ($debug)
1890   {
1891   my($prcmd) = $cmd;
1892   $prcmd =~ s/; /;\n>> /;
1893   print ">> $prcmd\n";
1894   }
1895 system("$cmd");
1896 }
1897
1898
1899
1900 ##################################################
1901 #      Subroutine to run one script command      #
1902 ##################################################
1903
1904 # The <SCRIPT> file is open for us to read an optional return code line,
1905 # followed by the command line and any following data lines for stdin. The
1906 # command line can be continued by the use of \. Data lines are not continued
1907 # in this way. In all lines, the following substitutions are made:
1908 #
1909 # DIR    => the current directory
1910 # CALLER => the caller of this script
1911 #
1912 # Arguments: the current test number
1913 #            reference to the subtest number, holding previous value
1914 #            reference to the expected return code value
1915 #            reference to where to put the command name (for messages)
1916 #            auxiliary information returned from a previous run
1917 #
1918 # Returns:   0 the command was executed inline, no subprocess was run
1919 #            1 a non-exim command was run and waited for
1920 #            2 an exim command was run and waited for
1921 #            3 a command was run and not waited for (daemon, server, exim_lock)
1922 #            4 EOF was encountered after an initial return code line
1923 # Optionally also a second parameter, a hash-ref, with auxiliary information:
1924 #            exim_pid: pid of a run process
1925 #            munge: name of a post-script results munger
1926
1927 sub run_command{
1928 my($testno) = $_[0];
1929 my($subtestref) = $_[1];
1930 my($commandnameref) = $_[3];
1931 my($aux_info) = $_[4];
1932 my($yield) = 1;
1933
1934 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1935
1936 if (/^(\d+)\s*$/)                # Handle unusual return code
1937   {
1938   my($r) = $_[2];
1939   $$r = $1 << 8;
1940   $_ = <SCRIPT>;
1941   return 4 if !defined $_;       # Missing command
1942   $lineno++;
1943   }
1944
1945 chomp;
1946 $wait_time = 0;
1947
1948 # Handle concatenated command lines
1949
1950 s/\s+$//;
1951 while (substr($_, -1) eq"\\")
1952   {
1953   my($temp);
1954   $_ = substr($_, 0, -1);
1955   chomp($temp = <SCRIPT>);
1956   if (defined $temp)
1957     {
1958     $lineno++;
1959     $temp =~ s/\s+$//;
1960     $temp =~ s/^\s+//;
1961     $_ .= $temp;
1962     }
1963   }
1964
1965 # Do substitutions
1966
1967 do_substitute($testno);
1968 if ($debug) { printf ">> $_\n"; }
1969
1970 # Pass back the command name (for messages)
1971
1972 ($$commandnameref) = /^(\S+)/;
1973
1974 # Here follows code for handling the various different commands that are
1975 # supported by this script. The first group of commands are all freestanding
1976 # in that they share no common code and are not followed by any data lines.
1977
1978
1979 ###################
1980 ###################
1981
1982 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1983 # utility and to make DBM files for testing DBM lookups.
1984
1985 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1986   {
1987   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1988          "echo exim_dbmbuild exit code = \$?)" .
1989          ">>test-stdout");
1990   return 1;
1991   }
1992
1993
1994 # The "dump" command runs exim_dumpdb. On different systems, the output for
1995 # some types of dump may appear in a different order because it's just hauled
1996 # out of the DBM file. We can solve this by sorting. Ignore the leading
1997 # date/time, as it will be flattened later during munging.
1998
1999 if (/^dump\s+(\S+)/)
2000   {
2001   my($which) = $1;
2002   my(@temp);
2003   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2004   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
2005   open(OUT, ">>test-stdout");
2006   print OUT "+++++++++++++++++++++++++++\n";
2007
2008   if ($which eq "retry")
2009     {
2010     $/ = "\n  ";
2011     @temp = <IN>;
2012     $/ = "\n";
2013
2014     @temp = sort {
2015                    my($aa) = split(' ', $a);
2016                    my($bb) = split(' ', $b);
2017                    return $aa cmp $bb;
2018                  } @temp;
2019
2020     foreach $item (@temp)
2021       {
2022       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2023       print OUT "  $item\n";
2024       }
2025     }
2026   else
2027     {
2028     @temp = <IN>;
2029     if ($which eq "callout")
2030       {
2031       @temp = sort {
2032                    my($aa) = substr $a, 21;
2033                    my($bb) = substr $b, 21;
2034                    return $aa cmp $bb;
2035                    } @temp;
2036       }
2037     print OUT @temp;
2038     }
2039
2040   close(IN);
2041   close(OUT);
2042   return 1;
2043   }
2044
2045
2046 # verbose comments start with ###
2047 if (/^###\s/) {
2048   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2049     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2050     say {$fh} $_;
2051   }
2052   return 0;
2053 }
2054
2055 # The "echo" command is a way of writing comments to the screen.
2056 if (/^echo\s+(.*)$/)
2057   {
2058   print "$1\n";
2059   return 0;
2060   }
2061
2062
2063 # The "exim_lock" command runs exim_lock in the same manner as "server",
2064 # but it doesn't use any input.
2065
2066 if (/^exim_lock\s+(.*)$/)
2067   {
2068   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2069   $server_pid = open SERVERCMD, "|$cmd" ||
2070     tests_exit(-1, "Failed to run $cmd\n");
2071
2072   # This gives the process time to get started; otherwise the next
2073   # process may not find it there when it expects it.
2074
2075   select(undef, undef, undef, 0.1);
2076   return 3;
2077   }
2078
2079
2080 # The "exinext" command runs exinext
2081
2082 if (/^exinext\s+(.*)/)
2083   {
2084   run_system("(./eximdir/exinext " .
2085     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2086     "-C $parm_cwd/test-config $1;" .
2087     "echo exinext exit code = \$?)" .
2088     ">>test-stdout");
2089   return 1;
2090   }
2091
2092
2093 # The "exigrep" command runs exigrep on the current mainlog
2094
2095 if (/^exigrep\s+(.*)/)
2096   {
2097   run_system("(./eximdir/exigrep " .
2098     "$1 $parm_cwd/spool/log/mainlog;" .
2099     "echo exigrep exit code = \$?)" .
2100     ">>test-stdout");
2101   return 1;
2102   }
2103
2104
2105 # The "eximstats" command runs eximstats on the current mainlog
2106
2107 if (/^eximstats\s+(.*)/)
2108   {
2109   run_system("(./eximdir/eximstats " .
2110     "$1 $parm_cwd/spool/log/mainlog;" .
2111     "echo eximstats exit code = \$?)" .
2112     ">>test-stdout");
2113   return 1;
2114   }
2115
2116
2117 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2118 # spool directory, to save Exim from re-creating it each time.
2119
2120 if (/^gnutls/)
2121   {
2122   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2123   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2124          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2125          "sudo chmod 0400 $gen_fn";
2126   return 1;
2127   }
2128
2129
2130 # The "killdaemon" command should ultimately follow the starting of any Exim
2131 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
2132 # it outputting "Terminated" to the terminal when not in the background.
2133
2134 if (/^killdaemon/)
2135   {
2136   my $return_extra = {};
2137   if (exists $aux_info->{exim_pid})
2138     {
2139     $pid = $aux_info->{exim_pid};
2140     $return_extra->{exim_pid} = undef;
2141     print ">> killdaemon: recovered pid $pid\n" if $debug;
2142     if ($pid)
2143       {
2144       run_system("sudo /bin/kill -INT $pid");
2145       wait;
2146       }
2147     } else {
2148     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2149     if ($pid)
2150       {
2151       run_system("sudo /bin/kill -INT $pid");
2152       close DAEMONCMD;                                   # Waits for process
2153       }
2154     }
2155     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2156   return (1, $return_extra);
2157   }
2158
2159
2160 # The "millisleep" command is like "sleep" except that its argument is in
2161 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2162 # is used for.
2163
2164 elsif (/^millisleep\s+(.*)$/)
2165   {
2166   select(undef, undef, undef, $1/1000);
2167   return 0;
2168   }
2169
2170
2171 # The "munge" command selects one of a hardwired set of test-result modifications
2172 # to be made before result compares are run agains the golden set.  This lets
2173 # us account for test-system dependent things which only affect a few, but known,
2174 # test-cases.
2175 # Currently only the last munge takes effect.
2176
2177 if (/^munge\s+(.*)$/)
2178   {
2179   return (0, { munge => $1 });
2180   }
2181
2182
2183 # The "sleep" command does just that. For sleeps longer than 1 second we
2184 # tell the user what's going on.
2185
2186 if (/^sleep\s+(.*)$/)
2187   {
2188   if ($1 == 1)
2189     {
2190     sleep(1);
2191     }
2192   else
2193     {
2194     printf("  Test %d sleep $1 ", $$subtestref);
2195     for (1..$1)
2196       {
2197       print ".";
2198       sleep(1);
2199       }
2200     printf("\r  Test %d                            $cr", $$subtestref);
2201     }
2202   return 0;
2203   }
2204
2205
2206 # Various Unix management commands are recognized
2207
2208 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2209     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2210   {
2211   run_system("$_ >>test-stdout 2>>test-stderr");
2212   return 1;
2213   }
2214
2215
2216
2217 ###################
2218 ###################
2219
2220 # The next group of commands are also freestanding, but they are all followed
2221 # by data lines.
2222
2223
2224 # The "server" command starts up a script-driven server that runs in parallel
2225 # with the following exim command. Therefore, we want to run a subprocess and
2226 # not yet wait for it to complete. The waiting happens after the next exim
2227 # command, triggered by $server_pid being non-zero. The server sends its output
2228 # to a different file. The variable $server_opts, if not empty, contains
2229 # options to disable IPv4 or IPv6 if necessary.
2230 # This works because "server" swallows its stdin before waiting for a connection.
2231
2232 if (/^server\s+(.*)$/)
2233   {
2234   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2235   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2236   print ">> $cmd\n" if ($debug);
2237   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2238   SERVERCMD->autoflush(1);
2239   print ">> Server pid is $server_pid\n" if $debug;
2240   while (<SCRIPT>)
2241     {
2242     $lineno++;
2243     last if /^\*{4}\s*$/;
2244     print SERVERCMD;
2245     }
2246   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2247                             # because close() waits for the process.
2248
2249   # Interlock the server startup; otherwise the next
2250   # process may not find it there when it expects it.
2251   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2252   return 3;
2253   }
2254
2255
2256 # The "write" command is a way of creating files of specific sizes for
2257 # buffering tests, or containing specific data lines from within the script
2258 # (rather than hold lots of little files). The "catwrite" command does the
2259 # same, but it also copies the lines to test-stdout.
2260
2261 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2262   {
2263   my($cat) = defined $1;
2264   @sizes = ();
2265   @sizes = split /\s+/, $3 if defined $3;
2266   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2267
2268   if ($cat)
2269     {
2270     open CAT, ">>test-stdout" ||
2271       tests_exit(-1, "Failed to open test-stdout: $!");
2272     print CAT "==========\n";
2273     }
2274
2275   if (scalar @sizes > 0)
2276     {
2277     # Pre-data
2278
2279     while (<SCRIPT>)
2280       {
2281       $lineno++;
2282       last if /^\+{4}\s*$/;
2283       print FILE;
2284       print CAT if $cat;
2285       }
2286
2287     # Sized data
2288
2289     while (scalar @sizes > 0)
2290       {
2291       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2292       $leadin = '' if !defined $leadin;
2293       $leadin =~ s/_/ /g;
2294       $len -= length($leadin) + 1;
2295       while ($count-- > 0)
2296         {
2297         print FILE $leadin, "a" x $len, "\n";
2298         print CAT $leadin, "a" x $len, "\n" if $cat;
2299         }
2300       }
2301     }
2302
2303   # Post data, or only data if no sized data
2304
2305   while (<SCRIPT>)
2306     {
2307     $lineno++;
2308     last if /^\*{4}\s*$/;
2309     print FILE;
2310     print CAT if $cat;
2311     }
2312   close FILE;
2313
2314   if ($cat)
2315     {
2316     print CAT "==========\n";
2317     close CAT;
2318     }
2319
2320   return 0;
2321   }
2322
2323
2324 ###################
2325 ###################
2326
2327 # From this point on, script commands are implemented by setting up a shell
2328 # command in the variable $cmd. Shared code to run this command and handle its
2329 # input and output follows.
2330
2331 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2332 # program that plays the part of an email client. We also have the availability
2333 # of running Perl for doing one-off special things. Note that all these
2334 # commands expect stdin data to be supplied.
2335
2336 if (/^client/ || /^(sudo\s+)?perl\b/)
2337   {
2338   s"client"./bin/client";
2339   $cmd = "$_ >>test-stdout 2>>test-stderr";
2340   }
2341
2342 # For the "exim" command, replace the text "exim" with the path for the test
2343 # binary, plus -D options to pass over various parameters, and a -C option for
2344 # the testing configuration file. When running in the test harness, Exim does
2345 # not drop privilege when -C and -D options are present. To run the exim
2346 # command as root, we use sudo.
2347
2348 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2349   {
2350   $args = $6;
2351   my($envset) = (defined $1)? $1      : '';
2352   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2353   my($special)= (defined $5)? $5      : '';
2354   $wait_time  = (defined $2)? $2      : 0;
2355
2356   # Return 2 rather than 1 afterwards
2357
2358   $yield = 2;
2359
2360   # Update the test number
2361
2362   $$subtestref = $$subtestref + 1;
2363   printf("  Test %d       $cr", $$subtestref);
2364
2365   # Copy the configuration file, making the usual substitutions.
2366
2367   open (IN, "$parm_cwd/confs/$testno") ||
2368     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2369   open (OUT, ">test-config") ||
2370     tests_exit(-1, "Couldn't open test-config: $!\n");
2371   while (<IN>)
2372     {
2373     do_substitute($testno);
2374     print OUT;
2375     }
2376   close(IN);
2377   close(OUT);
2378
2379   # The string $msg1 in args substitutes the message id of the first
2380   # message on the queue, and so on. */
2381
2382   if ($args =~ /\$msg/)
2383     {
2384     my @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2385                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2386                    -C => "$parm_cwd/test-config");
2387     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2388     # We need the message ids sorted in ascending order.
2389     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2390     # PIDs are randomized, so sorting just the whole PID doesn't work.
2391     # We do the Schartz' transformation here (sort on
2392     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2393     my @msglist =
2394       map { $_->[1] }                                   # extract the values
2395       sort { $a->[0] cmp $b->[0] }                      # sort by key
2396       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2397       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2398
2399     # Done backwards just in case there are more than 9
2400
2401     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2402     if ( $args =~ /\$msg\d/ )
2403       {
2404       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2405         unless $force_continue;
2406       }
2407     }
2408
2409   # If -d is specified in $optargs, remove it from $args; i.e. let
2410   # the command line for runtest override. Then run Exim.
2411
2412   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2413
2414   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2415
2416   $cmd = "$envset$sudo$opt_valgrind" .
2417          "$parm_cwd/eximdir/exim$special$optargs " .
2418          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2419          "-C $parm_cwd/test-config $args " .
2420          ">>test-stdout 2>>test-stderr";
2421   # If the command is starting an Exim daemon, we run it in the same
2422   # way as the "server" command above, that is, we don't want to wait
2423   # for the process to finish. That happens when "killdaemon" is obeyed later
2424   # in the script. We also send the stderr output to test-stderr-server. The
2425   # daemon has its log files put in a different place too (by configuring with
2426   # log_file_path). This requires the  directory to be set up in advance.
2427   #
2428   # There are also times when we want to run a non-daemon version of Exim
2429   # (e.g. a queue runner) with the server configuration. In this case,
2430   # we also define -DNOTDAEMON.
2431
2432   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2433     {
2434     if ($debug) { printf ">> daemon: $cmd\n"; }
2435     run_system("sudo mkdir spool/log 2>/dev/null");
2436     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2437
2438     # Before running the command, convert the -bd option into -bdf so that an
2439     # Exim daemon doesn't double fork. This means that when we wait close
2440     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2441     # file is written to the spool directory, in case the Exim binary was
2442     # built with PID_FILE_PATH pointing somewhere else.
2443
2444     if ($cmd =~ /\s-oP\s/)
2445       {
2446       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2447       $cmd =~ s!\s-bd\s! -bdf !;
2448       }
2449     else
2450       {
2451       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2452       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2453       }
2454     print ">> |${cmd}-server\n" if ($debug);
2455     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2456     DAEMONCMD->autoflush(1);
2457     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2458
2459     # Interlock with daemon startup
2460     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2461       { select(undef, undef, undef, 0.3); }
2462     return 3;                                     # Don't wait
2463     }
2464   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2465     {
2466
2467     # The port and the $dynamic_socket was already allocated while parsing the
2468     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2469
2470     my $listen_port = $1;
2471     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2472     run_system("sudo mkdir spool/log 2>/dev/null");
2473     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2474
2475     my $pid = fork();
2476     if (not defined $pid) { die "** fork failed: $!\n" }
2477     if (not $pid) {
2478       close(STDIN);
2479       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2480       close($dynamic_socket);
2481       print "[$$]>> ${cmd}-server\n" if ($debug);
2482       exec "exec ${cmd}-server";
2483       die "Can't exec ${cmd}-server: $!\n";
2484     }
2485     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2486     select(undef, undef, undef, 0.3);             # Let the daemon get going
2487     return (3, { exim_pid => $pid });             # Don't wait
2488     }
2489   }
2490
2491 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2492 # One script line is read and fork-exec'd.  The PID is stored for a later
2493 # killdaemon.
2494
2495 elsif (/^background$/)
2496   {
2497   my $line;
2498 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2499
2500   $_ = <SCRIPT>; $lineno++;
2501   chomp;
2502   do_substitute($testno);
2503   $line = $_;
2504   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2505
2506   my $pid = fork();
2507   if (not defined $pid) { die "** fork failed: $!\n" }
2508   if (not $pid) {
2509     print "[$$]>> ${line}\n" if ($debug);
2510     close(STDIN);
2511     open(STDIN, "<", "test-stdout");
2512     close(STDOUT);
2513     open(STDOUT, ">>", "test-stdout");
2514     close(STDERR);
2515     open(STDERR, ">>", "test-stderr-server");
2516     exec "exec ${line}";
2517     exit(1);
2518   }
2519
2520 #  open(my $fh, ">", $pidfile) ||
2521 #      tests_exit(-1, "Failed to open $pidfile: $!");
2522 #  printf($fh, "%d\n", $pid);
2523 #  close($fh);
2524
2525   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2526   select(undef, undef, undef, 0.3);             # Let the daemon get going
2527   return (3, { exim_pid => $pid });             # Don't wait
2528   }
2529
2530
2531
2532 # Unknown command
2533
2534 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2535
2536
2537 # Run the command, with stdin connected to a pipe, and write the stdin data
2538 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2539 # the terminating newline (and the \NONL\). If the command contains
2540 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2541 # for the stderr file. See comment above about the use of -DSERVER.
2542
2543 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2544 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2545 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2546
2547 CMD->autoflush(1);
2548 while (<SCRIPT>)
2549   {
2550   $lineno++;
2551   last if /^\*{4}\s*$/;
2552   do_substitute($testno);
2553   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2554   }
2555
2556 # For timeout tests, wait before closing the pipe; we expect a
2557 # SIGPIPE error in this case.
2558
2559 if ($wait_time > 0)
2560   {
2561   printf("  Test %d sleep $wait_time ", $$subtestref);
2562   while ($wait_time-- > 0)
2563     {
2564     print ".";
2565     sleep(1);
2566     }
2567   printf("\r  Test %d                                       $cr", $$subtestref);
2568   }
2569
2570 $sigpipehappened = 0;
2571 close CMD;                # Waits for command to finish
2572 return $yield;            # Ran command and waited
2573 }
2574
2575
2576
2577
2578 ###############################################################################
2579 ###############################################################################
2580
2581 # Here begins the Main Program ...
2582
2583 ###############################################################################
2584 ###############################################################################
2585
2586
2587 autoflush STDOUT 1;
2588 print "Exim tester $testversion\n";
2589
2590 # extend the PATH with .../sbin
2591 # we map all (.../bin) to (.../sbin:.../bin)
2592 $ENV{PATH} = do {
2593   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2594   join ':' => map { m{(.*)/bin$}
2595                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2596                 : ($_) }
2597       split /:/, $ENV{PATH};
2598 };
2599
2600 ##################################################
2601 #      Some tests check created file modes       #
2602 ##################################################
2603
2604 umask 022;
2605
2606
2607 ##################################################
2608 #       Check for the "less" command             #
2609 ##################################################
2610
2611 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2612
2613
2614
2615 ##################################################
2616 #      See if an Exim binary has been given      #
2617 ##################################################
2618
2619 # If the first character of the first argument is '/', the argument is taken
2620 # as the path to the binary. If the first argument does not start with a
2621 # '/' but exists in the file system, it's assumed to be the Exim binary.
2622
2623
2624 ##################################################
2625 # Sort out options and which tests are to be run #
2626 ##################################################
2627
2628 # There are a few possible options for the test script itself; after these, any
2629 # options are passed on to Exim calls within the tests. Typically, this is used
2630 # to turn on Exim debugging while setting up a test.
2631
2632 Getopt::Long::Configure qw(no_getopt_compat);
2633 GetOptions(
2634     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2635     'diff'     => sub { $cf             = 'diff -u' },
2636     'continue' => sub { $force_continue = 1; $more = 'cat' },
2637     'update'   => \$force_update,
2638     'ipv4!'    => \$have_ipv4,
2639     'ipv6!'    => \$have_ipv6,
2640     'keep'     => \$save_output,
2641     'slow'     => \$slow,
2642     'valgrind' => \$valgrind,
2643     'range=s{2}'       => \my @range_wanted,
2644     'test=i@'          => \my @tests_wanted,
2645     'flavor|flavour=s' => $flavour,
2646     'help'             => sub { pod2usage(-exit => 0) },
2647     'man'              => sub {
2648         pod2usage(
2649             -exit      => 0,
2650             -verbose   => 2,
2651             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
2652         );
2653     },
2654 ) or pod2usage;
2655
2656 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2657 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
2658
2659
2660 my @wanted = sort numerically uniq
2661   @tests_wanted ? @tests_wanted : (),
2662   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
2663   @ARGV ? @ARGV == 1 ? $ARGV[0] :
2664           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
2665           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
2666         : ();
2667 @wanted = 1..TEST_TOP if not @wanted;
2668
2669 ##################################################
2670 #        Check for sudo access to root           #
2671 ##################################################
2672
2673 print "You need to have sudo access to root to run these tests. Checking ...\n";
2674 if (system('sudo true >/dev/null') != 0)
2675   {
2676   die "** Test for sudo failed: testing abandoned.\n";
2677   }
2678 else
2679   {
2680   print "Test for sudo OK\n";
2681   }
2682
2683
2684
2685
2686 ##################################################
2687 #      Make the command's directory current      #
2688 ##################################################
2689
2690 # After doing so, we find its absolute path name.
2691
2692 $cwd = $0;
2693 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2694 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2695 $parm_cwd = Cwd::getcwd();
2696
2697
2698 ##################################################
2699 #     Search for an Exim binary to test          #
2700 ##################################################
2701
2702 # If an Exim binary hasn't been provided, try to find one. We can handle the
2703 # case where exim-testsuite is installed alongside Exim source directories. For
2704 # PH's private convenience, if there's a directory just called "exim4", that
2705 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2706 # releases.
2707
2708 # If $parm_exim is still empty, ask the caller
2709
2710 if (not $parm_exim)
2711   {
2712   print "** Did not find an Exim binary to test\n";
2713   for ($i = 0; $i < 5; $i++)
2714     {
2715     my($trybin);
2716     print "** Enter pathname for Exim binary: ";
2717     chomp($trybin = <STDIN>);
2718     if (-e $trybin)
2719       {
2720       $parm_exim = $trybin;
2721       last;
2722       }
2723     else
2724       {
2725       print "** $trybin does not exist\n";
2726       }
2727     }
2728   die "** Too many tries\n" if $parm_exim eq '';
2729   }
2730
2731
2732
2733 ##################################################
2734 #          Find what is in the binary            #
2735 ##################################################
2736
2737 # deal with TRUSTED_CONFIG_LIST restrictions
2738 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2739 open (IN, "$parm_cwd/confs/0000") ||
2740   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2741 open (OUT, ">test-config") ||
2742   tests_exit(-1, "Couldn't open test-config: $!\n");
2743 while (<IN>) { print OUT; }
2744 close(IN);
2745 close(OUT);
2746
2747 print("Probing with config file: $parm_cwd/test-config\n");
2748
2749 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
2750 chomp(my @eximinfo = `$eximinfo 2>&1`);
2751 die "$0: Can't run $eximinfo\n" if $? == -1;
2752
2753 warn 'Got ' . $?>>8 . " from $eximinfo\n" if $?;
2754 foreach (@eximinfo)
2755   {
2756   if (my ($version) = /^Exim version (\S+)/) {
2757     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2758     if (defined $git and $? == 0) {
2759       chomp $git;
2760       $version =~ s/^\d+\K\./_/;
2761       $git =~ s/^exim-//i;
2762       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2763       print <<___
2764
2765 *** Version mismatch
2766 *** Exim binary: $version
2767 *** Git        : $git
2768
2769 ___
2770         if not $version eq $git;
2771     }
2772   }
2773   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2774   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2775   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2776   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2777         if /^Configure owner:\s*(\d+):(\d+)/;
2778   print if /wrong owner/;
2779   }
2780
2781 if (not defined $parm_eximuser) {
2782   die <<XXX, map { "|$_\n" } @eximinfo;
2783 Unable to extract exim_user from binary.
2784 Check if Exim refused to run; if so, consider:
2785   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
2786 If debug permission denied, are you in the exim group?
2787 Failing to get information from binary.
2788 Output from $eximinfo:
2789 XXX
2790
2791 }
2792
2793 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2794 else { $parm_exim_uid = getpwnam($parm_eximuser); }
2795
2796 if (defined $parm_eximgroup)
2797   {
2798   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2799     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2800   }
2801
2802 # check the permissions on the TRUSTED_CONFIG_LIST
2803 if (defined $parm_trusted_config_list)
2804   {
2805   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2806     if not -f $parm_trusted_config_list;
2807
2808   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2809     if 02 & (stat _)[2];
2810
2811   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2812   (stat _)[1],
2813     scalar(getgrgid 0), scalar(getgrgid $>)
2814     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2815
2816   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2817   scalar(getpwuid 0), scalar(getpwuid $>)
2818      if (not (-o _ or (stat _)[4] == 0));
2819
2820   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2821   my $test_config = getcwd() . '/test-config';
2822   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2823   if not grep { /^\Q$test_config\E$/ } <TCL>;
2824   }
2825 else
2826   {
2827   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2828   }
2829
2830 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2831         if $parm_configure_owner != $>;
2832
2833 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2834         if 0020 & (stat "$parm_cwd/test-config")[2]
2835         and $parm_configure_group != $);
2836
2837 die "aux-fixed file is world-writeable; best to strip them all, recursively\n"
2838         if 0020 & (stat "aux-fixed/0037.f-1")[2];
2839
2840
2841 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2842   die "** Cannot run $parm_exim: $!\n";
2843
2844 print "-" x 78, "\n";
2845
2846 while (<EXIMINFO>)
2847   {
2848   my(@temp);
2849
2850   if (/^(Exim|Library) version/) { print; }
2851   if (/Runtime: /) {print; }
2852
2853   elsif (/^Size of off_t: (\d+)/)
2854     {
2855     print;
2856     $have_largefiles = 1 if $1 > 4;
2857     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2858         if ($1 > 32);
2859     }
2860
2861   elsif (/^Support for: (.*)/)
2862     {
2863     print;
2864     @temp = split /(\s+)/, $1;
2865     push(@temp, ' ');
2866     %parm_support = @temp;
2867     }
2868
2869   elsif (/^Lookups \(built-in\): (.*)/)
2870     {
2871     print;
2872     @temp = split /(\s+)/, $1;
2873     push(@temp, ' ');
2874     %parm_lookups = @temp;
2875     }
2876
2877   elsif (/^Authenticators: (.*)/)
2878     {
2879     print;
2880     @temp = split /(\s+)/, $1;
2881     push(@temp, ' ');
2882     %parm_authenticators = @temp;
2883     }
2884
2885   elsif (/^Routers: (.*)/)
2886     {
2887     print;
2888     @temp = split /(\s+)/, $1;
2889     push(@temp, ' ');
2890     %parm_routers = @temp;
2891     }
2892
2893   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2894   # that the basic transport name is set, and then the name with each of the
2895   # options.
2896
2897   elsif (/^Transports: (.*)/)
2898     {
2899     print;
2900     @temp = split /(\s+)/, $1;
2901     my($i,$k);
2902     push(@temp, ' ');
2903     %parm_transports = @temp;
2904     foreach $k (keys %parm_transports)
2905       {
2906       if ($k =~ "/")
2907         {
2908         @temp = split /\//, $k;
2909         $parm_transports{$temp[0]} = " ";
2910         for ($i = 1; $i < @temp; $i++)
2911           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2912         }
2913       }
2914     }
2915
2916   elsif (/^Malware: (.*)/)
2917     {
2918     print;
2919     @temp = split /(\s+)/, $1;
2920     push(@temp, ' ');
2921     %parm_malware = @temp;
2922     }
2923
2924   }
2925 close(EXIMINFO);
2926 print "-" x 78, "\n";
2927
2928 unlink("$parm_cwd/test-config");
2929
2930 ##################################################
2931 #    Check for SpamAssassin and ClamAV           #
2932 ##################################################
2933
2934 # These are crude tests. If they aren't good enough, we'll have to improve
2935 # them, for example by actually passing a message through spamc or clamscan.
2936
2937 if (defined $parm_support{Content_Scanning})
2938   {
2939   my $sock = new FileHandle;
2940
2941   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2942     {
2943     print "The spamc command works:\n";
2944
2945     # This test for an active SpamAssassin is courtesy of John Jetmore.
2946     # The tests are hard coded to localhost:783, so no point in making
2947     # this test flexible like the clamav test until the test scripts are
2948     # changed.  spamd doesn't have the nice PING/PONG protocol that
2949     # clamd does, but it does respond to errors in an informative manner,
2950     # so use that.
2951
2952     my($sint,$sport) = ('127.0.0.1',783);
2953     eval
2954       {
2955       my $sin = sockaddr_in($sport, inet_aton($sint))
2956           or die "** Failed packing $sint:$sport\n";
2957       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2958           or die "** Unable to open socket $sint:$sport\n";
2959
2960       local $SIG{ALRM} =
2961           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2962       alarm(5);
2963       connect($sock, $sin)
2964           or die "** Unable to connect to socket $sint:$sport\n";
2965       alarm(0);
2966
2967       select((select($sock), $| = 1)[0]);
2968       print $sock "bad command\r\n";
2969
2970       $SIG{ALRM} =
2971           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2972       alarm(10);
2973       my $res = <$sock>;
2974       alarm(0);
2975
2976       $res =~ m|^SPAMD/|
2977           or die "** Did not get SPAMD from socket $sint:$sport. "
2978                 ."It said: $res\n";
2979       };
2980     alarm(0);
2981     if($@)
2982       {
2983       print "  $@";
2984       print "  Assume SpamAssassin (spamd) is not running\n";
2985       }
2986     else
2987       {
2988       $parm_running{SpamAssassin} = ' ';
2989       print "  SpamAssassin (spamd) seems to be running\n";
2990       }
2991     }
2992   else
2993     {
2994     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2995     }
2996
2997   # For ClamAV, we need to find the clamd socket for use in the Exim
2998   # configuration. Search for the clamd configuration file.
2999
3000   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3001     {
3002     my($f, $clamconf, $test_prefix);
3003
3004     print "The clamscan command works";
3005
3006     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3007     $test_prefix = '' if !defined $test_prefix;
3008
3009     foreach $f ("$test_prefix/etc/clamd.conf",
3010                 "$test_prefix/usr/local/etc/clamd.conf",
3011                 "$test_prefix/etc/clamav/clamd.conf", '')
3012       {
3013       if (-e $f)
3014         {
3015         $clamconf = $f;
3016         last;
3017         }
3018       }
3019
3020     # Read the ClamAV configuration file and find the socket interface.
3021
3022     if ($clamconf ne '')
3023       {
3024       my $socket_domain;
3025       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3026       while (<IN>)
3027         {
3028         if (/^LocalSocket\s+(.*)/)
3029           {
3030           $parm_clamsocket = $1;
3031           $socket_domain = AF_UNIX;
3032           last;
3033           }
3034         if (/^TCPSocket\s+(\d+)/)
3035           {
3036           if (defined $parm_clamsocket)
3037             {
3038             $parm_clamsocket .= " $1";
3039             $socket_domain = AF_INET;
3040             last;
3041             }
3042           else
3043             {
3044             $parm_clamsocket = " $1";
3045             }
3046           }
3047         elsif (/^TCPAddr\s+(\S+)/)
3048           {
3049           if (defined $parm_clamsocket)
3050             {
3051             $parm_clamsocket = $1 . $parm_clamsocket;
3052             $socket_domain = AF_INET;
3053             last;
3054             }
3055           else
3056             {
3057             $parm_clamsocket = $1;
3058             }
3059           }
3060         }
3061       close(IN);
3062
3063       if (defined $socket_domain)
3064         {
3065         print ":\n  The clamd socket is $parm_clamsocket\n";
3066         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3067         eval
3068           {
3069           my $socket;
3070           if ($socket_domain == AF_UNIX)
3071             {
3072             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3073             }
3074           elsif ($socket_domain == AF_INET)
3075             {
3076             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3077             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3078             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3079             }
3080           else
3081             {
3082             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3083             }
3084           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3085           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3086           alarm(5);
3087           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3088           alarm(0);
3089
3090           my $ofh = select $sock; $| = 1; select $ofh;
3091           print $sock "PING\n";
3092
3093           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3094           alarm(10);
3095           my $res = <$sock>;
3096           alarm(0);
3097
3098           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3099           };
3100         alarm(0);
3101
3102         if($@)
3103           {
3104           print "  $@";
3105           print "  Assume ClamAV is not running\n";
3106           }
3107         else
3108           {
3109           $parm_running{ClamAV} = ' ';
3110           print "  ClamAV seems to be running\n";
3111           }
3112         }
3113       else
3114         {
3115         print ", but the socket for clamd could not be determined\n";
3116         print "Assume ClamAV is not running\n";
3117         }
3118       }
3119
3120     else
3121       {
3122       print ", but I can't find a configuration for clamd\n";
3123       print "Assume ClamAV is not running\n";
3124       }
3125     }
3126   }
3127
3128
3129 ##################################################
3130 #       Check for redis                          #
3131 ##################################################
3132 if (defined $parm_lookups{redis})
3133   {
3134   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3135     {
3136     print "The redis-server command works\n";
3137     $parm_running{redis} = ' ';
3138     }
3139   else
3140     {
3141     print "The redis-server command failed: assume Redis not installed\n";
3142     }
3143   }
3144
3145 ##################################################
3146 #         Test for the basic requirements        #
3147 ##################################################
3148
3149 # This test suite assumes that Exim has been built with at least the "usual"
3150 # set of routers, transports, and lookups. Ensure that this is so.
3151
3152 $missing = '';
3153
3154 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3155
3156 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3157 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3158 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3159 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3160
3161 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3162 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3163 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3164 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3165
3166 if ($missing ne '')
3167   {
3168   print "\n";
3169   print "** Many features can be included or excluded from Exim binaries.\n";
3170   print "** This test suite requires that Exim is built to contain a certain\n";
3171   print "** set of basic facilities. It seems that some of these are missing\n";
3172   print "** from the binary that is under test, so the test cannot proceed.\n";
3173   print "** The missing facilities are:\n";
3174   print "$missing";
3175   die "** Test script abandoned\n";
3176   }
3177
3178
3179 ##################################################
3180 #      Check for the auxiliary programs          #
3181 ##################################################
3182
3183 # These are always required:
3184
3185 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3186            "fakens", "iefbr14", "server")
3187   {
3188   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3189   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3190   if (!-e "bin/$prog")
3191     {
3192     print "\n";
3193     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3194     die "** Test script abandoned\n";
3195     }
3196   }
3197
3198 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3199 # compiled on systems where we don't know how to. However, if Exim does not
3200 # have that functionality compiled, we needn't bother.
3201
3202 $dlfunc_deleted = 0;
3203 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3204   {
3205   delete $parm_support{Expand_dlfunc};
3206   $dlfunc_deleted = 1;
3207   }
3208
3209
3210 ##################################################
3211 #          Find environmental details            #
3212 ##################################################
3213
3214 # Find the caller of this program.
3215
3216 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3217  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3218
3219 $pwpw = $pwpw;       # Kill Perl warnings
3220 $pwquota = $pwquota;
3221 $pwcomm = $pwcomm;
3222
3223 $parm_caller_group = getgrgid($parm_caller_gid);
3224
3225 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3226 print "Home directory is $parm_caller_home\n";
3227
3228 unless (defined $parm_eximgroup)
3229   {
3230   print "Unable to derive \$parm_eximgroup.\n";
3231   die "** ABANDONING.\n";
3232   }
3233
3234 if ($parm_caller_home eq $parm_cwd)
3235   {
3236   print "will confuse working dir with homedir; change homedir\n";
3237   die "** ABANDONING.\n";
3238   }
3239
3240 print "You need to be in the Exim group to run these tests. Checking ...";
3241
3242 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3243   {
3244   print " OK\n";
3245   }
3246 else
3247   {
3248   print "\nOh dear, you are not in the Exim group.\n";
3249   die "** Testing abandoned.\n";
3250   }
3251
3252 # Find this host's IP addresses - there may be many, of course, but we keep
3253 # one of each type (IPv4 and IPv6).
3254
3255 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3256   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3257 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3258   {
3259   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3260     {
3261     next if $1 =~ /^(?:127|10)\./;
3262     $parm_ipv4 = $1;
3263     }
3264
3265   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3266     {
3267     next if $1 eq '::1' or $1 =~ /^fe80/i;
3268     $parm_ipv6 = $1;
3269     }
3270   }
3271 close(IFCONFIG);
3272
3273 # Use private IP addresses if there are no public ones.
3274
3275 # If either type of IP address is missing, we need to set the value to
3276 # something other than empty, because that wrecks the substitutions. The value
3277 # is reflected, so use a meaningful string. Set appropriate options for the
3278 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3279 # available, so things will go wrong if there is no IPv4 address. The lack
3280 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3281 # and $have_ipv6 false.
3282
3283 if (not $parm_ipv4)
3284   {
3285   $have_ipv4 = 0;
3286   $parm_ipv4 = "<no IPv4 address found>";
3287   $server_opts .= " -noipv4";
3288   }
3289 elsif ($have_ipv4 == 0)
3290   {
3291   $parm_ipv4 = "<IPv4 testing disabled>";
3292   $server_opts .= " -noipv4";
3293   }
3294 else
3295   {
3296   $parm_running{IPv4} = " ";
3297   }
3298
3299 if (not $parm_ipv6)
3300   {
3301   $have_ipv6 = 0;
3302   $parm_ipv6 = "<no IPv6 address found>";
3303   $server_opts .= " -noipv6";
3304   delete($parm_support{IPv6});
3305   }
3306 elsif ($have_ipv6 == 0)
3307   {
3308   $parm_ipv6 = "<IPv6 testing disabled>";
3309   $server_opts .= " -noipv6";
3310   delete($parm_support{IPv6});
3311   }
3312 elsif (!defined $parm_support{IPv6})
3313   {
3314   $have_ipv6 = 0;
3315   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3316   $server_opts .= " -noipv6";
3317   }
3318 else
3319   {
3320   $parm_running{IPv6} = " ";
3321   }
3322
3323 print "IPv4 address is $parm_ipv4\n";
3324 print "IPv6 address is $parm_ipv6\n";
3325
3326 # For munging test output, we need the reversed IP addresses.
3327
3328 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3329   join(".", reverse(split /\./, $parm_ipv4));
3330
3331 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3332 if ($parm_ipv6 =~ /^[\da-f]/)
3333   {
3334   my(@comps) = split /:/, $parm_ipv6;
3335   my(@nibbles);
3336   foreach $comp (@comps)
3337     {
3338     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3339     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3340     }
3341   $parm_ipv6r = join(".", reverse(@nibbles));
3342   }
3343
3344 # Find the host name, fully qualified.
3345
3346 chomp($temp = `hostname`);
3347 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3348 if ($temp =~ /\./)
3349   {
3350   $parm_hostname = $temp;
3351   }
3352 else
3353   {
3354   $parm_hostname = (gethostbyname($temp))[0];
3355   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3356   }
3357 print "Hostname is $parm_hostname\n";
3358
3359 if ($parm_hostname !~ /\./)
3360   {
3361   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3362   }
3363
3364 if ($parm_hostname =~ /[[:upper:]]/)
3365   {
3366   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3367   }
3368
3369
3370
3371 ##################################################
3372 #     Create a testing version of Exim           #
3373 ##################################################
3374
3375 # We want to be able to run Exim with a variety of configurations. Normally,
3376 # the use of -C to change configuration causes Exim to give up its root
3377 # privilege (unless the caller is exim or root). For these tests, we do not
3378 # want this to happen. Also, we want Exim to know that it is running in its
3379 # test harness.
3380
3381 # We achieve this by copying the binary and patching it as we go. The new
3382 # binary knows it is a testing copy, and it allows -C and -D without loss of
3383 # privilege. Clearly, this file is dangerous to have lying around on systems
3384 # where there are general users with login accounts. To protect against this,
3385 # we put the new binary in a special directory that is accessible only to the
3386 # caller of this script, who is known to have sudo root privilege from the test
3387 # that was done above. Furthermore, we ensure that the binary is deleted at the
3388 # end of the test. First ensure the directory exists.
3389
3390 if (-d "eximdir")
3391   { unlink "eximdir/exim"; }     # Just in case
3392 else
3393   {
3394   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3395   system("sudo chgrp $parm_eximgroup eximdir");
3396   }
3397
3398 # The construction of the patched binary must be done as root, so we use
3399 # a separate script. As well as indicating that this is a test-harness binary,
3400 # the version number is patched to "x.yz" so that its length is always the
3401 # same. Otherwise, when it appears in Received: headers, it affects the length
3402 # of the message, which breaks certain comparisons.
3403
3404 die "** Unable to make patched exim: $!\n"
3405   if (system("sudo ./patchexim $parm_exim") != 0);
3406
3407 # From this point on, exits from the program must go via the subroutine
3408 # tests_exit(), so that suitable cleaning up can be done when required.
3409 # Arrange to catch interrupting signals, to assist with this.
3410
3411 $SIG{INT} = \&inthandler;
3412 $SIG{PIPE} = \&pipehandler;
3413
3414 # For some tests, we need another copy of the binary that is setuid exim rather
3415 # than root.
3416
3417 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3418        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3419        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3420        "sudo chmod 06755 eximdir/exim_exim");
3421
3422 ##################################################
3423 #     Make copies of utilities we might need     #
3424 ##################################################
3425
3426 # Certain of the tests make use of some of Exim's utilities. We do not need
3427 # to be root to copy these.
3428
3429 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3430
3431 $dbm_build_deleted = 0;
3432 if (defined $parm_lookups{dbm} &&
3433     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3434   {
3435   delete $parm_lookups{dbm};
3436   $dbm_build_deleted = 1;
3437   }
3438
3439 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3440   {
3441   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3442   }
3443
3444 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3445   {
3446   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3447   }
3448
3449 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3450   {
3451   tests_exit(-1, "Failed to make a copy of exinext: $!");
3452   }
3453
3454 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3455   {
3456   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3457   }
3458
3459 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3460   {
3461   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3462   }
3463
3464 # Collect some version information
3465 print '-' x 78, "\n";
3466 print "Perl version for runtest: $]\n";
3467 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats)) {
3468   # fold (or unfold?) multiline output into a one-liner
3469   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3470 }
3471 print '-' x 78, "\n";
3472
3473
3474 ##################################################
3475 #    Check that the Exim user can access stuff   #
3476 ##################################################
3477
3478 # We delay this test till here so that we can check access to the actual test
3479 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3480
3481 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3482 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3483
3484 if ($parm_caller_uid eq $parm_exim_uid) {
3485   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3486                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3487 }
3488 if ($parm_caller_gid eq $parm_exim_gid) {
3489   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3490                 ."the same as caller's ($parm_caller) group as it confuses "
3491                 ."results analysis");
3492 }
3493
3494 print "The Exim user needs access to the test suite directory. Checking ...";
3495
3496 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3497   {
3498   my($why) = "unknown failure $rc";
3499   $rc >>= 8;
3500   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3501   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3502   $why = "Couldn't read auxiliary group list" if $rc == 3;
3503   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3504   $why = "Couldn't set gid" if $rc == 5;
3505   $why = "Couldn't set uid" if $rc == 6;
3506   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3507   print "\n** $why\n";
3508   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3509   }
3510 else
3511   {
3512   print " OK\n";
3513   }
3514
3515 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3516   if not unlink($log_summary_filename) and -e $log_summary_filename;
3517
3518 ##################################################
3519 #        Create a list of available tests        #
3520 ##################################################
3521
3522 # The scripts directory contains a number of subdirectories whose names are
3523 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3524 # from the first requires certain optional features to be included in the Exim
3525 # binary. These requirements are contained in a file called "REQUIRES" within
3526 # the directory. We scan all these tests, discarding those that cannot be run
3527 # because the current binary does not support the right facilities, and also
3528 # those that are outside the numerical range selected.
3529
3530 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3531   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3532
3533 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3534   if $dlfunc_deleted;
3535 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3536   if $dbm_build_deleted;
3537
3538
3539 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3540   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3541
3542 # Scan for relevant tests
3543 # HS12: Needs to be reworked.
3544 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3545   {
3546   my($testdir) = $test_dirs[$i];
3547   my($wantthis) = 1;
3548
3549   print ">>Checking $testdir\n" if $debug;
3550
3551   # Skip this directory if the first test is equal or greater than the first
3552   # test in the next directory.
3553
3554   next DIR if ($i < @test_dirs - 1) &&
3555           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3556
3557   # No need to carry on if the end test is less than the first test in this
3558   # subdirectory.
3559
3560   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3561
3562   # Check requirements, if any.
3563
3564   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3565     {
3566     while (<$requires>)
3567       {
3568       next if /^\s*$/;
3569       s/\s+$//;
3570       if (/^support (.*)$/)
3571         {
3572         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3573         }
3574       elsif (/^running (.*)$/)
3575         {
3576         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3577         }
3578       elsif (/^lookup (.*)$/)
3579         {
3580         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3581         }
3582       elsif (/^authenticators? (.*)$/)
3583         {
3584         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3585         }
3586       elsif (/^router (.*)$/)
3587         {
3588         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3589         }
3590       elsif (/^transport (.*)$/)
3591         {
3592         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3593         }
3594       elsif (/^malware (.*)$/)
3595         {
3596         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3597         }
3598       elsif (/^feature (.*)$/)
3599         {
3600         # move to a subroutine?
3601         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3602
3603         open (IN, "$parm_cwd/confs/0000") ||
3604           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3605         open (OUT, ">test-config") ||
3606           tests_exit(-1, "Couldn't open test-config: $!\n");
3607         while (<IN>)
3608           {
3609           do_substitute($testno);
3610           print OUT;
3611           }
3612         close(IN);
3613         close(OUT);
3614
3615         system($eximinfo . " >/dev/null 2>&1");
3616         if ($? != 0) {
3617           unlink("$parm_cwd/test-config");
3618           $wantthis = 0;
3619           $_ = "feature $1";
3620           last;
3621         }
3622         unlink("$parm_cwd/test-config");
3623         }
3624       else
3625         {
3626         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3627         }
3628       }
3629     }
3630   else
3631     {
3632     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3633       unless $!{ENOENT};
3634     }
3635
3636   # Loop if we do not want the tests in this subdirectory.
3637
3638   if (!$wantthis)
3639     {
3640     chomp;
3641     print "Omitting tests in $testdir (missing $_)\n";
3642     }
3643
3644   # We want the tests from this subdirectory, provided they are in the
3645   # range that was selected.
3646
3647   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
3648   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
3649     if not @testlist;
3650
3651   foreach $test (@testlist)
3652     {
3653     if (!$wantthis)
3654       {
3655       log_test($log_summary_filename, $test, '.');
3656       }
3657     else
3658       {
3659       push @test_list, "$testdir/$test";
3660       }
3661     }
3662   }
3663
3664 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
3665
3666
3667 ##################################################
3668 #         Munge variable auxiliary data          #
3669 ##################################################
3670
3671 # Some of the auxiliary data files have to refer to the current testing
3672 # directory and other parameter data. The generic versions of these files are
3673 # stored in the aux-var-src directory. At this point, we copy each of them
3674 # to the aux-var directory, making appropriate substitutions. There aren't very
3675 # many of them, so it's easiest just to do this every time. Ensure the mode
3676 # is standardized, as this path is used as a test for the ${stat: expansion.
3677
3678 # A similar job has to be done for the files in the dnszones-src directory, to
3679 # make the fake DNS zones for testing. Most of the zone files are copied to
3680 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3681 # networks that are defined by parameter.
3682
3683 foreach $basedir ("aux-var", "dnszones")
3684   {
3685   system("sudo rm -rf $parm_cwd/$basedir");
3686   mkdir("$parm_cwd/$basedir", 0777);
3687   chmod(0755, "$parm_cwd/$basedir");
3688
3689   opendir(AUX, "$parm_cwd/$basedir-src") ||
3690     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3691   my(@filelist) = readdir(AUX);
3692   close(AUX);
3693
3694   foreach $file (@filelist)
3695     {
3696     my($outfile) = $file;
3697     next if $file =~ /^\./;
3698
3699     if ($file eq "db.ip4.V4NET")
3700       {
3701       $outfile = "db.ip4.$parm_ipv4_test_net";
3702       }
3703     elsif ($file eq "db.ip6.V6NET")
3704       {
3705       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3706       $" = '.';
3707       $outfile = "db.ip6.@nibbles";
3708       $" = ' ';
3709       }
3710
3711     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3712     open(IN, "$parm_cwd/$basedir-src/$file") ||
3713       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3714     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3715       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3716     while (<IN>)
3717       {
3718       do_substitute(0);
3719       print OUT;
3720       }
3721     close(IN);
3722     close(OUT);
3723     }
3724   }
3725
3726 # Set a user's shell, distinguishable from /bin/sh
3727
3728 symlink('/bin/sh' => 'aux-var/sh');
3729 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3730
3731 ##################################################
3732 #     Create fake DNS zones for this host        #
3733 ##################################################
3734
3735 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3736 # sure that there are forward and reverse registrations for this host, using
3737 # its real IP addresses. Dynamically created zone files achieve this.
3738
3739 if ($have_ipv4 || $have_ipv6)
3740   {
3741   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3742   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3743     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3744   print OUT "; This is a dynamically constructed fake zone file.\n" .
3745     "; The following line causes fakens to return PASS_ON\n" .
3746     "; for queries that it cannot answer\n\n" .
3747     "PASS ON NOT FOUND\n\n";
3748   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3749   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3750   print OUT "\n; End\n";
3751   close(OUT);
3752   }
3753
3754 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3755   {
3756   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3757   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3758     tests_exit(-1,
3759       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3760   print OUT "; This is a dynamically constructed fake zone file.\n" .
3761     "; The zone is $components[0].in-addr.arpa.\n\n" .
3762     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3763     "; End\n";
3764   close(OUT);
3765   }
3766
3767 if ($have_ipv6 && $parm_ipv6 ne "::1")
3768   {
3769   my($exp_v6) = $parm_ipv6;
3770   $exp_v6 =~ s/[^:]//g;
3771   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3772     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3773   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3774     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3775   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3776     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3777   } else {
3778     $exp_v6 = $parm_ipv6;
3779   }
3780   my(@components) = split /:/, $exp_v6;
3781   my(@nibbles) = reverse (split /\s*/, shift @components);
3782   my($sep) =  '';
3783
3784   $" = ".";
3785   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3786     tests_exit(-1,
3787       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3788   print OUT "; This is a dynamically constructed fake zone file.\n" .
3789     "; The zone is @nibbles.ip6.arpa.\n\n";
3790
3791   @components = reverse @components;
3792   foreach $c (@components)
3793     {
3794     $c = "0$c" until $c =~ /^..../;
3795     @nibbles = reverse(split /\s*/, $c);
3796     print OUT "$sep@nibbles";
3797     $sep = ".";
3798     }
3799
3800   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3801   close(OUT);
3802   $" = " ";
3803   }
3804
3805
3806
3807 ##################################################
3808 #    Create lists of mailboxes and message logs  #
3809 ##################################################
3810
3811 # We use these lists to check that a test has created the expected files. It
3812 # should be faster than looking for the file each time. For mailboxes, we have
3813 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3814 # is just a flat list of files.
3815
3816 @oldmails = list_files_below("mail");
3817 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3818 @oldmsglogs = readdir(DIR);
3819 closedir(DIR);
3820
3821
3822
3823 ##################################################
3824 #         Run the required tests                 #
3825 ##################################################
3826
3827 # Each test script contains a number of tests, separated by a line that
3828 # contains ****. We open input from the terminal so that we can read responses
3829 # to prompts.
3830
3831 if (not $force_continue) {
3832   # runtest needs to interact if we're not in continue
3833   # mode. It does so by communicate to /dev/tty
3834   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
3835   print "\nPress RETURN to run the tests: ";
3836   <T>;
3837 }
3838
3839
3840 foreach $test (@test_list)
3841   {
3842   state $lasttestdir = '';
3843
3844   local $lineno     = 0;
3845   local $commandno  = 0;
3846   local $subtestno  = 0;
3847   local $sortlog    = 0;
3848
3849   (local $testno = $test) =~ s|.*/||;
3850
3851   # Leaving traces in the process table and in the environment
3852   # gives us a chance to identify hanging processes (exim daemons)
3853   local $0 = "[runtest $testno]";
3854   local $ENV{EXIM_TEST_NUMBER} = $testno;
3855
3856   my $gnutls   = 0;
3857   my $docheck  = 1;
3858   my $thistestdir  = substr($test, 0, -5);
3859
3860   $dynamic_socket->close() if $dynamic_socket;
3861
3862   if ($lasttestdir ne $thistestdir)
3863     {
3864     $gnutls = 0;
3865     if (-s "scripts/$thistestdir/REQUIRES")
3866       {
3867       my $indent = '';
3868       print "\n>>> The following tests require: ";
3869       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
3870         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
3871       while (<$requires>)
3872         {
3873         $gnutls = 1 if /^support GnuTLS/;
3874         print $indent, $_;
3875         $indent = ">>>                              ";
3876         }
3877       }
3878       $lasttestdir = $thistestdir;
3879     }
3880
3881   # Remove any debris in the spool directory and the test-mail directory
3882   # and also the files for collecting stdout and stderr. Then put back
3883   # the test-mail directory for appendfile deliveries.
3884
3885   system "sudo /bin/rm -rf spool test-*";
3886   system "mkdir test-mail 2>/dev/null";
3887
3888   # A privileged Exim will normally make its own spool directory, but some of
3889   # the tests run in unprivileged modes that don't always work if the spool
3890   # directory isn't already there. What is more, we want anybody to be able
3891   # to read it in order to find the daemon's pid.
3892
3893   system "mkdir spool; " .
3894          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3895          "sudo chmod 0755 spool";
3896
3897   # Empty the cache that keeps track of things like message id mappings, and
3898   # set up the initial sequence strings.
3899
3900   undef %cache;
3901   $next_msgid = "aX";
3902   $next_pid = 1234;
3903   $next_port = 1111;
3904   $message_skip = 0;
3905   $msglog_skip = 0;
3906   $stderr_skip = 0;
3907   $stdout_skip = 0;
3908   $rmfiltertest = 0;
3909   $is_ipv6test = 0;
3910   $TEST_STATE->{munge} = '';
3911
3912   # Remove the associative arrays used to hold checked mail files and msglogs
3913
3914   undef %expected_mails;
3915   undef %expected_msglogs;
3916
3917   # Open the test's script
3918   open(SCRIPT, "scripts/$test") ||
3919     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3920   # Run through the script once to set variables which should be global
3921   while (<SCRIPT>)
3922     {
3923     if (/^no_message_check/) { $message_skip = 1; next; }
3924     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3925     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3926     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3927     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3928     if (/^sortlog/)          { $sortlog = 1; next; }
3929     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
3930     }
3931   # Reset to beginning of file for per test interpreting/processing
3932   seek(SCRIPT, 0, 0);
3933
3934   # The first line in the script must be a comment that is used to identify
3935   # the set of tests as a whole.
3936
3937   $_ = <SCRIPT>;
3938   $lineno++;
3939   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3940   printf("%s %s", (substr $test, 5), (substr $_, 2));
3941
3942   # Loop for each of the subtests within the script. The variable $server_pid
3943   # is used to remember the pid of a "server" process, for which we do not
3944   # wait until we have waited for a subsequent command.
3945
3946   local($server_pid) = 0;
3947   for ($commandno = 1; !eof SCRIPT; $commandno++)
3948     {
3949     # Skip further leading comments and blank lines, handle the flag setting
3950     # commands, and deal with tests for IP support.
3951
3952     while (<SCRIPT>)
3953       {
3954       $lineno++;
3955       # Could remove these variable settings because they are already
3956       # set above, but doesn't hurt to leave them here.
3957       if (/^no_message_check/) { $message_skip = 1; next; }
3958       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3959       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3960       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3961       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3962       if (/^sortlog/)          { $sortlog = 1; next; }
3963
3964       if (/^need_largefiles/)
3965         {
3966         next if $have_largefiles;
3967         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3968         $docheck = 0;      # don't check output
3969         undef $_;          # pretend EOF
3970         last;
3971         }
3972
3973       if (/^need_ipv4/)
3974         {
3975         next if $have_ipv4;
3976         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3977         $docheck = 0;      # don't check output
3978         undef $_;          # pretend EOF
3979         last;
3980         }
3981
3982       if (/^need_ipv6/)
3983         {
3984         if ($have_ipv6)
3985           {
3986           $is_ipv6test = 1;
3987           next;
3988           }
3989         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3990         $docheck = 0;      # don't check output
3991         undef $_;          # pretend EOF
3992         last;
3993         }
3994
3995       if (/^need_move_frozen_messages/)
3996         {
3997         next if defined $parm_support{move_frozen_messages};
3998         print ">>> move frozen message support is needed for test $testno, " .
3999           "but is not\n>>> available: skipping\n";
4000         $docheck = 0;      # don't check output
4001         undef $_;          # pretend EOF
4002         last;
4003         }
4004
4005       last unless /^(?:#(?!##\s)|\s*$)/;
4006       }
4007     last if !defined $_;  # Hit EOF
4008
4009     my($subtest_startline) = $lineno;
4010
4011     # Now run the command. The function returns 0 for an inline command,
4012     # 1 if a non-exim command was run and waited for, 2 if an exim
4013     # command was run and waited for, and 3 if a command
4014     # was run and not waited for (usually a daemon or server startup).
4015
4016     my($commandname) = '';
4017     my($expectrc) = 0;
4018     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4019     my($cmdrc) = $?;
4020
4021     if ($debug) {
4022       print ">> rc=$rc cmdrc=$cmdrc\n";
4023       if (defined $run_extra) {
4024         foreach my $k (keys %$run_extra) {
4025           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4026           print ">>   $k -> $v\n";
4027         }
4028       }
4029     }
4030     $run_extra = {} unless defined $run_extra;
4031     foreach my $k (keys %$run_extra) {
4032       if (exists $TEST_STATE->{$k}) {
4033         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4034         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4035       }
4036       if (defined $run_extra->{$k}) {
4037         $TEST_STATE->{$k} = $run_extra->{$k};
4038       } elsif (exists $TEST_STATE->{$k}) {
4039         delete $TEST_STATE->{$k};
4040       }
4041     }
4042
4043     # Hit EOF after an initial return code number
4044
4045     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4046
4047     # Carry on with the next command if we did not wait for this one. $rc == 0
4048     # if no subprocess was run; $rc == 3 if we started a process but did not
4049     # wait for it.
4050
4051     next if ($rc == 0 || $rc == 3);
4052
4053     # We ran and waited for a command. Check for the expected result unless
4054     # it died.
4055
4056     if ($cmdrc != $expectrc && !$sigpipehappened)
4057       {
4058       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4059       if (($cmdrc & 0xff) == 0)
4060         {
4061         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4062         }
4063       elsif (($cmdrc & 0xff00) == 0)
4064         { printf("** Killed by signal %d", $cmdrc & 255); }
4065       else
4066         { printf("** Status %x", $cmdrc); }
4067
4068       for (;;)
4069         {
4070         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4071         $_ = $force_continue ? "c" : <T>;
4072         tests_exit(1) if /^q?$/i;
4073         if (/^c$/ && $force_continue) {
4074           log_failure($log_failed_filename, $testno, "exit code unexpected");
4075           log_test($log_summary_filename, $testno, 'F')
4076         }
4077         if ($force_continue)
4078           {
4079           print "\nstdout tail:\n";
4080           print "==================>\n";
4081           system("tail -20 test-stdout");
4082           print "===================\n";
4083           print "stderr tail:\n";
4084           print "==================>\n";
4085           system("tail -20 test-stderr");
4086           print "===================\n";
4087           print "... continue forced\n";
4088           }
4089
4090         last if /^[rc]$/i;
4091         if (/^e$/i)
4092           {
4093           system("$more test-stderr");
4094           }
4095         elsif (/^o$/i)
4096           {
4097           system("$more test-stdout");
4098           }
4099         }
4100
4101       $retry = 1 if /^r$/i;
4102       $docheck = 0;
4103       }
4104
4105     # If the command was exim, and a listening server is running, we can now
4106     # close its input, which causes us to wait for it to finish, which is why
4107     # we didn't close it earlier.
4108
4109     if ($rc == 2 && $server_pid != 0)
4110       {
4111       close SERVERCMD;
4112       $server_pid = 0;
4113       if ($? != 0)
4114         {
4115         if (($? & 0xff) == 0)
4116           { printf("Server return code %d for test %d starting line %d", $?/256,
4117                 $testno, $subtest_startline); }
4118         elsif (($? & 0xff00) == 0)
4119           { printf("Server killed by signal %d", $? & 255); }
4120         else
4121           { printf("Server status %x", $?); }
4122
4123         for (;;)
4124           {
4125           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4126           $_ = $force_continue ? "c" : <T>;
4127           tests_exit(1) if /^q?$/i;
4128           if (/^c$/ && $force_continue) {
4129             log_failure($log_failed_filename, $testno, "exit code unexpected");
4130             log_test($log_summary_filename, $testno, 'F')
4131           }
4132           print "... continue forced\n" if $force_continue;
4133           last if /^[rc]$/i;
4134
4135           if (/^s$/i)
4136             {
4137             open(S, "test-stdout-server") ||
4138               tests_exit(-1, "Failed to open test-stdout-server: $!");
4139             print while <S>;
4140             close(S);
4141             }
4142           }
4143         $retry = 1 if /^r$/i;
4144         }
4145       }
4146     }
4147
4148   close SCRIPT;
4149
4150   # The script has finished. Check the all the output that was generated. The
4151   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4152   # rerun the test (the files # have been updated).
4153   # It does not return if the user responds Q to a prompt.
4154
4155   if ($retry)
4156     {
4157     $retry = '0';
4158     print (("#" x 79) . "\n");
4159     redo;
4160     }
4161
4162   if ($docheck)
4163     {
4164     sleep 1 if $slow;
4165     my $rc = check_output($TEST_STATE->{munge});
4166     log_test($log_summary_filename, $testno, 'P') if ($rc == 0);
4167     if ($rc < 2)
4168       {
4169       print ("  Script completed\n");
4170       }
4171     else
4172       {
4173       print (("#" x 79) . "\n");
4174       redo;
4175       }
4176     }
4177   }
4178
4179
4180 ##################################################
4181 #         Exit from the test script              #
4182 ##################################################
4183
4184 tests_exit(-1, "No runnable tests selected") if not @test_list;
4185 tests_exit(0);
4186
4187 __END__
4188
4189 =head1 NAME
4190
4191  runtest - run the exim testsuite
4192
4193 =head1 SYNOPSIS
4194
4195  runtest [exim-path] [options] [test0 [test1]]
4196
4197 =head1 DESCRIPTION
4198
4199 B<runtest> runs the Exim testsuite.
4200
4201 =head1 OPTIONS
4202
4203 For legacy reasons the options are not case sensitive.
4204
4205 =over
4206
4207 =item B<--continue>
4208
4209 Do not stop for user interaction or on errors. (default: off)
4210
4211 =item B<--debug>
4212
4213 This option enables the output of debug information when running the
4214 various test commands. (default: off)
4215
4216 =item B<--diff>
4217
4218 Use C<diff -u> for comparing the expected output with the produced
4219 output. (default: use a built-in routine)
4220
4221 =item B<--flavor>|B<--flavour> I<flavour>
4222
4223 Override the expected results for results for a specific (OS) flavour.
4224 (default: unused)
4225
4226 =item B<--[no]ipv4>
4227
4228 Skip IPv4 related setup and tests (default: use ipv4)
4229
4230 =item B<--[no]ipv6>
4231
4232 Skip IPv6 related setup and tests (default: use ipv6)
4233
4234 =item B<--keep>
4235
4236 Keep the various output files produced during a test run. (default: don't keep)
4237
4238 =item B<--range> I<n0> I<n1>
4239
4240 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4241 test available".
4242
4243 =item B<--slow>
4244
4245 Insert some delays to compensate for a slow host system. (default: off)
4246
4247 =item B<--test> I<n>
4248
4249 Run the specified test. This option may used multiple times.
4250
4251 =item B<--update>
4252
4253 Automatically update the recorded (expected) data on mismatch. (default: off)
4254
4255 =item B<--valgrind>
4256
4257 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4258
4259 =back
4260
4261 =cut
4262
4263
4264 # End of runtest script