git.exim.org Git - exim-website.git/blob

1 #!/usr/bin/env perl

2 #

3 use strict;

4 use warnings;

5

6 use CSS::Minifier::XS 0.07;

7 use File::Basename;

8 use File::Copy;

9 use File::Find;

10 use File::Path qw(make_path);

11 use File::Slurp;

12 use File::Spec;

13 use Getopt::Long;

14 use JavaScript::Minifier::XS;

15 use Pod::Usage;

16 use XML::LibXML;

17 use XML::LibXSLT;

18 use FindBin qw'$Bin';

19

20 my $canonical_url = 'https://www.exim.org/';

21

22 ## Parse arguments

23 my %opt = parse_arguments();

24

25 ## setup static root location

26 ## TODO: for doc generation only this should be within the docs dir

27 $opt{staticroot} = File::Spec->catdir( $opt{docroot}, 'static' );

28

29 ## Generate the pages

30 my %cache; # General cache object

31 do_doc( 'spec', $_ ) foreach @{ $opt{spec} || [] };

32 do_doc( 'filter', $_ ) foreach @{ $opt{filter} || [] };

33 do_web() if ( $opt{web} );

34 do_static() if ( $opt{web} or !$opt{localstatic} ); # need this for all other pages generated

35

36 ## Add the exim-html-current symlink

37 foreach my $type (qw(html pdf)) {

38 print "Symlinking exim-$type-current to exim-$type-$opt{latest}\n" if ( $opt{verbose} );

39 unlink("$opt{docroot}/exim-$type-current");

40 symlink( "exim-$type-$opt{latest}", "$opt{docroot}/exim-$type-current" )

41 || warn "symlink to $opt{docroot}/exim-$type-current failed";

42 }

43

44 # ------------------------------------------------------------------

45 ## Generate the website files

46 sub do_web {

47

48 ## copy these templates to docroot...

49 copy_transform_files( "$opt{tmpl}/web", $opt{docroot}, 0 );

50 }

51

52 # ------------------------------------------------------------------

53 ## Generate the static file set

54 sub do_static {

55 my $staticroot = shift || $opt{staticroot};

56

57 ## make sure I have a directory

58 mkdir($staticroot) or die "Unable to make staticroot: $!\n" unless ( -d $staticroot );

59

60 ## copy these templates to docroot...

61 copy_transform_files( "$opt{tmpl}/static", $staticroot, 1 );

62 }

63

64 # ------------------------------------------------------------------

65 ## Generate the website files

66 sub copy_transform_files {

67 my $source = shift;

68 my $target = shift;

69 my $static = shift;

70

71 ## Make sure the template web directory exists

72 die "No such directory: $source\n" unless ( -d $source );

73

74 ## Scan the web templates

75 find(

76 sub {

77 my ($path) = substr( $File::Find::name, length("$source"), length($File::Find::name) ) =~ m#^/*(.*)$#;

78

79 if ( -d "$source/$path" ) {

80

81 ## Create the directory in the target if it doesn't exist

82 if ( !-d "$target/$path" ) {

83 mkdir("$target/$path") or die "Unable to make $target/$path: $!\n";

84 }

85

86 }

87 else {

88

89 ## Build HTML from XSL files and simply copy static files which have changed

90 if ( ( !$static ) and ( $path =~ /(.+)\.xsl$/ ) ) {

91 print "Generating : /$1.html\n" if ( $opt{verbose} );

92 transform( undef, "$source/$path", "$target/$1.html" );

93 }

94 elsif ( -f "$source/$path" ) {

95

96 ## Skip if the file hasn't changed (mtime/size based)

97 return

98 if (( -f "$target/$path" )

99 and ( ( stat("$source/$path") )[9] == ( stat("$target/$path") )[9] )

100 and ( ( stat("$source/$path") )[7] == ( stat("$target/$path") )[7] ) );

101

102 if ( $path =~ /(.+)\.css$/ ) {

103 print "CSS to : /$path\n" if ( $opt{verbose} );

104 my $content = read_file("$source/$path");

105 write_file( "$target/$path", $opt{minify} ? CSS::Minifier::XS::minify($content) : $content );

106 }

107 elsif ( $path =~ /(.+)\.js$/ ) {

108 print "JS to : /$path\n" if ( $opt{verbose} );

109 my $content = read_file("$source/$path");

110 write_file( "$target/$path",

111 $opt{minify} ? JavaScript::Minifier::XS::minify($content) : $content );

112 }

113 else {

114 ## Copy

115 print "Copying to : /$path\n" if ( $opt{verbose} );

116 copy( "$source/$path", "$target/$path" ) or die "$path: $!";

117 }

118 ## Set mtime

119 utime( time, ( stat("$source/$path") )[9], "$target/$path" );

120 }

121 }

122

123 },

124 "$source"

125 );

126 }

127

128 # ------------------------------------------------------------------

129 ## Generate index/chapter files for a doc

130 sub do_doc {

131 my ( $type, $xml_path ) = @_;

132

133 ## Read and validate the XML file

134 my $xml = XML::LibXML->new(expand_entities => 1)->parse_file($xml_path) or die $!;

135

136 ## Get the version number

137 my $version = do {

138 my $version = $xml->findvalue('/book/bookinfo/revhistory/revision/revnumber');

139 die "Unable to get version number\n"

140 unless defined $version and $version =~ /^

141 (?<version>

142 \d+ # major

143 (?:\.\d+(?:\.\d+)?)? # (minor(.patch))

144 (?:\.\d+(?:\.\d+(?:\.\d+)?)?)? # (minor(.patch.(fixes)))

145 )

146 (?:-RC\d+)?$/x; # -RCX

147 $+{version};

148 };

149

150 ## Prepend chapter filenames?

151 my $prepend_chapter = $type eq 'filter' ? 'filter_' : '';

152

153 ## Add the canonical url for this document

154 $xml->documentElement()

155 ->appendTextChild( 'canonical_url',

156 "${canonical_url}exim-html-current/doc/html/spec_html/" . ( $type eq 'spec' ? 'index' : 'filter' ) . ".html" );

157

158 ## Add a url for the latest version of this document

159 if ( $version ne $opt{latest} ) {

160 $xml->documentElement()

161 ->appendTextChild( 'current_url',

162 "../../../../exim-html-current/doc/html/spec_html/" . ( $type eq 'spec' ? 'index' : 'filter' ) . ".html" );

163 }

164

165 ## Fixup the XML

166 xref_fixup( $xml, $prepend_chapter );

167

168 ## set the staticroot

169 my $staticroot =

170 $opt{localstatic}

171 ? File::Spec->catdir( $opt{docroot}, "exim-html-$version", 'doc', 'html', 'static' )

172 : $opt{staticroot};

173 unless ( -d $staticroot ) {

174 make_path( $staticroot, { verbose => $opt{verbose} } );

175 do_static($staticroot);

176 }

177

178 ## Generate the front page

179 {

180 my $path = "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? $type : 'index' ) . ".html";

181 print "Generating : docroot:/$path\n" if ( $opt{verbose} );

182 transform( $xml, "$opt{tmpl}/doc/index.xsl", "$opt{docroot}/$path", $staticroot );

183 }

184

185 ## Generate a Table of Contents XML file

186 {

187 my $path =

188 "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? 'filter_toc' : 'index_toc' ) . ".xml";

189 print "Generating : docroot:/$path\n" if ( $opt{verbose} );

190 transform( $xml, "$opt{tmpl}/doc/toc.xsl", "$opt{docroot}/$path", $staticroot );

191 }

192

193 ## Generate the chapters

194 my $counter = 0;

195 my @chapters = map { $_->cloneNode(1) } $xml->findnodes('/book/chapter');

196 my( $chapter_title, $chapter_title_prev, $chapter_title_next );

197 foreach my $chapter (@chapters) {

198

199 ## Add a <chapter_id>N</chapter_id> node for the stylesheet to use

200 $chapter->appendTextChild( 'chapter_id', ++$counter );

201

202 ## Get the current and surrounding chapter titles

203 $chapter_title_prev = $chapter_title;

204 $chapter_title = $chapter_title_next || $chapter->findvalue('title_uri');

205 $chapter_title_next = $chapters[$counter]->findvalue('title_uri') if $counter < int(@chapters);

206

207 ## Add previous/next/canonical urls for nav

208 {

209 $chapter->appendTextChild( 'prev_url',

210 $counter == 1

211 ? $type eq 'filter'

212 ? 'filter.html'

213 : 'index.html'

214 : sprintf( '%sch-%s.html', $prepend_chapter, $chapter_title_prev ) );

215 $chapter->appendTextChild( 'this_url', sprintf( '%sch-%s.html', $prepend_chapter, $chapter_title ) );

216 $chapter->appendTextChild( 'next_url', sprintf( '%sch-%s.html', $prepend_chapter, $chapter_title_next ) )

217 unless int(@chapters) == $counter;

218 $chapter->appendTextChild( 'toc_url', ( $type eq 'filter' ? 'filter' : 'index' ) . '.html' );

219 $chapter->appendTextChild(

220 'canonical_url',

221 sprintf(

222 'https://www.exim.org/exim-html-current/doc/html/spec_html/%sch-%s.html',

223 $prepend_chapter, $chapter_title

224 )

225 );

226 if ( $version ne $opt{latest} ) {

227 $chapter->appendTextChild(

228 'current_url',

229 sprintf(

230 '../../../../exim-html-current/doc/html/spec_html/%sch-%s.html',

231 $prepend_chapter, $chapter_title

232 )

233 );

234 }

235 }

236

237 ## Create an XML document from the chapter

238 my $doc = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );

239 $doc->setDocumentElement($chapter);

240

241 ## Transform the chapter into html

242 {

243 my $real_path = sprintf( 'exim-html-%s/doc/html/spec_html/%sch-%s.html', $version, $prepend_chapter, $chapter_title );

244 my $link_path = sprintf( 'exim-html-%s/doc/html/spec_html/%sch%02d.html', $version, $prepend_chapter, $counter );

245 print "Generating : docroot:/$real_path\n" if ( $opt{verbose} );

246 transform( $doc, "$opt{tmpl}/doc/chapter.xsl", "$opt{docroot}/$real_path", $staticroot );

247 # Making a relative symlink to a file in the same directory.

248 # Extract just the filename portion of $real_path.

249 my $real_file = basename($real_path);

250 print "Symlinking : docroot:/$link_path to $real_file\n" if ( $opt{verbose} );

251 if ( -f "$opt{docroot}/$link_path" ) {

252 unlink("$opt{docroot}/$link_path") or die "failed removing $opt{docroot}/$link_path: $!";

253 }

254 symlink( "$real_file", "$opt{docroot}/$link_path" ) || die "symlink to $opt{docroot}/$link_path failed: $!";

255 }

256 }

257 }

258

259 # ------------------------------------------------------------------

260 ## Fixup xref tags

261 sub xref_fixup {

262 my ( $xml, $prepend_chapter ) = @_;

263

264 my %index = ();

265

266 ## Add the "prepend_chapter" info

267 ( $xml->findnodes('/book') )[0]->appendTextChild( 'prepend_chapter', $prepend_chapter );

268

269 ## Iterate over each chapter

270 my $chapter_counter = 0;

271 foreach my $chapter ( $xml->findnodes('/book/chapter') ) {

272 ++$chapter_counter;

273

274 my $chapter_id = $chapter->getAttribute('id');

275 unless ($chapter_id) { # synthesise missing id

276 $chapter_id = sprintf( 'chapter_noid_%04d', $chapter_counter );

277 $chapter->setAttribute( 'id', $chapter_id );

278 }

279 my $chapter_title = $chapter->findvalue('title');

280

281 ## Set title_uri so we can use eg ch-introduction.html instead of ch01.html

282 $chapter->appendTextChild( 'title_uri', title_to_uri($chapter_title) );

283

284 $index{$chapter_id} = { chapter_id => $chapter_counter, chapter_title => $chapter_title };

285

286 ## Iterate over each section

287 my $section_counter = 0;

288 foreach my $section ( $chapter->findnodes('section') ) {

289 ++$section_counter;

290

291 my $section_id = $section->getAttribute('id');

292 unless ($section_id) { # synthesise missing id

293 $section_id = sprintf( 'section_noid_%04d_%04d', $chapter_counter, $section_counter );

294 $section->setAttribute( 'id', $section_id );

295 }

296 my $section_title = $section->findvalue('title');

297

298 $index{$section_id} = {

299 chapter_id => $chapter_counter,

300 chapter_title => $chapter_title,

301 section_id => $section_counter,

302 section_title => $section_title

303 };

304 }

305 }

306 ## Build indexes as new chapters

307 build_indexes( $xml, $prepend_chapter, \%index );

308

309 ## Replace all of the xrefs in the XML

310 foreach my $xref ( $xml->findnodes('//xref') ) {

311 my $linkend = $xref->getAttribute('linkend');

312 if ( exists $index{$linkend} ) {

313 $xref->setAttribute( 'chapter_id', $index{$linkend}{'chapter_id'} );

314 $xref->setAttribute( 'chapter_title', $index{$linkend}{'chapter_title'} );

315 $xref->setAttribute( 'section_id', $index{$linkend}{'section_id'} ) if ( $index{$linkend}{'section_id'} );

316 $xref->setAttribute( 'section_title', $index{$linkend}{'section_title'} )

317 if ( $index{$linkend}{'section_title'} );

318 $xref->setAttribute( 'url',

319 sprintf( '%sch-%s.html', $prepend_chapter, title_to_uri($index{$linkend}{'chapter_title'}) )

320 . ( $index{$linkend}{'section_id'} ? '#' . $linkend : '' ) );

321 }

322 }

323 }

324

325 # ------------------------------------------------------------------

326 ## Build indexes

327 sub build_indexes {

328 my ( $xml, $prepend_chapter, $xref ) = @_;

329

330 my $index_hash = {};

331 my $current_id;

332 foreach my $node ( $xml->findnodes('//section | //chapter | //indexterm') ) {

333 if ( $node->nodeName eq 'indexterm' ) {

334 my $role = $node->getAttribute('role') || 'concept';

335 my $primary = $node->findvalue('child::primary');

336 my $first = ( $primary =~ /^[A-Za-z]/ ) ? uc( substr( $primary, 0, 1 ) ) : ''; # first letter or marker

337 my $secondary = $node->findvalue('child::secondary') || '';

338 next unless ( $primary || $secondary ); # skip blank entries for now...

339 $index_hash->{$role}{$first}{$primary}{$secondary} ||= [];

340 push @{ $index_hash->{$role}{$first}{$primary}{$secondary} }, $current_id;

341 }

342 else {

343 $current_id = $node->getAttribute('id');

344 }

345 }

346

347 # now we build a set of new chapters with the index data in

348 my $book = ( $xml->findnodes('/book') )[0];

349 foreach my $role ( sort { $a cmp $b } keys %{$index_hash} ) {

350 my $chapter = XML::LibXML::Element->new('chapter');

351 $book->appendChild($chapter);

352 $chapter->setAttribute( 'id', join( '_', 'index', $role ) );

353 $chapter->setAttribute( 'class', 'index' );

354 $chapter->appendTextChild( 'title', ( ucfirst($role) . ' Index' ) );

355 $chapter->appendTextChild( 'title_uri', title_to_uri(ucfirst($role) . ' Index') );

356

357 foreach my $first ( sort { $a cmp $b } keys %{ $index_hash->{$role} } ) {

358 my $section = XML::LibXML::Element->new('section');

359 my $list = XML::LibXML::Element->new('variablelist');

360 $chapter->appendChild($section);

361 $section->setAttribute( 'id', join( '_', 'index', $role, $first ) );

362 $section->setAttribute( 'class', 'index' );

363 $section->appendTextChild( 'title', $first ? $first : 'Symbols' );

364 $section->appendChild($list);

365 foreach my $primary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first} } ) {

366 my $entry = XML::LibXML::Element->new('varlistentry');

367 my $item = XML::LibXML::Element->new('listitem');

368 $list->appendChild($entry)->appendTextChild( 'term', $primary );

369 $entry->appendChild($item);

370 my $slist;

371 foreach my $secondary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first}{$primary} } ) {

372 my $para = XML::LibXML::Element->new('para');

373 if ( $secondary eq '' ) {

374 $item->appendChild($para); # skip having extra layer of heirarchy

375 }

376 else {

377 unless ($slist) {

378 $slist = XML::LibXML::Element->new('variablelist');

379 $item->appendChild($slist);

380 }

381 my $sentry = XML::LibXML::Element->new('varlistentry');

382 my $sitem = XML::LibXML::Element->new('listitem');

383 $slist->appendChild($sentry)->appendTextChild( 'term', $secondary );

384 $sentry->appendChild($sitem)->appendChild($para);

385 }

386 my $count = 0;

387 foreach my $ref ( @{ $index_hash->{$role}{$first}{$primary}{$secondary} } ) {

388 $para->appendText(', ')

389 if ( $count++ );

390 my $xrefel = XML::LibXML::Element->new('xref');

391 $xrefel->setAttribute( linkend => $ref );

392 $xrefel->setAttribute( longref => 1 );

393 $para->appendChild($xrefel);

394 }

395 }

396 }

397 }

398 }

399 }

400

401 # ------------------------------------------------------------------

402 ## Handle the transformation

403 sub transform {

404 my ( $xml, $xsl_path, $out_path, $staticroot_abs ) = @_;

405

406 ## make sure $staticroot is set

407 $staticroot_abs ||= $opt{staticroot};

408

409 ## Build an empty XML structure if an undefined $xml was passed

410 unless ( defined $xml ) {

411 $xml = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );

412 $xml->setDocumentElement( $xml->createElement('content') );

413 }

414

415 ## Add the current version of Exim to the XML

416 $xml->documentElement()->appendTextChild( 'current_version', $opt{latest} );

417

418 ## Add the old versions of Exim to the XML

419 $xml->documentElement()->appendTextChild( 'old_versions', $_ ) foreach old_docs_versions();

420

421 ## Parse the ".xsl" file as XML

422 my $xsl = XML::LibXML->new(expand_entities => 1)->parse_file($xsl_path) or die $!;

423

424 ## Generate a stylesheet from the ".xsl" XML.

425 my $stylesheet = XML::LibXSLT->new()->parse_stylesheet($xsl);

426

427 ## work out the static root relative to the target

428 my $target_dir = ( File::Spec->splitpath($out_path) )[1];

429 my $staticroot = File::Spec->abs2rel( $staticroot_abs, $target_dir );

430

431 ## Generate a doc from the XML transformed with the XSL

432 my $doc = $stylesheet->transform( $xml, staticroot => sprintf( "'%s'", $staticroot ) );

433

434 ## Make the containing directory if it doesn't exist

435 make_path( ( $out_path =~ /^(.+)\/.+$/ )[0], { verbose => $opt{verbose} } );

436

437 ## Write out the document

438 open my $out, '>', $out_path or die "Unable to write $out_path - $!";

439 print $out $stylesheet->output_as_bytes($doc);

440 close $out;

441 }

442

443 # ------------------------------------------------------------------

444 ## Takes a chapter title and fixes it up so it is suitable for use in a URI

445 sub title_to_uri {

446 my $title = lc(shift);

447 $title =~ s/[^a-z0-9\s]+//gi; # Only allow spaces, numbers and letters

448 $title =~ s/\s+/_/g; # Replace spaces with underscores so URLs are easier to copy about

449 return $title;

450 }

451

452 # ------------------------------------------------------------------

453 ## Look in the docroot for old versions of the documentation

454 sub old_docs_versions {

455 if ( !exists $cache{old_docs_versions} ) {

456 my @versions;

457 foreach ( glob("$opt{docroot}/exim-html-*") ) {

458 push @versions, $1 if /-(\d+(?:\.\d+)?)$/ && $1 lt $opt{latest} && -d $_;

459 }

460 $cache{old_docs_versions} = [ reverse sort { $a cmp $b } @versions ];

461 }

462 return @{ $cache{old_docs_versions} };

463 }

464

465 # ------------------------------------------------------------------

466 ## error_help

467 sub error_help {

468 my $msg = shift;

469

470 warn $msg;

471 pod2usage( -exitval => 1, -verbose => 0 );

472 }

473

474 # ------------------------------------------------------------------

475 ## Parse arguments

476 sub parse_arguments {

477

478 my %opt = ( spec => [], filter => [], help => 0, man => 0, web => 0, minify => 1, verbose => 0, localstatic => 0, tmpl => "$Bin/../templates" );

479 GetOptions(

480 \%opt, 'help|h!', 'man!', 'web!', 'spec=s{1,}', 'filter=s{1,}',

481 'latest=s', 'tmpl=s', 'docroot=s', 'minify!', 'verbose!', 'localstatic!'

482 ) || pod2usage( -exitval => 1, -verbose => 0 );

483

484 ## --help

485 pod2usage(0) if ( $opt{help} );

486 pod2usage( -verbose => 2 ) if ( $opt{man} );

487

488 ## --spec and --filter lists

489 foreach my $set (qw[spec filter]) {

490 $opt{$set} =

491 [ map { my $f = File::Spec->rel2abs($_); error_help( 'No such file: ' . $_ ) unless -f $f; $f }

492 @{ $opt{$set} } ];

493 }

494 ## --latest

495 error_help('Missing value for latest') unless ( exists( $opt{latest} ) && defined( $opt{latest} ) );

496 error_help('Invalid value for latest') unless $opt{latest} =~ /^\d+(?:\.\d+)*$/;

497

498 ## --tmpl and --docroot

499 foreach my $set (qw[tmpl docroot]) {

500 error_help( 'Missing value for ' . $set ) unless ( exists( $opt{$set} ) && defined( $opt{$set} ) );

501 my $f = File::Spec->rel2abs( $opt{$set} );

502 error_help( 'No such directory: ' . $opt{$set} ) unless -d $f;

503 $opt{$set} = $f;

504 }

505 error_help('Excess arguments') if ( scalar(@ARGV) );

506

507 error_help('Must include at least one of --web, --spec or --filter')

508 unless ( $opt{web} || scalar( @{ $opt{spec} || [] } ) || scalar( @{ $opt{filter} || [] } ) );

509

510 return %opt;

511 }

512

513 # ------------------------------------------------------------------

514 1;

515

516 __END__

517

518 =head1 NAME

519

520 gen - Generate exim html documentation and website

521

522 =head1 SYNOPSIS

523

524 gen [options]

525

526 Options:

527 --help display this help and exits

528 --man displays man page

529 --spec file... spec docbook/XML source files

530 --filter file... filter docbook/XML source files

531 --web Generate the general website pages

532 --latest VERSION Required. Specify the latest stable version of Exim.

533 --tmpl PATH Required. Path to the templates directory

534 --docroot PATH Required. Path to the website document root

535 --[no-]minify [Don't] minify CSS and Javascript

536 --localstatic Makes the static files local to each doc ver

538 =head1 OPTIONS

540 =over 4

542 =item B<--help>

544 Display help and exits

545

546 =item B<--man>

547

548 Display man page

549

550 =item B<--spec> I<file...>

551

552 List of files that make up the specification documentation docbook/XML source

553 files.

554

555 =item B<--filter> I<file...>

556

557 List of files that make up the filter documentation docbook/XML source files.

558

559 =item B<--web>

560

561 Generate the website from the template files.

562

563 =item B<--latest> I<version>

564

565 Specify the current exim version. This is used to create links to the current

566 documentation.

567

568 This option is I<required>

569

570 =item B<--tmpl> I<directory>

571

572 Specify the directory that the templates are kept in.

573

574 This option is I<required>

575

576 =item B<--docroot> I<directory>

577

578 Specify the directory that the output should be generated into. This is the

579 website C<docroot> directory.

580

581 This option is I<required>

582

583 =item B<--minify>

584

585 If this option is set then both the CSS and Javascript files processed are

586 minified using L<CSS::Minifier::XS> and L<JavaScript::Minifier::XS>

587 respectively.

588

589 This option is set by default - to disable it specify C<--no-minify>

590

591 =item B<--localstatic>

592

593 Makes the static files (CSS, images etc), local for each version of the

594 documentation. This is more suitable for packaged HTML documentation.

595

596 =back

597

598 =head1 DESCRIPTION

599

600 Generates the exim website and HTML documentation.

601

602 =head1 EXAMPLE

603

604 script/gen \

605 --web \

606 --spec docbook/*/spec.xml \

607 --filter docbook/*/filter.xml \

608 --latest 4.72 \

609 --tmpl templates \

610 --docroot /tmp/website

611

612 =head1 AUTHOR

613

614 Mike Cardwell

615

616 Nigel Metheringham <nigel@exim.org> - mostly broke the framework Mike produced.

617

618 =head1 COPYRIGHT

619

621

622 =cut