test/runtest

   1 #! /usr/bin/env perl
   2 # We use env, because in some environments of our build farm
   3 # the Perl 5.010 interpreter is only reachable via $PATH
   4
   5 ###############################################################################
   6 # This is the controlling script for the "new" test suite for Exim. It should #
   7 # be possible to export this suite for running on a wide variety of hosts, in #
   8 # contrast to the old suite, which was very dependent on the environment of   #
   9 # Philip Hazel's desktop computer. This implementation inspects the version   #
  10 # of Exim that it finds, and tests only those features that are included. The #
  11 # surrounding environment is also tested to discover what is available. See   #
  12 # the README file for details of how it all works.                            #
  13 #                                                                             #
  14 # Implementation started: 03 August 2005 by Philip Hazel                      #
  15 # Placed in the Exim CVS: 06 February 2006                                    #
  16 ###############################################################################
  17
  18 #use strict;
  19 use 5.010;
  20 use feature 'state';    # included in 5.010
  21 use warnings;
  22
  23 use Errno;
  24 use FileHandle;
  25 use Socket;
  26 use Time::Local;
  27 use Cwd;
  28 use File::Basename;
  29 use FindBin qw'$RealBin';
  30
  31 use lib "$RealBin/lib";
  32 use Exim::Runtest;
  33
  34 use if $ENV{DEBUG} && $ENV{DEBUG} =~ /\bruntest\b/ => ('Smart::Comments' => '####');
  35
  36
  37 # Start by initializing some global variables
  38
  39 chomp(my $testversion = `git describe --always --dirty 2>&1` || '<unknown>');
  40
  41 # This gets embedded in the D-H params filename, and the value comes
  42 # from asking GnuTLS for "normal", but there appears to be no way to
  43 # use certtool/... to ask what that value currently is.  *sigh*
  44 # We also clamp it because of NSS interop, see addition of tls_dh_max_bits.
  45 # This value is correct as of GnuTLS 2.12.18 as clamped by tls_dh_max_bits.
  46 # normal = 2432   tls_dh_max_bits = 2236
  47 my $gnutls_dh_bits_normal = 2236;
  48
  49 my $cf = 'bin/cf -exact';
  50 my $cr = "\r";
  51 my $debug = 0;
  52 my $flavour = do {
  53   my $f = Exim::Runtest::flavour();
  54   (grep { $f eq $_ } Exim::Runtest::flavours()) ? $f : 'FOO';
  55 };
  56 my $force_continue = 0;
  57 my $force_update = 0;
  58 my $log_failed_filename = 'failed-summary.log';
  59 my $more = 'less -XF';
  60 my $optargs = '';
  61 my $save_output = 0;
  62 my $server_opts = '';
  63 my $valgrind = 0;
  64
  65 my $have_ipv4 = 1;
  66 my $have_ipv6 = 1;
  67 my $have_largefiles = 0;
  68
  69 my $test_start = 1;
  70 my $test_end = $test_top = 8999;
  71 my $test_special_top = 9999;
  72 my @test_list = ();
  73 my @test_dirs = ();
  74
  75
  76 # Networks to use for DNS tests. We need to choose some networks that will
  77 # never be used so that there is no chance that the host on which we are
  78 # running is actually in one of the test networks. Private networks such as
  79 # the IPv4 10.0.0.0/8 network are no good because hosts may well use them.
  80 # Rather than use some unassigned numbers (that might become assigned later),
  81 # I have chosen some multicast networks, in the belief that such addresses
  82 # won't ever be assigned to hosts. This is the only place where these numbers
  83 # are defined, so it is trivially possible to change them should that ever
  84 # become necessary.
  85
  86 my $parm_ipv4_test_net = 224;
  87 my $parm_ipv6_test_net = 'ff00';
  88
  89 # Port numbers are currently hard-wired
  90
  91 my $parm_port_n = 1223;         # Nothing listening on this port
  92 my $parm_port_s = 1224;         # Used for the "server" command
  93 my $parm_port_d = 1225;         # Used for the Exim daemon
  94 my $parm_port_d2 = 1226;        # Additional for daemon
  95 my $parm_port_d3 = 1227;        # Additional for daemon
  96 my $parm_port_d4 = 1228;        # Additional for daemon
  97 my $dynamic_socket;          # allocated later for PORT_DYNAMIC
  98
  99 # Find a suiteable group name for test (currently only 0001
 100 # uses a group name. A numeric group id would do
 101 my $parm_mailgroup = Exim::Runtest::mailgroup('mail');
 102
 103 # Manually set locale
 104 $ENV{LC_ALL} = 'C';
 105
 106 # In some environments USER does not exist, but we need it for some test(s)
 107 $ENV{USER} = getpwuid($>) if not exists $ENV{USER};
 108
 109 my ($parm_configure_owner, $parm_configure_group);
 110 my ($parm_ipv4, $parm_ipv6);
 111 my $parm_hostname;
 112
 113 ###############################################################################
 114 ###############################################################################
 115
 116 # Define a number of subroutines
 117
 118 ###############################################################################
 119 ###############################################################################
 120
 121
 122 ##################################################
 123 #              Handle signals                    #
 124 ##################################################
 125
 126 sub pipehandler { $sigpipehappened = 1; }
 127
 128 sub inthandler { print "\n"; tests_exit(-1, "Caught SIGINT"); }
 129
 130
 131 ##################################################
 132 #       Do global macro substitutions            #
 133 ##################################################
 134
 135 # This function is applied to configurations, command lines and data lines in
 136 # scripts, and to lines in the files of the aux-var-src and the dnszones-src
 137 # directory. It takes one argument: the current test number, or zero when
 138 # setting up files before running any tests.
 139
 140 sub do_substitute{
 141 s?\bCALLER\b?$parm_caller?g;
 142 s?\bCALLERGROUP\b?$parm_caller_group?g;
 143 s?\bCALLER_UID\b?$parm_caller_uid?g;
 144 s?\bCALLER_GID\b?$parm_caller_gid?g;
 145 s?\bCLAMSOCKET\b?$parm_clamsocket?g;
 146 s?\bDIR/?$parm_cwd/?g;
 147 s?\bEXIMGROUP\b?$parm_eximgroup?g;
 148 s?\bEXIMUSER\b?$parm_eximuser?g;
 149 s?\bHOSTIPV4\b?$parm_ipv4?g;
 150 s?\bHOSTIPV6\b?$parm_ipv6?g;
 151 s?\bHOSTNAME\b?$parm_hostname?g;
 152 s?\bPORT_D\b?$parm_port_d?g;
 153 s?\bPORT_D2\b?$parm_port_d2?g;
 154 s?\bPORT_D3\b?$parm_port_d3?g;
 155 s?\bPORT_D4\b?$parm_port_d4?g;
 156 s?\bPORT_N\b?$parm_port_n?g;
 157 s?\bPORT_S\b?$parm_port_s?g;
 158 s?\bTESTNUM\b?$_[0]?g;
 159 s?(\b|_)V4NET([\._])?$1$parm_ipv4_test_net$2?g;
 160 s?\bV6NET:?$parm_ipv6_test_net:?g;
 161 s?\bPORT_DYNAMIC\b?$dynamic_socket->sockport()?eg;
 162 s?\bMAILGROUP\b?$parm_mailgroup?g;
 163 }
 164
 165
 166 ##################################################
 167 #     Any state to be preserved across tests     #
 168 ##################################################
 169
 170 my $TEST_STATE = {};
 171
 172
 173 ##################################################
 174 #        Subroutine to tidy up and exit          #
 175 ##################################################
 176
 177 # In all cases, we check for any Exim daemons that have been left running, and
 178 # kill them. Then remove all the spool data, test output, and the modified Exim
 179 # binary if we are ending normally.
 180
 181 # Arguments:
 182 #    $_[0] = 0 for a normal exit; full cleanup done
 183 #    $_[0] > 0 for an error exit; no files cleaned up
 184 #    $_[0] < 0 for a "die" exit; $_[1] contains a message
 185
 186 sub tests_exit{
 187 my($rc) = $_[0];
 188 my($spool);
 189
 190 # Search for daemon pid files and kill the daemons. We kill with SIGINT rather
 191 # than SIGTERM to stop it outputting "Terminated" to the terminal when not in
 192 # the background.
 193
 194 if (exists $TEST_STATE->{exim_pid})
 195   {
 196   $pid = $TEST_STATE->{exim_pid};
 197   print "Tidyup: killing wait-mode daemon pid=$pid\n";
 198   system("sudo kill -INT $pid");
 199   }
 200
 201 if (opendir(DIR, "spool"))
 202   {
 203   my(@spools) = sort readdir(DIR);
 204   closedir(DIR);
 205   foreach $spool (@spools)
 206     {
 207     next if $spool !~ /^exim-daemon./;
 208     open(PID, "spool/$spool") || die "** Failed to open \"spool/$spool\": $!\n";
 209     chomp($pid = <PID>);
 210     close(PID);
 211     print "Tidyup: killing daemon pid=$pid\n";
 212     system("sudo rm -f spool/$spool; sudo kill -INT $pid");
 213     }
 214   }
 215 else
 216   { die "** Failed to opendir(\"spool\"): $!\n" unless $!{ENOENT}; }
 217
 218 # Close the terminal input and remove the test files if all went well, unless
 219 # the option to save them is set. Always remove the patched Exim binary. Then
 220 # exit normally, or die.
 221
 222 close(T);
 223 system("sudo /bin/rm -rf ./spool test-* ./dnszones/*")
 224   if ($rc == 0 && !$save_output);
 225
 226 system("sudo /bin/rm -rf ./eximdir/*")
 227   if (!$save_output);
 228
 229 print "\nYou were in test $test at the end there.\n\n" if defined $test;
 230 exit $rc if ($rc >= 0);
 231 die "** runtest error: $_[1]\n";
 232 }
 233
 234
 235
 236 ##################################################
 237 #   Subroutines used by the munging subroutine   #
 238 ##################################################
 239
 240 # This function is used for things like message ids, where we want to generate
 241 # more than one value, but keep a consistent mapping throughout.
 242 #
 243 # Arguments:
 244 #   $oldid        the value from the file
 245 #   $base         a base string into which we insert a sequence
 246 #   $sequence     the address of the current sequence counter
 247
 248 sub new_value {
 249 my($oldid, $base, $sequence) = @_;
 250 my($newid) = $cache{$oldid};
 251 if (! defined $newid)
 252   {
 253   $newid = sprintf($base, $$sequence++);
 254   $cache{$oldid} = $newid;
 255   }
 256 return $newid;
 257 }
 258
 259
 260 # This is used while munging the output from exim_dumpdb.
 261 # May go wrong across DST changes.
 262
 263 sub date_seconds {
 264 my($day,$month,$year,$hour,$min,$sec) =
 265   $_[0] =~ /^(\d\d)-(\w\w\w)-(\d{4})\s(\d\d):(\d\d):(\d\d)/;
 266 my($mon);
 267 if   ($month =~ /Jan/) {$mon = 0;}
 268 elsif($month =~ /Feb/) {$mon = 1;}
 269 elsif($month =~ /Mar/) {$mon = 2;}
 270 elsif($month =~ /Apr/) {$mon = 3;}
 271 elsif($month =~ /May/) {$mon = 4;}
 272 elsif($month =~ /Jun/) {$mon = 5;}
 273 elsif($month =~ /Jul/) {$mon = 6;}
 274 elsif($month =~ /Aug/) {$mon = 7;}
 275 elsif($month =~ /Sep/) {$mon = 8;}
 276 elsif($month =~ /Oct/) {$mon = 9;}
 277 elsif($month =~ /Nov/) {$mon = 10;}
 278 elsif($month =~ /Dec/) {$mon = 11;}
 279 return timelocal($sec,$min,$hour,$day,$mon,$year);
 280 }
 281
 282
 283 # This is a subroutine to sort maildir files into time-order. The second field
 284 # is the microsecond field, and may vary in length, so must be compared
 285 # numerically.
 286
 287 sub maildirsort {
 288 return $a cmp $b if ($a !~ /^\d+\.H\d/ || $b !~ /^\d+\.H\d/);
 289 my($x1,$y1) = $a =~ /^(\d+)\.H(\d+)/;
 290 my($x2,$y2) = $b =~ /^(\d+)\.H(\d+)/;
 291 return ($x1 != $x2)? ($x1 <=> $x2) : ($y1 <=> $y2);
 292 }
 293
 294
 295
 296 ##################################################
 297 #   Subroutine list files below a directory      #
 298 ##################################################
 299
 300 # This is used to build up a list of expected mail files below a certain path
 301 # in the directory tree. It has to be recursive in order to deal with multiple
 302 # maildir mailboxes.
 303
 304 sub list_files_below {
 305 my($dir) = $_[0];
 306 my(@yield) = ();
 307 my(@sublist, $file);
 308
 309 opendir(DIR, $dir) || tests_exit(-1, "Failed to open $dir: $!");
 310 @sublist = sort maildirsort readdir(DIR);
 311 closedir(DIR);
 312
 313 foreach $file (@sublist)
 314   {
 315   next if $file eq "." || $file eq ".." || $file eq "CVS";
 316   if (-d "$dir/$file")
 317     { @yield = (@yield, list_files_below("$dir/$file")); }
 318   else
 319     { push @yield, "$dir/$file"; }
 320   }
 321
 322 return @yield;
 323 }
 324
 325
 326
 327 ##################################################
 328 #         Munge a file before comparing          #
 329 ##################################################
 330
 331 # The pre-processing turns all dates, times, Exim versions, message ids, and so
 332 # on into standard values, so that the compare works. Perl's substitution with
 333 # an expression provides a neat way to do some of these changes.
 334
 335 # We keep a global associative array for repeatedly turning the same values
 336 # into the same standard values throughout the data from a single test.
 337 # Message ids get this treatment (can't be made reliable for times), and
 338 # times in dumped retry databases are also handled in a special way, as are
 339 # incoming port numbers.
 340
 341 # On entry to the subroutine, the file to write to is already opened with the
 342 # name MUNGED. The input file name is the only argument to the subroutine.
 343 # Certain actions are taken only when the name contains "stderr", "stdout",
 344 # or "log". The yield of the function is 1 if a line matching "*** truncated
 345 # ***" is encountered; otherwise it is 0.
 346
 347 sub munge {
 348 my($file) = $_[0];
 349 my($extra) = $_[1];
 350 my($yield) = 0;
 351 my(@saved) = ();
 352
 353 local $_;
 354
 355 open(IN, "$file") || tests_exit(-1, "Failed to open $file: $!");
 356
 357 my($is_log) = $file =~ /log/;
 358 my($is_stdout) = $file =~ /stdout/;
 359 my($is_stderr) = $file =~ /stderr/;
 360
 361 # Date pattern
 362
 363 $date = "\\d{2}-\\w{3}-\\d{4}\\s\\d{2}:\\d{2}:\\d{2}";
 364
 365 # Pattern for matching pids at start of stderr lines; initially something
 366 # that won't match.
 367
 368 $spid = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";
 369
 370 # Scan the file and make the changes. Near the bottom there are some changes
 371 # that are specific to certain file types, though there are also some of those
 372 # inline too.
 373
 374 LINE: while(<IN>)
 375   {
 376 RESET_AFTER_EXTRA_LINE_READ:
 377   # Custom munges
 378   if ($extra)
 379     {
 380     next if $extra =~ m%^/%  &&  eval $extra;
 381     eval $extra if $extra =~ m/^s/;
 382     }
 383
 384   # Check for "*** truncated ***"
 385   $yield = 1 if /\*\*\* truncated \*\*\*/;
 386
 387   # Replace the name of this host
 388   s/\Q$parm_hostname\E/the.local.host.name/g;
 389
 390   # But convert "name=the.local.host address=127.0.0.1" to use "localhost"
 391   s/name=the\.local\.host address=127\.0\.0\.1/name=localhost address=127.0.0.1/g;
 392
 393   # The name of the shell may vary
 394   s/\s\Q$parm_shell\E\b/ ENV_SHELL/;
 395
 396   # Replace the path to the testsuite directory
 397   s?\Q$parm_cwd\E?TESTSUITE?g;
 398
 399   # Replace the Exim version number (may appear in various places)
 400   # patchexim should have fixed this for us
 401   #s/(Exim) \d+\.\d+[\w_-]*/$1 x.yz/i;
 402
 403   # Replace Exim message ids by a unique series
 404   s/((?:[^\W_]{6}-){2}[^\W_]{2})
 405     /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
 406
 407   # The names of lock files appear in some error and debug messages
 408   s/\.lock(\.[-\w]+)+(\.[\da-f]+){2}/.lock.test.ex.dddddddd.pppppppp/;
 409
 410   # Unless we are in an IPv6 test, replace IPv4 and/or IPv6 in "listening on
 411   # port" message, because it is not always the same.
 412   s/port (\d+) \([^)]+\)/port $1/g
 413     if !$is_ipv6test && m/listening for SMTP(S?) on port/;
 414
 415   # Challenges in SPA authentication
 416   s/TlRMTVNTUAACAAAAAAAAAAAoAAABgg[\w+\/]+/TlRMTVNTUAACAAAAAAAAAAAoAAABggAAAEbBRwqFwwIAAAAAAAAAAAAt1sgAAAAA/;
 417
 418   # PRVS values
 419   s?prvs=([^/]+)/[\da-f]{10}@?prvs=$1/xxxxxxxxxx@?g;    # Old form
 420   s?prvs=[\da-f]{10}=([^@]+)@?prvs=xxxxxxxxxx=$1@?g;    # New form
 421
 422   # Error lines on stdout from SSL contain process id values and file names.
 423   # They also contain a source file name and line number, which may vary from
 424   # release to release.
 425   s/^\d+:error:/pppp:error:/;
 426   s/:(?:\/[^\s:]+\/)?([^\/\s]+\.c):\d+:/:$1:dddd:/;
 427
 428   # There are differences in error messages between OpenSSL versions
 429   s/SSL_CTX_set_cipher_list/SSL_connect/;
 430
 431   # One error test in expansions mentions base 62 or 36
 432   s/is not a base (36|62) number/is not a base 36\/62 number/;
 433
 434   # This message sometimes has a different number of seconds
 435   s/forced fail after \d seconds/forced fail after d seconds/;
 436
 437   # This message may contain a different DBM library name
 438   s/Failed to open \S+( \([^\)]+\))? file/Failed to open DBM file/;
 439
 440   # The message for a non-listening FIFO varies
 441   s/:[^:]+: while opening named pipe/: Error: while opening named pipe/;
 442
 443   # Debugging output of lists of hosts may have different sort keys
 444   s/sort=\S+/sort=xx/ if /^\S+ (?:\d+\.){3}\d+ mx=\S+ sort=\S+/;
 445
 446   # Random local part in callout cache testing
 447   s/myhost.test.ex-\d+-testing/myhost.test.ex-dddddddd-testing/;
 448   s/the.local.host.name-\d+-testing/the.local.host.name-dddddddd-testing/;
 449
 450   # File descriptor numbers may vary
 451   s/^writing data block fd=\d+/writing data block fd=dddd/;
 452   s/(running as transport filter:) fd_write=\d+ fd_read=\d+/$1 fd_write=dddd fd_read=dddd/;
 453
 454
 455   # ======== Dumpdb output ========
 456   # This must be before the general date/date munging.
 457   # Time data lines, which look like this:
 458   # 25-Aug-2000 12:11:37  25-Aug-2000 12:11:37  26-Aug-2000 12:11:37
 459   if (/^($date)\s+($date)\s+($date)(\s+\*)?\s*$/)
 460     {
 461     my($date1,$date2,$date3,$expired) = ($1,$2,$3,$4);
 462     $expired = '' if !defined $expired;
 463     my($increment) = date_seconds($date3) - date_seconds($date2);
 464
 465     # We used to use globally unique replacement values, but timing
 466     # differences make this impossible. Just show the increment on the
 467     # last one.
 468
 469     printf MUNGED ("first failed = time last try = time2 next try = time2 + %s%s\n",
 470       $increment, $expired);
 471     next;
 472     }
 473
 474   # more_errno values in exim_dumpdb output which are times
 475   s/T:(\S+)\s-22\s(\S+)\s/T:$1 -22 xxxx /;
 476
 477
 478   # ======== Dates and times ========
 479
 480   # Dates and times are all turned into the same value - trying to turn
 481   # them into different ones cannot be done repeatedly because they are
 482   # real time stamps generated while running the test. The actual date and
 483   # time used was fixed when I first started running automatic Exim tests.
 484
 485   # Date/time in header lines and SMTP responses
 486   s/[A-Z][a-z]{2},\s\d\d?\s[A-Z][a-z]{2}\s\d\d\d\d\s\d\d\:\d\d:\d\d\s[-+]\d{4}
 487     /Tue, 2 Mar 1999 09:44:33 +0000/gx;
 488
 489   # Date/time in logs and in one instance of a filter test
 490   s/^\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d(\s[+-]\d\d\d\d)?/1999-03-02 09:44:33/gx;
 491   s/^Logwrite\s"\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Logwrite "1999-03-02 09:44:33/gx;
 492
 493   # Date/time in message separators
 494   s/(?:[A-Z][a-z]{2}\s){2}\d\d\s\d\d:\d\d:\d\d\s\d\d\d\d
 495     /Tue Mar 02 09:44:33 1999/gx;
 496
 497   # Date of message arrival in spool file as shown by -Mvh
 498   s/^\d{9,10}\s0$/ddddddddd 0/;
 499
 500   # Date/time in mbx mailbox files
 501   s/\d\d-\w\w\w-\d\d\d\d\s\d\d:\d\d:\d\d\s[-+]\d\d\d\d,/06-Sep-1999 15:52:48 +0100,/gx;
 502
 503   # Dates/times in debugging output for writing retry records
 504   if (/^  first failed=(\d+) last try=(\d+) next try=(\d+) (.*)$/)
 505     {
 506     my($next) = $3 - $2;
 507     $_ = "  first failed=dddd last try=dddd next try=+$next $4\n";
 508     }
 509   s/^(\s*)now=\d+ first_failed=\d+ next_try=\d+ expired=(\d)/$1now=tttt first_failed=tttt next_try=tttt expired=$2/;
 510   s/^(\s*)received_time=\d+ diff=\d+ timeout=(\d+)/$1received_time=tttt diff=tttt timeout=$2/;
 511
 512   # Time to retry may vary
 513   s/time to retry = \S+/time to retry = tttt/;
 514   s/retry record exists: age=\S+/retry record exists: age=ttt/;
 515   s/failing_interval=\S+ message_age=\S+/failing_interval=ttt message_age=ttt/;
 516
 517   # Date/time in exim -bV output
 518   s/\d\d-[A-Z][a-z]{2}-\d{4}\s\d\d:\d\d:\d\d/07-Mar-2000 12:21:52/g;
 519
 520   # Time on queue tolerance
 521   s/(QT|D)=1s/$1=0s/;
 522
 523   # Eximstats heading
 524   s/Exim\sstatistics\sfrom\s\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d\sto\s
 525     \d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d/Exim statistics from <time> to <time>/x;
 526
 527   # Treat ECONNRESET the same as ECONNREFUSED.  At least some systems give
 528   # us the former on a new connection.
 529   s/(could not connect to .*: Connection) reset by peer$/$1 refused/;
 530
 531   # ======== TLS certificate algorithms ========
 532   # Test machines might have various different TLS library versions supporting
 533   # different protocols; can't rely upon TLS 1.2's AES256-GCM-SHA384, so we
 534   # treat the standard algorithms the same.
 535   # So far, have seen:
 536   #   TLSv1:AES128-GCM-SHA256:128
 537   #   TLSv1:AES256-SHA:256
 538   #   TLSv1.1:AES256-SHA:256
 539   #   TLSv1.2:AES256-GCM-SHA384:256
 540   #   TLSv1.2:DHE-RSA-AES256-SHA:256
 541   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 542   # We also need to handle the ciphersuite without the TLS part present, for
 543   # client-ssl's output.  We also see some older forced ciphersuites, but
 544   # negotiating TLS 1.2 instead of 1.0.
 545   # Mail headers (...), log-lines X=..., client-ssl output ...
 546   # (and \b doesn't match between ' ' and '(' )
 547
 548   s/( (?: (?:\b|\s) [\(=] ) | \s )TLSv1\.[12]:/$1TLSv1:/xg;
 549   s/\bAES128-GCM-SHA256:128\b/AES256-SHA:256/g;
 550   s/\bAES128-GCM-SHA256\b/AES256-SHA/g;
 551   s/\bAES256-GCM-SHA384\b/AES256-SHA/g;
 552   s/\bDHE-RSA-AES256-SHA\b/AES256-SHA/g;
 553
 554   # LibreSSL
 555   # TLSv1:ECDHE-RSA-CHACHA20-POLY1305:256
 556   s/\bECDHE-RSA-CHACHA20-POLY1305\b/AES256-SHA/g;
 557
 558   # GnuTLS have seen:
 559   #   TLS1.2:ECDHE_RSA_AES_256_GCM_SHA384:256
 560   #   TLS1.2:ECDHE_RSA_AES_128_GCM_SHA256:128
 561   #   TLS1.2:RSA_AES_256_CBC_SHA1:256 (canonical)
 562   #   TLS1.2:DHE_RSA_AES_128_CBC_SHA1:128
 563   #
 564   #   X=TLS1.2:DHE_RSA_AES_256_CBC_SHA256:256
 565   #   X=TLS1.2:RSA_AES_256_CBC_SHA1:256
 566   #   X=TLS1.1:RSA_AES_256_CBC_SHA1:256
 567   #   X=TLS1.0:DHE_RSA_AES_256_CBC_SHA1:256
 568   # and as stand-alone cipher:
 569   #   ECDHE-RSA-AES256-SHA
 570   #   DHE-RSA-AES256-SHA256
 571   #   DHE-RSA-AES256-SHA
 572   # picking latter as canonical simply because regex easier that way.
 573   s/\bDHE_RSA_AES_128_CBC_SHA1:128/RSA_AES_256_CBC_SHA1:256/g;
 574   s/TLS1.[012]:((EC)?DHE_)?RSA_AES_(256|128)_(CBC|GCM)_SHA(1|256|384):(256|128)/TLS1.x:xxxxRSA_AES_256_CBC_SHAnnn:256/g;
 575   s/\b(ECDHE-RSA-AES256-SHA|DHE-RSA-AES256-SHA256)\b/AES256-SHA/g;
 576
 577   # GnuTLS library error message changes
 578   s/No certificate was found/The peer did not send any certificate/g;
 579 #(dodgy test?)  s/\(certificate verification failed\): invalid/\(gnutls_handshake\): The peer did not send any certificate./g;
 580   s/\(gnutls_priority_set\): No or insufficient priorities were set/\(gnutls_handshake\): Could not negotiate a supported cipher suite/g;
 581
 582   # (this new one is a generic channel-read error, but the testsuite
 583   # only hits it in one place)
 584   s/TLS error on connection \(gnutls_handshake\): Error in the pull function\./a TLS session is required but an attempt to start TLS failed/g;
 585
 586   # (replace old with new, hoping that old only happens in one situation)
 587   s/TLS error on connection to \d{1,3}(.\d{1,3}){3} \[\d{1,3}(.\d{1,3}){3}\] \(gnutls_handshake\): A TLS packet with unexpected length was received./a TLS session is required for ip4.ip4.ip4.ip4 [ip4.ip4.ip4.ip4], but an attempt to start TLS failed/g;
 588   s/TLS error on connection from \[127.0.0.1\] \(recv\): A TLS packet with unexpected length was received./TLS error on connection from [127.0.0.1] (recv): The TLS connection was non-properly terminated./g;
 589
 590   # signature algorithm names
 591   s/RSA-SHA1/RSA-SHA/;
 592
 593
 594   # ======== Caller's login, uid, gid, home, gecos ========
 595
 596   s/\Q$parm_caller_home\E/CALLER_HOME/g;   # NOTE: these must be done
 597   s/\b\Q$parm_caller\E\b/CALLER/g;         #       in this order!
 598   s/\b\Q$parm_caller_group\E\b/CALLER/g;   # In case group name different
 599
 600   s/\beuid=$parm_caller_uid\b/euid=CALLER_UID/g;
 601   s/\begid=$parm_caller_gid\b/egid=CALLER_GID/g;
 602
 603   s/\buid=$parm_caller_uid\b/uid=CALLER_UID/g;
 604   s/\bgid=$parm_caller_gid\b/gid=CALLER_GID/g;
 605
 606   s/\bname="?$parm_caller_gecos"?/name=CALLER_GECOS/g;
 607
 608   # When looking at spool files with -Mvh, we will find not only the caller
 609   # login, but also the uid and gid. It seems that $) in some Perls gives all
 610   # the auxiliary gids as well, so don't bother checking for that.
 611
 612   s/^CALLER $> \d+$/CALLER UID GID/;
 613
 614   # There is one case where the caller's login is forced to something else,
 615   # in order to test the processing of logins that contain spaces. Weird what
 616   # some people do, isn't it?
 617
 618   s/^spaced user $> \d+$/CALLER UID GID/;
 619
 620
 621   # ======== Exim's login ========
 622   # For messages received by the daemon, this is in the -H file, which some
 623   # tests inspect. For bounce messages, this will appear on the U= lines in
 624   # logs and also after Received: and in addresses. In one pipe test it appears
 625   # after "Running as:". It also appears in addresses, and in the names of lock
 626   # files.
 627
 628   s/U=$parm_eximuser/U=EXIMUSER/;
 629   s/user=$parm_eximuser/user=EXIMUSER/;
 630   s/login=$parm_eximuser/login=EXIMUSER/;
 631   s/Received: from $parm_eximuser /Received: from EXIMUSER /;
 632   s/Running as: $parm_eximuser/Running as: EXIMUSER/;
 633   s/\b$parm_eximuser@/EXIMUSER@/;
 634   s/\b$parm_eximuser\.lock\./EXIMUSER.lock./;
 635
 636   s/\beuid=$parm_exim_uid\b/euid=EXIM_UID/g;
 637   s/\begid=$parm_exim_gid\b/egid=EXIM_GID/g;
 638
 639   s/\buid=$parm_exim_uid\b/uid=EXIM_UID/g;
 640   s/\bgid=$parm_exim_gid\b/gid=EXIM_GID/g;
 641
 642   s/^$parm_eximuser $parm_exim_uid $parm_exim_gid/EXIMUSER EXIM_UID EXIM_GID/;
 643
 644
 645   # ======== General uids, gids, and pids ========
 646   # Note: this must come after munges for caller's and exim's uid/gid
 647
 648   # These are for systems where long int is 64
 649   s/\buid=4294967295/uid=-1/;
 650   s/\beuid=4294967295/euid=-1/;
 651   s/\bgid=4294967295/gid=-1/;
 652   s/\begid=4294967295/egid=-1/;
 653
 654   s/\bgid=\d+/gid=gggg/;
 655   s/\begid=\d+/egid=gggg/;
 656   s/\bpid=\d+/pid=pppp/;
 657   s/\buid=\d+/uid=uuuu/;
 658   s/\beuid=\d+/euid=uuuu/;
 659   s/set_process_info:\s+\d+/set_process_info: pppp/;
 660   s/queue run pid \d+/queue run pid ppppp/;
 661   s/process \d+ running as transport filter/process pppp running as transport filter/;
 662   s/process \d+ writing to transport filter/process pppp writing to transport filter/;
 663   s/reading pipe for subprocess \d+/reading pipe for subprocess pppp/;
 664   s/remote delivery process \d+ ended/remote delivery process pppp ended/;
 665
 666   # Pid in temp file in appendfile transport
 667   s"test-mail/temp\.\d+\."test-mail/temp.pppp.";
 668
 669   # Optional pid in log lines
 670   s/^(\d{4}-\d\d-\d\d\s\d\d:\d\d:\d\d)(\s[+-]\d\d\d\d|)(\s\[\d+\])/
 671     "$1$2 [" . new_value($3, "%s", \$next_pid) . "]"/gxe;
 672
 673   # Detect a daemon stderr line with a pid and save the pid for subsequent
 674   # removal from following lines.
 675   $spid = $1 if /^(\s*\d+) (?:listening|LOG: MAIN|(?:daemon_smtp_port|local_interfaces) overridden by)/;
 676   s/^$spid //;
 677
 678   # Queue runner waiting messages
 679   s/waiting for children of \d+/waiting for children of pppp/;
 680   s/waiting for (\S+) \(\d+\)/waiting for $1 (pppp)/;
 681
 682   # The spool header file name varies with PID
 683   s%^(Writing spool header file: .*/hdr).[0-9]{1,5}%$1.pppp%;
 684
 685   # ======== Port numbers ========
 686   # Incoming port numbers may vary, but not in daemon startup line.
 687
 688   s/^Port: (\d+)/"Port: " . new_value($1, "%s", \$next_port)/e;
 689   s/\(port=(\d+)/"(port=" . new_value($1, "%s", \$next_port)/e;
 690
 691   # This handles "connection from" and the like, when the port is given
 692   if (!/listening for SMTP on/ && !/Connecting to/ && !/=>/ && !/->/
 693       && !/\*>/ && !/Connection refused/)
 694     {
 695     s/\[([a-z\d:]+|\d+(?:\.\d+){3})\]:(\d+)/"[".$1."]:".new_value($2,"%s",\$next_port)/ie;
 696     }
 697
 698   # Port in host address in spool file output from -Mvh
 699   s/^-host_address (.*)\.\d+/-host_address $1.9999/;
 700
 701   if ($dynamic_socket and $dynamic_socket->opened and my $port = $dynamic_socket->sockport) {
 702     s/^Connecting to 127\.0\.0\.1 port \K$port/<dynamic port>/;
 703   }
 704
 705
 706   # ======== Local IP addresses ========
 707   # The amount of space between "host" and the address in verification output
 708   # depends on the length of the host name. We therefore reduce it to one space
 709   # for all of them.
 710   # Also, the length of space at the end of the host line is dependent
 711   # on the length of the longest line, so strip it also on otherwise
 712   # un-rewritten lines like localhost
 713
 714   s/^\s+host\s(\S+)\s+(\S+)/  host $1 $2/;
 715   s/^\s+(host\s\S+\s\S+)\s+(port=.*)/  host $1 $2/;
 716   s/^\s+(host\s\S+\s\S+)\s+(?=MX=)/  $1 /;
 717   s/host\s\Q$parm_ipv4\E\s\[\Q$parm_ipv4\E\]/host ipv4.ipv4.ipv4.ipv4 [ipv4.ipv4.ipv4.ipv4]/;
 718   s/host\s\Q$parm_ipv6\E\s\[\Q$parm_ipv6\E\]/host ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6 [ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6]/;
 719   s/\b\Q$parm_ipv4\E\b/ip4.ip4.ip4.ip4/g;
 720   s/(^|\W)\K\Q$parm_ipv6\E/ip6:ip6:ip6:ip6:ip6:ip6:ip6:ip6/g;
 721   s/\b\Q$parm_ipv4r\E\b/ip4-reverse/g;
 722   s/(^|\W)\K\Q$parm_ipv6r\E/ip6-reverse/g;
 723   s/^(\s+host\s\S+\s+\[\S+\]) +$/$1 /;
 724
 725
 726   # ======== Test network IP addresses ========
 727   s/(\b|_)\Q$parm_ipv4_test_net\E(?=\.\d+\.\d+\.\d+\b|_|\.rbl|\.in-addr|\.test\.again\.dns)/$1V4NET/g;
 728   s/\b\Q$parm_ipv6_test_net\E(?=:[\da-f]+:[\da-f]+:[\da-f]+)/V6NET/gi;
 729
 730
 731   # ======== IP error numbers and messages ========
 732   # These vary between operating systems
 733   s/Can't assign requested address/Network Error/;
 734   s/Cannot assign requested address/Network Error/;
 735   s/Operation timed out/Connection timed out/;
 736   s/Address family not supported by protocol family/Network Error/;
 737   s/Network is unreachable/Network Error/;
 738   s/Invalid argument/Network Error/;
 739
 740   s/\(\d+\): Network/(dd): Network/;
 741   s/\(\d+\): Connection refused/(dd): Connection refused/;
 742   s/\(\d+\): Connection timed out/(dd): Connection timed out/;
 743   s/\d+ 65 Connection refused/dd 65 Connection refused/;
 744   s/\d+ 321 Connection timed out/dd 321 Connection timed out/;
 745
 746
 747   # ======== Other error numbers ========
 748   s/errno=\d+/errno=dd/g;
 749
 750   # ======== System Error Messages ======
 751   # depending on the underlaying file system the error message seems to differ
 752   s/(?: is not a regular file)|(?: has too many links \(\d+\))/ not a regular file or too many links/;
 753
 754   # ======== Output from ls ========
 755   # Different operating systems use different spacing on long output
 756   #s/ +/ /g if /^[-rwd]{10} /;
 757   # (Bug 1226) SUSv3 allows a trailing printable char for modified access method control.
 758   # Handle only the Gnu and MacOS space, dot, plus and at-sign.  A full [[:graph:]]
 759   # unfortunately matches a non-ls linefull of dashes.
 760   # Allow the case where we've already picked out the file protection bits.
 761   if (s/^([-d](?:[-r][-w][-SsTtx]){3})[.+@]?( +|$)/$1$2/) {
 762     s/ +/ /g;
 763   }
 764
 765
 766   # ======== Message sizes =========
 767   # Message sizes vary, owing to different logins and host names that get
 768   # automatically inserted. I can't think of any way of even approximately
 769   # comparing these.
 770
 771   s/([\s,])S=\d+\b/$1S=sss/;
 772   s/:S\d+\b/:Ssss/;
 773   s/^(\s*\d+m\s+)\d+(\s+[a-z0-9-]{16} <)/$1sss$2/i if $is_stdout;
 774   s/\sSIZE=\d+\b/ SIZE=ssss/;
 775   s/\ssize=\d+\b/ size=sss/ if $is_stderr;
 776   s/old size = \d+\b/old size = sssss/;
 777   s/message size = \d+\b/message size = sss/;
 778   s/this message = \d+\b/this message = sss/;
 779   s/Size of headers = \d+/Size of headers = sss/;
 780   s/sum=(?!0)\d+/sum=dddd/;
 781   s/(?<=sum=dddd )count=\d+\b/count=dd/;
 782   s/(?<=sum=0 )count=\d+\b/count=dd/;
 783   s/,S is \d+\b/,S is ddddd/;
 784   s/\+0100,\d+;/+0100,ddd;/;
 785   s/\(\d+ bytes written\)/(ddd bytes written)/;
 786   s/added '\d+ 1'/added 'ddd 1'/;
 787   s/Received\s+\d+/Received               nnn/;
 788   s/Delivered\s+\d+/Delivered              nnn/;
 789
 790
 791   # ======== Values in spool space failure message ========
 792   s/space=\d+ inodes=[+-]?\d+/space=xxxxx inodes=xxxxx/;
 793
 794
 795   # ======== Filter sizes ========
 796   # The sizes of filter files may vary because of the substitution of local
 797   # filenames, logins, etc.
 798
 799   s/^\d+(?= bytes read from )/ssss/;
 800
 801
 802   # ======== OpenSSL error messages ========
 803   # Different releases of the OpenSSL libraries seem to give different error
 804   # numbers, or handle specific bad conditions in different ways, leading to
 805   # different wording in the error messages, so we cannot compare them.
 806
 807   s/(TLS error on connection (?:from .* )?\(SSL_\w+\): error:)(.*)/$1 <<detail omitted>>/;
 808   next if /SSL verify error: depth=0 error=certificate not trusted/;
 809
 810   # ======== Maildir things ========
 811   # timestamp output in maildir processing
 812   s/(timestamp=|\(timestamp_only\): )\d+/$1ddddddd/g;
 813
 814   # maildir delivery files appearing in log lines (in cases of error)
 815   s/writing to(?: file)? tmp\/\d+\.[^.]+\.(\S+)/writing to tmp\/MAILDIR.$1/;
 816
 817   s/renamed tmp\/\d+\.[^.]+\.(\S+) as new\/\d+\.[^.]+\.(\S+)/renamed tmp\/MAILDIR.$1 as new\/MAILDIR.$1/;
 818
 819   # Maildir file names in general
 820   s/\b\d+\.H\d+P\d+\b/dddddddddd.HddddddPddddd/;
 821
 822   # Maildirsize data
 823   while (/^\d+S,\d+C\s*$/)
 824     {
 825     print MUNGED;
 826     while (<IN>)
 827       {
 828       last if !/^\d+ \d+\s*$/;
 829       print MUNGED "ddd d\n";
 830       }
 831     last if !defined $_;
 832     }
 833   last if !defined $_;
 834
 835
 836   # ======== Output from the "fd" program about open descriptors ========
 837   # The statuses seem to be different on different operating systems, but
 838   # at least we'll still be checking the number of open fd's.
 839
 840   s/max fd = \d+/max fd = dddd/;
 841   s/status=0 RDONLY/STATUS/g;
 842   s/status=1 WRONLY/STATUS/g;
 843   s/status=2 RDWR/STATUS/g;
 844
 845
 846   # ======== Contents of spool files ========
 847   # A couple of tests dump the contents of the -H file. The length fields
 848   # will be wrong because of different user names, etc.
 849   s/^\d\d\d(?=[PFS*])/ddd/;
 850
 851
 852   # ========= Exim lookups ==================
 853   # Lookups have a char which depends on the number of lookup types compiled in,
 854   # in stderr output.  Replace with a "0".  Recognising this while avoiding
 855   # other output is fragile; perhaps the debug output should be revised instead.
 856   s%(?<!sqlite)(?<!lsearch\*@)(?<!lsearch\*)(?<!lsearch)[0-?]TESTSUITE/aux-fixed/%0TESTSUITE/aux-fixed/%g;
 857
 858   # ==========================================================
 859   # MIME boundaries in RFC3461 DSN messages
 860   s/\d{8,10}-eximdsn-\d+/NNNNNNNNNN-eximdsn-MMMMMMMMMM/;
 861
 862   # ==========================================================
 863   # Some munging is specific to the specific file types
 864
 865   # ======== stdout ========
 866
 867   if ($is_stdout)
 868     {
 869     # Skip translate_ip_address and use_classresources in -bP output because
 870     # they aren't always there.
 871
 872     next if /translate_ip_address =/;
 873     next if /use_classresources/;
 874
 875     # In certain filter tests, remove initial filter lines because they just
 876     # clog up by repetition.
 877
 878     if ($rmfiltertest)
 879       {
 880       next if /^(Sender\staken\sfrom|
 881                  Return-path\scopied\sfrom|
 882                  Sender\s+=|
 883                  Recipient\s+=)/x;
 884       if (/^Testing \S+ filter/)
 885         {
 886         $_ = <IN>;    # remove blank line
 887         next;
 888         }
 889       }
 890
 891     # openssl version variances
 892     next if /^SSL info: unknown state/;
 893     next if /^SSL info: SSLv2\/v3 write client hello A/;
 894     next if /^SSL info: SSLv3 read server key exchange A/;
 895     next if /SSL verify error: depth=0 error=certificate not trusted/;
 896     s/SSL3_READ_BYTES/ssl3_read_bytes/i;
 897
 898     # gnutls version variances
 899     next if /^Error in the pull function./;
 900     }
 901
 902   # ======== stderr ========
 903
 904   elsif ($is_stderr)
 905     {
 906     # The very first line of debugging output will vary
 907
 908     s/^Exim version .*/Exim version x.yz ..../;
 909
 910     # Debugging lines for Exim terminations
 911
 912     s/(?<=^>>>>>>>>>>>>>>>> Exim pid=)\d+(?= terminating)/pppp/;
 913
 914     # IP address lookups use gethostbyname() when IPv6 is not supported,
 915     # and gethostbyname2() or getipnodebyname() when it is.
 916
 917     s/\b(gethostbyname2?|\bgetipnodebyname)(\(af=inet\))?/get[host|ipnode]byname[2]/;
 918
 919     # drop gnutls version strings
 920     next if /GnuTLS compile-time version: \d+[\.\d]+$/;
 921     next if /GnuTLS runtime version: \d+[\.\d]+$/;
 922
 923     # drop openssl version strings
 924     next if /OpenSSL compile-time version: OpenSSL \d+[\.\da-z]+/;
 925     next if /OpenSSL runtime version: OpenSSL \d+[\.\da-z]+/;
 926
 927     # drop lookups
 928     next if /^Lookups \(built-in\):/;
 929     next if /^Loading lookup modules from/;
 930     next if /^Loaded \d+ lookup modules/;
 931     next if /^Total \d+ lookups/;
 932
 933     # drop compiler information
 934     next if /^Compiler:/;
 935
 936     # and the ugly bit
 937     # different libraries will have different numbers (possibly 0) of follow-up
 938     # lines, indenting with more data
 939     if (/^Library version:/) {
 940       while (1) {
 941         $_ = <IN>;
 942         next if /^\s/;
 943         goto RESET_AFTER_EXTRA_LINE_READ;
 944       }
 945     }
 946
 947     # drop other build-time controls emitted for debugging
 948     next if /^WHITELIST_D_MACROS:/;
 949     next if /^TRUSTED_CONFIG_LIST:/;
 950
 951     # As of Exim 4.74, we log when a setgid fails; because we invoke Exim
 952     # with -be, privileges will have been dropped, so this will always
 953     # be the case
 954     next if /^changing group to \d+ failed: (Operation not permitted|Not owner)/;
 955
 956     # We might not keep this check; rather than change all the tests, just
 957     # ignore it as long as it succeeds; then we only need to change the
 958     # TLS tests where tls_require_ciphers has been set.
 959     if (m{^changed uid/gid: calling tls_validate_require_cipher}) {
 960       my $discard = <IN>;
 961       next;
 962     }
 963     next if /^tls_validate_require_cipher child \d+ ended: status=0x0/;
 964
 965     # We invoke Exim with -D, so we hit this new messag as of Exim 4.73:
 966     next if /^macros_trusted overridden to true by whitelisting/;
 967
 968     # We have to omit the localhost ::1 address so that all is well in
 969     # the IPv4-only case.
 970
 971     print MUNGED "MUNGED: ::1 will be omitted in what follows\n"
 972       if (/looked up these IP addresses/);
 973     next if /name=localhost address=::1/;
 974
 975     # drop pdkim debugging header
 976     next if /^PDKIM <<<<<<<<<<<<<<<<<<<<<<<<<<<<<+$/;
 977
 978     # Various other IPv6 lines must be omitted too
 979
 980     next if /using host_fake_gethostbyname for \S+ \(IPv6\)/;
 981     next if /get\[host\|ipnode\]byname\[2\]\(af=inet6\)/;
 982     next if /DNS lookup of \S+ \(AAAA\) using fakens/;
 983     next if / in dns_ipv4_lookup?/;
 984
 985     if (/DNS lookup of \S+ \(AAAA\) gave NO_DATA/)
 986       {
 987       $_= <IN>;     # Gets "returning DNS_NODATA"
 988       next;
 989       }
 990
 991     # Skip tls_advertise_hosts and hosts_require_tls checks when the options
 992     # are unset, because tls ain't always there.
 993
 994     next if /in\s(?:tls_advertise_hosts\?|hosts_require_tls\?)
 995                 \sno\s\((option\sunset|end\sof\slist)\)/x;
 996
 997     # Skip auxiliary group lists because they will vary.
 998
 999     next if /auxiliary group list:/;
1000
1001     # Skip "extracted from gecos field" because the gecos field varies
1002
1003     next if /extracted from gecos field/;
1004
1005     # Skip "waiting for data on socket" and "read response data: size=" lines
1006     # because some systems pack more stuff into packets than others.
1007
1008     next if /waiting for data on socket/;
1009     next if /read response data: size=/;
1010
1011     # If Exim is compiled with readline support but it can't find the library
1012     # to load, there will be an extra debug line. Omit it.
1013
1014     next if /failed to load readline:/;
1015
1016     # Some DBM libraries seem to make DBM files on opening with O_RDWR without
1017     # O_CREAT; other's don't. In the latter case there is some debugging output
1018     # which is not present in the former. Skip the relevant lines (there are
1019     # two of them).
1020
1021     if (/TESTSUITE\/spool\/db\/\S+ appears not to exist: trying to create/)
1022       {
1023       $_ = <IN>;
1024       next;
1025       }
1026
1027     # Some tests turn on +expand debugging to check on expansions.
1028     # Unfortunately, the Received: expansion varies, depending on whether TLS
1029     # is compiled or not. So we must remove the relevant debugging if it is.
1030
1031     if (/^condition: def:tls_cipher/)
1032       {
1033       while (<IN>) { last if /^condition: def:sender_address/; }
1034       }
1035     elsif (/^expanding: Received: /)
1036       {
1037       while (<IN>) { last if !/^\s/; }
1038       }
1039
1040     # remote port numbers vary
1041     s/(Connection request from 127.0.0.1 port) \d{1,5}/$1 sssss/;
1042
1043     # Skip hosts_require_dane checks when the options
1044     # are unset, because dane ain't always there.
1045
1046     next if /in\shosts_require_dane\?\sno\s\(option\sunset\)/x;
1047
1048     # SUPPORT_PROXY
1049     next if /host in hosts_proxy\?/;
1050
1051     # Experimental_International
1052     next if / in smtputf8_advertise_hosts\? no \(option unset\)/;
1053
1054     # Environment cleaning
1055     next if /\w+ in keep_environment\? (yes|no)/;
1056
1057     # Sizes vary with test hostname
1058     s/^cmd buf flush \d+ bytes$/cmd buf flush ddd bytes/;
1059
1060     # Spool filesystem free space changes on different systems.
1061     s/^((?:spool|log) directory space =) -?\d+K (inodes =)\s*-?\d+/$1 nnnnnK $2 nnnnn/;
1062
1063     # Non-TLS builds have different expansions for received_header_text
1064     if (s/(with \$received_protocol)\}\} \$\{if def:tls_cipher \{\(\$tls_cipher\)\n$/$1/)
1065       {
1066       $_ .= <IN>;
1067       s/\s+\}\}(?=\(Exim )/\}\} /;
1068       }
1069     if (/^  condition: def:tls_cipher$/)
1070       {
1071       <IN>; <IN>; <IN>; <IN>; <IN>; <IN>;
1072       <IN>; <IN>; <IN>; <IN>; <IN>; next;
1073       }
1074
1075     # Not all platforms build with DKIM enabled
1076     next if /^PDKIM >> Body data for hash, canonicalized/;
1077
1078     # Not all platforms support TCP Fast Open, and the compile omits the check
1079     if (s/\S+ in hosts_try_fastopen\? no \(option unset\)\n$//)
1080       {
1081       $_ .= <IN>;
1082       s/ \.\.\. >>> / ... /;
1083       s/Network is unreachable/Network Error/;
1084       }
1085
1086     next if /^(ppppp )?setsockopt FASTOPEN: Protocol not available$/;
1087
1088     # When Exim is checking the size of directories for maildir, it uses
1089     # the check_dir_size() function to scan directories. Of course, the order
1090     # of the files that are obtained using readdir() varies from system to
1091     # system. We therefore buffer up debugging lines from check_dir_size()
1092     # and sort them before outputting them.
1093
1094     if (/^check_dir_size:/ || /^skipping TESTSUITE\/test-mail\//)
1095       {
1096       push @saved, $_;
1097       }
1098     else
1099       {
1100       if (@saved > 0)
1101         {
1102         print MUNGED "MUNGED: the check_dir_size lines have been sorted " .
1103           "to ensure consistency\n";
1104         @saved = sort(@saved);
1105         print MUNGED @saved;
1106         @saved = ();
1107         }
1108
1109       # Skip some lines that Exim puts out at the start of debugging output
1110       # because they will be different in different binaries.
1111
1112       print MUNGED
1113         unless (/^Berkeley DB: / ||
1114                 /^Probably (?:Berkeley DB|ndbm|GDBM)/ ||
1115                 /^Authenticators:/ ||
1116                 /^Lookups:/ ||
1117                 /^Support for:/ ||
1118                 /^Routers:/ ||
1119                 /^Transports:/ ||
1120                 /^log selectors =/ ||
1121                 /^cwd=/ ||
1122                 /^Fixed never_users:/ ||
1123                 /^Configure owner:/ ||
1124                 /^Size of off_t:/
1125                 );
1126
1127
1128       }
1129
1130     next;
1131     }
1132
1133   # ======== log ========
1134
1135   elsif ($is_log)
1136     {
1137     # Berkeley DB version differences
1138     next if / Berkeley DB error: /;
1139     }
1140
1141   # ======== All files other than stderr ========
1142
1143   print MUNGED;
1144   }
1145
1146 close(IN);
1147 return $yield;
1148 }
1149
1150
1151
1152
1153 ##################################################
1154 #        Subroutine to interact with caller      #
1155 ##################################################
1156
1157 # Arguments: [0] the prompt string
1158 #            [1] if there is a U in the prompt and $force_update is true
1159 #            [2] if there is a C in the prompt and $force_continue is true
1160 # Returns:   returns the answer
1161
1162 sub interact {
1163   my ($prompt, $have_u, $have_c) = @_;
1164
1165   print $prompt;
1166
1167   if ($have_u) {
1168     print "... update forced\n";
1169     return 'u';
1170   }
1171
1172   if ($have_c) {
1173     print "... continue forced\n";
1174     return 'c';
1175   }
1176
1177   return lc <T>;
1178 }
1179
1180
1181
1182 ##################################################
1183 #    Subroutine to log in force_continue mode    #
1184 ##################################################
1185
1186 # In force_continue mode, we just want a terse output to a statically
1187 # named logfile.  If multiple files in same batch (stdout, stderr, etc)
1188 # all have mismatches, it will log multiple times.
1189 #
1190 # Arguments: [0] the logfile to append to
1191 #            [1] the testno that failed
1192 # Returns:   nothing
1193
1194
1195
1196 sub log_failure {
1197   my ($logfile, $testno, $detail) = @_;
1198
1199   open(my $fh, '>>', $logfile) or return;
1200
1201   print $fh "Test $testno "
1202         . (defined $detail ? "$detail " : '')
1203         . "failed\n";
1204 }
1205
1206
1207
1208 ##################################################
1209 #    Subroutine to compare one output file       #
1210 ##################################################
1211
1212 # When an Exim server is part of the test, its output is in separate files from
1213 # an Exim client. The server data is concatenated with the client data as part
1214 # of the munging operation.
1215 #
1216 # Arguments:  [0] the name of the main raw output file
1217 #             [1] the name of the server raw output file or undef
1218 #             [2] where to put the munged copy
1219 #             [3] the name of the saved file
1220 #             [4] TRUE if this is a log file whose deliveries must be sorted
1221 #             [5] optionally, a custom munge command
1222 #
1223 # Returns:    0 comparison succeeded or differences to be ignored
1224 #             1 comparison failed; files may have been updated (=> re-compare)
1225 #
1226 # Does not return if the user replies "Q" to a prompt.
1227
1228 sub check_file{
1229 my($rf,$rsf,$mf,$sf,$sortfile,$extra) = @_;
1230
1231 # If there is no saved file, the raw files must either not exist, or be
1232 # empty. The test ! -s is TRUE if the file does not exist or is empty.
1233
1234 # we check if there is a flavour specific file, but we remember
1235 # the original file name as "generic"
1236 $sf_generic = $sf;
1237 $sf_flavour = "$sf_generic.$flavour";
1238 $sf_current = -e $sf_flavour ? $sf_flavour : $sf_generic;
1239
1240 if (! -e $sf_current)
1241   {
1242   return 0 if (! -s $rf && (! defined $rsf || ! -s $rsf));
1243
1244   print "\n";
1245   print "** $rf is not empty\n" if (-s $rf);
1246   print "** $rsf is not empty\n" if (defined $rsf && -s $rsf);
1247
1248   for (;;)
1249     {
1250     $_ = interact('Continue, Show, or Quit? [Q] ', undef, $force_continue);
1251     tests_exit(1) if /^q?$/;
1252     log_failure($log_failed_filename, $testno, $rf) if (/^c$/ && $force_continue);
1253     return 0 if /^c$/i;
1254     last if (/^s$/);
1255     }
1256
1257   foreach $f ($rf, $rsf)
1258     {
1259     if (defined $f && -s $f)
1260       {
1261       print "\n";
1262       print "------------ $f -----------\n"
1263         if (defined $rf && -s $rf && defined $rsf && -s $rsf);
1264       system("$more '$f'");
1265       }
1266     }
1267
1268   print "\n";
1269   for (;;)
1270     {
1271     $_ = interact('Continue, Update & retry, Quit? [Q] ', $force_update, $force_continue);
1272     tests_exit(1) if /^q?$/;
1273     log_failure($log_failed_filename, $testno, $rsf) if (/^c$/ && $force_continue);
1274     return 0 if /^c$/i;
1275     last if (/^u$/i);
1276     }
1277   }
1278
1279 #### $_
1280
1281 # Control reaches here if either (a) there is a saved file ($sf), or (b) there
1282 # was a request to create a saved file. First, create the munged file from any
1283 # data that does exist.
1284
1285 open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1286 my($truncated) = munge($rf, $extra) if -e $rf;
1287
1288 # Append the raw server log, if it is non-empty
1289 if (defined $rsf && -e $rsf)
1290   {
1291   print MUNGED "\n******** SERVER ********\n";
1292   $truncated |= munge($rsf, $extra);
1293   }
1294 close(MUNGED);
1295
1296 # If a saved file exists, do the comparison. There are two awkward cases:
1297 #
1298 # If "*** truncated ***" was found in the new file, it means that a log line
1299 # was overlong, and truncated. The problem is that it may be truncated at
1300 # different points on different systems, because of different user name
1301 # lengths. We reload the file and the saved file, and remove lines from the new
1302 # file that precede "*** truncated ***" until we reach one that matches the
1303 # line that precedes it in the saved file.
1304 #
1305 # If $sortfile is set, we are dealing with a mainlog file where the deliveries
1306 # for an individual message might vary in their order from system to system, as
1307 # a result of parallel deliveries. We load the munged file and sort sequences
1308 # of delivery lines.
1309
1310 if (-e $sf_current)
1311   {
1312   # Deal with truncated text items
1313
1314   if ($truncated)
1315     {
1316     my(@munged, @saved, $i, $j, $k);
1317
1318     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1319     @munged = <MUNGED>;
1320     close(MUNGED);
1321     open(SAVED, $sf_current) || tests_exit(-1, "Failed to open $sf_current: $!");
1322     @saved = <SAVED>;
1323     close(SAVED);
1324
1325     $j = 0;
1326     for ($i = 0; $i < @munged; $i++)
1327       {
1328       if ($munged[$i] =~ /\*\*\* truncated \*\*\*/)
1329         {
1330         for (; $j < @saved; $j++)
1331           { last if $saved[$j] =~ /\*\*\* truncated \*\*\*/; }
1332         last if $j >= @saved;     # not found in saved
1333
1334         for ($k = $i - 1; $k >= 0; $k--)
1335           { last if $munged[$k] eq $saved[$j - 1]; }
1336
1337         last if $k <= 0;          # failed to find previous match
1338         splice @munged, $k + 1, $i - $k - 1;
1339         $i = $k + 1;
1340         }
1341       }
1342
1343     open(MUNGED, '>', $mf) || tests_exit(-1, "Failed to open $mf: $!");
1344     for ($i = 0; $i < @munged; $i++)
1345       { print MUNGED $munged[$i]; }
1346     close(MUNGED);
1347     }
1348
1349   # Deal with log sorting
1350
1351   if ($sortfile)
1352     {
1353     my(@munged, $i, $j);
1354
1355     open(MUNGED, $mf) || tests_exit(-1, "Failed to open $mf: $!");
1356     @munged = <MUNGED>;
1357     close(MUNGED);
1358
1359     for ($i = 0; $i < @munged; $i++)
1360       {
1361       if ($munged[$i] =~ /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/)
1362         {
1363         for ($j = $i + 1; $j < @munged; $j++)
1364           {
1365           last if $munged[$j] !~
1366             /^[-\d]{10}\s[:\d]{8}\s[-A-Za-z\d]{16}\s[-=*]>/;
1367           }
1368         @temp = splice(@munged, $i, $j - $i);
1369         @temp = sort(@temp);
1370         splice(@munged, $i, 0, @temp);
1371         }
1372       }
1373
1374     open(MUNGED, ">$mf") || tests_exit(-1, "Failed to open $mf: $!");
1375     print MUNGED "**NOTE: The delivery lines in this file have been sorted.\n";
1376     for ($i = 0; $i < @munged; $i++)
1377       { print MUNGED $munged[$i]; }
1378     close(MUNGED);
1379     }
1380
1381   # Do the comparison
1382
1383   return 0 if (system("$cf '$mf' '$sf_current' >test-cf") == 0);
1384
1385   # Handle comparison failure
1386
1387   print "** Comparison of $mf with $sf_current failed";
1388   system("$more test-cf");
1389
1390   print "\n";
1391   for (;;)
1392     {
1393     $_ = interact('Continue, Retry, Update current'
1394         . ($sf_current ne $sf_flavour  ? "/Save for flavour '$flavour'" : '')
1395         . ' & retry, Quit? [Q] ', $force_update, $force_continue);
1396     tests_exit(1) if /^q?$/;
1397     log_failure($log_failed_filename, $testno, $sf_current) if (/^c$/i && $force_continue);
1398     return 0 if /^c$/i;
1399     return 1 if /^r$/i;
1400     last if (/^[us]$/i);
1401     }
1402   }
1403
1404 # Update or delete the saved file, and give the appropriate return code.
1405
1406 if (-s $mf)
1407   {
1408         my $sf = /^u/i ? $sf_current : $sf_flavour;
1409                 tests_exit(-1, "Failed to cp $mf $sf") if system("cp '$mf' '$sf'") != 0;
1410   }
1411 else
1412   {
1413         # if we deal with a flavour file, we can't delete it, because next time the generic
1414         # file would be used again
1415         if ($sf_current eq $sf_flavour) {
1416                 open(FOO, ">$sf_current");
1417                 close(FOO);
1418         }
1419         else {
1420                 tests_exit(-1, "Failed to unlink $sf_current") if !unlink($sf_current);
1421         }
1422   }
1423
1424 return 1;
1425 }
1426
1427
1428
1429 ##################################################
1430 # Custom munges
1431 # keyed by name of munge; value is a ref to a hash
1432 # which is keyed by file, value a string to look for.
1433 # Usable files are:
1434 #  paniclog, rejectlog, mainlog, stdout, stderr, msglog, mail
1435 # Search strings starting with 's' do substitutions;
1436 # with '/' do line-skips.
1437 # Triggered by a scriptfile line "munge <name>"
1438 ##################################################
1439 $munges =
1440   { 'dnssec' =>
1441     { 'stderr' => '/^Reverse DNS security status: unverified\n/' },
1442
1443     'gnutls_unexpected' =>
1444     { 'mainlog' => '/\(recv\): A TLS packet with unexpected length was received./' },
1445
1446     'gnutls_handshake' =>
1447     { 'mainlog' => 's/\(gnutls_handshake\): Error in the push function/\(gnutls_handshake\): A TLS packet with unexpected length was received/' },
1448
1449     'optional_events' =>
1450     { 'stdout' => '/event_action =/' },
1451
1452     'optional_ocsp' =>
1453     { 'stderr' => '/127.0.0.1 in hosts_requ(ire|est)_ocsp/' },
1454
1455     'optional_cert_hostnames' =>
1456     { 'stderr' => '/in tls_verify_cert_hostnames\? no/' },
1457
1458     'loopback' =>
1459     { 'stdout' => 's/[[](127\.0\.0\.1|::1)]/[IP_LOOPBACK_ADDR]/' },
1460
1461     'scanfile_size' =>
1462     { 'stdout' => 's/(Content-length:) \d\d\d/$1 ddd/' },
1463
1464     'delay_1500' =>
1465     { 'stderr' => 's/(1[5-9]|23\d)\d\d msec/ssss msec/' },
1466
1467     'tls_anycipher' =>
1468     { 'mainlog' => 's/ X=TLS\S+ / X=TLS_proto_and_cipher /' },
1469
1470     'debug_pid' =>
1471     { 'stderr' => 's/(^\s{0,4}|(?<=Process )|(?<=child ))\d{1,5}/ppppp/g' },
1472
1473     'optional_dsn_info' =>
1474     { 'mail' => '/^(X-(Remote-MTA-(smtp-greeting|helo-response)|Exim-Diagnostic|(body|message)-linecount):|Remote-MTA: X-ip;)/'
1475     },
1476
1477     'optional_config' =>
1478     { 'stdout' => '/^(
1479                   dkim_(canon|domain|private_key|selector|sign_headers|strict)
1480                   |gnutls_require_(kx|mac|protocols)
1481                   |hosts_(requ(est|ire)|try)_(dane|ocsp)
1482                   |hosts_(avoid|nopass|require|verify_avoid)_tls
1483                   |socks_proxy
1484                   |tls_[^ ]*
1485                   )($|[ ]=)/x' },
1486
1487     'sys_bindir' =>
1488     { 'mainlog' => 's%/(usr/)?bin/%SYSBINDIR/%' },
1489
1490     'sync_check_data' =>
1491     { 'mainlog'   => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/',
1492       'rejectlog' => 's/^(.* SMTP protocol synchronization error .* next input=.{8}).*$/$1<suppressed>/'},
1493
1494     'debuglog_stdout' =>
1495     { 'stdout' => 's/^\d\d:\d\d:\d\d\s+\d+ //;
1496                   s/Process \d+ is ready for new message/Process pppp is ready for new message/'
1497     },
1498
1499     'timeout_errno' =>          # actual errno differs Solaris vs. Linux
1500     { 'mainlog' => 's/(host deferral .* errno) <\d+> /$1 <EEE> /' },
1501   };
1502
1503
1504 ##################################################
1505 #    Subroutine to check the output of a test    #
1506 ##################################################
1507
1508 # This function is called when the series of subtests is complete. It makes
1509 # use of check_file(), whose arguments are:
1510 #
1511 #  [0] the name of the main raw output file
1512 #  [1] the name of the server raw output file or undef
1513 #  [2] where to put the munged copy
1514 #  [3] the name of the saved file
1515 #  [4] TRUE if this is a log file whose deliveries must be sorted
1516 #  [5] an optional custom munge command
1517 #
1518 # Arguments: Optionally, name of a single custom munge to run.
1519 # Returns:   0 if the output compared equal
1520 #            1 if re-run needed (files may have been updated)
1521
1522 sub check_output{
1523 my($mungename) = $_[0];
1524 my($yield) = 0;
1525 my($munge) = $munges->{$mungename} if defined $mungename;
1526
1527 $yield = 1 if check_file("spool/log/paniclog",
1528                        "spool/log/serverpaniclog",
1529                        "test-paniclog-munged",
1530                        "paniclog/$testno", 0,
1531                        $munge->{paniclog});
1532
1533 $yield = 1 if check_file("spool/log/rejectlog",
1534                        "spool/log/serverrejectlog",
1535                        "test-rejectlog-munged",
1536                        "rejectlog/$testno", 0,
1537                        $munge->{rejectlog});
1538
1539 $yield = 1 if check_file("spool/log/mainlog",
1540                        "spool/log/servermainlog",
1541                        "test-mainlog-munged",
1542                        "log/$testno", $sortlog,
1543                        $munge->{mainlog});
1544
1545 if (!$stdout_skip)
1546   {
1547   $yield = 1 if check_file("test-stdout",
1548                        "test-stdout-server",
1549                        "test-stdout-munged",
1550                        "stdout/$testno", 0,
1551                        $munge->{stdout});
1552   }
1553
1554 if (!$stderr_skip)
1555   {
1556   $yield = 1 if check_file("test-stderr",
1557                        "test-stderr-server",
1558                        "test-stderr-munged",
1559                        "stderr/$testno", 0,
1560                        $munge->{stderr});
1561   }
1562
1563 # Compare any delivered messages, unless this test is skipped.
1564
1565 if (! $message_skip)
1566   {
1567   my($msgno) = 0;
1568
1569   # Get a list of expected mailbox files for this script. We don't bother with
1570   # directories, just the files within them.
1571
1572   foreach $oldmail (@oldmails)
1573     {
1574     next unless $oldmail =~ /^mail\/$testno\./;
1575     print ">> EXPECT $oldmail\n" if $debug;
1576     $expected_mails{$oldmail} = 1;
1577     }
1578
1579   # If there are any files in test-mail, compare them. Note that "." and
1580   # ".." are automatically omitted by list_files_below().
1581
1582   @mails = list_files_below("test-mail");
1583
1584   foreach $mail (@mails)
1585     {
1586     next if $mail eq "test-mail/oncelog";
1587
1588     $saved_mail = substr($mail, 10);               # Remove "test-mail/"
1589     $saved_mail =~ s/^$parm_caller(\/|$)/CALLER/;  # Convert caller name
1590
1591     if ($saved_mail =~ /(\d+\.[^.]+\.)/)
1592       {
1593       $msgno++;
1594       $saved_mail =~ s/(\d+\.[^.]+\.)/$msgno./gx;
1595       }
1596
1597     print ">> COMPARE $mail mail/$testno.$saved_mail\n" if $debug;
1598     $yield = 1 if check_file($mail, undef, "test-mail-munged",
1599       "mail/$testno.$saved_mail", 0,
1600       $munge->{mail});
1601     delete $expected_mails{"mail/$testno.$saved_mail"};
1602     }
1603
1604   # Complain if not all expected mails have been found
1605
1606   if (scalar(keys %expected_mails) != 0)
1607     {
1608     foreach $key (keys %expected_mails)
1609       { print "** no test file found for $key\n"; }
1610
1611     for (;;)
1612       {
1613       $_ = interact('Continue, Update & retry, or Quit? [Q] ', $force_update, $force_continue);
1614       tests_exit(1) if /^q?$/;
1615       log_failure($log_failed_filename, $testno, "missing email") if (/^c$/ && $force_continue);
1616       last if /^c$/;
1617
1618       # For update, we not only have to unlink the file, but we must also
1619       # remove it from the @oldmails vector, as otherwise it will still be
1620       # checked for when we re-run the test.
1621
1622       if (/^u$/)
1623         {
1624         foreach $key (keys %expected_mails)
1625           {
1626           my($i);
1627           tests_exit(-1, "Failed to unlink $key") if !unlink("$key");
1628           for ($i = 0; $i < @oldmails; $i++)
1629             {
1630             if ($oldmails[$i] eq $key)
1631               {
1632               splice @oldmails, $i, 1;
1633               last;
1634               }
1635             }
1636           }
1637         last;
1638         }
1639       }
1640     }
1641   }
1642
1643 # Compare any remaining message logs, unless this test is skipped.
1644
1645 if (! $msglog_skip)
1646   {
1647   # Get a list of expected msglog files for this test
1648
1649   foreach $oldmsglog (@oldmsglogs)
1650     {
1651     next unless $oldmsglog =~ /^$testno\./;
1652     $expected_msglogs{$oldmsglog} = 1;
1653     }
1654
1655   # If there are any files in spool/msglog, compare them. However, we have
1656   # to munge the file names because they are message ids, which are
1657   # time dependent.
1658
1659   if (opendir(DIR, "spool/msglog"))
1660     {
1661     @msglogs = sort readdir(DIR);
1662     closedir(DIR);
1663
1664     foreach $msglog (@msglogs)
1665       {
1666       next if ($msglog eq "." || $msglog eq ".." || $msglog eq "CVS");
1667       ($munged_msglog = $msglog) =~
1668         s/((?:[^\W_]{6}-){2}[^\W_]{2})
1669           /new_value($1, "10Hm%s-0005vi-00", \$next_msgid)/egx;
1670       $yield = 1 if check_file("spool/msglog/$msglog", undef,
1671         "test-msglog-munged", "msglog/$testno.$munged_msglog", 0,
1672         $munge->{msglog});
1673       delete $expected_msglogs{"$testno.$munged_msglog"};
1674       }
1675     }
1676
1677   # Complain if not all expected msglogs have been found
1678
1679   if (scalar(keys %expected_msglogs) != 0)
1680     {
1681     foreach $key (keys %expected_msglogs)
1682       {
1683       print "** no test msglog found for msglog/$key\n";
1684       ($msgid) = $key =~ /^\d+\.(.*)$/;
1685       foreach $cachekey (keys %cache)
1686         {
1687         if ($cache{$cachekey} eq $msgid)
1688           {
1689           print "** original msgid $cachekey\n";
1690           last;
1691           }
1692         }
1693       }
1694
1695     for (;;)
1696       {
1697       $_ = interact('Continue, Update, or Quit? [Q] ', $force_update, $force_continue);
1698       tests_exit(1) if /^q?$/;
1699       log_failure($log_failed_filename, $testno, "missing msglog") if (/^c$/ && $force_continue);
1700       last if /^c$/;
1701       if (/^u$/)
1702         {
1703         foreach $key (keys %expected_msglogs)
1704           {
1705           tests_exit(-1, "Failed to unlink msglog/$key")
1706             if !unlink("msglog/$key");
1707           }
1708         last;
1709         }
1710       }
1711     }
1712   }
1713
1714 return $yield;
1715 }
1716
1717
1718
1719 ##################################################
1720 #     Subroutine to run one "system" command     #
1721 ##################################################
1722
1723 # We put this in a subroutine so that the command can be reflected when
1724 # debugging.
1725 #
1726 # Argument: the command to be run
1727 # Returns:  nothing
1728
1729 sub run_system {
1730 my($cmd) = $_[0];
1731 if ($debug)
1732   {
1733   my($prcmd) = $cmd;
1734   $prcmd =~ s/; /;\n>> /;
1735   print ">> $prcmd\n";
1736   }
1737 system("$cmd");
1738 }
1739
1740
1741
1742 ##################################################
1743 #      Subroutine to run one script command      #
1744 ##################################################
1745
1746 # The <SCRIPT> file is open for us to read an optional return code line,
1747 # followed by the command line and any following data lines for stdin. The
1748 # command line can be continued by the use of \. Data lines are not continued
1749 # in this way. In all lines, the following substutions are made:
1750 #
1751 # DIR    => the current directory
1752 # CALLER => the caller of this script
1753 #
1754 # Arguments: the current test number
1755 #            reference to the subtest number, holding previous value
1756 #            reference to the expected return code value
1757 #            reference to where to put the command name (for messages)
1758 #            auxilliary information returned from a previous run
1759 #
1760 # Returns:   0 the commmand was executed inline, no subprocess was run
1761 #            1 a non-exim command was run and waited for
1762 #            2 an exim command was run and waited for
1763 #            3 a command was run and not waited for (daemon, server, exim_lock)
1764 #            4 EOF was encountered after an initial return code line
1765 # Optionally alse a second parameter, a hash-ref, with auxilliary information:
1766 #            exim_pid: pid of a run process
1767 #            munge: name of a post-script results munger
1768
1769 sub run_command{
1770 my($testno) = $_[0];
1771 my($subtestref) = $_[1];
1772 my($commandnameref) = $_[3];
1773 my($aux_info) = $_[4];
1774 my($yield) = 1;
1775
1776 our %ENV = map { $_ => $ENV{$_} } grep { /^(?:USER|SHELL|PATH|TERM|EXIM_TEST_.*)$/ } keys %ENV;
1777
1778 if (/^(\d+)\s*$/)                # Handle unusual return code
1779   {
1780   my($r) = $_[2];
1781   $$r = $1 << 8;
1782   $_ = <SCRIPT>;
1783   return 4 if !defined $_;       # Missing command
1784   $lineno++;
1785   }
1786
1787 chomp;
1788 $wait_time = 0;
1789
1790 # Handle concatenated command lines
1791
1792 s/\s+$//;
1793 while (substr($_, -1) eq"\\")
1794   {
1795   my($temp);
1796   $_ = substr($_, 0, -1);
1797   chomp($temp = <SCRIPT>);
1798   if (defined $temp)
1799     {
1800     $lineno++;
1801     $temp =~ s/\s+$//;
1802     $temp =~ s/^\s+//;
1803     $_ .= $temp;
1804     }
1805   }
1806
1807 # Do substitutions
1808
1809 do_substitute($testno);
1810 if ($debug) { printf ">> $_\n"; }
1811
1812 # Pass back the command name (for messages)
1813
1814 ($$commandnameref) = /^(\S+)/;
1815
1816 # Here follows code for handling the various different commands that are
1817 # supported by this script. The first group of commands are all freestanding
1818 # in that they share no common code and are not followed by any data lines.
1819
1820
1821 ###################
1822 ###################
1823
1824 # The "dbmbuild" command runs exim_dbmbuild. This is used both to test the
1825 # utility and to make DBM files for testing DBM lookups.
1826
1827 if (/^dbmbuild\s+(\S+)\s+(\S+)/)
1828   {
1829   run_system("(./eximdir/exim_dbmbuild $parm_cwd/$1 $parm_cwd/$2;" .
1830          "echo exim_dbmbuild exit code = \$?)" .
1831          ">>test-stdout");
1832   return 1;
1833   }
1834
1835
1836 # The "dump" command runs exim_dumpdb. On different systems, the output for
1837 # some types of dump may appear in a different order because it's just hauled
1838 # out of the DBM file. We can solve this by sorting. Ignore the leading
1839 # date/time, as it will be flattened later during munging.
1840
1841 if (/^dump\s+(\S+)/)
1842   {
1843   my($which) = $1;
1844   my(@temp);
1845   print ">> ./eximdir/exim_dumpdb $parm_cwd/spool $which\n" if $debug;
1846   open(IN, "./eximdir/exim_dumpdb $parm_cwd/spool $which |");
1847   open(OUT, ">>test-stdout");
1848   print OUT "+++++++++++++++++++++++++++\n";
1849
1850   if ($which eq "retry")
1851     {
1852     $/ = "\n  ";
1853     @temp = <IN>;
1854     $/ = "\n";
1855
1856     @temp = sort {
1857                    my($aa) = split(' ', $a);
1858                    my($bb) = split(' ', $b);
1859                    return $aa cmp $bb;
1860                  } @temp;
1861
1862     foreach $item (@temp)
1863       {
1864       $item =~ s/^\s*(.*)\n(.*)\n?\s*$/$1\n$2/m;
1865       print OUT "  $item\n";
1866       }
1867     }
1868   else
1869     {
1870     @temp = <IN>;
1871     if ($which eq "callout")
1872       {
1873       @temp = sort {
1874                    my($aa) = substr $a, 21;
1875                    my($bb) = substr $b, 21;
1876                    return $aa cmp $bb;
1877                    } @temp;
1878       }
1879     print OUT @temp;
1880     }
1881
1882   close(IN);
1883   close(OUT);
1884   return 1;
1885   }
1886
1887
1888 # verbose comments start with ###
1889 if (/^###\s/) {
1890   for my $file (qw(test-stdout test-stderr test-stderr-server test-stdout-server)) {
1891     open my $fh, '>>', $file or die "Can't open >>$file: $!\n";
1892     say {$fh} $_;
1893   }
1894   return 0;
1895 }
1896
1897 # The "echo" command is a way of writing comments to the screen.
1898 if (/^echo\s+(.*)$/)
1899   {
1900   print "$1\n";
1901   return 0;
1902   }
1903
1904
1905 # The "exim_lock" command runs exim_lock in the same manner as "server",
1906 # but it doesn't use any input.
1907
1908 if (/^exim_lock\s+(.*)$/)
1909   {
1910   $cmd = "./eximdir/exim_lock $1 >>test-stdout";
1911   $server_pid = open SERVERCMD, "|$cmd" ||
1912     tests_exit(-1, "Failed to run $cmd\n");
1913
1914   # This gives the process time to get started; otherwise the next
1915   # process may not find it there when it expects it.
1916
1917   select(undef, undef, undef, 0.1);
1918   return 3;
1919   }
1920
1921
1922 # The "exinext" command runs exinext
1923
1924 if (/^exinext\s+(.*)/)
1925   {
1926   run_system("(./eximdir/exinext " .
1927     "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
1928     "-C $parm_cwd/test-config $1;" .
1929     "echo exinext exit code = \$?)" .
1930     ">>test-stdout");
1931   return 1;
1932   }
1933
1934
1935 # The "exigrep" command runs exigrep on the current mainlog
1936
1937 if (/^exigrep\s+(.*)/)
1938   {
1939   run_system("(./eximdir/exigrep " .
1940     "$1 $parm_cwd/spool/log/mainlog;" .
1941     "echo exigrep exit code = \$?)" .
1942     ">>test-stdout");
1943   return 1;
1944   }
1945
1946
1947 # The "eximstats" command runs eximstats on the current mainlog
1948
1949 if (/^eximstats\s+(.*)/)
1950   {
1951   run_system("(./eximdir/eximstats " .
1952     "$1 $parm_cwd/spool/log/mainlog;" .
1953     "echo eximstats exit code = \$?)" .
1954     ">>test-stdout");
1955   return 1;
1956   }
1957
1958
1959 # The "gnutls" command makes a copy of saved GnuTLS parameter data in the
1960 # spool directory, to save Exim from re-creating it each time.
1961
1962 if (/^gnutls/)
1963   {
1964   my $gen_fn = "spool/gnutls-params-$gnutls_dh_bits_normal";
1965   run_system "sudo cp -p aux-fixed/gnutls-params $gen_fn;" .
1966          "sudo chown $parm_eximuser:$parm_eximgroup $gen_fn;" .
1967          "sudo chmod 0400 $gen_fn";
1968   return 1;
1969   }
1970
1971
1972 # The "killdaemon" command should ultimately follow the starting of any Exim
1973 # daemon with the -bd option. We kill with SIGINT rather than SIGTERM to stop
1974 # it outputting "Terminated" to the terminal when not in the background.
1975
1976 if (/^killdaemon/)
1977   {
1978   my $return_extra = {};
1979   if (exists $aux_info->{exim_pid})
1980     {
1981     $pid = $aux_info->{exim_pid};
1982     $return_extra->{exim_pid} = undef;
1983     print ">> killdaemon: recovered pid $pid\n" if $debug;
1984     if ($pid)
1985       {
1986       run_system("sudo /bin/kill -INT $pid");
1987       wait;
1988       }
1989     } else {
1990     $pid = `cat $parm_cwd/spool/exim-daemon.*`;
1991     if ($pid)
1992       {
1993       run_system("sudo /bin/kill -INT $pid");
1994       close DAEMONCMD;                                   # Waits for process
1995       }
1996     }
1997     run_system("sudo /bin/rm -f spool/exim-daemon.*");
1998   return (1, $return_extra);
1999   }
2000
2001
2002 # The "millisleep" command is like "sleep" except that its argument is in
2003 # milliseconds, thus allowing for a subsecond sleep, which is, in fact, all it
2004 # is used for.
2005
2006 elsif (/^millisleep\s+(.*)$/)
2007   {
2008   select(undef, undef, undef, $1/1000);
2009   return 0;
2010   }
2011
2012
2013 # The "munge" command selects one of a hardwired set of test-result modifications
2014 # to be made before result compares are run agains the golden set.  This lets
2015 # us account for test-system dependent things which only affect a few, but known,
2016 # test-cases.
2017 # Currently only the last munge takes effect.
2018
2019 if (/^munge\s+(.*)$/)
2020   {
2021   return (0, { munge => $1 });
2022   }
2023
2024
2025 # The "sleep" command does just that. For sleeps longer than 1 second we
2026 # tell the user what's going on.
2027
2028 if (/^sleep\s+(.*)$/)
2029   {
2030   if ($1 == 1)
2031     {
2032     sleep(1);
2033     }
2034   else
2035     {
2036     printf("  Test %d sleep $1 ", $$subtestref);
2037     for (1..$1)
2038       {
2039       print ".";
2040       sleep(1);
2041       }
2042     printf("\r  Test %d                            $cr", $$subtestref);
2043     }
2044   return 0;
2045   }
2046
2047
2048 # Various Unix management commands are recognized
2049
2050 if (/^(ln|ls|du|mkdir|mkfifo|touch|cp|cat)\s/ ||
2051     /^sudo\s(rmdir|rm|mv|chown|chmod)\s/)
2052   {
2053   run_system("$_ >>test-stdout 2>>test-stderr");
2054   return 1;
2055   }
2056
2057
2058
2059 ###################
2060 ###################
2061
2062 # The next group of commands are also freestanding, but they are all followed
2063 # by data lines.
2064
2065
2066 # The "server" command starts up a script-driven server that runs in parallel
2067 # with the following exim command. Therefore, we want to run a subprocess and
2068 # not yet wait for it to complete. The waiting happens after the next exim
2069 # command, triggered by $server_pid being non-zero. The server sends its output
2070 # to a different file. The variable $server_opts, if not empty, contains
2071 # options to disable IPv4 or IPv6 if necessary.
2072 # This works because "server" swallows its stdin before waiting for a connection.
2073
2074 if (/^server\s+(.*)$/)
2075   {
2076   $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2077   $cmd = "./bin/server $server_opts -oP $pidfile $1 >>test-stdout-server";
2078   print ">> $cmd\n" if ($debug);
2079   $server_pid = open SERVERCMD, "|$cmd" || tests_exit(-1, "Failed to run $cmd");
2080   SERVERCMD->autoflush(1);
2081   print ">> Server pid is $server_pid\n" if $debug;
2082   while (<SCRIPT>)
2083     {
2084     $lineno++;
2085     last if /^\*{4}\s*$/;
2086     print SERVERCMD;
2087     }
2088   print SERVERCMD "++++\n"; # Send end to server; can't send EOF yet
2089                             # because close() waits for the process.
2090
2091   # Interlock the server startup; otherwise the next
2092   # process may not find it there when it expects it.
2093   while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2094   return 3;
2095   }
2096
2097
2098 # The "write" command is a way of creating files of specific sizes for
2099 # buffering tests, or containing specific data lines from within the script
2100 # (rather than hold lots of little files). The "catwrite" command does the
2101 # same, but it also copies the lines to test-stdout.
2102
2103 if (/^(cat)?write\s+(\S+)(?:\s+(.*))?\s*$/)
2104   {
2105   my($cat) = defined $1;
2106   @sizes = ();
2107   @sizes = split /\s+/, $3 if defined $3;
2108   open FILE, ">$2" || tests_exit(-1, "Failed to open \"$2\": $!");
2109
2110   if ($cat)
2111     {
2112     open CAT, ">>test-stdout" ||
2113       tests_exit(-1, "Failed to open test-stdout: $!");
2114     print CAT "==========\n";
2115     }
2116
2117   if (scalar @sizes > 0)
2118     {
2119     # Pre-data
2120
2121     while (<SCRIPT>)
2122       {
2123       $lineno++;
2124       last if /^\+{4}\s*$/;
2125       print FILE;
2126       print CAT if $cat;
2127       }
2128
2129     # Sized data
2130
2131     while (scalar @sizes > 0)
2132       {
2133       ($count,$len,$leadin) = (shift @sizes) =~ /(\d+)x(\d+)(?:=(.*))?/;
2134       $leadin = '' if !defined $leadin;
2135       $leadin =~ s/_/ /g;
2136       $len -= length($leadin) + 1;
2137       while ($count-- > 0)
2138         {
2139         print FILE $leadin, "a" x $len, "\n";
2140         print CAT $leadin, "a" x $len, "\n" if $cat;
2141         }
2142       }
2143     }
2144
2145   # Post data, or only data if no sized data
2146
2147   while (<SCRIPT>)
2148     {
2149     $lineno++;
2150     last if /^\*{4}\s*$/;
2151     print FILE;
2152     print CAT if $cat;
2153     }
2154   close FILE;
2155
2156   if ($cat)
2157     {
2158     print CAT "==========\n";
2159     close CAT;
2160     }
2161
2162   return 0;
2163   }
2164
2165
2166 ###################
2167 ###################
2168
2169 # From this point on, script commands are implemented by setting up a shell
2170 # command in the variable $cmd. Shared code to run this command and handle its
2171 # input and output follows.
2172
2173 # The "client", "client-gnutls", and "client-ssl" commands run a script-driven
2174 # program that plays the part of an email client. We also have the availability
2175 # of running Perl for doing one-off special things. Note that all these
2176 # commands expect stdin data to be supplied.
2177
2178 if (/^client/ || /^(sudo\s+)?perl\b/)
2179   {
2180   s"client"./bin/client";
2181   $cmd = "$_ >>test-stdout 2>>test-stderr";
2182   }
2183
2184 # For the "exim" command, replace the text "exim" with the path for the test
2185 # binary, plus -D options to pass over various parameters, and a -C option for
2186 # the testing configuration file. When running in the test harness, Exim does
2187 # not drop privilege when -C and -D options are present. To run the exim
2188 # command as root, we use sudo.
2189
2190 elsif (/^((?i:[A-Z\d_]+=\S+\s+)+)?(\d+)?\s*(sudo(?:\s+-u\s+(\w+))?\s+)?exim(_\S+)?\s+(.*)$/)
2191   {
2192   $args = $6;
2193   my($envset) = (defined $1)? $1      : '';
2194   my($sudo)   = (defined $3)? "sudo " . (defined $4 ? "-u $4 ":'')  : '';
2195   my($special)= (defined $5)? $5      : '';
2196   $wait_time  = (defined $2)? $2      : 0;
2197
2198   # Return 2 rather than 1 afterwards
2199
2200   $yield = 2;
2201
2202   # Update the test number
2203
2204   $$subtestref = $$subtestref + 1;
2205   printf("  Test %d       $cr", $$subtestref);
2206
2207   # Copy the configuration file, making the usual substitutions.
2208
2209   open (IN, "$parm_cwd/confs/$testno") ||
2210     tests_exit(-1, "Couldn't open $parm_cwd/confs/$testno: $!\n");
2211   open (OUT, ">test-config") ||
2212     tests_exit(-1, "Couldn't open test-config: $!\n");
2213   while (<IN>)
2214     {
2215     do_substitute($testno);
2216     print OUT;
2217     }
2218   close(IN);
2219   close(OUT);
2220
2221   # The string $msg1 in args substitutes the message id of the first
2222   # message on the queue, and so on. */
2223
2224   if ($args =~ /\$msg/)
2225     {
2226     my($listcmd) = "$parm_cwd/eximdir/exim -bp " .
2227                    "-DEXIM_PATH=$parm_cwd/eximdir/exim " .
2228                    "-C $parm_cwd/test-config |";
2229     print ">> Getting queue list from:\n>>    $listcmd\n" if ($debug);
2230     open (QLIST, $listcmd) || tests_exit(-1, "Couldn't run \"exim -bp\": $!\n");
2231     my(@msglist) = ();
2232     while (<QLIST>) { push (@msglist, $1) if /^\s*\d+[smhdw]\s+\S+\s+(\S+)/; }
2233     close(QLIST);
2234
2235     # Done backwards just in case there are more than 9
2236
2237     for (my $i = @msglist; $i > 0; $i--) { $args =~ s/\$msg$i/$msglist[$i-1]/g; }
2238     if ( $args =~ /\$msg\d/ )
2239       {
2240       tests_exit(-1, "Not enough messages in spool, for test $testno line $lineno\n")
2241         unless $force_continue;
2242       }
2243     }
2244
2245   # If -d is specified in $optargs, remove it from $args; i.e. let
2246   # the command line for runtest override. Then run Exim.
2247
2248   $args =~ s/(?:^|\s)-d\S*// if $optargs =~ /(?:^|\s)-d/;
2249
2250   my $opt_valgrind = $valgrind ? "valgrind --leak-check=yes --suppressions=$parm_cwd/aux-fixed/valgrind.supp " : '';
2251
2252   $cmd = "$envset$sudo$opt_valgrind" .
2253          "$parm_cwd/eximdir/exim$special$optargs " .
2254          "-DEXIM_PATH=$parm_cwd/eximdir/exim$special " .
2255          "-C $parm_cwd/test-config $args " .
2256          ">>test-stdout 2>>test-stderr";
2257   # If the command is starting an Exim daemon, we run it in the same
2258   # way as the "server" command above, that is, we don't want to wait
2259   # for the process to finish. That happens when "killdaemon" is obeyed later
2260   # in the script. We also send the stderr output to test-stderr-server. The
2261   # daemon has its log files put in a different place too (by configuring with
2262   # log_file_path). This requires the  directory to be set up in advance.
2263   #
2264   # There are also times when we want to run a non-daemon version of Exim
2265   # (e.g. a queue runner) with the server configuration. In this case,
2266   # we also define -DNOTDAEMON.
2267
2268   if ($cmd =~ /\s-DSERVER=server\s/ && $cmd !~ /\s-DNOTDAEMON\s/)
2269     {
2270     $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2271     if ($debug) { printf ">> daemon: $cmd\n"; }
2272     run_system("sudo mkdir spool/log 2>/dev/null");
2273     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2274
2275     # Before running the command, convert the -bd option into -bdf so that an
2276     # Exim daemon doesn't double fork. This means that when we wait close
2277     # DAEMONCMD, it waits for the correct process. Also, ensure that the pid
2278     # file is written to the spool directory, in case the Exim binary was
2279     # built with PID_FILE_PATH pointing somewhere else.
2280
2281     if ($cmd =~ /\s-oP\s/)
2282       {
2283       ($pidfile = $cmd) =~ s/^.*-oP ([^ ]+).*$/$1/;
2284       $cmd =~ s!\s-bd\s! -bdf !;
2285       }
2286     else
2287       {
2288       $pidfile = "$parm_cwd/spool/exim-daemon.pid";
2289       $cmd =~ s!\s-bd\s! -bdf -oP $pidfile !;
2290       }
2291     print ">> |${cmd}-server\n" if ($debug);
2292     open DAEMONCMD, "|${cmd}-server" || tests_exit(-1, "Failed to run $cmd");
2293     DAEMONCMD->autoflush(1);
2294     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2295
2296     # Interlock with daemon startup
2297     while (! stat("$pidfile") ) { select(undef, undef, undef, 0.3); }
2298     return 3;                                     # Don't wait
2299     }
2300   elsif ($cmd =~ /\s-DSERVER=wait:(\d+)\s/)
2301     {
2302
2303     # The port and the $dynamic_socket was already allocated while parsing the
2304     # script file, where -DSERVER=wait:PORT_DYNAMIC was encountered.
2305
2306     my $listen_port = $1;
2307     if ($debug) { printf ">> wait-mode daemon: $cmd\n"; }
2308     run_system("sudo mkdir spool/log 2>/dev/null");
2309     run_system("sudo chown $parm_eximuser:$parm_eximgroup spool/log");
2310
2311     my $pid = fork();
2312     if (not defined $pid) { die "** fork failed: $!\n" }
2313     if (not $pid) {
2314       close(STDIN);
2315       open(STDIN, '<&', $dynamic_socket) or die "** dup sock to stdin failed: $!\n";
2316       close($dynamic_socket);
2317       print "[$$]>> ${cmd}-server\n" if ($debug);
2318       exec "exec ${cmd}-server";
2319       die "Can't exec ${cmd}-server: $!\n";
2320     }
2321     while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2322     select(undef, undef, undef, 0.3);             # Let the daemon get going
2323     return (3, { exim_pid => $pid });             # Don't wait
2324     }
2325   }
2326
2327 # The "background" command is run but not waited-for, like exim -DSERVER=server.
2328 # One script line is read and fork-exec'd.  The PID is stored for a later
2329 # killdaemon.
2330
2331 elsif (/^background$/)
2332   {
2333   my $line;
2334 #  $pidfile = "$parm_cwd/aux-var/server-daemon.pid";
2335
2336   $_ = <SCRIPT>; $lineno++;
2337   chomp;
2338   $line = $_;
2339   if ($debug) { printf ">> daemon: $line >>test-stdout 2>>test-stderr\n"; }
2340
2341   my $pid = fork();
2342   if (not defined $pid) { die "** fork failed: $!\n" }
2343   if (not $pid) {
2344     print "[$$]>> ${line}\n" if ($debug);
2345     close(STDIN);
2346     open(STDIN, "<", "test-stdout");
2347     close(STDOUT);
2348     open(STDOUT, ">>", "test-stdout");
2349     close(STDERR);
2350     open(STDERR, ">>", "test-stderr-server");
2351     exec "exec ${line}";
2352     exit(1);
2353   }
2354
2355 #  open(my $fh, ">", $pidfile) ||
2356 #      tests_exit(-1, "Failed to open $pidfile: $!");
2357 #  printf($fh, "%d\n", $pid);
2358 #  close($fh);
2359
2360   while (<SCRIPT>) { $lineno++; last if /^\*{4}\s*$/; }   # Ignore any input
2361   select(undef, undef, undef, 0.3);             # Let the daemon get going
2362   return (3, { exim_pid => $pid });             # Don't wait
2363   }
2364
2365
2366
2367 # Unknown command
2368
2369 else { tests_exit(-1, "Command unrecognized in line $lineno: $_"); }
2370
2371
2372 # Run the command, with stdin connected to a pipe, and write the stdin data
2373 # to it, with appropriate substitutions. If a line ends with \NONL\, chop off
2374 # the terminating newline (and the \NONL\). If the command contains
2375 # -DSERVER=server add "-server" to the command, where it will adjoin the name
2376 # for the stderr file. See comment above about the use of -DSERVER.
2377
2378 $stderrsuffix = ($cmd =~ /\s-DSERVER=server\s/)? "-server" : '';
2379 print ">> |${cmd}${stderrsuffix}\n" if ($debug);
2380 open CMD, "|${cmd}${stderrsuffix}" || tests_exit(1, "Failed to run $cmd");
2381
2382 CMD->autoflush(1);
2383 while (<SCRIPT>)
2384   {
2385   $lineno++;
2386   last if /^\*{4}\s*$/;
2387   do_substitute($testno);
2388   if (/^(.*)\\NONL\\\s*$/) { print CMD $1; } else { print CMD; }
2389   }
2390
2391 # For timeout tests, wait before closing the pipe; we expect a
2392 # SIGPIPE error in this case.
2393
2394 if ($wait_time > 0)
2395   {
2396   printf("  Test %d sleep $wait_time ", $$subtestref);
2397   while ($wait_time-- > 0)
2398     {
2399     print ".";
2400     sleep(1);
2401     }
2402   printf("\r  Test %d                                       $cr", $$subtestref);
2403   }
2404
2405 $sigpipehappened = 0;
2406 close CMD;                # Waits for command to finish
2407 return $yield;            # Ran command and waited
2408 }
2409
2410
2411
2412
2413 ###############################################################################
2414 ###############################################################################
2415
2416 # Here begins the Main Program ...
2417
2418 ###############################################################################
2419 ###############################################################################
2420
2421
2422 autoflush STDOUT 1;
2423 print "Exim tester $testversion\n";
2424
2425 # extend the PATH with .../sbin
2426 # we map all (.../bin) to (.../sbin:.../bin)
2427 $ENV{PATH} = do {
2428   my %seen = map { $_, 1 } split /:/, $ENV{PATH};
2429   join ':' => map { m{(.*)/bin$}
2430                 ? ( $seen{"$1/sbin"} ? () : ("$1/sbin"), $_)
2431                 : ($_) }
2432       split /:/, $ENV{PATH};
2433 };
2434
2435 ##################################################
2436 #      Some tests check created file modes       #
2437 ##################################################
2438
2439 umask 022;
2440
2441
2442 ##################################################
2443 #       Check for the "less" command             #
2444 ##################################################
2445
2446 $more = 'more' if system('which less >/dev/null 2>&1') != 0;
2447
2448
2449
2450 ##################################################
2451 #        Check for sudo access to root           #
2452 ##################################################
2453
2454 print "You need to have sudo access to root to run these tests. Checking ...\n";
2455 if (system('sudo true >/dev/null') != 0)
2456   {
2457   die "** Test for sudo failed: testing abandoned.\n";
2458   }
2459 else
2460   {
2461   print "Test for sudo OK\n";
2462   }
2463
2464
2465
2466 ##################################################
2467 #      See if an Exim binary has been given      #
2468 ##################################################
2469
2470 # If the first character of the first argument is '/', the argument is taken
2471 # as the path to the binary. If the first argument does not start with a
2472 # '/' but exists in the file system, it's assumed to be the Exim binary.
2473
2474 ($parm_exim, @ARGV) = Exim::Runtest::exim_binary(@ARGV);
2475 print "Exim binary is $parm_exim\n" if $parm_exim ne '';
2476
2477
2478
2479 ##################################################
2480 # Sort out options and which tests are to be run #
2481 ##################################################
2482
2483 # There are a few possible options for the test script itself; after these, any
2484 # options are passed on to Exim calls within the tests. Typically, this is used
2485 # to turn on Exim debugging while setting up a test.
2486
2487 while (@ARGV > 0 && $ARGV[0] =~ /^-/)
2488   {
2489   my($arg) = shift @ARGV;
2490   if ($optargs eq '')
2491     {
2492     if ($arg eq "-DEBUG")  { $debug = 1; $cr = "\n"; next; }
2493     if ($arg eq "-DIFF")   { $cf = "diff -u"; next; }
2494     if ($arg eq "-CONTINUE"){$force_continue = 1;
2495                              $more = "cat";
2496                              next; }
2497     if ($arg eq "-UPDATE") { $force_update = 1; next; }
2498     if ($arg eq "-NOIPV4") { $have_ipv4 = 0; next; }
2499     if ($arg eq "-NOIPV6") { $have_ipv6 = 0; next; }
2500     if ($arg eq "-KEEP")   { $save_output = 1; next; }
2501     if ($arg eq "-VALGRIND")   { $valgrind = 1; next; }
2502     if ($arg =~ /^-FLAVOU?R$/) { $flavour = shift; next; }
2503     }
2504   $optargs .= " $arg";
2505   }
2506
2507 # Any subsequent arguments are a range of test numbers.
2508
2509 if (@ARGV > 0)
2510   {
2511   $test_end = $test_start = $ARGV[0];
2512   $test_end = $ARGV[1] if (@ARGV > 1);
2513   $test_end = ($test_start >= 9000)? $test_special_top : $test_top
2514     if $test_end eq "+";
2515   die "** Test numbers out of order\n" if ($test_end < $test_start);
2516   }
2517
2518
2519 ##################################################
2520 #      Make the command's directory current      #
2521 ##################################################
2522
2523 # After doing so, we find its absolute path name.
2524
2525 $cwd = $0;
2526 $cwd = '.' if ($cwd !~ s|/[^/]+$||);
2527 chdir($cwd) || die "** Failed to chdir to \"$cwd\": $!\n";
2528 $parm_cwd = Cwd::getcwd();
2529
2530
2531 ##################################################
2532 #     Search for an Exim binary to test          #
2533 ##################################################
2534
2535 # If an Exim binary hasn't been provided, try to find one. We can handle the
2536 # case where exim-testsuite is installed alongside Exim source directories. For
2537 # PH's private convenience, if there's a directory just called "exim4", that
2538 # takes precedence; otherwise exim-snapshot takes precedence over any numbered
2539 # releases.
2540
2541 # If $parm_exim is still empty, ask the caller
2542
2543 if ($parm_exim eq '')
2544   {
2545   print "** Did not find an Exim binary to test\n";
2546   for ($i = 0; $i < 5; $i++)
2547     {
2548     my($trybin);
2549     print "** Enter pathname for Exim binary: ";
2550     chomp($trybin = <STDIN>);
2551     if (-e $trybin)
2552       {
2553       $parm_exim = $trybin;
2554       last;
2555       }
2556     else
2557       {
2558       print "** $trybin does not exist\n";
2559       }
2560     }
2561   die "** Too many tries\n" if $parm_exim eq '';
2562   }
2563
2564
2565
2566 ##################################################
2567 #          Find what is in the binary            #
2568 ##################################################
2569
2570 # deal with TRUSTED_CONFIG_LIST restrictions
2571 unlink("$parm_cwd/test-config") if -e "$parm_cwd/test-config";
2572 open (IN, "$parm_cwd/confs/0000") ||
2573   tests_exit(-1, "Couldn't open $parm_cwd/confs/0000: $!\n");
2574 open (OUT, ">test-config") ||
2575   tests_exit(-1, "Couldn't open test-config: $!\n");
2576 while (<IN>) { print OUT; }
2577 close(IN);
2578 close(OUT);
2579
2580 print("Probing with config file: $parm_cwd/test-config\n");
2581 open(EXIMINFO, "$parm_exim -d -C $parm_cwd/test-config -DDIR=$parm_cwd " .
2582                "-bP exim_user exim_group 2>&1|") ||
2583   die "** Cannot run $parm_exim: $!\n";
2584 while(<EXIMINFO>)
2585   {
2586   if (my ($version) = /^Exim version (\S+)/) {
2587     my $git = `git describe --dirty=-XX --match 'exim-4*'`;
2588     if (defined $git and $? == 0) {
2589       chomp $git;
2590       $version =~ s/^\d+\K\./_/;
2591       $git =~ s/^exim-//i;
2592       $git =~ s/.*-\Kg([[:xdigit:]]+(?:-XX)?)/$1/;
2593       print <<___
2594
2595 *** Version mismatch
2596 *** Exim binary: $version
2597 *** Git        : $git
2598
2599 ___
2600         if not $version eq $git;
2601     }
2602   }
2603   $parm_eximuser = $1 if /^exim_user = (.*)$/;
2604   $parm_eximgroup = $1 if /^exim_group = (.*)$/;
2605   $parm_trusted_config_list = $1 if /^TRUSTED_CONFIG_LIST:.*?"(.*?)"$/;
2606   ($parm_configure_owner, $parm_configure_group) = ($1, $2)
2607         if /^Configure owner:\s*(\d+):(\d+)/;
2608   print if /wrong owner/;
2609   }
2610 close(EXIMINFO);
2611
2612 if (defined $parm_eximuser)
2613   {
2614   if ($parm_eximuser =~ /^\d+$/) { $parm_exim_uid = $parm_eximuser; }
2615     else { $parm_exim_uid = getpwnam($parm_eximuser); }
2616   }
2617 else
2618   {
2619   print "Unable to extract exim_user from binary.\n";
2620   print "Check if Exim refused to run; if so, consider:\n";
2621   print "  TRUSTED_CONFIG_LIST ALT_CONFIG_PREFIX WHITELIST_D_MACROS\n";
2622   print "If debug permission denied, are you in the exim group?\n";
2623   die "Failing to get information from binary.\n";
2624   }
2625
2626 if (defined $parm_eximgroup)
2627   {
2628   if ($parm_eximgroup =~ /^\d+$/) { $parm_exim_gid = $parm_eximgroup; }
2629     else { $parm_exim_gid = getgrnam($parm_eximgroup); }
2630   }
2631
2632 # check the permissions on the TRUSTED_CONFIG_LIST
2633 if (defined $parm_trusted_config_list)
2634   {
2635   die "TRUSTED_CONFIG_LIST: $parm_trusted_config_list: $!\n"
2636     if not -f $parm_trusted_config_list;
2637
2638   die "TRUSTED_CONFIG_LIST $parm_trusted_config_list must not be world writable!\n"
2639     if 02 & (stat _)[2];
2640
2641   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list %d is group writable, but not owned by group '%s' or '%s'.\n",
2642   (stat _)[1],
2643     scalar(getgrgid 0), scalar(getgrgid $>)
2644     if (020 & (stat _)[2]) and not ((stat _)[5] == $> or (stat _)[5] == 0);
2645
2646   die sprintf "TRUSTED_CONFIG_LIST: $parm_trusted_config_list is not owned by user '%s' or '%s'.\n",
2647   scalar(getpwuid 0), scalar(getpwuid $>)
2648      if (not (-o _ or (stat _)[4] == 0));
2649
2650   open(TCL, $parm_trusted_config_list) or die "Can't open $parm_trusted_config_list: $!\n";
2651   my $test_config = getcwd() . '/test-config';
2652   die "Can't find '$test_config' in TRUSTED_CONFIG_LIST $parm_trusted_config_list."
2653   if not grep { /^$test_config$/ } <TCL>;
2654   }
2655 else
2656   {
2657   die "Unable to check the TRUSTED_CONFIG_LIST, seems to be empty?\n";
2658   }
2659
2660 die "CONFIGURE_OWNER ($parm_configure_owner) does not match the user invoking $0 ($>)\n"
2661         if $parm_configure_owner != $>;
2662
2663 die "CONFIGURE_GROUP ($parm_configure_group) does not match the group invoking $0 ($))\n"
2664         if 0020 & (stat "$parm_cwd/test-config")[2]
2665         and $parm_configure_group != $);
2666
2667
2668 open(EXIMINFO, "$parm_exim -d-all+transport -bV -C $parm_cwd/test-config -DDIR=$parm_cwd |") ||
2669   die "** Cannot run $parm_exim: $!\n";
2670
2671 print "-" x 78, "\n";
2672
2673 while (<EXIMINFO>)
2674   {
2675   my(@temp);
2676
2677   if (/^(Exim|Library) version/) { print; }
2678
2679   elsif (/^Size of off_t: (\d+)/)
2680     {
2681     print;
2682     $have_largefiles = 1 if $1 > 4;
2683     die "** Size of off_t > 32 which seems improbable, not running tests\n"
2684         if ($1 > 32);
2685     }
2686
2687   elsif (/^Support for: (.*)/)
2688     {
2689     print;
2690     @temp = split /(\s+)/, $1;
2691     push(@temp, ' ');
2692     %parm_support = @temp;
2693     }
2694
2695   elsif (/^Lookups \(built-in\): (.*)/)
2696     {
2697     print;
2698     @temp = split /(\s+)/, $1;
2699     push(@temp, ' ');
2700     %parm_lookups = @temp;
2701     }
2702
2703   elsif (/^Authenticators: (.*)/)
2704     {
2705     print;
2706     @temp = split /(\s+)/, $1;
2707     push(@temp, ' ');
2708     %parm_authenticators = @temp;
2709     }
2710
2711   elsif (/^Routers: (.*)/)
2712     {
2713     print;
2714     @temp = split /(\s+)/, $1;
2715     push(@temp, ' ');
2716     %parm_routers = @temp;
2717     }
2718
2719   # Some transports have options, e.g. appendfile/maildir. For those, ensure
2720   # that the basic transport name is set, and then the name with each of the
2721   # options.
2722
2723   elsif (/^Transports: (.*)/)
2724     {
2725     print;
2726     @temp = split /(\s+)/, $1;
2727     my($i,$k);
2728     push(@temp, ' ');
2729     %parm_transports = @temp;
2730     foreach $k (keys %parm_transports)
2731       {
2732       if ($k =~ "/")
2733         {
2734         @temp = split /\//, $k;
2735         $parm_transports{$temp[0]} = " ";
2736         for ($i = 1; $i < @temp; $i++)
2737           { $parm_transports{"$temp[0]/$temp[$i]"} = " "; }
2738         }
2739       }
2740     }
2741   }
2742 close(EXIMINFO);
2743 print "-" x 78, "\n";
2744
2745 unlink("$parm_cwd/test-config");
2746
2747 ##################################################
2748 #    Check for SpamAssassin and ClamAV           #
2749 ##################################################
2750
2751 # These are crude tests. If they aren't good enough, we'll have to improve
2752 # them, for example by actually passing a message through spamc or clamscan.
2753
2754 if (defined $parm_support{Content_Scanning})
2755   {
2756   my $sock = new FileHandle;
2757
2758   if (system("spamc -h 2>/dev/null >/dev/null") == 0)
2759     {
2760     print "The spamc command works:\n";
2761
2762     # This test for an active SpamAssassin is courtesy of John Jetmore.
2763     # The tests are hard coded to localhost:783, so no point in making
2764     # this test flexible like the clamav test until the test scripts are
2765     # changed.  spamd doesn't have the nice PING/PONG protoccol that
2766     # clamd does, but it does respond to errors in an informative manner,
2767     # so use that.
2768
2769     my($sint,$sport) = ('127.0.0.1',783);
2770     eval
2771       {
2772       my $sin = sockaddr_in($sport, inet_aton($sint))
2773           or die "** Failed packing $sint:$sport\n";
2774       socket($sock, PF_INET, SOCK_STREAM, getprotobyname('tcp'))
2775           or die "** Unable to open socket $sint:$sport\n";
2776
2777       local $SIG{ALRM} =
2778           sub { die "** Timeout while connecting to socket $sint:$sport\n"; };
2779       alarm(5);
2780       connect($sock, $sin)
2781           or die "** Unable to connect to socket $sint:$sport\n";
2782       alarm(0);
2783
2784       select((select($sock), $| = 1)[0]);
2785       print $sock "bad command\r\n";
2786
2787       $SIG{ALRM} =
2788           sub { die "** Timeout while reading from socket $sint:$sport\n"; };
2789       alarm(10);
2790       my $res = <$sock>;
2791       alarm(0);
2792
2793       $res =~ m|^SPAMD/|
2794           or die "** Did not get SPAMD from socket $sint:$sport. "
2795                 ."It said: $res\n";
2796       };
2797     alarm(0);
2798     if($@)
2799       {
2800       print "  $@";
2801       print "  Assume SpamAssassin (spamd) is not running\n";
2802       }
2803     else
2804       {
2805       $parm_running{SpamAssassin} = ' ';
2806       print "  SpamAssassin (spamd) seems to be running\n";
2807       }
2808     }
2809   else
2810     {
2811     print "The spamc command failed: assume SpamAssassin (spamd) is not running\n";
2812     }
2813
2814   # For ClamAV, we need to find the clamd socket for use in the Exim
2815   # configuration. Search for the clamd configuration file.
2816
2817   if (system("clamscan -h 2>/dev/null >/dev/null") == 0)
2818     {
2819     my($f, $clamconf, $test_prefix);
2820
2821     print "The clamscan command works";
2822
2823     $test_prefix = $ENV{EXIM_TEST_PREFIX};
2824     $test_prefix = '' if !defined $test_prefix;
2825
2826     foreach $f ("$test_prefix/etc/clamd.conf",
2827                 "$test_prefix/usr/local/etc/clamd.conf",
2828                 "$test_prefix/etc/clamav/clamd.conf", '')
2829       {
2830       if (-e $f)
2831         {
2832         $clamconf = $f;
2833         last;
2834         }
2835       }
2836
2837     # Read the ClamAV configuration file and find the socket interface.
2838
2839     if ($clamconf ne '')
2840       {
2841       my $socket_domain;
2842       open(IN, "$clamconf") || die "\n** Unable to open $clamconf: $!\n";
2843       while (<IN>)
2844         {
2845         if (/^LocalSocket\s+(.*)/)
2846           {
2847           $parm_clamsocket = $1;
2848           $socket_domain = AF_UNIX;
2849           last;
2850           }
2851         if (/^TCPSocket\s+(\d+)/)
2852           {
2853           if (defined $parm_clamsocket)
2854             {
2855             $parm_clamsocket .= " $1";
2856             $socket_domain = AF_INET;
2857             last;
2858             }
2859           else
2860             {
2861             $parm_clamsocket = " $1";
2862             }
2863           }
2864         elsif (/^TCPAddr\s+(\S+)/)
2865           {
2866           if (defined $parm_clamsocket)
2867             {
2868             $parm_clamsocket = $1 . $parm_clamsocket;
2869             $socket_domain = AF_INET;
2870             last;
2871             }
2872           else
2873             {
2874             $parm_clamsocket = $1;
2875             }
2876           }
2877         }
2878       close(IN);
2879
2880       if (defined $socket_domain)
2881         {
2882         print ":\n  The clamd socket is $parm_clamsocket\n";
2883         # This test for an active ClamAV is courtesy of Daniel Tiefnig.
2884         eval
2885           {
2886           my $socket;
2887           if ($socket_domain == AF_UNIX)
2888             {
2889             $socket = sockaddr_un($parm_clamsocket) or die "** Failed packing '$parm_clamsocket'\n";
2890             }
2891           elsif ($socket_domain == AF_INET)
2892             {
2893             my ($ca_host, $ca_port) = split(/\s+/,$parm_clamsocket);
2894             my $ca_hostent = gethostbyname($ca_host) or die "** Failed to get raw address for host '$ca_host'\n";
2895             $socket = sockaddr_in($ca_port, $ca_hostent) or die "** Failed packing '$parm_clamsocket'\n";
2896             }
2897           else
2898             {
2899             die "** Unknown socket domain '$socket_domain' (should not happen)\n";
2900             }
2901           socket($sock, $socket_domain, SOCK_STREAM, 0) or die "** Unable to open socket '$parm_clamsocket'\n";
2902           local $SIG{ALRM} = sub { die "** Timeout while connecting to socket '$parm_clamsocket'\n"; };
2903           alarm(5);
2904           connect($sock, $socket) or die "** Unable to connect to socket '$parm_clamsocket'\n";
2905           alarm(0);
2906
2907           my $ofh = select $sock; $| = 1; select $ofh;
2908           print $sock "PING\n";
2909
2910           $SIG{ALRM} = sub { die "** Timeout while reading from socket '$parm_clamsocket'\n"; };
2911           alarm(10);
2912           my $res = <$sock>;
2913           alarm(0);
2914
2915           $res =~ /PONG/ or die "** Did not get PONG from socket '$parm_clamsocket'. It said: $res\n";
2916           };
2917         alarm(0);
2918
2919         if($@)
2920           {
2921           print "  $@";
2922           print "  Assume ClamAV is not running\n";
2923           }
2924         else
2925           {
2926           $parm_running{ClamAV} = ' ';
2927           print "  ClamAV seems to be running\n";
2928           }
2929         }
2930       else
2931         {
2932         print ", but the socket for clamd could not be determined\n";
2933         print "Assume ClamAV is not running\n";
2934         }
2935       }
2936
2937     else
2938       {
2939       print ", but I can't find a configuration for clamd\n";
2940       print "Assume ClamAV is not running\n";
2941       }
2942     }
2943   }
2944
2945
2946 ##################################################
2947 #       Check for redis                          #
2948 ##################################################
2949 if (defined $parm_lookups{redis})
2950   {
2951   if (system("redis-server -v 2>/dev/null >/dev/null") == 0)
2952     {
2953     print "The redis-server command works\n";
2954     $parm_running{redis} = ' ';
2955     }
2956   else
2957     {
2958     print "The redis-server command failed: assume Redis not installed\n";
2959     }
2960   }
2961
2962 ##################################################
2963 #         Test for the basic requirements        #
2964 ##################################################
2965
2966 # This test suite assumes that Exim has been built with at least the "usual"
2967 # set of routers, transports, and lookups. Ensure that this is so.
2968
2969 $missing = '';
2970
2971 $missing .= "     Lookup: lsearch\n" if (!defined $parm_lookups{lsearch});
2972
2973 $missing .= "     Router: accept\n" if (!defined $parm_routers{accept});
2974 $missing .= "     Router: dnslookup\n" if (!defined $parm_routers{dnslookup});
2975 $missing .= "     Router: manualroute\n" if (!defined $parm_routers{manualroute});
2976 $missing .= "     Router: redirect\n" if (!defined $parm_routers{redirect});
2977
2978 $missing .= "     Transport: appendfile\n" if (!defined $parm_transports{appendfile});
2979 $missing .= "     Transport: autoreply\n" if (!defined $parm_transports{autoreply});
2980 $missing .= "     Transport: pipe\n" if (!defined $parm_transports{pipe});
2981 $missing .= "     Transport: smtp\n" if (!defined $parm_transports{smtp});
2982
2983 if ($missing ne '')
2984   {
2985   print "\n";
2986   print "** Many features can be included or excluded from Exim binaries.\n";
2987   print "** This test suite requires that Exim is built to contain a certain\n";
2988   print "** set of basic facilities. It seems that some of these are missing\n";
2989   print "** from the binary that is under test, so the test cannot proceed.\n";
2990   print "** The missing facilities are:\n";
2991   print "$missing";
2992   die "** Test script abandoned\n";
2993   }
2994
2995
2996 ##################################################
2997 #      Check for the auxiliary programs          #
2998 ##################################################
2999
3000 # These are always required:
3001
3002 for $prog ("cf", "checkaccess", "client", "client-ssl", "client-gnutls",
3003            "fakens", "iefbr14", "server")
3004   {
3005   next if ($prog eq "client-ssl" && !defined $parm_support{OpenSSL});
3006   next if ($prog eq "client-gnutls" && !defined $parm_support{GnuTLS});
3007   if (!-e "bin/$prog")
3008     {
3009     print "\n";
3010     print "** bin/$prog does not exist. Have you run ./configure and make?\n";
3011     die "** Test script abandoned\n";
3012     }
3013   }
3014
3015 # If the "loaded" binary is missing, we cut out tests for ${dlfunc. It isn't
3016 # compiled on systems where we don't know how to. However, if Exim does not
3017 # have that functionality compiled, we needn't bother.
3018
3019 $dlfunc_deleted = 0;
3020 if (defined $parm_support{Expand_dlfunc} && !-e 'bin/loaded')
3021   {
3022   delete $parm_support{Expand_dlfunc};
3023   $dlfunc_deleted = 1;
3024   }
3025
3026
3027 ##################################################
3028 #          Find environmental details            #
3029 ##################################################
3030
3031 # Find the caller of this program.
3032
3033 ($parm_caller,$pwpw,$parm_caller_uid,$parm_caller_gid,$pwquota,$pwcomm,
3034  $parm_caller_gecos, $parm_caller_home) = getpwuid($>);
3035
3036 $pwpw = $pwpw;       # Kill Perl warnings
3037 $pwquota = $pwquota;
3038 $pwcomm = $pwcomm;
3039
3040 $parm_caller_group = getgrgid($parm_caller_gid);
3041
3042 print "Program caller is $parm_caller ($parm_caller_uid), whose group is $parm_caller_group ($parm_caller_gid)\n";
3043 print "Home directory is $parm_caller_home\n";
3044
3045 unless (defined $parm_eximgroup)
3046   {
3047   print "Unable to derive \$parm_eximgroup.\n";
3048   die "** ABANDONING.\n";
3049   }
3050
3051 print "You need to be in the Exim group to run these tests. Checking ...";
3052
3053 if (`groups` =~ /\b\Q$parm_eximgroup\E\b/)
3054   {
3055   print " OK\n";
3056   }
3057 else
3058   {
3059   print "\nOh dear, you are not in the Exim group.\n";
3060   die "** Testing abandoned.\n";
3061   }
3062
3063 # Find this host's IP addresses - there may be many, of course, but we keep
3064 # one of each type (IPv4 and IPv6).
3065
3066 open(IFCONFIG, '-|', (grep { -x "$_/ip" } split /:/, $ENV{PATH}) ? 'ip address' : 'ifconfig -a')
3067   or die "** Cannot run 'ip address' or 'ifconfig -a'\n";
3068 while (not ($parm_ipv4 and $parm_ipv6) and defined($_ = <IFCONFIG>))
3069   {
3070   if (not $parm_ipv4 and /^\s*inet(?:\saddr)?:?\s?(\d+\.\d+\.\d+\.\d+)(?:\/\d+)?\s/i)
3071     {
3072     next if $1 =~ /^(?:127|10)\./;
3073     $parm_ipv4 = $1;
3074     }
3075
3076   if (not $parm_ipv6 and /^\s*inet6(?:\saddr)?:?\s?([abcdef\d:]+)(?:\/\d+)/i)
3077     {
3078     next if $1 eq '::1' or $1 =~ /^fe80/i;
3079     $parm_ipv6 = $1;
3080     }
3081   }
3082 close(IFCONFIG);
3083
3084 # Use private IP addresses if there are no public ones.
3085
3086 # If either type of IP address is missing, we need to set the value to
3087 # something other than empty, because that wrecks the substitutions. The value
3088 # is reflected, so use a meaningful string. Set appropriate options for the
3089 # "server" command. In practice, however, many tests assume 127.0.0.1 is
3090 # available, so things will go wrong if there is no IPv4 address. The lack
3091 # of IPV4 or IPv6 can be simulated by command options, which force $have_ipv4
3092 # and $have_ipv6 false.
3093
3094 if (not $parm_ipv4)
3095   {
3096   $have_ipv4 = 0;
3097   $parm_ipv4 = "<no IPv4 address found>";
3098   $server_opts .= " -noipv4";
3099   }
3100 elsif ($have_ipv4 == 0)
3101   {
3102   $parm_ipv4 = "<IPv4 testing disabled>";
3103   $server_opts .= " -noipv4";
3104   }
3105 else
3106   {
3107   $parm_running{IPv4} = " ";
3108   }
3109
3110 if (not $parm_ipv6)
3111   {
3112   $have_ipv6 = 0;
3113   $parm_ipv6 = "<no IPv6 address found>";
3114   $server_opts .= " -noipv6";
3115   delete($parm_support{IPv6});
3116   }
3117 elsif ($have_ipv6 == 0)
3118   {
3119   $parm_ipv6 = "<IPv6 testing disabled>";
3120   $server_opts .= " -noipv6";
3121   delete($parm_support{IPv6});
3122   }
3123 elsif (!defined $parm_support{IPv6})
3124   {
3125   $have_ipv6 = 0;
3126   $parm_ipv6 = "<no IPv6 support in Exim binary>";
3127   $server_opts .= " -noipv6";
3128   }
3129 else
3130   {
3131   $parm_running{IPv6} = " ";
3132   }
3133
3134 print "IPv4 address is $parm_ipv4\n";
3135 print "IPv6 address is $parm_ipv6\n";
3136
3137 # For munging test output, we need the reversed IP addresses.
3138
3139 $parm_ipv4r = ($parm_ipv4 !~ /^\d/)? '' :
3140   join(".", reverse(split /\./, $parm_ipv4));
3141
3142 $parm_ipv6r = $parm_ipv6;             # Appropriate if not in use
3143 if ($parm_ipv6 =~ /^[\da-f]/)
3144   {
3145   my(@comps) = split /:/, $parm_ipv6;
3146   my(@nibbles);
3147   foreach $comp (@comps)
3148     {
3149     push @nibbles, sprintf("%lx", hex($comp) >> 8);
3150     push @nibbles, sprintf("%lx", hex($comp) & 0xff);
3151     }
3152   $parm_ipv6r = join(".", reverse(@nibbles));
3153   }
3154
3155 # Find the host name, fully qualified.
3156
3157 chomp($temp = `hostname`);
3158 die "'hostname' didn't return anything\n" unless defined $temp and length $temp;
3159 if ($temp =~ /\./)
3160   {
3161   $parm_hostname = $temp;
3162   }
3163 else
3164   {
3165   $parm_hostname = (gethostbyname($temp))[0];
3166   $parm_hostname = "no.host.name.found" unless defined $parm_hostname and length $parm_hostname;
3167   }
3168 print "Hostname is $parm_hostname\n";
3169
3170 if ($parm_hostname !~ /\./)
3171   {
3172   print "\n*** Host name is not fully qualified: this may cause problems ***\n\n";
3173   }
3174
3175 if ($parm_hostname =~ /[[:upper:]]/)
3176   {
3177   print "\n*** Host name has upper case characters: this may cause problems ***\n\n";
3178   }
3179
3180
3181
3182 ##################################################
3183 #     Create a testing version of Exim           #
3184 ##################################################
3185
3186 # We want to be able to run Exim with a variety of configurations. Normally,
3187 # the use of -C to change configuration causes Exim to give up its root
3188 # privilege (unless the caller is exim or root). For these tests, we do not
3189 # want this to happen. Also, we want Exim to know that it is running in its
3190 # test harness.
3191
3192 # We achieve this by copying the binary and patching it as we go. The new
3193 # binary knows it is a testing copy, and it allows -C and -D without loss of
3194 # privilege. Clearly, this file is dangerous to have lying around on systems
3195 # where there are general users with login accounts. To protect against this,
3196 # we put the new binary in a special directory that is accessible only to the
3197 # caller of this script, who is known to have sudo root privilege from the test
3198 # that was done above. Furthermore, we ensure that the binary is deleted at the
3199 # end of the test. First ensure the directory exists.
3200
3201 if (-d "eximdir")
3202   { unlink "eximdir/exim"; }     # Just in case
3203 else
3204   {
3205   mkdir("eximdir", 0710) || die "** Unable to mkdir $parm_cwd/eximdir: $!\n";
3206   system("sudo chgrp $parm_eximgroup eximdir");
3207   }
3208
3209 # The construction of the patched binary must be done as root, so we use
3210 # a separate script. As well as indicating that this is a test-harness binary,
3211 # the version number is patched to "x.yz" so that its length is always the
3212 # same. Otherwise, when it appears in Received: headers, it affects the length
3213 # of the message, which breaks certain comparisons.
3214
3215 die "** Unable to make patched exim: $!\n"
3216   if (system("sudo ./patchexim $parm_exim") != 0);
3217
3218 # From this point on, exits from the program must go via the subroutine
3219 # tests_exit(), so that suitable cleaning up can be done when required.
3220 # Arrange to catch interrupting signals, to assist with this.
3221
3222 $SIG{INT} = \&inthandler;
3223 $SIG{PIPE} = \&pipehandler;
3224
3225 # For some tests, we need another copy of the binary that is setuid exim rather
3226 # than root.
3227
3228 system("sudo cp eximdir/exim eximdir/exim_exim;" .
3229        "sudo chown $parm_eximuser eximdir/exim_exim;" .
3230        "sudo chgrp $parm_eximgroup eximdir/exim_exim;" .
3231        "sudo chmod 06755 eximdir/exim_exim");
3232
3233
3234 ##################################################
3235 #     Make copies of utilities we might need     #
3236 ##################################################
3237
3238 # Certain of the tests make use of some of Exim's utilities. We do not need
3239 # to be root to copy these.
3240
3241 ($parm_exim_dir) = $parm_exim =~ m?^(.*)/exim?;
3242
3243 $dbm_build_deleted = 0;
3244 if (defined $parm_lookups{dbm} &&
3245     system("cp $parm_exim_dir/exim_dbmbuild eximdir") != 0)
3246   {
3247   delete $parm_lookups{dbm};
3248   $dbm_build_deleted = 1;
3249   }
3250
3251 if (system("cp $parm_exim_dir/exim_dumpdb eximdir") != 0)
3252   {
3253   tests_exit(-1, "Failed to make a copy of exim_dumpdb: $!");
3254   }
3255
3256 if (system("cp $parm_exim_dir/exim_lock eximdir") != 0)
3257   {
3258   tests_exit(-1, "Failed to make a copy of exim_lock: $!");
3259   }
3260
3261 if (system("cp $parm_exim_dir/exinext eximdir") != 0)
3262   {
3263   tests_exit(-1, "Failed to make a copy of exinext: $!");
3264   }
3265
3266 if (system("cp $parm_exim_dir/exigrep eximdir") != 0)
3267   {
3268   tests_exit(-1, "Failed to make a copy of exigrep: $!");
3269   }
3270
3271 if (system("cp $parm_exim_dir/eximstats eximdir") != 0)
3272   {
3273   tests_exit(-1, "Failed to make a copy of eximstats: $!");
3274   }
3275
3276
3277 ##################################################
3278 #    Check that the Exim user can access stuff   #
3279 ##################################################
3280
3281 # We delay this test till here so that we can check access to the actual test
3282 # binary. This will be needed when Exim re-exec's itself to do deliveries.
3283
3284 print "Exim user is $parm_eximuser ($parm_exim_uid)\n";
3285 print "Exim group is $parm_eximgroup ($parm_exim_gid)\n";
3286
3287 if ($parm_caller_uid eq $parm_exim_uid) {
3288   tests_exit(-1, "Exim user ($parm_eximuser,$parm_exim_uid) cannot be "
3289                 ."the same as caller ($parm_caller,$parm_caller_uid)");
3290 }
3291 if ($parm_caller_gid eq $parm_exim_gid) {
3292   tests_exit(-1, "Exim group ($parm_eximgroup,$parm_exim_gid) cannot be "
3293                 ."the same as caller's ($parm_caller) group as it confuses "
3294                 ."results analysis");
3295 }
3296
3297 print "The Exim user needs access to the test suite directory. Checking ...";
3298
3299 if (($rc = system("sudo bin/checkaccess $parm_cwd/eximdir/exim $parm_eximuser $parm_eximgroup")) != 0)
3300   {
3301   my($why) = "unknown failure $rc";
3302   $rc >>= 8;
3303   $why = "Couldn't find user \"$parm_eximuser\"" if $rc == 1;
3304   $why = "Couldn't find group \"$parm_eximgroup\"" if $rc == 2;
3305   $why = "Couldn't read auxiliary group list" if $rc == 3;
3306   $why = "Couldn't get rid of auxiliary groups" if $rc == 4;
3307   $why = "Couldn't set gid" if $rc == 5;
3308   $why = "Couldn't set uid" if $rc == 6;
3309   $why = "Couldn't open \"$parm_cwd/eximdir/exim\"" if $rc == 7;
3310   print "\n** $why\n";
3311   tests_exit(-1, "$parm_eximuser cannot access the test suite directory");
3312   }
3313 else
3314   {
3315   print " OK\n";
3316   }
3317
3318
3319 ##################################################
3320 #        Create a list of available tests        #
3321 ##################################################
3322
3323 # The scripts directory contains a number of subdirectories whose names are
3324 # of the form 0000-xxxx, 1100-xxxx, 2000-xxxx, etc. Each set of tests apart
3325 # from the first requires certain optional features to be included in the Exim
3326 # binary. These requirements are contained in a file called "REQUIRES" within
3327 # the directory. We scan all these tests, discarding those that cannot be run
3328 # because the current binary does not support the right facilities, and also
3329 # those that are outside the numerical range selected.
3330
3331 print "\nTest range is $test_start to $test_end (flavour $flavour)\n";
3332 print "Omitting \${dlfunc expansion tests (loadable module not present)\n"
3333   if $dlfunc_deleted;
3334 print "Omitting dbm tests (unable to copy exim_dbmbuild)\n"
3335   if $dbm_build_deleted;
3336
3337 opendir(DIR, "scripts") || tests_exit(-1, "Failed to opendir(\"scripts\"): $!");
3338 @test_dirs = sort readdir(DIR);
3339 closedir(DIR);
3340
3341 # Remove . and .. and CVS from the list.
3342
3343 for ($i = 0; $i < @test_dirs; $i++)
3344   {
3345   my($d) = $test_dirs[$i];
3346   if ($d eq "." || $d eq ".." || $d eq "CVS")
3347     {
3348     splice @test_dirs, $i, 1;
3349     $i--;
3350     }
3351   }
3352
3353 # Scan for relevant tests
3354
3355 for ($i = 0; $i < @test_dirs; $i++)
3356   {
3357   my($testdir) = $test_dirs[$i];
3358   my($wantthis) = 1;
3359
3360   print ">>Checking $testdir\n" if $debug;
3361
3362   # Skip this directory if the first test is equal or greater than the first
3363   # test in the next directory.
3364
3365   next if ($i < @test_dirs - 1) &&
3366           ($test_start >= substr($test_dirs[$i+1], 0, 4));
3367
3368   # No need to carry on if the end test is less than the first test in this
3369   # subdirectory.
3370
3371   last if $test_end < substr($testdir, 0, 4);
3372
3373   # Check requirements, if any.
3374
3375   if (open(REQUIRES, "scripts/$testdir/REQUIRES"))
3376     {
3377     while (<REQUIRES>)
3378       {
3379       next if /^\s*$/;
3380       s/\s+$//;
3381       if (/^support (.*)$/)
3382         {
3383         if (!defined $parm_support{$1}) { $wantthis = 0; last; }
3384         }
3385       elsif (/^running (.*)$/)
3386         {
3387         if (!defined $parm_running{$1}) { $wantthis = 0; last; }
3388         }
3389       elsif (/^lookup (.*)$/)
3390         {
3391         if (!defined $parm_lookups{$1}) { $wantthis = 0; last; }
3392         }
3393       elsif (/^authenticators? (.*)$/)
3394         {
3395         if (!defined $parm_authenticators{$1}) { $wantthis = 0; last; }
3396         }
3397       elsif (/^router (.*)$/)
3398         {
3399         if (!defined $parm_routers{$1}) { $wantthis = 0; last; }
3400         }
3401       elsif (/^transport (.*)$/)
3402         {
3403         if (!defined $parm_transports{$1}) { $wantthis = 0; last; }
3404         }
3405       else
3406         {
3407         tests_exit(-1, "Unknown line in \"scripts/$testdir/REQUIRES\": \"$_\"");
3408         }
3409       }
3410     close(REQUIRES);
3411     }
3412   else
3413     {
3414     tests_exit(-1, "Failed to open \"scripts/$testdir/REQUIRES\": $!")
3415       unless $!{ENOENT};
3416     }
3417
3418   # Loop if we do not want the tests in this subdirectory.
3419
3420   if (!$wantthis)
3421     {
3422     chomp;
3423     print "Omitting tests in $testdir (missing $_)\n";
3424     next;
3425     }
3426
3427   # We want the tests from this subdirectory, provided they are in the
3428   # range that was selected.
3429
3430   opendir(SUBDIR, "scripts/$testdir") ||
3431     tests_exit(-1, "Failed to opendir(\"scripts/$testdir\"): $!");
3432   @testlist = sort readdir(SUBDIR);
3433   close(SUBDIR);
3434
3435   foreach $test (@testlist)
3436     {
3437     next if $test !~ /^\d{4}(?:\.\d+)?$/;
3438     next if $test < $test_start || $test > $test_end;
3439     push @test_list, "$testdir/$test";
3440     }
3441   }
3442
3443 print ">>Test List: @test_list\n", if $debug;
3444
3445
3446 ##################################################
3447 #         Munge variable auxiliary data          #
3448 ##################################################
3449
3450 # Some of the auxiliary data files have to refer to the current testing
3451 # directory and other parameter data. The generic versions of these files are
3452 # stored in the aux-var-src directory. At this point, we copy each of them
3453 # to the aux-var directory, making appropriate substitutions. There aren't very
3454 # many of them, so it's easiest just to do this every time. Ensure the mode
3455 # is standardized, as this path is used as a test for the ${stat: expansion.
3456
3457 # A similar job has to be done for the files in the dnszones-src directory, to
3458 # make the fake DNS zones for testing. Most of the zone files are copied to
3459 # files of the same name, but db.ipv4.V4NET and db.ipv6.V6NET use the testing
3460 # networks that are defined by parameter.
3461
3462 foreach $basedir ("aux-var", "dnszones")
3463   {
3464   system("sudo rm -rf $parm_cwd/$basedir");
3465   mkdir("$parm_cwd/$basedir", 0777);
3466   chmod(0755, "$parm_cwd/$basedir");
3467
3468   opendir(AUX, "$parm_cwd/$basedir-src") ||
3469     tests_exit(-1, "Failed to opendir $parm_cwd/$basedir-src: $!");
3470   my(@filelist) = readdir(AUX);
3471   close(AUX);
3472
3473   foreach $file (@filelist)
3474     {
3475     my($outfile) = $file;
3476     next if $file =~ /^\./;
3477
3478     if ($file eq "db.ip4.V4NET")
3479       {
3480       $outfile = "db.ip4.$parm_ipv4_test_net";
3481       }
3482     elsif ($file eq "db.ip6.V6NET")
3483       {
3484       my(@nibbles) = reverse(split /\s*/, $parm_ipv6_test_net);
3485       $" = '.';
3486       $outfile = "db.ip6.@nibbles";
3487       $" = ' ';
3488       }
3489
3490     print ">>Copying $basedir-src/$file to $basedir/$outfile\n" if $debug;
3491     open(IN, "$parm_cwd/$basedir-src/$file") ||
3492       tests_exit(-1, "Failed to open $parm_cwd/$basedir-src/$file: $!");
3493     open(OUT, ">$parm_cwd/$basedir/$outfile") ||
3494       tests_exit(-1, "Failed to open $parm_cwd/$basedir/$outfile: $!");
3495     while (<IN>)
3496       {
3497       do_substitute(0);
3498       print OUT;
3499       }
3500     close(IN);
3501     close(OUT);
3502     }
3503   }
3504
3505 # Set a user's shell, distinguishable from /bin/sh
3506
3507 symlink('/bin/sh' => 'aux-var/sh');
3508 $ENV{SHELL} = $parm_shell = "$parm_cwd/aux-var/sh";
3509
3510 ##################################################
3511 #     Create fake DNS zones for this host        #
3512 ##################################################
3513
3514 # There are fixed zone files for 127.0.0.1 and ::1, but we also want to be
3515 # sure that there are forward and reverse registrations for this host, using
3516 # its real IP addresses. Dynamically created zone files achieve this.
3517
3518 if ($have_ipv4 || $have_ipv6)
3519   {
3520   my($shortname,$domain) = $parm_hostname =~ /^([^.]+)(.*)/;
3521   open(OUT, ">$parm_cwd/dnszones/db$domain") ||
3522     tests_exit(-1, "Failed to open $parm_cwd/dnszones/db$domain: $!");
3523   print OUT "; This is a dynamically constructed fake zone file.\n" .
3524     "; The following line causes fakens to return PASS_ON\n" .
3525     "; for queries that it cannot answer\n\n" .
3526     "PASS ON NOT FOUND\n\n";
3527   print OUT "$shortname  A     $parm_ipv4\n" if $have_ipv4;
3528   print OUT "$shortname  AAAA  $parm_ipv6\n" if $have_ipv6;
3529   print OUT "\n; End\n";
3530   close(OUT);
3531   }
3532
3533 if ($have_ipv4 && $parm_ipv4 ne "127.0.0.1")
3534   {
3535   my(@components) = $parm_ipv4 =~ /^(\d+)\.(\d+)\.(\d+)\.(\d+)/;
3536   open(OUT, ">$parm_cwd/dnszones/db.ip4.$components[0]") ||
3537     tests_exit(-1,
3538       "Failed  to open $parm_cwd/dnszones/db.ip4.$components[0]: $!");
3539   print OUT "; This is a dynamically constructed fake zone file.\n" .
3540     "; The zone is $components[0].in-addr.arpa.\n\n" .
3541     "$components[3].$components[2].$components[1]  PTR  $parm_hostname.\n\n" .
3542     "; End\n";
3543   close(OUT);
3544   }
3545
3546 if ($have_ipv6 && $parm_ipv6 ne "::1")
3547   {
3548   my($exp_v6) = $parm_ipv6;
3549   $exp_v6 =~ s/[^:]//g;
3550   if ( $parm_ipv6 =~ /^([^:].+)::$/ ) {
3551     $exp_v6 = $1 . ':0' x (9-length($exp_v6));
3552   } elsif ( $parm_ipv6 =~ /^(.+)::(.+)$/ ) {
3553     $exp_v6 = $1 . ':0' x (8-length($exp_v6)) . ':' . $2;
3554   } elsif ( $parm_ipv6 =~ /^::(.+[^:])$/ ) {
3555     $exp_v6 = '0:' x (9-length($exp_v6)) . $1;
3556   } else {
3557     $exp_v6 = $parm_ipv6;
3558   }
3559   my(@components) = split /:/, $exp_v6;
3560   my(@nibbles) = reverse (split /\s*/, shift @components);
3561   my($sep) =  '';
3562
3563   $" = ".";
3564   open(OUT, ">$parm_cwd/dnszones/db.ip6.@nibbles") ||
3565     tests_exit(-1,
3566       "Failed  to open $parm_cwd/dnszones/db.ip6.@nibbles: $!");
3567   print OUT "; This is a dynamically constructed fake zone file.\n" .
3568     "; The zone is @nibbles.ip6.arpa.\n\n";
3569
3570   @components = reverse @components;
3571   foreach $c (@components)
3572     {
3573     $c = "0$c" until $c =~ /^..../;
3574     @nibbles = reverse(split /\s*/, $c);
3575     print OUT "$sep@nibbles";
3576     $sep = ".";
3577     }
3578
3579   print OUT "  PTR  $parm_hostname.\n\n; End\n";
3580   close(OUT);
3581   $" = " ";
3582   }
3583
3584
3585
3586 ##################################################
3587 #    Create lists of mailboxes and message logs  #
3588 ##################################################
3589
3590 # We use these lists to check that a test has created the expected files. It
3591 # should be faster than looking for the file each time. For mailboxes, we have
3592 # to scan a complete subtree, in order to handle maildirs. For msglogs, there
3593 # is just a flat list of files.
3594
3595 @oldmails = list_files_below("mail");
3596 opendir(DIR, "msglog") || tests_exit(-1, "Failed to opendir msglog: $!");
3597 @oldmsglogs = readdir(DIR);
3598 closedir(DIR);
3599
3600
3601
3602 ##################################################
3603 #         Run the required tests                 #
3604 ##################################################
3605
3606 # Each test script contains a number of tests, separated by a line that
3607 # contains ****. We open input from the terminal so that we can read responses
3608 # to prompts.
3609
3610 if (not $force_continue) {
3611   # runtest needs to interact if we're not in continue
3612   # mode. It does so by communicate to /dev/tty
3613   open(T, "/dev/tty") or tests_exit(-1, "Failed to open /dev/tty: $!");
3614 }
3615
3616
3617 print "\nPress RETURN to run the tests: ";
3618 $_ = $force_continue ? "c" : <T>;
3619 print "\n";
3620
3621 $lasttestdir = '';
3622
3623 foreach $test (@test_list)
3624   {
3625   local($lineno) = 0;
3626   local($commandno) = 0;
3627   local($subtestno) = 0;
3628   (local $testno = $test) =~ s|.*/||;
3629   local($sortlog) = 0;
3630
3631   my($gnutls) = 0;
3632   my($docheck) = 1;
3633   my($thistestdir) = substr($test, 0, -5);
3634
3635   $dynamic_socket->close() if $dynamic_socket;
3636
3637   if ($lasttestdir ne $thistestdir)
3638     {
3639     $gnutls = 0;
3640     if (-s "scripts/$thistestdir/REQUIRES")
3641       {
3642       my($indent) = '';
3643       print "\n>>> The following tests require: ";
3644       open(IN, "scripts/$thistestdir/REQUIRES") ||
3645         tests_exit(-1, "Failed to open scripts/$thistestdir/REQUIRES: $1");
3646       while (<IN>)
3647         {
3648         $gnutls = 1 if /^support GnuTLS/;
3649         print $indent, $_;
3650         $indent = ">>>                              ";
3651         }
3652       close(IN);
3653       }
3654     }
3655   $lasttestdir = $thistestdir;
3656
3657   # Remove any debris in the spool directory and the test-mail directory
3658   # and also the files for collecting stdout and stderr. Then put back
3659   # the test-mail directory for appendfile deliveries.
3660
3661   system "sudo /bin/rm -rf spool test-*";
3662   system "mkdir test-mail 2>/dev/null";
3663
3664   # A privileged Exim will normally make its own spool directory, but some of
3665   # the tests run in unprivileged modes that don't always work if the spool
3666   # directory isn't already there. What is more, we want anybody to be able
3667   # to read it in order to find the daemon's pid.
3668
3669   system "mkdir spool; " .
3670          "sudo chown $parm_eximuser:$parm_eximgroup spool; " .
3671          "sudo chmod 0755 spool";
3672
3673   # Empty the cache that keeps track of things like message id mappings, and
3674   # set up the initial sequence strings.
3675
3676   undef %cache;
3677   $next_msgid = "aX";
3678   $next_pid = 1234;
3679   $next_port = 1111;
3680   $message_skip = 0;
3681   $msglog_skip = 0;
3682   $stderr_skip = 0;
3683   $stdout_skip = 0;
3684   $rmfiltertest = 0;
3685   $is_ipv6test = 0;
3686   $TEST_STATE->{munge} = '';
3687
3688   # Remove the associative arrays used to hold checked mail files and msglogs
3689
3690   undef %expected_mails;
3691   undef %expected_msglogs;
3692
3693   # Open the test's script
3694   open(SCRIPT, "scripts/$test") ||
3695     tests_exit(-1, "Failed to open \"scripts/$test\": $!");
3696   # Run through the script once to set variables which should be global
3697   while (<SCRIPT>)
3698     {
3699     if (/^no_message_check/) { $message_skip = 1; next; }
3700     if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3701     if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3702     if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3703     if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3704     if (/^sortlog/)          { $sortlog = 1; next; }
3705     if (/\bPORT_DYNAMIC\b/)  { $dynamic_socket = Exim::Runtest::dynamic_socket(); next; }
3706     }
3707   # Reset to beginning of file for per test interpreting/processing
3708   seek(SCRIPT, 0, 0);
3709
3710   # The first line in the script must be a comment that is used to identify
3711   # the set of tests as a whole.
3712
3713   $_ = <SCRIPT>;
3714   $lineno++;
3715   tests_exit(-1, "Missing identifying comment at start of $test") if (!/^#/);
3716   printf("%s %s", (substr $test, 5), (substr $_, 2));
3717
3718   # Loop for each of the subtests within the script. The variable $server_pid
3719   # is used to remember the pid of a "server" process, for which we do not
3720   # wait until we have waited for a subsequent command.
3721
3722   local($server_pid) = 0;
3723   for ($commandno = 1; !eof SCRIPT; $commandno++)
3724     {
3725     # Skip further leading comments and blank lines, handle the flag setting
3726     # commands, and deal with tests for IP support.
3727
3728     while (<SCRIPT>)
3729       {
3730       $lineno++;
3731       # Could remove these variable settings because they are already
3732       # set above, but doesn't hurt to leave them here.
3733       if (/^no_message_check/) { $message_skip = 1; next; }
3734       if (/^no_msglog_check/)  { $msglog_skip = 1; next; }
3735       if (/^no_stderr_check/)  { $stderr_skip = 1; next; }
3736       if (/^no_stdout_check/)  { $stdout_skip = 1; next; }
3737       if (/^rmfiltertest/)     { $rmfiltertest = 1; next; }
3738       if (/^sortlog/)          { $sortlog = 1; next; }
3739
3740       if (/^need_largefiles/)
3741         {
3742         next if $have_largefiles;
3743         print ">>> Large file support is needed for test $testno, but is not available: skipping\n";
3744         $docheck = 0;      # don't check output
3745         undef $_;          # pretend EOF
3746         last;
3747         }
3748
3749       if (/^need_ipv4/)
3750         {
3751         next if $have_ipv4;
3752         print ">>> IPv4 is needed for test $testno, but is not available: skipping\n";
3753         $docheck = 0;      # don't check output
3754         undef $_;          # pretend EOF
3755         last;
3756         }
3757
3758       if (/^need_ipv6/)
3759         {
3760         if ($have_ipv6)
3761           {
3762           $is_ipv6test = 1;
3763           next;
3764           }
3765         print ">>> IPv6 is needed for test $testno, but is not available: skipping\n";
3766         $docheck = 0;      # don't check output
3767         undef $_;          # pretend EOF
3768         last;
3769         }
3770
3771       if (/^need_move_frozen_messages/)
3772         {
3773         next if defined $parm_support{move_frozen_messages};
3774         print ">>> move frozen message support is needed for test $testno, " .
3775           "but is not\n>>> available: skipping\n";
3776         $docheck = 0;      # don't check output
3777         undef $_;          # pretend EOF
3778         last;
3779         }
3780
3781       last unless /^(?:#(?!##\s)|\s*$)/;
3782       }
3783     last if !defined $_;  # Hit EOF
3784
3785     my($subtest_startline) = $lineno;
3786
3787     # Now run the command. The function returns 0 for an inline command,
3788     # 1 if a non-exim command was run and waited for, 2 if an exim
3789     # command was run and waited for, and 3 if a command
3790     # was run and not waited for (usually a daemon or server startup).
3791
3792     my($commandname) = '';
3793     my($expectrc) = 0;
3794     my($rc, $run_extra) = run_command($testno, \$subtestno, \$expectrc, \$commandname, $TEST_STATE);
3795     my($cmdrc) = $?;
3796
3797     $0 = "[runtest $testno]";
3798
3799     if ($debug) {
3800       print ">> rc=$rc cmdrc=$cmdrc\n";
3801       if (defined $run_extra) {
3802         foreach my $k (keys %$run_extra) {
3803           my $v = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : '<undef>';
3804           print ">>   $k -> $v\n";
3805         }
3806       }
3807     }
3808     $run_extra = {} unless defined $run_extra;
3809     foreach my $k (keys %$run_extra) {
3810       if (exists $TEST_STATE->{$k}) {
3811         my $nv = defined $run_extra->{$k} ? qq!"$run_extra->{$k}"! : 'removed';
3812         print ">> override of $k; was $TEST_STATE->{$k}, now $nv\n" if $debug;
3813       }
3814       if (defined $run_extra->{$k}) {
3815         $TEST_STATE->{$k} = $run_extra->{$k};
3816       } elsif (exists $TEST_STATE->{$k}) {
3817         delete $TEST_STATE->{$k};
3818       }
3819     }
3820
3821     # Hit EOF after an initial return code number
3822
3823     tests_exit(-1, "Unexpected EOF in script") if ($rc == 4);
3824
3825     # Carry on with the next command if we did not wait for this one. $rc == 0
3826     # if no subprocess was run; $rc == 3 if we started a process but did not
3827     # wait for it.
3828
3829     next if ($rc == 0 || $rc == 3);
3830
3831     # We ran and waited for a command. Check for the expected result unless
3832     # it died.
3833
3834     if ($cmdrc != $expectrc && !$sigpipehappened)
3835       {
3836       printf("** Command $commandno (\"$commandname\", starting at line $subtest_startline)\n");
3837       if (($cmdrc & 0xff) == 0)
3838         {
3839         printf("** Return code %d (expected %d)", $cmdrc/256, $expectrc/256);
3840         }
3841       elsif (($cmdrc & 0xff00) == 0)
3842         { printf("** Killed by signal %d", $cmdrc & 255); }
3843       else
3844         { printf("** Status %x", $cmdrc); }
3845
3846       for (;;)
3847         {
3848         print "\nshow stdErr, show stdOut, Retry, Continue (without file comparison), or Quit? [Q] ";
3849         $_ = $force_continue ? "c" : <T>;
3850         tests_exit(1) if /^q?$/i;
3851         log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3852         if ($force_continue)
3853           {
3854           print "\nstderr tail:\n";
3855           print "===================\n";
3856           system("tail -20 test-stderr");
3857           print "===================\n";
3858           print "... continue forced\n";
3859           }
3860
3861         last if /^[rc]$/i;
3862         if (/^e$/i)
3863           {
3864           system("$more test-stderr");
3865           }
3866         elsif (/^o$/i)
3867           {
3868           system("$more test-stdout");
3869           }
3870         }
3871
3872       $retry = 1 if /^r$/i;
3873       $docheck = 0;
3874       }
3875
3876     # If the command was exim, and a listening server is running, we can now
3877     # close its input, which causes us to wait for it to finish, which is why
3878     # we didn't close it earlier.
3879
3880     if ($rc == 2 && $server_pid != 0)
3881       {
3882       close SERVERCMD;
3883       $server_pid = 0;
3884       if ($? != 0)
3885         {
3886         if (($? & 0xff) == 0)
3887           { printf("Server return code %d", $?/256); }
3888         elsif (($? & 0xff00) == 0)
3889           { printf("Server killed by signal %d", $? & 255); }
3890         else
3891           { printf("Server status %x", $?); }
3892
3893         for (;;)
3894           {
3895           print "\nShow server stdout, Retry, Continue, or Quit? [Q] ";
3896           $_ = $force_continue ? "c" : <T>;
3897           tests_exit(1) if /^q?$/i;
3898           log_failure($log_failed_filename, $testno, "exit code unexpected") if (/^c$/i && $force_continue);
3899           print "... continue forced\n" if $force_continue;
3900           last if /^[rc]$/i;
3901
3902           if (/^s$/i)
3903             {
3904             open(S, "test-stdout-server") ||
3905               tests_exit(-1, "Failed to open test-stdout-server: $!");
3906             print while <S>;
3907             close(S);
3908             }
3909           }
3910         $retry = 1 if /^r$/i;
3911         }
3912       }
3913     }
3914
3915   close SCRIPT;
3916
3917   # The script has finished. Check the all the output that was generated. The
3918   # function returns 0 if all is well, 1 if we should rerun the test (the files
3919   # have been updated). It does not return if the user responds Q to a prompt.
3920
3921   if ($retry)
3922     {
3923     $retry = '0';
3924     print (("#" x 79) . "\n");
3925     redo;
3926     }
3927
3928   if ($docheck)
3929     {
3930     if (check_output($TEST_STATE->{munge}) != 0)
3931       {
3932       print (("#" x 79) . "\n");
3933       redo;
3934       }
3935     else
3936       {
3937       print ("  Script completed\n");
3938       }
3939     }
3940   }
3941
3942
3943 ##################################################
3944 #         Exit from the test script              #
3945 ##################################################
3946
3947 tests_exit(-1, "No runnable tests selected") if @test_list == 0;
3948 tests_exit(0);
3949
3950 # End of runtest script