test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use v5.10.1;
  20 use warnings;
  21 use if $^V >= v5.19.11, experimental => 'smartmatch';
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use Pod::Usage;
  30 use Getopt::Long;
  31 use FindBin qw'$RealBin';
  32 use File::Copy;
  33
  34 use lib "$RealBin/lib";
  35 use Exim::Runtest;
  36 use Exim::Utils qw(uniq numerically cp);
  37
  38 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Smart::Comments' => '####';
  39 use if $ENV{DEBUG} && scalar($ENV{DEBUG} =~ /\bruntest\b/) => 'Data::Dumper';
  40
  41 use constant TEST_TOP => 8999;
  42 use constant TEST_SPECIAL_TOP => 9999;
  43
  44
  45 # Start by initializing some global variables
  46
  47 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  48
  49 # This gets embedded in the D-H params filename, and the value comes
  50 # from asking GnuTLS for "normal", but there appears to be no way to
  51 # use certtool/... to ask what that value currently is.  *sigh*
  52 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  53 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  54 # normal = 2432   tls_dh_max_bits = 2236
  55 my $gnutls_dh_bits_normal = 2236;
  56
  57 my $cf = 'bin/cf -exact';
  58 my $cr = "\r";
  59 my $debug = 0;
  60 my $flavour = do {
  61   my $f = Exim::Runtest::flavour() // '';
  62   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  63 };
  64 my $force_continue = 0;
  65 my $force_update = 0;
  66 my $log_failed_filename = 'failed-summary.log';
  67 my $log_summary_filename = 'run-summary.log';
  68 my @more = qw'less -XF';
  69 my $optargs = '';
  70 my $save_output = 0;
  71 my $server_opts = '';
  72 my $slow = 0;
  73 my $valgrind = 0;
  74
  75 my $have_ipv4 = 1;
  76 my $have_ipv6 = 1;
  77 my $have_largefiles = 0;
  78
  79 my @test_list = ();
  80
  81
  82 # Networks to use for DNS tests. We need to choose some networks that will
  83 # never be used so that there is no chance that the host on which we are
  84 # running is actually in one of the test networks. Private networks such as
  85 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  86 # Rather than use some unassigned numbers (that might become assigned later),
  87 # I have chosen some multicast networks, in the belief that such addresses
  88 # won't ever be assigned to hosts. This is the only place where these numbers
  89 # are defined, so it is trivially possible to change them should that ever
  90 # become necessary.
  91
  92 my $parm_ipv4_test_net = 224;
  93 my $parm_ipv6_test_net = 'ff00';
  94
  95 # Port numbers are currently hard-wired
  96
  97 my $parm_port_n = 1223;         # Nothing listening on this port
  98 my $parm_port_s = 1224;         # Used for the "server" command
  99 my $parm_port_d = 1225;         # Used for the Exim daemon
 100 my $parm_port_d2 = 1226;        # Additional for daemon
 101 my $parm_port_d3 = 1227;        # Additional for daemon
 102 my $parm_port_d4 = 1228;        # Additional for daemon
 103 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
 104
 105 # Find a suiteable group name for test (currently only 0001
 106 # uses a group name. A numeric group id would do
 107 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 108
 109 # Manually set locale
 110 $ENV{LC_ALL} = 'C';
 111
 112 # In some environments USER does not exist, but we need it for some test(s)
 113 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 114
 115 my ($parm_configure_owner, $parm_configure_group);
 116 my ($parm_ipv4, $parm_ipv6, $parm_ipv6_stripped);
 117 my $parm_hostname;
 118
 119 ###############################################################################
 120 ###############################################################################
 121
 122 # Define a number of subroutines
 123
 124 ###############################################################################
 125 ###############################################################################
 126
 127
 128 ##################################################
 129 #              Handle signals                    #
 130 ##################################################
 131
 132 sub pipehandler { $sigpipehappened = 1; }
 133
 134 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 135
 136
 137 ##################################################
 138 #       Do global macro substitutions            #
 139 ##################################################
 140
 141 # This function is applied to configurations, command lines and data lines in
 142 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 143 # directory. It takes one argument: the current test number, or zero when
 144 # setting up files before running any tests.
 145
 146 sub do_substitute{
 147 s?\bCALLER\b?$parm_caller?g;
 148 s?\bCALLERGROUP\b?$parm_caller_group?g;
 149 s?\bCALLER_UID\b?$parm_caller_uid?g;
 150 s?\bCALLER_GID\b?$parm_caller_gid?g;
 151 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 152 s?\bDIR/?$parm_cwd/?g;
 153 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 154 s?\bEXIMUSER\b?$parm_eximuser?g;
 155 s?\bHOSTIPV4\b?$parm_ipv4?g;
 156 s?\bHOSTIPV6\b?$parm_ipv6?g;
 157 s?\bHOSTNAME\b?$parm_hostname?g;
 158 s?\bPORT_D\b?$parm_port_d?g;
 159 s?\bPORT_D2\b?$parm_port_d2?g;
 160 s?\bPORT_D3\b?$parm_port_d3?g;
 161 s?\bPORT_D4\b?$parm_port_d4?g;
 162 s?\bPORT_N\b?$parm_port_n?g;
 163 s?\bPORT_S\b?$parm_port_s?g;
 164 s?\bTESTNUM\b?$_[0]?g;
 165 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 166 s?\bV6NET:?$parm_ipv6_test_net:?g;
 167 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 168 s?\bMAILGROUP\b?$parm_mailgroup?g;
 169 }
 170
 171
 172 ##################################################
 173 #     Any state to be preserved across tests     #
 174 ##################################################
 175
 176 my $TEST_STATE = {};
 177
 178
 179 ##################################################
 180 #        Subroutine to tidy up and exit          #
 181 ##################################################
 182
 183 # In all cases, we check for any Exim daemons that have been left running, and
 184 # kill them. Then remove all the spool data, test output, and the modified Exim
 185 # binary if we are ending normally.
 186
 187 # Arguments:
 188 #    $_[0] = 0 for a normal exit; full cleanup done
 189 #    $_[0] > 0 for an error exit; no files cleaned up
 190 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 191
 192 sub tests_exit{
 193 my($rc) = $_[0];
 194 my($spool);
 195
 196 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 197 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 198 # the background.
 199
 200 if (exists $TEST_STATE->{exim_pid})
 201   {
 202   $pid = $TEST_STATE->{exim_pid};
 203   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 204   system("sudo kill -INT $pid");
 205   }
 206
 207 if (opendir(DIR, "spool"))
 208   {
 209   my(@spools) = sort readdir(DIR);
 210   closedir(DIR);
 211   foreach $spool (@spools)
 212     {
 213     next if $spool !~ /^exim-daemon./;
 214     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 215     chomp($pid = <PID>);
 216     close(PID);
 217     print "Tidyup: killing daemon pid=$pid\n";
 218     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 219     }
 220   }
 221 else
 222   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 223
 224 # Close the terminal input and remove the test files if all went well, unless
 225 # the option to save them is set. Always remove the patched Exim binary. Then
 226 # exit normally, or die.
 227
 228 close(T);
 229 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 230   if ($rc == 0 && !$save_output);
 231
 232 system("sudo /bin/rm -rf ./eximdir/*")
 233   if (!$save_output);
 234
 235 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 236 exit $rc if ($rc >= 0);
 237 die "** runtest error: $_[1]\n";
 238 }
 239
 240
 241
 242 ##################################################
 243 #   Subroutines used by the munging subroutine   #
 244 ##################################################
 245
 246 # This function is used for things like message ids, where we want to generate
 247 # more than one value, but keep a consistent mapping throughout.
 248 #
 249 # Arguments:
 250 #   $oldid        the value from the file
 251 #   $base         a base string into which we insert a sequence
 252 #   $sequence     the address of the current sequence counter
 253
 254 sub new_value {
 255 my($oldid, $base, $sequence) = @_;
 256 my($newid) = $cache{$oldid};
 257 if (! defined $newid)
 258   {
 259   $newid = sprintf($base, $$sequence++);
 260   $cache{$oldid} = $newid;
 261   }
 262 return $newid;
 263 }
 264
 265
 266 # This is used while munging the output from exim_dumpdb.
 267 # May go wrong across DST changes.
 268
 269 sub date_seconds {
 270 my($day,$month,$year,$hour,$min,$sec) =
 271   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 272 my($mon);
 273 if   ($month =~ /Jan/) {$mon = 0;}
 274 elsif($month =~ /Feb/) {$mon = 1;}
 275 elsif($month =~ /Mar/) {$mon = 2;}
 276 elsif($month =~ /Apr/) {$mon = 3;}
 277 elsif($month =~ /May/) {$mon = 4;}
 278 elsif($month =~ /Jun/) {$mon = 5;}
 279 elsif($month =~ /Jul/) {$mon = 6;}
 280 elsif($month =~ /Aug/) {$mon = 7;}
 281 elsif($month =~ /Sep/) {$mon = 8;}
 282 elsif($month =~ /Oct/) {$mon = 9;}
 283 elsif($month =~ /Nov/) {$mon = 10;}
 284 elsif($month =~ /Dec/) {$mon = 11;}
 285 return timelocal($sec,$min,$hour,$day,$mon,$year);
 286 }
 287
 288
 289 # This is a subroutine to sort maildir files into time-order. The second field
 290 # is the microsecond field, and may vary in length, so must be compared
 291 # numerically.
 292
 293 sub maildirsort {
 294 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 295 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 296 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 297 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 298 }
 299
 300
 301
 302 ##################################################
 303 #   Subroutine list files below a directory      #
 304 ##################################################
 305
 306 # This is used to build up a list of expected mail files below a certain path
 307 # in the directory tree. It has to be recursive in order to deal with multiple
 308 # maildir mailboxes.
 309
 310 sub list_files_below {
 311 my($dir) = $_[0];
 312 my(@yield) = ();
 313 my(@sublist, $file);
 314
 315 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 316 @sublist = sort maildirsort readdir(DIR);
 317 closedir(DIR);
 318
 319 foreach $file (@sublist)
 320   {
 321   next if $file eq "." || $file eq ".." || $file eq "CVS";
 322   if (-d "$dir/$file")
 323     { @yield = (@yield, list_files_below("$dir/$file")); }
 324   else
 325     { push @yield, "$dir/$file"; }
 326   }
 327
 328 return @yield;
 329 }
 330
 331
 332
 333 ##################################################
 334 #         Munge a file before comparing          #
 335 ##################################################
 336
 337 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 338 # on into standard values, so that the compare works. Perl's substitution with
 339 # an expression provides a neat way to do some of these changes.
 340
 341 # We keep a global associative array for repeatedly turning the same values
 342 # into the same standard values throughout the data from a single test.
 343 # Message ids get this treatment (can't be made reliable for times), and
 344 # times in dumped retry databases are also handled in a special way, as are
 345 # incoming port numbers.
 346
 347 # On entry to the subroutine, the file to write to is already opened with the
 348 # name MUNGED. The input file name is the only argument to the subroutine.
 349 # Certain actions are taken only when the name contains "stderr", "stdout",
 350 # or "log". The yield of the function is 1 if a line matching "*** truncated
 351 # ***" is encountered; otherwise it is 0.
 352
 353 sub munge {
 354 my($file) = $_[0];
 355 my($extra) = $_[1];
 356 my($yield) = 0;
 357 my(@saved) = ();
 358
 359 local $_;
 360
 361 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 362
 363 my($is_log) = $file =~ /log/;
 364 my($is_stdout) = $file =~ /stdout/;
 365 my($is_stderr) = $file =~ /stderr/;
 366 my($is_mail) = $file =~ /mail/;
 367
 368 # Date pattern
 369
 370 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 371
 372 # Debug time & pid
 373
 374 $time_pid = "(?:\\d{2}:\\d{2}:\\d{2}\\s+\\d+\\s)";
 375
 376 # Pattern for matching pids at start of stderr lines; initially something
 377 # that won't match.
 378
 379 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 380
 381 # Scan the file and make the changes. Near the bottom there are some changes
 382 # that are specific to certain file types, though there are also some of those
 383 # inline too.
 384
 385 LINE: while(<IN>)
 386   {
 387 RESET_AFTER_EXTRA_LINE_READ:
 388   # Custom munges
 389   if ($extra)
 390     {
 391     next if $extra =~ m%^/%  &&  eval $extra;
 392     eval $extra if $extra =~ m/^s/;
 393     }
 394
 395   # Check for "*** truncated ***"
 396   $yield = 1 if /\*\*\* truncated \*\*\*/;
 397
 398   # Replace the name of this host
 399   s/\Q$parm_hostname\E/the.local.host.name/g;
 400
 401   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 402   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 403
 404   # The name of the shell may vary
 405   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 406
 407   # Replace the path to the testsuite directory
 408   s?\Q$parm_cwd\E?TESTSUITE?g;
 409
 410   # Replace the Exim version number (may appear in various places)
 411   # patchexim should have fixed this for us
 412   #s/Exim \K\d+[._]\d+[\w_-]*/x.yz/i;
 413
 414   # Replace Exim message ids by a unique series
 415   s/(\d[^\W_]{5}-[^\W_]{6}-[^\W_]{2})
 416     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 417
 418   # The names of lock files appear in some error and debug messages
 419   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 420
 421   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 422   # port" message, because it is not always the same.
 423   s/port (\d+) \([^)]+\)/port $1/g
 424     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 425
 426   # Challenges in SPA authentication
 427   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 428
 429   # PRVS values
 430   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 431   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 432
 433   # There are differences in error messages between OpenSSL versions
 434   s/SSL_CTX_set_cipher_list/SSL_connect/;
 435
 436   # One error test in expansions mentions base 62 or 36
 437   s/is not a base (36|62) number/is not a base 36\/62 number/;
 438
 439   # This message sometimes has a different number of seconds
 440   s/forced fail after \d seconds/forced fail after d seconds/;
 441
 442   # This message may contain a different DBM library name
 443   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 444
 445   # The message for a non-listening FIFO varies
 446   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 447
 448   # Debugging output of lists of hosts may have different sort keys
 449   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 450
 451   # Random local part in callout cache testing
 452   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 453   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 454
 455   # File descriptor numbers may vary
 456   s/^writing data block fd=\d+/writing data block fd=dddd/;
 457   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 458
 459
 460   # ======== Dumpdb output ========
 461   # This must be before the general date/date munging.
 462   # Time data lines, which look like this:
 463   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 464   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 465     {
 466     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 467     $expired = '' if !defined $expired;
 468
 469     # Round the time-difference up to nearest even value
 470     my($increment) = ((date_seconds($date3) - date_seconds($date2) + 1) >> 1) << 1;
 471
 472     # We used to use globally unique replacement values, but timing
 473     # differences make this impossible. Just show the increment on the
 474     # last one.
 475
 476     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 477       $increment, $expired);
 478     next;
 479     }
 480
 481   # more_errno values in exim_dumpdb output which are times
 482   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 483
 484   # port numbers in dumpdb output
 485   s/T:([a-z.]+(:[0-9.]+)?):$parm_port_n /T:$1:PORT_N /;
 486
 487   # port numbers in stderr
 488   s/^set_process_info: .*\]:\K$parm_port_d /PORT_D /;
 489   s/^set_process_info: .*\]:\K$parm_port_s /PORT_S /;
 490
 491
 492   # ======== Dates and times ========
 493
 494   # Dates and times are all turned into the same value - trying to turn
 495   # them into different ones cannot be done repeatedly because they are
 496   # real time stamps generated while running the test. The actual date and
 497   # time used was fixed when I first started running automatic Exim tests.
 498
 499   # Date/time in header lines and SMTP responses
 500   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 501     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 502   # and in a French locale
 503   s/\S{4},\s\d\d?\s[^,]+\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 504     /dim., 10 f\xE9vr 2019 20:05:49 +0000/gx;
 505
 506   # Date/time in logs and in one instance of a filter test
 507   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?\s/1999-03-02 09:44:33 /gx;
 508   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}(\s[+-]\d\d\d\d)?\s/2017-07-30 18:51:05.712 /gx;
 509   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 510   # Date/time in syslog test
 511   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s/2017-07-30 18:51:05 /gx;
 512   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s/2017-07-30 18:51:05.712 /gx;
 513   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\s[+-]\d\d\d\d\s/2017-07-30 18:51:05 +9999 /gx;
 514   s/^SYSLOG:\s\'\K\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\.\d{3}\s[+-]\d\d\d\d\s/2017-07-30 18:51:05.712 +9999 /gx;
 515
 516   s/((D|[RQD]T)=)\d+s/$1qqs/g;
 517   s/((D|[RQD]T)=)\d\.\d{3}s/$1q.qqqs/g;
 518
 519   # Date/time in message separators
 520   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 521     /Tue Mar 02 09:44:33 1999/gx;
 522
 523   # Date of message arrival in spool file as shown by -Mvh
 524   s/^\d{9,10}\s0$/ddddddddd 0/;
 525
 526   # Date/time in mbx mailbox files
 527   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 528
 529   # Dates/times in debugging output for writing retry records
 530   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 531     {
 532     my($next) = $3 - $2;
 533     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 534     }
 535   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\w)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 536   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 537
 538   # Time to retry may vary
 539   s/time to retry = \S+/time to retry = tttt/;
 540   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 541   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 542
 543   # Date/time in exim -bV output
 544   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 545
 546   # Eximstats heading
 547   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 548     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 549
 550   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 551   # us the former on a new connection.
 552   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 553
 554   # ======== TLS certificate algorithms ========
 555   #
 556   # In Received: headers, convert RFC 8314 style ciphersuite to
 557   # the older (comment) style, keeping only the Auth element
 558   # (discarding kex, cipher, mac).  For TLS 1.3 there is no kex
 559   # element (and no _WITH); insert a spurious "RSA".
 560   # Also in $tls_X_cipher_std reporting.
 561
 562   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.*?([^_]+)_WITH.+$/(TLS1.x:ke-$1-AES256-SHAnnn:xxx)/;
 563   s/^\s+by \S+ with .+ \K \(TLS1(?:\.[0-3])?\) tls TLS_.+$/(TLS1.x:ke-RSA-AES256-SHAnnn:xxx)/;
 564
 565   s/ cipher_ TLS_.*?([^_]+)_WITH.+$/ cipher_ TLS1.x:ke_$1_WITH_ci_mac/;
 566   s/ cipher_ TLS_.*$/ cipher_ TLS1.x:ke_RSA_WITH_ci_mac/;
 567
 568   # Test machines might have various different TLS library versions supporting
 569   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 570   # treat the standard algorithms the same.
 571   #
 572   # TLSversion : KeyExchange? - Authentication/Signature - C_iph_er - MAC : bits
 573   #
 574   # So far, have seen:
 575   #   TLSv1:AES128-GCM-SHA256:128
 576   #   TLSv1:AES256-SHA:256
 577   #   TLSv1.1:AES256-SHA:256
 578   #   TLSv1.2:AES256-GCM-SHA384:256
 579   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 580   #   TLSv1.3:TLS_AES_256_GCM_SHA384:256
 581   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 582   # We also need to handle the ciphersuite without the TLS part present, for
 583   # client-ssl's output.  We also see some older forced ciphersuites, but
 584   # negotiating TLS 1.2 instead of 1.0.
 585   # Mail headers (...), log-lines X=..., client-ssl output ...
 586   # (and \b doesn't match between ' ' and '(' )
 587   #
 588   # Retain the authentication algorith field as we want to test that.
 589
 590   s/( (?: (?:\b|\s) [\(=] ) | \s )TLS1(\.[123])?:/$1TLS1.x:/xg;
 591   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA)(?!:)/ke-$3-AES256-SHAnnn/g;
 592   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-AES(128|256)-(GCM-SHA(256|384)|SHA):(128|256)/ke-$3-AES256-SHAnnn:xxx/g;
 593
 594   # OpenSSL TLSv1.3 - unsure what to do about the authentication-variant testcases now,
 595   # as it seems the protocol no longer supports a user choice.  Replace the "TLS" field with "RSA".
 596   # Also insert a key-exchange field for back-compat, even though 1.3 doesn't do that.
 597   #
 598   # TLSversion : "TLS" - C_iph_er - MAC : ???
 599   #
 600   s/TLS_AES(_256)?_GCM_SHA384(?!:)/ke-RSA-AES256-SHAnnn/g;
 601   s/:TLS_AES(_256)?_GCM_SHA384:256/:ke-RSA-AES256-SHAnnn:xxx/g;
 602
 603   # LibreSSL
 604   # TLSv1:AES256-GCM-SHA384:256
 605   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 606   # TLS1.3:AEAD-AES256-GCM-SHA384:256
 607   #
 608   # ECDHE-RSA-CHACHA20-POLY1305
 609   # AES256-GCM-SHA384
 610
 611   s/(?<!-)(AES256-GCM-SHA384)/RSA-$1/;
 612   s/AEAD-(AES256-GCM-SHA384)/RSA-$1/g;
 613   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305)(?!:)/ke-$3-AES256-SHAnnn/g;
 614   s/(?<!ke-)((EC)?DHE-)?(RSA|ECDSA)-(AES256|CHACHA20)-(GCM-SHA384|POLY1305):256/ke-$3-AES256-SHAnnn:xxx/g;
 615
 616   # GnuTLS have seen:
 617   #   TLS1.3:ECDHE_RSA_AES_256_GCM_SHA384:256
 618   #   TLS1.3:ECDHE_SECP256R1__RSA_PSS_RSAE_SHA256__AES_256_GCM__AEAD:256
 619   #   TLS1.3:ECDHE_X25519__RSA_PSS_RSAE_SHA256__AES_256_GCM:256
 620   #   TLS1.3:ECDHE_PSK_SECP256R1__AES_256_GCM__AEAD:256
 621   #
 622   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 623   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 624   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 625   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 626   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_256_GCM:256
 627   #   TLS1.2:ECDHE_SECP256R1__RSA_SHA256__AES_128_CBC__SHA256:128
 628   #   TLS1.2:ECDHE_SECP256R1__ECDSA_SHA512__AES_256_GCM:256
 629   #   TLS1.2:ECDHE_SECP256R1__AES_256_GCM:256           (3.6.7 resumption)
 630   #   TLS1.2:ECDHE_RSA_SECP256R1__AES_256_GCM:256       (! 3.5.18 !)
 631   #   TLS1.2:RSA__CAMELLIA_256_GCM:256                  (leave the cipher name)
 632   #   TLS1.2-PKIX:RSA__AES_128_GCM__AEAD:128            (the -PKIX seems to be a 3.1.20 thing)
 633   #   TLS1.2-PKIX:ECDHE_RSA_SECP521R1__AES_256_GCM__AEAD:256
 634   #
 635   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 636   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 637   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 638   #   X=TLS1.0:RSA_AES_256_CBC_SHA1:256
 639   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 640   #   X=TLS1.0-PKIX:RSA__AES_256_CBC__SHA1:256
 641   # and as stand-alone cipher:
 642   #   ECDHE-RSA-AES256-SHA
 643   #   DHE-RSA-AES256-SHA256
 644   #   DHE-RSA-AES256-SHA
 645   # picking latter as canonical simply because regex easier that way.
 646   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA-AES256-SHA1:256/g;
 647   s/TLS1.[x0123](-PKIX)?:                                               # TLS version
 648     ((EC)?DHE(_((?<psk>PSK)_)?((?<auth>RSA|ECDSA)_)?
 649                                 (SECP(256|521)R1|X25519))?__?)?         # key-exchange
 650     ((?<auth>RSA|ECDSA)((_PSS_RSAE)?_SHA(512|256))?__?)?                # authentication
 651     (?<with>WITH_)?                                                     # stdname-with
 652     AES_(256|128)_(CBC|GCM)                                             # cipher
 653     (__?AEAD)?                                                          # pseudo-MAC
 654     (__?SHA(1|256|384))?                                                # PRF
 655     :(256|128)                                                          # cipher strength
 656     /"TLS1.x:ke-"
 657         . (defined($+{psk}) ? $+{psk} : "")
 658         . (defined($+{auth}) ? $+{auth} : "")
 659         . (defined($+{with}) ? $+{with} : "")
 660         . "-AES256-SHAnnn:xxx"/gex;
 661   s/TLS1.2:RSA__CAMELLIA_256_GCM(_SHA384)?:256/TLS1.2:RSA_CAMELLIA_256_GCM-SHAnnn:256/g;
 662   s/\b(ECDHE-(RSA|ECDSA)-AES256-SHA|DHE-RSA-AES256-SHA256)\b/ke-$2-AES256-SHAnnn/g;
 663
 664   # Separate reporting of TLS version
 665   s/ver:    TLS1(\.[0-3])?$/ver:    TLS1.x/;
 666   s/ \(TLS1(\.[0-3])?\) / (TLS1.x) /;
 667
 668   # GnuTLS library error message changes
 669   s/(No certificate was found|Certificate is required)/The peer did not send any certificate/g;
 670 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 671   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 672   s/\(gnutls_handshake\): \KNo supported cipher suites have been found.$/Could not negotiate a supported cipher suite./;
 673
 674   # (this new one is a generic channel-read error, but the testsuite
 675   # only hits it in one place)
 676   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 677
 678   # (replace old with new, hoping that old only happens in one situation)
 679   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 680   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 681
 682   # signature algorithm names
 683   s/RSA-SHA1/RSA-SHA/;
 684
 685
 686   # ======== Caller's login, uid, gid, home, gecos ========
 687
 688   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 689   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 690   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 691
 692   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 693   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 694
 695   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 696   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 697
 698   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 699
 700   # When looking at spool files with -Mvh, we will find not only the caller
 701   # login, but also the uid and gid. It seems that $) in some Perls gives all
 702   # the auxiliary gids as well, so don't bother checking for that.
 703
 704   s/^CALLER $> \d+$/CALLER UID GID/;
 705
 706   # There is one case where the caller's login is forced to something else,
 707   # in order to test the processing of logins that contain spaces. Weird what
 708   # some people do, isn't it?
 709
 710   s/^spaced user $> \d+$/CALLER UID GID/;
 711
 712
 713   # ======== Exim's login ========
 714   # For messages received by the daemon, this is in the -H file, which some
 715   # tests inspect. For bounce messages, this will appear on the U= lines in
 716   # logs and also after Received: and in addresses. In one pipe test it appears
 717   # after "Running as:". It also appears in addresses, and in the names of lock
 718   # files.
 719
 720   s/U=$parm_eximuser/U=EXIMUSER/;
 721   s/user=$parm_eximuser/user=EXIMUSER/;
 722   s/login=$parm_eximuser/login=EXIMUSER/;
 723   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 724   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 725   s/\b$parm_eximuser@/EXIMUSER@/;
 726   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 727
 728   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 729   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 730
 731   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 732   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 733
 734   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 735
 736
 737   # ======== General uids, gids, and pids ========
 738   # Note: this must come after munges for caller's and exim's uid/gid
 739
 740   # These are for systems where long int is 64
 741   s/\buid=4294967295/uid=-1/;
 742   s/\beuid=4294967295/euid=-1/;
 743   s/\bgid=4294967295/gid=-1/;
 744   s/\begid=4294967295/egid=-1/;
 745
 746   s/\bgid=\d+/gid=gggg/;
 747   s/\begid=\d+/egid=gggg/;
 748   s/\b(pid=|pid |PID: )\d+/$1pppp/;
 749   s/\buid=\d+/uid=uuuu/;
 750   s/\beuid=\d+/euid=uuuu/;
 751   s/set_process_info:\s+\d+/set_process_info: pppp/;
 752   s/process \d+ running as transport filter/process pppp running as transport filter/;
 753   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 754   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 755   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 756
 757   # Pid in temp file in appendfile transport
 758   s"test-mail/(subdir/)?temp\K\.\d+\.".pppp.";
 759
 760   # Optional pid in log lines
 761   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\.\d{3}|)(\s[+-]\d{4}|)(\s\[\d+\])/
 762     "$1$2$3 [" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 763
 764   # Optional pid in syslog test lines
 765   s/^(SYSLOG:\s\'([-0-9]{10}\s[:.0-9]{8,12}\s([-+]\d{4}\s)?|))(\[\d+\] )/
 766     "$1\[" . new_value($4, "%s", \$next_pid) . "]"/gxe;
 767
 768   # Detect a daemon stderr line with a pid and save the pid for subsequent
 769   # removal from following lines.
 770   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 771   s/^$spid //;
 772
 773   # Queue runner waiting messages
 774   s/waiting for children of \d+/waiting for children of pppp/;
 775   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 776
 777   # Most builds are without HAVE_LOCAL_SCAN
 778   next if /^calling local_scan\(\); timeout=300$/;
 779   next if /^local_scan\(\) returned 0 NULL$/;
 780
 781   # ======== Port numbers ========
 782   # Incoming port numbers may vary, but not in daemon startup line.
 783
 784   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 785   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 786
 787   # This handles "connection from" and the like, when the port is given
 788   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 789       && !/\*>/&& !/==/  && !/\*\*/ && !/Connection refused/ && !/in response to/)
 790     {
 791     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 792     }
 793
 794   # Port in host address in spool file output from -Mvh
 795   s/^(--?host_address) (.*[:.])\d+$/$1 ${2}9999/;
 796
 797   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 798     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 799   }
 800
 801
 802   # ======== Local IP addresses ========
 803   # The amount of space between "host" and the address in verification output
 804   # depends on the length of the host name. We therefore reduce it to one space
 805   # for all of them.
 806   # Also, the length of space at the end of the host line is dependent
 807   # on the length of the longest line, so strip it also on otherwise
 808   # un-rewritten lines like localhost
 809   #
 810   # host 127.0.0.1     [127.0.0.1]
 811   # host 10.0.0.1      [10.0.0.1]-
 812   #
 813   # host 127.0.0.1     [127.0.0.1]--
 814   # host 169.16.16.16  [169.16.16.10]
 815
 816   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 817   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 818   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 819   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 820   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 821   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 822   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 823   s/(^|\W)\K\Q$parm_ipv6_stripped\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 824   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 825   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 826   s/^\s+host\s\S+\s+\[\S+\]\K +$//;     # strip, not collapse the trailing whitespace
 827
 828
 829   # ======== Test network IP addresses ========
 830   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 831   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 832
 833
 834   # ======== IP error numbers and messages ========
 835   # These vary between operating systems
 836   s/Can(no|')t assign requested address/Network Error/;
 837   s/Operation timed out/Connection timed out/;
 838   s/Address family not supported by protocol family/Network Error/;
 839   s/Network( is)? unreachable/Network Error/;
 840   s/Invalid argument/Network Error/;
 841
 842   s/\(\d+\): Network/(dd): Network/;
 843   s/\(\d+\): Connection refused/(dd): Connection refused/;
 844   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 845   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 846   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 847
 848
 849   # ======== Other error numbers ========
 850   s/errno=\d+/errno=dd/g;
 851
 852   # ======== System Error Messages ======
 853   # depending on the underlaying file system the error message seems to differ
 854   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 855
 856   # ======== Output from ls ========
 857   # Different operating systems use different spacing on long output
 858   #s/ +/ /g if /^[-rwd]{10} /;
 859   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 860   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 861   # unfortunately matches a non-ls linefull of dashes.
 862   # Allow the case where we've already picked out the file protection bits.
 863   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 864     s/ +/ /g;
 865   }
 866
 867
 868   # ======== Message sizes =========
 869   # Message sizes vary, owing to different logins and host names that get
 870   # automatically inserted. I can't think of any way of even approximately
 871   # comparing these.
 872
 873   s/([\s,])S=\d+\b/$1S=sss/;
 874   s/:S\d+\b/:Ssss/;
 875   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 876   s/\sSIZE=\d+\b/ SIZE=ssss/;
 877   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 878   s/old size = \d+\b/old size = sssss/;
 879   s/message size = \d+\b/message size = sss/;
 880   s/this message = \d+\b/this message = sss/;
 881   s/Size of headers = \d+/Size of headers = sss/;
 882   s/sum=(?!0)\d+/sum=dddd/;
 883   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 884   s/(?<=sum=0 )count=\d+\b/count=dd/;
 885   s/,S is \d+\b/,S is ddddd/;
 886   s/\+0100,\d+;/+0100,ddd;/;
 887   s/\(\d+ bytes written\)/(ddd bytes written)/;
 888   s/added '\d+ 1'/added 'ddd 1'/;
 889   s/Received\s+\d+/Received               nnn/;
 890   s/Delivered\s+\d+/Delivered              nnn/;
 891
 892
 893   # ======== Values in spool space failure message ========
 894   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 895
 896
 897   # ======== Filter sizes ========
 898   # The sizes of filter files may vary because of the substitution of local
 899   # filenames, logins, etc.
 900
 901   s/^\d+(?= (\(tainted\) )?bytes read from )/ssss/;
 902
 903
 904   # ======== OpenSSL error messages ========
 905   # Different releases of the OpenSSL libraries seem to give different error
 906   # numbers, or handle specific bad conditions in different ways, leading to
 907   # different wording in the error messages, so we cannot compare them.
 908
 909 #XXX This loses any trailing "deliving unencypted to" which is unfortunate
 910 #    but I can't work out how to deal with that.
 911   s/(TLS session: \(SSL_\w+\): error:)(.*)(?!: delivering)/$1 <<detail omitted>>/;
 912   s/(TLS error on connection from .* \(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 913   next if /SSL verify error: depth=0 error=certificate not trusted/;
 914
 915   # OpenSSL 3.0.0
 916   s/TLS error \(D-H param setting .* error:\K.*dh key too small/xxxxxxxx:SSL routines::dh key too small/;
 917
 918   # ======== Maildir things ========
 919   # timestamp output in maildir processing
 920   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 921
 922   # maildir delivery files appearing in log lines (in cases of error)
 923   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 924
 925   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 926
 927   # Maildir file names in general
 928   s/\b\d+\.M\d+P\d+\b/dddddddddd.HddddddPddddd/;
 929
 930   # Maildirsize data
 931   while (/^\d+S,\d+C\s*$/)
 932     {
 933     print MUNGED;
 934     while (<IN>)
 935       {
 936       last if !/^\d+ \d+\s*$/;
 937       print MUNGED "ddd d\n";
 938       }
 939     last if !defined $_;
 940     }
 941   last if !defined $_;
 942
 943
 944   # SRS timestamps and signatures vary by hostname and from run to run
 945
 946   s/(?i)SRS0=....=.[^=]?=([^=]+)=([^@]+)\@([^ ]+)/SRS0=ZZZZ=YY=$1=$2\@$3/g;
 947
 948
 949   # ======== Output from the "fd" program about open descriptors ========
 950   # The statuses seem to be different on different operating systems, but
 951   # at least we'll still be checking the number of open fd's.
 952
 953   s/max fd = \d+/max fd = dddd/;
 954   s/status=[0-9a-f]+ (?:RDONLY|WRONLY|RDWR)/STATUS/g;
 955
 956
 957   # ======== Contents of spool files ========
 958   # A couple of tests dump the contents of the -H file. The length fields
 959   # will be wrong because of different user names, etc.
 960   s/^\d\d\d(?=[PFS*])/ddd/;
 961
 962
 963   # ==========================================================
 964   # MIME boundaries in RFC3461 DSN messages
 965   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 966
 967   # Cyrus SASL library version differences (rejectlog)
 968   s/Cyrus SASL permanent failure: \Kuser not found$/generic failure/;
 969
 970   # ==========================================================
 971   # Some munging is specific to the specific file types
 972
 973   # ======== stdout ========
 974
 975   if ($is_stdout)
 976     {
 977     # Skip translate_ip_address and use_classresources in -bP output because
 978     # they aren't always there.
 979
 980     next if /translate_ip_address =/;
 981     next if /use_classresources/;
 982
 983     # In certain filter tests, remove initial filter lines because they just
 984     # clog up by repetition.
 985
 986     if ($rmfiltertest)
 987       {
 988       next if /^(Sender\staken\sfrom|
 989                  Return-path\scopied\sfrom|
 990                  Sender\s+=|
 991                  Recipient\s+=)/x;
 992       if (/^Testing \S+ filter/)
 993         {
 994         $_ = <IN>;    # remove blank line
 995         next;
 996         }
 997       }
 998
 999     # remote IPv6 addrs vary
1000     s/^(Connection request from) \[.*:.*:.*\]$/$1 \[ipv6\]/;
1001
1002     # openssl version variances
1003   # Error lines on stdout from SSL contain process id values and file names.
1004   # They also contain a source file name and line number, which may vary from
1005   # release to release.
1006
1007     next if /^SSL info:/;
1008     next if /SSL verify error: depth=0 error=certificate not trusted/;
1009     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
1010     s/CONNECT_CR_FINISHED/ssl3_read_bytes/i;
1011     s/^\d+:error:\d+(?:E\d+)?(:SSL routines:ssl3_read_bytes:[^:]+:).*(:SSL alert number \d\d)$/pppp:error:dddddddd$1\[...\]$2/;
1012     s/^error:[^:]*:(SSL routines:ssl3_read_bytes:(tls|ssl)v\d+ alert)/error:dddddddd:$1/;
1013
1014     # gnutls version variances
1015     next if /^Error in the pull function./;
1016
1017     # optional IDN2 variant conversions.  Accept either IDN1 or IDN2
1018     s/conversion  strasse.de/conversion  xn--strae-oqa.de/;
1019     s/conversion: german.xn--strae-oqa.de/conversion: german.straße.de/;
1020
1021     # subsecond timstamp info in reported header-files
1022     s/^-received_time_usec \.\K\d{6}$/uuuuuu/;
1023     s/^-received_time_complete \K\d+\.\d{6}$/tttt.uuuuuu/;
1024
1025     # Postgres server takes varible time to shut down; lives in various places
1026     s/^waiting for server to shut down\.+ done$/waiting for server to shut down.... done/;
1027     s/^\/.*postgres /POSTGRES /;
1028
1029     # DMARC is not always supported by the build
1030     next if /^dmarc_tld_file =/;
1031
1032     # ARC is not always supported by the build
1033     next if /^arc_sign =/;
1034
1035     # LIMITS is not always supported by the build
1036     next if /^limits_advertise_hosts =/;
1037
1038     # TLS resumption is not always supported by the build
1039     next if /^tls_resumption_hosts =/;
1040     next if /^-tls_resumption/;
1041
1042     # gsasl library version may not support some methods
1043     s/250-AUTH ANONYMOUS PLAIN SCRAM-SHA-1\K SCRAM-SHA-256//;
1044     }
1045
1046   # ======== stderr ========
1047
1048   elsif ($is_stderr)
1049     {
1050     # The very first line of debugging output will vary
1051
1052     s/^Exim version .*/Exim version x.yz ..../;
1053
1054     # Debugging lines for Exim terminations and process-generation
1055
1056     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
1057     s/^(proxy-proc \w{5}-pid) \d+$/$1 pppp/;
1058     s/^(?:\s*\d+ )(exec .* -oPX)$/pppp $1/;
1059     next if /(?:postfork: | fork(?:ing|ed) for )/;
1060
1061     # IP address lookups use gethostbyname() when IPv6 is not supported,
1062     # and gethostbyname2() or getipnodebyname() when it is.
1063
1064     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
1065
1066     # Extra lookups done when ipv6 is supported
1067     next if /^host_fake_gethostbyname\(af=inet6\) returned 1 \(HOST_NOT_FOUND\)$/;
1068
1069     # we don't care what TZ enviroment the testhost was running
1070     next if /^Reset TZ to/;
1071
1072     # ========= Exim lookups ==================
1073     # Lookups have a char which depends on the number of lookup types compiled in,
1074     # in stderr output.  Replace with a "0".  Recognising this while avoiding
1075     # other output is fragile; perhaps the debug output should be revised instead.
1076     s%^\s+(:?closing )?\K[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
1077
1078     # drop gnutls version strings
1079     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
1080     next if /GnuTLS runtime version: \d+[\.\d]+$/;
1081     # and unwanted debug
1082     next if /^GnuTLS<2>: FIPS140-2 (context is not set|operation mode switched from initial to not-approved)$/;
1083     next if /^GnuTLS<3>: ASSERT: sign.c\[_gnutls_sign_is_secure2\]:\d+$/;
1084
1085     # drop openssl version strings
1086     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
1087     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
1088
1089     # this is timing-dependent
1090     next if /^OpenSSL: creating STEK$/;
1091     next if /^selfsign cert rotate$/;
1092
1093     # TLS preload
1094     # only OpenSSL speaks of these
1095     next if /^TLS: (preloading (DH params|ECDH curve|CA bundle) for server|generating selfsigned server cert)/;
1096     next if /^Diffie-Hellman initialized from default/;
1097     next if /^ECDH OpenSSL (< )?[\d.+]+: temp key parameter settings:/;
1098     next if /^ECDH: .*'prime256v1'/;
1099     next if /^tls_verify_certificates: system$/;
1100     next if /^tls_set_watch: .*\/cert.pem/;
1101     next if /^Generating 2048 bit RSA key/;
1102
1103     # TLS preload
1104     # only GnuTLS speaks of these
1105     next if /^GnuTLS global init required$/;
1106     next if /^TLS: basic cred init, server/;
1107     next if /^TLS: preloading cipher list for server: NULL$/;
1108     s/^GnuTLS using default session cipher\/priority "NORMAL"$/TLS: not preloading cipher list for server/;
1109     next if /^GnuTLS<2>: added \d+ protocols, \d+ ciphersuites, \d+ sig algos and \d+ groups into priority list$/;
1110     next if /^GnuTLS<2>: (Disabling X.509 extensions|signing structure using RSA-SHA256)/;
1111     next if /^GnuTLS.*(wrap_nettle_mpi_print|gnutls_subject_alt_names_get|get_alt_name)/;
1112     next if /^GnuTLS<[23]>: (p11|ASSERT: pkcs11.c|Initializing needed PKCS #11 modules)/;
1113     next if /^GnuTLS<2>: Intel (AES|GCM) accelerator was detected/;
1114     next if /^Added \d{3} certificate authorities/;
1115     next if /^TLS: not preloading CRL for server/;
1116     next if /^GnuTLS<3>: ASSERT: extensions.c\[_gnutls_get_extension/;
1117     next if /^GnuTLS<3>: ASSERT: \.\.\/\.\.\/\.\.\/lib\/x509\//;
1118     next if /^GnuTLS<2>: Initializing PKCS #11 modules/;
1119
1120
1121     # only kevent platforms (FreeBSD, OpenBSD) say this
1122     next if /^watch dir/;
1123     next if /^watch file .*\/usr\/local/;
1124     next if /^watch file .*\/etc\/ssl/;
1125     next if /^closing watch fd:/;
1126
1127     # TLS preload
1128     # there happen in different orders for OpenSSL/GnuTLS/noTLS
1129     next if /^TLS: generating selfsigned server cert/;
1130     next if /^TLS: not preloading (CA bundle|cipher list) for server$/;
1131     next if /^TLS: not preloading server certs$/;
1132
1133     # drop lookups
1134     next if /^$time_pid?(?: Lookups\ \(built-in\):
1135                                         | Loading\ lookup\ modules\ from
1136                                         | Loaded\ \d+\ lookup\ modules
1137                                         | Total\ \d+\ lookups)/x;
1138
1139     # drop compiler information
1140     next if /^$time_pid?Compiler:/;
1141
1142     # and the ugly bit
1143     # different libraries will have different numbers (possibly 0) of follow-up
1144     # lines, indenting with more data
1145     if (/^$time_pid?Library version:/) {
1146       while (1) {
1147         $_ = <IN>;
1148         next if /^$time_pid?\s/;
1149         goto RESET_AFTER_EXTRA_LINE_READ;
1150       }
1151     }
1152
1153     # drop other build-time controls emitted for debugging
1154     next if /^$time_pid?WHITELIST_D_MACROS:/;
1155     next if /^$time_pid?TRUSTED_CONFIG_LIST:/;
1156
1157     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
1158     # with -be, privileges will have been dropped, so this will always
1159     # be the case
1160     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
1161
1162     # We might not keep this check; rather than change all the tests, just
1163     # ignore it as long as it succeeds; then we only need to change the
1164     # TLS tests where tls_require_ciphers has been set.
1165     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
1166       my $discard = <IN>;
1167       next;
1168     }
1169     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
1170
1171     # We invoke Exim with -D, so we hit this new message as of Exim 4.73:
1172     next if /^macros_trusted overridden to true by whitelisting/;
1173
1174     # We have to omit the localhost ::1 address so that all is well in
1175     # the IPv4-only case.
1176
1177     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
1178       if (/looked up these IP addresses/);
1179     next if /name=localhost address=::1/;
1180
1181     # drop pdkim debugging header
1182     next if /^DKIM( <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+|: no signatures)$/;
1183
1184     # Some platforms have TIOCOUTome do not
1185     next if /\d+ bytes remain in socket output buffer$/;
1186     # Various other IPv6 lines must be omitted too
1187
1188     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
1189     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
1190     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
1191     next if / in dns_ipv4_lookup?/;
1192     next if / writing neg-cache entry for .*AAAA/;
1193     next if /^faking res_search\(AAAA\) response length as 65535/;
1194
1195     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
1196       {
1197       $_= <IN>;     # Gets "returning DNS_NODATA"
1198       next;
1199       }
1200
1201     # Non-TLS builds have a different default Recieved: header expansion
1202     s/^((.*)\t}}}}by \$primary_hostname \$\{if def:received_protocol \{with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_ver        { (\$tls_in_ver)}}\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1203     s/^((\s*).*considering: with \$received_protocol }})\(Exim \$version_number\)$/$1\${if def:tls_in_ver        { (\$tls_in_ver)}}\${if def:tls_in_cipher_std { tls \$tls_in_cipher_std\n$2\t}}(Exim \$version_number)/;
1204     if (/condition: def:tls_in_ver$/)
1205       {
1206       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1207       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1208       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1209       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>;
1210       $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>; $_= <IN>; next;
1211       }
1212
1213
1214     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
1215     # are unset, because tls ain't always there.
1216
1217     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
1218                 \sno\s\((option\sunset|end\sof\slist)\)/x;
1219
1220     # Skip auxiliary group lists because they will vary.
1221
1222     next if /auxiliary group list:/;
1223
1224     # Skip "extracted from gecos field" because the gecos field varies
1225
1226     next if /extracted from gecos field/;
1227
1228     # Skip "waiting for data on socket" and "read response data: size=" lines
1229     # because some systems pack more stuff into packets than others.
1230
1231     next if /waiting for data on socket/;
1232     next if /read response data: size=/;
1233
1234     # If Exim is compiled with readline support but it can't find the library
1235     # to load, there will be an extra debug line. Omit it.
1236
1237     next if /failed to load readline:/;
1238
1239     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1240     # O_CREAT; other's don't. In the latter case there is some debugging output
1241     # which is not present in the former. Skip the relevant lines (there are
1242     # three of them).
1243
1244     if (/returned from EXIM_DBOPEN: \(nil\)/)
1245       {
1246       $_ .= <IN>;
1247       s?\Q$parm_cwd\E?TESTSUITE?g;
1248       if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1249         { $_ = <IN>; next; }
1250       }
1251
1252     # Some tests turn on +expand debugging to check on expansions.
1253     # Unfortunately, the Received: expansion varies, depending on whether TLS
1254     # is compiled or not. So we must remove the relevant debugging if it is.
1255
1256     if (/^condition: def:tls_cipher/)
1257       {
1258       while (<IN>) { last if /^condition: def:sender_address/; }
1259       }
1260     elsif (/^expanding: Received: /)
1261       {
1262       while (<IN>) { last if !/^\s/; }
1263       }
1264
1265     # remote port numbers vary
1266     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1267
1268     # Platform-dependent error strings
1269     s/Operation timed out/Connection timed out/;
1270
1271     # Platform differences on disconnect
1272     s/unexpected disconnection while reading SMTP command from \[127.0.0.1\] \K\(error: Connection reset by peer\) //;
1273
1274     # Platform-dependent resolver option bits
1275     s/^ (?:writing|update) neg-cache entry for [^,]+-\K[0-9a-f]+, ttl/xxxx, ttl/;
1276
1277     # timing variance, run-to-run
1278     s/^time on queue = \K1s/0s/;
1279
1280     # content-scan: file order can vary in directory
1281     s%unspool_mbox\(\): unlinking 'TESTSUITE/spool/scan/[^/]*/\K[^\']*%FFFFFFFFF%;
1282
1283     # Skip hosts_require_dane checks when the options
1284     # are unset, because dane ain't always there.
1285     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1286
1287     # daemon notifier socket
1288     s/^(\s*\d+|ppppp) (creating notifier socket)$/ppppp $2/;
1289     s/^ \@(.*exim_daemon_notify)$/ $1/;
1290     s/^(\s*\d+|ppppp)  \@?(.*exim_daemon_notify)$/ppppp  $2/;
1291     next if /unlinking notifier socket/;
1292
1293     # daemon notifier socket
1294     # Timing variance over runs.  Collapse repeated memssages.
1295     if (/notify triggered queue run/)
1296       {
1297       my $line = $_;
1298       while (/notify triggered queue run/) { $_ = <IN>; }
1299       $_ = $line . $_;
1300       }
1301
1302     # Different builds will have different lookup types included
1303     s/^\s*search_type \K\d+ \((\w+)\) quoting -1 \(none\)$/NN ($1) quoting -1 (none)/;
1304
1305     # DISABLE_OCSP
1306     next if /in hosts_requ(est|ire)_ocsp\? (no|yes)/;
1307
1308     # SUPPORT_PROXY
1309     next if /host in hosts_proxy\?/;
1310
1311     # PIPE_CONNECT
1312     next if / in (pipelining_connect_advertise_hosts|hosts_pipe_connect)?\? no /;
1313
1314     # Experimental_International
1315     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1316
1317     # Experimental_REQUIRETLS
1318     next if / in tls_advertise_requiretls?\? no \(end of list\)/;
1319
1320     # Experimental_LIMITS
1321     next if / in limits_advertise_hosts?\? no \(matched "!\*"\)/;
1322
1323     # TCP Fast Open
1324     next if /^(ppppp )?setsockopt FASTOPEN: Network Error/;
1325
1326     # Environment cleaning
1327     next if /\w+ in keep_environment\? (yes|no)/;
1328
1329     # Sizes vary with test hostname
1330     s/^cmd buf flush \d+ bytes/cmd buf flush ddd bytes/;
1331
1332     # Spool filesystem free space changes on different systems.
1333     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1334
1335     # Non-TLS builds have different expansions for received_header_text
1336     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1337       {
1338       $_ .= <IN>;
1339       s/[\s╎]+\}\}(?=\(Exim )/\}\} /;
1340       }
1341     if (/^ ├──condition: def:tls_cipher$/)
1342       {
1343       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1344       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1345       }
1346
1347     # Not all platforms build with DKIM enabled
1348     next if /^DKIM >> Body data for hash, canonicalized/;
1349
1350     # Not all platforms build with SPF enabled
1351     next if /^(spf_conn_init|SPF_dns_exim_new|spf_compile\.c)/;
1352
1353     # Not all platforms have sendfile support
1354     next if /^cannot use sendfile for body: no support$/;
1355
1356     #  Parts of DKIM-specific debug output depend on the time/date
1357     next if /^date:\w+,\{SP\}/;
1358     next if /^DKIM \[[^[]+\] (Header hash|b) computed:/;
1359
1360     # Not all platforms support TCP Fast Open, and the compile omits the check
1361     if (s/\S+ in hosts_try_fastopen\? (no \(option unset\)|no \(end of list\)|yes \(matched "\*"\))\n$//)
1362       {
1363       chomp;
1364       $_ .= <IN>;
1365       s/ \.\.\. >>> / ... /;
1366       if (s/ non-TFO mode connection attempt to 224.0.0.0, 0 data\b$//) { chomp; $_ .= <IN>; }
1367       s/Address family not supported by protocol family/Network Error/;
1368       s/Network is unreachable/Network Error/;
1369       }
1370     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1371     s/^(Connecting to .* \.\.\. sending) \d+ (nonTFO early-data)$/$1 dd $2/;
1372
1373     if (/^([0-9: ]*                                             # possible timestamp
1374         Connecting\ to\ [^ ]+\ [^ ]+(\ from\ [^ ]+)?)\ \.\.\.
1375         \ .*TFO\ mode\x20
1376         (sendto,\ no\ data:\ EINPROGRESS                        # Linux
1377         |connection\ attempt\ to\ [^,]+,\ 0\ data)              # MacOS & no-support
1378         $/x)
1379       {
1380       $_ = $1 . " ... " . <IN>;
1381       s/^(.* \.\.\.) [0-9: ]*connected$/$1  connected/;
1382
1383       if (/^Connecting to .* \.\.\.  connected$/)
1384         {
1385         $_ .= <IN>;
1386         if (/^(Connecting to .* \.\.\.  )connected\n\s+SMTP(\(close\)>>|\(Connection refused\)<<)$/)
1387           {
1388           $_ = $1 . "failed: Connection refused\n" . <IN>;
1389           s/^(Connecting .*)\n\s+SMTP\(close\)>>$/$1/;
1390           }
1391         elsif (/^(Connecting to .* \.\.\.  connected\n)read response data: size=/)
1392           { $_ = $1; }
1393
1394         # Date/time in SMTP banner
1395         s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d{4}\s\d\d\:\d\d:\d\d\s[-+]\d{4}
1396           /Tue, 2 Mar 1999 09:44:33 +0000/gx;
1397         }
1398       }
1399
1400     # Specific pointer values reported for DB operations change from run to run
1401     s/^(\s*returned from EXIM_DBOPEN: )(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1402     s/^(\s*EXIM_DBCLOSE.)(0x)?[0-9a-f]+/${1}0xAAAAAAAA/;
1403
1404     # Platform-dependent output during MySQL startup
1405     next if /PerconaFT file system space/;
1406     next if /^Waiting for MySQL server to answer/;
1407     next if /mysqladmin: CREATE DATABASE failed; .* database exists/;
1408
1409     # Postgres version-dependent differences
1410     s/^initdb: warning: (enabling "trust" authentication for local connections)$/\nWARNING: $1/;
1411
1412     # Not all builds include DMARC
1413     next if /^DMARC: no (dmarc_tld_file|sender_host_address)$/ ;
1414
1415     # TLS resumption is not always supported by the build
1416     next if /in tls_resumption_hosts\?/;
1417
1418     # Platform differences in errno strings
1419     s/  SMTP\(Operation timed out\)<</  SMTP(Connection timed out)<</;
1420
1421     # Platform differences for errno values (eg. Hurd)
1422     s/^errno = \d+$/errno = EEE/;
1423     s/^writing error \d+: /writing error EEE: /;
1424
1425     # Time-only, in debug output
1426     # we have to handle double lines from the DBOPEN, hence placed down here and /mg
1427     s/^\d\d:\d\d:\d\d\s+/01:01:01 /mg;
1428
1429     # pid in debug lines
1430     s/^(\d\d:\d\d:\d\d)(\s+\d+\s)/"$1 " . new_value($2, "%s", \$next_pid) . " "/mgxe;
1431     s/(?<!post-)[Pp]rocess\K(\s\d+ )/new_value($1, "%s", \$next_pid) . " "/gxe;
1432
1433     # When Exim is checking the size of directories for maildir, it uses
1434     # the check_dir_size() function to scan directories. Of course, the order
1435     # of the files that are obtained using readdir() varies from system to
1436     # system. We therefore buffer up debugging lines from check_dir_size()
1437     # and sort them before outputting them.
1438
1439     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1440       {
1441       push @saved, $_;
1442       }
1443     else
1444       {
1445       if (@saved > 0)
1446         {
1447         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1448           "to ensure consistency\n";
1449         @saved = sort(@saved);
1450         print MUNGED @saved;
1451         @saved = ();
1452         }
1453
1454       # Skip some lines that Exim puts out at the start of debugging output
1455       # because they will be different in different binaries.
1456
1457       next if /^$time_pid?
1458                   (?: Berkeley\ DB:\s
1459                     | Probably\ (?:Berkeley\ DB|ndbm|GDBM)
1460                     | Using\ tdb
1461                     | Authenticators:
1462                     | Lookups(?:\(built-in\))?:
1463                     | Support\ for:
1464                     | Routers:
1465                     | Transports:
1466                     | Malware:
1467                     | log\ selectors\ =
1468                     | cwd=
1469                     | Fixed\ never_users
1470                     | Configure\ owner
1471                     | Size\ of\ off_t:
1472                   )
1473                 /x;
1474
1475       print MUNGED;
1476       }
1477
1478     next;
1479     }
1480
1481   # ======== log ========
1482
1483   elsif ($is_log)
1484     {
1485     # Berkeley DB version differences
1486     next if / Berkeley DB error: /;
1487
1488     # CHUNKING: exact sizes depend on hostnames in headers
1489     s/(=>.* K C="250- \d)\d+ (byte chunk, total \d)\d+/$1nn $2nn/;
1490
1491     # openssl version variances
1492     s/(TLS error on connection [^:]*: error:)[0-9A-F]{8}(:system library):(?:fopen|func\(4095\)):(No such file or directory)$/$1xxxxxxxx$2:fopen:$3/;
1493     s/(DANE attempt failed.*error:)[0-9A-F]{8}(:SSL routines:)(?:(?i)ssl3_get_server_certificate|tls_process_server_certificate|CONNECT_CR_CERT)(?=:certificate verify failed$)/$1xxxxxxxx$2ssl3_get_server_certificate/;
1494     s/(DKIM: validation error: )error:[0-9A-F]{8}:rsa routines:(?:(?i)int_rsa_verify|CRYPTO_internal):(?:bad signature|algorithm mismatch)$/$1Public key signature verification has failed./;
1495     s/ARC: AMS signing: privkey PEM-block import: error:\K[0-9A-F]{8}:(PEM routines):get_name:(no start line)/0906D06C:$1:PEM_read_bio:$2/;
1496
1497     # gnutls version variances
1498     if (/TLS error on connection \(recv\): .* (Decode error|peer did not send any certificate)/)
1499       {
1500       my $prev = $_;
1501       $_ = <IN>;
1502       if (/error on first read/)
1503         {
1504         s/TLS session: \Kerror on first read:/(gnutls_handshake): A TLS fatal alert has been received.:/;
1505         goto RESET_AFTER_EXTRA_LINE_READ;
1506         }
1507       else
1508         { $_ = $prev; }
1509       }
1510     # translate gnutls error into the openssl one
1511     s/ARC: AMS signing: privkey PEM-block import: \KThe requested data were not available.$/error:0906D06C:PEM routines:PEM_read_bio:no start line/;
1512
1513     # DKIM timestamps
1514     if ( /(DKIM: d=.*) t=([0-9]*) x=([0-9]*) / )
1515       {
1516       my ($prefix, $t_diff) = ($1, $3 - $2);
1517       s/DKIM: d=.* t=[0-9]* x=[0-9]* /${prefix} t=T x=T+${t_diff} /;
1518       }
1519     # GnuTLS reports a different keysize vs. OpenSSL, for ed25519 keys
1520     s/signer: [^ ]* bits:\K 256/ 253/;
1521     s/public key too short:\K 256 bits/ 253 bits/;
1522
1523     # port numbers
1524     s/(?:\[[^\]]*\]:|port )\K$parm_port_d/PORT_D/;
1525     s/(?:\[[^\]]*\]:|port )\K$parm_port_d2/PORT_D2/;
1526     s/(?:\[[^\]]*\]:|port )\K$parm_port_d3/PORT_D3/;
1527     s/(?:\[[^\]]*\]:|port )\K$parm_port_d4/PORT_D4/;
1528     s/(?:\[[^\]]*\]:|port )\K$parm_port_s/PORT_S/;
1529     s/(?:\[[^\]]*\]:|port )\K$parm_port_n/PORT_N/;
1530     s/I=\[[^\]]*\]:\K\d+/ppppp/;
1531
1532     # Platform differences for errno values (eg. Hurd).  Leave 0 and negative numbers alone.
1533     s/R=\w+ T=\w+ defer\K \([1-9]\d*\): / (EEE): /;
1534
1535     # Platform differences in errno strings
1536     s/Arg list too long/Argument list too long/;
1537
1538     # OpenSSL vs. GnuTLS
1539     s/session: \K\((SSL_connect|gnutls_handshake)\): timed out/(tls lib connect fn): timed out/;
1540     s/TLS error on connection from .*\K\((SSL_accept|gnutls_handshake)\): timed out/(tls lib accept fn): timed out/;
1541     s/TLS error on connection from .*\K(SSL_accept: TCP connection closed by peer|\(gnutls_handshake\): The TLS connection was non-properly terminated.)/(tls lib accept fn): TCP connection closed by peer/;
1542     s/TLS session: \K\(gnutls_handshake\): No supported application protocol could be negotiated/(SSL_connect): error: <<detail omitted>>/;
1543     s/\(gnutls_handshake\): No common application protocol could be negotiated./(SSL_accept): error: <<detail omitted>>/;
1544     }
1545
1546   # ======== mail ========
1547
1548   elsif ($is_mail)
1549     {
1550     # DKIM timestamps, and signatures depending thereon
1551     if ( /^(\s+)t=([0-9]*); x=([0-9]*); b=[A-Za-z0-9+\/]+$/ )
1552       {
1553       my ($indent, $t_diff) = ($1, $3 - $2);
1554       s/.*/${indent}t=T; x=T+${t_diff}; b=bbbb;/;
1555       <IN>;
1556       <IN>;
1557       }
1558     }
1559
1560   # ======== All files other than stderr ========
1561
1562   print MUNGED;
1563   }
1564
1565 close(IN);
1566 return $yield;
1567 }
1568
1569
1570
1571
1572 ##################################################
1573 #        Subroutine to interact with caller      #
1574 ##################################################
1575
1576 # Arguments: [0] the prompt string
1577 #            [1] if there is a U in the prompt and $force_update is true
1578 #            [2] if there is a C in the prompt and $force_continue is true
1579 # Returns:   returns the answer
1580
1581 sub interact {
1582   my ($prompt, $have_u, $have_c) = @_;
1583
1584   print $prompt;
1585
1586   if ($have_u) {
1587     print "... update forced\n";
1588     return 'u';
1589   }
1590
1591   if ($have_c) {
1592     print "... continue forced\n";
1593     return 'c';
1594   }
1595
1596   return lc <T>;
1597 }
1598
1599
1600
1601 ##################################################
1602 #    Subroutine to log in force_continue mode    #
1603 ##################################################
1604
1605 # In force_continue mode, we just want a terse output to a statically
1606 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1607 # all have mismatches, it will log multiple times.
1608 #
1609 # Arguments: [0] the logfile to append to
1610 #            [1] the testno that failed
1611 # Returns:   nothing
1612
1613
1614
1615 sub log_failure {
1616   my ($logfile, $testno, $detail) = @_;
1617
1618   open(my $fh, '>>', $logfile) or return;
1619
1620   print $fh "Test $testno "
1621         . (defined $detail ? "$detail " : '')
1622         . "failed\n";
1623 }
1624
1625 # Computer-readable summary results logfile
1626
1627 sub log_test {
1628   my ($logfile, $testno, $resultchar) = @_;
1629
1630   open(my $fh, '>>', $logfile) or return;
1631   print $fh "$testno $resultchar\n";
1632 }
1633
1634
1635
1636 ##################################################
1637 #    Subroutine to compare one output file       #
1638 ##################################################
1639
1640 # When an Exim server is part of the test, its output is in separate files from
1641 # an Exim client. The server data is concatenated with the client data as part
1642 # of the munging operation.
1643 #
1644 # Arguments:  [0] the name of the main raw output file
1645 #             [1] the name of the server raw output file or undef
1646 #             [2] where to put the munged copy
1647 #             [3] the name of the saved file
1648 #             [4] TRUE if this is a log file whose deliveries must be sorted
1649 #             [5] optionally, a custom munge command
1650 #
1651 # Returns:    0 comparison succeeded
1652 #             1 comparison failed; differences to be ignored
1653 #             2 comparison failed; files may have been updated (=> re-compare)
1654 #
1655 # Does not return if the user replies "Q" to a prompt.
1656
1657 sub check_file{
1658 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1659
1660 # If there is no saved file, the raw files must either not exist, or be
1661 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1662
1663 # we check if there is a flavour specific file, but we remember
1664 # the original file name as "generic"
1665 $sf_generic = $sf;
1666 $sf_flavour = "$sf_generic.$flavour";
1667 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1668
1669 if (! -e $sf_current)
1670   {
1671   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1672
1673   print "\n";
1674   print "** $rf is not empty\n" if (-s $rf);
1675   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1676
1677   for (;;)
1678     {
1679     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1680     tests_exit(1) if /^q?$/;
1681     if (/^c$/ && $force_continue) {
1682       log_failure($log_failed_filename, $testno, $rf);
1683       log_test($log_summary_filename, $testno, 'F') if ($force_continue);
1684     }
1685     return 1 if /^c$/i && $rf !~ /paniclog/ && (!defined $rsf || $rsf !~ /paniclog/);
1686     last if (/^[sc]$/);
1687     }
1688
1689   foreach $f ($rf, $rsf)
1690     {
1691     if (defined $f && -s $f)
1692       {
1693       print "\n";
1694       print "------------ $f -----------\n"
1695         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1696       system @more => $f;
1697       }
1698     }
1699
1700   print "\n";
1701   for (;;)
1702     {
1703     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1704     tests_exit(1) if /^q?$/;
1705     if (/^c$/ && $force_continue) {
1706       log_failure($log_failed_filename, $testno, $rf);
1707       log_test($log_summary_filename, $testno, 'F')
1708     }
1709     return 1 if /^c$/i;
1710     last if (/^u$/i);
1711     }
1712   }
1713
1714 #### $_
1715
1716 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1717 # was a request to create a saved file. First, create the munged file from any
1718 # data that does exist.
1719
1720 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1721 my($truncated) = munge($rf, $extra) if -e $rf;
1722
1723 # Append the raw server log, if it is non-empty
1724 if (defined $rsf && -e $rsf)
1725   {
1726   print MUNGED "\n******** SERVER ********\n";
1727   $truncated |= munge($rsf, $extra);
1728   }
1729 close(MUNGED);
1730
1731 # If a saved file exists, do the comparison. There are two awkward cases:
1732 #
1733 # If "*** truncated ***" was found in the new file, it means that a log line
1734 # was overlong, and truncated. The problem is that it may be truncated at
1735 # different points on different systems, because of different user name
1736 # lengths. We reload the file and the saved file, and remove lines from the new
1737 # file that precede "*** truncated ***" until we reach one that matches the
1738 # line that precedes it in the saved file.
1739 #
1740 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1741 # for an individual message might vary in their order from system to system, as
1742 # a result of parallel deliveries. We load the munged file and sort sequences
1743 # of delivery lines.
1744
1745 if (-e $sf_current)
1746   {
1747   # Deal with truncated text items
1748
1749   if ($truncated)
1750     {
1751     my(@munged, @saved, $i, $j, $k);
1752
1753     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1754     @munged = <MUNGED>;
1755     close(MUNGED);
1756     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1757     @saved = <SAVED>;
1758     close(SAVED);
1759
1760     $j = 0;
1761     for ($i = 0; $i < @munged; $i++)
1762       {
1763       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1764         {
1765         for (; $j < @saved; $j++)
1766           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1767         last if $j >= @saved;     # not found in saved
1768
1769         for ($k = $i - 1; $k >= 0; $k--)
1770           { last if $munged[$k] eq $saved[$j - 1]; }
1771
1772         last if $k <= 0;          # failed to find previous match
1773         splice @munged, $k + 1, $i - $k - 1;
1774         $i = $k + 1;
1775         }
1776       }
1777
1778     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1779     print $fh @munged;
1780     }
1781
1782   # Deal with log sorting
1783
1784   if ($sortfile)
1785     {
1786
1787     my @munged = do {
1788       open(my $fh, '<', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1789       <$fh>;
1790     };
1791
1792     for (my $i = 0; $i < @munged; $i++)
1793       {
1794       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1795         {
1796         my $j;
1797         for ($j = $i + 1; $j < @munged; $j++)
1798           {
1799           last if $munged[$j] !~
1800             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1801           }
1802         @temp = splice(@munged, $i, $j - $i);
1803         @temp = sort(@temp);
1804         splice(@munged, $i, 0, @temp);
1805         }
1806       }
1807
1808     open(my $fh, '>', $mf) or tests_exit(-1, "Failed to open $mf: $!");
1809     print $fh "**NOTE: The delivery lines in this file have been sorted.\n";
1810     print $fh @munged;
1811     }
1812
1813   # Do the comparison
1814
1815   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1816
1817   # Handle comparison failure
1818
1819   print "** Comparison of $mf with $sf_current failed";
1820   system @more => 'test-cf';
1821
1822   print "\n";
1823   for (;;)
1824     {
1825     $_ = interact('Continue, Retry, Update current'
1826         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1827         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1828     tests_exit(1) if /^q?$/;
1829     if (/^c$/ && $force_continue) {
1830       log_failure($log_failed_filename, $testno, $sf_current);
1831       log_test($log_summary_filename, $testno, 'F')
1832     }
1833     return 1 if /^c$/i;
1834     return 2 if /^r$/i;
1835     last if (/^[us]$/i);
1836     }
1837   }
1838
1839 # Update or delete the saved file, and give the appropriate return code.
1840
1841 if (-s $mf)
1842   {
1843     my $sf = /^u/i ? $sf_current : $sf_flavour;
1844     copy($mf, $sf) or tests_exit(-1, "Failed to copy $mf $sf");
1845   }
1846 else
1847   {
1848     # if we deal with a flavour file, we can't delete it, because next time the generic
1849     # file would be used again
1850     if ($sf_current eq $sf_flavour) {
1851       open(my $fh, '>', $sf_current);
1852     }
1853     else {
1854       tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1855     }
1856   }
1857
1858 return 2;
1859 }
1860
1861
1862
1863 ##################################################
1864 # Custom munges
1865 # keyed by name of munge; value is a ref to a hash
1866 # which is keyed by file, value a string to look for.
1867 # Usable files are:
1868 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1869 # Search strings starting with 's' do substitutions;
1870 # with '/' do line-skips.
1871 # Triggered by a scriptfile line "munge <name>"
1872 ##################################################
1873 $munges =
1874   { 'dnssec' =>
1875     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1876
1877     'gnutls_unexpected' =>
1878     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1879
1880     'gnutls_handshake' =>
1881     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1882
1883     'gnutls_bad_clientcert' =>
1884     { 'mainlog' => 's/\(certificate verification failed\): certificate invalid/\(gnutls_handshake\): The peer did not send any certificate./',
1885       'stdout'  => 's/Succeeded in starting TLS/A TLS fatal alert has been received.\nFailed to start TLS'
1886     },
1887
1888     'optional_events' =>
1889     { 'stdout' => '/event_action =/' },
1890
1891     'optional_ocsp' =>
1892     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1893
1894     'optional_cert_hostnames' =>
1895     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1896
1897     'loopback' =>
1898     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1899
1900     'scanfile_size' =>
1901     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1902
1903     'delay_1500' =>
1904     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1905
1906     'tls_anycipher' =>
1907     { 'mainlog'   => 's! X=TLS\S+ ! X=TLS_proto_and_cipher !;
1908                       s! DN="C=! DN="/C=!;
1909                       s! DN="[^,"]*\K,!/!;
1910                       s! DN="[^,"]*\K,!/!;
1911                       s! DN="[^,"]*\K,!/!;
1912                      ',
1913       'rejectlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /',
1914     },
1915
1916     'debug_pid' =>
1917     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d+/ppppp/g' },
1918
1919     'optional_dsn_info' =>
1920     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1921     },
1922
1923     'optional_config' =>
1924     { 'stdout' => '/^(
1925                   dkim_(canon|domain|private_key|selector|sign_headers|strict|hash|identity|timestamps)
1926                   |gnutls_require_(kx|mac|protocols)
1927                   |hosts_pipe_connect
1928                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1929                   |dane_require_tls_ciphers
1930                   |hosts_(avoid|nopass|noproxy|require|verify_avoid)_tls
1931                   |pipelining_connect_advertise_hosts
1932                   |socks_proxy
1933                   |tls_[^ ]*
1934                   |utf8_downconvert
1935                   )($|[ ]=)/x'
1936     },
1937
1938     'sys_bindir' =>
1939     { 'mainlog' => 's%/(usr/(local/)?)?bin/%SYSBINDIR/%' },
1940
1941     'sync_check_data' =>
1942     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1943       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1944
1945     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1946     { 'mainlog' => 's/((?:host|message) deferral .* errno) <\d+> /$1 <EEE> /' },
1947
1948     'peer_terminated_conn' =>   # actual error differs FreedBSD vs. Linux
1949     { 'stderr' => 's/^(  SMTP\()Connection reset by peer(\)<<)$/$1closed$2/' },
1950
1951     'perl_variants' =>          # result of hash-in-scalar-context changed from bucket-fill to keycount
1952     { 'stdout' => 's%^> X/X$%> X%' },
1953   };
1954
1955
1956 sub max {
1957   my ($a, $b) = @_;
1958   return $a if ($a > $b);
1959   return $b;
1960 }
1961
1962 ##################################################
1963 #    Subroutine to check the output of a test    #
1964 ##################################################
1965
1966 # This function is called when the series of subtests is complete. It makes
1967 # use of check_file(), whose arguments are:
1968 #
1969 #  [0] the name of the main raw output file
1970 #  [1] the name of the server raw output file or undef
1971 #  [2] where to put the munged copy
1972 #  [3] the name of the saved file
1973 #  [4] TRUE if this is a log file whose deliveries must be sorted
1974 #  [5] an optional custom munge command
1975 #
1976 # Arguments: Optionally, name of a single custom munge to run.
1977 # Returns:   0 if the output compared equal
1978 #            1 if comparison failed; differences to be ignored
1979 #            2 if re-run needed (files may have been updated)
1980
1981 sub check_output{
1982 my($mungename) = $_[0];
1983 my($yield) = 0;
1984 my($munge) = $munges->{$mungename} if defined $mungename;
1985
1986 $yield = max($yield,  check_file("spool/log/paniclog",
1987                        "spool/log/serverpaniclog",
1988                        "test-paniclog-munged",
1989                        "paniclog/$testno", 0,
1990                        $munge->{paniclog}));
1991
1992 $yield = max($yield,  check_file("spool/log/rejectlog",
1993                        "spool/log/serverrejectlog",
1994                        "test-rejectlog-munged",
1995                        "rejectlog/$testno", 0,
1996                        $munge->{rejectlog}));
1997
1998 $yield = max($yield,  check_file("spool/log/mainlog",
1999                        "spool/log/servermainlog",
2000                        "test-mainlog-munged",
2001                        "log/$testno", $sortlog,
2002                        $munge->{mainlog}));
2003
2004 if (!$stdout_skip)
2005   {
2006   $yield = max($yield,  check_file("test-stdout",
2007                        "test-stdout-server",
2008                        "test-stdout-munged",
2009                        "stdout/$testno", 0,
2010                        $munge->{stdout}));
2011   }
2012
2013 if (!$stderr_skip)
2014   {
2015   $yield = max($yield,  check_file("test-stderr",
2016                        "test-stderr-server",
2017                        "test-stderr-munged",
2018                        "stderr/$testno", 0,
2019                        $munge->{stderr}));
2020   }
2021
2022 # Compare any delivered messages, unless this test is skipped.
2023
2024 if (! $message_skip)
2025   {
2026   my($msgno) = 0;
2027
2028   # Get a list of expected mailbox files for this script. We don't bother with
2029   # directories, just the files within them.
2030
2031   foreach $oldmail (@oldmails)
2032     {
2033     next unless $oldmail =~ /^mail\/$testno\./;
2034     print ">> EXPECT $oldmail\n" if $debug;
2035     $expected_mails{$oldmail} = 1;
2036     }
2037
2038   # If there are any files in test-mail, compare them. Note that "." and
2039   # ".." are automatically omitted by list_files_below().
2040
2041   @mails = list_files_below("test-mail");
2042
2043   foreach $mail (@mails)
2044     {
2045     next if $mail =~ /^test-mail\/oncelog(.(dir|pag|db))?$/;
2046
2047     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
2048     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
2049
2050     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
2051       {
2052       $msgno++;
2053       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
2054       }
2055
2056     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
2057     $yield = max($yield,  check_file($mail, undef, "test-mail-munged",
2058       "mail/$testno.$saved_mail", 0,
2059       $munge->{mail}));
2060     delete $expected_mails{"mail/$testno.$saved_mail"};
2061     }
2062
2063   # Complain if not all expected mails have been found
2064
2065   if (scalar(keys %expected_mails) != 0)
2066     {
2067     foreach $key (keys %expected_mails)
2068       { print "** no test file found for $key\n"; }
2069
2070     for (;;)
2071       {
2072       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
2073       tests_exit(1) if /^q?$/;
2074       if (/^c$/ && $force_continue) {
2075         log_failure($log_failed_filename, $testno, "missing email");
2076         log_test($log_summary_filename, $testno, 'F')
2077       }
2078       last if /^c$/;
2079
2080       # For update, we not only have to unlink the file, but we must also
2081       # remove it from the @oldmails vector, as otherwise it will still be
2082       # checked for when we re-run the test.
2083
2084       if (/^u$/)
2085         {
2086         foreach $key (keys %expected_mails)
2087           {
2088           my($i);
2089           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
2090           for ($i = 0; $i < @oldmails; $i++)
2091             {
2092             if ($oldmails[$i] eq $key)
2093               {
2094               splice @oldmails, $i, 1;
2095               last;
2096               }
2097             }
2098           }
2099         last;
2100         }
2101       }
2102     }
2103   }
2104
2105 # Compare any remaining message logs, unless this test is skipped.
2106
2107 if (! $msglog_skip)
2108   {
2109   # Get a list of expected msglog files for this test
2110
2111   foreach $oldmsglog (@oldmsglogs)
2112     {
2113     next unless $oldmsglog =~ /^$testno\./;
2114     $expected_msglogs{$oldmsglog} = 1;
2115     }
2116
2117   # If there are any files in spool/msglog, compare them. However, we have
2118   # to munge the file names because they are message ids, which are
2119   # time dependent.
2120
2121   if (opendir(DIR, "spool/msglog"))
2122     {
2123     @msglogs = sort readdir(DIR);
2124     closedir(DIR);
2125
2126     foreach $msglog (@msglogs)
2127       {
2128       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
2129       ($munged_msglog = $msglog) =~
2130         s/((?:[^\W_]{6}-){2}[^\W_]{2})
2131           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
2132       $yield = max($yield,  check_file("spool/msglog/$msglog", undef,
2133         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
2134         $munge->{msglog}));
2135       delete $expected_msglogs{"$testno.$munged_msglog"};
2136       }
2137     }
2138
2139   # Complain if not all expected msglogs have been found
2140
2141   if (scalar(keys %expected_msglogs) != 0)
2142     {
2143     foreach $key (keys %expected_msglogs)
2144       {
2145       print "** no test msglog found for msglog/$key\n";
2146       ($msgid) = $key =~ /^\d+\.(.*)$/;
2147       foreach $cachekey (keys %cache)
2148         {
2149         if ($cache{$cachekey} eq $msgid)
2150           {
2151           print "** original msgid $cachekey\n";
2152           last;
2153           }
2154         }
2155       }
2156
2157     for (;;)
2158       {
2159       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
2160       tests_exit(1) if /^q?$/;
2161       if (/^c$/ && $force_continue) {
2162         log_failure($log_failed_filename, $testno, "missing msglog");
2163         log_test($log_summary_filename, $testno, 'F')
2164       }
2165       last if /^c$/;
2166       if (/^u$/)
2167         {
2168         foreach $key (keys %expected_msglogs)
2169           {
2170           tests_exit(-1, "Failed to unlink msglog/$key")
2171             if !unlink("msglog/$key");
2172           }
2173         last;
2174         }
2175       }
2176     }
2177   }
2178
2179 return $yield;
2180 }
2181
2182
2183
2184 ##################################################
2185 #     Subroutine to run one "system" command     #
2186 ##################################################
2187
2188 # We put this in a subroutine so that the command can be reflected when
2189 # debugging.
2190 #
2191 # Argument: the command to be run
2192 # Returns:  nothing
2193
2194 sub run_system {
2195 my($cmd) = $_[0];
2196 if ($debug)
2197   {
2198   my($prcmd) = $cmd;
2199   $prcmd =~ s/; /;\n>> /;
2200   print ">> $prcmd\n";
2201   }
2202 system($cmd);
2203 }
2204
2205
2206
2207 ##################################################
2208 #      Subroutine to run one script command      #
2209 ##################################################
2210
2211 # The <SCRIPT> file is open for us to read an optional return code line,
2212 # followed by the command line and any following data lines for stdin. The
2213 # command line can be continued by the use of \. Data lines are not continued
2214 # in this way. In all lines, the following substitutions are made:
2215 #
2216 # DIR    => the current directory
2217 # CALLER => the caller of this script
2218 #
2219 # Arguments: the current test number
2220 #            reference to the subtest number, holding previous value
2221 #            reference to the expected return code value
2222 #            reference to where to put the command name (for messages)
2223 #            auxiliary information returned from a previous run
2224 #
2225 # Returns:   0 the command was executed inline, no subprocess was run
2226 #            1 a non-exim command was run and waited for
2227 #            2 an exim command was run and waited for
2228 #            3 a command was run and not waited for (daemon, server, exim_lock)
2229 #            4 EOF was encountered after an initial return code line
2230 # Optionally also a second parameter, a hash-ref, with auxiliary information:
2231 #            exim_pid: pid of a run process
2232 #            munge: name of a post-script results munger
2233
2234 sub run_command{
2235 my($testno) = $_[0];
2236 my($subtestref) = $_[1];
2237 my($commandnameref) = $_[3];
2238 my($aux_info) = $_[4];
2239 my($yield) = 1;
2240
2241 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
2242
2243 if (/^(\d+)\s*$/)                # Handle unusual return code
2244   {
2245   my($r) = $_[2];
2246   $$r = $1 << 8;
2247   $_ = <SCRIPT>;
2248   return 4 if !defined $_;       # Missing command
2249   $lineno++;
2250   }
2251
2252 chomp;
2253 $wait_time = 0;
2254
2255 # Handle concatenated command lines
2256
2257 s/\s+$//;
2258 while (substr($_, -1) eq"\\")
2259   {
2260   my($temp);
2261   $_ = substr($_, 0, -1);
2262   chomp($temp = <SCRIPT>);
2263   if (defined $temp)
2264     {
2265     $lineno++;
2266     $temp =~ s/\s+$//;
2267     $temp =~ s/^\s+//;
2268     $_ .= $temp;
2269     }
2270   }
2271
2272 # Do substitutions
2273
2274 do_substitute($testno);
2275 if ($debug) { printf ">> $_\n"; }
2276
2277 # Pass back the command name (for messages)
2278
2279 ($$commandnameref) = /^(\S+)/;
2280
2281 # Here follows code for handling the various different commands that are
2282 # supported by this script. The first group of commands are all freestanding
2283 # in that they share no common code and are not followed by any data lines.
2284
2285
2286 ###################
2287 ###################
2288
2289 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
2290 # utility and to make DBM files for testing DBM lookups.
2291
2292 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
2293   {
2294   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
2295          "echo exim_dbmbuild exit code = \$?)" .
2296          ">>test-stdout");
2297   return 1;
2298   }
2299
2300
2301 # The "dump" command runs exim_dumpdb. On different systems, the output for
2302 # some types of dump may appear in a different order because it's just hauled
2303 # out of the DBM file. We can solve this by sorting. Ignore the leading
2304 # date/time, as it will be flattened later during munging.
2305
2306 if (/^dump\s+(\S+)/)
2307   {
2308   my $which  = $1;
2309   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
2310   open(my $in, "-|", './eximdir/exim_dumpdb', "$parm_cwd/spool", $which) or die "Can't run exim_dumpdb: $!";
2311   open(my $out, ">>test-stdout");
2312   print $out "+++++++++++++++++++++++++++\n";
2313
2314   if ($which eq "retry")
2315     {
2316     # the sort key is the first part of the retry db dump line, but for
2317     # sorting we (temporarly) replace the own hosts ipv4 with a munged
2318     # version, which matches the munging that is done later
2319     # Why? We must ensure sure, that 127.0.0.1 always sorts first
2320     # map-sort-map: Schwartz's transformation
2321     # test 0099
2322     my @temp = map  { $_->[1] }
2323                sort { $a->[0] cmp $b->[0] }
2324                #map  { [ (split)[0] =~ s/\Q$parm_ipv4/ip4.ip4.ip4.ip4/gr, $_ ] }  # this is too modern for 5.10.1
2325                map  {
2326                 (my $k = (split)[0]) =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/g;
2327                 [ $k, $_ ]
2328                }
2329                do { local $/ = "\n  "; <$in> };
2330     foreach $item (@temp)
2331       {
2332       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
2333       print $out "  $item\n";
2334       }
2335     }
2336   else
2337     {
2338     my @temp = <$in>;
2339     if ($which eq "callout")
2340       {
2341       @temp = sort {
2342                    my($aa) = substr $a, 21;
2343                    my($bb) = substr $b, 21;
2344                    return $aa cmp $bb;
2345                    } @temp;
2346       }
2347     elsif ($which eq "seen")
2348       {
2349       @temp = sort {
2350                    (my $aa = $a) =~ s/^([\d.]+)/$1/;
2351                    (my $bb = $b) =~ s/^([\d.]+)/$1/;
2352                    $aa =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/;
2353                    $bb =~ s/\Q$parm_ipv4\E/ip4.ip4.ip4.ip4/;
2354                    return $aa cmp $bb;
2355                    } @temp;
2356       }
2357     print $out @temp;
2358     }
2359   close($in); # close it explicitly, otherwise $? does not get set
2360   return 1;
2361   }
2362
2363
2364 # verbose comments start with ###
2365 if (/^###\s/) {
2366   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
2367     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
2368     say {$fh} $_;
2369   }
2370   return 0;
2371 }
2372
2373 # The "echo" command is a way of writing comments to the screen.
2374 if (/^echo\s+(.*)$/)
2375   {
2376   print "$1\n";
2377   return 0;
2378   }
2379
2380
2381 # The "exim_lock" command runs exim_lock in the same manner as "server",
2382 # but it doesn't use any input.
2383
2384 if (/^exim_lock\s+(.*)$/)
2385   {
2386   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
2387   $server_pid = open SERVERCMD, "|$cmd" ||
2388     tests_exit(-1, "Failed to run $cmd\n");
2389
2390   # This gives the process time to get started; otherwise the next
2391   # process may not find it there when it expects it.
2392
2393   select(undef, undef, undef, 0.1);
2394   return 3;
2395   }
2396
2397
2398 # The "exinext" command runs exinext
2399
2400 if (/^exinext\s+(.*)/)
2401   {
2402   run_system("(./eximdir/exinext " .
2403     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2404     "-C $parm_cwd/test-config $1;" .
2405     "echo exinext exit code = \$?)" .
2406     ">>test-stdout");
2407   return 1;
2408   }
2409
2410
2411 # The "exigrep" command runs exigrep on the current mainlog
2412
2413 if (/^exigrep\s+(.*)/)
2414   {
2415   run_system("(./eximdir/exigrep " .
2416     "$1 $parm_cwd/spool/log/mainlog;" .
2417     "echo exigrep exit code = \$?)" .
2418     ">>test-stdout");
2419   return 1;
2420   }
2421
2422
2423 # The "exiqgrep" command runs exiqgrep on the current spool
2424
2425 if (/^exiqgrep(\s+.*)?/)
2426   {
2427   run_system("(./eximdir/exiqgrep -E ./eximdir/exim -C $parm_cwd/test-config" . ($1 || '') . ";" .
2428     "echo exiqgrep exit code = \$?)" .
2429     ">>test-stdout");
2430   return 1;
2431   }
2432
2433
2434 # The "eximstats" command runs eximstats on the current mainlog
2435
2436 if (/^eximstats\s+(.*)/)
2437   {
2438   run_system("(./eximdir/eximstats " .
2439     "$1 $parm_cwd/spool/log/mainlog;" .
2440     "echo eximstats exit code = \$?)" .
2441     ">>test-stdout");
2442   return 1;
2443   }
2444
2445
2446 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
2447 # spool directory, to save Exim from re-creating it each time.
2448
2449 if (/^gnutls/)
2450   {
2451   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
2452   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
2453          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
2454          "sudo chmod 0400 $gen_fn";
2455   return 1;
2456   }
2457
2458
2459 # The "killdaemon" command should ultimately follow the starting of any Exim
2460 # daemon with the -bd option.
2461
2462 if (/^killdaemon/)
2463   {
2464   my $return_extra = {};
2465   if (exists $aux_info->{exim_pid})
2466     {
2467     $pid = $aux_info->{exim_pid};
2468     $return_extra->{exim_pid} = undef;
2469     print ">> killdaemon: recovered pid $pid\n" if $debug;
2470     if ($pid)
2471       {
2472       run_system("sudo /bin/kill -TERM $pid");
2473       wait;
2474       }
2475     } else {
2476     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
2477     if ($pid)
2478       {
2479       run_system("sudo /bin/kill -TERM $pid");
2480       close DAEMONCMD;                                   # Waits for process
2481       }
2482     }
2483     run_system("sudo /bin/rm -f spool/exim-daemon.*");
2484   return (1, $return_extra);
2485   }
2486
2487
2488 # The "millisleep" command is like "sleep" except that its argument is in
2489 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2490 # is used for.
2491
2492 elsif (/^millisleep\s+(.*)$/)
2493   {
2494   select(undef, undef, undef, $1/1000);
2495   return 0;
2496   }
2497
2498
2499 # The "munge" command selects one of a hardwired set of test-result modifications
2500 # to be made before result compares are run against the golden set.  This lets
2501 # us account for test-system dependent things which only affect a few, but known,
2502 # test-cases.
2503 # Currently only the last munge takes effect.
2504
2505 if (/^munge\s+(.*)$/)
2506   {
2507   return (0, { munge => $1 });
2508   }
2509
2510
2511 # The "sleep" command does just that. For sleeps longer than 1 second we
2512 # tell the user what's going on.
2513
2514 if (/^sleep\s+(.*)$/)
2515   {
2516   if ($1 == 1)
2517     {
2518     sleep(1);
2519     }
2520   else
2521     {
2522     printf("  Test %d sleep $1 ", $$subtestref);
2523     for (1..$1)
2524       {
2525       print ".";
2526       sleep(1);
2527       }
2528     printf("\r  Test %d                            $cr", $$subtestref);
2529     }
2530   return 0;
2531   }
2532
2533
2534 # Various Unix management commands are recognized
2535
2536 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2537     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2538   {
2539   run_system("$_ >>test-stdout 2>>test-stderr");
2540   return 1;
2541   }
2542
2543
2544
2545 ###################
2546 ###################
2547
2548 # The next group of commands are also freestanding, but they are all followed
2549 # by data lines.
2550
2551
2552 # The "server" command starts up a script-driven server that runs in parallel
2553 # with the following exim command. Therefore, we want to run a subprocess and
2554 # not yet wait for it to complete. The waiting happens after the next exim
2555 # command, triggered by $server_pid being non-zero. The server sends its output
2556 # to a different file. The variable $server_opts, if not empty, contains
2557 # options to disable IPv4 or IPv6 if necessary.
2558 # This works because "server" swallows its stdin before waiting for a connection.
2559
2560 if (/^server\s+(.*)$/)
2561   {
2562   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2563   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2564   print ">> $cmd\n" if ($debug);
2565   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2566   SERVERCMD->autoflush(1);
2567   print ">> Server pid is $server_pid\n" if $debug;
2568   while (<SCRIPT>)
2569     {
2570     $lineno++;
2571     last if /^\*{4}\s*$/;
2572     print SERVERCMD;
2573     }
2574   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2575                             # because close() waits for the process.
2576
2577   # Interlock the server startup; otherwise the next
2578   # process may not find it there when it expects it.
2579   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2580   return 3;
2581   }
2582
2583
2584 # The "write" command is a way of creating files of specific sizes for
2585 # buffering tests, or containing specific data lines from within the script
2586 # (rather than hold lots of little files). The "catwrite" command does the
2587 # same, but it also copies the lines to test-stdout.
2588
2589 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2590   {
2591   my($cat) = defined $1;
2592   @sizes = ();
2593   @sizes = split /\s+/, $3 if defined $3;
2594   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2595
2596   if ($cat)
2597     {
2598     open CAT, ">>test-stdout" ||
2599       tests_exit(-1, "Failed to open test-stdout: $!");
2600     print CAT "==========\n";
2601     }
2602
2603   if (scalar @sizes > 0)
2604     {
2605     # Pre-data
2606
2607     while (<SCRIPT>)
2608       {
2609       $lineno++;
2610       last if /^\+{4}\s*$/;
2611       print FILE;
2612       print CAT if $cat;
2613       }
2614
2615     # Sized data
2616
2617     while (scalar @sizes > 0)
2618       {
2619       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2620       $leadin = '' if !defined $leadin;
2621       $leadin =~ s/_/ /g;
2622       $len -= length($leadin) + 1;
2623       while ($count-- > 0)
2624         {
2625         print FILE $leadin, "a" x $len, "\n";
2626         print CAT $leadin, "a" x $len, "\n" if $cat;
2627         }
2628       }
2629     }
2630
2631   # Post data, or only data if no sized data
2632
2633   while (<SCRIPT>)
2634     {
2635     $lineno++;
2636     last if /^\*{4}\s*$/;
2637     print FILE;
2638     print CAT if $cat;
2639     }
2640   close FILE;
2641
2642   if ($cat)
2643     {
2644     print CAT "==========\n";
2645     close CAT;
2646     }
2647
2648   return 0;
2649   }
2650
2651
2652 ###################
2653 ###################
2654
2655 # From this point on, script commands are implemented by setting up a shell
2656 # command in the variable $cmd. Shared code to run this command and handle its
2657 # input and output follows.
2658
2659 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2660 # program that plays the part of an email client. We also have the availability
2661 # of running Perl for doing one-off special things. Note that all these
2662 # commands expect stdin data to be supplied.
2663
2664 if (/^client/ || /^(sudo\s+)?perl\b/)
2665   {
2666   s"client"./bin/client";
2667   $cmd = "$_ >>test-stdout 2>>test-stderr";
2668   }
2669
2670 # For the "exim" command, replace the text "exim" with the path for the test
2671 # binary, plus -D options to pass over various parameters, and a -C option for
2672 # the testing configuration file. When running in the test harness, Exim does
2673 # not drop privilege when -C and -D options are present. To run the exim
2674 # command as root, we use sudo.
2675
2676 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2677   {
2678   $args = $6;
2679   my($envset) = (defined $1)? $1      : '';
2680   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2681   my($special)= (defined $5)? $5      : '';
2682   $wait_time  = (defined $2)? $2      : 0;
2683
2684   # Return 2 rather than 1 afterwards
2685
2686   $yield = 2;
2687
2688   # Update the test number
2689
2690   $$subtestref = $$subtestref + 1;
2691   printf("  Test %d       $cr", $$subtestref);
2692
2693   # Copy the configuration file, making the usual substitutions.
2694
2695   open (IN, "$parm_cwd/confs/$testno") ||
2696     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2697   open (OUT, ">test-config") ||
2698     tests_exit(-1, "Couldn't open test-config: $!\n");
2699   while (<IN>)
2700     {
2701     do_substitute($testno);
2702     print OUT;
2703     }
2704   close(IN);
2705   close(OUT);
2706
2707   # The string $msg1 in args substitutes the message id of the first
2708   # message on the queue, and so on. */
2709
2710   if ($args =~ /\$msg/)
2711     {
2712     my($queuespec);
2713     if ($args =~ /-qG\w+/) { $queuespec = $&; }
2714
2715     my @listcmd;
2716
2717     if (defined $queuespec)
2718       {
2719       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2720                    $queuespec,
2721                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2722                    -C => "$parm_cwd/test-config");
2723       }
2724     else
2725       {
2726       @listcmd  = ("$parm_cwd/eximdir/exim", '-bp',
2727                    "-DEXIM_PATH=$parm_cwd/eximdir/exim",
2728                    -C => "$parm_cwd/test-config");
2729       }
2730     print ">> Getting queue list from:\n>>    @listcmd\n" if $debug;
2731     # We need the message ids sorted in ascending order.
2732     # Message id is: <timestamp>-<pid>-<fractional-time>. On some systems (*BSD) the
2733     # PIDs are randomized, so sorting just the whole PID doesn't work.
2734     # We do the Schartz' transformation here (sort on
2735     # <timestamp><fractional-time>). Thanks to Kirill Miazine
2736     my @msglist =
2737       map { $_->[1] }                                   # extract the values
2738       sort { $a->[0] cmp $b->[0] }                      # sort by key
2739       map { [join('.' => (split /-/, $_)[0,2]) => $_] } # key (timestamp.fractional-time) => value(message_id)
2740       map { /^\s*\d+[smhdw]\s+\S+\s+(\S+)/ } `@listcmd` or tests_exit(-1, "No output from `exim -bp` (@listcmd)\n");
2741
2742     # Done backwards just in case there are more than 9
2743
2744     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2745     if ( $args =~ /\$msg\d/ )
2746       {
2747       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2748         unless $force_continue;
2749       }
2750     }
2751
2752   # If -d is specified in $optargs, remove it from $args; i.e. let
2753   # the command line for runtest override. Then run Exim.
2754
2755   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2756
2757   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2758
2759   $cmd = "$envset$sudo$opt_valgrind" .
2760          "$parm_cwd/eximdir/exim$special$optargs " .
2761          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2762          "-C $parm_cwd/test-config $args " .
2763          ">>test-stdout 2>>test-stderr";
2764   # If the command is starting an Exim daemon, we run it in the same
2765   # way as the "server" command above, that is, we don't want to wait
2766   # for the process to finish. That happens when "killdaemon" is obeyed later
2767   # in the script. We also send the stderr output to test-stderr-server. The
2768   # daemon has its log files put in a different place too (by configuring with
2769   # log_file_path). This requires the  directory to be set up in advance.
2770   #
2771   # There are also times when we want to run a non-daemon version of Exim
2772   # (e.g. a queue runner) with the server configuration. In this case,
2773   # we also define -DNOTDAEMON.
2774
2775   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2776     {
2777     if ($debug) { printf ">> daemon: $cmd\n"; }
2778     run_system("sudo mkdir spool/log 2>/dev/null");
2779     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2780
2781     # Before running the command, convert the -bd option into -bdf so that an
2782     # Exim daemon doesn't double fork. This means that when we wait close
2783     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2784     # file is written to the spool directory, in case the Exim binary was
2785     # built with PID_FILE_PATH pointing somewhere else.
2786
2787     if ($cmd =~ /\s-oP\s/)
2788       {
2789       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2790       $cmd =~ s!\s-bd\s! -bdf !;
2791       }
2792     else
2793       {
2794       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2795       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2796       }
2797     print ">> |${cmd}-server\n" if ($debug);
2798     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2799     DAEMONCMD->autoflush(1);
2800     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2801
2802     # Interlock with daemon startup
2803     for (my $count = 0; ! stat("$pidfile") && $count < 30; $count++ )
2804       { select(undef, undef, undef, 0.3); }
2805     return 3;                                     # Don't wait
2806     }
2807   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2808     {
2809
2810     # The port and the $dynamic_socket was already allocated while parsing the
2811     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2812
2813     my $listen_port = $1;
2814     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2815     run_system("sudo mkdir spool/log 2>/dev/null");
2816     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2817
2818     my $pid = fork();
2819     if (not defined $pid) { die "** fork failed: $!\n" }
2820     if (not $pid) {
2821       close(STDIN);
2822       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2823       close($dynamic_socket);
2824       print "[$$]>> ${cmd}-server\n" if ($debug);
2825       exec "exec ${cmd}-server";
2826       die "Can't exec ${cmd}-server: $!\n";
2827     }
2828     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2829     select(undef, undef, undef, 0.3);             # Let the daemon get going
2830     return (3, { exim_pid => $pid });             # Don't wait
2831     }
2832   }
2833
2834 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2835 # One script line is read and fork-exec'd.  The PID is stored for a later
2836 # killdaemon.
2837
2838 elsif (/^background$/)
2839   {
2840   my $line;
2841 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2842
2843   $_ = <SCRIPT>; $lineno++;
2844   chomp;
2845   do_substitute($testno);
2846   $line = $_;
2847   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2848
2849   my $pid = fork();
2850   if (not defined $pid) { die "** fork failed: $!\n" }
2851   if (not $pid) {
2852     print "[$$]>> ${line}\n" if ($debug);
2853     close(STDIN);
2854     open(STDIN, "<", "test-stdout");
2855     close(STDOUT);
2856     open(STDOUT, ">>", "test-stdout");
2857     close(STDERR);
2858     open(STDERR, ">>", "test-stderr-server");
2859     exec "exec ${line}";
2860     exit(1);
2861   }
2862
2863 #  open(my $fh, ">", $pidfile) ||
2864 #      tests_exit(-1, "Failed to open $pidfile: $!");
2865 #  printf($fh, "%d\n", $pid);
2866 #  close($fh);
2867
2868   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2869   select(undef, undef, undef, 0.3);             # Let the daemon get going
2870   return (3, { exim_pid => $pid });             # Don't wait
2871   }
2872
2873
2874
2875 # Unknown command
2876
2877 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2878
2879
2880 # Run the command, with stdin connected to a pipe, and write the stdin data
2881 # to it, with appropriate substitutions. If a starts with '>>> ', process it
2882 # via Perl's string eval().
2883 # If the command contains
2884 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2885 # for the stderr file. See comment above about the use of -DSERVER.
2886
2887 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2888 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2889 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2890
2891 CMD->autoflush(1);
2892 LINE: while (<SCRIPT>)
2893   {
2894   $lineno++;
2895   last if /^\*{4}\s*$/;
2896   do_substitute($testno);
2897   if (my ($cmd, $line) = /^(:\S+?:)(.*)/) {
2898     $_ = $line;
2899       {
2900       $cmd eq ':eval:' and do {
2901         $_ = eval "\"$_\"";
2902         last;
2903       };
2904       $cmd eq ':noeol:' and do {
2905         s/[\r\n]*$//;
2906         last;
2907       };
2908       $cmd eq ':sleep:' and do {
2909         sleep $_;
2910         next LINE;
2911       };
2912     }
2913   }
2914   print CMD;
2915   }
2916
2917 # For timeout tests, wait before closing the pipe; we expect a
2918 # SIGPIPE error in this case.
2919
2920 if ($wait_time > 0)
2921   {
2922   printf("  Test %d sleep $wait_time ", $$subtestref);
2923   while ($wait_time-- > 0)
2924     {
2925     print ".";
2926     sleep(1);
2927     }
2928   printf("\r  Test %d                                       $cr", $$subtestref);
2929   }
2930
2931 $sigpipehappened = 0;
2932 close CMD;                # Waits for command to finish
2933 return $yield;            # Ran command and waited
2934 }
2935
2936
2937
2938
2939 ###############################################################################
2940 ###############################################################################
2941
2942 # Here begins the Main Program ...
2943
2944 ###############################################################################
2945 ###############################################################################
2946
2947
2948 autoflush STDOUT 1;
2949 print "Exim tester $testversion\n";
2950
2951 # extend the PATH with .../sbin
2952 # we map all (.../bin) to (.../sbin:.../bin)
2953 $ENV{PATH} = do {
2954   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2955   join ':' => map { m{(.*)/bin$}
2956                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2957                 : ($_) }
2958       split /:/, $ENV{PATH};
2959 };
2960
2961 ##################################################
2962 #      Some tests check created file modes       #
2963 ##################################################
2964
2965 umask 022;
2966
2967
2968 ##################################################
2969 #       Check for the "less" command             #
2970 ##################################################
2971
2972 @more = 'more' if system('which less >/dev/null 2>&1') != 0;
2973
2974
2975
2976 ##################################################
2977 #      See if an Exim binary has been given      #
2978 ##################################################
2979
2980 # If the first character of the first argument is '/', the argument is taken
2981 # as the path to the binary. If the first argument does not start with a
2982 # '/' but exists in the file system, it's assumed to be the Exim binary.
2983
2984
2985 ##################################################
2986 # Sort out options and which tests are to be run #
2987 ##################################################
2988
2989 # There are a few possible options for the test script itself; after these, any
2990 # options are passed on to Exim calls within the tests. Typically, this is used
2991 # to turn on Exim debugging while setting up a test.
2992
2993 Getopt::Long::Configure qw(no_getopt_compat);
2994 GetOptions(
2995     'debug'    => sub { $debug          = 1; $cr   = "\n" },
2996     'diff'     => sub { $cf             = 'diff -u' },
2997     'continue' => sub { $force_continue = 1; @more = 'cat' },
2998     'update'   => \$force_update,
2999     'ipv4!'    => \$have_ipv4,
3000     'ipv6!'    => \$have_ipv6,
3001     'keep'     => \$save_output,
3002     'slow'     => \$slow,
3003     'valgrind' => \$valgrind,
3004     'range=s{2}'       => \my @range_wanted,
3005     'test=i@'          => \my @tests_wanted,
3006     'fail-any!'        => \my $fail_any,
3007     'flavor|flavour=s' => \$flavour,
3008     'help'             => sub { pod2usage(-exit => 0) },
3009     'man'              => sub {
3010         pod2usage(
3011             -exit      => 0,
3012             -verbose   => 2,
3013             -noperldoc => system('perldoc -V 2>/dev/null 1>&2')
3014         );
3015     },
3016 ) or pod2usage;
3017
3018 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
3019 print "Exim binary is `$parm_exim'\n" if defined $parm_exim;
3020
3021
3022 my @wanted = sort numerically uniq
3023   @tests_wanted ? @tests_wanted : (),
3024   @range_wanted ? $range_wanted[0] .. $range_wanted[1] : (),
3025   @ARGV ? @ARGV == 1 ? $ARGV[0] :
3026           $ARGV[1] eq '+' ? $ARGV[0]..($ARGV[0] >= 9000 ? TEST_SPECIAL_TOP : TEST_TOP) :
3027           0+$ARGV[0]..0+$ARGV[1]    # add 0 to cope with test numbers starting with zero
3028         : ();
3029 @wanted = 1..TEST_TOP if not @wanted;
3030
3031 ##################################################
3032 #        Check for sudo access to root           #
3033 ##################################################
3034
3035 print "You need to have sudo access to root to run these tests. Checking ...\n";
3036 if (system('sudo true >/dev/null') != 0)
3037   {
3038   die "** Test for sudo failed: testing abandoned.\n";
3039   }
3040 else
3041   {
3042   print "Test for sudo OK\n";
3043   }
3044
3045
3046
3047
3048 ##################################################
3049 #      Make the command's directory current      #
3050 ##################################################
3051
3052 # After doing so, we find its absolute path name.
3053
3054 $cwd = $0;
3055 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
3056 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
3057 $parm_cwd = Cwd::getcwd();
3058
3059
3060 ##################################################
3061 #     Search for an Exim binary to test          #
3062 ##################################################
3063
3064 # If an Exim binary hasn't been provided, try to find one. We can handle the
3065 # case where exim-testsuite is installed alongside Exim source directories. For
3066 # PH's private convenience, if there's a directory just called "exim4", that
3067 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
3068 # releases.
3069
3070 # If $parm_exim is still empty, ask the caller
3071
3072 if (not $parm_exim)
3073   {
3074   print "** Did not find an Exim binary to test\n";
3075   for ($i = 0; $i < 5; $i++)
3076     {
3077     my($trybin);
3078     print "** Enter pathname for Exim binary: ";
3079     chomp($trybin = <STDIN>);
3080     if (-e $trybin)
3081       {
3082       $parm_exim = $trybin;
3083       last;
3084       }
3085     else
3086       {
3087       print "** $trybin does not exist\n";
3088       }
3089     }
3090   die "** Too many tries\n" if $parm_exim eq '';
3091   }
3092
3093
3094
3095 ##################################################
3096 #          Find what is in the binary            #
3097 ##################################################
3098
3099 # deal with TRUSTED_CONFIG_LIST restrictions
3100 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
3101 open (IN, "$parm_cwd/confs/0000") ||
3102   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3103 open (OUT, ">test-config") ||
3104   tests_exit(-1, "Couldn't open test-config: $!\n");
3105 while (<IN>) { print OUT; }
3106 close(IN);
3107 close(OUT);
3108
3109 print("Probing with config file: $parm_cwd/test-config\n");
3110
3111 my $eximinfo = "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd -bP exim_user exim_group";
3112 chomp(my @eximinfo = `$eximinfo 2>&1`);
3113 die "$0: Can't run $eximinfo\n" if $? == -1;
3114
3115 warn 'Got ' . ($?>>8) . " from $eximinfo\n" if $?;
3116 foreach (@eximinfo)
3117   {
3118   if (my ($version) = /^Exim version (\S+)/) {
3119     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
3120     if (defined $git and $? == 0) {
3121       chomp $git;
3122       $git =~ s/^exim-//i;
3123       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
3124       print <<___
3125
3126 *** Version mismatch
3127 *** Exim binary: $version
3128 *** Git        : $git
3129
3130 ___
3131         if not $version eq $git;
3132     }
3133   }
3134   $parm_eximuser = $1 if /^exim_user = (.*)$/;
3135   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
3136   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
3137   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
3138         if /^Configure owner:\s*(\d+):(\d+)/;
3139   print if /wrong owner/;
3140   }
3141
3142 if (not defined $parm_eximuser) {
3143   die <<XXX, map { "|$_\n" } @eximinfo;
3144 Unable to extract exim_user from binary.
3145 Check if Exim refused to run; if so, consider:
3146   TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS
3147 If debug permission denied, are you in the exim group?
3148 Failing to get information from binary.
3149 Output from $eximinfo:
3150 XXX
3151
3152 }
3153
3154 if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
3155 else { $parm_exim_uid = getpwnam($parm_eximuser); }
3156
3157 if (defined $parm_eximgroup)
3158   {
3159   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
3160     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
3161   }
3162
3163 # check the permissions on the TRUSTED_CONFIG_LIST
3164 if (defined $parm_trusted_config_list)
3165   {
3166   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
3167     if not -f $parm_trusted_config_list;
3168
3169   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
3170     if 02 & (stat _)[2];
3171
3172   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
3173   (stat _)[1],
3174     scalar(getgrgid 0), scalar(getgrgid $>)
3175     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
3176
3177   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
3178   scalar(getpwuid 0), scalar(getpwuid $>)
3179      if (not (-o _ or (stat _)[4] == 0));
3180
3181   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
3182   my $test_config = getcwd() . '/test-config';
3183   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
3184     if not grep { /^\Q$test_config\E$/ } <TCL>;
3185   }
3186 else
3187   {
3188   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
3189   }
3190
3191 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
3192         if $parm_configure_owner != $>;
3193
3194 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
3195         if 0020 & (stat "$parm_cwd/test-config")[2]
3196         and $parm_configure_group != $);
3197
3198 die "aux-fixed file is group-writeable; best to strip them all, recursively\n"
3199         if 0020 & (stat "aux-fixed/0037.f-1")[2];
3200
3201
3202 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
3203   die "** Cannot run $parm_exim: $!\n";
3204
3205 print "-" x 78, "\n";
3206
3207 while (<EXIMINFO>)
3208   {
3209   my(@temp);
3210
3211   if (/^(Exim|Library) version/) { print; }
3212   if (/Runtime: /) {print; }
3213
3214   elsif (/^Size of off_t: (\d+)/)
3215     {
3216     print;
3217     $have_largefiles = 1 if $1 > 4;
3218     die "** Size of off_t > 32 which seems improbable, not running tests\n"
3219         if ($1 > 32);
3220     }
3221
3222   elsif (/^Support for: (.*)/)
3223     {
3224     print;
3225     @temp = split /(\s+)/, $1;
3226     push(@temp, ' ');
3227     %parm_support = @temp;
3228     }
3229
3230   elsif (/^Lookups \(built-in\): (.*)/)
3231     {
3232     print;
3233     @temp = split /(\s+)/, $1;
3234     push(@temp, ' ');
3235     %parm_lookups = @temp;
3236     }
3237
3238   elsif (/^Authenticators: (.*)/)
3239     {
3240     print;
3241     @temp = split /(\s+)/, $1;
3242     push(@temp, ' ');
3243     %parm_authenticators = @temp;
3244     }
3245
3246   elsif (/^Routers: (.*)/)
3247     {
3248     print;
3249     @temp = split /(\s+)/, $1;
3250     push(@temp, ' ');
3251     %parm_routers = @temp;
3252     }
3253
3254   # Some transports have options, e.g. appendfile/maildir. For those, ensure
3255   # that the basic transport name is set, and then the name with each of the
3256   # options.
3257
3258   elsif (/^Transports: (.*)/)
3259     {
3260     print;
3261     @temp = split /(\s+)/, $1;
3262     my($i,$k);
3263     push(@temp, ' ');
3264     %parm_transports = @temp;
3265     foreach $k (keys %parm_transports)
3266       {
3267       if ($k =~ "/")
3268         {
3269         @temp = split /\//, $k;
3270         $parm_transports{$temp[0]} = " ";
3271         for ($i = 1; $i < @temp; $i++)
3272           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
3273         }
3274       }
3275     }
3276
3277   elsif (/^Malware: (.*)/)
3278     {
3279     print;
3280     @temp = split /(\s+)/, $1;
3281     push(@temp, ' ');
3282     %parm_malware = @temp;
3283     }
3284
3285   }
3286 close(EXIMINFO);
3287 print "-" x 78, "\n";
3288
3289 unlink("$parm_cwd/test-config");
3290
3291 ##################################################
3292 #    Check for SpamAssassin and ClamAV           #
3293 ##################################################
3294
3295 # These are crude tests. If they aren't good enough, we'll have to improve
3296 # them, for example by actually passing a message through spamc or clamscan.
3297
3298 if (defined $parm_support{Content_Scanning})
3299   {
3300   my $sock = new FileHandle;
3301
3302   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
3303     {
3304     print "The spamc command works:\n";
3305
3306     # This test for an active SpamAssassin is courtesy of John Jetmore.
3307     # The tests are hard coded to localhost:783, so no point in making
3308     # this test flexible like the clamav test until the test scripts are
3309     # changed.  spamd doesn't have the nice PING/PONG protocol that
3310     # clamd does, but it does respond to errors in an informative manner,
3311     # so use that.
3312
3313     my($sint,$sport) = ('127.0.0.1',783);
3314     eval
3315       {
3316       my $sin = sockaddr_in($sport, inet_aton($sint))
3317           or die "** Failed packing $sint:$sport\n";
3318       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
3319           or die "** Unable to open socket $sint:$sport\n";
3320
3321       local $SIG{ALRM} =
3322           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
3323       alarm(5);
3324       connect($sock, $sin)
3325           or die "** Unable to connect to socket $sint:$sport\n";
3326       alarm(0);
3327
3328       select((select($sock), $| = 1)[0]);
3329       print $sock "bad command\r\n";
3330
3331       $SIG{ALRM} =
3332           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
3333       alarm(10);
3334       my $res = <$sock>;
3335       alarm(0);
3336
3337       $res =~ m|^SPAMD/|
3338           or die "** Did not get SPAMD from socket $sint:$sport. "
3339                 ."It said: $res\n";
3340       };
3341     alarm(0);
3342     if($@)
3343       {
3344       print "  $@";
3345       print "  Assume SpamAssassin (spamd) is not running\n";
3346       }
3347     else
3348       {
3349       $parm_running{SpamAssassin} = ' ';
3350       print "  SpamAssassin (spamd) seems to be running\n";
3351       }
3352     }
3353   else
3354     {
3355     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
3356     }
3357
3358   # For ClamAV, we need to find the clamd socket for use in the Exim
3359   # configuration. Search for the clamd configuration file.
3360
3361   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
3362     {
3363     my($f, $clamconf, $test_prefix);
3364
3365     print "The clamscan command works";
3366
3367     $test_prefix = $ENV{EXIM_TEST_PREFIX};
3368     $test_prefix = '' if !defined $test_prefix;
3369
3370     foreach $f ("$test_prefix/etc/clamd.conf",
3371                 "$test_prefix/usr/local/etc/clamd.conf",
3372                 "$test_prefix/etc/clamav/clamd.conf", '')
3373       {
3374       if (-e $f)
3375         {
3376         $clamconf = $f;
3377         last;
3378         }
3379       }
3380
3381     # Read the ClamAV configuration file and find the socket interface.
3382
3383     if ($clamconf ne '')
3384       {
3385       my $socket_domain;
3386       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
3387       while (<IN>)
3388         {
3389         if (/^LocalSocket\s+(.*)/)
3390           {
3391           $parm_clamsocket = $1;
3392           $socket_domain = AF_UNIX;
3393           last;
3394           }
3395         if (/^TCPSocket\s+(\d+)/)
3396           {
3397           if (defined $parm_clamsocket)
3398             {
3399             $parm_clamsocket .= " $1";
3400             $socket_domain = AF_INET;
3401             last;
3402             }
3403           else
3404             {
3405             $parm_clamsocket = " $1";
3406             }
3407           }
3408         elsif (/^TCPAddr\s+(\S+)/)
3409           {
3410           if (defined $parm_clamsocket)
3411             {
3412             $parm_clamsocket = $1 . $parm_clamsocket;
3413             $socket_domain = AF_INET;
3414             last;
3415             }
3416           else
3417             {
3418             $parm_clamsocket = $1;
3419             }
3420           }
3421         }
3422       close(IN);
3423
3424       if (defined $socket_domain)
3425         {
3426         print ":\n  The clamd socket is $parm_clamsocket\n";
3427         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
3428         eval
3429           {
3430           my $socket;
3431           if ($socket_domain == AF_UNIX)
3432             {
3433             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
3434             }
3435           elsif ($socket_domain == AF_INET)
3436             {
3437             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
3438             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
3439             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
3440             }
3441           else
3442             {
3443             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
3444             }
3445           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
3446           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
3447           alarm(5);
3448           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
3449           alarm(0);
3450
3451           my $ofh = select $sock; $| = 1; select $ofh;
3452           print $sock "PING\n";
3453
3454           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
3455           alarm(10);
3456           my $res = <$sock>;
3457           alarm(0);
3458
3459           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
3460           };
3461         alarm(0);
3462
3463         if($@)
3464           {
3465           print "  $@";
3466           print "  Assume ClamAV is not running\n";
3467           }
3468         else
3469           {
3470           $parm_running{ClamAV} = ' ';
3471           print "  ClamAV seems to be running\n";
3472           }
3473         }
3474       else
3475         {
3476         print ", but the socket for clamd could not be determined\n";
3477         print "Assume ClamAV is not running\n";
3478         }
3479       }
3480
3481     else
3482       {
3483       print ", but I can't find a configuration for clamd\n";
3484       print "Assume ClamAV is not running\n";
3485       }
3486     }
3487   }
3488
3489
3490 ##################################################
3491 #       Check for redis                          #
3492 ##################################################
3493 if (defined $parm_lookups{redis})
3494   {
3495   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
3496     {
3497     print "The redis-server command works\n";
3498     $parm_running{redis} = ' ';
3499     }
3500   else
3501     {
3502     print "The redis-server command failed: assume Redis not installed\n";
3503     }
3504   }
3505
3506 ##################################################
3507 #         Test for the basic requirements        #
3508 ##################################################
3509
3510 # This test suite assumes that Exim has been built with at least the "usual"
3511 # set of routers, transports, and lookups. Ensure that this is so.
3512
3513 $missing = '';
3514
3515 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
3516
3517 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
3518 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
3519 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
3520 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
3521
3522 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
3523 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
3524 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
3525 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
3526
3527 if ($missing ne '')
3528   {
3529   print "\n";
3530   print "** Many features can be included or excluded from Exim binaries.\n";
3531   print "** This test suite requires that Exim is built to contain a certain\n";
3532   print "** set of basic facilities. It seems that some of these are missing\n";
3533   print "** from the binary that is under test, so the test cannot proceed.\n";
3534   print "** The missing facilities are:\n";
3535   print "$missing";
3536   die "** Test script abandoned\n";
3537   }
3538
3539
3540 ##################################################
3541 #      Check for the auxiliary programs          #
3542 ##################################################
3543
3544 # These are always required:
3545
3546 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3547            "fakens", "iefbr14", "server")
3548   {
3549   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3550   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3551   if (!-e "bin/$prog")
3552     {
3553     print "\n";
3554     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3555     die "** Test script abandoned\n";
3556     }
3557   }
3558
3559 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3560 # compiled on systems where we don't know how to. However, if Exim does not
3561 # have that functionality compiled, we needn't bother.
3562
3563 $dlfunc_deleted = 0;
3564 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3565   {
3566   delete $parm_support{Expand_dlfunc};
3567   $dlfunc_deleted = 1;
3568   }
3569
3570
3571 ##################################################
3572 #          Find environmental details            #
3573 ##################################################
3574
3575 # Find the caller of this program.
3576
3577 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3578  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3579
3580 $pwpw = $pwpw;       # Kill Perl warnings
3581 $pwquota = $pwquota;
3582 $pwcomm = $pwcomm;
3583
3584 $parm_caller_group = getgrgid($parm_caller_gid);
3585
3586 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3587 print "Home directory is $parm_caller_home\n";
3588
3589 unless (defined $parm_eximgroup)
3590   {
3591   print "Unable to derive \$parm_eximgroup.\n";
3592   die "** ABANDONING.\n";
3593   }
3594
3595 if ($parm_caller_home eq $parm_cwd)
3596   {
3597   print "will confuse working dir with homedir; change homedir\n";
3598   die "** ABANDONING.\n";
3599   }
3600
3601 print "You need to be in the Exim group to run these tests. Checking ...";
3602
3603 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3604   {
3605   print " OK\n";
3606   }
3607 else
3608   {
3609   print "\nOh dear, you are not in the Exim group.\n";
3610   die "** Testing abandoned.\n";
3611   }
3612
3613 # Find this host's IP addresses - there may be many, of course, but we keep
3614 # one of each type (IPv4 and IPv6).
3615 #XXX it would be good to avoid non-UP interfaces
3616
3617 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3618   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3619 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3620   {
3621   if (/^(?:[0-9]+: )?([a-z0-9]+): /) { $ifname = $1; }
3622
3623   if (not $parm_ipv4 and /^\s*inet(?:\saddr(?:ess))?:?\s*(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3624     {
3625     # It would be nice to be able to vary the /16 used for manyhome; we could take
3626     # an option to runtest used here - but we'd also have to pass it on to fakens.
3627     # Possibly an environment variable?
3628     next if $1 eq '0.0.0.0' or $1 =~ /^(?:127|10\.250)\./;
3629     $parm_ipv4 = $1;
3630     }
3631
3632   if (   (not $parm_ipv6 or $parm_ipv6 =~ /%/)
3633      and /^\s*inet6(?:\saddr(?:ess))?:?\s*([abcdef\d:]+)(?:%[^ \/]+)?(?:\/\d+)?/i)
3634     {
3635     next if $1 eq '::' or $1 eq '::1' or $1 =~ /^ff00/i or $1 =~ /^fe80::1/i;
3636     $parm_ipv6 = $1;
3637     if ($1 =~ /^fe80/i) { $parm_ipv6 .= '%' . $ifname; }
3638     }
3639   }
3640 close(IFCONFIG);
3641
3642 # Use private IP addresses if there are no public ones.
3643
3644 # If either type of IP address is missing, we need to set the value to
3645 # something other than empty, because that wrecks the substitutions. The value
3646 # is reflected, so use a meaningful string. Set appropriate options for the
3647 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3648 # available, so things will go wrong if there is no IPv4 address. The lack
3649 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3650 # and $have_ipv6 false.
3651
3652 if (not $parm_ipv4)
3653   {
3654   $have_ipv4 = 0;
3655   $parm_ipv4 = "<no IPv4 address found>";
3656   $server_opts .= " -noipv4";
3657   }
3658 elsif ($have_ipv4 == 0)
3659   {
3660   $parm_ipv4 = "<IPv4 testing disabled>";
3661   $server_opts .= " -noipv4";
3662   }
3663 else
3664   {
3665   $parm_running{IPv4} = " ";
3666   }
3667
3668 if (not $parm_ipv6)
3669   {
3670   $have_ipv6 = 0;
3671   $parm_ipv6 = "<no IPv6 address found>";
3672   $server_opts .= " -noipv6";
3673   delete($parm_support{IPv6});
3674   }
3675 elsif ($have_ipv6 == 0)
3676   {
3677   $parm_ipv6 = "<IPv6 testing disabled>";
3678   $server_opts .= " -noipv6";
3679   delete($parm_support{IPv6});
3680   }
3681 elsif (!defined $parm_support{IPv6})
3682   {
3683   $have_ipv6 = 0;
3684   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3685   $server_opts .= " -noipv6";
3686   }
3687 else
3688   {
3689   $parm_running{IPv6} = " ";
3690   }
3691
3692 print "IPv4 address is $parm_ipv4\n";
3693 print "IPv6 address is $parm_ipv6\n";
3694 $parm_ipv6 =~ /^[^%\/]*/;
3695 # drop any %scope from the ipv6, for some uses
3696 ($parm_ipv6_stripped = $parm_ipv6) =~ s/%.*//g;
3697
3698 # For munging test output, we need the reversed IP addresses.
3699
3700 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3701   join(".", reverse(split /\./, $parm_ipv4));
3702
3703 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3704 if ($parm_ipv6 =~ /^[\da-f]/)
3705   {
3706   my(@comps) = split /:/, $parm_ipv6_stripped;
3707   my(@nibbles);
3708   foreach $comp (@comps)
3709     {
3710     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3711     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3712     }
3713   $parm_ipv6r = join(".", reverse(@nibbles));
3714   }
3715
3716 # Find the host name, fully qualified.
3717
3718 chomp($temp = `hostname`);
3719 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3720 if ($temp =~ /\./)
3721   {
3722   $parm_hostname = $temp;
3723   }
3724 else
3725   {
3726   $parm_hostname = (gethostbyname($temp))[0];
3727   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3728   }
3729 print "Hostname is $parm_hostname\n";
3730
3731 if ($parm_hostname !~ /\./)
3732   {
3733   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3734   }
3735
3736 if ($parm_hostname =~ /[[:upper:]]/)
3737   {
3738   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3739   }
3740
3741 if ($parm_hostname =~ /\.example\.com$/)
3742   {
3743   die "\n*** Host name ends in .example.com; this conflicts with the testsuite use of that domain.\n"
3744         . "    Please change the host's name (or comment out this check, and fail several testcases)\n";
3745   }
3746
3747
3748
3749 ##################################################
3750 #     Create a testing version of Exim           #
3751 ##################################################
3752
3753 # We want to be able to run Exim with a variety of configurations. Normally,
3754 # the use of -C to change configuration causes Exim to give up its root
3755 # privilege (unless the caller is exim or root). For these tests, we do not
3756 # want this to happen. Also, we want Exim to know that it is running in its
3757 # test harness.
3758
3759 # We achieve this by copying the binary and patching it as we go. The new
3760 # binary knows it is a testing copy, and it allows -C and -D without loss of
3761 # privilege. Clearly, this file is dangerous to have lying around on systems
3762 # where there are general users with login accounts. To protect against this,
3763 # we put the new binary in a special directory that is accessible only to the
3764 # caller of this script, who is known to have sudo root privilege from the test
3765 # that was done above. Furthermore, we ensure that the binary is deleted at the
3766 # end of the test. First ensure the directory exists.
3767
3768 if (-d "eximdir")
3769   { unlink "eximdir/exim"; }     # Just in case
3770 else
3771   {
3772   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3773   system("sudo chgrp $parm_eximgroup eximdir");
3774   }
3775
3776 # The construction of the patched binary must be done as root, so we use
3777 # a separate script. As well as indicating that this is a test-harness binary,
3778 # the version number is patched to "x.yz" so that its length is always the
3779 # same. Otherwise, when it appears in Received: headers, it affects the length
3780 # of the message, which breaks certain comparisons.
3781
3782 die "** Unable to make patched exim: $!\n"
3783   if (system("sudo ./patchexim $parm_exim") != 0);
3784
3785 # From this point on, exits from the program must go via the subroutine
3786 # tests_exit(), so that suitable cleaning up can be done when required.
3787 # Arrange to catch interrupting signals, to assist with this.
3788
3789 $SIG{INT} = \&inthandler;
3790 $SIG{PIPE} = \&pipehandler;
3791
3792 # For some tests, we need another copy of the binary that is setuid exim rather
3793 # than root.
3794
3795 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3796        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3797        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3798        "sudo chmod 06755 eximdir/exim_exim");
3799
3800 ##################################################
3801 #     Make copies of utilities we might need     #
3802 ##################################################
3803
3804 # Certain of the tests make use of some of Exim's utilities. We do not need
3805 # to be root to copy these.
3806
3807 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3808
3809 $dbm_build_deleted = 0;
3810 if (defined $parm_lookups{dbm} && not cp("$parm_exim_dir/exim_dbmbuild", "eximdir/exim_dbmbuild"))
3811   {
3812   delete $parm_lookups{dbm};
3813   $dbm_build_deleted = 1;
3814   }
3815
3816 foreach my $tool (qw(exim_dumpdb exim_lock exinext exigrep eximstats exiqgrep)) {
3817   cp("$parm_exim_dir/$tool" => "eximdir/$tool")
3818     or tests_exit(-1, "Failed to make a copy of $tool: $!");
3819 }
3820
3821 # Collect some version information
3822 print '-' x 78, "\n";
3823 print "Perl version for runtest: $]\n";
3824 foreach (map { "./eximdir/$_" } qw(exigrep exinext eximstats exiqgrep)) {
3825   # fold (or unfold?) multiline output into a one-liner
3826   print join(', ', map { chomp; $_ } `$_ --version`), "\n";
3827 }
3828 print '-' x 78, "\n";
3829
3830
3831 ##################################################
3832 #    Check that the Exim user can access stuff   #
3833 ##################################################
3834
3835 # We delay this test till here so that we can check access to the actual test
3836 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3837
3838 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3839 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3840
3841 if ($parm_caller_uid eq $parm_exim_uid) {
3842   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3843                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3844 }
3845 if ($parm_caller_gid eq $parm_exim_gid) {
3846   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3847                 ."the same as caller's ($parm_caller) group as it confuses "
3848                 ."results analysis");
3849 }
3850
3851 print "The Exim user needs access to the test suite directory. Checking ...";
3852
3853 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3854   {
3855   my($why) = "unknown failure $rc";
3856   $rc >>= 8;
3857   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3858   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3859   $why = "Couldn't read auxiliary group list" if $rc == 3;
3860   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3861   $why = "Couldn't set gid" if $rc == 5;
3862   $why = "Couldn't set uid" if $rc == 6;
3863   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3864   print "\n** $why\n";
3865   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3866   }
3867 else
3868   {
3869   print " OK\n";
3870   }
3871
3872 tests_exit(-1, "Failed to unlink $log_summary_filename: $!")
3873   if not unlink($log_summary_filename) and -e $log_summary_filename;
3874
3875 ##################################################
3876 #        Create a list of available tests        #
3877 ##################################################
3878
3879 # The scripts directory contains a number of subdirectories whose names are
3880 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3881 # from the first requires certain optional features to be included in the Exim
3882 # binary. These requirements are contained in a file called "REQUIRES" within
3883 # the directory. We scan all these tests, discarding those that cannot be run
3884 # because the current binary does not support the right facilities, and also
3885 # those that are outside the numerical range selected.
3886
3887 printf "\nWill run %d tests between %d and %d for flavour %s\n",
3888   scalar(@wanted), $wanted[0], $wanted[-1], $flavour;
3889
3890 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3891   if $dlfunc_deleted;
3892 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3893   if $dbm_build_deleted;
3894
3895
3896 my @test_dirs = grep { not /^CVS$/ } map { basename $_ } glob 'scripts/*'
3897   or die tests_exit(-1, "Failed to find test scripts in 'scripts/*`: $!");
3898
3899 # Scan for relevant tests
3900 # HS12: Needs to be reworked.
3901 DIR: for (my $i = 0; $i < @test_dirs; $i++)
3902   {
3903   my($testdir) = $test_dirs[$i];
3904   my($wantthis) = 1;
3905
3906   print ">>Checking $testdir\n" if $debug;
3907
3908   # Skip this directory if the first test is equal or greater than the first
3909   # test in the next directory.
3910
3911   next DIR if ($i < @test_dirs - 1) &&
3912           ($wanted[0] >= substr($test_dirs[$i+1], 0, 4));
3913
3914   # No need to carry on if the end test is less than the first test in this
3915   # subdirectory.
3916
3917   last DIR if $wanted[-1] < substr($testdir, 0, 4);
3918
3919   # Check requirements, if any.
3920
3921   if (open(my $requires, "scripts/$testdir/REQUIRES"))
3922     {
3923     while (<$requires>)
3924       {
3925       next if /^\s*$/;
3926       s/\s+$//;
3927       if (/^support (.*)$/)
3928         {
3929         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3930         }
3931       elsif (/^running (.*)$/)
3932         {
3933         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3934         }
3935       elsif (/^lookup (.*)$/)
3936         {
3937         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3938         }
3939       elsif (/^authenticators? (.*)$/)
3940         {
3941         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3942         }
3943       elsif (/^router (.*)$/)
3944         {
3945         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3946         }
3947       elsif (/^transport (.*)$/)
3948         {
3949         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3950         }
3951       elsif (/^malware (.*)$/)
3952         {
3953         if (!defined $parm_malware{$1}) { $wantthis = 0; last; }
3954         }
3955       elsif (/^feature (.*)$/)
3956         {
3957         # move to a subroutine?
3958         my $eximinfo = "$parm_exim -C $parm_cwd/test-config -DDIR=$parm_cwd -bP macro $1";
3959
3960         open (IN, "$parm_cwd/confs/0000") ||
3961           tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
3962         open (OUT, ">test-config") ||
3963           tests_exit(-1, "Couldn't open test-config: $!\n");
3964         while (<IN>)
3965           {
3966           do_substitute($testno);
3967           print OUT;
3968           }
3969         close(IN);
3970         close(OUT);
3971
3972         system($eximinfo . " >/dev/null 2>&1");
3973         if ($? != 0) {
3974           unlink("$parm_cwd/test-config");
3975           $wantthis = 0;
3976           $_ = "feature $1";
3977           last;
3978         }
3979         unlink("$parm_cwd/test-config");
3980         }
3981       elsif (/^ipv6-non-linklocal/)
3982         {
3983         if ($parm_ipv6 =~ /%/) { $wantthis = 0; last; }
3984         }
3985       else
3986         {
3987         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3988         }
3989       }
3990     }
3991   else
3992     {
3993     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3994       unless $!{ENOENT};
3995     }
3996
3997   # Loop if we do not want the tests in this subdirectory.
3998
3999   if (!$wantthis)
4000     {
4001     chomp;
4002     print "Omitting tests in $testdir (missing $_)\n";
4003     }
4004
4005   # We want the tests from this subdirectory, provided they are in the
4006   # range that was selected.
4007
4008   @testlist = grep { $_ ~~ @wanted } grep { /^\d+(?:\.\d+)?$/ } map { basename $_ } glob "scripts/$testdir/*";
4009   tests_exit(-1, "Failed to read test scripts from `scripts/$testdir/*': $!")
4010     if not @testlist;
4011
4012   foreach $test (@testlist)
4013     {
4014     if (!$wantthis)
4015       {
4016       log_test($log_summary_filename, $test, '.');
4017       }
4018     else
4019       {
4020       push @test_list, "$testdir/$test";
4021       }
4022     }
4023   }
4024
4025 print ">>Test List:\n", join "\n", @test_list, '' if $debug;
4026
4027
4028 ##################################################
4029 #         Munge variable auxiliary data          #
4030 ##################################################
4031
4032 # Some of the auxiliary data files have to refer to the current testing
4033 # directory and other parameter data. The generic versions of these files are
4034 # stored in the aux-var-src directory. At this point, we copy each of them
4035 # to the aux-var directory, making appropriate substitutions. There aren't very
4036 # many of them, so it's easiest just to do this every time. Ensure the mode
4037 # is standardized, as this path is used as a test for the ${stat: expansion.
4038
4039 # A similar job has to be done for the files in the dnszones-src directory, to
4040 # make the fake DNS zones for testing. Most of the zone files are copied to
4041 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
4042 # networks that are defined by parameter.
4043
4044 foreach $basedir ("aux-var", "dnszones")
4045   {
4046   system("sudo rm -rf $parm_cwd/$basedir");
4047   mkdir("$parm_cwd/$basedir", 0777);
4048   chmod(0755, "$parm_cwd/$basedir");
4049
4050   opendir(AUX, "$parm_cwd/$basedir-src") ||
4051     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
4052   my(@filelist) = readdir(AUX);
4053   close(AUX);
4054
4055   foreach $file (@filelist)
4056     {
4057     my($outfile) = $file;
4058     next if $file =~ /^\./;
4059
4060     if ($file eq "db.ip4.V4NET")
4061       {
4062       $outfile = "db.ip4.$parm_ipv4_test_net";
4063       }
4064     elsif ($file eq "db.ip6.V6NET")
4065       {
4066       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
4067       $" = '.';
4068       $outfile = "db.ip6.@nibbles";
4069       $" = ' ';
4070       }
4071
4072     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
4073     open(IN, "$parm_cwd/$basedir-src/$file") ||
4074       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
4075     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
4076       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
4077     while (<IN>)
4078       {
4079       do_substitute(0);
4080       print OUT;
4081       }
4082     close(IN);
4083     close(OUT);
4084     }
4085   }
4086
4087 # Set a user's shell, distinguishable from /bin/sh
4088
4089 symlink('/bin/sh' => 'aux-var/sh');
4090 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
4091
4092 ##################################################
4093 #     Create fake DNS zones for this host        #
4094 ##################################################
4095
4096 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
4097 # sure that there are forward and reverse registrations for this host, using
4098 # its real IP addresses. Dynamically created zone files achieve this.
4099
4100 if ($have_ipv4 || $have_ipv6)
4101   {
4102   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
4103   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
4104     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
4105   print OUT "; This is a dynamically constructed fake zone file.\n" .
4106     "; The following line causes fakens to return PASS_ON\n" .
4107     "; for queries that it cannot answer\n\n" .
4108     "PASS ON NOT FOUND\n\n";
4109   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
4110   print OUT "$shortname  AAAA  $parm_ipv6_stripped\n" if $have_ipv6;
4111   print OUT "\n; End\n";
4112   close(OUT);
4113   }
4114
4115 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
4116   {
4117   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
4118
4119   if ($components[0]=='10')
4120     {
4121     open(OUT, ">>$parm_cwd/dnszones/db.ip4.$components[0]") ||
4122       tests_exit(-1, "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4123     print OUT "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n";
4124     close(OUT);
4125     }
4126   else
4127     {
4128     open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
4129       tests_exit(-1,
4130         "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
4131     print OUT "; This is a dynamically constructed fake zone file.\n" .
4132       "; The zone is $components[0].in-addr.arpa.\n\n" .
4133       "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
4134       "; End\n";
4135     close(OUT);
4136     }
4137   }
4138
4139 if ($have_ipv6 && $parm_ipv6_stripped ne "::1")
4140   {
4141   my($exp_v6) = $parm_ipv6_stripped;
4142   $exp_v6 =~ s/[^:]//g;
4143   if ( $parm_ipv6_stripped =~ /^([^:].+)::$/ ) {
4144     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
4145   } elsif ( $parm_ipv6_stripped =~ /^(.+)::(.+)$/ ) {
4146     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
4147   } elsif ( $parm_ipv6_stripped =~ /^::(.+[^:])$/ ) {
4148     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
4149   } else {
4150     $exp_v6 = $parm_ipv6_stripped;
4151   }
4152   my(@components) = split /:/, $exp_v6;
4153   my(@nibbles) = reverse (split /\s*/, shift @components);
4154   my($sep) =  '';
4155
4156   $" = ".";
4157   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
4158     tests_exit(-1,
4159       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
4160   print OUT "; This is a dynamically constructed fake zone file.\n" .
4161     "; The zone is @nibbles.ip6.arpa.\n\n";
4162
4163   @components = reverse @components;
4164   foreach $c (@components)
4165     {
4166     $c = "0$c" until $c =~ /^..../;
4167     @nibbles = reverse(split /\s*/, $c);
4168     print OUT "$sep@nibbles";
4169     $sep = ".";
4170     }
4171
4172   print OUT "  PTR  $parm_hostname.\n\n; End\n";
4173   close(OUT);
4174   $" = " ";
4175   }
4176
4177
4178
4179 ##################################################
4180 #    Create lists of mailboxes and message logs  #
4181 ##################################################
4182
4183 # We use these lists to check that a test has created the expected files. It
4184 # should be faster than looking for the file each time. For mailboxes, we have
4185 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
4186 # is just a flat list of files.
4187
4188 @oldmails = list_files_below("mail");
4189 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
4190 @oldmsglogs = readdir(DIR);
4191 closedir(DIR);
4192
4193
4194
4195 ##################################################
4196 #         Run the required tests                 #
4197 ##################################################
4198
4199 # Each test script contains a number of tests, separated by a line that
4200 # contains ****. We open input from the terminal so that we can read responses
4201 # to prompts.
4202
4203 if (not $force_continue) {
4204   # runtest needs to interact if we're not in continue
4205   # mode. It does so by communicate to /dev/tty
4206   open(T, '<', '/dev/tty') or tests_exit(-1, "Failed to open /dev/tty: $!");
4207   print "\nPress RETURN to run the tests: ";
4208   <T>;
4209 }
4210
4211
4212 my $failures = 0;
4213 foreach $test (@test_list)
4214   {
4215   state $lasttestdir = '';
4216
4217   local $lineno     = 0;
4218   local $commandno  = 0;
4219   local $subtestno  = 0;
4220   local $sortlog    = 0;
4221
4222   (local $testno = $test) =~ s|.*/||;
4223
4224   # Leaving traces in the process table and in the environment
4225   # gives us a chance to identify hanging processes (exim daemons)
4226   local $0 = "[runtest $testno]";
4227   local $ENV{EXIM_TEST_NUMBER} = $testno;
4228
4229   my $gnutls   = 0;
4230   my $docheck  = 1;
4231   my $thistestdir  = substr($test, 0, -5);
4232
4233   $dynamic_socket->close() if $dynamic_socket;
4234
4235   if ($lasttestdir ne $thistestdir)
4236     {
4237     $gnutls = 0;
4238     if (-s "scripts/$thistestdir/REQUIRES")
4239       {
4240       my $indent = '';
4241       print "\n>>> The following tests require: ";
4242       open(my $requires, '<', "scripts/$thistestdir/REQUIRES") ||
4243         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $!");
4244       while (<$requires>)
4245         {
4246         $gnutls = 1 if /^support GnuTLS/;
4247         print $indent, $_;
4248         $indent = ">>>                              ";
4249         }
4250       }
4251       $lasttestdir = $thistestdir;
4252     }
4253
4254   # Remove any debris in the spool directory and the test-mail directory
4255   # and also the files for collecting stdout and stderr. Then put back
4256   # the test-mail directory for appendfile deliveries.
4257
4258   system "sudo /bin/rm -rf spool test-*";
4259   mkdir "test-mail";
4260
4261   # A privileged Exim will normally make its own spool directory, but some of
4262   # the tests run in unprivileged modes that don't always work if the spool
4263   # directory isn't already there. What is more, we want anybody to be able
4264   # to read it in order to find the daemon's pid.
4265
4266   mkdir "spool";
4267   system "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
4268          "sudo chmod 0755 spool";
4269
4270   # Empty the cache that keeps track of things like message id mappings, and
4271   # set up the initial sequence strings.
4272
4273   undef %cache;
4274   $next_msgid = "aX";
4275   $next_pid = 1234;
4276   $next_port = 1111;
4277   $message_skip = 0;
4278   $msglog_skip = 0;
4279   $stderr_skip = 0;
4280   $stdout_skip = 0;
4281   $rmfiltertest = 0;
4282   $is_ipv6test = 0;
4283   $TEST_STATE->{munge} = '';
4284
4285   # Remove the associative arrays used to hold checked mail files and msglogs
4286
4287   undef %expected_mails;
4288   undef %expected_msglogs;
4289
4290   # Open the test's script
4291   open(SCRIPT, "scripts/$test") ||
4292     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
4293   # Run through the script once to set variables which should be global
4294   while (<SCRIPT>)
4295     {
4296     if (/^no_message_check/) { $message_skip = 1; next; }
4297     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4298     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4299     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4300     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4301     if (/^sortlog/)          { $sortlog = 1; next; }
4302     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
4303     }
4304   # Reset to beginning of file for per test interpreting/processing
4305   seek(SCRIPT, 0, 0);
4306
4307   # The first line in the script must be a comment that is used to identify
4308   # the set of tests as a whole.
4309
4310   $_ = <SCRIPT>;
4311   $lineno++;
4312   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
4313   printf("%s %s", (substr $test, 5), (substr $_, 2));
4314
4315   # Loop for each of the subtests within the script. The variable $server_pid
4316   # is used to remember the pid of a "server" process, for which we do not
4317   # wait until we have waited for a subsequent command.
4318
4319   local($server_pid) = 0;
4320   for ($commandno = 1; !eof SCRIPT; $commandno++)
4321     {
4322     # Skip further leading comments and blank lines, handle the flag setting
4323     # commands, and deal with tests for IP support.
4324
4325     while (<SCRIPT>)
4326       {
4327       $lineno++;
4328       # Could remove these variable settings because they are already
4329       # set above, but doesn't hurt to leave them here.
4330       if (/^no_message_check/) { $message_skip = 1; next; }
4331       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
4332       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
4333       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
4334       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
4335       if (/^sortlog/)          { $sortlog = 1; next; }
4336
4337       if (/^need_largefiles/)
4338         {
4339         next if $have_largefiles;
4340         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
4341         $docheck = 0;      # don't check output
4342         undef $_;          # pretend EOF
4343         last;
4344         }
4345
4346       if (/^need_ipv4/)
4347         {
4348         next if $have_ipv4;
4349         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
4350         $docheck = 0;      # don't check output
4351         undef $_;          # pretend EOF
4352         last;
4353         }
4354
4355       if (/^need_ipv6/)
4356         {
4357         if ($have_ipv6)
4358           {
4359           $is_ipv6test = 1;
4360           next;
4361           }
4362         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
4363         $docheck = 0;      # don't check output
4364         undef $_;          # pretend EOF
4365         last;
4366         }
4367
4368       if (/^need_move_frozen_messages/)
4369         {
4370         next if defined $parm_support{move_frozen_messages};
4371         print ">>> move frozen message support is needed for test $testno, " .
4372           "but is not\n>>> available: skipping\n";
4373         $docheck = 0;      # don't check output
4374         undef $_;          # pretend EOF
4375         last;
4376         }
4377
4378       last unless /^(?:#(?!##\s)|\s*$)/;
4379       }
4380     last if !defined $_;  # Hit EOF
4381
4382     my($subtest_startline) = $lineno;
4383
4384     # Now run the command. The function returns 0 for an inline command,
4385     # 1 if a non-exim command was run and waited for, 2 if an exim
4386     # command was run and waited for, and 3 if a command
4387     # was run and not waited for (usually a daemon or server startup).
4388
4389     my($commandname) = '';
4390     my($expectrc) = 0;
4391     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
4392     my($cmdrc) = $?;
4393
4394     if ($debug) {
4395       print ">> rc=$rc cmdrc=$cmdrc\n";
4396       if (defined $run_extra) {
4397         foreach my $k (keys %$run_extra) {
4398           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
4399           print ">>   $k -> $v\n";
4400         }
4401       }
4402     }
4403     $run_extra = {} unless defined $run_extra;
4404     foreach my $k (keys %$run_extra) {
4405       if (exists $TEST_STATE->{$k}) {
4406         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
4407         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
4408       }
4409       if (defined $run_extra->{$k}) {
4410         $TEST_STATE->{$k} = $run_extra->{$k};
4411       } elsif (exists $TEST_STATE->{$k}) {
4412         delete $TEST_STATE->{$k};
4413       }
4414     }
4415
4416     # Hit EOF after an initial return code number
4417
4418     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
4419
4420     # Carry on with the next command if we did not wait for this one. $rc == 0
4421     # if no subprocess was run; $rc == 3 if we started a process but did not
4422     # wait for it.
4423
4424     next if ($rc == 0 || $rc == 3);
4425
4426     # We ran and waited for a command. Check for the expected result unless
4427     # it died.
4428
4429     if ($cmdrc != $expectrc && !$sigpipehappened)
4430       {
4431       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
4432       if (($cmdrc & 0xff) == 0)
4433         {
4434         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
4435         }
4436       elsif (($cmdrc & 0xff00) == 0)
4437         { printf("** Killed by signal %d", $cmdrc & 255); }
4438       else
4439         { printf("** Status %x", $cmdrc); }
4440
4441       for (;;)
4442         {
4443         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
4444         $_ = $force_continue ? "c" : <T>;
4445         tests_exit(1) if /^q?$/i;
4446         if (/^c$/ && $force_continue)
4447           {
4448           log_failure($log_failed_filename, $testno, "exit code unexpected");
4449           log_test($log_summary_filename, $testno, 'F');
4450           $failures++;
4451           }
4452         if ($force_continue)
4453           {
4454           print "\nstdout tail:\n";
4455           print "==================>\n";
4456           system("tail -20 test-stdout");
4457           print "===================\n";
4458
4459           print "stderr tail:\n";
4460           print "==================>\n";
4461           system("tail -30 test-stderr");
4462           print "===================\n";
4463
4464           print "stdout-server tail:\n";
4465           print "==================>\n";
4466           system("tail -20 test-stdout-server");
4467           print "===================\n";
4468
4469           print "stderr-server tail:\n";
4470           print "==================>\n";
4471           system("tail -30 test-stderr-server");
4472           print "===================\n";
4473
4474           print "... continue forced\n";
4475           }
4476
4477         last if /^[rc]$/i;
4478         if (/^e$/i)
4479           {
4480           system @more => 'test-stderr';
4481           }
4482         elsif (/^o$/i)
4483           {
4484           system @more => 'test-stdout';
4485           }
4486         }
4487
4488       $retry = 1 if /^r$/i;
4489       $docheck = 0;
4490       }
4491
4492     # If the command was exim, and a listening server is running, we can now
4493     # close its input, which causes us to wait for it to finish, which is why
4494     # we didn't close it earlier.
4495
4496     if ($rc == 2 && $server_pid != 0)
4497       {
4498       close SERVERCMD;
4499       $server_pid = 0;
4500       if ($? != 0)
4501         {
4502         if (($? & 0xff) == 0)
4503           { printf("Server return code %d for test %d starting line %d", $?/256,
4504                 $testno, $subtest_startline); }
4505         elsif (($? & 0xff00) == 0)
4506           { printf("Server killed by signal %d", $? & 255); }
4507         else
4508           { printf("Server status %x", $?); }
4509
4510         for (;;)
4511           {
4512           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
4513           $_ = $force_continue ? "c" : <T>;
4514           tests_exit(1) if /^q?$/i;
4515           if (/^c$/ && $force_continue)
4516             {
4517             log_failure($log_failed_filename, $testno, "exit code unexpected");
4518             log_test($log_summary_filename, $testno, 'F');
4519             $failures++;
4520             }
4521           print "... continue forced\n" if $force_continue;
4522           last if /^[rc]$/i;
4523
4524           if (/^s$/i)
4525             {
4526             open(S, "test-stdout-server") ||
4527               tests_exit(-1, "Failed to open test-stdout-server: $!");
4528             print while <S>;
4529             close(S);
4530             }
4531           }
4532         $retry = 1 if /^r$/i;
4533         }
4534       }
4535     }
4536
4537   close SCRIPT;
4538
4539   # The script has finished. Check the all the output that was generated. The
4540   # function returns 0 for a perfect pass, 1 if imperfect but ok, 2 if we should
4541   # rerun the test (the files # have been updated).
4542   # It does not return if the user responds Q to a prompt.
4543
4544   if ($retry)
4545     {
4546     $retry = '0';
4547     print (("#" x 79) . "\n");
4548     redo;
4549     }
4550
4551   if ($docheck)
4552     {
4553     sleep 1 if $slow;
4554     my $rc = check_output($TEST_STATE->{munge});
4555     if ($rc == 0)
4556       {
4557       log_test($log_summary_filename, $testno, 'P');
4558       }
4559     else
4560       {
4561       $failures++;
4562       }
4563     if ($rc < 2)
4564       {
4565       print ("  Script completed\n");
4566       }
4567     else
4568       {
4569       print (("#" x 79) . "\n");
4570       redo;
4571       }
4572     }
4573   }
4574
4575
4576 ##################################################
4577 #         Exit from the test script              #
4578 ##################################################
4579
4580 tests_exit(-1, "No runnable tests selected") if not @test_list;
4581 tests_exit($fail_any ? $failures : 0);
4582
4583 __END__
4584
4585 =head1 NAME
4586
4587  runtest - run the exim testsuite
4588
4589 =head1 SYNOPSIS
4590
4591  runtest [exim-path] [options] [test0 [test1]]
4592
4593 =head1 DESCRIPTION
4594
4595 B<runtest> runs the Exim testsuite.
4596
4597 =head1 OPTIONS
4598
4599 For legacy reasons the options are not case sensitive.
4600
4601 =over
4602
4603 =item B<--continue>
4604
4605 Do not stop for user interaction or on errors. (default: off)
4606
4607 =item B<--debug>
4608
4609 This option enables the output of debug information when running the
4610 various test commands. (default: off)
4611
4612 =item B<--diff>
4613
4614 Use C<diff -u> for comparing the expected output with the produced
4615 output. (default: use a built-in routine)
4616
4617 =item B<--flavor>|B<--flavour> I<flavour>
4618
4619 Override the expected results for results for a specific (OS) flavour.
4620 (default: unused)
4621
4622 =item B<--[no]ipv4>
4623
4624 Skip IPv4 related setup and tests (default: use ipv4)
4625
4626 =item B<--[no]ipv6>
4627
4628 Skip IPv6 related setup and tests (default: use ipv6)
4629
4630 =item B<--keep>
4631
4632 Keep the various output files produced during a test run. (default: don't keep)
4633
4634 =item B<--range> I<n0> I<n1>
4635
4636 Run tests between (including) I<n0> and I<n1>. A "+" may be used to specify the "last
4637 test available".
4638
4639 =item B<--slow>
4640
4641 Insert some delays to compensate for a slow host system. (default: off)
4642
4643 =item B<--test> I<n>
4644
4645 Run the specified test. This option may used multiple times.
4646
4647 =item B<--update>
4648
4649 Automatically update the recorded (expected) data on mismatch. (default: off)
4650
4651 =item B<--valgrind>
4652
4653 Start Exim wrapped by I<valgrind>. (default: don't use valgrind)
4654
4655 =back
4656
4657 =cut
4658
4659
4660 # End of runtest script