script/gen.pl

   1 #!/usr/bin/env perl
   2 #
   3 use strict;
   4 use warnings;
   5
   6 use CSS::Minifier::XS 0.07;
   7 use File::Copy;
   8 use File::Find;
   9 use File::Path qw(make_path);
  10 use File::Slurp;
  11 use File::Spec;
  12 use Getopt::Long;
  13 use JavaScript::Minifier::XS;
  14 use Pod::Usage;
  15 use XML::LibXML;
  16 use XML::LibXSLT;
  17
  18 my $canonical_url = 'http://www.exim.org/';
  19
  20 ## Parse arguments
  21 my %opt = parse_arguments();
  22
  23 ## Generate the pages
  24 do_doc( 'spec',   $_ ) foreach @{ $opt{spec}   || [] };
  25 do_doc( 'filter', $_ ) foreach @{ $opt{filter} || [] };
  26 do_web() if exists $opt{web};
  27
  28 ## Add the exim-html-current symlink
  29 print "Symlinking exim-html-current to exim-html-$opt{latest}\n";
  30 unlink("$opt{docroot}/exim-html-current") if ( -l "$opt{docroot}/exim-html-current" );
  31 symlink( "exim-html-$opt{latest}", "$opt{docroot}/exim-html-current" )
  32     || die "symlink to $opt{docroot}/exim-html-current failed";
  33
  34 ## Generate the website files
  35 sub do_web {
  36
  37     ## Make sure the template web directory exists
  38     die "No such directory: $opt{tmpl}/web\n" unless -d "$opt{tmpl}/web";
  39
  40     ## Scan the web templates
  41     find(
  42         sub {
  43             my ($path) =
  44                 substr( $File::Find::name, length("$opt{tmpl}/web"), length($File::Find::name) ) =~ m#^/*(.*)$#;
  45
  46             if ( -d "$opt{tmpl}/web/$path" ) {
  47
  48                 ## Create the directory in the doc root if it doesn't exist
  49                 if ( !-d "$opt{docroot}/$path" ) {
  50                     mkdir("$opt{docroot}/$path") or die "Unable to make $opt{docroot}/$path: $!\n";
  51                 }
  52
  53             }
  54             else {
  55
  56                 ## Build HTML from XSL files and simply copy static files which have changed
  57                 if ( $path =~ /(.+)\.xsl$/ ) {
  58                     print "Generating  : docroot:/$1.html\n" if ( $opt{verbose} );
  59                     transform( undef, "$opt{tmpl}/web/$path", "$opt{docroot}/$1.html" );
  60                 }
  61                 elsif ( -f "$opt{tmpl}/web/$path" ) {
  62
  63                     ## Skip if the file hasn't changed (mtime based)
  64                     return
  65                         if -f "$opt{docroot}/$path"
  66                             && ( stat("$opt{tmpl}/web/$path") )[9] == ( stat("$opt{docroot}/$path") )[9];
  67
  68                     if ( $path =~ /(.+)\.css$/ ) {
  69                         print "CSS to  : docroot:/$path\n" if ( $opt{verbose} );
  70                         my $content = read_file("$opt{tmpl}/web/$path");
  71                         write_file( "$opt{docroot}/$path",
  72                             $opt{minify} ? CSS::Minifier::XS::minify($content) : $content );
  73                     }
  74                     elsif ( $path =~ /(.+)\.js$/ ) {
  75                         print "JS to  : docroot:/$path\n" if ( $opt{verbose} );
  76                         my $content = read_file("$opt{tmpl}/web/$path");
  77                         write_file( "$opt{docroot}/$path",
  78                             $opt{minify} ? JavaScript::Minifier::XS::minify($content) : $content );
  79                     }
  80                     else {
  81                         ## Copy
  82                         print "Copying to  : docroot:/$path\n" if ( $opt{verbose} );
  83                         copy( "$opt{tmpl}/web/$path", "$opt{docroot}/$path" ) or die "$path: $!";
  84                     }
  85                     ## Set mtime
  86                     utime( time, ( stat("$opt{tmpl}/web/$path") )[9], "$opt{docroot}/$path" );
  87                 }
  88             }
  89
  90         },
  91         "$opt{tmpl}/web"
  92     );
  93 }
  94
  95 ## Generate index/chapter files for a doc
  96 sub do_doc {
  97     my ( $type, $xml_path ) = @_;
  98
  99     ## Read and validate the XML file
 100     my $xml = XML::LibXML->new()->parse_file($xml_path) or die $!;
 101
 102     ## Get the version number
 103     my $version = $xml->findvalue('/book/bookinfo/revhistory/revision/revnumber');
 104     die "Unable to get version number\n" unless defined $version && $version =~ /^\d+(\.\d+)*$/;
 105
 106     ## Prepend chapter filenames?
 107     my $prepend_chapter = $type eq 'filter' ? 'filter_' : '';
 108
 109     ## Add the canonical url for this document
 110     $xml->documentElement()
 111         ->appendTextChild( 'canonical_url',
 112         "${canonical_url}exim-html-current/doc/html/spec_html/" . ( $type eq 'spec' ? 'index' : 'filter' ) . ".html" );
 113
 114     ## Fixup the XML
 115     xref_fixup( $xml, $prepend_chapter );
 116
 117     ## Generate the front page
 118     {
 119         my $path = "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? $type : 'index' ) . ".html";
 120         print "Generating  : docroot:/$path\n";
 121         transform( $xml, "$opt{tmpl}/doc/index.xsl", "$opt{docroot}/$path", );
 122     }
 123
 124     ## Generate a Table of Contents XML file
 125     {
 126         my $path =
 127             "exim-html-$version/doc/html/spec_html/" . ( $type eq 'filter' ? 'filter_toc' : 'index_toc' ) . ".xml";
 128         print "Generating  : docroot:/$path\n" if ( $opt{verbose} );
 129         transform( $xml, "$opt{tmpl}/doc/toc.xsl", "$opt{docroot}/$path", );
 130     }
 131
 132     ## Generate the chapters
 133     my $counter = 0;
 134     foreach my $chapter ( map { $_->cloneNode(1) } $xml->findnodes('/book/chapter') ) {
 135
 136         ## Add a <chapter_id>N</chapter_id> node for the stylesheet to use
 137         $chapter->appendTextChild( 'chapter_id', ++$counter );
 138
 139         ## Add previous/next/canonical urls for nav
 140         {
 141             $chapter->appendTextChild( 'prev_url',
 142                   $counter == 1
 143                 ? $type eq 'filter'
 144                         ? 'filter.html'
 145                         : 'index.html'
 146                 : sprintf( '%sch%02d.html', $prepend_chapter, $counter - 1 ) );
 147             $chapter->appendTextChild( 'next_url', sprintf( '%sch%02d.html', $prepend_chapter, $counter + 1 ) );
 148             $chapter->appendTextChild(
 149                 'canonical_url',
 150                 sprintf(
 151                     'http://www.exim.org/exim-html-current/doc/html/spec_html/%sch%02d.html',
 152                     $prepend_chapter, $counter
 153                 )
 154             );
 155         }
 156
 157         ## Create an XML document from the chapter
 158         my $doc = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );
 159         $doc->setDocumentElement($chapter);
 160
 161         ## Transform the chapter into html
 162         {
 163             my $path = sprintf( 'exim-html-%s/doc/html/spec_html/%sch%02d.html', $version, $prepend_chapter, $counter );
 164             print "Generating  : docroot:/$path\n" if ( $opt{verbose} );
 165             transform( $doc, "$opt{tmpl}/doc/chapter.xsl", "$opt{docroot}/$path", );
 166         }
 167     }
 168 }
 169
 170 ## Fixup xref tags
 171 sub xref_fixup {
 172     my ( $xml, $prepend_chapter ) = @_;
 173
 174     my %index = ();
 175
 176     ## Add the "prepend_chapter" info
 177     ( $xml->findnodes('/book') )[0]->appendTextChild( 'prepend_chapter', $prepend_chapter );
 178
 179     ## Iterate over each chapter
 180     my $chapter_counter = 0;
 181     foreach my $chapter ( $xml->findnodes('/book/chapter') ) {
 182         ++$chapter_counter;
 183
 184         my $chapter_id = $chapter->getAttribute('id');
 185         unless ($chapter_id) {    # synthesise missing id
 186             $chapter_id = sprintf( 'chapter_noid_%04d', $chapter_counter );
 187             $chapter->setAttribute( 'id', $chapter_id );
 188         }
 189         my $chapter_title = $chapter->findvalue('title');
 190
 191         $index{$chapter_id} = { chapter_id => $chapter_counter, chapter_title => $chapter_title };
 192
 193         ## Iterate over each section
 194         my $section_counter = 0;
 195         foreach my $section ( $chapter->findnodes('section') ) {
 196             ++$section_counter;
 197
 198             my $section_id = $section->getAttribute('id');
 199             unless ($section_id) {    # synthesise missing id
 200                 $section_id = sprintf( 'section_noid_%04d_%04d', $chapter_counter, $section_counter );
 201                 $section->setAttribute( 'id', $section_id );
 202             }
 203             my $section_title = $section->findvalue('title');
 204
 205             $index{$section_id} = {
 206                 chapter_id    => $chapter_counter,
 207                 chapter_title => $chapter_title,
 208                 section_id    => $section_counter,
 209                 section_title => $section_title
 210             };
 211         }
 212     }
 213     ## Build indexes as new chapters
 214     build_indexes( $xml, $prepend_chapter, \%index );
 215
 216     ## Replace all of the xrefs in the XML
 217     foreach my $xref ( $xml->findnodes('//xref') ) {
 218         my $linkend = $xref->getAttribute('linkend');
 219         if ( exists $index{$linkend} ) {
 220             $xref->setAttribute( 'chapter_id',    $index{$linkend}{'chapter_id'} );
 221             $xref->setAttribute( 'chapter_title', $index{$linkend}{'chapter_title'} );
 222             $xref->setAttribute( 'section_id', $index{$linkend}{'section_id'} ) if ( $index{$linkend}{'section_id'} );
 223             $xref->setAttribute( 'section_title', $index{$linkend}{'section_title'} )
 224                 if ( $index{$linkend}{'section_title'} );
 225             $xref->setAttribute( 'url',
 226                 sprintf( '%sch%02d.html', $prepend_chapter, $index{$linkend}{'chapter_id'} )
 227                     . ( $index{$linkend}{'section_id'} ? '#' . $linkend : '' ) );
 228         }
 229     }
 230 }
 231
 232 ## Build indexes
 233 sub build_indexes {
 234     my ( $xml, $prepend_chapter, $xref ) = @_;
 235
 236     my $index_hash = {};
 237     my $current_id;
 238     foreach my $node ( $xml->findnodes('//section | //chapter | //indexterm') ) {
 239         if ( $node->nodeName eq 'indexterm' ) {
 240             my $role      = $node->getAttribute('role') || 'concept';
 241             my $primary   = $node->findvalue('child::primary');
 242             my $first     = ( $primary =~ /^[A-Za-z]/ ) ? uc( substr( $primary, 0, 1 ) ) : '';  # first letter or marker
 243             my $secondary = $node->findvalue('child::secondary') || '';
 244             next unless ( $primary || $secondary );    # skip blank entries for now...
 245             $index_hash->{$role}{$first}{$primary}{$secondary} ||= [];
 246             push @{ $index_hash->{$role}{$first}{$primary}{$secondary} }, $current_id;
 247         }
 248         else {
 249             $current_id = $node->getAttribute('id');
 250         }
 251     }
 252
 253     # now we build a set of new chapters with the index data in
 254     my $book = ( $xml->findnodes('/book') )[0];
 255     foreach my $role ( sort { $a cmp $b } keys %{$index_hash} ) {
 256         my $chapter = XML::LibXML::Element->new('chapter');
 257         $book->appendChild($chapter);
 258         $chapter->setAttribute( 'id', join( '_', 'index', $role ) );
 259         $chapter->setAttribute( 'class', 'index' );
 260         $chapter->appendTextChild( 'title', ( ucfirst($role) . ' Index' ) );
 261         foreach my $first ( sort { $a cmp $b } keys %{ $index_hash->{$role} } ) {
 262             my $section = XML::LibXML::Element->new('section');
 263             my $list    = XML::LibXML::Element->new('variablelist');
 264             $chapter->appendChild($section);
 265             $section->setAttribute( 'id', join( '_', 'index', $role, $first ) );
 266             $section->setAttribute( 'class', 'index' );
 267             $section->appendTextChild( 'title', $first ? $first : 'Symbols' );
 268             $section->appendChild($list);
 269             foreach my $primary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first} } ) {
 270                 my $entry = XML::LibXML::Element->new('varlistentry');
 271                 my $item  = XML::LibXML::Element->new('listitem');
 272                 $list->appendChild($entry)->appendTextChild( 'term', $primary );
 273                 $entry->appendChild($item);
 274                 my $slist;
 275                 foreach my $secondary ( sort { $a cmp $b } keys %{ $index_hash->{$role}{$first}{$primary} } ) {
 276                     my $para = XML::LibXML::Element->new('para');
 277                     if ( $secondary eq '' ) {
 278                         $item->appendChild($para);    # skip having extra layer of heirarchy
 279                     }
 280                     else {
 281                         unless ($slist) {
 282                             $slist = XML::LibXML::Element->new('variablelist');
 283                             $item->appendChild($slist);
 284                         }
 285                         my $sentry = XML::LibXML::Element->new('varlistentry');
 286                         my $sitem  = XML::LibXML::Element->new('listitem');
 287                         $slist->appendChild($sentry)->appendTextChild( 'term', $secondary );
 288                         $sentry->appendChild($sitem)->appendChild($para);
 289                     }
 290                     my $count = 0;
 291                     foreach my $ref ( @{ $index_hash->{$role}{$first}{$primary}{$secondary} } ) {
 292                         $para->appendText(', ')
 293                             if ( $count++ );
 294                         my $xrefel = XML::LibXML::Element->new('xref');
 295                         $xrefel->setAttribute( linkend => $ref );
 296                         $xrefel->setAttribute( longref => 1 );
 297                         $para->appendChild($xrefel);
 298                     }
 299                 }
 300             }
 301         }
 302     }
 303 }
 304
 305 ## Handle the transformation
 306 sub transform {
 307     my ( $xml, $xsl_path, $out_path ) = @_;
 308
 309     ## Build an empty XML structure if an undefined $xml was passed
 310     unless ( defined $xml ) {
 311         $xml = XML::LibXML::Document->createDocument( '1.0', 'UTF-8' );
 312         $xml->setDocumentElement( $xml->createElement('content') );
 313     }
 314
 315     ## Add the current version of Exim to the XML
 316     $xml->documentElement()->appendTextChild( 'current_version', $opt{latest} );
 317
 318     ## Parse the ".xsl" file as XML
 319     my $xsl = XML::LibXML->new()->parse_file($xsl_path) or die $!;
 320
 321     ## Generate a stylesheet from the ".xsl" XML.
 322     my $stylesheet = XML::LibXSLT->new()->parse_stylesheet($xsl);
 323
 324     ## Generate a doc from the XML transformed with the XSL
 325     my $doc = $stylesheet->transform($xml);
 326
 327     ## Make the containing directory if it doesn't exist
 328     make_path( ( $out_path =~ /^(.+)\/.+$/ )[0], { verbose => 1 } );
 329
 330     ## Write out the document
 331     open my $out, '>', $out_path or die "Unable to write $out_path - $!";
 332     print $out $stylesheet->output_as_bytes($doc);
 333     close $out;
 334 }
 335
 336 ## error_help
 337 sub error_help {
 338     my $msg = shift;
 339
 340     warn $msg;
 341     pod2usage( -exitval => 1, -verbose => 0 );
 342 }
 343
 344 ## Parse arguments
 345 sub parse_arguments {
 346
 347     my %opt = ( spec => [], filter => [], help => 0, man => 0, web => 0, minify => 1, verbose => 0 );
 348     GetOptions(
 349         \%opt,      'help|h!', 'man!',      'web!',    'spec=s{1,}', 'filter=s{1,}',
 350         'latest=s', 'tmpl=s',  'docroot=s', 'minify!', 'verbose!'
 351     ) || pod2usage( -exitval => 1, -verbose => 0 );
 352
 353     ## --help
 354     pod2usage(0) if ( $opt{help} );
 355     pod2usage( -verbose => 2 ) if ( $opt{man} );
 356
 357     ## --spec and --filter lists
 358     foreach my $set (qw[spec filter]) {
 359         $opt{$set} =
 360             [ map { my $f = File::Spec->rel2abs($_); help( 1, 'No such file: ' . $_ ) unless -f $f; $f }
 361                 @{ $opt{$set} } ];
 362     }
 363     ## --latest
 364     error_help('Missing value for latest') unless ( exists( $opt{latest} ) && defined( $opt{latest} ) );
 365     error_help('Invalid value for latest') unless $opt{latest} =~ /^\d+(?:\.\d+)*$/;
 366
 367     ## --tmpl and --docroot
 368     foreach my $set (qw[tmpl docroot]) {
 369         error_help( 'Missing value for ' . $set ) unless ( exists( $opt{$set} ) && defined( $opt{$set} ) );
 370         my $f = File::Spec->rel2abs( $opt{$set} );
 371         error_help( 'No such directory: ' . $opt{$set} ) unless -d $f;
 372         $opt{$set} = $f;
 373     }
 374     error_help('Excess arguments') if ( scalar(@ARGV) );
 375
 376     error_help('Must include at least one of --web, --spec or --filter')
 377         unless ( $opt{web} || scalar( @{ $opt{spec} || [] } ) || scalar( @{ $opt{filter} || [] } ) );
 378
 379     return %opt;
 380 }
 381
 382 1;
 383
 384 __END__
 385
 386 =head1 NAME
 387
 388 gen.pl - Generate exim html documentation and website
 389
 390 =head1 SYNOPSIS
 391
 392 gen.pl [options]
 393
 394  Options:
 395    --help              display this help and exits
 396    --man               displays man page
 397    --spec file...      spec docbook/XML source files
 398    --filter file...    filter docbook/XML source files
 399    --web               Generate the general website pages
 400    --latest VERSION    Required. Specify the latest stable version of Exim.
 401    --tmpl PATH         Required. Path to the templates directory
 402    --docroot PATH      Required. Path to the website document root
 403    --[no-]minify       [Don't] minify CSS and Javascript
 404
 405 =head1 OPTIONS
 406
 407 =over 4
 408
 409 =item B<--help>
 410
 411 Display help and exits
 412
 413 =item B<--man>
 414
 415 Display man page
 416
 417 =item B<--spec> I<file...>
 418
 419 List of files that make up the specification documentation
 420 docbook/XML source files.
 421
 422 =item B<--filter> I<file...>
 423
 424 List of files that make up the filter documentation docbook/XML
 425 source files.
 426
 427 =item B<--web>
 428
 429 Generate the website from the template files.
 430
 431 =item B<--latest> I<version>
 432
 433 Specify the current exim version. This is used to create links to
 434 the current documentation.
 435
 436 This option is I<required>
 437
 438 =item B<--tmpl> I<directory>
 439
 440 Specify the directory that the templates are kept in.
 441
 442 This option is I<required>
 443
 444 =item B<--docroot> I<directory>
 445
 446 Specify the directory that the output should be generated into.
 447 This is the website C<docroot> directory.
 448
 449 This option is I<required>
 450
 451 =item B<--minify>
 452
 453 If this option is set then both the CSS and Javascript files
 454 processed are minified using L<CSS::Minifier::XS> and
 455 L<JavaScript::Minifier::XS> respectively.
 456
 457 This option is set by default - to disable it specify C<--no-minify>
 458
 459 =back
 460
 461 =head1 DESCRIPTION
 462
 463 Generates the exim website and HTML documentation.
 464
 465 =head1 EXAMPLE
 466
 467     script/gen.pl \
 468       --web \
 469       --spec docbook/*/spec.xml \
 470       --filter  docbook/*/filter.xml \
 471       --latest 4.72 \
 472       --tmpl templates \
 473       --docroot /tmp/website
 474
 475 =head1 AUTHOR
 476
 477 Mike Cardwell
 478
 479 Nigel Metheringham <nigel@exim.org> - mostly broke the framework
 480 Mike produced.
 481
 482 =head1 COPYRIGHT
 483
 484 Copyright 2010 Exim Maintainers. All rights reserved.
 485
 486 =cut