script/gen.pl

   1 #!/usr/bin/env perl
   2 #
   3 use strict;
   4 use warnings;
   5
   6 use CSS::Minifier::XS 0.07;
   7 use File::Copy;
   8 use File::Find;
   9 use File::Path qw(make_path);
  10 use File::Slurp;
  11 use File::Spec;
  12 use Getopt::Long;
  13 use JavaScript::Minifier::XS;
  14 use Pod::Usage;
  15 use XML::LibXML;
  16 use XML::LibXSLT;
  17
  18 my $canonical_url = 'http://www.exim.org/';
  19
  20 ## Parse arguments
  21 my %opt = parse_arguments();
  22
  23 ## Generate the pages
  24 do_doc( 'spec',   $_ ) foreach @{ $opt{spec}   || [] };
  25 do_doc( 'filter', $_ ) foreach @{ $opt{filter} || [] };
  26 do_web() if exists $opt{web};
  27
  28 ## Add the exim-html-current symlink
  29 print "Symlinking exim-html-current to exim-html-$opt{latest}\n";
  30 unlink("$opt{docroot}/exim-html-current") if ( -l "$opt{docroot}/exim-html-current" );
  31 symlink( "exim-html-$opt{latest}", "$opt{docroot}/exim-html-current" )
  32   || die "symlink to $opt{docroot}/exim-html-current failed";
  33
  34 ## Generate the website files
  35 sub do_web {
  36
  37     ## Make sure the template web directory exists
  38     die "No such directory: $opt{tmpl}/web\n" unless -d "$opt{tmpl}/web";
  39
  40     ## Scan the web templates
  41     find(
  42         sub {
  43             my ($path) = substr( $File::Find::name, length("$opt{tmpl}/web"), length($File::Find::name) ) =~ m#^/*(.*)$#;
  44
  45             if ( -d "$opt{tmpl}/web/$path" ) {
  46
  47                 ## Create the directory in the doc root if it doesn't exist
  48                 if ( !-d "$opt{docroot}/$path" ) {
  49                     mkdir("$opt{docroot}/$path") or die "Unable to make $opt{docroot}/$path: $!\n";
  50                 }
  51
  52             }
  53             else {
  54
  55                 ## Build HTML from XSL files and simply copy static files which have changed
  56                 if ( $path =~ /(.+)\.xsl$/ ) {
  57                     print "Generating  : docroot:/$1.html\n" if ($opt{verbose});
  58                     transform( undef, "$opt{tmpl}/web/$path", "$opt{docroot}/$1.html" );
  59                 }
  60                 elsif ( -f "$opt{tmpl}/web/$path" ) {
  61
  62                     ## Skip if the file hasn't changed (mtime based)
  63                     return if -f "$opt{docroot}/$path" && ( stat("$opt{tmpl}/web/$path") )[9] == ( stat("$opt{docroot}/$path") )[9];
  64
  65                     if ( $path =~ /(.+)\.css$/ ) {
  66                         print "CSS to  : docroot:/$path\n" if ($opt{verbose});
  67                         my $content = read_file("$opt{tmpl}/web/$path");
  68                         write_file( "$opt{docroot}/$path", $opt{minify} ? CSS::Minifier::XS::minify($content) : $content );
  69                     }
  70                     elsif ( $path =~ /(.+)\.js$/ ) {
  71                         print "JS to  : docroot:/$path\n" if ($opt{verbose});
  72                         my $content = read_file("$opt{tmpl}/web/$path");
  73                         write_file( "$opt{docroot}/$path", $opt{minify} ? JavaScript::Minifier::XS::minify($content) : $content );
  74                     }
  75                     else {
  76                         ## Copy
  77                         print "Copying to  : docroot:/$path\n" if ($opt{verbose});
  78                         copy( "$opt{tmpl}/web/$path", "$opt{docroot}/$path" ) or die "$path: $!";
  79                     }
  80                     ## Set mtime
  81                     utime( time, ( stat("$opt{tmpl}/web/$path") )[9], "$opt{docroot}/$path" );
  82                 }
  83             }
  84
  85         },
  86         "$opt{tmpl}/web"
  87     );
  88 }
  89
  90 ## Generate index/chapter files for a doc
  91 sub do_doc {
  92     my ( $type, $xml_path ) = @_;
  93
  94     ## Read and validate the XML file
  95     my $xml = XML::LibXML->new()->parse_file($xml_path) or die $!;
  96
  97     ## Get the version number
  98     my $version = $xml->findvalue('/book/bookinfo/revhistory/revision/revnumber');
  99     die "Unable to get version number\n" unless defined $version && $version =~ /^\d+(\.\d+)*$/;
 100
 101     ## Prepend chapter filenames?
 102     my $prepend_chapter = $type eq 'filter' ? 'filter_' : '';
 103
 104     ## Add the canonical url for this document
 105     $xml->documentElement()
 106       ->appendTextChild( 'canonical_url',
 107         "${canonical_url}exim-html-current/doc/html/spec_html/" . ( $type eq 'spec' ? 'index' : 'filter' ) . ".html" );
 108
 109     ## Fixup the XML
 110     xref_fixup( $xml, $prepend_chapter );
 111
 112     ## Generate the front page
 113     {
 114         my $path = "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? $type : 'index' ) . ".html";
 115         print "Generating  : docroot:/$path\n";
 116         transform( $xml, "$opt{tmpl}/doc/index.xsl", "$opt{docroot}/$path", );
 117     }
 118
 119     ## Generate a Table of Contents XML file
 120     {
 121         my $path = "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? 'filter_toc' : 'index_toc' ) . ".xml";
 122         print "Generating  : docroot:/$path\n" if ($opt{verbose});
 123         transform( $xml, "$opt{tmpl}/doc/toc.xsl", "$opt{docroot}/$path", );
 124     }
 125
 126     ## Generate the chapters
 127     my $counter = 0;
 128     foreach my $chapter ( map { $_->cloneNode(1) } $xml->findnodes('/book/chapter') ) {
 129
 130         ## Add a <chapter_id>N</chapter_id> node for the stylesheet to use
 131         $chapter->appendTextChild( 'chapter_id', ++$counter );
 132
 133         ## Add previous/next/canonical urls for nav
 134         {
 135             $chapter->appendTextChild( 'prev_url',
 136                   $counter == 1
 137                 ? $type eq 'filter'
 138                       ? 'filter.html'
 139                       : 'index.html'
 140                 : sprintf( '%sch%02d.html', $prepend_chapter, $counter - 1 ) );
 141             $chapter->appendTextChild( 'next_url', sprintf( '%sch%02d.html', $prepend_chapter, $counter + 1 ) );
 142             $chapter->appendTextChild( 'canonical_url',
 143                 sprintf( 'http://www.exim.org/exim-html-current/doc/html/spec_html/%sch%02d.html', $prepend_chapter, $counter ) );
 144         }
 145
 146         ## Create an XML document from the chapter
 147         my $doc = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );
 148         $doc->setDocumentElement($chapter);
 149
 150         ## Transform the chapter into html
 151         {
 152             my $path = sprintf( 'exim-html-%s/doc/html/spec_html/%sch%02d.html', $version, $prepend_chapter, $counter );
 153             print "Generating  : docroot:/$path\n" if ($opt{verbose});
 154             transform( $doc, "$opt{tmpl}/doc/chapter.xsl", "$opt{docroot}/$path", );
 155         }
 156     }
 157 }
 158
 159 ## Fixup xref tags
 160 sub xref_fixup {
 161     my ( $xml, $prepend_chapter ) = @_;
 162
 163     my %index = ();
 164
 165     ## Add the "prepend_chapter" info
 166     ( $xml->findnodes('/book') )[0]->appendTextChild( 'prepend_chapter', $prepend_chapter );
 167
 168     ## Iterate over each chapter
 169     my $chapter_counter = 0;
 170     foreach my $chapter ( $xml->findnodes('/book/chapter') ) {
 171         ++$chapter_counter;
 172
 173         my $chapter_id = $chapter->getAttribute('id');
 174         unless ($chapter_id) {    # synthesise missing id
 175             $chapter_id = sprintf( 'chapter_noid_%04d', $chapter_counter );
 176             $chapter->setAttribute( 'id', $chapter_id );
 177         }
 178         my $chapter_title = $chapter->findvalue('title');
 179
 180         $index{$chapter_id} = { chapter_id => $chapter_counter, chapter_title => $chapter_title };
 181
 182         ## Iterate over each section
 183         my $section_counter = 0;
 184         foreach my $section ( $chapter->findnodes('section') ) {
 185             ++$section_counter;
 186
 187             my $section_id = $section->getAttribute('id');
 188             unless ($section_id) {    # synthesise missing id
 189                 $section_id = sprintf( 'section_noid_%04d_%04d', $chapter_counter, $section_counter );
 190                 $section->setAttribute( 'id', $section_id );
 191             }
 192             my $section_title = $section->findvalue('title');
 193
 194             $index{$section_id} = {
 195                 chapter_id    => $chapter_counter,
 196                 chapter_title => $chapter_title,
 197                 section_id    => $section_counter,
 198                 section_title => $section_title
 199             };
 200         }
 201     }
 202     ## Build indexes as new chapters
 203     build_indexes( $xml, $prepend_chapter, \%index );
 204
 205     ## Replace all of the xrefs in the XML
 206     foreach my $xref ( $xml->findnodes('//xref') ) {
 207         my $linkend = $xref->getAttribute('linkend');
 208         if ( exists $index{$linkend} ) {
 209             $xref->setAttribute( 'chapter_id',    $index{$linkend}{'chapter_id'} );
 210             $xref->setAttribute( 'chapter_title', $index{$linkend}{'chapter_title'} );
 211             $xref->setAttribute( 'section_id',    $index{$linkend}{'section_id'} ) if ( $index{$linkend}{'section_id'} );
 212             $xref->setAttribute( 'section_title', $index{$linkend}{'section_title'} ) if ( $index{$linkend}{'section_title'} );
 213             $xref->setAttribute( 'url',
 214                 sprintf( '%sch%02d.html', $prepend_chapter, $index{$linkend}{'chapter_id'} )
 215                   . ( $index{$linkend}{'section_id'} ? '#' . $linkend : '' ) );
 216         }
 217     }
 218 }
 219
 220 ## Build indexes
 221 sub build_indexes {
 222     my ( $xml, $prepend_chapter, $xref ) = @_;
 223
 224     my $index_hash = {};
 225     my $current_id;
 226     foreach my $node ( $xml->findnodes('//section | //chapter | //indexterm') ) {
 227         if ( $node->nodeName eq 'indexterm' ) {
 228             my $role      = $node->getAttribute('role') || 'concept';
 229             my $primary   = $node->findvalue('child::primary');
 230             my $first     = ( $primary =~ /^[A-Za-z]/ ) ? uc( substr( $primary, 0, 1 ) ) : '';    # first letter or marker
 231             my $secondary = $node->findvalue('child::secondary') || '';
 232             next unless ( $primary || $secondary );                                               # skip blank entries for now...
 233             $index_hash->{$role}{$first}{$primary}{$secondary} ||= [];
 234             push @{ $index_hash->{$role}{$first}{$primary}{$secondary} }, $current_id;
 235         }
 236         else {
 237             $current_id = $node->getAttribute('id');
 238         }
 239     }
 240
 241     # now we build a set of new chapters with the index data in
 242     my $book = ( $xml->findnodes('/book') )[0];
 243     foreach my $role ( sort { $a cmp $b } keys %{$index_hash} ) {
 244         my $chapter = XML::LibXML::Element->new('chapter');
 245         $book->appendChild($chapter);
 246         $chapter->setAttribute( 'id', join( '_', 'index', $role ) );
 247         $chapter->setAttribute( 'class', 'index' );
 248         $chapter->appendTextChild( 'title', ( ucfirst($role) . ' Index' ) );
 249         foreach my $first ( sort { $a cmp $b } keys %{ $index_hash->{$role} } ) {
 250             my $section = XML::LibXML::Element->new('section');
 251             my $list    = XML::LibXML::Element->new('variablelist');
 252             $chapter->appendChild($section);
 253             $section->setAttribute( 'id', join( '_', 'index', $role, $first ) );
 254             $section->setAttribute( 'class', 'index' );
 255             $section->appendTextChild( 'title', $first ? $first : 'Symbols' );
 256             $section->appendChild($list);
 257             foreach my $primary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first} } ) {
 258                 my $entry = XML::LibXML::Element->new('varlistentry');
 259                 my $item  = XML::LibXML::Element->new('listitem');
 260                 $list->appendChild($entry)->appendTextChild( 'term', $primary );
 261                 $entry->appendChild($item);
 262                 my $slist;
 263                 foreach my $secondary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first}{$primary} } ) {
 264                     my $para = XML::LibXML::Element->new('para');
 265                     if ( $secondary eq '' ) {
 266                         $item->appendChild($para);    # skip having extra layer of heirarchy
 267                     }
 268                     else {
 269                         unless ($slist) {
 270                             $slist = XML::LibXML::Element->new('variablelist');
 271                             $item->appendChild($slist);
 272                         }
 273                         my $sentry = XML::LibXML::Element->new('varlistentry');
 274                         my $sitem  = XML::LibXML::Element->new('listitem');
 275                         $slist->appendChild($sentry)->appendTextChild( 'term', $secondary );
 276                         $sentry->appendChild($sitem)->appendChild($para);
 277                     }
 278                     my $count = 0;
 279                     foreach my $ref ( @{ $index_hash->{$role}{$first}{$primary}{$secondary} } ) {
 280                         $para->appendText(', ')
 281                           if ( $count++ );
 282                         my $xrefel = XML::LibXML::Element->new('xref');
 283                         $xrefel->setAttribute( linkend => $ref );
 284                         $xrefel->setAttribute( longref => 1 );
 285                         $para->appendChild($xrefel);
 286                     }
 287                 }
 288             }
 289         }
 290     }
 291 }
 292
 293 ## Handle the transformation
 294 sub transform {
 295     my ( $xml, $xsl_path, $out_path ) = @_;
 296
 297     ## Build an empty XML structure if an undefined $xml was passed
 298     unless ( defined $xml ) {
 299         $xml = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );
 300         $xml->setDocumentElement( $xml->createElement('content') );
 301     }
 302
 303     ## Add the current version of Exim to the XML
 304     $xml->documentElement()->appendTextChild( 'current_version', $opt{latest} );
 305
 306     ## Parse the ".xsl" file as XML
 307     my $xsl = XML::LibXML->new()->parse_file($xsl_path) or die $!;
 308
 309     ## Generate a stylesheet from the ".xsl" XML.
 310     my $stylesheet = XML::LibXSLT->new()->parse_stylesheet($xsl);
 311
 312     ## Generate a doc from the XML transformed with the XSL
 313     my $doc = $stylesheet->transform($xml);
 314
 315     ## Make the containing directory if it doesn't exist
 316     make_path( ( $out_path =~ /^(.+)\/.+$/ )[0], { verbose => 1 } );
 317
 318     ## Write out the document
 319     open my $out, '>', $out_path or die "Unable to write $out_path - $!";
 320     print $out $stylesheet->output_as_bytes($doc);
 321     close $out;
 322 }
 323
 324 ## error_help
 325 sub error_help {
 326     my $msg = shift;
 327
 328     warn $msg;
 329     pod2usage( -exitval => 1, -verbose => 0 );
 330 }
 331
 332 ## Parse arguments
 333 sub parse_arguments {
 334
 335     my %opt = ( spec => [], filter => [], help => 0, man => 0, web => 0, minify => 1, verbose => 0 );
 336     GetOptions( \%opt, 'help|h!', 'man!', 'web!', 'spec=s{1,}', 'filter=s{1,}', 'latest=s', 'tmpl=s', 'docroot=s', 'minify!', 'verbose!' )
 337       || pod2usage( -exitval => 1, -verbose => 0 );
 338
 339     ## --help
 340     pod2usage(0) if ( $opt{help} );
 341     pod2usage( -verbose => 2 ) if ( $opt{man} );
 342
 343     ## --spec and --filter lists
 344     foreach my $set (qw[spec filter]) {
 345         $opt{$set} = [ map { my $f = File::Spec->rel2abs($_); help( 1, 'No such file: ' . $_ ) unless -f $f; $f } @{ $opt{$set} } ];
 346     }
 347     ## --latest
 348     error_help('Missing value for latest') unless ( exists( $opt{latest} ) && defined( $opt{latest} ) );
 349     error_help('Invalid value for latest') unless $opt{latest} =~ /^\d+(?:\.\d+)*$/;
 350
 351     ## --tmpl and --docroot
 352     foreach my $set (qw[tmpl docroot]) {
 353         error_help( 'Missing value for ' . $set ) unless ( exists( $opt{$set} ) && defined( $opt{$set} ) );
 354         my $f = File::Spec->rel2abs( $opt{$set} );
 355         error_help( 'No such directory: ' . $opt{$set} ) unless -d $f;
 356         $opt{$set} = $f;
 357     }
 358     error_help('Excess arguments') if ( scalar(@ARGV) );
 359
 360     error_help('Must include at least one of --web, --spec or --filter')
 361       unless ( $opt{web} || scalar( @{ $opt{spec} || [] } ) || scalar( @{ $opt{filter} || [] } ) );
 362
 363     return %opt;
 364 }
 365
 366 1;
 367
 368 __END__
 369
 370 =head1 NAME
 371
 372 gen.pl - Generate exim html documentation and website
 373
 374 =head1 SYNOPSIS
 375
 376 gen.pl [options]
 377
 378  Options:
 379    --help              display this help and exits
 380    --man               displays man page
 381    --spec file...      spec docbook/XML source files
 382    --filter file...    filter docbook/XML source files
 383    --web               Generate the general website pages
 384    --latest VERSION    Required. Specify the latest stable version of Exim.
 385    --tmpl PATH         Required. Path to the templates directory
 386    --docroot PATH      Required. Path to the website document root
 387    --[no-]minify       [Don't] minify CSS and Javascript
 388
 389 =head1 OPTIONS
 390
 391 =over 4
 392
 393 =item B<--help>
 394
 395 Display help and exits
 396
 397 =item B<--man>
 398
 399 Display man page
 400
 401 =item B<--spec> I<file...>
 402
 403 List of files that make up the specification documentation
 404 docbook/XML source files.
 405
 406 =item B<--filter> I<file...>
 407
 408 List of files that make up the filter documentation docbook/XML
 409 source files.
 410
 411 =item B<--web>
 412
 413 Generate the website from the template files.
 414
 415 =item B<--latest> I<version>
 416
 417 Specify the current exim version. This is used to create links to
 418 the current documentation.
 419
 420 This option is I<required>
 421
 422 =item B<--tmpl> I<directory>
 423
 424 Specify the directory that the templates are kept in.
 425
 426 This option is I<required>
 427
 428 =item B<--docroot> I<directory>
 429
 430 Specify the directory that the output should be generated into.
 431 This is the website C<docroot> directory.
 432
 433 This option is I<required>
 434
 435 =item B<--minify>
 436
 437 If this option is set then both the CSS and Javascript files
 438 processed are minified using L<CSS::Minifier::XS> and
 439 L<JavaScript::Minifier::XS> respectively.
 440
 441 This option is set by default - to disable it specify C<--no-minify>
 442
 443 =back
 444
 445 =head1 DESCRIPTION
 446
 447 Generates the exim website and HTML documentation.
 448
 449 =head1 EXAMPLE
 450
 451     script/gen.pl \
 452       --web \
 453       --spec docbook/*/spec.xml \
 454       --filter  docbook/*/filter.xml \
 455       --latest 4.72 \
 456       --tmpl templates \
 457       --docroot /tmp/website
 458
 459 =head1 AUTHOR
 460
 461 Mike Cardwell
 462
 463 Nigel Metheringham <nigel@exim.org> - mostly broke the framework
 464 Mike produced.
 465
 466 =head1 COPYRIGHT
 467
 468 Copyright 2010 Exim Maintainers. All rights reserved.
 469
 470 =cut
 471