src/src/exigrep.src

   1 #! PERL_COMMAND -w
   2
   3 use strict;
   4
   5 # Copyright (c) 2007 University of Cambridge.
   6 # See the file NOTICE for conditions of use and distribution.
   7
   8 # Except when they appear in comments, the following placeholders in this
   9 # source are replaced when it is turned into a runnable script:
  10 #
  11 # PERL_COMMAND
  12 # ZCAT_COMMAND
  13 # COMPRESS_SUFFIX
  14
  15 # PROCESSED_FLAG
  16
  17 # This is a perl script which extracts from an Exim log all entries
  18 # for all messages that have an entry that matches a given pattern.
  19 # If *any* entry for a particular message matches the pattern, *all*
  20 # entries for that message are displayed.
  21
  22 # We buffer up information on a per-message basis. It is done this way rather
  23 # than reading the input twice so that the input can be a pipe.
  24
  25 # There must be one argument, which is the pattern. Subsequent arguments
  26 # are the files to scan; if none, the standard input is read. If any file
  27 # appears to be compressed, it is passed through zcat. We can't just do this
  28 # for all files, because zcat chokes on non-compressed files.
  29
  30 # Performance optimized in 02/02/2007 by Jori Hamalainen
  31 # Typical run time acceleration: 4 times
  32
  33
  34 use Getopt::Std qw(getopts);
  35 use POSIX qw(mktime);
  36
  37
  38 # This subroutine converts a time/date string from an Exim log line into
  39 # the number of seconds since the epoch. It handles optional timezone
  40 # information.
  41
  42 sub seconds {
  43 my($year,$month,$day,$hour,$min,$sec,$tzs,$tzh,$tzm) =
  44   $_[0] =~ /^(\d{4})-(\d\d)-(\d\d)\s(\d\d):(\d\d):(\d\d)(?>\s([+-])(\d\d)(\d\d))?/o;
  45
  46 my $seconds = mktime $sec, $min, $hour, $day, $month - 1, $year - 1900;
  47
  48 if (defined $tzs)
  49   {
  50   $seconds -= $tzh * 3600 + $tzm * 60 if $tzs eq "+";
  51   $seconds += $tzh * 3600 + $tzm * 60 if $tzs eq "-";
  52   }
  53
  54 return $seconds;
  55 }
  56
  57
  58 # This subroutine processes a single line (in $_) from a log file. Program
  59 # defensively against short lines finding their way into the log.
  60
  61 my (%saved, %id_list, $pattern, $queue_time, $insensitive, $invert);
  62
  63 sub do_line {
  64
  65 # Convert syslog lines to mainlog format, as in eximstats.
  66
  67 if (!/^\d{4}-/o) { $_ =~ s/^.*? exim\b.*?: //o; }
  68
  69 return unless
  70   my($date,$id) = /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?(\w{6}\-\w{6}\-\w{2})?/o;
  71
  72 # Handle the case when the log line belongs to a specific message. We save
  73 # lines for specific messages until the message is complete. Then either print
  74 # or discard.
  75
  76 if (defined $id)
  77   {
  78   $saved{$id} = '' unless defined($saved{$id});
  79
  80   # Save up the data for this message in case it becomes interesting later.
  81
  82   $saved{$id} .= $_;
  83
  84   # Are we interested in this id ? Short circuit if we already were interested.
  85
  86   if ($invert)
  87     {
  88     $id_list{$id} = 1 if (!defined($id_list{$id}));
  89     $id_list{$id} = 0 if (($insensitive && /$pattern/io) || /$pattern/o);
  90     }
  91   else
  92     {
  93     $id_list{$id} = 1 if defined $id_list{$id} ||
  94       ($insensitive && /$pattern/io) || /$pattern/o;
  95     }
  96
  97   # See if this is a completion for some message. If it is interesting,
  98   # print it, but in any event, throw away what was saved.
  99
 100   if (index($_, 'Completed') != -1 ||
 101       index($_, 'SMTP data timeout') != -1 ||
 102         (index($_, 'rejected') != -1 &&
 103           /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d (?:[+-]\d{4} )?)(?:\[\d+\] )?\w{6}\-\w{6}\-\w{2} rejected/o))
 104     {
 105     if ($queue_time != -1 &&
 106         $saved{$id} =~ /^(\d{4}-\d\d-\d\d \d\d:\d\d:\d\d ([+-]\d{4} )?)/o)
 107       {
 108       my $old_sec = &seconds($1);
 109       my $sec = &seconds($date);
 110       $id_list{$id} = 0 if $id_list{$id} && $sec - $old_sec <= $queue_time;
 111       }
 112
 113     print "$saved{$id}\n" if ($id_list{$id});
 114     delete $id_list{$id};
 115     delete $saved{$id};
 116     }
 117   }
 118
 119 # Handle the case where the log line does not belong to a specific message.
 120 # Print it if it is interesting.
 121
 122 elsif ( ($invert && (($insensitive && !/$pattern/io) || !/$pattern/o)) ||
 123        (!$invert && (($insensitive &&  /$pattern/io) ||  /$pattern/o)) )
 124   { print "$_\n"; }
 125 }
 126
 127
 128 # The main program. Extract the pattern and make sure any relevant characters
 129 # are quoted if the -l flag is given. The -t flag gives a time-on-queue value
 130 # which is an additional condition.
 131
 132 getopts('Ilvt:',\my %args);
 133 $queue_time  = $args{'t'}? $args{'t'} : -1;
 134 $insensitive = $args{'I'}? 0 : 1;
 135 $invert      = $args{'v'}? 1 : 0;
 136
 137 die "usage: exigrep [-I] [-l] [-t <seconds>] [-v] <pattern> [<log file>]...\n"
 138   if ($#ARGV < 0);
 139
 140 $pattern = shift @ARGV;
 141 $pattern = quotemeta $pattern if $args{l};
 142
 143
 144 # If file arguments are given, open each one and process according as it is
 145 # is compressed or not.
 146
 147 if (@ARGV)
 148   {
 149   foreach (@ARGV)
 150     {
 151     my $filename = $_;
 152     if ($filename =~ /\.(?:COMPRESS_SUFFIX)$/o)
 153       {
 154       open(LOG, "ZCAT_COMMAND $filename |") ||
 155         die "Unable to zcat $filename: $!\n";
 156       }
 157     else
 158       {
 159       open(LOG, "<$filename") || die "Unable to open $filename: $!\n";
 160       }
 161     do_line() while (<LOG>);
 162     close(LOG);
 163     }
 164   }
 165
 166 # If no files are named, process STDIN only
 167
 168 else { do_line() while (<STDIN>); }
 169
 170 # At the end of processing all the input, print any uncompleted messages.
 171
 172 for (keys %id_list)
 173   {
 174   print "+++ $_ has not completed +++\n$saved{$_}\n";
 175   }
 176
 177 # End of exigrep